libstdc++-v3/testsuite/lib/libstdc++.exp

   1 # libstdc++ "tool init file" for DejaGNU
   2
   3 # Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19
  20 # Define callbacks and load other libraries.  This file is loaded relatively
  21 # early, and before any other file we write ourselves.  "load_lib" will
  22 # find anything in the DejaGNU installation tree, or in our lib directory.
  23 # "load_gcc_lib" will search the core compiler's .exp collection instead.
  24 #
  25 # The naming rule is that dg.exp looks for "tool-" and runtest.exp looks
  26 # for "tool_" when finding callbacks.  Utility routines we define for
  27 # our callbacks begin with "v3-".
  28 #
  29 # libstdc++_* callbacks we don't define, but could:
  30 # ..._option_help           prints additional --help output
  31 # ..._option_proc (--foo)   process our own options
  32 # ..._init (normal.exp)     called once per test file
  33 # ..._finish                bracketing function for libstdc++_init
  34 # ...-dg-prune              removing output text, see top of system dg.exp
  35 #
  36 # Useful hook:  if ${hostname}_init exists, it will be called, almost
  37 # the last thing before testing begins.  This can be defined in, e.g.,
  38 # ~/.dejagnurc or $DEJAGNU.
  39
  40 proc load_gcc_lib { filename } {
  41     global srcdir
  42     load_file $srcdir/../../gcc/testsuite/lib/$filename
  43 }
  44
  45 # system routines
  46 load_lib dg.exp
  47 load_lib libgloss.exp
  48 # compiler routines, then ours
  49 load_gcc_lib target-supports.exp
  50 load_lib prune.exp
  51 load_lib dg-options.exp
  52 load_gcc_lib target-libpath.exp
  53 load_gcc_lib wrapper.exp
  54
  55 # Useful for debugging.  Pass the name of a variable and the verbosity
  56 # threshold (number of -v's on the command line).
  57 proc v3track { var n } {
  58     upvar $var val
  59     verbose "++ $var is $val" $n
  60 }
  61
  62 # Called by v3-init below.  "Static" to this file.
  63 proc v3-copy-files {srcfiles} {
  64     foreach f $srcfiles {
  65         if { [catch { set symlink [file readlink $f] } x] } then {
  66             remote_download target $f
  67         } else {
  68             if { [regexp "^/" "$symlink"] } then {
  69                 remote_download target $symlink
  70             } else {
  71                 set dirname [file dirname $f]
  72                 remote_download target $dirname/$symlink
  73             }
  74         }
  75     }
  76 }
  77
  78 # Called once, during runtest.exp setup.
  79 proc libstdc++_init { testfile } {
  80     global env
  81     global srcdir blddir objdir tool_root_dir
  82     global cxx
  83     global includes
  84     global gluefile wrap_flags
  85     global ld_library_path
  86     global target_triplet
  87
  88     # We set LC_ALL and LANG to C so that we get the same error messages as expected.
  89     setenv LC_ALL C
  90     setenv LANG C
  91
  92     set blddir [lookfor_file [get_multilibs] libstdc++-v3]
  93     set flags_file "${blddir}/scripts/testsuite_flags"
  94     v3track flags_file 2
  95
  96     # If a test doesn't have special options, use DEFAULT_CXXFLAGS.
  97     # Use this variable if the behavior
  98     #   1) only applies to libstdc++ testing
  99     #   2) might need to be negated
 100     # In particular, some tests have to be run without precompiled
 101     # headers, or without assertions.
 102     global DEFAULT_CXXFLAGS
 103     if ![info exists DEFAULT_CXXFLAGS] then {
 104         # Set up includes for stdc++.h.gch, the precompiled header file.
 105         if { [file exists $flags_file] } {
 106             set cxxpchflags [exec sh $flags_file --cxxpchflags]
 107         } else {
 108             set cxxpchflags ""
 109         }
 110         set DEFAULT_CXXFLAGS " ${cxxpchflags}"
 111
 112         # Host specific goo here.
 113         if { [string match "powerpc-*-darwin*" $target_triplet] } {
 114             append DEFAULT_CXXFLAGS " -multiply_defined suppress"
 115         }
 116     }
 117     v3track DEFAULT_CXXFLAGS 2
 118
 119     # By default, we assume we want to run program images.
 120     global dg-do-what-default
 121     set dg-do-what-default run
 122
 123     # Copy any required data files.
 124     v3-copy-files [glob -nocomplain "$srcdir/data/*.tst"]
 125     v3-copy-files [glob -nocomplain "$srcdir/data/*.txt"]
 126
 127     # Locate libgcc.a so we don't need to account for different values of
 128     # SHLIB_EXT on different platforms
 129     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 130     if {$gccdir != ""} {
 131         set gccdir [file dirname $gccdir]
 132     }
 133     v3track gccdir 3
 134
 135     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 136     set ld_library_path ""
 137     append ld_library_path ":${gccdir}"
 138     set compiler ${gccdir}/g++
 139     if { [is_remote host] == 0 && [which $compiler] != 0 } {
 140         foreach i "[exec [which $compiler] --print-multi-lib]" {
 141             set mldir ""
 142             regexp -- "\[a-z0-9=/\.-\]*;" $i mldir
 143             set mldir [string trimright $mldir "\;@"]
 144             if { "$mldir" == "." } {
 145                 continue
 146             }
 147             if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 148                 append ld_library_path ":${gccdir}/${mldir}"
 149             }
 150         }
 151     }
 152     append ld_library_path ":${blddir}/src/.libs"
 153
 154     set_ld_library_path_env_vars
 155     if [info exists env(LD_LIBRARY_PATH)] {
 156       verbose -log "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
 157     }
 158
 159     # Do a bunch of handstands and backflips for cross compiling and
 160     # finding simulators...
 161     if [is_remote host] {
 162         set header [remote_download host ${blddir}/testsuite/testsuite_hooks.h]
 163         if { $header == "" } {
 164             verbose -log "Unable to download ${blddir}/testsuite/testsuite_hooks.h to host."
 165             return "untested"
 166         }
 167       set cxx [transform "g++"]
 168       set includes "-I./"
 169     } else {
 170         # If we find a testsuite_flags file, we're testing in the build dir.
 171         if { [file exists $flags_file] } {
 172             set cxx [exec sh $flags_file --build-cxx]
 173             set includes [exec sh $flags_file --build-includes]
 174         } else {
 175             set cxx [transform "g++"]
 176             set includes "-I${srcdir}"
 177         }
 178     }
 179
 180     libstdc++_maybe_build_wrapper "${objdir}/testglue.o"
 181 }
 182
 183 # Callback for cleanup routines.
 184 proc libstdc++_exit { } {
 185     global gluefile;
 186
 187     if [info exists gluefile] {
 188         file_on_build delete $gluefile;
 189         unset gluefile;
 190     }
 191 }
 192
 193 # Callback from system dg-test.
 194 proc libstdc++-dg-test { prog do_what extra_tool_flags } {
 195     # Set up the compiler flags, based on what we're going to do.
 196     switch $do_what {
 197         "preprocess" {
 198             set compile_type "preprocess"
 199             set output_file "[file rootname [file tail $prog]].i"
 200         }
 201         "compile" {
 202             set compile_type "assembly"
 203             set output_file "[file rootname [file tail $prog]].s"
 204         }
 205         "assemble" {
 206             set compile_type "object"
 207             set output_file "[file rootname [file tail $prog]].o"
 208         }
 209         "link" {
 210             set compile_type "executable"
 211             set output_file "./[file rootname [file tail $prog]].exe"
 212         }
 213         "run" {
 214             set compile_type "executable"
 215             # FIXME: "./" is to cope with "." not being in $PATH.
 216             # Should this be handled elsewhere?
 217             # YES.
 218             set output_file "./[file rootname [file tail $prog]].exe"
 219             # This is the only place where we care if an executable was
 220             # created or not.  If it was, dg.exp will try to run it.
 221             remote_file build delete $output_file;
 222         }
 223         default {
 224             perror "$do_what: not a valid dg-do keyword"
 225             return ""
 226         }
 227     }
 228     set options ""
 229     if { $extra_tool_flags != "" } {
 230         lappend options "additional_flags=$extra_tool_flags"
 231     }
 232
 233     # There is a libstdc++_compile made for us by default (via the tool-
 234     # and-target file), but the defaults are lacking in goodness.
 235     set comp_output [v3_target_compile "$prog" "$output_file" "$compile_type" $options];
 236     set comp_output [ prune_g++_output $comp_output ];
 237
 238     return [list $comp_output $output_file]
 239 }
 240
 241 # Called from libstdc++-dg-test above.  Calls back into system's
 242 # target_compile to actually do the work.
 243 proc v3_target_compile { source dest type options } {
 244     global gluefile
 245     global wrap_flags
 246     global cxx
 247     global cxxflags
 248     global includes
 249     global objdir
 250
 251     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 252         lappend options "libs=${gluefile}"
 253         lappend options "ldflags=${wrap_flags}"
 254     }
 255
 256     set cxx_final $cxx
 257     set cxxlibglossflags  [libgloss_link_flags]
 258     set cxx_final [concat $cxx_final $cxxlibglossflags]
 259     set cxx_final [concat $cxx_final $cxxflags]
 260     set cxx_final [concat $cxx_final $includes]
 261
 262     lappend options "compiler=$cxx_final"
 263
 264     # Picks up the freshly-built testsuite library corresponding to the
 265     # multilib under test.
 266     lappend options "ldflags=-L${objdir}"
 267     lappend options "libs=-lv3test"
 268
 269     return [target_compile $source $dest $type $options]
 270 }
 271
 272
 273 # This is the equivalent of the Tcl 8.4 "lsearch -all -inline" except
 274 # slower
 275 proc lsearch_all_inline {listData pattern} {
 276     set result [list]
 277     foreach item $listData {
 278         if {[string match $pattern $item]} {
 279             lappend result $item
 280         }
 281     }
 282     return $result
 283 }
 284
 285 # This is the equivalent of the Tcl 8.4 "lsearch -all -inline -not"
 286 # except slower
 287 proc lsearch_all_inline_not {listData pattern} {
 288     set result [list]
 289     foreach item $listData {
 290         if {! [string match $pattern $item]} {
 291             lappend result $item
 292         }
 293     }
 294     return $result
 295 }
 296
 297 # Called once, from libstdc++/normal.exp.
 298 proc v3-list-tests { filename } {
 299     global srcdir tests_to_ignore
 300
 301     set sfiles [lsort [ find $srcdir "*.cc"] ]
 302     set sfiles [ lsearch_all_inline $sfiles "$srcdir/*/*.cc" ]
 303     foreach pattern $tests_to_ignore {
 304         set sfiles [ lsearch_all_inline_not $sfiles $pattern ]
 305     }
 306     if { $filename == "testsuite_files" } {
 307         set sfiles [ lsearch_all_inline_not $sfiles *_xin* ]
 308         set sfiles [ lsearch_all_inline_not $sfiles *performance* ]
 309     } elseif { $filename == "testsuite_files_interactive" } {
 310         set sfiles [ lsearch_all_inline $sfiles *_xin* ]
 311     } elseif { $filename == "testsuite_files_performance" } {
 312         set sfiles [ lsearch_all_inline $sfiles *performance* ]
 313     } else {
 314         verbose "cannot compute list of tests named $filename"
 315         set sfiles [list]
 316     }
 317     return $sfiles
 318 }