libstdc++-v3/testsuite/lib/libstdc++.exp

   1 # libstdc++ "tool init file" for DejaGNU
   2
   3 # Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19
  20 # Define callbacks and load other libraries.  This file is loaded relatively
  21 # early, and before any other file we write ourselves.  "load_lib" will
  22 # find anything in the DejaGNU installation tree, or in our lib directory.
  23 # "load_gcc_lib" will search the core compiler's .exp collection instead.
  24 #
  25 # The naming rule is that dg.exp looks for "tool-" and runtest.exp looks
  26 # for "tool_" when finding callbacks.  Utility routines we define for
  27 # our callbacks begin with "v3-".
  28 #
  29 # libstdc++_* callbacks we don't define, but could:
  30 # ..._option_help           prints additional --help output
  31 # ..._option_proc (--foo)   process our own options
  32 # ..._exit                  cleanup routines (do we need any?)
  33 # ..._init (normal.exp)     called once per test file
  34 # ..._finish                bracketing function for libstdc++_init
  35 # ...-dg-prune              removing output text, see top of system dg.exp
  36 #
  37 # Useful hook:  if ${hostname}_init exists, it will be called, almost
  38 # the last thing before testing begins.  This can be defined in, e.g.,
  39 # ~/.dejagnurc or $DEJAGNU.
  40
  41 proc load_gcc_lib { filename } {
  42     global srcdir
  43     load_file $srcdir/../../gcc/testsuite/lib/$filename
  44 }
  45
  46 # system routines
  47 load_lib dg.exp
  48 load_lib libgloss.exp
  49 # compiler routines, then ours
  50 load_gcc_lib target-supports.exp
  51 load_lib prune.exp
  52 load_lib dg-options.exp
  53 load_gcc_lib wrapper.exp
  54
  55 # Useful for debugging.  Pass the name of a variable and the verbosity
  56 # threshold (number of -v's on the command line).
  57 proc v3track { var n } {
  58     upvar $var val
  59     verbose "++ $var is $val" $n
  60 }
  61
  62 # Called by v3-init below.  "Static" to this file.
  63 proc v3-copy-files {srcfiles} {
  64     foreach f $srcfiles {
  65         if { [catch { set symlink [file readlink $f] } x] } then {
  66             remote_download target $f
  67         } else {
  68             if { [regexp "^/" "$symlink"] } then {
  69                 remote_download target $symlink
  70             } else {
  71                 set dirname [file dirname $f]
  72                 remote_download target $dirname/$symlink
  73             }
  74         }
  75     }
  76 }
  77
  78 # Called once, during runtest.exp setup.
  79 proc libstdc++_init { testfile } {
  80     global env
  81     global srcdir blddir objdir tool_root_dir
  82     global cxx cxxflags
  83     global includes
  84     global gluefile wrap_flags
  85     global original_ld_library_path
  86     global target_triplet
  87
  88     set blddir [lookfor_file [get_multilibs] libstdc++-v3]
  89     set flags_file "${blddir}/scripts/testsuite_flags"
  90     v3track flags_file 2
  91
  92     # If a test doesn't have special options, use DEFAULT_CXXFLAGS.
  93     # Use this variable if the behavior
  94     #   1) only applies to libstdc++ testing
  95     #   2) might need to be negated
  96     # In particular, some tests have to be run without precompiled
  97     # headers, or without assertions.
  98     global DEFAULT_CXXFLAGS
  99     if ![info exists DEFAULT_CXXFLAGS] then {
 100         # Set up includes for stdc++.h.gch, the precompiled header file.
 101         if { [file exists $flags_file] } {
 102             set cxxpchflags [exec sh $flags_file --cxxpchflags]
 103         } else {
 104             set cxxpchflags ""
 105         }
 106         set DEFAULT_CXXFLAGS " ${cxxpchflags}"
 107
 108         # Host specific goo here.
 109         if { [string match "powerpc-*-darwin*" $target_triplet] } {
 110             append DEFAULT_CXXFLAGS " -multiply_defined suppress"
 111         }
 112     }
 113     v3track DEFAULT_CXXFLAGS 2
 114
 115     # By default, we assume we want to run program images.
 116     global dg-do-what-default
 117     set dg-do-what-default run
 118
 119     # Copy any required data files.
 120     v3-copy-files [glob -nocomplain "$srcdir/data/*.tst"]
 121     v3-copy-files [glob -nocomplain "$srcdir/data/*.txt"]
 122
 123     # Setup LD_LIBRARY_PATH so that libgcc_s, libstdc++ binaries can be found.
 124     # Find the existing LD_LIBRARY_PATH.
 125     if [info exists env(LD_LIBRARY_PATH)] {
 126         set original_ld_library_path $env(LD_LIBRARY_PATH)
 127         # For HP-UX
 128     } elseif [info exists env(SHLIB_PATH)] {
 129         set original_ld_library_path $env(SHLIB_PATH)
 130         # For Darwin:
 131     } elseif [info exists env(DYLD_LIBRARY_PATH)] {
 132         set original_ld_library_path $env(DYLD_LIBRARY_PATH)
 133         # For Solaris 32 bit:
 134     } elseif [info exists env(LD_LIBRARY_PATH_32)] {
 135         set original_ld_library_path $env(LD_LIBRARY_PATH_32)
 136         # For Solaris 64 bit:
 137     } elseif [info exists env(LD_LIBRARY_PATH_64)] {
 138         set original_ld_library_path $env(LD_LIBRARY_PATH_64)
 139     } else {
 140         set original_ld_library_path ""
 141     }
 142
 143     # Locate libgcc.a so we don't need to account for different values of
 144     # SHLIB_EXT on different platforms
 145     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 146     if {$gccdir != ""} {
 147         set gccdir [file dirname $gccdir]
 148     }
 149     v3track gccdir 3
 150
 151     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 152     set ld_library_path ""
 153     append ld_library_path ":${gccdir}"
 154     set compiler ${gccdir}/g++
 155     if { [is_remote host] == 0 && [which $compiler] != 0 } {
 156       foreach i "[exec $compiler --print-multi-lib]" {
 157         set mldir ""
 158         regexp -- "\[a-z0-9=/\.-\]*;" $i mldir
 159         set mldir [string trimright $mldir "\;@"]
 160         if { "$mldir" == "." } {
 161           continue
 162         }
 163         if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] == 1 } {
 164           append ld_library_path ":${gccdir}/${mldir}"
 165         }
 166       }
 167     }
 168     append ld_library_path ":${blddir}/src/.libs"
 169
 170     # On IRIX 6, we have to set variables akin to LD_LIBRARY_PATH, but
 171     # called LD_LIBRARYN32_PATH (for the N32 ABI) and LD_LIBRARY64_PATH
 172     # (for the 64-bit ABI).  The right way to do this would be to modify
 173     # unix.exp -- but that's not an option since it's part of DejaGNU
 174     # proper, so we do it here.
 175     # The same applies to darwin (DYLD_LIBRARY_PATH), solaris 32 bit
 176     # (LD_LIBRARY_PATH_32), solaris 64 bit (LD_LIBRARY_PATH_64), and HP-UX
 177     # (SHLIB_PATH).
 178     setenv  LD_LIBRARY_PATH     "$ld_library_path:$original_ld_library_path"
 179     setenv  SHLIB_PATH          "$ld_library_path:$original_ld_library_path"
 180     setenv  LD_LIBRARYN32_PATH  "$ld_library_path:$original_ld_library_path"
 181     setenv  LD_LIBRARY64_PATH   "$ld_library_path:$original_ld_library_path"
 182     setenv  LD_RUN_PATH         "$ld_library_path:$original_ld_library_path"
 183     setenv  LD_LIBRARY_PATH_32  "$ld_library_path:$original_ld_library_path"
 184     setenv  LD_LIBRARY_PATH_64  "$ld_library_path:$original_ld_library_path"
 185     setenv  DYLD_LIBRARY_PATH   "$ld_library_path:$original_ld_library_path"
 186     verbose -log "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
 187
 188     # Do a bunch of handstands and backflips for cross compiling and
 189     # finding simulators...
 190     if [is_remote host] {
 191         set header [remote_download host ${blddir}/testsuite/testsuite_hooks.h]
 192         if { $header == "" } {
 193             verbose -log "Unable to download ${blddir}/testsuite/testsuite_hooks.h to host."
 194             return "untested"
 195         }
 196       set cxx [transform "g++"]
 197       set cxxflags "-ggdb3"
 198       set includes "-I./"
 199     } else {
 200         # If we find a testsuite_flags file, we're testing in the build dir.
 201         if { [file exists $flags_file] } {
 202             set cxx [exec sh $flags_file --build-cxx]
 203             set cxxflags [exec sh $flags_file --cxxflags]
 204             set includes [exec sh $flags_file --build-includes]
 205         } else {
 206             set cxx [transform "g++"]
 207             set cxxflags "-ggdb3"
 208             set includes "-I${srcdir}"
 209         }
 210     }
 211
 212     libstdc++_maybe_build_wrapper "${objdir}/testglue.o"
 213 }
 214
 215 # Callback from system dg-test.
 216 proc libstdc++-dg-test { prog do_what extra_tool_flags } {
 217     # Set up the compiler flags, based on what we're going to do.
 218     switch $do_what {
 219         "preprocess" {
 220             set compile_type "preprocess"
 221             set output_file "[file rootname [file tail $prog]].i"
 222         }
 223         "compile" {
 224             set compile_type "assembly"
 225             set output_file "[file rootname [file tail $prog]].s"
 226         }
 227         "assemble" {
 228             set compile_type "object"
 229             set output_file "[file rootname [file tail $prog]].o"
 230         }
 231         "link" {
 232             set compile_type "executable"
 233             set output_file "./[file rootname [file tail $prog]].exe"
 234         }
 235         "run" {
 236             set compile_type "executable"
 237             # FIXME: "./" is to cope with "." not being in $PATH.
 238             # Should this be handled elsewhere?
 239             # YES.
 240             set output_file "./[file rootname [file tail $prog]].exe"
 241             # This is the only place where we care if an executable was
 242             # created or not.  If it was, dg.exp will try to run it.
 243             remote_file build delete $output_file;
 244         }
 245         default {
 246             perror "$do_what: not a valid dg-do keyword"
 247             return ""
 248         }
 249     }
 250     set options ""
 251     if { $extra_tool_flags != "" } {
 252         lappend options "additional_flags=$extra_tool_flags"
 253     }
 254
 255     # There is a libstdc++_compile made for us by default (via the tool-
 256     # and-target file), but the defaults are lacking in goodness.
 257     set comp_output [v3_target_compile "$prog" "$output_file" "$compile_type" $options];
 258     set comp_output [ prune_g++_output $comp_output ];
 259
 260     return [list $comp_output $output_file]
 261 }
 262
 263 # Called from libstdc++-dg-test above.  Calls back into system's
 264 # target_compile to actually do the work.
 265 proc v3_target_compile { source dest type options } {
 266     global gluefile
 267     global wrap_flags
 268     global cxx
 269     global cxxflags
 270     global includes
 271     global blddir
 272
 273     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 274         lappend options "libs=${gluefile}"
 275         lappend options "ldflags=${wrap_flags}"
 276     }
 277
 278     set cxx_final $cxx
 279     set cxxlibglossflags  [libgloss_link_flags]
 280     set cxx_final [concat $cxx_final $cxxlibglossflags]
 281     set cxx_final [concat $cxx_final $cxxflags]
 282     set cxx_final [concat $cxx_final $includes]
 283
 284     lappend options "compiler=$cxx_final"
 285
 286     # Picks up the freshly-built testsuite library corresponding to the
 287     # multilib under test.
 288     lappend options "ldflags=-L${blddir}/testsuite"
 289     lappend options "libs=-lv3test"
 290
 291     return [target_compile $source $dest $type $options]
 292 }
 293
 294
 295 # Called once, from libstdc++/normal.exp.
 296 proc v3-list-tests { filename } {
 297     global srcdir
 298     global blddir
 299
 300     set tests_file "${blddir}/testsuite/${filename}"
 301     set sfiles ""
 302
 303     verbose -log "In v3-list-tests"
 304     verbose -log "blddir = ${blddir}"
 305     verbose -log "tests_file = $tests_file"
 306
 307     # If there is a testsuite_file, use it.
 308     if { [file exists $tests_file] } {
 309         set f [open $tests_file]
 310         while { ! [eof $f] } {
 311             set t [gets $f]
 312             if { [string length "$t"] != 0 } {
 313                 lappend sfiles  ${srcdir}/${t}
 314             }
 315         }
 316         close $f
 317     } else {
 318         verbose "cannot open $tests_file"
 319     }
 320     return $sfiles
 321 }