libstdc++-v3/configure.in

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal, autoconf, autoheader, automake
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(src/complex.cc)
   6 AC_CONFIG_AUX_DIR(..)
   7
   8 # Gets and sets build, host, target, *_vendor, *_cpu, *_os, etc.
   9 AC_CANONICAL_SYSTEM
  10
  11 # We use these options to decide which functions to include.
  12 AC_ARG_WITH(target-subdir,
  13 [  --with-target-subdir=SUBDIR
  14                            configuring in a subdirectory])
  15 AC_ARG_WITH(cross-host,
  16 [  --with-cross-host=HOST  configuring with a cross compiler])
  17
  18 GLIBCPP_CONFIGURE(.)
  19 AC_LIBTOOL_DLOPEN
  20 AM_PROG_LIBTOOL
  21 GLIBCPP_CHECK_GNU_MAKE
  22   if test "x$_cv_gnu_make_command" = "x"; then
  23     AC_MSG_ERROR([GNU make not found. Please install it or correct your path.])
  24   fi
  25 AM_CONFIG_HEADER(config.h)
  26
  27 # Check for c++ or library specific bits that don't require linking.
  28 GLIBCPP_CHECK_COMPILER_VERSION
  29 GLIBCPP_CHECK_CPU
  30 GLIBCPP_CHECK_OS
  31
  32 AC_CACHE_SAVE
  33
  34 # Enable all the crazy c++ stuff.  C_MBCHAR must come early.
  35 GLIBCPP_ENABLE_DEBUG($USE_MAINTAINER_MODE)
  36 GLIBCPP_ENABLE_C_MBCHAR([yes])
  37 GLIBCPP_ENABLE_CSTDIO
  38 GLIBCPP_ENABLE_LONG_LONG(yes)
  39 GLIBCPP_ENABLE_SHADOW(no)
  40 GLIBCPP_ENABLE_THREADS
  41 GLIBCPP_ENABLE_ATOMICITY
  42 GLIBCPP_ENABLE_CXX_FLAGS([none])
  43
  44
  45 if test -n "$with_cross_host"; then
  46
  47   # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  48   # may not work correctly, because the compiler may not be able to
  49   # link executables.
  50
  51   xcompiling=1
  52   NATIVE=no
  53   # If Canadian cross, then don't pick up tools from the build
  54   # directory.
  55   if test "$build" != "$with_cross_host"; then
  56     CANADIAN=yes
  57     NULL_TARGET=yes
  58   else
  59     CANADIAN=no
  60     NULL_TARGET=no
  61   fi
  62
  63   case "$target_alias" in
  64     *-wince-*)
  65         # Configure for Microsoft Windows CE, or whatever they are
  66         # currently calling it.
  67         AC_DEFINE(HAVE_FLOAT_H)
  68
  69         AC_DEFINE(HAVE__FINITE)
  70         AC_DEFINE(HAVE__ISNAN)
  71         AC_DEFINE(HAVE__COPYSIGN)
  72         AC_DEFINE(HAVE__FPCLASS)
  73         AC_DEFINE(HAVE_MODF)
  74
  75         ctype_include_dir="config/os/wince"
  76         AC_LINK_FILES($ctype_include_dir/bits/ctype_base.h, bits/ctype_base.h)
  77         AC_LINK_FILES($ctype_include_dir/bits/ctype_inline.h, \
  78         bits/ctype_inline.h)
  79         AC_LINK_FILES($ctype_include_dir/bits/ctype_noninline.h, \
  80         bits/ctype_noninline.h)
  81
  82
  83         AC_DEFINE(_GLIBCPP_NEED_MBSTATE_T)
  84
  85         AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
  86         AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
  87         ;;
  88     *)
  89         # We assume newlib.  This lets us hard-code the functions we know
  90         # we'll have.
  91         AC_DEFINE(HAVE_FINITE)
  92         AC_DEFINE(HAVE_ISNAN)
  93         AC_DEFINE(HAVE_ISNANF)
  94         AC_DEFINE(HAVE_ISINF)
  95         AC_DEFINE(HAVE_ISINFF)
  96
  97         ctype_include_dir="config/os/newlib"
  98         AC_LINK_FILES($ctype_include_dir/bits/ctype_base.h, bits/ctype_base.h)
  99         AC_LINK_FILES($ctype_include_dir/bits/ctype_inline.h, \
 100         bits/ctype_inline.h)
 101         AC_LINK_FILES($ctype_include_dir/bits/ctype_noninline.h, \
 102         bits/ctype_noninline.h)
 103
 104         AC_DEFINE(_GLIBCPP_NEED_MBSTATE_T)
 105
 106         AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
 107         AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
 108         # need to ceck for faster f versions of math functions, ie sinf?
 109         ;;
 110   esac
 111 else
 112
 113   # We are being configured natively. We can do more elaborate tests
 114   # that include AC_TRY_COMPILE now, as the linker is assumed to be
 115   # working.
 116
 117   xcompiling=0
 118   NATIVE=yes
 119   CANADIAN=no
 120   NULL_TARGET=no
 121
 122   # Check for available headers.
 123   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 124   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h])
 125
 126   GLIBCPP_CHECK_COMPILER_FEATURES
 127   GLIBCPP_CHECK_LINKER_FEATURES
 128   GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 129   GLIBCPP_CHECK_MATH_SUPPORT
 130   GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 131   GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT
 132   AC_CACHE_SAVE
 133   GLIBCPP_CHECK_WCHAR_T_SUPPORT
 134   GLIBCPP_CHECK_CTYPE
 135
 136   AC_FUNC_MMAP
 137   AC_CHECK_HEADERS(gconv.h)
 138 fi
 139
 140 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 141 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 142 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 143 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 144
 145 AC_LC_MESSAGES
 146
 147 if test "${multilib}" = "yes"; then
 148   multilib_arg="--enable-multilib"
 149 else
 150   multilib_arg=
 151 fi
 152
 153
 154 # Generate the various Makefiles, include files, and scripts.
 155
 156 # This helps subvert libstdcxx_interface, as calculated by devo/config.if
 157 # Needed so that g++ can find the correct include subdir automatically.
 158 INTERFACE=v3
 159
 160 # Check for the interface version number for specifying where header
 161 # files are installed, if a version number is provided.
 162 AC_MSG_CHECKING([for interface version number])
 163 libstdcxx_interface=$INTERFACE
 164 AC_MSG_RESULT($libstdcxx_interface)
 165 AC_SUBST(libstdcxx_interface)
 166
 167 # Process the option --with-gxx-include-dir=<path to include-files directory>
 168 AC_MSG_CHECKING([for --with-gxx-include-dir])
 169 AC_ARG_WITH(gxx-include-dir,
 170 [ --with-gxx-include-dir  the installation directory for include files],
 171 [case "${withval}" in
 172   yes)
 173     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
 174     gxx_include_dir=no
 175     ;;
 176   no)
 177     gxx_include_dir=no
 178     ;;
 179   *)
 180     gxx_include_dir=${withval}
 181     ;;
 182 esac], [gxx_include_dir=no])
 183 AC_MSG_RESULT($gxx_include_dir)
 184 AC_SUBST(gxx_include_dir)
 185 AM_CONDITIONAL(GXX_INCLUDE_DIR, test x${gxx_include_dir} != xno)
 186
 187 # Process the option "--enable-version-specific-runtime-libs"
 188 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 189 AC_ARG_ENABLE(version-specific-runtime-libs,
 190 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 191 [  version_specific_libs=yes
 192 # Need the gcc compiler version to know where to install libraries
 193 # and header files if --enable-version-specific-runtime-libs option
 194 # is selected.
 195 changequote(,)dnl
 196 gcc_tmp=`grep version_string ${srcdir}/../gcc/version.c | awk '{print $6}'`
 197 gcc_num=`echo ${gcc_tmp} | sed 's/\"//g'`
 198 #gcc_date=`grep version_string ${srcdir}/../gcc/version.c | awk '{print $7}'`
 199 #gcc_version=$gcc_num-$gcc_date
 200 gcc_version=$gcc_num
 201 changequote([,])dnl
 202 AC_SUBST(gcc_version)
 203 ],version_specific_libs=no)
 204 AC_MSG_RESULT($version_specific_libs)
 205 if test x${version_specific_libs} = xyes; then
 206   AM_CONDITIONAL(VERSION_SPECIFIC_LIBS, test x${version_specific_libs} = xyes)
 207   AC_MSG_WARN(version specific directory is: $gcc_version)
 208 fi
 209
 210
 211
 212 # Export all the include and flag information to makefiles.
 213 GLIBCPP_EXPORT_INCLUDES
 214 GLIBCPP_EXPORT_FLAGS
 215
 216 # NB: Multilibs need MULTISUBDIR defined correctly in src/Makefile.am
 217 # so that multilib installs will end up installed in the correct
 218 # place. To work around this not being passed down from config-ml.in
 219 # -> top_srcdir/Makefile.am -> top_srcdir/src/Makefile.am, manually
 220 # append it here.
 221 AC_OUTPUT(mkcheck Makefile src/Makefile libmath/Makefile libio/Makefile libsupc++/Makefile,
 222 [if test -n "$CONFIG_FILES"; then
 223   ac_file=Makefile . ${glibcpp_basedir}/../config-ml.in
 224   grep '^MULTISUBDIR =' Makefile >> src/Makefile
 225 fi
 226 chmod +x mkcheck
 227 ],
 228 srcdir=${srcdir}
 229 host=${host}
 230 target=${target}
 231 with_multisubdir=${with_multisubdir}
 232 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 233 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 234 glibcpp_basedir=${glibcpp_basedir}
 235 CC="${CC}"
 236 CXX="${CXX}"
 237 )
 238
 239
 240 blddir=`pwd`
 241 # Generate bits/c++config.h
 242 # NB: This must be the first generated file as others include it. . .
 243 AC_OUTPUT_COMMANDS([$srcdir/mkc++config $blddir $srcdir])
 244
 245 # Generate bits/std_limits.h and src/limitsMEMBERS.cc
 246 if test ! -f stamp-limits; then
 247   AC_OUTPUT_COMMANDS([$srcdir/mknumeric_limits $blddir $srcdir $xcompiling])
 248   touch stamp-limits
 249 fi
 250
 251
 252 # Sanity checking & User-visible messages.
 253 # Checks down here, otherwise they get scrolled off before
 254 # the user will notice.
 255 ### warnings removed; none were applicable anymore
 256
 257
 258 # Trying to get more people to read documentation.  Possibly remove
 259 # check and warn all the time. There is no "informational" AC_MSG_
 260 # macro, so these are going to be printed even when --quiet/--silent
 261 # is given.
 262 if test ! -f stamp-sanity-warned; then
 263   touch stamp-sanity-warned
 264   echo ""
 265   echo "Please make certain that you read the installation information here:"
 266   echo "  faster => ${srcdir}/docs/install.html"
 267   echo "  slower => <URL:http://sources.redhat.com/libstdc++/install.html>"
 268   echo ""
 269   echo "and the configuration information here:"
 270   echo "  faster => ${srcdir}/docs/configopts.html"
 271   echo "  slower => <URL:http://sources.redhat.com/libstdc++/configopts.html>"
 272   echo ""
 273   echo "before proceeding with ${_cv_gnu_make_command}."
 274   echo ""
 275 fi
 276
 277