src/plugins/plugins.pro

   1 # USE .subdir AND .depends !
   2 # OTHERWISE PLUGINS WILL BUILD IN WRONG ORDER (DIRECTORIES ARE COMPILED IN PARALLEL)
   3
   4 TEMPLATE  = subdirs
   5
   6 SUBDIRS   = plugin_coreplugin \
   7             plugin_welcome \
   8             plugin_find \
   9             plugin_texteditor \
  10             plugin_cppeditor \
  11             plugin_bineditor \
  12             plugin_imageviewer \
  13             plugin_bookmarks \
  14             plugin_projectexplorer \
  15             plugin_vcsbase \
  16             plugin_perforce \
  17             plugin_subversion \
  18             plugin_git \
  19             plugin_cvs \
  20             plugin_cpptools \
  21             plugin_qt4projectmanager \
  22 #            plugin_snippets \ # buggy and annoying
  23             plugin_locator \
  24             plugin_debugger \
  25 #            plugin_qtestlib \ # this seems to be dead
  26 #            plugin_helloworld \ # sample plugin
  27             plugin_help \
  28 #            plugin_regexp \ # don't know what to do with this
  29             plugin_cpaster \
  30             plugin_cmakeprojectmanager \
  31             plugin_fakevim \
  32             plugin_designer \
  33             plugin_resourceeditor \
  34             plugin_genericprojectmanager \
  35             plugin_qmljseditor \
  36             plugin_mercurial \
  37             debugger/dumper.pro
  38
  39 contains(QT_CONFIG, declarative) {
  40
  41     SUBDIRS += plugin_qmlprojectmanager
  42
  43     include(../private_headers.pri)
  44     exists($${QT_PRIVATE_HEADERS}/QtDeclarative/private/qdeclarativecontext_p.h) {
  45         SUBDIRS += plugin_qmldesigner \
  46                    plugin_qmlinspector
  47     } else {
  48         warning()
  49         warning("QmlDesigner and QmlInspector plugins have been disabled")
  50         warning("The plugins depend on on private headers from QtDeclarative module.")
  51         warning("To enable them, pass 'QT_PRIVATE_HEADERS=$QTDIR/include' to qmake, where $QTDIR is the source directory of qt.")
  52         warning()
  53     }
  54 }
  55
  56 plugin_coreplugin.subdir = coreplugin
  57
  58 plugin_welcome.subdir = welcome
  59 plugin_welcome.depends = plugin_coreplugin
  60
  61 plugin_find.subdir = find
  62 plugin_find.depends += plugin_coreplugin
  63
  64 plugin_texteditor.subdir = texteditor
  65 plugin_texteditor.depends = plugin_find
  66 plugin_texteditor.depends += plugin_locator
  67 plugin_texteditor.depends += plugin_coreplugin
  68
  69 plugin_cppeditor.subdir = cppeditor
  70 plugin_cppeditor.depends = plugin_texteditor
  71 plugin_cppeditor.depends += plugin_coreplugin
  72 plugin_cppeditor.depends += plugin_cpptools
  73
  74 plugin_bineditor.subdir = bineditor
  75 plugin_bineditor.depends = plugin_texteditor
  76 plugin_bineditor.depends += plugin_coreplugin
  77
  78 plugin_imageviewer.subdir = imageviewer
  79 plugin_imageviewer.depends = plugin_coreplugin
  80
  81 plugin_designer.subdir = designer
  82 plugin_designer.depends = plugin_coreplugin plugin_cppeditor plugin_projectexplorer
  83
  84 plugin_vcsbase.subdir = vcsbase
  85 plugin_vcsbase.depends = plugin_find
  86 plugin_vcsbase.depends += plugin_texteditor
  87 plugin_vcsbase.depends += plugin_coreplugin
  88 plugin_vcsbase.depends += plugin_projectexplorer
  89
  90 plugin_perforce.subdir = perforce
  91 plugin_perforce.depends = plugin_vcsbase
  92 plugin_perforce.depends += plugin_projectexplorer
  93 plugin_perforce.depends += plugin_coreplugin
  94
  95 plugin_git.subdir = git
  96 plugin_git.depends = plugin_vcsbase
  97 plugin_git.depends += plugin_projectexplorer
  98 plugin_git.depends += plugin_coreplugin
  99
 100 plugin_cvs.subdir = cvs
 101 plugin_cvs.depends = plugin_vcsbase
 102 plugin_cvs.depends += plugin_projectexplorer
 103 plugin_cvs.depends += plugin_coreplugin
 104
 105 plugin_subversion.subdir = subversion
 106 plugin_subversion.depends = plugin_vcsbase
 107 plugin_subversion.depends += plugin_projectexplorer
 108 plugin_subversion.depends += plugin_coreplugin
 109
 110 plugin_projectexplorer.subdir = projectexplorer
 111 plugin_projectexplorer.depends = plugin_locator
 112 plugin_projectexplorer.depends += plugin_find
 113 plugin_projectexplorer.depends += plugin_coreplugin
 114 plugin_projectexplorer.depends += plugin_texteditor
 115
 116 plugin_qt4projectmanager.subdir = qt4projectmanager
 117 plugin_qt4projectmanager.depends = plugin_texteditor
 118 plugin_qt4projectmanager.depends += plugin_projectexplorer
 119 plugin_qt4projectmanager.depends += plugin_cpptools
 120 plugin_qt4projectmanager.depends += plugin_cppeditor
 121 plugin_qt4projectmanager.depends += plugin_designer
 122 plugin_qt4projectmanager.depends += plugin_debugger
 123
 124 plugin_locator.subdir = locator
 125 plugin_locator.depends = plugin_coreplugin
 126
 127 plugin_cpptools.subdir = cpptools
 128 plugin_cpptools.depends = plugin_projectexplorer
 129 plugin_cpptools.depends += plugin_coreplugin
 130 plugin_cpptools.depends += plugin_texteditor
 131
 132 plugin_bookmarks.subdir = bookmarks
 133 plugin_bookmarks.depends = plugin_projectexplorer
 134 plugin_bookmarks.depends += plugin_coreplugin
 135 plugin_bookmarks.depends += plugin_texteditor
 136
 137 plugin_snippets.subdir = snippets
 138 plugin_snippets.depends = plugin_projectexplorer
 139 plugin_snippets.depends += plugin_coreplugin
 140 plugin_snippets.depends += plugin_texteditor
 141
 142 plugin_debugger.subdir = debugger
 143 plugin_debugger.depends = plugin_projectexplorer
 144 plugin_debugger.depends += plugin_coreplugin
 145 plugin_debugger.depends += plugin_cppeditor
 146
 147 plugin_fakevim.subdir = fakevim
 148 plugin_fakevim.depends = plugin_projectexplorer
 149 plugin_fakevim.depends += plugin_coreplugin
 150 plugin_fakevim.depends += plugin_cppeditor
 151
 152 plugin_qtestlib.subdir = qtestlib
 153 plugin_qtestlib.depends = plugin_projectexplorer
 154 plugin_qtestlib.depends += plugin_coreplugin
 155
 156 plugin_helloworld.subdir = helloworld
 157 plugin_helloworld.depends = plugin_coreplugin
 158
 159 plugin_help.subdir = help
 160 plugin_help.depends = plugin_find
 161 plugin_help.depends += plugin_locator
 162 plugin_help.depends += plugin_coreplugin
 163
 164 plugin_resourceeditor.subdir = resourceeditor
 165 plugin_resourceeditor.depends = plugin_coreplugin
 166
 167 plugin_regexp.subdir = regexp
 168 plugin_regexp.depends = plugin_coreplugin
 169
 170 plugin_cpaster.subdir = cpaster
 171 plugin_cpaster.depends = plugin_texteditor
 172 plugin_cpaster.depends += plugin_coreplugin
 173 plugin_cpaster.depends += plugin_projectexplorer
 174
 175 plugin_cmakeprojectmanager.subdir = cmakeprojectmanager
 176 plugin_cmakeprojectmanager.depends = plugin_texteditor
 177 plugin_cmakeprojectmanager.depends += plugin_projectexplorer
 178 plugin_cmakeprojectmanager.depends += plugin_cpptools
 179 plugin_cmakeprojectmanager.depends += plugin_cppeditor
 180
 181 plugin_genericprojectmanager.subdir = genericprojectmanager
 182 plugin_genericprojectmanager.depends = plugin_texteditor
 183 plugin_genericprojectmanager.depends += plugin_projectexplorer
 184 plugin_genericprojectmanager.depends += plugin_cpptools
 185 plugin_genericprojectmanager.depends += plugin_cppeditor
 186
 187 plugin_qmljseditor.subdir = qmljseditor
 188 plugin_qmljseditor.depends = plugin_texteditor
 189 plugin_qmljseditor.depends += plugin_coreplugin
 190 plugin_qmljseditor.depends += plugin_projectexplorer
 191
 192 plugin_qmlprojectmanager.subdir = qmlprojectmanager
 193 plugin_qmlprojectmanager.depends = plugin_texteditor
 194 plugin_qmlprojectmanager.depends += plugin_projectexplorer
 195 plugin_qmlprojectmanager.depends += plugin_qmljseditor
 196 plugin_qmlprojectmanager.depends += plugin_debugger
 197
 198 plugin_qmldesigner.subdir = qmldesigner
 199 plugin_qmldesigner.depends = plugin_coreplugin
 200 plugin_qmldesigner.depends += plugin_texteditor
 201 plugin_qmldesigner.depends += plugin_qmljseditor
 202
 203 plugin_qmlinspector.subdir = qmlinspector
 204 plugin_qmlinspector.depends += plugin_projectexplorer
 205 plugin_qmlinspector.depends += plugin_cppeditor
 206 plugin_qmlinspector.depends += plugin_qmlprojectmanager
 207 plugin_qmlinspector.depends += plugin_debugger
 208 plugin_qmlinspector.depends += plugin_cpptools
 209
 210 plugin_mercurial.subdir = mercurial
 211 plugin_mercurial.depends = plugin_vcsbase
 212 plugin_mercurial.depends += plugin_projectexplorer
 213 plugin_mercurial.depends += plugin_coreplugin