libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:11:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 if test "x${with_newlib}" != "xyes"; then
  86   AC_LIBTOOL_DLOPEN
  87 fi
  88 AM_PROG_LIBTOOL
  89 AC_SUBST(enable_shared)
  90 AC_SUBST(enable_static)
  91
  92 # Possibly disable most of the library.
  93 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  94 ## than just ignoring the results.  Faster /and/ more correct, win win.
  95 GLIBCXX_ENABLE_HOSTED
  96
  97 # Enable compiler support that doesn't require linking.
  98 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  99 GLIBCXX_ENABLE_PCH($is_hosted)
 100 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 101 GLIBCXX_ENABLE_THREADS
 102
 103 # Checks for compiler support that don't require linking.
 104 GLIBCXX_CHECK_COMPILER_FEATURES
 105 GLIBCXX_CHECK_STANDARD_LAYOUT
 106
 107 # Enable all the variable C++ runtime options that doesn't require linking.
 108 GLIBCXX_ENABLE_CSTDIO
 109 GLIBCXX_ENABLE_CLOCALE
 110 GLIBCXX_ENABLE_ALLOCATOR
 111 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 112 GLIBCXX_ENABLE_LONG_LONG([yes])
 113 GLIBCXX_ENABLE_WCHAR_T([yes])
 114 GLIBCXX_ENABLE_C99([yes])
 115 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 116 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 117 GLIBCXX_ENABLE_DEBUG([no])
 118 GLIBCXX_ENABLE_PARALLEL([yes])
 119 GLIBCXX_ENABLE_CXX_FLAGS
 120 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 121
 122 # Checks for operating systems support that don't require linking.
 123 GLIBCXX_CHECK_SYSTEM_ERROR
 124
 125
 126 # Only do link tests if native. Else, hardcode.
 127 if $GLIBCXX_IS_NATIVE; then
 128
 129   # We can do more elaborate tests that assume a working linker.
 130   CANADIAN=no
 131
 132   # Check for available headers.
 133   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 134   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h \
 135   sys/types.h sys/ipc.h sys/sem.h])
 136
 137   GLIBCXX_CHECK_LINKER_FEATURES
 138   GLIBCXX_CHECK_MATH_SUPPORT
 139   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 140   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 141   GLIBCXX_CHECK_STDLIB_SUPPORT
 142
 143   # For showmanyc_helper().
 144   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 145   GLIBCXX_CHECK_POLL
 146   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 147
 148   # For xsputn_2().
 149   AC_CHECK_HEADERS(sys/uio.h)
 150   GLIBCXX_CHECK_WRITEV
 151
 152   # For the __streamoff_base_type typedef.
 153   GLIBCXX_CHECK_INT64_T
 154
 155   # For LFS support.
 156   GLIBCXX_CHECK_LFS
 157
 158   # For C99 support to TR1.
 159   GLIBCXX_CHECK_C99_TR1
 160
 161   # For dev/random and dev/urandom for TR1.
 162   GLIBCXX_CHECK_RANDOM_TR1
 163
 164   # For clock_gettime support.
 165   GLIBCXX_CHECK_CLOCK_GETTIME
 166
 167   # For gettimeofday support.
 168   GLIBCXX_CHECK_GETTIMEOFDAY
 169
 170   #
 171   GLIBCXX_CHECK_STDIO_MACROS
 172
 173   # For TLS support.
 174   GCC_CHECK_TLS
 175
 176   # For _Unwind_GetIPInfo.
 177   GCC_CHECK_UNWIND_GETIPINFO
 178
 179   AC_LC_MESSAGES
 180
 181   AC_TRY_COMPILE(
 182     [#include <setjmp.h>],
 183     [sigjmp_buf env;
 184      while (! sigsetjmp (env, 1))
 185        siglongjmp (env, 1);
 186     ],
 187     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 188
 189   AC_FUNC_MMAP
 190
 191   # For iconv support.
 192   AM_ICONV
 193
 194 else
 195
 196   # This lets us hard-code the functionality we know we'll have in the cross
 197   # target environment.  "Let" is a sugar-coated word placed on an especially
 198   # dull and tedious hack, actually.
 199   #
 200   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 201   # that involve linking, can't be used:
 202   #    "cannot open sim-crt0.o"
 203   #    "cannot open crt0.o"
 204   # etc.  All this is because there currently exists no unified, consistent
 205   # way for top level CC information to be passed down to target directories:
 206   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 207   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 208   # crosses can be removed.
 209
 210   # If Canadian cross, then don't pick up tools from the build directory.
 211   # Used only in GLIBCXX_EXPORT_INCLUDES.
 212   if test -n "$with_cross_host" &&
 213      test x"$build_alias" != x"$with_cross_host" &&
 214      test x"$build" != x"$target";
 215   then
 216     CANADIAN=yes
 217   else
 218     CANADIAN=no
 219   fi
 220
 221   # Construct crosses by hand, eliminating bits that need ld...
 222   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 223   # GLIBCXX_CHECK_MATH_SUPPORT
 224
 225   # First, test for "known" system libraries.  We may be using newlib even
 226   # on a hosted environment.
 227   if test "x${with_newlib}" = "xyes"; then
 228     os_include_dir="os/newlib"
 229     AC_DEFINE(HAVE_HYPOT)
 230
 231     # GLIBCXX_CHECK_STDLIB_SUPPORT
 232     AC_DEFINE(HAVE_STRTOF)
 233     # AC_FUNC_MMAP
 234     AC_DEFINE(HAVE_MMAP)
 235
 236     AC_DEFINE(HAVE_ACOSF)
 237     AC_DEFINE(HAVE_ASINF)
 238     AC_DEFINE(HAVE_ATAN2F)
 239     AC_DEFINE(HAVE_ATANF)
 240     AC_DEFINE(HAVE_CEILF)
 241     AC_DEFINE(HAVE_COPYSIGN)
 242     AC_DEFINE(HAVE_COPYSIGNF)
 243     AC_DEFINE(HAVE_COSF)
 244     AC_DEFINE(HAVE_COSHF)
 245     AC_DEFINE(HAVE_EXPF)
 246     AC_DEFINE(HAVE_FABSF)
 247     AC_DEFINE(HAVE_FLOORF)
 248     AC_DEFINE(HAVE_FMODF)
 249     AC_DEFINE(HAVE_FREXPF)
 250     AC_DEFINE(HAVE_LDEXPF)
 251     AC_DEFINE(HAVE_LOG10F)
 252     AC_DEFINE(HAVE_LOGF)
 253     AC_DEFINE(HAVE_MODFF)
 254     AC_DEFINE(HAVE_POWF)
 255     AC_DEFINE(HAVE_SINF)
 256     AC_DEFINE(HAVE_SINHF)
 257     AC_DEFINE(HAVE_SQRTF)
 258     AC_DEFINE(HAVE_TANF)
 259     AC_DEFINE(HAVE_TANHF)
 260
 261     AC_DEFINE(HAVE_S_ISREG)
 262     AC_DEFINE(HAVE_S_IFREG)
 263
 264     AC_DEFINE(HAVE_ICONV)
 265   else
 266     GLIBCXX_CROSSCONFIG
 267   fi
 268
 269   # At some point, we should differentiate between architectures
 270   # like x86, which have long double versions, and alpha/powerpc/etc.,
 271   # which don't. For the time being, punt.
 272   if test x"long_double_math_on_this_cpu" = x"yes"; then
 273     AC_DEFINE(HAVE_ACOSL)
 274     AC_DEFINE(HAVE_ASINL)
 275     AC_DEFINE(HAVE_ATAN2L)
 276     AC_DEFINE(HAVE_ATANL)
 277     AC_DEFINE(HAVE_CEILL)
 278     AC_DEFINE(HAVE_COPYSIGNL)
 279     AC_DEFINE(HAVE_COSL)
 280     AC_DEFINE(HAVE_COSHL)
 281     AC_DEFINE(HAVE_EXPL)
 282     AC_DEFINE(HAVE_FABSL)
 283     AC_DEFINE(HAVE_FLOORL)
 284     AC_DEFINE(HAVE_FMODL)
 285     AC_DEFINE(HAVE_FREXPL)
 286     AC_DEFINE(HAVE_LDEXPL)
 287     AC_DEFINE(HAVE_LOG10L)
 288     AC_DEFINE(HAVE_LOGL)
 289     AC_DEFINE(HAVE_MODFL)
 290     AC_DEFINE(HAVE_POWL)
 291     AC_DEFINE(HAVE_SINCOSL)
 292     AC_DEFINE(HAVE_SINL)
 293     AC_DEFINE(HAVE_SINHL)
 294     AC_DEFINE(HAVE_SQRTL)
 295     AC_DEFINE(HAVE_TANL)
 296     AC_DEFINE(HAVE_TANHL)
 297   fi
 298
 299   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 300   AC_DEFINE(HAVE_GETIPINFO)
 301 fi
 302
 303 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 304
 305 GCC_HEADER_STDINT(include/gstdint.h)
 306
 307 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 308 GLIBCXX_ENABLE_SYMVERS([yes])
 309 GLIBCXX_ENABLE_VISIBILITY([yes])
 310
 311 ac_ldbl_compat=no
 312 case "$target" in
 313   powerpc*-*-linux* | \
 314   powerpc*-*-gnu* | \
 315   sparc*-*-linux* | \
 316   s390*-*-linux* | \
 317   alpha*-*-linux*)
 318   AC_TRY_COMPILE(, [
 319 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 320 #error no need for long double compatibility
 321 #endif
 322   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 323   if test "$ac_ldbl_compat" = yes; then
 324     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 325               [Define if compatibility should be provided for -mlong-double-64.])
 326     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 327   fi
 328 esac
 329 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 330
 331 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 332 GLIBCXX_CONFIGURE_TESTSUITE
 333
 334 # Propagate the target-specific source directories through the build chain.
 335 ATOMICITY_SRCDIR=config/${atomicity_dir}
 336 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 337 ATOMIC_FLAGS=${atomic_flags}
 338 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 339 OS_INC_SRCDIR=config/${os_include_dir}
 340 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 341 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 342 AC_SUBST(ATOMICITY_SRCDIR)
 343 AC_SUBST(ATOMIC_WORD_SRCDIR)
 344 AC_SUBST(ATOMIC_FLAGS)
 345 AC_SUBST(CPU_DEFINES_SRCDIR)
 346 AC_SUBST(ABI_TWEAKS_SRCDIR)
 347 AC_SUBST(OS_INC_SRCDIR)
 348 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 349
 350
 351 # Determine cross-compile flags and AM_CONDITIONALs.
 352 #AC_SUBST(GLIBCXX_IS_NATIVE)
 353 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 354 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 355 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 356 GLIBCXX_EVALUATE_CONDITIONALS
 357
 358 AC_CACHE_SAVE
 359
 360 if test ${multilib} = yes; then
 361   multilib_arg="--enable-multilib"
 362 else
 363   multilib_arg=
 364 fi
 365
 366 # Export all the install information.
 367 GLIBCXX_EXPORT_INSTALL_INFO
 368
 369 # Export all the include and flag information to Makefiles.
 370 GLIBCXX_EXPORT_INCLUDES
 371 GLIBCXX_EXPORT_FLAGS
 372
 373 if test "$enable_shared" = yes; then
 374   LIBSUPCXX_PICFLAGS="-prefer-pic"
 375 else
 376   LIBSUPCXX_PICFLAGS=
 377 fi
 378 AC_SUBST(LIBSUPCXX_PICFLAGS)
 379
 380 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 381 dnl which can all be called multiple times as needed, plus one (different)
 382 dnl AC_OUTPUT macro.  This one lists the files to be created:
 383 AC_CONFIG_FILES( \
 384   Makefile \
 385   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 386   )
 387 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 388
 389 dnl These commands are run at the end of config.status:
 390 AC_CONFIG_COMMANDS([default],
 391 [if test -n "$CONFIG_FILES"; then
 392    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 393    # that multilib installs will end up installed in the correct place.
 394    # The testsuite needs it for multilib-aware ABI baseline files.
 395    # To work around this not being passed down from config-ml.in ->
 396    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 397    # append it here.  Only modify Makefiles that have just been created.
 398    #
 399    # Also, get rid of this simulated-VPATH thing that automake does.
 400    cat > vpsed << \_EOF
 401 s!`test -f '$<' || echo '$(srcdir)/'`!!
 402 _EOF
 403    for i in $SUBDIRS; do
 404     case $CONFIG_FILES in
 405      *${i}/Makefile*)
 406        #echo "Adding MULTISUBDIR to $i/Makefile"
 407        sed -f vpsed $i/Makefile > tmp
 408        grep '^MULTISUBDIR =' Makefile >> tmp
 409        mv tmp $i/Makefile
 410        ;;
 411     esac
 412    done
 413    rm vpsed
 414  fi
 415  (cd include && ${MAKE-make})
 416 ],
 417 [
 418 # Variables needed in config.status (file generation) which aren't already
 419 # passed by autoconf.
 420 SUBDIRS="$SUBDIRS"
 421 ])
 422
 423 dnl And this actually makes things happen:
 424 AC_OUTPUT