src/plugins/plugins.pro

   1 # USE .subdir AND .depends !
   2 # OTHERWISE PLUGINS WILL BUILD IN WRONG ORDER (DIRECTORIES ARE COMPILED IN PARALLEL)
   3
   4 TEMPLATE  = subdirs
   5
   6 SUBDIRS   = plugin_coreplugin \
   7             plugin_welcome \
   8             plugin_find \
   9             plugin_texteditor \
  10             plugin_cppeditor \
  11             plugin_bineditor \
  12             plugin_imageviewer \
  13             plugin_bookmarks \
  14             plugin_projectexplorer \
  15             plugin_vcsbase \
  16             plugin_perforce \
  17             plugin_subversion \
  18             plugin_git \
  19             plugin_cvs \
  20             plugin_cpptools \
  21             plugin_qt4projectmanager \
  22 #            plugin_snippets \ # buggy and annoying
  23             plugin_locator \
  24             plugin_debugger \
  25 #            plugin_qtestlib \ # this seems to be dead
  26             plugin_helloworld \ # sample plugin
  27             plugin_help \
  28 #            plugin_regexp \ # don't know what to do with this
  29             plugin_cpaster \
  30             plugin_cmakeprojectmanager \
  31             plugin_fakevim \
  32             plugin_designer \
  33             plugin_resourceeditor \
  34             plugin_genericprojectmanager \
  35             plugin_qmljseditor \
  36             plugin_mercurial \
  37             plugin_classview \
  38             plugin_tasklist \
  39             debugger/dumper.pro
  40
  41 include(../../qtcreator.pri)
  42
  43 contains(QT_CONFIG, declarative) {
  44     SUBDIRS += \
  45             plugin_qmlprojectmanager \
  46             plugin_qmljsinspector
  47
  48     include(../private_headers.pri)
  49     exists($${QT_PRIVATE_HEADERS}/QtDeclarative/private/qdeclarativecontext_p.h) {
  50
  51         minQtVersion(4, 7, 1) {
  52             SUBDIRS += plugin_qmldesigner
  53         } else {
  54             warning()
  55             warning("QmlDesigner plugin has been disabled.")
  56             warning("QmlDesigner requires Qt 4.7.1 or later.")
  57         }
  58     } else {
  59         warning()
  60         warning("QmlDesigner plugin has been disabled.")
  61         warning("The plugin depends on private headers from QtDeclarative module.")
  62         warning("To enable it, pass 'QT_PRIVATE_HEADERS=$QTDIR/include' to qmake, where $QTDIR is the source directory of qt.")
  63     }
  64 }
  65
  66 plugin_coreplugin.subdir = coreplugin
  67
  68 plugin_welcome.subdir = welcome
  69 plugin_welcome.depends = plugin_coreplugin
  70
  71 plugin_find.subdir = find
  72 plugin_find.depends += plugin_coreplugin
  73
  74 plugin_texteditor.subdir = texteditor
  75 plugin_texteditor.depends = plugin_find
  76 plugin_texteditor.depends += plugin_locator
  77 plugin_texteditor.depends += plugin_coreplugin
  78
  79 plugin_cppeditor.subdir = cppeditor
  80 plugin_cppeditor.depends = plugin_texteditor
  81 plugin_cppeditor.depends += plugin_coreplugin
  82 plugin_cppeditor.depends += plugin_cpptools
  83
  84 plugin_bineditor.subdir = bineditor
  85 plugin_bineditor.depends = plugin_texteditor
  86 plugin_bineditor.depends += plugin_coreplugin
  87
  88 plugin_imageviewer.subdir = imageviewer
  89 plugin_imageviewer.depends = plugin_coreplugin
  90
  91 plugin_designer.subdir = designer
  92 plugin_designer.depends = plugin_coreplugin plugin_cppeditor plugin_projectexplorer
  93
  94 plugin_vcsbase.subdir = vcsbase
  95 plugin_vcsbase.depends = plugin_find
  96 plugin_vcsbase.depends += plugin_texteditor
  97 plugin_vcsbase.depends += plugin_coreplugin
  98 plugin_vcsbase.depends += plugin_projectexplorer
  99
 100 plugin_perforce.subdir = perforce
 101 plugin_perforce.depends = plugin_vcsbase
 102 plugin_perforce.depends += plugin_projectexplorer
 103 plugin_perforce.depends += plugin_coreplugin
 104
 105 plugin_git.subdir = git
 106 plugin_git.depends = plugin_vcsbase
 107 plugin_git.depends += plugin_projectexplorer
 108 plugin_git.depends += plugin_coreplugin
 109
 110 plugin_cvs.subdir = cvs
 111 plugin_cvs.depends = plugin_vcsbase
 112 plugin_cvs.depends += plugin_projectexplorer
 113 plugin_cvs.depends += plugin_coreplugin
 114
 115 plugin_subversion.subdir = subversion
 116 plugin_subversion.depends = plugin_vcsbase
 117 plugin_subversion.depends += plugin_projectexplorer
 118 plugin_subversion.depends += plugin_coreplugin
 119
 120 plugin_projectexplorer.subdir = projectexplorer
 121 plugin_projectexplorer.depends = plugin_locator
 122 plugin_projectexplorer.depends += plugin_find
 123 plugin_projectexplorer.depends += plugin_coreplugin
 124 plugin_projectexplorer.depends += plugin_texteditor
 125
 126 plugin_qt4projectmanager.subdir = qt4projectmanager
 127 plugin_qt4projectmanager.depends = plugin_texteditor
 128 plugin_qt4projectmanager.depends += plugin_projectexplorer
 129 plugin_qt4projectmanager.depends += plugin_cpptools
 130 plugin_qt4projectmanager.depends += plugin_cppeditor
 131 plugin_qt4projectmanager.depends += plugin_qmljseditor
 132 plugin_qt4projectmanager.depends += plugin_designer
 133 plugin_qt4projectmanager.depends += plugin_debugger
 134 plugin_qt4projectmanager.depends += plugin_qmljseditor
 135
 136 plugin_locator.subdir = locator
 137 plugin_locator.depends = plugin_coreplugin
 138
 139 plugin_cpptools.subdir = cpptools
 140 plugin_cpptools.depends = plugin_projectexplorer
 141 plugin_cpptools.depends += plugin_coreplugin
 142 plugin_cpptools.depends += plugin_texteditor
 143 plugin_cpptools.depends += plugin_find
 144
 145 plugin_bookmarks.subdir = bookmarks
 146 plugin_bookmarks.depends = plugin_projectexplorer
 147 plugin_bookmarks.depends += plugin_coreplugin
 148 plugin_bookmarks.depends += plugin_texteditor
 149
 150 plugin_snippets.subdir = snippets
 151 plugin_snippets.depends = plugin_projectexplorer
 152 plugin_snippets.depends += plugin_coreplugin
 153 plugin_snippets.depends += plugin_texteditor
 154
 155 plugin_debugger.subdir = debugger
 156 plugin_debugger.depends = plugin_projectexplorer
 157 plugin_debugger.depends += plugin_coreplugin
 158 plugin_debugger.depends += plugin_cppeditor
 159
 160 plugin_fakevim.subdir = fakevim
 161 plugin_fakevim.depends = plugin_projectexplorer
 162 plugin_fakevim.depends += plugin_coreplugin
 163 plugin_fakevim.depends += plugin_cppeditor
 164
 165 plugin_qtestlib.subdir = qtestlib
 166 plugin_qtestlib.depends = plugin_projectexplorer
 167 plugin_qtestlib.depends += plugin_coreplugin
 168
 169 plugin_helloworld.subdir = helloworld
 170 plugin_helloworld.depends = plugin_coreplugin
 171
 172 plugin_help.subdir = help
 173 plugin_help.depends = plugin_find
 174 plugin_help.depends += plugin_locator
 175 plugin_help.depends += plugin_coreplugin
 176
 177 plugin_resourceeditor.subdir = resourceeditor
 178 plugin_resourceeditor.depends = plugin_coreplugin
 179
 180 plugin_regexp.subdir = regexp
 181 plugin_regexp.depends = plugin_coreplugin
 182
 183 plugin_cpaster.subdir = cpaster
 184 plugin_cpaster.depends = plugin_texteditor
 185 plugin_cpaster.depends += plugin_coreplugin
 186 plugin_cpaster.depends += plugin_projectexplorer
 187
 188 plugin_cmakeprojectmanager.subdir = cmakeprojectmanager
 189 plugin_cmakeprojectmanager.depends = plugin_texteditor
 190 plugin_cmakeprojectmanager.depends += plugin_projectexplorer
 191 plugin_cmakeprojectmanager.depends += plugin_cpptools
 192 plugin_cmakeprojectmanager.depends += plugin_cppeditor
 193
 194 plugin_genericprojectmanager.subdir = genericprojectmanager
 195 plugin_genericprojectmanager.depends = plugin_texteditor
 196 plugin_genericprojectmanager.depends += plugin_projectexplorer
 197 plugin_genericprojectmanager.depends += plugin_cpptools
 198 plugin_genericprojectmanager.depends += plugin_cppeditor
 199
 200 plugin_qmljseditor.subdir = qmljseditor
 201 plugin_qmljseditor.depends = plugin_texteditor
 202 plugin_qmljseditor.depends += plugin_coreplugin
 203 plugin_qmljseditor.depends += plugin_projectexplorer
 204
 205 plugin_qmlprojectmanager.subdir = qmlprojectmanager
 206 plugin_qmlprojectmanager.depends = plugin_texteditor
 207 plugin_qmlprojectmanager.depends += plugin_projectexplorer
 208 plugin_qmlprojectmanager.depends += plugin_qmljseditor
 209 plugin_qmlprojectmanager.depends += plugin_debugger
 210 plugin_qmlprojectmanager.depends += plugin_qt4projectmanager
 211
 212 plugin_qmldesigner.subdir = qmldesigner
 213 plugin_qmldesigner.depends = plugin_coreplugin
 214 plugin_qmldesigner.depends += plugin_texteditor
 215 plugin_qmldesigner.depends += plugin_qmljseditor
 216
 217 plugin_qmljsinspector.subdir = qmljsinspector
 218 plugin_qmljsinspector.depends += plugin_projectexplorer
 219 plugin_qmljsinspector.depends += plugin_qmlprojectmanager
 220 plugin_qmljsinspector.depends += plugin_debugger
 221
 222 plugin_mercurial.subdir = mercurial
 223 plugin_mercurial.depends = plugin_vcsbase
 224 plugin_mercurial.depends += plugin_projectexplorer
 225 plugin_mercurial.depends += plugin_coreplugin
 226
 227 plugin_classview.subdir = classview
 228 plugin_classview.depends = plugin_coreplugin
 229 plugin_classview.depends += plugin_cpptools
 230 plugin_classview.depends += plugin_projectexplorer
 231 plugin_classview.depends += plugin_texteditor
 232
 233 plugin_tasklist.subdir = tasklist
 234 plugin_tasklist.depends = plugin_coreplugin
 235 plugin_tasklist.depends += plugin_projectexplorer