src/plugins/plugins.pro

   1 # USE .subdir AND .depends !
   2 # OTHERWISE PLUGINS WILL BUILD IN WRONG ORDER (DIRECTORIES ARE COMPILED IN PARALLEL)
   3
   4 TEMPLATE  = subdirs
   5
   6 SUBDIRS   = plugin_coreplugin \
   7             plugin_welcome \
   8             plugin_find \
   9             plugin_texteditor \
  10             plugin_cppeditor \
  11             plugin_bineditor \
  12             plugin_imageviewer \
  13             plugin_bookmarks \
  14             plugin_projectexplorer \
  15             plugin_vcsbase \
  16             plugin_perforce \
  17             plugin_subversion \
  18             plugin_git \
  19             plugin_cvs \
  20             plugin_cpptools \
  21             plugin_qt4projectmanager \
  22 #            plugin_snippets \ # buggy and annoying
  23             plugin_locator \
  24             plugin_debugger \
  25 #            plugin_qtestlib \ # this seems to be dead
  26             plugin_helloworld \ # sample plugin
  27             plugin_help \
  28 #            plugin_regexp \ # don't know what to do with this
  29             plugin_cpaster \
  30             plugin_cmakeprojectmanager \
  31             plugin_fakevim \
  32             plugin_designer \
  33             plugin_resourceeditor \
  34             plugin_genericprojectmanager \
  35             plugin_qmljseditor \
  36             plugin_mercurial \
  37             plugin_classview \
  38             plugin_tasklist \
  39             debugger/dumper.pro
  40
  41 contains(QT_CONFIG, declarative) {
  42
  43     SUBDIRS += \
  44             plugin_qmlprojectmanager \
  45             plugin_qmljsinspector
  46
  47     include(../private_headers.pri)
  48     exists($${QT_PRIVATE_HEADERS}/QtDeclarative/private/qdeclarativecontext_p.h) {
  49         SUBDIRS += plugin_qmldesigner
  50     } else {
  51         warning()
  52         warning("QmlDesigner plugin have been disabled")
  53         warning("The plugin depend on on private headers from QtDeclarative module.")
  54         warning("To enable them, pass 'QT_PRIVATE_HEADERS=$QTDIR/include' to qmake, where $QTDIR is the source directory of qt.")
  55         warning()
  56     }
  57 }
  58
  59 plugin_coreplugin.subdir = coreplugin
  60
  61 plugin_welcome.subdir = welcome
  62 plugin_welcome.depends = plugin_coreplugin
  63
  64 plugin_find.subdir = find
  65 plugin_find.depends += plugin_coreplugin
  66
  67 plugin_texteditor.subdir = texteditor
  68 plugin_texteditor.depends = plugin_find
  69 plugin_texteditor.depends += plugin_locator
  70 plugin_texteditor.depends += plugin_coreplugin
  71
  72 plugin_cppeditor.subdir = cppeditor
  73 plugin_cppeditor.depends = plugin_texteditor
  74 plugin_cppeditor.depends += plugin_coreplugin
  75 plugin_cppeditor.depends += plugin_cpptools
  76
  77 plugin_bineditor.subdir = bineditor
  78 plugin_bineditor.depends = plugin_texteditor
  79 plugin_bineditor.depends += plugin_coreplugin
  80
  81 plugin_imageviewer.subdir = imageviewer
  82 plugin_imageviewer.depends = plugin_coreplugin
  83
  84 plugin_designer.subdir = designer
  85 plugin_designer.depends = plugin_coreplugin plugin_cppeditor plugin_projectexplorer
  86
  87 plugin_vcsbase.subdir = vcsbase
  88 plugin_vcsbase.depends = plugin_find
  89 plugin_vcsbase.depends += plugin_texteditor
  90 plugin_vcsbase.depends += plugin_coreplugin
  91 plugin_vcsbase.depends += plugin_projectexplorer
  92
  93 plugin_perforce.subdir = perforce
  94 plugin_perforce.depends = plugin_vcsbase
  95 plugin_perforce.depends += plugin_projectexplorer
  96 plugin_perforce.depends += plugin_coreplugin
  97
  98 plugin_git.subdir = git
  99 plugin_git.depends = plugin_vcsbase
 100 plugin_git.depends += plugin_projectexplorer
 101 plugin_git.depends += plugin_coreplugin
 102
 103 plugin_cvs.subdir = cvs
 104 plugin_cvs.depends = plugin_vcsbase
 105 plugin_cvs.depends += plugin_projectexplorer
 106 plugin_cvs.depends += plugin_coreplugin
 107
 108 plugin_subversion.subdir = subversion
 109 plugin_subversion.depends = plugin_vcsbase
 110 plugin_subversion.depends += plugin_projectexplorer
 111 plugin_subversion.depends += plugin_coreplugin
 112
 113 plugin_projectexplorer.subdir = projectexplorer
 114 plugin_projectexplorer.depends = plugin_locator
 115 plugin_projectexplorer.depends += plugin_find
 116 plugin_projectexplorer.depends += plugin_coreplugin
 117 plugin_projectexplorer.depends += plugin_texteditor
 118
 119 plugin_qt4projectmanager.subdir = qt4projectmanager
 120 plugin_qt4projectmanager.depends = plugin_texteditor
 121 plugin_qt4projectmanager.depends += plugin_projectexplorer
 122 plugin_qt4projectmanager.depends += plugin_cpptools
 123 plugin_qt4projectmanager.depends += plugin_cppeditor
 124 plugin_qt4projectmanager.depends += plugin_designer
 125 plugin_qt4projectmanager.depends += plugin_debugger
 126
 127 plugin_locator.subdir = locator
 128 plugin_locator.depends = plugin_coreplugin
 129
 130 plugin_cpptools.subdir = cpptools
 131 plugin_cpptools.depends = plugin_projectexplorer
 132 plugin_cpptools.depends += plugin_coreplugin
 133 plugin_cpptools.depends += plugin_texteditor
 134 plugin_cpptools.depends += plugin_find
 135
 136 plugin_bookmarks.subdir = bookmarks
 137 plugin_bookmarks.depends = plugin_projectexplorer
 138 plugin_bookmarks.depends += plugin_coreplugin
 139 plugin_bookmarks.depends += plugin_texteditor
 140
 141 plugin_snippets.subdir = snippets
 142 plugin_snippets.depends = plugin_projectexplorer
 143 plugin_snippets.depends += plugin_coreplugin
 144 plugin_snippets.depends += plugin_texteditor
 145
 146 plugin_debugger.subdir = debugger
 147 plugin_debugger.depends = plugin_projectexplorer
 148 plugin_debugger.depends += plugin_coreplugin
 149 plugin_debugger.depends += plugin_cppeditor
 150
 151 plugin_fakevim.subdir = fakevim
 152 plugin_fakevim.depends = plugin_projectexplorer
 153 plugin_fakevim.depends += plugin_coreplugin
 154 plugin_fakevim.depends += plugin_cppeditor
 155
 156 plugin_qtestlib.subdir = qtestlib
 157 plugin_qtestlib.depends = plugin_projectexplorer
 158 plugin_qtestlib.depends += plugin_coreplugin
 159
 160 plugin_helloworld.subdir = helloworld
 161 plugin_helloworld.depends = plugin_coreplugin
 162
 163 plugin_help.subdir = help
 164 plugin_help.depends = plugin_find
 165 plugin_help.depends += plugin_locator
 166 plugin_help.depends += plugin_coreplugin
 167
 168 plugin_resourceeditor.subdir = resourceeditor
 169 plugin_resourceeditor.depends = plugin_coreplugin
 170
 171 plugin_regexp.subdir = regexp
 172 plugin_regexp.depends = plugin_coreplugin
 173
 174 plugin_cpaster.subdir = cpaster
 175 plugin_cpaster.depends = plugin_texteditor
 176 plugin_cpaster.depends += plugin_coreplugin
 177 plugin_cpaster.depends += plugin_projectexplorer
 178
 179 plugin_cmakeprojectmanager.subdir = cmakeprojectmanager
 180 plugin_cmakeprojectmanager.depends = plugin_texteditor
 181 plugin_cmakeprojectmanager.depends += plugin_projectexplorer
 182 plugin_cmakeprojectmanager.depends += plugin_cpptools
 183 plugin_cmakeprojectmanager.depends += plugin_cppeditor
 184
 185 plugin_genericprojectmanager.subdir = genericprojectmanager
 186 plugin_genericprojectmanager.depends = plugin_texteditor
 187 plugin_genericprojectmanager.depends += plugin_projectexplorer
 188 plugin_genericprojectmanager.depends += plugin_cpptools
 189 plugin_genericprojectmanager.depends += plugin_cppeditor
 190
 191 plugin_qmljseditor.subdir = qmljseditor
 192 plugin_qmljseditor.depends = plugin_texteditor
 193 plugin_qmljseditor.depends += plugin_coreplugin
 194 plugin_qmljseditor.depends += plugin_projectexplorer
 195
 196 plugin_qmlprojectmanager.subdir = qmlprojectmanager
 197 plugin_qmlprojectmanager.depends = plugin_texteditor
 198 plugin_qmlprojectmanager.depends += plugin_projectexplorer
 199 plugin_qmlprojectmanager.depends += plugin_qmljseditor
 200 plugin_qmlprojectmanager.depends += plugin_debugger
 201 plugin_qmlprojectmanager.depends += plugin_qt4projectmanager
 202
 203 plugin_qmldesigner.subdir = qmldesigner
 204 plugin_qmldesigner.depends = plugin_coreplugin
 205 plugin_qmldesigner.depends += plugin_texteditor
 206 plugin_qmldesigner.depends += plugin_qmljseditor
 207
 208 plugin_qmljsinspector.subdir = qmljsinspector
 209 plugin_qmljsinspector.depends += plugin_projectexplorer
 210 plugin_qmljsinspector.depends += plugin_qmlprojectmanager
 211 plugin_qmljsinspector.depends += plugin_debugger
 212
 213 plugin_mercurial.subdir = mercurial
 214 plugin_mercurial.depends = plugin_vcsbase
 215 plugin_mercurial.depends += plugin_projectexplorer
 216 plugin_mercurial.depends += plugin_coreplugin
 217
 218 plugin_classview.subdir = classview
 219 plugin_classview.depends = plugin_coreplugin
 220 plugin_classview.depends += plugin_cpptools
 221 plugin_classview.depends += plugin_projectexplorer
 222 plugin_classview.depends += plugin_texteditor
 223
 224 plugin_tasklist.subdir = tasklist
 225 plugin_tasklist.depends = plugin_coreplugin
 226 plugin_tasklist.depends += plugin_projectexplorer