libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:11:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 if test "x${with_newlib}" != "xyes"; then
  86   AC_LIBTOOL_DLOPEN
  87 fi
  88 AM_PROG_LIBTOOL
  89 AC_SUBST(enable_shared)
  90 AC_SUBST(enable_static)
  91
  92 # Possibly disable most of the library.
  93 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  94 ## than just ignoring the results.  Faster /and/ more correct, win win.
  95 GLIBCXX_ENABLE_HOSTED
  96
  97 # Enable compiler support that doesn't require linking.
  98 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  99 GLIBCXX_ENABLE_PCH($is_hosted)
 100 GLIBCXX_ENABLE_THREADS
 101 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 102
 103 # Checks for compiler support that doesn't require linking.
 104 GLIBCXX_CHECK_COMPILER_FEATURES
 105
 106 # Enable all the variable C++ runtime options that don't require linking.
 107 GLIBCXX_ENABLE_CSTDIO
 108 GLIBCXX_ENABLE_CLOCALE
 109 GLIBCXX_ENABLE_ALLOCATOR
 110 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 111 GLIBCXX_ENABLE_LONG_LONG([yes])
 112 GLIBCXX_ENABLE_WCHAR_T([yes])
 113 GLIBCXX_ENABLE_C99([yes])
 114 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 115 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 116 GLIBCXX_ENABLE_DEBUG([no])
 117 GLIBCXX_ENABLE_PARALLEL([yes])
 118 GLIBCXX_ENABLE_CXX_FLAGS
 119 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 120
 121 # Checks for operating systems support that doesn't require linking.
 122 GLIBCXX_CHECK_SYSTEM_ERROR
 123
 124 # For the streamoff typedef.
 125 GLIBCXX_CHECK_INT64_T
 126
 127 # For LFS support.
 128 GLIBCXX_CHECK_LFS
 129
 130 # For showmanyc_helper().
 131 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 132 GLIBCXX_CHECK_POLL
 133 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 134
 135 # For xsputn_2().
 136 AC_CHECK_HEADERS(sys/uio.h)
 137 GLIBCXX_CHECK_WRITEV
 138
 139 # For C99 support to TR1.
 140 GLIBCXX_CHECK_C99_TR1
 141
 142 # For common values of EOF, SEEK_CUR, SEEK_END.
 143 GLIBCXX_CHECK_STDIO_MACROS
 144
 145 # For gettimeofday support.
 146 GLIBCXX_CHECK_GETTIMEOFDAY
 147
 148 # For clock_gettime support.
 149 # NB: The default is [no], because otherwise it requires linking.
 150 GLIBCXX_ENABLE_CLOCK_GETTIME([no])
 151
 152 # For gthread support
 153 GLIBCXX_CHECK_GTHREADS
 154
 155 # For nanosleep support
 156 GLIBCXX_CHECK_NANOSLEEP
 157
 158 AC_LC_MESSAGES
 159
 160 # Check for available headers.
 161 AC_CHECK_HEADERS([endian.h float.h fp.h ieeefp.h inttypes.h locale.h \
 162 machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 163 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 164 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 165 wchar.h wctype.h])
 166
 167 # Only do link tests if native. Else, hardcode.
 168 if $GLIBCXX_IS_NATIVE; then
 169
 170   # We can do more elaborate tests that assume a working linker.
 171   CANADIAN=no
 172
 173   GLIBCXX_CHECK_LINKER_FEATURES
 174   GLIBCXX_CHECK_MATH_SUPPORT
 175   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 176   GLIBCXX_CHECK_STDLIB_SUPPORT
 177
 178   # For /dev/random and /dev/urandom for TR1.
 179   GLIBCXX_CHECK_RANDOM_TR1
 180
 181   # For TLS support.
 182   GCC_CHECK_TLS
 183
 184   # For iconv support.
 185   AM_ICONV
 186
 187 else
 188
 189   # This lets us hard-code the functionality we know we'll have in the cross
 190   # target environment.  "Let" is a sugar-coated word placed on an especially
 191   # dull and tedious hack, actually.
 192   #
 193   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 194   # that involve linking, can't be used:
 195   #    "cannot open sim-crt0.o"
 196   #    "cannot open crt0.o"
 197   # etc.  All this is because there currently exists no unified, consistent
 198   # way for top level CC information to be passed down to target directories:
 199   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 200   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 201   # crosses can be removed.
 202
 203   # If Canadian cross, then don't pick up tools from the build directory.
 204   # Used only in GLIBCXX_EXPORT_INCLUDES.
 205   if test -n "$with_cross_host" &&
 206      test x"$build_alias" != x"$with_cross_host" &&
 207      test x"$build" != x"$target";
 208   then
 209     CANADIAN=yes
 210   else
 211     CANADIAN=no
 212   fi
 213
 214   # Construct crosses by hand, eliminating bits that need ld...
 215   # GLIBCXX_CHECK_MATH_SUPPORT
 216
 217   # First, test for "known" system libraries.  We may be using newlib even
 218   # on a hosted environment.
 219   if test "x${with_newlib}" = "xyes"; then
 220     os_include_dir="os/newlib"
 221     AC_DEFINE(HAVE_HYPOT)
 222
 223     # GLIBCXX_CHECK_STDLIB_SUPPORT
 224     AC_DEFINE(HAVE_STRTOF)
 225
 226     AC_DEFINE(HAVE_ACOSF)
 227     AC_DEFINE(HAVE_ASINF)
 228     AC_DEFINE(HAVE_ATAN2F)
 229     AC_DEFINE(HAVE_ATANF)
 230     AC_DEFINE(HAVE_CEILF)
 231     AC_DEFINE(HAVE_COPYSIGN)
 232     AC_DEFINE(HAVE_COPYSIGNF)
 233     AC_DEFINE(HAVE_COSF)
 234     AC_DEFINE(HAVE_COSHF)
 235     AC_DEFINE(HAVE_EXPF)
 236     AC_DEFINE(HAVE_FABSF)
 237     AC_DEFINE(HAVE_FLOORF)
 238     AC_DEFINE(HAVE_FMODF)
 239     AC_DEFINE(HAVE_FREXPF)
 240     AC_DEFINE(HAVE_LDEXPF)
 241     AC_DEFINE(HAVE_LOG10F)
 242     AC_DEFINE(HAVE_LOGF)
 243     AC_DEFINE(HAVE_MODFF)
 244     AC_DEFINE(HAVE_POWF)
 245     AC_DEFINE(HAVE_SINF)
 246     AC_DEFINE(HAVE_SINHF)
 247     AC_DEFINE(HAVE_SQRTF)
 248     AC_DEFINE(HAVE_TANF)
 249     AC_DEFINE(HAVE_TANHF)
 250
 251     AC_DEFINE(HAVE_ICONV)
 252   else
 253     GLIBCXX_CROSSCONFIG
 254   fi
 255
 256   # At some point, we should differentiate between architectures
 257   # like x86, which have long double versions, and alpha/powerpc/etc.,
 258   # which don't. For the time being, punt.
 259   if test x"long_double_math_on_this_cpu" = x"yes"; then
 260     AC_DEFINE(HAVE_ACOSL)
 261     AC_DEFINE(HAVE_ASINL)
 262     AC_DEFINE(HAVE_ATAN2L)
 263     AC_DEFINE(HAVE_ATANL)
 264     AC_DEFINE(HAVE_CEILL)
 265     AC_DEFINE(HAVE_COPYSIGNL)
 266     AC_DEFINE(HAVE_COSL)
 267     AC_DEFINE(HAVE_COSHL)
 268     AC_DEFINE(HAVE_EXPL)
 269     AC_DEFINE(HAVE_FABSL)
 270     AC_DEFINE(HAVE_FLOORL)
 271     AC_DEFINE(HAVE_FMODL)
 272     AC_DEFINE(HAVE_FREXPL)
 273     AC_DEFINE(HAVE_LDEXPL)
 274     AC_DEFINE(HAVE_LOG10L)
 275     AC_DEFINE(HAVE_LOGL)
 276     AC_DEFINE(HAVE_MODFL)
 277     AC_DEFINE(HAVE_POWL)
 278     AC_DEFINE(HAVE_SINCOSL)
 279     AC_DEFINE(HAVE_SINL)
 280     AC_DEFINE(HAVE_SINHL)
 281     AC_DEFINE(HAVE_SQRTL)
 282     AC_DEFINE(HAVE_TANL)
 283     AC_DEFINE(HAVE_TANHL)
 284   fi
 285 fi
 286
 287 # Check for _Unwind_GetIPInfo.
 288 GCC_CHECK_UNWIND_GETIPINFO
 289
 290
 291 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 292
 293 GCC_HEADER_STDINT(include/gstdint.h)
 294
 295 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 296 GLIBCXX_ENABLE_SYMVERS([yes])
 297 GLIBCXX_ENABLE_VISIBILITY([yes])
 298
 299 ac_ldbl_compat=no
 300 case "$target" in
 301   powerpc*-*-linux* | \
 302   powerpc*-*-gnu* | \
 303   sparc*-*-linux* | \
 304   s390*-*-linux* | \
 305   alpha*-*-linux*)
 306   AC_TRY_COMPILE(, [
 307 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 308 #error no need for long double compatibility
 309 #endif
 310   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 311   if test "$ac_ldbl_compat" = yes; then
 312     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 313               [Define if compatibility should be provided for -mlong-double-64.])
 314     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 315   fi
 316 esac
 317 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 318
 319 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 320 GLIBCXX_CONFIGURE_TESTSUITE
 321
 322 # Propagate the target-specific source directories through the build chain.
 323 ATOMICITY_SRCDIR=config/${atomicity_dir}
 324 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 325 ATOMIC_FLAGS=${atomic_flags}
 326 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 327 OS_INC_SRCDIR=config/${os_include_dir}
 328 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 329 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 330 AC_SUBST(ATOMICITY_SRCDIR)
 331 AC_SUBST(ATOMIC_WORD_SRCDIR)
 332 AC_SUBST(ATOMIC_FLAGS)
 333 AC_SUBST(CPU_DEFINES_SRCDIR)
 334 AC_SUBST(ABI_TWEAKS_SRCDIR)
 335 AC_SUBST(OS_INC_SRCDIR)
 336 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 337
 338
 339 # Determine cross-compile flags and AM_CONDITIONALs.
 340 #AC_SUBST(GLIBCXX_IS_NATIVE)
 341 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 342 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 343 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 344 GLIBCXX_EVALUATE_CONDITIONALS
 345
 346 AC_CACHE_SAVE
 347
 348 if test ${multilib} = yes; then
 349   multilib_arg="--enable-multilib"
 350 else
 351   multilib_arg=
 352 fi
 353
 354 # Export all the install information.
 355 GLIBCXX_EXPORT_INSTALL_INFO
 356
 357 # Export all the include and flag information to Makefiles.
 358 GLIBCXX_EXPORT_INCLUDES
 359 GLIBCXX_EXPORT_FLAGS
 360
 361 if test "$enable_shared" = yes; then
 362   LIBSUPCXX_PICFLAGS="-prefer-pic"
 363 else
 364   LIBSUPCXX_PICFLAGS=
 365 fi
 366 AC_SUBST(LIBSUPCXX_PICFLAGS)
 367
 368 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 369 dnl which can all be called multiple times as needed, plus one (different)
 370 dnl AC_OUTPUT macro.  This one lists the files to be created:
 371 AC_CONFIG_FILES( \
 372   Makefile \
 373   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 374   )
 375 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 376
 377 dnl These commands are run at the end of config.status:
 378 AC_CONFIG_COMMANDS([default],
 379 [if test -n "$CONFIG_FILES"; then
 380    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 381    # that multilib installs will end up installed in the correct place.
 382    # The testsuite needs it for multilib-aware ABI baseline files.
 383    # To work around this not being passed down from config-ml.in ->
 384    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 385    # append it here.  Only modify Makefiles that have just been created.
 386    #
 387    # Also, get rid of this simulated-VPATH thing that automake does.
 388    cat > vpsed << \_EOF
 389 s!`test -f '$<' || echo '$(srcdir)/'`!!
 390 _EOF
 391    for i in $SUBDIRS; do
 392     case $CONFIG_FILES in
 393      *${i}/Makefile*)
 394        #echo "Adding MULTISUBDIR to $i/Makefile"
 395        sed -f vpsed $i/Makefile > tmp
 396        grep '^MULTISUBDIR =' Makefile >> tmp
 397        mv tmp $i/Makefile
 398        ;;
 399     esac
 400    done
 401    rm vpsed
 402  fi
 403  (cd include && ${MAKE-make})
 404 ],
 405 [
 406 # Variables needed in config.status (file generation) which aren't already
 407 # passed by autoconf.
 408 SUBDIRS="$SUBDIRS"
 409 ])
 410
 411 dnl And this actually makes things happen:
 412 AC_OUTPUT