libstdc++-v3/configure.in

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal, autoconf, autoheader, automake
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(src/ios.cc)
   6
   7 PACKAGE=libstdc++
   8 MAJOR_VERSION=3
   9 MINOR_VERSION=1
  10 MICRO_VERSION=0
  11 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
  12 AC_SUBST(PACKAGE)
  13 AC_SUBST(VERSION)
  14
  15 # Gets and sets build, host, target, *_vendor, *_cpu, *_os, etc.
  16 # AC 2.50 sets target_alias iff the user specified --target, but we use it
  17 # everywhere, so we set it here just to be sure.
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$target}
  20 AC_SUBST(target_alias)
  21
  22 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  23 AM_CONFIG_HEADER(config.h)
  24
  25 # Runs configure.host and configure.target, as well as finds CC, CXX
  26 # and assorted other critical bits. Have to run this before the
  27 # GLIBCPP_ENABLE_* macros below.
  28 GLIBCPP_CONFIGURE(.)
  29
  30 AC_LIBTOOL_DLOPEN
  31 AM_PROG_LIBTOOL
  32 AC_SUBST(enable_shared)
  33 AC_SUBST(enable_static)
  34
  35 AM_CONFIG_HEADER(config.h testsuite/testsuite_hooks.h)
  36
  37 # Check for c++ or library specific bits that don't require linking.
  38 #GLIBCPP_CHECK_COMPILER_VERSION
  39 GLIBCPP_CHECK_GNU_MAKE
  40
  41 # Enable all the variable C++ stuff.  C_MBCHAR must come early.
  42 GLIBCPP_ENABLE_DEBUG($USE_MAINTAINER_MODE)
  43 GLIBCPP_ENABLE_CSTDIO
  44 GLIBCPP_ENABLE_CLOCALE
  45 GLIBCPP_ENABLE_C_MBCHAR([yes])
  46 GLIBCPP_ENABLE_C99([yes])
  47 GLIBCPP_ENABLE_LONG_LONG([yes])
  48 GLIBCPP_ENABLE_CHEADERS([c_std])
  49 GLIBCPP_ENABLE_THREADS
  50 GLIBCPP_ENABLE_CXX_FLAGS([none])
  51 GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
  52
  53
  54 if test -n "$with_cross_host" || test x"$build" != x"$host"; then
  55
  56   # We are being configured with some form of cross compiler.
  57   # mknumeric_limits may not work correctly, either because the
  58   # compiler may not run on this machine, may not be able to link
  59   # executables, or may produce executables we can't run on this
  60   # machine. Thus, just use the pre-generated include/bits/limits_generic.h
  61   GLIBCPP_IS_CROSS_COMPILING=1
  62
  63   # If Canadian cross, then don't pick up tools from the build
  64   # directory.
  65   if test -n "$with_cross_host" && test x"$build" != x"$with_cross_host"; then
  66     CANADIAN=yes
  67   else
  68     CANADIAN=no
  69   fi
  70
  71   case "$target_alias" in
  72     *-linux*)
  73         # Construct linux crosses by hand, eliminating bits that need ld...
  74         # Check for available headers.
  75         AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h \
  76         machine/endian.h machine/param.h sys/machine.h fp.h locale.h \
  77         float.h inttypes.h])
  78
  79         # GLIBCPP_CHECK_COMPILER_FEATURES
  80         SECTION_FLAGS='-ffunction-sections -fdata-sections'
  81         AC_SUBST(SECTION_FLAGS)
  82         GLIBCPP_CHECK_LINKER_FEATURES
  83         # GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
  84         # GLIBCPP_CHECK_MATH_SUPPORT
  85         AC_DEFINE(HAVE_ACOSF)
  86         AC_DEFINE(HAVE_ASINF)
  87         AC_DEFINE(HAVE_ATAN2F)
  88         AC_DEFINE(HAVE_ATANF)
  89         AC_DEFINE(HAVE_CEILF)
  90         AC_DEFINE(HAVE_COPYSIGN)
  91         AC_DEFINE(HAVE_COPYSIGNF)
  92         AC_DEFINE(HAVE_COSF)
  93         AC_DEFINE(HAVE_COSHF)
  94         AC_DEFINE(HAVE_EXPF)
  95         AC_DEFINE(HAVE_FABSF)
  96         AC_DEFINE(HAVE_FINITE)
  97         AC_DEFINE(HAVE_FINITEF)
  98         AC_DEFINE(HAVE_FLOORF)
  99         AC_DEFINE(HAVE_FMODF)
 100         AC_DEFINE(HAVE_FREXPF)
 101         AC_DEFINE(HAVE_ISINF)
 102         AC_DEFINE(HAVE_ISINFF)
 103         AC_DEFINE(HAVE_ISNAN)
 104         AC_DEFINE(HAVE_ISNANF)
 105         AC_DEFINE(HAVE_LDEXPF)
 106         AC_DEFINE(HAVE_LOG10F)
 107         AC_DEFINE(HAVE_LOGF)
 108         AC_DEFINE(HAVE_MODFF)
 109         AC_DEFINE(HAVE_POWF)
 110         AC_DEFINE(HAVE_SINCOS)
 111         AC_DEFINE(HAVE_SINCOSF)
 112         AC_DEFINE(HAVE_SINF)
 113         AC_DEFINE(HAVE_SINHF)
 114         AC_DEFINE(HAVE_SQRTF)
 115         AC_DEFINE(HAVE_TANF)
 116         AC_DEFINE(HAVE_TANHF)
 117
 118         # At some point, we should differentiate between architectures
 119         # like x86, which have long double versions, and alpha/powerpc/etc.,
 120         # which don't. For the time being, punt.
 121         if test x"long_double_math_on_this_cpu" = x"yes"; then
 122           AC_DEFINE(HAVE_ACOSL)
 123           AC_DEFINE(HAVE_ASINL)
 124           AC_DEFINE(HAVE_ATAN2L)
 125           AC_DEFINE(HAVE_ATANL)
 126           AC_DEFINE(HAVE_CEILL)
 127           AC_DEFINE(HAVE_COPYSIGNL)
 128           AC_DEFINE(HAVE_COSL)
 129           AC_DEFINE(HAVE_COSHL)
 130           AC_DEFINE(HAVE_EXPL)
 131           AC_DEFINE(HAVE_FABSL)
 132           AC_DEFINE(HAVE_FINITEL)
 133           AC_DEFINE(HAVE_FLOORL)
 134           AC_DEFINE(HAVE_FMODL)
 135           AC_DEFINE(HAVE_FREXPL)
 136           AC_DEFINE(HAVE_ISINFL)
 137           AC_DEFINE(HAVE_ISNANL)
 138           AC_DEFINE(HAVE_LDEXPL)
 139           AC_DEFINE(HAVE_LOG10L)
 140           AC_DEFINE(HAVE_LOGL)
 141           AC_DEFINE(HAVE_MODFL)
 142           AC_DEFINE(HAVE_POWL)
 143           AC_DEFINE(HAVE_SINCOSL)
 144           AC_DEFINE(HAVE_SINL)
 145           AC_DEFINE(HAVE_SINHL)
 146           AC_DEFINE(HAVE_SQRTL)
 147           AC_DEFINE(HAVE_TANL)
 148           AC_DEFINE(HAVE_TANHL)
 149         fi
 150         GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 151         GLIBCPP_CHECK_WCHAR_T_SUPPORT
 152         os_include_dir="config/os/gnu-linux"
 153         # GLIBCPP_CHECK_STDLIB_SUPPORT
 154         AC_DEFINE(HAVE_STRTOF)
 155         AC_DEFINE(HAVE_STRTOLD)
 156         # AC_FUNC_MMAP
 157         AC_DEFINE(HAVE_MMAP)
 158         ;;
 159     *)
 160         # We assume newlib.  This lets us hard-code the functions we know
 161         # we'll have.
 162         AC_DEFINE(HAVE_FINITE)
 163         AC_DEFINE(HAVE_ISNAN)
 164         AC_DEFINE(HAVE_ISNANF)
 165         AC_DEFINE(HAVE_ISINF)
 166         AC_DEFINE(HAVE_ISINFF)
 167
 168         os_include_dir="config/os/newlib"
 169
 170         # need to check for faster f versions of math functions, ie sinf?
 171         ;;
 172   esac
 173 else
 174
 175   # We are being configured natively. We can do more elaborate tests
 176   # that include AC_TRY_COMPILE now, as the linker is assumed to be
 177   # working.
 178   GLIBCPP_IS_CROSS_COMPILING=0
 179   CANADIAN=no
 180
 181   # Check for available headers.
 182   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 183   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h])
 184
 185   GLIBCPP_CHECK_COMPILER_FEATURES
 186   GLIBCPP_CHECK_LINKER_FEATURES
 187   GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 188   GLIBCPP_CHECK_MATH_SUPPORT
 189   GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 190   GLIBCPP_CHECK_WCHAR_T_SUPPORT
 191   GLIBCPP_CHECK_STDLIB_SUPPORT
 192
 193   AC_TRY_COMPILE([
 194 #include <setjmp.h>
 195 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 196 [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.  ])])
 197
 198   AC_FUNC_MMAP
 199
 200 fi
 201
 202 # Enable/configure some pieces which may require knowledge about the
 203 # compiler situation (native/cross), which we just finished discovering.
 204 GLIBCPP_CONFIGURE_TESTSUITE
 205
 206 # Propagate the target-specific source directories through the build chain.
 207 OS_INC_SRCDIR=$os_include_dir/bits
 208 ATOMICITY_INC_SRCDIR=$ATOMICITYH/bits
 209 AC_SUBST(OS_INC_SRCDIR)
 210 AC_SUBST(ATOMICITY_INC_SRCDIR)
 211
 212 # Set up cross-compile flags
 213 AC_SUBST(GLIBCPP_IS_CROSS_COMPILING)
 214 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 215
 216 AC_CACHE_SAVE
 217 AC_LC_MESSAGES
 218
 219 if test "${multilib}" = "yes"; then
 220   multilib_arg="--enable-multilib"
 221 else
 222   multilib_arg=
 223 fi
 224
 225 # Needed so that g++ can find the correct include subdir automatically.
 226 INTERFACE=v3
 227
 228 # Export all the install information
 229 GLIBCPP_EXPORT_INSTALL_INFO
 230
 231 # Export all the include and flag information to makefiles.
 232 GLIBCPP_EXPORT_INCLUDES
 233 GLIBCPP_EXPORT_FLAGS
 234
 235 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 236    grep "enable shared" > /dev/null; then
 237   LIBSUPCXX_PICFLAGS=-prefer-pic
 238 else
 239   LIBSUPCXX_PICFLAGS=
 240 fi
 241 AC_SUBST(LIBSUPCXX_PICFLAGS)
 242
 243 # Generate the various Makefiles, include files, and scripts.
 244 # NB: Multilibs need MULTISUBDIR defined correctly in src/Makefile.am
 245 # and libsupc++/Makefile.am so that multilib installs will end up
 246 # installed in the correct place. To work around this not being passed
 247 # down from config-ml.in -> top_srcdir/Makefile.am ->
 248 # top_srcdir/{src,libsupc++}/Makefile.am, manually append it here.
 249 AC_OUTPUT(Makefile \
 250     include/Makefile src/Makefile \
 251     libmath/Makefile libio/Makefile libsupc++/Makefile \
 252     po/Makefile intl/Makefile testsuite/Makefile mkcheck testsuite_flags,
 253 [if test -n "$CONFIG_FILES"; then
 254   ac_file=Makefile . ${glibcpp_basedir}/../config-ml.in
 255   grep '^MULTISUBDIR =' Makefile >> src/Makefile
 256   grep '^MULTISUBDIR =' Makefile >> libsupc++/Makefile
 257 fi
 258 chmod +x mkcheck
 259 chmod +x testsuite_flags
 260 ],
 261 srcdir=${srcdir}
 262 host=${host}
 263 target=${target}
 264 with_multisubdir=${with_multisubdir}
 265 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 266 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 267 glibcpp_basedir=${glibcpp_basedir}
 268 CC="${CC}"
 269 CXX="${CXX}"
 270 )
 271
 272
 273 # Sanity checking & User-visible messages.
 274 # Checks down here, otherwise they get scrolled off before
 275 # the user will notice.
 276
 277 # Trying to get more people to read documentation.  Possibly remove
 278 # check and warn all the time. There is no "informational" AC_MSG_
 279 # macro, so these are going to be printed even when --quiet/--silent
 280 # is given.
 281 if test ! -f stamp-sanity-warned; then
 282   touch stamp-sanity-warned
 283   echo ""
 284   echo "Please make certain that you read the installation information here:"
 285   echo "  faster => ${srcdir}/docs/install.html"
 286   echo "  slower => <URL:http://gcc.gnu.org/onlinedocs/libstdc++/install.html>"
 287   echo ""
 288   echo "and the configuration information here:"
 289   echo "  faster => ${srcdir}/docs/configopts.html"
 290   echo "  slower => <URL:http://gcc.gnu.org/onlinedocs/libstdc++/configopts.html>"
 291   echo ""
 292   echo "before proceeding with ${_cv_gnu_make_command}."
 293   echo ""
 294 fi