tk/library/demos/vscale.tcl

   1 # vscale.tcl --
   2 #
   3 # This demonstration script shows an example with a vertical scale.
   4 #
   5 # RCS: @(#) $Id$
   6
   7 if {![info exists widgetDemo]} {
   8     error "This script should be run from the \"widget\" demo."
   9 }
  10
  11 set w .vscale
  12 catch {destroy $w}
  13 toplevel $w
  14 wm title $w "Vertical Scale Demonstration"
  15 wm iconname $w "vscale"
  16 positionWindow $w
  17
  18 label $w.msg -font $font -wraplength 3.5i -justify left -text "An arrow and a vertical scale are displayed below.  If you click or drag mouse button 1 in the scale, you can change the size of the arrow."
  19 pack $w.msg -side top -padx .5c
  20
  21 frame $w.buttons
  22 pack $w.buttons -side bottom -fill x -pady 2m
  23 button $w.buttons.dismiss -text Dismiss -command "destroy $w"
  24 button $w.buttons.code -text "See Code" -command "showCode $w"
  25 pack $w.buttons.dismiss $w.buttons.code -side left -expand 1
  26
  27 frame $w.frame -borderwidth 10
  28 pack $w.frame
  29
  30 scale $w.frame.scale -orient vertical -length 284 -from 0 -to 250 \
  31         -command "setHeight $w.frame.canvas" -tickinterval 50
  32 canvas $w.frame.canvas -width 50 -height 50 -bd 0 -highlightthickness 0
  33 $w.frame.canvas create polygon 0 0 1 1 2 2 -fill SeaGreen3 -tags poly
  34 $w.frame.canvas create line 0 0 1 1 2 2 0 0 -fill black -tags line
  35 frame $w.frame.right -borderwidth 15
  36 pack $w.frame.scale -side left -anchor ne
  37 pack $w.frame.canvas -side left -anchor nw -fill y
  38 $w.frame.scale set 75
  39
  40 proc setHeight {w height} {
  41     incr height 21
  42     set y2 [expr $height - 30]
  43     if {$y2 < 21} {
  44         set y2 21
  45     }
  46     $w coords poly 15 20 35 20 35 $y2 45 $y2 25 $height 5 $y2 15 $y2 15 20
  47     $w coords line 15 20 35 20 35 $y2 45 $y2 25 $height 5 $y2 15 $y2 15 20
  48 }
  49