fixincludes/configure.ac

   1 AC_PREREQ(2.59)
   2
   3 AC_INIT(fixincludes, [ ])
   4 AC_CONFIG_SRCDIR(inclhack.def)
   5 AC_CONFIG_AUX_DIR(..)
   6 AC_CANONICAL_SYSTEM
   7 AC_PROG_CC
   8
   9 # Choose one or two-process fix methodology.  Systems that cannot handle
  10 # bi-directional pipes must use the two process method.
  11 #
  12 case $host in
  13         i?86-*-msdosdjgpp* | \
  14         *-*-beos* )
  15                 TARGET=twoprocess
  16                 AC_DEFINE(SEPARATE_FIX_PROC, 1, [Define if testing and fixing are done by separate process])
  17                 ;;
  18
  19         vax-dec-bsd* )
  20                 TARGET=oneprocess
  21                 AC_DEFINE(exit, xexit, [Define to xexit if the host system does not support atexit])
  22                 AC_DEFINE(atexit, xatexit, [Define to xatexit if the host system does not support atexit])
  23                 ;;
  24
  25         * )
  26                 TARGET=oneprocess
  27                 ;;
  28 esac
  29 AC_SUBST(TARGET)
  30
  31 # Checks for header files.
  32 AC_HEADER_STDC
  33 AC_CHECK_HEADERS([stddef.h stdlib.h strings.h unistd.h fcntl.h sys/file.h \
  34         sys/stat.h])
  35 AC_CHECK_FUNCS(putc_unlocked fputc_unlocked fputs_unlocked \
  36         fwrite_unlocked fprintf_unlocked)
  37 AC_CHECK_DECLS([abort, errno, putc_unlocked, fputc_unlocked,
  38         fputs_unlocked, fwrite_unlocked, fprintf_unlocked])
  39
  40 # Checks for typedefs, structures, and compiler characteristics.
  41 AC_C_CONST
  42
  43 # Checks for library functions.
  44 gcc_AC_FUNC_MMAP_BLACKLIST
  45
  46 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  47 AC_ARG_ENABLE(maintainer-mode,
  48 [  --enable-maintainer-mode enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       USE_MAINTAINER_MODE=$enableval,
  51       USE_MAINTAINER_MODE=no)
  52 AC_MSG_RESULT($USE_MAINTAINER_MODE)
  53 if test "$USE_MAINTAINER_MODE" = yes; then
  54   MAINT=
  55 else
  56   MAINT='#'
  57 fi
  58 AC_SUBST(MAINT)
  59
  60 AC_CONFIG_HEADERS(config.h, [echo timestamp > stamp-h])
  61 AC_CONFIG_FILES(Makefile)
  62 AC_OUTPUT