doc/doc.pri

   1 QDOC_BIN = $$targetPath($$[QT_INSTALL_BINS]/qdoc3)
   2 HELPGENERATOR = $$targetPath($$[QT_INSTALL_BINS]/qhelpgenerator)
   3
   4 VERSION_TAG = $$replace(QTCREATOR_VERSION, "[-.]", )
   5
   6 equals(QMAKE_DIR_SEP, /) {   # unix, mingw+msys
   7     QDOC = SRCDIR=$$PWD OUTDIR=$$OUT_PWD/doc/html QTC_VERSION=$$QTCREATOR_VERSION QTC_VERSION_TAG=$$VERSION_TAG $$QDOC_BIN
   8 } else:win32-g++* {   # just mingw
   9     # The lack of spaces in front of the && is necessary!
  10     QDOC = set SRCDIR=$$PWD&& set OUTDIR=$$OUT_PWD/doc/html&& set QTC_VERSION=$$QTCREATOR_VERSION&& set QTC_VERSION_TAG=$$VERSION_TAG&& $$QDOC_BIN
  11 } else {   # nmake
  12     QDOC = set SRCDIR=$$PWD $$escape_expand(\\n\\t) \
  13            set OUTDIR=$$OUT_PWD/doc/html $$escape_expand(\\n\\t) \
  14            set QTC_VERSION=$$QTCREATOR_VERSION $$escape_expand(\\n\\t) \
  15            set QTC_VERSION_TAG=$$VERSION_TAG $$escape_expand(\\n\\t) \
  16            $$QDOC_BIN
  17 }
  18
  19 QHP_FILE = $$OUT_PWD/doc/html/qtcreator.qhp
  20 QCH_FILE = $$IDE_DOC_PATH/qtcreator.qch
  21
  22 HELP_DEP_FILES = $$PWD/qtcreator.qdoc \
  23                  $$PWD/addressbook-sdk.qdoc \
  24                  $$PWD/config/compat.qdocconf \
  25                  $$PWD/config/macros.qdocconf \
  26                  $$PWD/config/qt-cpp-ignore.qdocconf \
  27                  $$PWD/config/qt-defines.qdocconf \
  28                  $$PWD/config/qt-html-templates.qdocconf \
  29                  $$PWD/config/qt-html-default-styles.qdocconf \
  30                  $$PWD/qtcreator.qdocconf
  31
  32 html_docs.commands = $$QDOC $$PWD/qtcreator.qdocconf
  33 html_docs.depends += $$HELP_DEP_FILES
  34 html_docs.files = $$QHP_FILE
  35
  36 html_docs_online.commands = $$QDOC $$PWD/qtcreator-online.qdocconf
  37 html_docs_online.depends += $$HELP_DEP_FILES
  38
  39 qch_docs.commands = $$HELPGENERATOR -o \"$$QCH_FILE\" $$QHP_FILE
  40 qch_docs.depends += html_docs
  41 qch_docs.files = $$QCH_FILE
  42
  43 unix:!macx {
  44     qch_docs.path = /share/doc/qtcreator
  45     qch_docs.CONFIG += no_check_exist
  46     INSTALLS += qch_docs
  47 }
  48
  49 docs_online.depends = html_docs_online
  50 docs.depends = qch_docs
  51 QMAKE_EXTRA_TARGETS += html_docs html_docs_online qch_docs docs docs_online
  52
  53 OTHER_FILES = $$HELP_DEP_FILES \
  54               $$PWD/api/qtcreator-api.qdoc \
  55               $$PWD/api/qtcreator-api.qdocconf
  56
  57 fixnavi.commands = \
  58     cd $$targetPath($$PWD) && \
  59     perl fixnavi.pl -Dqcmanual -Dqtquick \
  60         qtcreator.qdoc maemodev.qdoc symbiandev.qdoc qtcreator-faq.qdoc
  61 QMAKE_EXTRA_TARGETS += fixnavi