libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:17:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  no-dist:  we don't want 'dist' and related rules.
  76 #  -Wall:  turns on all automake warnings...
  77 #  -Wno-portability:  ...except this one, since GNU make is now required.
  78 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  79 AH_TEMPLATE(PACKAGE, [Name of package])
  80 AH_TEMPLATE(VERSION, [Version number of package])
  81
  82 # -fno-builtin must be present here so that a non-conflicting form of
  83 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  84
  85 save_CXXFLAGS="$CXXFLAGS"
  86 CXXFLAGS="$CXXFLAGS -fno-builtin"
  87 AC_PROG_CC
  88 AC_PROG_CXX
  89 CXXFLAGS="$save_CXXFLAGS"
  90
  91 # Runs configure.host, and assorted other critical bits.  Sets
  92 # up critical shell variables.
  93 GLIBCXX_CONFIGURE
  94
  95 if test "x${with_newlib}" != "xyes"; then
  96   AC_LIBTOOL_DLOPEN
  97 fi
  98 AM_PROG_LIBTOOL
  99 ACX_LT_HOST_FLAGS
 100 AC_SUBST(enable_shared)
 101 AC_SUBST(enable_static)
 102
 103 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 104 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 105
 106 # Possibly disable most of the library.
 107 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 108 ## than just ignoring the results.  Faster /and/ more correct, win win.
 109 GLIBCXX_ENABLE_HOSTED
 110
 111 # Enable compiler support that doesn't require linking.
 112 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 113 GLIBCXX_ENABLE_PCH($is_hosted)
 114 GLIBCXX_ENABLE_THREADS
 115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 116 GLIBCXX_ENABLE_DECIMAL_FLOAT
 117 GLIBCXX_ENABLE_INT128_FLOAT128
 118
 119 # Checks for compiler support that doesn't require linking.
 120 GLIBCXX_CHECK_COMPILER_FEATURES
 121
 122 # Enable all the variable C++ runtime options that don't require linking.
 123 GLIBCXX_ENABLE_CSTDIO
 124 GLIBCXX_ENABLE_CLOCALE
 125 GLIBCXX_ENABLE_ALLOCATOR
 126 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 127 GLIBCXX_ENABLE_LONG_LONG([yes])
 128 GLIBCXX_ENABLE_WCHAR_T([yes])
 129 GLIBCXX_ENABLE_C99([yes])
 130 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 131 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 132 GLIBCXX_ENABLE_DEBUG([no])
 133 GLIBCXX_ENABLE_PARALLEL([yes])
 134 GLIBCXX_ENABLE_CXX_FLAGS
 135 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 136 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 137
 138 # Checks for operating systems support that doesn't require linking.
 139 GLIBCXX_CHECK_MATH_PROTO
 140 GLIBCXX_CHECK_STDLIB_PROTO
 141 GLIBCXX_CHECK_SYSTEM_ERROR
 142
 143 # For the streamoff typedef.
 144 GLIBCXX_CHECK_INT64_T
 145
 146 # For LFS support.
 147 GLIBCXX_CHECK_LFS
 148
 149 # For showmanyc_helper().
 150 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 151 GLIBCXX_CHECK_POLL
 152 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 153
 154 # For xsputn_2().
 155 AC_CHECK_HEADERS(sys/uio.h)
 156 GLIBCXX_CHECK_WRITEV
 157
 158 # For C99 support to TR1.
 159 GLIBCXX_CHECK_C99_TR1
 160
 161 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 162 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 163
 164 # For gettimeofday support.
 165 GLIBCXX_CHECK_GETTIMEOFDAY
 166
 167 # For clock_gettime, nanosleep and sched_yield support.
 168 # NB: The default is [no], because otherwise it requires linking.
 169 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 170
 171 # For gthread support
 172 GLIBCXX_CHECK_GTHREADS
 173
 174 AC_LC_MESSAGES
 175
 176 # For hardware_concurrency
 177 AC_CHECK_HEADERS(sys/sysinfo.h)
 178 GLIBCXX_CHECK_GET_NPROCS
 179 AC_CHECK_HEADERS(unistd.h)
 180 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 181
 182 # Check for available headers.
 183 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 184 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 185 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 186 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 187 wchar.h wctype.h])
 188
 189 # Only do link tests if native. Else, hardcode.
 190 if $GLIBCXX_IS_NATIVE; then
 191
 192   # We can do more elaborate tests that assume a working linker.
 193   CANADIAN=no
 194
 195   GLIBCXX_CHECK_LINKER_FEATURES
 196   GLIBCXX_CHECK_MATH_SUPPORT
 197   GLIBCXX_CHECK_STDLIB_SUPPORT
 198
 199   # For /dev/random and /dev/urandom for TR1.
 200   GLIBCXX_CHECK_RANDOM_TR1
 201
 202   # For TLS support.
 203   GCC_CHECK_TLS
 204
 205   # For iconv support.
 206   AM_ICONV
 207
 208 else
 209
 210   # This lets us hard-code the functionality we know we'll have in the cross
 211   # target environment.  "Let" is a sugar-coated word placed on an especially
 212   # dull and tedious hack, actually.
 213   #
 214   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 215   # that involve linking, can't be used:
 216   #    "cannot open sim-crt0.o"
 217   #    "cannot open crt0.o"
 218   # etc.  All this is because there currently exists no unified, consistent
 219   # way for top level CC information to be passed down to target directories:
 220   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 221   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 222   # crosses can be removed.
 223
 224   # If Canadian cross, then don't pick up tools from the build directory.
 225   # Used only in GLIBCXX_EXPORT_INCLUDES.
 226   if test -n "$with_cross_host" &&
 227      test x"$build_alias" != x"$with_cross_host" &&
 228      test x"$build" != x"$target";
 229   then
 230     CANADIAN=yes
 231   else
 232     CANADIAN=no
 233   fi
 234
 235   # Construct crosses by hand, eliminating bits that need ld...
 236   # GLIBCXX_CHECK_MATH_SUPPORT
 237
 238   # First, test for "known" system libraries.  We may be using newlib even
 239   # on a hosted environment.
 240   if test "x${with_newlib}" = "xyes"; then
 241     os_include_dir="os/newlib"
 242     AC_DEFINE(HAVE_HYPOT)
 243
 244     # GLIBCXX_CHECK_STDLIB_SUPPORT
 245     AC_DEFINE(HAVE_STRTOF)
 246
 247     AC_DEFINE(HAVE_ACOSF)
 248     AC_DEFINE(HAVE_ASINF)
 249     AC_DEFINE(HAVE_ATAN2F)
 250     AC_DEFINE(HAVE_ATANF)
 251     AC_DEFINE(HAVE_CEILF)
 252     AC_DEFINE(HAVE_COSF)
 253     AC_DEFINE(HAVE_COSHF)
 254     AC_DEFINE(HAVE_EXPF)
 255     AC_DEFINE(HAVE_FABSF)
 256     AC_DEFINE(HAVE_FLOORF)
 257     AC_DEFINE(HAVE_FMODF)
 258     AC_DEFINE(HAVE_FREXPF)
 259     AC_DEFINE(HAVE_LDEXPF)
 260     AC_DEFINE(HAVE_LOG10F)
 261     AC_DEFINE(HAVE_LOGF)
 262     AC_DEFINE(HAVE_MODFF)
 263     AC_DEFINE(HAVE_POWF)
 264     AC_DEFINE(HAVE_SINF)
 265     AC_DEFINE(HAVE_SINHF)
 266     AC_DEFINE(HAVE_SQRTF)
 267     AC_DEFINE(HAVE_TANF)
 268     AC_DEFINE(HAVE_TANHF)
 269
 270     AC_DEFINE(HAVE_ICONV)
 271   else
 272     GLIBCXX_CROSSCONFIG
 273   fi
 274
 275   # At some point, we should differentiate between architectures
 276   # like x86, which have long double versions, and alpha/powerpc/etc.,
 277   # which don't. For the time being, punt.
 278   if test x"long_double_math_on_this_cpu" = x"yes"; then
 279     AC_DEFINE(HAVE_ACOSL)
 280     AC_DEFINE(HAVE_ASINL)
 281     AC_DEFINE(HAVE_ATAN2L)
 282     AC_DEFINE(HAVE_ATANL)
 283     AC_DEFINE(HAVE_CEILL)
 284     AC_DEFINE(HAVE_COSL)
 285     AC_DEFINE(HAVE_COSHL)
 286     AC_DEFINE(HAVE_EXPL)
 287     AC_DEFINE(HAVE_FABSL)
 288     AC_DEFINE(HAVE_FLOORL)
 289     AC_DEFINE(HAVE_FMODL)
 290     AC_DEFINE(HAVE_FREXPL)
 291     AC_DEFINE(HAVE_LDEXPL)
 292     AC_DEFINE(HAVE_LOG10L)
 293     AC_DEFINE(HAVE_LOGL)
 294     AC_DEFINE(HAVE_MODFL)
 295     AC_DEFINE(HAVE_POWL)
 296     AC_DEFINE(HAVE_SINCOSL)
 297     AC_DEFINE(HAVE_SINL)
 298     AC_DEFINE(HAVE_SINHL)
 299     AC_DEFINE(HAVE_SQRTL)
 300     AC_DEFINE(HAVE_TANL)
 301     AC_DEFINE(HAVE_TANHL)
 302   fi
 303 fi
 304
 305 # Check for _Unwind_GetIPInfo.
 306 GCC_CHECK_UNWIND_GETIPINFO
 307
 308
 309 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 310
 311 GCC_HEADER_STDINT(include/gstdint.h)
 312
 313 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 314 GLIBCXX_ENABLE_SYMVERS([yes])
 315 GLIBCXX_ENABLE_VISIBILITY([yes])
 316
 317 ac_ldbl_compat=no
 318 case "$target" in
 319   powerpc*-*-linux* | \
 320   sparc*-*-linux* | \
 321   s390*-*-linux* | \
 322   alpha*-*-linux*)
 323   AC_TRY_COMPILE(, [
 324 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 325 #error no need for long double compatibility
 326 #endif
 327   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 328   if test "$ac_ldbl_compat" = yes; then
 329     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 330               [Define if compatibility should be provided for -mlong-double-64.])
 331     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 332   fi
 333 esac
 334 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 335
 336 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 337 GLIBCXX_CONFIGURE_TESTSUITE
 338
 339 # Define documentation rules conditionally.
 340
 341 # See if makeinfo has been installed and is modern enough
 342 # that we can use it.
 343 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 344                    [GNU texinfo.* \([0-9][0-9.]*\)],
 345                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 346 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 347
 348 # Check for doxygen
 349 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 350 AC_CHECK_PROG([DOT], dot, yes, no)
 351
 352 # Check for docbook
 353 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 354 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 355 GLIBCXX_CONFIGURE_DOCBOOK
 356
 357 # Check for xml/html dependencies.
 358 AM_CONDITIONAL(BUILD_XML,
 359                test $ac_cv_prog_DOXYGEN = "yes" &&
 360                test $ac_cv_prog_DOT = "yes" &&
 361                test $ac_cv_prog_XSLTPROC = "yes" &&
 362                test $ac_cv_prog_XMLLINT = "yes" &&
 363                test $glibcxx_stylesheets = "yes")
 364
 365 AM_CONDITIONAL(BUILD_HTML,
 366                test $ac_cv_prog_DOXYGEN = "yes" &&
 367                test $ac_cv_prog_DOT = "yes" &&
 368                test $ac_cv_prog_XSLTPROC = "yes" &&
 369                test $ac_cv_prog_XMLLINT = "yes" &&
 370                test $glibcxx_stylesheets = "yes")
 371
 372 # Check for man dependencies.
 373 AM_CONDITIONAL(BUILD_MAN,
 374                test $ac_cv_prog_DOXYGEN = "yes" &&
 375                test $ac_cv_prog_DOT = "yes")
 376
 377 # Check for pdf/epub dependencies.
 378 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 379 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 380 AM_CONDITIONAL(BUILD_PDF,
 381                test $ac_cv_prog_DBLATEX = "yes" &&
 382                test $ac_cv_prog_PDFLATEX = "yes")
 383
 384 AC_CHECK_PROG([RUBY], ruby, yes, no)
 385 AC_CHECK_PROG([DBTOEPUB], dbtoepub, yes, no)
 386 AM_CONDITIONAL(BUILD_EPUB,
 387                test $ac_cv_prog_RUBY = "yes" &&
 388                test $ac_cv_prog_DBTOEPUB = "yes")
 389
 390
 391 # Propagate the target-specific source directories through the build chain.
 392 ATOMICITY_SRCDIR=config/${atomicity_dir}
 393 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 394 ATOMIC_FLAGS=${atomic_flags}
 395 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 396 OS_INC_SRCDIR=config/${os_include_dir}
 397 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 398 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 399 AC_SUBST(ATOMICITY_SRCDIR)
 400 AC_SUBST(ATOMIC_WORD_SRCDIR)
 401 AC_SUBST(ATOMIC_FLAGS)
 402 AC_SUBST(CPU_DEFINES_SRCDIR)
 403 AC_SUBST(ABI_TWEAKS_SRCDIR)
 404 AC_SUBST(OS_INC_SRCDIR)
 405 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 406
 407
 408 # Determine cross-compile flags and AM_CONDITIONALs.
 409 #AC_SUBST(GLIBCXX_IS_NATIVE)
 410 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 411 GLIBCXX_EVALUATE_CONDITIONALS
 412
 413 AC_CACHE_SAVE
 414
 415 if test ${multilib} = yes; then
 416   multilib_arg="--enable-multilib"
 417 else
 418   multilib_arg=
 419 fi
 420
 421 # Export all the install information.
 422 GLIBCXX_EXPORT_INSTALL_INFO
 423
 424 # Export all the include and flag information to Makefiles.
 425 GLIBCXX_EXPORT_INCLUDES
 426 GLIBCXX_EXPORT_FLAGS
 427
 428 if test "$enable_shared" = yes; then
 429   LIBSUPCXX_PICFLAGS="-prefer-pic"
 430 else
 431   LIBSUPCXX_PICFLAGS=
 432 fi
 433 AC_SUBST(LIBSUPCXX_PICFLAGS)
 434
 435 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 436 dnl which can all be called multiple times as needed, plus one (different)
 437 dnl AC_OUTPUT macro.  This one lists the files to be created:
 438 AC_CONFIG_FILES(Makefile)
 439 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 440 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 441
 442 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 443 # that multilib installs will end up installed in the correct place.
 444 # The testsuite needs it for multilib-aware ABI baseline files.
 445 # To work around this not being passed down from config-ml.in ->
 446 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 447 # append it here.  Only modify Makefiles that have just been created.
 448 #
 449 # Also, get rid of this simulated-VPATH thing that automake does.
 450 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 451   [cat > vpsed$$ << \_EOF
 452 s!`test -f '$<' || echo '$(srcdir)/'`!!
 453 _EOF
 454    sed -f vpsed$$ $ac_file > tmp$$
 455    mv tmp$$ $ac_file
 456    rm vpsed$$
 457    echo 'MULTISUBDIR =' >> $ac_file
 458    ml_norecursion=yes
 459    . ${multi_basedir}/config-ml.in
 460    AS_UNSET([ml_norecursion])
 461 ])
 462
 463 AC_CONFIG_COMMANDS([generate-headers],
 464   [(cd include && ${MAKE-make} pch_build= )])
 465
 466 dnl And this actually makes things happen:
 467 AC_OUTPUT