libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 # libtool variables for C++ shared and position-independent compiles.
 101 #
 102 # Use glibcxx_lt_pic_flag to designate the automake variable
 103 # used to encapsulate the default libtool approach to creating objects
 104 # with position-independent code. Default: -prefer-pic.
 105 #
 106 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 107 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 108 #
 109 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 110 # creating position-independent objects. This varies with the target
 111 # hardware and operating system, but is often: -DPIC -fPIC.
 112 if test "$enable_shared" = yes; then
 113   glibcxx_lt_pic_flag="-prefer-pic"
 114   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 115   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 116
 117 else
 118   glibcxx_lt_pic_flag=
 119   glibcxx_compiler_pic_flag=
 120   glibcxx_compiler_shared_flag=
 121 fi
 122 AC_SUBST(glibcxx_lt_pic_flag)
 123 AC_SUBST(glibcxx_compiler_pic_flag)
 124 AC_SUBST(glibcxx_compiler_shared_flag)
 125
 126 # Override the libtool's pic_flag and pic_mode.
 127 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 128 # NB: this impacts --with-pic and --without-pic.
 129 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 130 pic_mode='default'
 131
 132 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 133 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 134
 135 # Possibly disable most of the library.
 136 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 137 ## than just ignoring the results.  Faster /and/ more correct, win win.
 138 GLIBCXX_ENABLE_HOSTED
 139
 140 # Enable descriptive messages to standard output on termination.
 141 GLIBCXX_ENABLE_VERBOSE
 142
 143 # Enable compiler support that doesn't require linking.
 144 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 145 GLIBCXX_ENABLE_PCH($is_hosted)
 146 GLIBCXX_ENABLE_THREADS
 147 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 148 GLIBCXX_ENABLE_DECIMAL_FLOAT
 149 GLIBCXX_ENABLE_INT128_FLOAT128
 150
 151 # Checks for compiler support that doesn't require linking.
 152 GLIBCXX_CHECK_COMPILER_FEATURES
 153
 154 # Enable all the variable C++ runtime options that don't require linking.
 155 GLIBCXX_ENABLE_CSTDIO
 156 GLIBCXX_ENABLE_CLOCALE
 157 GLIBCXX_ENABLE_ALLOCATOR
 158 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 159 GLIBCXX_ENABLE_LONG_LONG([yes])
 160 GLIBCXX_ENABLE_WCHAR_T([yes])
 161 GLIBCXX_ENABLE_C99([yes])
 162 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 163 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 164 GLIBCXX_ENABLE_DEBUG([no])
 165 GLIBCXX_ENABLE_PARALLEL([yes])
 166 GLIBCXX_ENABLE_CXX_FLAGS
 167 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 168 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 169 GLIBCXX_ENABLE_PYTHON
 170 GLIBCXX_ENABLE_WERROR([yes])
 171
 172 # Checks for operating systems support that doesn't require linking.
 173 GLIBCXX_CHECK_STDIO_PROTO
 174 GLIBCXX_CHECK_SYSTEM_ERROR
 175
 176 # For the streamoff typedef.
 177 GLIBCXX_CHECK_INT64_T
 178
 179 # For LFS support.
 180 GLIBCXX_CHECK_LFS
 181
 182 # For showmanyc_helper().
 183 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 184 GLIBCXX_CHECK_POLL
 185 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 186
 187 # For xsputn_2().
 188 AC_CHECK_HEADERS(sys/uio.h)
 189 GLIBCXX_CHECK_WRITEV
 190
 191 # For C99 support to TR1.
 192 GLIBCXX_CHECK_C99_TR1
 193
 194 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 195 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 196
 197 # For gettimeofday support.
 198 GLIBCXX_CHECK_GETTIMEOFDAY
 199
 200 # For clock_gettime, nanosleep and sched_yield support.
 201 # NB: The default is [no], because otherwise it requires linking.
 202 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 203
 204 AC_LC_MESSAGES
 205
 206 # For hardware_concurrency
 207 AC_CHECK_HEADERS(sys/sysinfo.h)
 208 GLIBCXX_CHECK_GET_NPROCS
 209 AC_CHECK_HEADERS(unistd.h)
 210 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 211 GLIBCXX_CHECK_SC_NPROC_ONLN
 212 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 213 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 214 GLIBCXX_CHECK_SDT_H
 215
 216 # Check for available headers.
 217 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 218 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 219 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 220 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 221 wchar.h wctype.h])
 222
 223 # Only do link tests if native. Else, hardcode.
 224 if $GLIBCXX_IS_NATIVE; then
 225
 226   # We can do more elaborate tests that assume a working linker.
 227   CANADIAN=no
 228
 229   GLIBCXX_CHECK_LINKER_FEATURES
 230   GLIBCXX_CHECK_MATH_SUPPORT
 231   GLIBCXX_CHECK_STDLIB_SUPPORT
 232
 233   # For /dev/random and /dev/urandom for TR1.
 234   GLIBCXX_CHECK_RANDOM_TR1
 235
 236   # For TLS support.
 237   GCC_CHECK_TLS
 238
 239   AC_CHECK_FUNCS(__cxa_thread_atexit_impl)
 240
 241   # For iconv support.
 242   AM_ICONV
 243
 244 else
 245
 246   # This lets us hard-code the functionality we know we'll have in the cross
 247   # target environment.  "Let" is a sugar-coated word placed on an especially
 248   # dull and tedious hack, actually.
 249   #
 250   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 251   # that involve linking, can't be used:
 252   #    "cannot open sim-crt0.o"
 253   #    "cannot open crt0.o"
 254   # etc.  All this is because there currently exists no unified, consistent
 255   # way for top level CC information to be passed down to target directories:
 256   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 257   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 258   # crosses can be removed.
 259
 260   # If Canadian cross, then don't pick up tools from the build directory.
 261   # Used only in GLIBCXX_EXPORT_INCLUDES.
 262   if test -n "$with_cross_host" &&
 263      test x"$build_alias" != x"$with_cross_host" &&
 264      test x"$build" != x"$target";
 265   then
 266     CANADIAN=yes
 267   else
 268     CANADIAN=no
 269   fi
 270
 271   # Construct crosses by hand, eliminating bits that need ld...
 272   # GLIBCXX_CHECK_MATH_SUPPORT
 273
 274   # First, test for "known" system libraries.  We may be using newlib even
 275   # on a hosted environment.
 276   if test "x${with_newlib}" = "xyes"; then
 277     os_include_dir="os/newlib"
 278     AC_DEFINE(HAVE_HYPOT)
 279
 280     # GLIBCXX_CHECK_STDLIB_SUPPORT
 281     AC_DEFINE(HAVE_STRTOF)
 282
 283     AC_DEFINE(HAVE_ACOSF)
 284     AC_DEFINE(HAVE_ASINF)
 285     AC_DEFINE(HAVE_ATAN2F)
 286     AC_DEFINE(HAVE_ATANF)
 287     AC_DEFINE(HAVE_CEILF)
 288     AC_DEFINE(HAVE_COSF)
 289     AC_DEFINE(HAVE_COSHF)
 290     AC_DEFINE(HAVE_EXPF)
 291     AC_DEFINE(HAVE_FABSF)
 292     AC_DEFINE(HAVE_FLOORF)
 293     AC_DEFINE(HAVE_FMODF)
 294     AC_DEFINE(HAVE_FREXPF)
 295     AC_DEFINE(HAVE_LDEXPF)
 296     AC_DEFINE(HAVE_LOG10F)
 297     AC_DEFINE(HAVE_LOGF)
 298     AC_DEFINE(HAVE_MODFF)
 299     AC_DEFINE(HAVE_POWF)
 300     AC_DEFINE(HAVE_SINF)
 301     AC_DEFINE(HAVE_SINHF)
 302     AC_DEFINE(HAVE_SQRTF)
 303     AC_DEFINE(HAVE_TANF)
 304     AC_DEFINE(HAVE_TANHF)
 305
 306     AC_DEFINE(HAVE_ICONV)
 307   else
 308     GLIBCXX_CROSSCONFIG
 309   fi
 310
 311   # At some point, we should differentiate between architectures
 312   # like x86, which have long double versions, and alpha/powerpc/etc.,
 313   # which don't. For the time being, punt.
 314   if test x"long_double_math_on_this_cpu" = x"yes"; then
 315     AC_DEFINE(HAVE_ACOSL)
 316     AC_DEFINE(HAVE_ASINL)
 317     AC_DEFINE(HAVE_ATAN2L)
 318     AC_DEFINE(HAVE_ATANL)
 319     AC_DEFINE(HAVE_CEILL)
 320     AC_DEFINE(HAVE_COSL)
 321     AC_DEFINE(HAVE_COSHL)
 322     AC_DEFINE(HAVE_EXPL)
 323     AC_DEFINE(HAVE_FABSL)
 324     AC_DEFINE(HAVE_FLOORL)
 325     AC_DEFINE(HAVE_FMODL)
 326     AC_DEFINE(HAVE_FREXPL)
 327     AC_DEFINE(HAVE_LDEXPL)
 328     AC_DEFINE(HAVE_LOG10L)
 329     AC_DEFINE(HAVE_LOGL)
 330     AC_DEFINE(HAVE_MODFL)
 331     AC_DEFINE(HAVE_POWL)
 332     AC_DEFINE(HAVE_SINCOSL)
 333     AC_DEFINE(HAVE_SINL)
 334     AC_DEFINE(HAVE_SINHL)
 335     AC_DEFINE(HAVE_SQRTL)
 336     AC_DEFINE(HAVE_TANL)
 337     AC_DEFINE(HAVE_TANHL)
 338   fi
 339 fi
 340
 341 # Check for _Unwind_GetIPInfo.
 342 GCC_CHECK_UNWIND_GETIPINFO
 343
 344 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 345
 346 GCC_HEADER_STDINT(include/gstdint.h)
 347
 348 GLIBCXX_ENABLE_SYMVERS([yes])
 349 AC_SUBST(libtool_VERSION)
 350
 351 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 352
 353 ac_ldbl_compat=no
 354 case "$target" in
 355   powerpc*-*-linux* | \
 356   sparc*-*-linux* | \
 357   s390*-*-linux* | \
 358   alpha*-*-linux*)
 359   AC_TRY_COMPILE(, [
 360 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 361 #error no need for long double compatibility
 362 #endif
 363   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 364   if test "$ac_ldbl_compat" = yes; then
 365     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 366               [Define if compatibility should be provided for -mlong-double-64.])
 367     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 368   fi
 369 esac
 370 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 371
 372 # Check if assembler supports disabling hardware capability support.
 373 GLIBCXX_CHECK_ASSEMBLER_HWCAP
 374
 375 # Check if assembler supports rdrand opcode.
 376 GLIBCXX_CHECK_X86_RDRAND
 377
 378 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 379 GLIBCXX_CONFIGURE_TESTSUITE
 380
 381 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 382 GLIBCXX_CHECK_GTHREADS
 383
 384 # Define documentation rules conditionally.
 385
 386 # See if makeinfo has been installed and is modern enough
 387 # that we can use it.
 388 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 389                    [GNU texinfo.* \([0-9][0-9.]*\)],
 390                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 391 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 392
 393 # Check for doxygen
 394 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 395 AC_CHECK_PROG([DOT], dot, yes, no)
 396
 397 # Check for docbook
 398 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 399 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 400 GLIBCXX_CONFIGURE_DOCBOOK
 401
 402 # Check for xml/html dependencies.
 403 AM_CONDITIONAL(BUILD_XML,
 404                test $ac_cv_prog_DOXYGEN = "yes" &&
 405                test $ac_cv_prog_DOT = "yes" &&
 406                test $ac_cv_prog_XSLTPROC = "yes" &&
 407                test $ac_cv_prog_XMLLINT = "yes" &&
 408                test $glibcxx_stylesheets = "yes")
 409
 410 AM_CONDITIONAL(BUILD_HTML,
 411                test $ac_cv_prog_DOXYGEN = "yes" &&
 412                test $ac_cv_prog_DOT = "yes" &&
 413                test $ac_cv_prog_XSLTPROC = "yes" &&
 414                test $ac_cv_prog_XMLLINT = "yes" &&
 415                test $glibcxx_stylesheets = "yes")
 416
 417 # Check for man dependencies.
 418 AM_CONDITIONAL(BUILD_MAN,
 419                test $ac_cv_prog_DOXYGEN = "yes" &&
 420                test $ac_cv_prog_DOT = "yes")
 421
 422 # Check for pdf dependencies.
 423 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 424 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 425 AM_CONDITIONAL(BUILD_PDF,
 426                test $ac_cv_prog_DBLATEX = "yes" &&
 427                test $ac_cv_prog_PDFLATEX = "yes")
 428
 429
 430 # Propagate the target-specific source directories through the build chain.
 431 ATOMICITY_SRCDIR=config/${atomicity_dir}
 432 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 433 ATOMIC_FLAGS=${atomic_flags}
 434 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 435 OS_INC_SRCDIR=config/${os_include_dir}
 436 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 437 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 438 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 439 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 440 AC_SUBST(ATOMICITY_SRCDIR)
 441 AC_SUBST(ATOMIC_WORD_SRCDIR)
 442 AC_SUBST(ATOMIC_FLAGS)
 443 AC_SUBST(CPU_DEFINES_SRCDIR)
 444 AC_SUBST(ABI_TWEAKS_SRCDIR)
 445 AC_SUBST(OS_INC_SRCDIR)
 446 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 447 AC_SUBST(CPU_OPT_EXT_RANDOM)
 448 AC_SUBST(CPU_OPT_BITS_RANDOM)
 449
 450
 451 # Determine cross-compile flags and AM_CONDITIONALs.
 452 #AC_SUBST(GLIBCXX_IS_NATIVE)
 453 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 454 GLIBCXX_EVALUATE_CONDITIONALS
 455
 456 AC_CACHE_SAVE
 457
 458 if test ${multilib} = yes; then
 459   multilib_arg="--enable-multilib"
 460 else
 461   multilib_arg=
 462 fi
 463
 464 # Export all the install information.
 465 GLIBCXX_EXPORT_INSTALL_INFO
 466
 467 # Export all the include and flag information to Makefiles.
 468 GLIBCXX_EXPORT_INCLUDES
 469 GLIBCXX_EXPORT_FLAGS
 470
 471 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 472 dnl which can all be called multiple times as needed, plus one (different)
 473 dnl AC_OUTPUT macro.  This one lists the files to be created:
 474 AC_CONFIG_FILES(Makefile)
 475 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 476 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 477 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 478
 479 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 480 # that multilib installs will end up installed in the correct place.
 481 # The testsuite needs it for multilib-aware ABI baseline files.
 482 # To work around this not being passed down from config-ml.in ->
 483 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 484 # append it here.  Only modify Makefiles that have just been created.
 485 #
 486 # Also, get rid of this simulated-VPATH thing that automake does.
 487 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 488   [cat > vpsed$$ << \_EOF
 489 s!`test -f '$<' || echo '$(srcdir)/'`!!
 490 _EOF
 491    sed -f vpsed$$ $ac_file > tmp$$
 492    mv tmp$$ $ac_file
 493    rm vpsed$$
 494    echo 'MULTISUBDIR =' >> $ac_file
 495    ml_norecursion=yes
 496    . ${multi_basedir}/config-ml.in
 497    AS_UNSET([ml_norecursion])
 498 ])
 499
 500 AC_CONFIG_COMMANDS([generate-headers],
 501   [(cd include && ${MAKE-make} pch_build= )])
 502
 503 dnl And this actually makes things happen:
 504 AC_OUTPUT