zlib/configure.in

   1 dnl Process this with autoconf to create configure
   2
   3 AC_INIT(zlib.h)
   4 AC_CANONICAL_SYSTEM
   5 AM_INIT_AUTOMAKE(zlib, 1.1.3)
   6
   7 AM_MAINTAINER_MODE
   8
   9 AC_CONFIG_AUX_DIR(..)
  10
  11 dnl We use these options to decide which functions to include.
  12 AC_ARG_WITH(target-subdir,
  13 [  --with-target-subdir=SUBDIR
  14                           configuring in a subdirectory])
  15 AC_ARG_WITH(cross-host,
  16 [  --with-cross-host=HOST  configuring with a cross compiler])
  17
  18 dnl Default to --enable-multilib
  19 AC_ARG_ENABLE(multilib,
  20 [  --enable-multilib       build many library versions (default)],
  21 [case "${enableval}" in
  22   yes) multilib=yes ;;
  23   no)  multilib=no ;;
  24   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  25  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  26
  27 dnl We may get other options which we dont document:
  28 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  29
  30 if test "[$]{srcdir}" = "."; then
  31   if test "[$]{with_target_subdir}" != "."; then
  32     zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}../"
  33   else
  34     zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}"
  35   fi
  36 else
  37   zlib_basedir="[$]{srcdir}/"
  38 fi
  39 AC_SUBST(zlib_basedir)
  40
  41 AC_ARG_WITH(system-zlib,
  42 [  --with-system-zlib      use installed libz])
  43
  44 LIB_AC_PROG_CC
  45 # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
  46 # at least currently, we never actually build a program, so we never
  47 # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
  48 # fails, because we are probably configuring with a cross compiler
  49 # which cant create executables.  So we include AC_EXEEXT to keep
  50 # automake happy, but we dont execute it, since we dont care about
  51 # the result.
  52 if false; then
  53   AC_EXEEXT
  54 fi
  55 AM_PROG_LIBTOOL
  56
  57 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  58    COMPPATH=.
  59 else
  60    COMPPATH=..
  61 fi
  62 AC_SUBST(COMPPATH)
  63
  64
  65 if test -n "$with_cross_host"; then
  66    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  67    # may not work correctly, because the compiler may not be able to
  68    # link executables.
  69
  70    # We assume newlib.  This lets us hard-code the functions we know
  71    # we'll have.
  72    AC_DEFINE(HAVE_MEMCPY)
  73    AC_DEFINE(HAVE_STRERROR)
  74
  75    # We ignore --with-system-zlib in this case.
  76    target_all=libzgcj.la
  77 else
  78    AC_FUNC_MMAP
  79    AC_CHECK_FUNCS(memcpy strerror)
  80
  81    if test "$with_system_zlib" = yes; then
  82       AC_CHECK_LIB(z, deflate, target_all=, target_all=libzgcj.la)
  83    else
  84       target_all=libzgcj.la
  85    fi
  86 fi
  87
  88 AC_SUBST(target_all)
  89
  90 AC_CHECK_HEADERS(unistd.h)
  91
  92 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
  93 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
  94
  95 if test "${multilib}" = "yes"; then
  96   multilib_arg="--enable-multilib"
  97 else
  98   multilib_arg=
  99 fi
 100
 101 AC_OUTPUT(Makefile,
 102 [if test -n "$CONFIG_FILES"; then
 103   ac_file=Makefile . ${zlib_basedir}/../config-ml.in
 104 fi],
 105 srcdir=${srcdir}
 106 host=${host}
 107 target=${target}
 108 with_multisubdir=${with_multisubdir}
 109 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 110 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 111 zlib_basedir=${zlib_basedir}
 112 CC="${CC}"
 113 CXX="${CXX}"
 114 )