configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 ### we might need to use some other shell than /bin/sh for running subshells
  93 ### If we are on Windows, search for the shell.  This will permit people
  94 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
  95 ### without also having to set CONFIG_SHELL.  This code will work when
  96 ### using bash, which sets OSTYPE.
  97 case "${OSTYPE}" in
  98 *win32*)
  99   if test x${CONFIG_SHELL} = x ; then
 100     if test ! -f /bin/sh ; then
 101       if test x${SHELL} != x && test -f ${SHELL} ; then
 102         CONFIG_SHELL=${SHELL}
 103         export CONFIG_SHELL
 104       else
 105         for prog in sh sh.exe bash bash.exe; do
 106           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
 107           for dir in $PATH; do
 108             test -z "$dir" && dir=.
 109             if test -f $dir/$prog; then
 110               CONFIG_SHELL=$dir/$prog
 111               export CONFIG_SHELL
 112               break
 113             fi
 114           done
 115           IFS="$save_ifs"
 116           test -n "${CONFIG_SHELL}" && break
 117         done
 118       fi
 119     fi
 120   fi
 121   ;;
 122 esac
 123
 124 config_shell=${CONFIG_SHELL-/bin/sh}
 125
 126 moveifchange=${srcdir}/move-if-change
 127
 128 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 129
 130 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 131 # a relative path.
 132 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 133   INSTALL="${srcpwd}/install-sh -c"
 134 fi
 135
 136 # Set srcdir to "." if that's what it is.
 137 # This is important for multilib support.
 138 pwd=`${PWDCMD-pwd}`
 139 if test "${pwd}" = "${srcpwd}" ; then
 140   srcdir=.
 141 fi
 142
 143 topsrcdir=$srcpwd
 144
 145 extra_host_args=
 146
 147 ### To add a new directory to the tree, first choose whether it is a target
 148 ### or a host dependent tool.  Then put it into the appropriate list
 149 ### (library or tools, host or target), doing a dependency sort.
 150
 151 # Subdirs will be configured in the order listed in build_configdirs,
 152 # configdirs, or target_configdirs; see the serialization section below.
 153
 154 # Dependency sorting is only needed when *configuration* must be done in
 155 # a particular order.  In all cases a dependency should be specified in
 156 # the Makefile, whether or not it's implicitly specified here.
 157
 158 # Double entries in build_configdirs, configdirs, or target_configdirs may
 159 # cause circular dependencies and break everything horribly.
 160
 161 # these library is used by various programs built for the build
 162 # environment
 163 #
 164 build_libs="build-libiberty"
 165
 166 # these tools are built for the build environment
 167 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
 168
 169 # these libraries are used by various programs built for the host environment
 170 #
 171 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 172
 173 # these tools are built for the host environment
 174 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 175 # know that we are building the simulator.
 176 # binutils, gas and ld appear in that order because it makes sense to run
 177 # "make check" in that particular order.
 178 # If --enable-gold is used, "gold" may replace "ld".
 179 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc cgen sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
 180
 181 # libgcj represents the runtime libraries only used by gcj.
 182 libgcj="target-libffi \
 183         target-zlib \
 184         target-qthreads \
 185         target-libjava"
 186
 187 # these libraries are built for the target environment, and are built after
 188 # the host libraries and the host tools (which may be a cross compiler)
 189 #
 190 target_libraries="target-libgcc \
 191                 target-libiberty \
 192                 target-libgloss \
 193                 target-newlib \
 194                 target-libgomp \
 195                 target-libstdc++-v3 \
 196                 target-libmudflap \
 197                 target-libssp \
 198                 target-libquadmath \
 199                 target-libgfortran \
 200                 target-boehm-gc \
 201                 ${libgcj} \
 202                 target-libobjc \
 203                 target-libada \
 204                 target-libgo"
 205
 206 # these tools are built using the target libraries, and are intended to
 207 # run only in the target environment
 208 #
 209 # note: any program that *uses* libraries that are in the "target_libraries"
 210 # list belongs in this list.  those programs are also very likely
 211 # candidates for the "native_only" list which follows
 212 #
 213 target_tools="target-examples target-groff target-gperf target-rda"
 214
 215 ################################################################################
 216
 217 ## All tools belong in one of the four categories, and are assigned above
 218 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 219 ## is important because configure will choke if they ever get through.
 220 ## ${configdirs} is directories we build using the host tools.
 221 ## ${target_configdirs} is directories we build using the target tools.
 222 configdirs=`echo ${host_libs} ${host_tools}`
 223 target_configdirs=`echo ${target_libraries} ${target_tools}`
 224 build_configdirs=`echo ${build_libs} ${build_tools}`
 225
 226 m4_divert_text([PARSE_ARGS],
 227 [case $srcdir in
 228   *" "*)
 229 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 230     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 231 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 232     ;;
 233 esac
 234 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 235 ])
 236
 237 ################################################################################
 238
 239 srcname="gnu development package"
 240
 241 # This gets set non-empty for some net releases of packages.
 242 appdirs=""
 243
 244 # Define is_cross_compiler to save on calls to 'test'.
 245 is_cross_compiler=
 246 if test x"${host}" = x"${target}" ; then
 247   is_cross_compiler=no
 248 else
 249   is_cross_compiler=yes
 250 fi
 251
 252 # Find the build and target subdir names.
 253 GCC_TOPLEV_SUBDIRS
 254 # Be sure to cover against remnants of an in-tree build.
 255 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 256   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 257 Use a pristine source tree when building in a separate tree])
 258 fi
 259
 260 # Skipdirs are removed silently.
 261 skipdirs=
 262 # Noconfigdirs are removed loudly.
 263 noconfigdirs=""
 264
 265 use_gnu_ld=
 266 # Make sure we don't let GNU ld be added if we didn't want it.
 267 if test x$with_gnu_ld = xno ; then
 268   use_gnu_ld=no
 269   noconfigdirs="$noconfigdirs ld gold"
 270 fi
 271
 272 use_gnu_as=
 273 # Make sure we don't let GNU as be added if we didn't want it.
 274 if test x$with_gnu_as = xno ; then
 275   use_gnu_as=no
 276   noconfigdirs="$noconfigdirs gas"
 277 fi
 278
 279 use_included_zlib=
 280 # Make sure we don't let ZLIB be added if we didn't want it.
 281 if test x$with_system_zlib = xyes ; then
 282   use_included_zlib=no
 283   noconfigdirs="$noconfigdirs zlib"
 284 fi
 285
 286 # some tools are so dependent upon X11 that if we're not building with X,
 287 # it's not even worth trying to configure, much less build, that tool.
 288
 289 case ${with_x} in
 290   yes | "") ;; # the default value for this tree is that X11 is available
 291   no)
 292     skipdirs="${skipdirs} tk itcl libgui"
 293     # We won't be able to build gdbtk without X.
 294     enable_gdbtk=no
 295     ;;
 296   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 297 esac
 298
 299 # Some tools are only suitable for building in a "native" situation.
 300 # Remove these if host!=target.
 301 native_only="autoconf automake libtool fileutils find gawk gettext gzip hello indent m4 rcs recode sed shellutils tar textutils uudecode wdiff target-groff guile perl time ash bash bzip2 prms gnuserv target-gperf"
 302
 303 # Similarly, some are only suitable for cross toolchains.
 304 # Remove these if host=target.
 305 cross_only="target-libgloss target-newlib target-opcodes"
 306
 307 case $is_cross_compiler in
 308   no) skipdirs="${skipdirs} ${cross_only}" ;;
 309   yes) skipdirs="${skipdirs} ${native_only}" ;;
 310 esac
 311
 312 # If both --with-headers and --with-libs are specified, default to
 313 # --without-newlib.
 314 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 315    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 316   if test x"${with_newlib}" = x ; then
 317     with_newlib=no
 318   fi
 319 fi
 320
 321 # Recognize --with-newlib/--without-newlib.
 322 case ${with_newlib} in
 323   no) skipdirs="${skipdirs} target-newlib" ;;
 324   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 325 esac
 326
 327 # Handle --enable-gold, --enable-ld.
 328 # --disable-gold [--enable-ld]
 329 #     Build only ld.  Default option.
 330 # --enable-gold [--enable-ld]
 331 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 332 #     as "ld.bfd" and "ld".
 333 # --enable-gold=default [--enable-ld]
 334 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 335 #     install ld as "ld.bfd".
 336 # --enable-gold[=default] --disable-ld
 337 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 338 # --enable-gold --enable-ld=default
 339 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 340 #     and ld.bfd).
 341 #     In other words, ld is default
 342 # --enable-gold=default --enable-ld=default
 343 #     Error.
 344
 345 default_ld=
 346 AC_ARG_ENABLE(gold,
 347 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 348                 [build gold @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_GOLD=$enableval,
 350 ENABLE_GOLD=no)
 351 case "${ENABLE_GOLD}" in
 352   yes|default)
 353     # Check for ELF target.
 354     is_elf=no
 355     case "${target}" in
 356       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 357       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 358       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-solaris2* | *-*-nto*)
 359         case "${target}" in
 360           *-*-linux*aout* | *-*-linux*oldld*)
 361             ;;
 362           *)
 363             is_elf=yes
 364             ;;
 365         esac
 366     esac
 367
 368     if test "$is_elf" = "yes"; then
 369       # Check for target supported by gold.
 370       case "${target}" in
 371         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 372           configdirs="$configdirs gold"
 373           if test x${ENABLE_GOLD} = xdefault; then
 374             default_ld=gold
 375           fi
 376           ENABLE_GOLD=yes
 377           ;;
 378       esac
 379     fi
 380     ;;
 381   no)
 382     ;;
 383   *)
 384     AC_MSG_ERROR([invalid --enable-gold argument])
 385     ;;
 386 esac
 387
 388 AC_ARG_ENABLE(ld,
 389 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 390                 [build ld @<:@ARG={default,yes,no}@:>@])],
 391 ENABLE_LD=$enableval,
 392 ENABLE_LD=yes)
 393
 394 case "${ENABLE_LD}" in
 395   default)
 396     if test x${default_ld} != x; then
 397       AC_MSG_ERROR([either gold or ld can be the default ld])
 398     fi
 399     ;;
 400   yes)
 401     ;;
 402   no)
 403     if test x${ENABLE_GOLD} != xyes; then
 404       AC_MSG_WARN([neither ld nor gold are enabled])
 405     fi
 406     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 407     ;;
 408   *)
 409     AC_MSG_ERROR([invalid --enable-ld argument])
 410     ;;
 411 esac
 412
 413 # Configure extra directories which are host specific
 414
 415 case "${host}" in
 416   *-cygwin*)
 417     configdirs="$configdirs libtermcap" ;;
 418 esac
 419
 420 # A target can indicate whether a language isn't supported for some reason.
 421 # Only spaces may be used in this macro; not newlines or tabs.
 422 unsupported_languages=
 423
 424 # Remove more programs from consideration, based on the host or
 425 # target this usually means that a port of the program doesn't
 426 # exist yet.
 427
 428 case "${host}" in
 429   hppa*64*-*-*)
 430     noconfigdirs="$noconfigdirs byacc"
 431     ;;
 432   i[[3456789]]86-*-msdosdjgpp*)
 433     noconfigdirs="$noconfigdirs tcl tk expect dejagnu send-pr uudecode guile itcl gnuserv libffi"
 434     ;;
 435   x86_64-*-mingw*)
 436     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 437     ;;
 438   i[[3456789]]86-*-mingw32*)
 439     # noconfigdirs="tcl tk expect dejagnu make texinfo bison patch flex byacc send-pr uudecode dejagnu diff guile perl itcl gnuserv"
 440     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 441     ;;
 442   *-*-cygwin*)
 443     noconfigdirs="$noconfigdirs autoconf automake send-pr rcs guile perl"
 444     ;;
 445   *-*-netbsd*)
 446     noconfigdirs="$noconfigdirs rcs"
 447     ;;
 448 esac
 449
 450
 451 AC_ARG_ENABLE(libquadmath,
 452 AS_HELP_STRING([--disable-libquadmath],
 453   [do not build libquadmath directory]),
 454 ENABLE_LIBQUADMATH=$enableval,
 455 ENABLE_LIBQUADMATH=yes)
 456 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 457   noconfigdirs="$noconfigdirs target-libquadmath"
 458 fi
 459
 460
 461 AC_ARG_ENABLE(libquadmath-support,
 462 AS_HELP_STRING([--disable-libquadmath-support],
 463   [disable libquadmath support for Fortran]),
 464 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 465 ENABLE_LIBQUADMATH_SUPPORT=yes)
 466 enable_libquadmath_support=
 467 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 468   enable_libquadmath_support=no
 469 fi
 470
 471
 472 AC_ARG_ENABLE(libada,
 473 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 474 ENABLE_LIBADA=$enableval,
 475 ENABLE_LIBADA=yes)
 476 if test "${ENABLE_LIBADA}" != "yes" ; then
 477   noconfigdirs="$noconfigdirs gnattools"
 478 fi
 479
 480 AC_ARG_ENABLE(libssp,
 481 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 482 ENABLE_LIBSSP=$enableval,
 483 ENABLE_LIBSSP=yes)
 484
 485 # Save it here so that, even in case of --enable-libgcj, if the Java
 486 # front-end isn't enabled, we still get libgcj disabled.
 487 libgcj_saved=$libgcj
 488 case $enable_libgcj in
 489 yes)
 490   # If we reset it here, it won't get added to noconfigdirs in the
 491   # target-specific build rules, so it will be forcibly enabled
 492   # (unless the Java language itself isn't enabled).
 493   libgcj=
 494   ;;
 495 no)
 496   # Make sure we get it printed in the list of not supported target libs.
 497   # Don't disable libffi, though, other languages use it.
 498   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 499   # Clear libgcj_saved so that even if java is enabled libffi won't be
 500   # built.
 501   libgcj_saved=
 502   ;;
 503 esac
 504
 505
 506 # Disable libmudflap on some systems.
 507 if test x$enable_libmudflap = x ; then
 508     case "${target}" in
 509     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 510         # Enable libmudflap by default in GNU and friends.
 511         ;;
 512     *-*-freebsd*)
 513         # Enable libmudflap by default in FreeBSD.
 514         ;;
 515     *)
 516         # Disable it by default everywhere else.
 517         noconfigdirs="$noconfigdirs target-libmudflap"
 518         ;;
 519     esac
 520 fi
 521
 522 # Disable libgomp on non POSIX hosted systems.
 523 if test x$enable_libgomp = x ; then
 524     # Enable libgomp by default on hosted POSIX systems.
 525     case "${target}" in
 526     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 527         ;;
 528     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
 529         ;;
 530     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 531         ;;
 532     *-*-darwin* | *-*-aix*)
 533         ;;
 534     *)
 535         noconfigdirs="$noconfigdirs target-libgomp"
 536         ;;
 537     esac
 538 fi
 539
 540 # Default libgloss CPU subdirectory.
 541 libgloss_dir="$target_cpu"
 542
 543 case "${target}" in
 544   *-*-chorusos)
 545     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 546     ;;
 547   powerpc-*-darwin*)
 548     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 549     noconfigdirs="$noconfigdirs sim target-rda"
 550     ;;
 551   i[[3456789]]86-*-darwin*)
 552     noconfigdirs="$noconfigdirs ld gprof"
 553     noconfigdirs="$noconfigdirs sim target-rda"
 554     ;;
 555   x86_64-*-darwin[[912]]*)
 556     noconfigdirs="$noconfigdirs ld gas gprof"
 557     noconfigdirs="$noconfigdirs sim target-rda"
 558     ;;
 559   *-*-darwin*)
 560     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 561     noconfigdirs="$noconfigdirs sim target-rda"
 562     noconfigdirs="$noconfigdirs ${libgcj}"
 563     ;;
 564   *-*-freebsd[[12]] | *-*-freebsd[[12]].* | *-*-freebsd*aout*)
 565     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 566     ;;
 567   *-*-freebsd*)
 568     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 569     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 570         && test -f /usr/local/include/gmp.h; then
 571       with_gmp=/usr/local
 572     fi
 573
 574     # Skip some stuff that's unsupported on some FreeBSD configurations.
 575     case "${target}" in
 576       i*86-*-*) ;;
 577       alpha*-*-*) ;;
 578       x86_64-*-*) ;;
 579       *)
 580         noconfigdirs="$noconfigdirs ${libgcj}"
 581         ;;
 582     esac
 583     ;;
 584   *-*-kaos*)
 585     # Remove unsupported stuff on all kaOS configurations.
 586     skipdirs="target-libiberty ${libgcj} target-libstdc++-v3 target-librx"
 587     skipdirs="$skipdirs target-libobjc target-examples target-groff target-gperf"
 588     skipdirs="$skipdirs zlib fastjar target-libjava target-boehm-gc target-zlib"
 589     noconfigdirs="$noconfigdirs target-libgloss"
 590     ;;
 591   *-*-netbsd*)
 592     # Skip some stuff on all NetBSD configurations.
 593     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss"
 594
 595     # Skip some stuff that's unsupported on some NetBSD configurations.
 596     case "${target}" in
 597       i*86-*-netbsdelf*) ;;
 598       arm*-*-netbsdelf*) ;;
 599       *)
 600         noconfigdirs="$noconfigdirs ${libgcj}"
 601         ;;
 602     esac
 603     ;;
 604   *-*-netware*)
 605     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss ${libgcj} target-libmudflap"
 606     ;;
 607   *-*-rtems*)
 608     skipdirs="${skipdirs} target-libiberty"
 609     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 610     ;;
 611     # The tpf target doesn't support gdb yet.
 612   *-*-tpf*)
 613     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty ${libgcj} target-libmudflap gdb tcl tk libgui itcl"
 614     ;;
 615   *-*-uclinux*)
 616     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
 617     ;;
 618   *-*-vxworks*)
 619     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty target-libstdc++-v3 ${libgcj}"
 620     ;;
 621   alpha*-dec-osf*)
 622     # ld works, but does not support shared libraries.
 623     # newlib is not 64 bit ready.  I'm not sure about fileutils.
 624     # gas doesn't generate exception information.
 625     noconfigdirs="$noconfigdirs gas ld fileutils target-newlib target-libgloss"
 626     ;;
 627   alpha*-*-*vms*)
 628     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 629     ;;
 630   alpha*-*-linux*)
 631     # newlib is not 64 bit ready
 632     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 633     ;;
 634   alpha*-*-*)
 635     # newlib is not 64 bit ready
 636     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 637     ;;
 638   am33_2.0-*-linux*)
 639     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 640     ;;
 641   sh-*-linux*)
 642     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 643     ;;
 644   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 645     noconfigdirs="$noconfigdirs ${libgcj}"
 646     noconfigdirs="$noconfigdirs target-examples"
 647     noconfigdirs="$noconfigdirs target-libiberty texinfo send-pr"
 648     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 649     noconfigdirs="$noconfigdirs expect dejagnu"
 650     # the C++ libraries don't build on top of CE's C libraries
 651     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 652     noconfigdirs="$noconfigdirs target-newlib"
 653     case "${host}" in
 654       *-*-cygwin*) ;; # keep gdb and readline
 655       *) noconfigdirs="$noconfigdirs gdb readline"
 656          ;;
 657     esac
 658     libgloss_dir=wince
 659     ;;
 660   arc-*-*)
 661     noconfigdirs="$noconfigdirs target-libgloss"
 662     ;;
 663   arm-*-coff)
 664     noconfigdirs="$noconfigdirs ${libgcj}"
 665     libgloss_dir=arm
 666     ;;
 667   arm-*-elf* | arm*-*-eabi* )
 668     noconfigdirs="$noconfigdirs target-libffi target-qthreads"
 669     libgloss_dir=arm
 670     ;;
 671   arm*-*-linux-gnueabi)
 672     noconfigdirs="$noconfigdirs target-qthreads"
 673     case ${with_newlib} in
 674       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 675     esac
 676     libgloss_dir=arm
 677     ;;
 678   arm*-*-symbianelf*)
 679     noconfigdirs="$noconfigdirs ${libgcj} target-libiberty"
 680     libgloss_dir=arm
 681     ;;
 682   arm-*-pe*)
 683     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 684     ;;
 685   arm-*-riscix*)
 686     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 687     ;;
 688   avr-*-*)
 689     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj} target-libssp"
 690     ;;
 691   bfin-*-*)
 692     unsupported_languages="$unsupported_languages java"
 693     noconfigdirs="$noconfigdirs target-boehm-gc"
 694     if test x${is_cross_compiler} != xno ; then
 695       target_configdirs="${target_configdirs} target-bsp target-cygmon"
 696     fi
 697     ;;
 698   c4x-*-* | tic4x-*-*)
 699     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 700     ;;
 701   c54x*-*-* | tic54x-*-*)
 702     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj} gcc gdb newlib"
 703     ;;
 704   cr16-*-*)
 705     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 706     ;;
 707   cris-*-* | crisv32-*-*)
 708     unsupported_languages="$unsupported_languages java"
 709     case "${target}" in
 710       *-*-aout)
 711         unsupported_languages="$unsupported_languages fortran"
 712         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 713       *-*-elf) # See PR46792 regarding target-libffi.
 714         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 715       *-*-linux*)
 716         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
 717       *)
 718         unsupported_languages="$unsupported_languages fortran"
 719         noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss";;
 720     esac
 721     libgloss_dir=cris
 722     ;;
 723   d10v-*-*)
 724     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 725     ;;
 726   d30v-*-*)
 727     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 728     ;;
 729   fr30-*-elf*)
 730     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 731     ;;
 732   frv-*-*)
 733     noconfigdirs="$noconfigdirs ${libgcj}"
 734     ;;
 735   moxie-*-*)
 736     noconfigdirs="$noconfigdirs ${libgcj}"
 737     noconfigdirs="$noconfigdirs gprof"
 738     ;;
 739   h8300*-*-*)
 740     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 741     ;;
 742   h8500-*-*)
 743     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 744     ;;
 745   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 746     ;;
 747   hppa*64*-*-linux*)
 748     # In this case, it's because the hppa64-linux target is for
 749     # the kernel only at this point and has no libc, and thus no
 750     # headers, crt*.o, etc., all of which are needed by these.
 751     noconfigdirs="$noconfigdirs target-zlib"
 752     ;;
 753   hppa*-*-linux*)
 754     ;;
 755   hppa*-*-*elf* | \
 756   hppa*-*-lites* | \
 757   hppa*-*-openbsd* | \
 758   hppa*64*-*-*)
 759     noconfigdirs="$noconfigdirs ${libgcj}"
 760     ;;
 761   hppa*-hp-hpux11*)
 762     noconfigdirs="$noconfigdirs ld shellutils"
 763     ;;
 764   hppa*-*-pro*)
 765     libgloss_dir=pa
 766     ;;
 767   hppa*-*-*)
 768     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 769     # build on HP-UX 10.20.
 770     noconfigdirs="$noconfigdirs ld shellutils ${libgcj}"
 771     ;;
 772   i960-*-*)
 773     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 774     ;;
 775   ia64*-*-elf*)
 776     # No gdb support yet.
 777     noconfigdirs="$noconfigdirs readline mmalloc libgui itcl gdb"
 778     ;;
 779   ia64*-**-hpux*)
 780     # No ld support yet.
 781     noconfigdirs="$noconfigdirs ${libgcj} libgui itcl ld"
 782     ;;
 783   ia64*-*-*vms*)
 784     # No gdb or ld support yet.
 785     noconfigdirs="$noconfigdirs ${libgcj} tix readline mmalloc libgui itcl gdb ld"
 786     ;;
 787   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
 788     noconfigdirs="$noconfigdirs ${libgcj}"
 789     libgloss_dir=i386
 790     ;;
 791   i[[3456789]]86-*-linux*)
 792     # The GCC port for glibc1 has no MD_FALLBACK_FRAME_STATE_FOR, so let's
 793     # not build java stuff by default.
 794     case "${target}" in
 795       *-*-*libc1*)
 796         noconfigdirs="$noconfigdirs ${libgcj}";;
 797     esac
 798
 799     # This section makes it possible to build newlib natively on linux.
 800     # If we are using a cross compiler then don't configure newlib.
 801     if test x${is_cross_compiler} != xno ; then
 802       noconfigdirs="$noconfigdirs target-newlib"
 803     fi
 804     noconfigdirs="$noconfigdirs target-libgloss"
 805     # If we are not using a cross compiler, do configure newlib.
 806     # Note however, that newlib will only be configured in this situation
 807     # if the --with-newlib option has been given, because otherwise
 808     # 'target-newlib' will appear in skipdirs.
 809     ;;
 810   i[[3456789]]86-w64-mingw*)
 811     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 812     ;;
 813   i[[3456789]]86-*-mingw*)
 814     target_configdirs="$target_configdirs target-winsup"
 815     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 816     ;;
 817   x86_64-*-mingw*)
 818     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 819     ;;
 820   *-*-cygwin*)
 821     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 822     noconfigdirs="$noconfigdirs target-gperf target-libgloss"
 823     # always build newlib if winsup directory is present.
 824     if test -d "$srcdir/winsup/cygwin"; then
 825       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 826     elif test -d "$srcdir/newlib"; then
 827       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 828     fi
 829     ;;
 830   i[[3456789]]86-*-interix* )
 831     ;;
 832   i[[3456789]]86-*-pe)
 833     noconfigdirs="$noconfigdirs target-libgloss"
 834     ;;
 835   i[[3456789]]86-*-sco3.2v5*)
 836     # The linker does not yet know about weak symbols in COFF,
 837     # and is not configured to handle mixed ELF and COFF.
 838     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 839     ;;
 840   i[[3456789]]86-*-sco*)
 841     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 842     ;;
 843   i[[3456789]]86-*-solaris2*)
 844     noconfigdirs="$noconfigdirs target-libgloss"
 845     ;;
 846   i[[3456789]]86-*-sysv4*)
 847     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 848     ;;
 849   i[[3456789]]86-*-beos*)
 850     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 851     ;;
 852   i[[3456789]]86-*-rdos*)
 853     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 854     ;;
 855   m32r-*-*)
 856     noconfigdirs="$noconfigdirs ${libgcj}"
 857     ;;
 858   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 859     noconfigdirs="$noconfigdirs target-libiberty"
 860     libgloss_dir=m68hc11
 861     ;;
 862   m68k-*-elf*)
 863     noconfigdirs="$noconfigdirs ${libgcj}"
 864     ;;
 865   m68k-*-coff*)
 866     noconfigdirs="$noconfigdirs ${libgcj}"
 867     ;;
 868   m68*-*-* | fido-*-*)
 869     libgloss_dir=m68k
 870     ;;
 871   mmix-*-*)
 872     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb libgloss"
 873     unsupported_languages="$unsupported_languages fortran java"
 874     ;;
 875   mn10200-*-*)
 876     noconfigdirs="$noconfigdirs ${libgcj}"
 877     ;;
 878   mn10300-*-*)
 879     noconfigdirs="$noconfigdirs ${libgcj}"
 880     ;;
 881   mt-*-*)
 882     noconfigdirs="$noconfigdirs sim"
 883     ;;
 884   picochip-*-*)
 885     noconfigdirs="$noconfigdirs target-libiberty"
 886     ;;
 887   powerpc-*-aix*)
 888     # copied from rs6000-*-* entry
 889     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 890     ;;
 891   powerpc*-*-winnt* | powerpc*-*-pe*)
 892     target_configdirs="$target_configdirs target-winsup"
 893     noconfigdirs="$noconfigdirs gdb tcl tk make expect target-libgloss itcl gnuserv ${libgcj}"
 894     # always build newlib.
 895     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 896     ;;
 897     # This is temporary until we can link against shared libraries
 898   powerpcle-*-solaris*)
 899     noconfigdirs="$noconfigdirs gdb sim make tcl tk expect itcl gnuserv ${libgcj}"
 900     libgloss_dir=rs6000
 901     ;;
 902   powerpc-*-beos*)
 903     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 904     ;;
 905   powerpc-*-eabi)
 906     noconfigdirs="$noconfigdirs ${libgcj}"
 907     libgloss_dir=rs6000
 908     ;;
 909   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
 910     libgloss_dir=rs6000
 911     ;;
 912   rs6000-*-lynxos*)
 913     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
 914     ;;
 915   rs6000-*-aix*)
 916     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 917     ;;
 918   rs6000-*-*)
 919     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 920     ;;
 921   m68k-apollo-*)
 922     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss ${libgcj}"
 923     ;;
 924   microblaze*)
 925     noconfigdirs="$noconfigdirs gprof target-libssp ${libgcj}"
 926     ;;
 927   mips*-sde-elf*)
 928     skipdirs="$skipdirs target-libiberty"
 929     noconfigdirs="$noconfigdirs ${libgcj}"
 930     if test x$with_newlib = xyes; then
 931       noconfigdirs="$noconfigdirs gprof"
 932     fi
 933     libgloss_dir=mips
 934     ;;
 935   mips*-*-irix5*)
 936     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 937     ;;
 938   mips*-*-irix6*)
 939     # Linking libjava exceeds command-line length limits on at least
 940     # IRIX 6.2, but not on IRIX 6.5.
 941     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 942     # <oldham@codesourcery.com>
 943     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 944     ;;
 945   mips*-*-bsd*)
 946     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 947     ;;
 948   mips*-*-linux*)
 949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 950     ;;
 951   mips*-*-*)
 952     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 953     libgloss_dir=mips
 954     ;;
 955   romp-*-*)
 956     noconfigdirs="$noconfigdirs bfd binutils ld gas opcodes target-libgloss ${libgcj}"
 957     ;;
 958   sh-*-* | sh64-*-*)
 959     case "${host}" in
 960       i[[3456789]]86-*-msdosdjgpp*) ;; # don't add gprof back in
 961       *) skipdirs=`echo " ${skipdirs} " | sed -e 's/ gprof / /'` ;;
 962     esac
 963     case "${target}" in
 964       sh*-*-elf)
 965          noconfigdirs="$noconfigdirs ${libgcj}" ;;
 966       *)
 967          noconfigdirs="$noconfigdirs target-libgloss ${libgcj}" ;;
 968     esac
 969     ;;
 970   sparclet-*-aout* | sparc86x-*-*)
 971     libgloss_dir=sparc
 972     ;;
 973   sparc-*-elf*)
 974     noconfigdirs="$noconfigdirs ${libgcj}"
 975     ;;
 976   sparc64-*-elf*)
 977     noconfigdirs="$noconfigdirs ${libgcj}"
 978     libgloss_dir=sparc
 979     ;;
 980   sparclite-*-*)
 981     noconfigdirs="$noconfigdirs ${libgcj}"
 982     libgloss_dir=sparc
 983     ;;
 984   sparc-*-sunos4*)
 985     noconfigdirs="$noconfigdirs ${libgcj}"
 986     if test x${is_cross_compiler} != xno ; then
 987            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 988     else
 989            use_gnu_ld=no
 990     fi
 991     ;;
 992   sparc-*-solaris2.[[0-6]] | sparc-*-solaris2.[[0-6]].*)
 993     noconfigdirs="$noconfigdirs ${libgcj}"
 994     ;;
 995   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
 996     ;;
 997   tic6x-*-*)
 998     noconfigdirs="$noconfigdirs gdb sim ${libgcj}"
 999     ;;
1000   v810-*-*)
1001     noconfigdirs="$noconfigdirs bfd binutils gas gcc gdb ld target-libstdc++-v3 opcodes target-libgloss ${libgcj}"
1002     ;;
1003   v850*-*-*)
1004     noconfigdirs="$noconfigdirs ${libgcj}"
1005     ;;
1006   vax-*-vms)
1007     noconfigdirs="$noconfigdirs bfd binutils gdb ld target-newlib opcodes target-libgloss ${libgcj}"
1008     ;;
1009   vax-*-*)
1010     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1011     ;;
1012   xtensa*-*-*)
1013     noconfigdirs="$noconfigdirs ${libgcj}"
1014     ;;
1015   ip2k-*-*)
1016     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
1017     ;;
1018   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1019     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1020     ;;
1021   *-*-lynxos*)
1022     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1023     ;;
1024   *-*-*)
1025     noconfigdirs="$noconfigdirs ${libgcj}"
1026     ;;
1027 esac
1028
1029 # If we aren't building newlib, then don't build libgloss, since libgloss
1030 # depends upon some newlib header files.
1031 case "${noconfigdirs}" in
1032   *target-libgloss*) ;;
1033   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1034 esac
1035
1036 # Work in distributions that contain no compiler tools, like Autoconf.
1037 host_makefile_frag=/dev/null
1038 if test -d ${srcdir}/config ; then
1039 case "${host}" in
1040   i[[3456789]]86-*-msdosdjgpp*)
1041     host_makefile_frag="config/mh-djgpp"
1042     ;;
1043   *-cygwin*)
1044     ACX_CHECK_CYGWIN_CAT_WORKS
1045     host_makefile_frag="config/mh-cygwin"
1046     ;;
1047   *-mingw*)
1048     host_makefile_frag="config/mh-mingw"
1049     ;;
1050   *-interix*)
1051     host_makefile_frag="config/mh-interix"
1052     ;;
1053   hppa*-hp-hpux10*)
1054     host_makefile_frag="config/mh-pa-hpux10"
1055     ;;
1056   hppa*-hp-hpux*)
1057     host_makefile_frag="config/mh-pa"
1058     ;;
1059   hppa*-*)
1060     host_makefile_frag="config/mh-pa"
1061     ;;
1062   *-*-darwin*)
1063     host_makefile_frag="config/mh-darwin"
1064     ;;
1065   powerpc-*-aix*)
1066     host_makefile_frag="config/mh-ppc-aix"
1067     ;;
1068   rs6000-*-aix*)
1069     host_makefile_frag="config/mh-ppc-aix"
1070     ;;
1071 esac
1072 fi
1073
1074 if test "${build}" != "${host}" ; then
1075   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1076   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1077   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1078   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1079   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1080   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1081   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1082   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1083   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1084   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1085   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1086   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1087   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1088 else
1089   AR_FOR_BUILD="\$(AR)"
1090   AS_FOR_BUILD="\$(AS)"
1091   CC_FOR_BUILD="\$(CC)"
1092   CXX_FOR_BUILD="\$(CXX)"
1093   GCJ_FOR_BUILD="\$(GCJ)"
1094   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1095   GOC_FOR_BUILD="\$(GOC)"
1096   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1097   LD_FOR_BUILD="\$(LD)"
1098   NM_FOR_BUILD="\$(NM)"
1099   RANLIB_FOR_BUILD="\$(RANLIB)"
1100   WINDRES_FOR_BUILD="\$(WINDRES)"
1101   WINDMC_FOR_BUILD="\$(WINDMC)"
1102 fi
1103
1104 AC_PROG_CC
1105 AC_PROG_CXX
1106
1107 # We must set the default linker to the linker used by gcc for the correct
1108 # operation of libtool.  If LD is not defined and we are using gcc, try to
1109 # set the LD default to the ld used by gcc.
1110 if test -z "$LD"; then
1111   if test "$GCC" = yes; then
1112     case $build in
1113     *-*-mingw*)
1114       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1115     *)
1116       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1117     esac
1118     case $gcc_prog_ld in
1119     # Accept absolute paths.
1120     [[\\/]* | [A-Za-z]:[\\/]*)]
1121       LD="$gcc_prog_ld" ;;
1122     esac
1123   fi
1124 fi
1125
1126 ACX_PROG_GNAT
1127 ACX_PROG_CMP_IGNORE_INITIAL
1128
1129 # See if we are building gcc with C++.
1130 AC_ARG_ENABLE(build-with-cxx,
1131 [AS_HELP_STRING([--enable-build-with-cxx],
1132                 [build with C++ compiler instead of C compiler])],
1133 ENABLE_BUILD_WITH_CXX=$enableval,
1134 ENABLE_BUILD_WITH_CXX=no)
1135
1136 # Used for setting $lt_cv_objdir
1137 _LT_CHECK_OBJDIR
1138
1139 # Check for GMP, MPFR and MPC
1140 gmplibs="-lmpc -lmpfr -lgmp"
1141 gmpinc=
1142 have_gmp=no
1143
1144 # Specify a location for mpc
1145 # check for this first so it ends up on the link line before mpfr.
1146 AC_ARG_WITH(mpc,
1147 [AS_HELP_STRING([--with-mpc=PATH],
1148                 [specify prefix directory for installed MPC package.
1149                  Equivalent to --with-mpc-include=PATH/include
1150                  plus --with-mpc-lib=PATH/lib])])
1151 AC_ARG_WITH(mpc-include,
1152 [AS_HELP_STRING([--with-mpc-include=PATH],
1153                 [specify directory for installed MPC include files])])
1154 AC_ARG_WITH(mpc-lib,
1155 [AS_HELP_STRING([--with-mpc-lib=PATH],
1156                 [specify directory for the installed MPC library])])
1157
1158 if test "x$with_mpc" != x; then
1159   gmplibs="-L$with_mpc/lib $gmplibs"
1160   gmpinc="-I$with_mpc/include $gmpinc"
1161 fi
1162 if test "x$with_mpc_include" != x; then
1163   gmpinc="-I$with_mpc_include $gmpinc"
1164 fi
1165 if test "x$with_mpc_lib" != x; then
1166   gmplibs="-L$with_mpc_lib $gmplibs"
1167 fi
1168 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1169   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1170   gmpinc='-I$$s/mpc/src '"$gmpinc"
1171   # Do not test the mpc version.  Assume that it is sufficient, since
1172   # it is in the source tree, and the library has not been built yet
1173   # but it would be included on the link line in the version check below
1174   # hence making the test fail.
1175   have_gmp=yes
1176 fi
1177
1178 # Specify a location for mpfr
1179 # check for this first so it ends up on the link line before gmp.
1180 AC_ARG_WITH(mpfr-dir,
1181 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1182 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1183 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1184
1185 AC_ARG_WITH(mpfr,
1186 [AS_HELP_STRING([--with-mpfr=PATH],
1187                 [specify prefix directory for installed MPFR package.
1188                  Equivalent to --with-mpfr-include=PATH/include
1189                  plus --with-mpfr-lib=PATH/lib])])
1190 AC_ARG_WITH(mpfr-include,
1191 [AS_HELP_STRING([--with-mpfr-include=PATH],
1192                 [specify directory for installed MPFR include files])])
1193 AC_ARG_WITH(mpfr-lib,
1194 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1195                 [specify directory for the installed MPFR library])])
1196
1197 if test "x$with_mpfr" != x; then
1198   gmplibs="-L$with_mpfr/lib $gmplibs"
1199   gmpinc="-I$with_mpfr/include $gmpinc"
1200 fi
1201 if test "x$with_mpfr_include" != x; then
1202   gmpinc="-I$with_mpfr_include $gmpinc"
1203 fi
1204 if test "x$with_mpfr_lib" != x; then
1205   gmplibs="-L$with_mpfr_lib $gmplibs"
1206 fi
1207 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1208   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1209   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1210   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1211   # Do not test the mpfr version.  Assume that it is sufficient, since
1212   # it is in the source tree, and the library has not been built yet
1213   # but it would be included on the link line in the version check below
1214   # hence making the test fail.
1215   have_gmp=yes
1216 fi
1217
1218 # Specify a location for gmp
1219 AC_ARG_WITH(gmp-dir,
1220 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1221 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1222 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1223
1224 AC_ARG_WITH(gmp,
1225 [AS_HELP_STRING([--with-gmp=PATH],
1226                 [specify prefix directory for the installed GMP package.
1227                  Equivalent to --with-gmp-include=PATH/include
1228                  plus --with-gmp-lib=PATH/lib])])
1229 AC_ARG_WITH(gmp-include,
1230 [AS_HELP_STRING([--with-gmp-include=PATH],
1231                 [specify directory for installed GMP include files])])
1232 AC_ARG_WITH(gmp-lib,
1233 [AS_HELP_STRING([--with-gmp-lib=PATH],
1234                 [specify directory for the installed GMP library])])
1235
1236
1237 if test "x$with_gmp" != x; then
1238   gmplibs="-L$with_gmp/lib $gmplibs"
1239   gmpinc="-I$with_gmp/include $gmpinc"
1240 fi
1241 if test "x$with_gmp_include" != x; then
1242   gmpinc="-I$with_gmp_include $gmpinc"
1243 fi
1244 if test "x$with_gmp_lib" != x; then
1245   gmplibs="-L$with_gmp_lib $gmplibs"
1246 fi
1247 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1248   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1249   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1250   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1251   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1252   # Do not test the gmp version.  Assume that it is sufficient, since
1253   # it is in the source tree, and the library has not been built yet
1254   # but it would be included on the link line in the version check below
1255   # hence making the test fail.
1256   have_gmp=yes
1257 fi
1258
1259 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1260   have_gmp=yes
1261   saved_CFLAGS="$CFLAGS"
1262   CFLAGS="$CFLAGS $gmpinc"
1263   # Check for the recommended and required versions of GMP.
1264   AC_MSG_CHECKING([for the correct version of gmp.h])
1265   AC_TRY_COMPILE([#include "gmp.h"],[
1266   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1267   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1268   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1269   choke me
1270   #endif
1271   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1272   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1273   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1274   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1275   choke me
1276   #endif
1277   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1278    [AC_MSG_RESULT([no]); have_gmp=no])
1279
1280   # If we have GMP, check the MPFR version.
1281   if test x"$have_gmp" = xyes; then
1282     # Check for the recommended and required versions of MPFR.
1283     AC_MSG_CHECKING([for the correct version of mpfr.h])
1284     AC_TRY_COMPILE([#include <gmp.h>
1285     #include <mpfr.h>],[
1286     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1287     choke me
1288     #endif
1289     ], [AC_TRY_COMPILE([#include <gmp.h>
1290     #include <mpfr.h>],[
1291     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1292     choke me
1293     #endif
1294     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1295      [AC_MSG_RESULT([no]); have_gmp=no])
1296   fi
1297
1298   # Check for the MPC header version.
1299   if test x"$have_gmp" = xyes ; then
1300     # Check for the recommended and required versions of MPC.
1301     AC_MSG_CHECKING([for the correct version of mpc.h])
1302     AC_TRY_COMPILE([#include <mpc.h>],[
1303     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1304     choke me
1305     #endif
1306     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1307     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1308     choke me
1309     #endif
1310     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1311      [AC_MSG_RESULT([no]); have_gmp=no])
1312   fi
1313
1314   # Now check the MPFR library.
1315   if test x"$have_gmp" = xyes; then
1316     saved_LIBS="$LIBS"
1317     LIBS="$LIBS $gmplibs"
1318     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1319     AC_TRY_LINK([#include <mpc.h>],[
1320     mpfr_t n;
1321     mpfr_t x;
1322     mpc_t c;
1323     int t;
1324     mpfr_init (n);
1325     mpfr_init (x);
1326     mpfr_atan2 (n, n, x, GMP_RNDN);
1327     mpfr_erfc (n, x, GMP_RNDN);
1328     mpfr_subnormalize (x, t, GMP_RNDN);
1329     mpfr_clear(n);
1330     mpfr_clear(x);
1331     mpc_init2 (c, 53);
1332     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1333     mpc_cosh (c, c, MPC_RNDNN);
1334     mpc_pow (c, c, c, MPC_RNDNN);
1335     mpc_acosh (c, c, MPC_RNDNN);
1336     mpc_clear (c);
1337     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1338     LIBS="$saved_LIBS"
1339   fi
1340
1341   CFLAGS="$saved_CFLAGS"
1342
1343 # The library versions listed in the error message below should match
1344 # the HARD-minimums enforced above.
1345   if test x$have_gmp != xyes; then
1346     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1347 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1348 their locations.  Source code for these libraries can be found at
1349 their respective hosting sites as well as at
1350 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1351 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1352 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1353 make sure that you have installed both the libraries and the header
1354 files.  They may be located in separate packages.])
1355   fi
1356 fi
1357
1358 # Flags needed for both GMP, MPFR and/or MPC.
1359 AC_SUBST(gmplibs)
1360 AC_SUBST(gmpinc)
1361 AC_SUBST(extra_mpfr_configure_flags)
1362 AC_SUBST(extra_mpc_gmp_configure_flags)
1363 AC_SUBST(extra_mpc_mpfr_configure_flags)
1364
1365 # Allow host libstdc++ to be specified for static linking with PPL.
1366 AC_ARG_WITH(host-libstdcxx,
1367 [AS_HELP_STRING([--with-host-libstdcxx=L],
1368                 [use linker arguments L to link with libstdc++
1369                  when linking with PPL])])
1370
1371 case $with_host_libstdcxx in
1372   no|yes)
1373     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1374     ;;
1375 esac
1376
1377 # Linker flags to use for stage1 or when not boostrapping.
1378 AC_ARG_WITH(stage1-ldflags,
1379 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1380 [if test "$withval" = "no" -o "$withval" = "yes"; then
1381    stage1_ldflags=
1382  else
1383    stage1_ldflags=$withval
1384  fi],
1385 [stage1_ldflags=])
1386 AC_SUBST(stage1_ldflags)
1387
1388 # Libraries to use for stage1 or when not bootstrapping.
1389 AC_ARG_WITH(stage1-libs,
1390 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1391 [if test "$withval" = "no" -o "$withval" = "yes"; then
1392    stage1_libs=
1393  else
1394    stage1_libs=$withval
1395  fi],
1396 [stage1_libs=$with_host_libstdcxx])
1397 AC_SUBST(stage1_libs)
1398
1399 # Libraries to use for stage2 and later builds.  This defaults to the
1400 # argument passed to --with-host-libstdcxx.
1401 AC_ARG_WITH(boot-libs,
1402 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1403 [if test "$withval" = "no" -o "$withval" = "yes"; then
1404    poststage1_libs=
1405  else
1406    poststage1_libs=$withval
1407  fi],
1408 [poststage1_libs=$with_host_libstdcxx])
1409 AC_SUBST(poststage1_libs)
1410
1411 # Linker flags to use for stage2 and later builds.
1412 AC_ARG_WITH(boot-ldflags,
1413 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1414                 [linker flags for stage2 and later])],
1415 [if test "$withval" = "no" -o "$withval" = "yes"; then
1416    poststage1_ldflags=
1417  else
1418    poststage1_ldflags=$withval
1419  fi],
1420 [poststage1_ldflags=
1421  # In stages 2 and 3, default to linking libstdc++ and libgcc
1422  # statically.  But if the user explicitly specified the libraries to
1423  # use, trust that they are doing what they want.
1424  if test "$poststage1_libs" = ""; then
1425    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1426  fi])
1427 AC_SUBST(poststage1_ldflags)
1428
1429 # Check for PPL
1430 ppllibs=
1431 pplinc=
1432 pwllib=
1433
1434 AC_ARG_WITH(ppl,
1435 [AS_HELP_STRING([--with-ppl=PATH],
1436                 [specify prefix directory for the installed PPL package.
1437                  Equivalent to --with-ppl-include=PATH/include
1438                  plus --with-ppl-lib=PATH/lib])])
1439 AC_ARG_WITH(ppl-include,
1440 [AS_HELP_STRING([--with-ppl-include=PATH],
1441                 [specify directory for installed PPL include files])])
1442 AC_ARG_WITH(ppl-lib,
1443 [AS_HELP_STRING([--with-ppl-lib=PATH],
1444                 [specify directory for the installed PPL library])])
1445
1446 AC_ARG_ENABLE(ppl-version-check,
1447 [AS_HELP_STRING([--disable-ppl-version-check],
1448                 [disable check for PPL version])])
1449
1450 case $with_ppl in
1451   yes | no | "")
1452     ;;
1453   *)
1454     ppllibs="-L$with_ppl/lib"
1455     pplinc="-I$with_ppl/include $pplinc"
1456     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1457       with_ppl=yes
1458     else
1459       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1460     fi
1461     ;;
1462 esac
1463
1464 if test x"$with_ppl_include" != x; then
1465   pplinc="-I$with_ppl_include $pplinc"
1466   with_ppl=yes
1467 fi
1468
1469 if test "x$with_ppl_lib" != x; then
1470   ppllibs="-L$with_ppl_lib"
1471   with_ppl=yes
1472 fi
1473
1474 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1475   if test x"$enable_watchdog" = xyes; then
1476     pwllib="-lpwl"
1477   fi
1478   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1479   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1480   enable_ppl_version_check=no
1481   with_ppl=yes
1482 fi
1483
1484 if test "x$with_ppl" != xno; then
1485   if test "x$pwllib" = x; then
1486     saved_LIBS="$LIBS"
1487     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1488     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1489     LIBS="$saved_LIBS"
1490   fi
1491
1492   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1493
1494   if test "$enable_ppl_version_check" != no; then
1495     saved_CFLAGS="$CFLAGS"
1496     CFLAGS="$CFLAGS $pplinc $gmpinc"
1497     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1498     AC_TRY_COMPILE([#include "ppl_c.h"],[
1499     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1500     choke me
1501     #endif
1502     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1503     CFLAGS="$saved_CFLAGS"
1504   fi
1505 fi
1506
1507 # Flags needed for PPL
1508 AC_SUBST(ppllibs)
1509 AC_SUBST(pplinc)
1510
1511
1512 # Check for CLOOG
1513
1514 dnl Provide configure switches and initialize clooginc & clooglibs
1515 dnl with user input.
1516 CLOOG_INIT_FLAGS
1517 if test "x$with_ppl" = "xno"; then
1518   dnl Only execute fail-action, if CLooG has been requested.
1519   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1520   if test "${graphite_requested}" = yes; then
1521     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1522   fi
1523   with_cloog=no
1524 fi
1525 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1526   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1527   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1528   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1529 fi
1530 if test "x$with_cloog" != "xno"; then
1531   dnl The minimal version of CLooG required for Graphite.
1532   dnl
1533   dnl If we use CLooG-Legacy, the provided version information is
1534   dnl ignored.
1535   CLOOG_CHECK_VERSION(0,16,1)
1536
1537   dnl Only execute fail-action, if CLooG has been requested.
1538   CLOOG_IF_FAILED([
1539     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1540 fi
1541
1542 # Check for LTO support.
1543 AC_ARG_ENABLE(lto,
1544 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1545 enable_lto=$enableval,
1546 enable_lto=yes; default_enable_lto=yes)
1547
1548 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1549   build_lto_plugin=yes
1550 ],[if test x"$default_enable_lto" = x"yes" ; then
1551     case $target in
1552       *-apple-darwin9 | *-cygwin* | *-mingw*) ;;
1553       # On other non-ELF platforms, LTO has yet to be validated.
1554       *) enable_lto=no ;;
1555     esac
1556   else
1557   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1558   # It would also be nice to check the binutils support, but we don't
1559   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1560   # warn during gcc/ subconfigure; unless you're bootstrapping with
1561   # -flto it won't be needed until after installation anyway.
1562     case $target in
1563       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1564       *) if test x"$enable_lto" = x"yes"; then
1565         AC_MSG_ERROR([LTO support is not enabled for this target.])
1566         fi
1567       ;;
1568     esac
1569   fi
1570   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1571   # Build it unless LTO was explicitly disabled.
1572   case $target in
1573     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1574     *) ;;
1575   esac
1576 ])
1577
1578
1579 # By default, C is the only stage 1 language.
1580 stage1_languages=,c,
1581
1582 # Target libraries that we bootstrap.
1583 bootstrap_target_libs=,target-libgcc,
1584
1585 # Figure out what language subdirectories are present.
1586 # Look if the user specified --enable-languages="..."; if not, use
1587 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1588 # go away some day.
1589 # NB:  embedded tabs in this IF block -- do not untabify
1590 if test -d ${srcdir}/gcc; then
1591   if test x"${enable_languages+set}" != xset; then
1592     if test x"${LANGUAGES+set}" = xset; then
1593       enable_languages="${LANGUAGES}"
1594         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1595     else
1596       enable_languages=all
1597     fi
1598   else
1599     if test x"${enable_languages}" = x ||
1600        test x"${enable_languages}" = xyes;
1601        then
1602       echo configure.in: --enable-languages needs at least one language argument 1>&2
1603       exit 1
1604     fi
1605   fi
1606   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1607
1608   # 'f95' is the old name for the 'fortran' language. We issue a warning
1609   # and make the substitution.
1610   case ,${enable_languages}, in
1611     *,f95,*)
1612       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1613       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1614       ;;
1615   esac
1616
1617   # First scan to see if an enabled language requires some other language.
1618   # We assume that a given config-lang.in will list all the language
1619   # front ends it requires, even if some are required indirectly.
1620   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1621     case ${lang_frag} in
1622       ..) ;;
1623       # The odd quoting in the next line works around
1624       # an apparent bug in bash 1.12 on linux.
1625       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1626       *)
1627         # From the config-lang.in, get $language, $lang_requires, and
1628         # $lang_requires_boot_languages.
1629         language=
1630         lang_requires=
1631         lang_requires_boot_languages=
1632         . ${lang_frag}
1633         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1634           case ,${enable_languages}, in
1635             *,$other,*) ;;
1636             *,all,*) ;;
1637             *,$language,*)
1638               echo " \`$other' language required by \`$language'; enabling" 1>&2
1639               enable_languages="${enable_languages},${other}"
1640               ;;
1641           esac
1642         done
1643         for other in ${lang_requires_boot_languages} ; do
1644           if test "$other" != "c"; then
1645             case ,${enable_stage1_languages}, in
1646               *,$other,*) ;;
1647               *,all,*) ;;
1648               *)
1649                 case ,${enable_languages}, in
1650                   *,$language,*)
1651                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1652                     enable_stage1_languages="$enable_stage1_languages,${other}"
1653                     ;;
1654                 esac
1655                 ;;
1656             esac
1657           fi
1658         done
1659         ;;
1660     esac
1661   done
1662
1663   new_enable_languages=,c,
1664
1665   # If LTO is enabled, add the LTO front end.
1666   extra_host_libiberty_configure_flags=
1667   if test "$enable_lto" = "yes" ; then
1668     case ,${enable_languages}, in
1669       *,lto,*) ;;
1670       *) enable_languages="${enable_languages},lto" ;;
1671     esac
1672     if test "${build_lto_plugin}" = "yes" ; then
1673       configdirs="$configdirs lto-plugin"
1674       extra_host_libiberty_configure_flags=--enable-shared
1675     fi
1676   fi
1677   AC_SUBST(extra_host_libiberty_configure_flags)
1678
1679   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1680   potential_languages=,c,
1681
1682   enabled_target_libs=
1683   disabled_target_libs=
1684
1685   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1686     case ${lang_frag} in
1687       ..) ;;
1688       # The odd quoting in the next line works around
1689       # an apparent bug in bash 1.12 on linux.
1690       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1691       *)
1692         # From the config-lang.in, get $language, $target_libs,
1693         # $lang_dirs, $boot_language, and $build_by_default
1694         language=
1695         target_libs=
1696         lang_dirs=
1697         subdir_requires=
1698         boot_language=no
1699         build_by_default=yes
1700         . ${lang_frag}
1701         if test x${language} = x; then
1702           echo "${lang_frag} doesn't set \$language." 1>&2
1703           exit 1
1704         fi
1705
1706         if test "$language" = "c++" \
1707            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1708           boot_language=yes
1709         fi
1710
1711         case ,${enable_languages}, in
1712           *,${language},*)
1713             # Language was explicitly selected; include it.
1714             add_this_lang=yes
1715             ;;
1716           *,all,*)
1717             # 'all' was selected, select it if it is a default language
1718             add_this_lang=${build_by_default}
1719             ;;
1720           *)
1721             add_this_lang=no
1722             ;;
1723         esac
1724
1725         # Disable languages that need other directories if these aren't available.
1726         for i in $subdir_requires; do
1727           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1728           case ,${enable_languages}, in
1729             *,${language},*)
1730               # Specifically requested language; tell them.
1731               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1732               ;;
1733             *)
1734               # Silently disable.
1735               add_this_lang=unsupported
1736               ;;
1737           esac
1738         done
1739
1740         # Disable Ada if no preexisting GNAT is available.
1741         case ,${enable_languages},:${language}:${have_gnat} in
1742           *,${language},*:ada:no)
1743             # Specifically requested language; tell them.
1744             AC_MSG_ERROR([GNAT is required to build $language])
1745             ;;
1746           *:ada:no)
1747             # Silently disable.
1748             add_this_lang=unsupported
1749             ;;
1750         esac
1751
1752         # Disable a language that is unsupported by the target.
1753         case " $unsupported_languages " in
1754           *" $language "*)
1755             add_this_lang=unsupported
1756             ;;
1757         esac
1758
1759         case $add_this_lang in
1760           unsupported)
1761             # Remove language-dependent dirs.
1762             disabled_target_libs="$disabled_target_libs $target_libs"
1763             noconfigdirs="$noconfigdirs $lang_dirs"
1764             ;;
1765           no)
1766             # Remove language-dependent dirs; still show language as supported.
1767             disabled_target_libs="$disabled_target_libs $target_libs"
1768             noconfigdirs="$noconfigdirs $lang_dirs"
1769             potential_languages="${potential_languages}${language},"
1770             ;;
1771           yes)
1772             new_enable_languages="${new_enable_languages}${language},"
1773             potential_languages="${potential_languages}${language},"
1774             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1775             enabled_target_libs="$enabled_target_libs $target_libs"
1776             case "${boot_language}:,$enable_stage1_languages," in
1777               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1778                 # Add to (comma-separated) list of stage 1 languages.
1779                 case ",$stage1_languages," in
1780                   *,$language,* | ,yes, | ,all,) ;;
1781                   *) stage1_languages="${stage1_languages}${language}," ;;
1782                 esac
1783                 # We need to bootstrap any supporting libraries.
1784                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1785                 ;;
1786             esac
1787             ;;
1788         esac
1789         ;;
1790     esac
1791   done
1792
1793   # Add target libraries which are only needed for disabled languages
1794   # to noconfigdirs.
1795   if test -n "$disabled_target_libs"; then
1796     for dir in $disabled_target_libs; do
1797       case " $enabled_target_libs " in
1798       *" ${dir} "*) ;;
1799       *) noconfigdirs="$noconfigdirs $dir" ;;
1800       esac
1801     done
1802   fi
1803
1804   AC_ARG_ENABLE(stage1-languages,
1805   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1806                   [choose additional languages to build during
1807                   stage1.  Mostly useful for compiler development])],
1808   [case ,${enable_stage1_languages}, in
1809     ,no,|,,)
1810       # Set it to something that will have no effect in the loop below
1811       enable_stage1_languages=c ;;
1812     ,yes,)
1813       enable_stage1_languages=`echo $new_enable_languages | \
1814         sed -e "s/^,//" -e "s/,$//" ` ;;
1815     *,all,*)
1816       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1817         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1818   esac
1819
1820   # Add "good" languages from enable_stage1_languages to stage1_languages,
1821   # while "bad" languages go in missing_languages.  Leave no duplicates.
1822   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1823     case $potential_languages in
1824       *,$i,*)
1825         case $stage1_languages in
1826           *,$i,*) ;;
1827           *) stage1_languages="$stage1_languages$i," ;;
1828         esac ;;
1829       *)
1830         case $missing_languages in
1831           *,$i,*) ;;
1832           *) missing_languages="$missing_languages$i," ;;
1833         esac ;;
1834      esac
1835   done])
1836
1837   # Remove leading/trailing commas that were added for simplicity
1838   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1839   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1840   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1841   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1842
1843   if test "x$missing_languages" != x; then
1844     AC_MSG_ERROR([
1845 The following requested languages could not be built: ${missing_languages}
1846 Supported languages are: ${potential_languages}])
1847   fi
1848   if test "x$new_enable_languages" != "x$enable_languages"; then
1849     echo The following languages will be built: ${new_enable_languages}
1850     enable_languages="$new_enable_languages"
1851   fi
1852
1853   AC_SUBST(stage1_languages)
1854   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1855 fi
1856
1857 # Handle --disable-<component> generically.
1858 for dir in $configdirs $build_configdirs $target_configdirs ; do
1859   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1860   varname=`echo $dirname | sed -e s/+/_/g`
1861   if eval test x\${enable_${varname}} "=" xno ; then
1862     noconfigdirs="$noconfigdirs $dir"
1863   fi
1864 done
1865
1866 # Check for Boehm's garbage collector
1867 AC_ARG_ENABLE(objc-gc,
1868 [AS_HELP_STRING([--enable-objc-gc],
1869                 [enable use of Boehm's garbage collector with the
1870                  GNU Objective-C runtime])],
1871 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1872   *,objc,*:*:yes:*target-boehm-gc*)
1873     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1874     ;;
1875 esac])
1876
1877 # Make sure we only build Boehm's garbage collector if required.
1878 case ,${enable_languages},:${enable_objc_gc} in
1879   *,objc,*:yes)
1880     # Keep target-boehm-gc if requested for Objective-C.
1881     ;;
1882   *)
1883     # Otherwise remove target-boehm-gc depending on target-libjava.
1884     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1885       noconfigdirs="$noconfigdirs target-boehm-gc"
1886     fi
1887     ;;
1888 esac
1889
1890 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1891 # $build_configdirs and $target_configdirs.
1892 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1893
1894 notsupp=""
1895 for dir in . $skipdirs $noconfigdirs ; do
1896   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1897   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1898     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1899     if test -r $srcdir/$dirname/configure ; then
1900       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1901         true
1902       else
1903         notsupp="$notsupp $dir"
1904       fi
1905     fi
1906   fi
1907   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1908     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1909     if test -r $srcdir/$dirname/configure ; then
1910       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1911         true
1912       else
1913         notsupp="$notsupp $dir"
1914       fi
1915     fi
1916   fi
1917   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1918     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1919     if test -r $srcdir/$dirname/configure ; then
1920       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1921         true
1922       else
1923         notsupp="$notsupp $dir"
1924       fi
1925     fi
1926   fi
1927 done
1928
1929 # Sometimes the tools are distributed with libiberty but with no other
1930 # libraries.  In that case, we don't want to build target-libiberty.
1931 # Don't let libgcc imply libiberty either.
1932 if test -n "${target_configdirs}" ; then
1933   libgcc=
1934   others=
1935   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1936     if test "$i" = "libgcc"; then
1937       libgcc=target-libgcc
1938     elif test "$i" != "libiberty" ; then
1939       if test -r $srcdir/$i/configure ; then
1940         others=yes;
1941         break;
1942       fi
1943     fi
1944   done
1945   if test -z "${others}" ; then
1946     target_configdirs=$libgcc
1947   fi
1948 fi
1949
1950 # Quietly strip out all directories which aren't configurable in this tree.
1951 # This relies on all configurable subdirectories being autoconfiscated, which
1952 # is now the case.
1953 build_configdirs_all="$build_configdirs"
1954 build_configdirs=
1955 for i in ${build_configdirs_all} ; do
1956   j=`echo $i | sed -e s/build-//g`
1957   if test -f ${srcdir}/$j/configure ; then
1958     build_configdirs="${build_configdirs} $i"
1959   fi
1960 done
1961
1962 configdirs_all="$configdirs"
1963 configdirs=
1964 for i in ${configdirs_all} ; do
1965   if test -f ${srcdir}/$i/configure ; then
1966     configdirs="${configdirs} $i"
1967   fi
1968 done
1969
1970 target_configdirs_all="$target_configdirs"
1971 target_configdirs=
1972 for i in ${target_configdirs_all} ; do
1973   j=`echo $i | sed -e s/target-//g`
1974   if test -f ${srcdir}/$j/configure ; then
1975     target_configdirs="${target_configdirs} $i"
1976   fi
1977 done
1978
1979 # Produce a warning message for the subdirs we can't configure.
1980 # This isn't especially interesting in the Cygnus tree, but in the individual
1981 # FSF releases, it's important to let people know when their machine isn't
1982 # supported by the one or two programs in a package.
1983
1984 if test -n "${notsupp}" && test -z "${norecursion}" ; then
1985   # If $appdirs is non-empty, at least one of those directories must still
1986   # be configured, or we error out.  (E.g., if the gas release supports a
1987   # specified target in some subdirs but not the gas subdir, we shouldn't
1988   # pretend that all is well.)
1989   if test -n "$appdirs" ; then
1990     for dir in $appdirs ; do
1991       if test -r $dir/Makefile.in ; then
1992         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1993           appdirs=""
1994           break
1995         fi
1996         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
1997           appdirs=""
1998           break
1999         fi
2000       fi
2001     done
2002     if test -n "$appdirs" ; then
2003       echo "*** This configuration is not supported by this package." 1>&2
2004       exit 1
2005     fi
2006   fi
2007   # Okay, some application will build, or we don't care to check.  Still
2008   # notify of subdirs not getting built.
2009   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2010   echo "    ${notsupp}" 1>&2
2011   echo "    (Any other directories should still work fine.)" 1>&2
2012 fi
2013
2014 case "$host" in
2015   *msdosdjgpp*)
2016     enable_gdbtk=no ;;
2017 esac
2018
2019 # To find our prefix, in gcc_cv_tool_prefix.
2020 ACX_TOOL_DIRS
2021
2022 copy_dirs=
2023
2024 AC_ARG_WITH([build-sysroot],
2025   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2026                   [use sysroot as the system root during the build])],
2027   [if test x"$withval" != x ; then
2028      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2029    fi],
2030   [SYSROOT_CFLAGS_FOR_TARGET=])
2031 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2032
2033 AC_ARG_WITH([debug-prefix-map],
2034   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2035                   [map A to B, C to D ... in debug information])],
2036   [if test x"$withval" != x; then
2037      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2038      for debug_map in $withval; do
2039        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2040      done
2041    fi],
2042   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2043 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2044
2045 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2046 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2047 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2048 # We want to ensure that TARGET libraries (which we know are built with
2049 # gcc) are built with "-O2 -g", so include those options when setting
2050 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2051 if test "x$CFLAGS_FOR_TARGET" = x; then
2052   CFLAGS_FOR_TARGET=$CFLAGS
2053   case " $CFLAGS " in
2054     *" -O2 "*) ;;
2055     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2056   esac
2057   case " $CFLAGS " in
2058     *" -g "* | *" -g3 "*) ;;
2059     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2060   esac
2061 fi
2062 AC_SUBST(CFLAGS_FOR_TARGET)
2063
2064 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2065   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2066   case " $CXXFLAGS " in
2067     *" -O2 "*) ;;
2068     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2069   esac
2070   case " $CXXFLAGS " in
2071     *" -g "* | *" -g3 "*) ;;
2072     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2073   esac
2074 fi
2075 AC_SUBST(CXXFLAGS_FOR_TARGET)
2076
2077 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2078 # the named directory are copied to $(tooldir)/sys-include.
2079 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2080   if test x${is_cross_compiler} = xno ; then
2081     echo 1>&2 '***' --with-headers is only supported when cross compiling
2082     exit 1
2083   fi
2084   if test x"${with_headers}" != xyes ; then
2085     x=${gcc_cv_tool_prefix}
2086     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2087   fi
2088 fi
2089
2090 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2091 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2092 # are permitted.
2093 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2094   if test x${is_cross_compiler} = xno ; then
2095     echo 1>&2 '***' --with-libs is only supported when cross compiling
2096     exit 1
2097   fi
2098   if test x"${with_libs}" != xyes ; then
2099     # Copy the libraries in reverse order, so that files in the first named
2100     # library override files in subsequent libraries.
2101     x=${gcc_cv_tool_prefix}
2102     for l in ${with_libs}; do
2103       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2104     done
2105   fi
2106 fi
2107
2108 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2109 #
2110 # This is done by determining whether or not the appropriate directory
2111 # is available, and by checking whether or not specific configurations
2112 # have requested that this magic not happen.
2113 #
2114 # The command line options always override the explicit settings in
2115 # configure.in, and the settings in configure.in override this magic.
2116 #
2117 # If the default for a toolchain is to use GNU as and ld, and you don't
2118 # want to do that, then you should use the --without-gnu-as and
2119 # --without-gnu-ld options for the configure script.  Similarly, if
2120 # the default is to use the included zlib and you don't want to do that,
2121 # you should use the --with-system-zlib option for the configure script.
2122
2123 if test x${use_gnu_as} = x &&
2124    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2125   with_gnu_as=yes
2126   extra_host_args="$extra_host_args --with-gnu-as"
2127 fi
2128
2129 if test x${use_gnu_ld} = x &&
2130    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2131   with_gnu_ld=yes
2132   extra_host_args="$extra_host_args --with-gnu-ld"
2133 fi
2134
2135 if test x${use_included_zlib} = x &&
2136    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2137   :
2138 else
2139   with_system_zlib=yes
2140   extra_host_args="$extra_host_args --with-system-zlib"
2141 fi
2142
2143 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2144 # can detect this case.
2145
2146 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2147   with_newlib=yes
2148   extra_host_args="$extra_host_args --with-newlib"
2149 fi
2150
2151 # Handle ${copy_dirs}
2152 set fnord ${copy_dirs}
2153 shift
2154 while test $# != 0 ; do
2155   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2156     :
2157   else
2158     echo Copying $1 to $2
2159
2160     # Use the install script to create the directory and all required
2161     # parent directories.
2162     if test -d $2 ; then
2163       :
2164     else
2165       echo >config.temp
2166       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2167     fi
2168
2169     # Copy the directory, assuming we have tar.
2170     # FIXME: Should we use B in the second tar?  Not all systems support it.
2171     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2172
2173     # It is the responsibility of the user to correctly adjust all
2174     # symlinks.  If somebody can figure out how to handle them correctly
2175     # here, feel free to add the code.
2176
2177     echo $1 > $2/COPIED
2178   fi
2179   shift; shift
2180 done
2181
2182 # Determine a target-dependent exec_prefix that the installed
2183 # gcc will search in.  Keep this list sorted by triplet, with
2184 # the *-*-osname triplets last.
2185 md_exec_prefix=
2186 case "${target}" in
2187   alpha*-*-*vms*)
2188     md_exec_prefix=/gnu/lib/gcc-lib
2189     ;;
2190   i[[34567]]86-pc-msdosdjgpp*)
2191     md_exec_prefix=/dev/env/DJDIR/bin
2192     ;;
2193   i[[34567]]86-*-sco3.2v5*)
2194     if test $with_gnu_as = yes; then
2195       md_exec_prefix=/usr/gnu/bin
2196     else
2197       md_exec_prefix=/usr/ccs/bin/elf
2198     fi
2199     ;;
2200
2201   mn10300-*-* | \
2202   powerpc-*-chorusos* | \
2203   powerpc*-*-eabi* | \
2204   powerpc*-*-sysv* | \
2205   powerpc*-*-kaos* | \
2206   s390x-ibm-tpf*)
2207     md_exec_prefix=/usr/ccs/bin
2208     ;;
2209   sparc64-*-elf*)
2210     ;;
2211   v850*-*-*)
2212     md_exec_prefix=/usr/ccs/bin
2213     ;;
2214   xtensa*-*-elf*)
2215     ;;
2216
2217   *-*-beos* | \
2218   *-*-elf* | \
2219   *-*-hpux* | \
2220   *-*-netware* | \
2221   *-*-nto-qnx* | \
2222   *-*-rtems* | \
2223   *-*-solaris2* | \
2224   *-*-sysv[[45]]* | \
2225   *-*-vxworks* | \
2226   *-wrs-windiss)
2227     md_exec_prefix=/usr/ccs/bin
2228     ;;
2229 esac
2230
2231 extra_arflags_for_target=
2232 extra_nmflags_for_target=
2233 extra_ranlibflags_for_target=
2234 target_makefile_frag=/dev/null
2235 case "${target}" in
2236   spu-*-*)
2237     target_makefile_frag="config/mt-spu"
2238     ;;
2239   mips*-sde-elf*)
2240     target_makefile_frag="config/mt-sde"
2241     ;;
2242   mipsisa*-*-elfoabi*)
2243     target_makefile_frag="config/mt-mips-elfoabi"
2244     ;;
2245   mips*-*-*linux* | mips*-*-gnu*)
2246     target_makefile_frag="config/mt-mips-gnu"
2247     ;;
2248   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2249     target_makefile_frag="config/mt-gnu"
2250     ;;
2251   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2252     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2253     # commands to handle both 32-bit and 64-bit objects.  These flags are
2254     # harmless if we're using GNU nm or ar.
2255     extra_arflags_for_target=" -X32_64"
2256     extra_nmflags_for_target=" -B -X32_64"
2257     ;;
2258   *-*-darwin[[3-9]]*)
2259     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2260     extra_ranlibflags_for_target=" -c"
2261     ;;
2262 esac
2263
2264 alphaieee_frag=/dev/null
2265 case $target in
2266   alpha*-*-*)
2267     # This just makes sure to use the -mieee option to build target libs.
2268     # This should probably be set individually by each library.
2269     alphaieee_frag="config/mt-alphaieee"
2270     ;;
2271 esac
2272
2273 # If --enable-target-optspace always use -Os instead of -O2 to build
2274 # the target libraries, similarly if it is not specified, use -Os
2275 # on selected platforms.
2276 ospace_frag=/dev/null
2277 case "${enable_target_optspace}:${target}" in
2278   yes:*)
2279     ospace_frag="config/mt-ospace"
2280     ;;
2281   :d30v-*)
2282     ospace_frag="config/mt-d30v"
2283     ;;
2284   :m32r-* | :d10v-* | :fr30-*)
2285     ospace_frag="config/mt-ospace"
2286     ;;
2287   no:* | :*)
2288     ;;
2289   *)
2290     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2291     ;;
2292 esac
2293
2294 # Default to using --with-stabs for certain targets.
2295 if test x${with_stabs} = x ; then
2296   case "${target}" in
2297   mips*-*-irix[[56]]*)
2298     ;;
2299   mips*-*-* | alpha*-*-osf*)
2300     with_stabs=yes;
2301     extra_host_args="${extra_host_args} --with-stabs"
2302     ;;
2303   esac
2304 fi
2305
2306 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2307 # them automatically.
2308 case "${host}" in
2309   hppa*64*-*-hpux11*)
2310     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2311     ;;
2312 esac
2313
2314 # Some systems (e.g., one of the i386-aix systems the gas testers are
2315 # using) don't handle "\$" correctly, so don't use it here.
2316 tooldir='${exec_prefix}'/${target_noncanonical}
2317 build_tooldir=${tooldir}
2318
2319 # Create a .gdbinit file which runs the one in srcdir
2320 # and tells GDB to look there for source files.
2321
2322 if test -r ${srcdir}/.gdbinit ; then
2323   case ${srcdir} in
2324     .) ;;
2325     *) cat > ./.gdbinit <<EOF
2326 # ${NO_EDIT}
2327 dir ${srcdir}
2328 dir .
2329 source ${srcdir}/.gdbinit
2330 EOF
2331     ;;
2332   esac
2333 fi
2334
2335 # Make sure that the compiler is able to generate an executable.  If it
2336 # can't, we are probably in trouble.  We don't care whether we can run the
2337 # executable--we might be using a cross compiler--we only care whether it
2338 # can be created.  At this point the main configure script has set CC.
2339 we_are_ok=no
2340 echo "int main () { return 0; }" > conftest.c
2341 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2342 if test $? = 0 ; then
2343   if test -s conftest || test -s conftest.exe ; then
2344     we_are_ok=yes
2345   fi
2346 fi
2347 case $we_are_ok in
2348   no)
2349     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2350     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2351     rm -f conftest*
2352     exit 1
2353     ;;
2354 esac
2355 rm -f conftest*
2356
2357 # The Solaris /usr/ucb/cc compiler does not appear to work.
2358 case "${host}" in
2359   sparc-sun-solaris2*)
2360       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2361       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2362           could_use=
2363           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2364           if test -d /opt/cygnus/bin ; then
2365               if test "$could_use" = "" ; then
2366                   could_use="/opt/cygnus/bin"
2367               else
2368                   could_use="$could_use or /opt/cygnus/bin"
2369               fi
2370           fi
2371         if test "$could_use" = "" ; then
2372             echo "Warning: compilation may fail because you're using"
2373             echo "/usr/ucb/cc.  You should change your PATH or CC "
2374             echo "variable and rerun configure."
2375         else
2376             echo "Warning: compilation may fail because you're using"
2377             echo "/usr/ucb/cc, when you should use the C compiler from"
2378             echo "$could_use.  You should change your"
2379             echo "PATH or CC variable and rerun configure."
2380         fi
2381       fi
2382   ;;
2383 esac
2384
2385 # Decide which environment variable is used to find dynamic libraries.
2386 case "${host}" in
2387   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2388   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2389   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2390   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2391 esac
2392
2393 # On systems where the dynamic library environment variable is PATH,
2394 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2395 # built executables to PATH.
2396 if test "$RPATH_ENVVAR" = PATH; then
2397   GCC_SHLIB_SUBDIR=/shlib
2398 else
2399   GCC_SHLIB_SUBDIR=
2400 fi
2401
2402 # Record target_configdirs and the configure arguments for target and
2403 # build configuration in Makefile.
2404 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2405 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2406
2407 # If we are building libgomp, bootstrap it.
2408 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2409   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2410 fi
2411
2412 # Determine whether gdb needs tk/tcl or not.
2413 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2414 # and in that case we want gdb to be built without tk.  Ugh!
2415 # In fact I believe gdb is the *only* package directly dependent on tk,
2416 # so we should be able to put the 'maybe's in unconditionally and
2417 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2418 # 100% sure that that's safe though.
2419
2420 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2421 case "$enable_gdbtk" in
2422   no)
2423     GDB_TK="" ;;
2424   yes)
2425     GDB_TK="${gdb_tk}" ;;
2426   *)
2427     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2428     # distro.  Eventually someone will fix this and move Insight, nee
2429     # gdbtk to a separate directory.
2430     if test -d ${srcdir}/gdb/gdbtk ; then
2431       GDB_TK="${gdb_tk}"
2432     else
2433       GDB_TK=""
2434     fi
2435     ;;
2436 esac
2437 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2438 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2439
2440 # Strip out unwanted targets.
2441
2442 # While at that, we remove Makefiles if we were started for recursive
2443 # configuration, so that the top-level Makefile reconfigures them,
2444 # like we used to do when configure itself was recursive.
2445
2446 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2447 # but now we're fixing up the Makefile ourselves with the additional
2448 # commands passed to AC_CONFIG_FILES.  Use separate variables
2449 # extrasub-{build,host,target} not because there is any reason to split
2450 # the substitutions up that way, but only to remain below the limit of
2451 # 99 commands in a script, for HP-UX sed.
2452 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2453
2454 AC_ARG_ENABLE([bootstrap],
2455 [AS_HELP_STRING([--enable-bootstrap],
2456                 [enable bootstrapping @<:@yes if native build@:>@])],,
2457 enable_bootstrap=default)
2458
2459 # Issue errors and warnings for invalid/strange bootstrap combinations.
2460 case "$configdirs" in
2461   *gcc*) have_compiler=yes ;;
2462   *) have_compiler=no ;;
2463 esac
2464
2465 case "$have_compiler:$host:$target:$enable_bootstrap" in
2466   *:*:*:no) ;;
2467
2468   # Default behavior.  Enable bootstrap if we have a compiler
2469   # and we are in a native configuration.
2470   yes:$build:$build:default)
2471     enable_bootstrap=yes ;;
2472
2473   *:*:*:default)
2474     enable_bootstrap=no ;;
2475
2476   # We have a compiler and we are in a native configuration, bootstrap is ok
2477   yes:$build:$build:yes)
2478     ;;
2479
2480   # Other configurations, but we have a compiler.  Assume the user knows
2481   # what he's doing.
2482   yes:*:*:yes)
2483     AC_MSG_WARN([trying to bootstrap a cross compiler])
2484     ;;
2485
2486   # No compiler: if they passed --enable-bootstrap explicitly, fail
2487   no:*:*:yes)
2488     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2489
2490   # Fail if wrong command line
2491   *)
2492     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2493     ;;
2494 esac
2495
2496 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2497   *,c++,*:yes:yes) ;;
2498   *:yes:yes)
2499     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2500     ;;
2501 esac
2502
2503 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2504   yes:yes:*\ gold\ *:*,c++,*) ;;
2505   yes:yes:*\ gold\ *:*)
2506     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2507     ;;
2508 esac
2509
2510 # Adjust the toplevel makefile according to whether bootstrap was selected.
2511 case $enable_bootstrap in
2512   yes)
2513     bootstrap_suffix=bootstrap
2514     BUILD_CONFIG=bootstrap-debug
2515     ;;
2516   no)
2517     bootstrap_suffix=no-bootstrap
2518     BUILD_CONFIG=
2519     ;;
2520 esac
2521
2522 AC_MSG_CHECKING(for default BUILD_CONFIG)
2523
2524 AC_ARG_WITH([build-config],
2525   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2526                   [use config/NAME.mk build configuration])],
2527   [case $with_build_config in
2528    yes) with_build_config= ;;
2529    no) with_build_config= BUILD_CONFIG= ;;
2530    esac])
2531
2532 if test "x${with_build_config}" != x; then
2533   BUILD_CONFIG=$with_build_config
2534 else
2535   case $BUILD_CONFIG in
2536   bootstrap-debug)
2537     if echo "int f (void) { return 0; }" > conftest.c &&
2538        ${CC} -c conftest.c &&
2539        mv conftest.o conftest.o.g0 &&
2540        ${CC} -c -g conftest.c &&
2541        mv conftest.o conftest.o.g &&
2542        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2543       :
2544     else
2545       BUILD_CONFIG=
2546     fi
2547     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2548     ;;
2549   esac
2550 fi
2551 AC_MSG_RESULT($BUILD_CONFIG)
2552 AC_SUBST(BUILD_CONFIG)
2553
2554 extrasub_build=
2555 for module in ${build_configdirs} ; do
2556   if test -z "${no_recursion}" \
2557      && test -f ${build_subdir}/${module}/Makefile; then
2558     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2559     rm -f ${build_subdir}/${module}/Makefile
2560   fi
2561   extrasub_build="$extrasub_build
2562 /^@if build-$module\$/d
2563 /^@endif build-$module\$/d
2564 /^@if build-$module-$bootstrap_suffix\$/d
2565 /^@endif build-$module-$bootstrap_suffix\$/d"
2566 done
2567 extrasub_host=
2568 for module in ${configdirs} ; do
2569   if test -z "${no_recursion}"; then
2570     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2571       if test -f ${file}; then
2572         echo 1>&2 "*** removing ${file} to force reconfigure"
2573         rm -f ${file}
2574       fi
2575     done
2576   fi
2577   extrasub_host="$extrasub_host
2578 /^@if $module\$/d
2579 /^@endif $module\$/d
2580 /^@if $module-$bootstrap_suffix\$/d
2581 /^@endif $module-$bootstrap_suffix\$/d"
2582 done
2583 extrasub_target=
2584 for module in ${target_configdirs} ; do
2585   if test -z "${no_recursion}" \
2586      && test -f ${target_subdir}/${module}/Makefile; then
2587     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2588     rm -f ${target_subdir}/${module}/Makefile
2589   fi
2590
2591   # We only bootstrap target libraries listed in bootstrap_target_libs.
2592   case $bootstrap_target_libs in
2593     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2594     *) target_bootstrap_suffix=no-bootstrap ;;
2595   esac
2596
2597   extrasub_target="$extrasub_target
2598 /^@if target-$module\$/d
2599 /^@endif target-$module\$/d
2600 /^@if target-$module-$target_bootstrap_suffix\$/d
2601 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2602 done
2603
2604 # Do the final fixup along with target modules.
2605 extrasub_target="$extrasub_target
2606 /^@if /,/^@endif /d"
2607
2608 # Create the serialization dependencies.  This uses a temporary file.
2609
2610 AC_ARG_ENABLE([serial-configure],
2611 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2612                 [force sequential configuration of
2613                  sub-packages for the host, target or build
2614                  machine, or all sub-packages])])
2615
2616 case ${enable_serial_configure} in
2617   yes)
2618     enable_serial_build_configure=yes
2619     enable_serial_host_configure=yes
2620     enable_serial_target_configure=yes
2621     ;;
2622 esac
2623
2624 # These force 'configure's to be done one at a time, to avoid problems
2625 # with contention over a shared config.cache.
2626 rm -f serdep.tmp
2627 echo '# serdep.tmp' > serdep.tmp
2628 olditem=
2629 test "x${enable_serial_build_configure}" = xyes &&
2630 for item in ${build_configdirs} ; do
2631   case ${olditem} in
2632     "") ;;
2633     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2634   esac
2635   olditem=${item}
2636 done
2637 olditem=
2638 test "x${enable_serial_host_configure}" = xyes &&
2639 for item in ${configdirs} ; do
2640   case ${olditem} in
2641     "") ;;
2642     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2643   esac
2644   olditem=${item}
2645 done
2646 olditem=
2647 test "x${enable_serial_target_configure}" = xyes &&
2648 for item in ${target_configdirs} ; do
2649   case ${olditem} in
2650     "") ;;
2651     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2652   esac
2653   olditem=${item}
2654 done
2655 serialization_dependencies=serdep.tmp
2656 AC_SUBST_FILE(serialization_dependencies)
2657
2658 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2659 # target, nonopt, and variable assignments.  These are the ones we
2660 # might not want to pass down to subconfigures.  The exception being
2661 # --cache-file=/dev/null, which is used to turn off the use of cache
2662 # files altogether, and which should be passed on to subconfigures.
2663 # Also strip program-prefix, program-suffix, and program-transform-name,
2664 # so that we can pass down a consistent program-transform-name.
2665 baseargs=
2666 tbaseargs=
2667 keep_next=no
2668 skip_next=no
2669 eval "set -- $ac_configure_args"
2670 for ac_arg
2671 do
2672   if test X"$skip_next" = X"yes"; then
2673     skip_next=no
2674     continue
2675   fi
2676   if test X"$keep_next" = X"yes"; then
2677     case $ac_arg in
2678       *\'*)
2679         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2680     esac
2681     baseargs="$baseargs '$ac_arg'"
2682     tbaseargs="$tbaseargs '$ac_arg'"
2683     keep_next=no
2684     continue
2685   fi
2686
2687   # Handle separated arguments.  Based on the logic generated by
2688   # autoconf 2.59.
2689   case $ac_arg in
2690     *=* | --config-cache | -C | -disable-* | --disable-* \
2691       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2692       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2693       | -with-* | --with-* | -without-* | --without-* | --x)
2694       separate_arg=no
2695       ;;
2696     -*)
2697       separate_arg=yes
2698       ;;
2699     *)
2700       separate_arg=no
2701       ;;
2702   esac
2703
2704   skip_targ=no
2705   case $ac_arg in
2706 changequote(,)
2707   --with-* | --without-*)
2708     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2709
2710     case $libopt in
2711     *[-_]include)
2712       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2713       ;;
2714     *[-_]lib)
2715       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2716       ;;
2717     *)
2718       lib=$libopt
2719       ;;
2720     esac
2721 changequote([,])
2722
2723     case $lib in
2724     mpc | mpfr | gmp | ppl | cloog)
2725       # If we're processing --with-$lib, --with-$lib-include or
2726       # --with-$lib-lib, for one of the libs above, and target is
2727       # different from host, don't pass the current argument to any
2728       # target library's configure.
2729       if test x$is_cross_compiler = xyes; then
2730         skip_targ=yes
2731       fi
2732       ;;
2733     esac
2734     ;;
2735   esac
2736
2737   case "$ac_arg" in
2738     --cache-file=/dev/null | \
2739     -cache-file=/dev/null )
2740       # Handled here to avoid the test to skip args below.
2741       baseargs="$baseargs '$ac_arg'"
2742       tbaseargs="$tbaseargs '$ac_arg'"
2743       # Assert: $separate_arg should always be no.
2744       keep_next=$separate_arg
2745       ;;
2746     --no*)
2747       continue
2748       ;;
2749     --c* | \
2750     --sr* | \
2751     --ho* | \
2752     --bu* | \
2753     --t* | \
2754     --program-* | \
2755     -cache_file* | \
2756     -srcdir* | \
2757     -host* | \
2758     -build* | \
2759     -target* | \
2760     -program-prefix* | \
2761     -program-suffix* | \
2762     -program-transform-name* )
2763       skip_next=$separate_arg
2764       continue
2765       ;;
2766     -*)
2767       # An option.  Add it.
2768       case $ac_arg in
2769         *\'*)
2770           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2771       esac
2772       baseargs="$baseargs '$ac_arg'"
2773       if test X"$skip_targ" = Xno; then
2774         tbaseargs="$tbaseargs '$ac_arg'"
2775       fi
2776       keep_next=$separate_arg
2777       ;;
2778     *)
2779       # Either a variable assignment, or a nonopt (triplet).  Don't
2780       # pass it down; let the Makefile handle this.
2781       continue
2782       ;;
2783   esac
2784 done
2785 # Remove the initial space we just introduced and, as these will be
2786 # expanded by make, quote '$'.
2787 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2788
2789 # Add in --program-transform-name, after --program-prefix and
2790 # --program-suffix have been applied to it.  Autoconf has already
2791 # doubled dollar signs and backslashes in program_transform_name; we want
2792 # the backslashes un-doubled, and then the entire thing wrapped in single
2793 # quotes, because this will be expanded first by make and then by the shell.
2794 # Also, because we want to override the logic in subdir configure scripts to
2795 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2796 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2797 ${program_transform_name}
2798 EOF_SED
2799 gcc_transform_name=`cat conftestsed.out`
2800 rm -f conftestsed.out
2801 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2802 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2803 if test "$silent" = yes; then
2804   baseargs="$baseargs --silent"
2805   tbaseargs="$tbaseargs --silent"
2806 fi
2807 baseargs="$baseargs --disable-option-checking"
2808 tbaseargs="$tbaseargs --disable-option-checking"
2809
2810 # Record and document user additions to sub configure arguments.
2811 AC_ARG_VAR([build_configargs],
2812            [additional configure arguments for build directories])
2813 AC_ARG_VAR([host_configargs],
2814            [additional configure arguments for host directories])
2815 AC_ARG_VAR([target_configargs],
2816            [additional configure arguments for target directories])
2817
2818 # For the build-side libraries, we just need to pretend we're native,
2819 # and not use the same cache file.  Multilibs are neither needed nor
2820 # desired.
2821 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2822
2823 # For host modules, accept cache file option, or specification as blank.
2824 case "${cache_file}" in
2825 "") # empty
2826   cache_file_option="" ;;
2827 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2828   cache_file_option="--cache-file=${cache_file}" ;;
2829 *) # relative path
2830   cache_file_option="--cache-file=../${cache_file}" ;;
2831 esac
2832
2833 # Host dirs don't like to share a cache file either, horribly enough.
2834 # This seems to be due to autoconf 2.5x stupidity.
2835 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2836
2837 target_configargs="$target_configargs ${tbaseargs}"
2838
2839 # Passing a --with-cross-host argument lets the target libraries know
2840 # whether they are being built with a cross-compiler or being built
2841 # native.  However, it would be better to use other mechanisms to make the
2842 # sorts of decisions they want to make on this basis.  Please consider
2843 # this option to be deprecated.  FIXME.
2844 if test x${is_cross_compiler} = xyes ; then
2845   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2846 fi
2847
2848 # Default to --enable-multilib.
2849 if test x${enable_multilib} = x ; then
2850   target_configargs="--enable-multilib ${target_configargs}"
2851 fi
2852
2853 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2854 # changed from the earlier setting of with_newlib.
2855 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2856   target_configargs="--with-newlib ${target_configargs}"
2857 fi
2858
2859 # Different target subdirs use different values of certain variables
2860 # (notably CXX).  Worse, multilibs use *lots* of different values.
2861 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2862 # it doesn't automatically accept command-line overrides of them.
2863 # This means it's not safe for target subdirs to share a cache file,
2864 # which is disgusting, but there you have it.  Hopefully this can be
2865 # fixed in future.  It's still worthwhile to use a cache file for each
2866 # directory.  I think.
2867
2868 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2869 # We need to pass --target, as newer autoconf's requires consistency
2870 # for target_alias and gcc doesn't manage it consistently.
2871 target_configargs="--cache-file=./config.cache ${target_configargs}"
2872
2873 FLAGS_FOR_TARGET=
2874 case " $target_configdirs " in
2875  *" newlib "*)
2876   case " $target_configargs " in
2877   *" --with-newlib "*)
2878    case "$target" in
2879     *-cygwin*)
2880       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2881       ;;
2882    esac
2883
2884    # If we're not building GCC, don't discard standard headers.
2885    if test -d ${srcdir}/gcc; then
2886      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2887
2888      if test "${build}" != "${host}"; then
2889        # On Canadian crosses, CC_FOR_TARGET will have already been set
2890        # by `configure', so we won't have an opportunity to add -Bgcc/
2891        # to it.  This is right: we don't want to search that directory
2892        # for binaries, but we want the header files in there, so add
2893        # them explicitly.
2894        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2895
2896        # Someone might think of using the pre-installed headers on
2897        # Canadian crosses, in case the installed compiler is not fully
2898        # compatible with the compiler being built.  In this case, it
2899        # would be better to flag an error than risking having
2900        # incompatible object files being constructed.  We can't
2901        # guarantee that an error will be flagged, but let's hope the
2902        # compiler will do it, when presented with incompatible header
2903        # files.
2904      fi
2905    fi
2906
2907    case "${target}-${is_cross_compiler}" in
2908    i[[3456789]]86-*-linux*-no)
2909       # Here host == target, so we don't need to build gcc,
2910       # so we don't want to discard standard headers.
2911       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2912       ;;
2913    *)
2914       # If we're building newlib, use its generic headers last, but search
2915       # for any libc-related directories first (so make it the last -B
2916       # switch).
2917       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2918
2919       # If we're building libgloss, find the startup file, simulator library
2920       # and linker script.
2921       case " $target_configdirs " in
2922         *" libgloss "*)
2923         # Look for startup file, simulator library and maybe linker script.
2924         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2925         # Look for libnosys.a in case the target needs it.
2926         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2927         # Most targets have the linker script in the source directory.
2928         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2929         ;;
2930       esac
2931       ;;
2932    esac
2933    ;;
2934   esac
2935   ;;
2936 esac
2937
2938 case "$target" in
2939   x86_64-*mingw* | *-w64-mingw*)
2940   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2941   # however, use a symlink named 'mingw' in ${prefix} .
2942     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2943     ;;
2944   *-mingw*)
2945   # MinGW can't be handled as Cygwin above since it does not use newlib.
2946     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2947     ;;
2948 esac
2949
2950 # Allow the user to override the flags for
2951 # our build compiler if desired.
2952 if test x"${build}" = x"${host}" ; then
2953   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2954   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2955   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2956 fi
2957
2958 # On Canadian crosses, we'll be searching the right directories for
2959 # the previously-installed cross compiler, so don't bother to add
2960 # flags for directories within the install tree of the compiler
2961 # being built; programs in there won't even run.
2962 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2963   # Search for pre-installed headers if nothing else fits.
2964   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2965 fi
2966
2967 if test "x${use_gnu_ld}" = x &&
2968    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2969   # Arrange for us to find uninstalled linker scripts.
2970   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2971 fi
2972
2973 # Search for other target-specific linker scripts and such.
2974 case "${target}" in
2975   mep*)
2976     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2977     ;;
2978 esac
2979
2980 # Makefile fragments.
2981 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2982 do
2983   eval fragval=\$$frag
2984   if test $fragval != /dev/null; then
2985     eval $frag=${srcdir}/$fragval
2986   fi
2987 done
2988 AC_SUBST_FILE(host_makefile_frag)
2989 AC_SUBST_FILE(target_makefile_frag)
2990 AC_SUBST_FILE(alphaieee_frag)
2991 AC_SUBST_FILE(ospace_frag)
2992
2993 # Miscellanea: directories, flags, etc.
2994 AC_SUBST(RPATH_ENVVAR)
2995 AC_SUBST(GCC_SHLIB_SUBDIR)
2996 AC_SUBST(tooldir)
2997 AC_SUBST(build_tooldir)
2998 AC_SUBST(CONFIGURE_GDB_TK)
2999 AC_SUBST(GDB_TK)
3000 AC_SUBST(INSTALL_GDB_TK)
3001
3002 # Build module lists & subconfigure args.
3003 AC_SUBST(build_configargs)
3004 AC_SUBST(build_configdirs)
3005
3006 # Host module lists & subconfigure args.
3007 AC_SUBST(host_configargs)
3008 AC_SUBST(configdirs)
3009 AC_SUBST(target_configdirs)
3010
3011 # Target module lists & subconfigure args.
3012 AC_SUBST(target_configargs)
3013
3014
3015 # Build tools.
3016 AC_SUBST(AR_FOR_BUILD)
3017 AC_SUBST(AS_FOR_BUILD)
3018 AC_SUBST(CC_FOR_BUILD)
3019 AC_SUBST(CFLAGS_FOR_BUILD)
3020 AC_SUBST(CXXFLAGS_FOR_BUILD)
3021 AC_SUBST(CXX_FOR_BUILD)
3022 AC_SUBST(DLLTOOL_FOR_BUILD)
3023 AC_SUBST(GCJ_FOR_BUILD)
3024 AC_SUBST(GFORTRAN_FOR_BUILD)
3025 AC_SUBST(GOC_FOR_BUILD)
3026 AC_SUBST(LDFLAGS_FOR_BUILD)
3027 AC_SUBST(LD_FOR_BUILD)
3028 AC_SUBST(NM_FOR_BUILD)
3029 AC_SUBST(RANLIB_FOR_BUILD)
3030 AC_SUBST(WINDMC_FOR_BUILD)
3031 AC_SUBST(WINDRES_FOR_BUILD)
3032 AC_SUBST(config_shell)
3033
3034 # Generate default definitions for YACC, M4, LEX and other programs that run
3035 # on the build machine.  These are used if the Makefile can't locate these
3036 # programs in objdir.
3037 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3038
3039 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3040 case " $build_configdirs " in
3041   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3042   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
3043 esac
3044
3045 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3046 case " $build_configdirs " in
3047   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3048 esac
3049
3050 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3051 case " $build_configdirs " in
3052   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3053 esac
3054
3055 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3056 case " $build_configdirs " in
3057   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3058   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3059 esac
3060
3061 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3062 case " $build_configdirs " in
3063   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3064 esac
3065
3066 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3067 case " $build_configdirs " in
3068   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3069   *)
3070 changequote(,)
3071     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3072     # higher, else we use the "missing" dummy.
3073     if ${MAKEINFO} --version \
3074        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3075       :
3076     else
3077       MAKEINFO="$MISSING makeinfo"
3078     fi
3079     ;;
3080 changequote([,])
3081 esac
3082
3083 # FIXME: expect and dejagnu may become build tools?
3084
3085 AC_CHECK_PROGS(EXPECT, expect, expect)
3086 case " $configdirs " in
3087   *" expect "*)
3088     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3089     ;;
3090 esac
3091
3092 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3093 case " $configdirs " in
3094   *" dejagnu "*)
3095     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3096     ;;
3097 esac
3098
3099
3100 # Host tools.
3101 NCN_STRICT_CHECK_TOOLS(AR, ar)
3102 NCN_STRICT_CHECK_TOOLS(AS, as)
3103 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3104 NCN_STRICT_CHECK_TOOLS(LD, ld)
3105 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3106 NCN_STRICT_CHECK_TOOLS(NM, nm)
3107 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3108 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3109 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3110 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3111 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3112 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3113 AC_SUBST(CC)
3114 AC_SUBST(CXX)
3115 AC_SUBST(CFLAGS)
3116 AC_SUBST(CXXFLAGS)
3117
3118 # Target tools.
3119 AC_ARG_WITH([build-time-tools],
3120   [AS_HELP_STRING([--with-build-time-tools=PATH],
3121                   [use given path to find target tools during the build])],
3122   [case x"$withval" in
3123      x/*) ;;
3124      *)
3125        with_build_time_tools=
3126        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3127        ;;
3128    esac],
3129   [with_build_time_tools=])
3130
3131 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3132 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3133 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3134 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3135 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3136 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3137
3138 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3139 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3140 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3141 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3142 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3143 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3144 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3145 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3146 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3147 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3148 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3149
3150 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3151
3152 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3153 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3154 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3155 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3156 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3157                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3158                 c++)
3159 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3160                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3161                 c++)
3162 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3163 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3164 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3165                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3166 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3167                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3168 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3169                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3170 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3171 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3172 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3173 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3174 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3175 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3176 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3177 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3178
3179 AC_SUBST(FLAGS_FOR_TARGET)
3180 AC_SUBST(RAW_CXX_FOR_TARGET)
3181
3182 # Certain tools may need extra flags.
3183 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3184 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3185 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3186
3187 # When building target libraries, except in a Canadian cross, we use
3188 # the same toolchain as the compiler we just built.
3189 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3190 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3191 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3192 if test $host = $build; then
3193   case " $configdirs " in
3194     *" gcc "*)
3195       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3196       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3197       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3198       ;;
3199   esac
3200 fi
3201
3202 AC_SUBST(COMPILER_AS_FOR_TARGET)
3203 AC_SUBST(COMPILER_LD_FOR_TARGET)
3204 AC_SUBST(COMPILER_NM_FOR_TARGET)
3205
3206 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3207 AC_ARG_ENABLE(maintainer-mode,
3208 [AS_HELP_STRING([--enable-maintainer-mode],
3209                 [enable make rules and dependencies not useful
3210                  (and sometimes confusing) to the casual installer])],
3211       USE_MAINTAINER_MODE=$enableval,
3212       USE_MAINTAINER_MODE=no)
3213 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3214 AC_SUBST(MAINTAINER_MODE_TRUE)
3215 AC_SUBST(MAINTAINER_MODE_FALSE)
3216 if test "$USE_MAINTAINER_MODE" = yes; then
3217   MAINTAINER_MODE_TRUE=
3218   MAINTAINER_MODE_FALSE='#'
3219 else
3220   MAINTAINER_MODE_TRUE='#'
3221   MAINTAINER_MODE_FALSE=
3222 fi
3223 MAINT=$MAINTAINER_MODE_TRUE
3224 AC_SUBST(MAINT)dnl
3225
3226 # ---------------------
3227 # GCC bootstrap support
3228 # ---------------------
3229
3230 # Stage specific cflags for build.
3231 stage1_cflags="-g"
3232 case $build in
3233   vax-*-*)
3234     case ${GCC} in
3235       yes) stage1_cflags="-g -Wa,-J" ;;
3236       *) stage1_cflags="-g -J" ;;
3237     esac ;;
3238 esac
3239
3240 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3241 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3242   saved_CFLAGS="$CFLAGS"
3243
3244   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3245   CFLAGS="$CFLAGS -fkeep-inline-functions"
3246   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3247   AC_TRY_COMPILE([
3248 #if (__GNUC__ < 3) \
3249     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3250                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3251 #error http://gcc.gnu.org/PR29382
3252 #endif
3253     ],,
3254     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3255     [AC_MSG_RESULT([no])])
3256
3257   CFLAGS="$saved_CFLAGS"
3258 fi
3259
3260 AC_SUBST(stage1_cflags)
3261
3262 # Enable --enable-checking in stage1 of the compiler.
3263 AC_ARG_ENABLE(stage1-checking,
3264 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3265                 [choose additional checking for stage1 of the compiler])],
3266 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3267 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3268   stage1_checking=--enable-checking=yes,types
3269 else
3270   stage1_checking=--enable-checking=$enable_checking,types
3271 fi])
3272 AC_SUBST(stage1_checking)
3273
3274 # Enable -Werror in bootstrap stage2 and later.
3275 AC_ARG_ENABLE(werror,
3276 [AS_HELP_STRING([--enable-werror],
3277                 [enable -Werror in bootstrap stage2 and later])], [],
3278 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3279   enable_werror=yes
3280 else
3281   enable_werror=no
3282 fi])
3283 case ${enable_werror} in
3284   yes) stage2_werror_flag="--enable-werror-always" ;;
3285   *) stage2_werror_flag="" ;;
3286 esac
3287 AC_SUBST(stage2_werror_flag)
3288
3289 # Specify what files to not compare during bootstrap.
3290
3291 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3292 case "$target" in
3293   hppa*64*-*-hpux*) ;;
3294   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3295 esac
3296 case " $configdirs " in
3297 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3298 esac
3299 AC_SUBST(compare_exclusions)
3300
3301 AC_CONFIG_FILES([Makefile],
3302   [sed "$extrasub_build" Makefile |
3303    sed "$extrasub_host" |
3304    sed "$extrasub_target" > mf$$
3305    mv -f mf$$ Makefile],
3306   [extrasub_build="$extrasub_build"
3307    extrasub_host="$extrasub_host"
3308    extrasub_target="$extrasub_target"])
3309 AC_OUTPUT