libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:10:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Enable compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options that doesn't require linking.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_LONG_LONG([yes])
 105 GLIBCXX_ENABLE_WCHAR_T([yes])
 106 GLIBCXX_ENABLE_C99([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_CXX_FLAGS
 111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 112
 113 # Checks for operating systems support that don't require linking.
 114 GLIBCXX_CHECK_SYSTEM_ERROR
 115
 116 # No surprises, no surprises...
 117 GLIBCXX_ENABLE_THREADS
 118 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 119 if test $atomicity_dir = cpu/generic/atomicity_mutex ; then
 120   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 121   if test $target_thread_file = single; then
 122     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 123     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 124   else
 125     AC_MSG_WARN([They will be faked using a mutex.])
 126     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 127   fi
 128 fi
 129
 130 GLIBCXX_CHECK_COMPILER_FEATURES
 131
 132 if $GLIBCXX_IS_NATIVE; then
 133
 134   # We can do more elaborate tests that assume a working linker.
 135   CANADIAN=no
 136
 137   # Check for available headers.
 138   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 139   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 140   sys/types.h sys/ipc.h sys/sem.h])
 141
 142   GLIBCXX_CHECK_LINKER_FEATURES
 143   GLIBCXX_CHECK_MATH_SUPPORT
 144   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 145   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 146   GLIBCXX_CHECK_STDLIB_SUPPORT
 147
 148   # For showmanyc_helper().
 149   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 150   GLIBCXX_CHECK_POLL
 151   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 152
 153   # For xsputn_2().
 154   AC_CHECK_HEADERS(sys/uio.h)
 155   GLIBCXX_CHECK_WRITEV
 156
 157   # For the __streamoff_base_type typedef.
 158   GLIBCXX_CHECK_INT64_T
 159
 160   # For LFS support.
 161   GLIBCXX_CHECK_LFS
 162
 163   # For C99 support to TR1.
 164   GLIBCXX_CHECK_C99_TR1
 165
 166   # For dev/random and dev/urandom for TR1.
 167   GLIBCXX_CHECK_RANDOM_TR1
 168
 169   # For TLS support.
 170   GCC_CHECK_TLS
 171
 172   # For _Unwind_GetIPInfo.
 173   GCC_CHECK_UNWIND_GETIPINFO
 174
 175   AC_LC_MESSAGES
 176
 177   AC_TRY_COMPILE(
 178     [#include <setjmp.h>],
 179     [sigjmp_buf env;
 180      while (! sigsetjmp (env, 1))
 181        siglongjmp (env, 1);
 182     ],
 183     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 184
 185   AC_FUNC_MMAP
 186
 187   # For iconv support.
 188   AM_ICONV
 189
 190 else
 191
 192   # This lets us hard-code the functionality we know we'll have in the cross
 193   # target environment.  "Let" is a sugar-coated word placed on an especially
 194   # dull and tedious hack, actually.
 195   #
 196   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 197   # that involve linking, can't be used:
 198   #    "cannot open sim-crt0.o"
 199   #    "cannot open crt0.o"
 200   # etc.  All this is because there currently exists no unified, consistent
 201   # way for top level CC information to be passed down to target directories:
 202   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 203   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 204   # crosses can be removed.
 205
 206   # If Canadian cross, then don't pick up tools from the build directory.
 207   # Used only in GLIBCXX_EXPORT_INCLUDES.
 208   if test -n "$with_cross_host" &&
 209      test x"$build_alias" != x"$with_cross_host" &&
 210      test x"$build" != x"$target";
 211   then
 212     CANADIAN=yes
 213   else
 214     CANADIAN=no
 215   fi
 216
 217   # Construct crosses by hand, eliminating bits that need ld...
 218   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 219   # GLIBCXX_CHECK_MATH_SUPPORT
 220
 221   # First, test for "known" system libraries.  We may be using newlib even
 222   # on a hosted environment.
 223   if test "x${with_newlib}" = "xyes"; then
 224     os_include_dir="os/newlib"
 225     AC_DEFINE(HAVE_HYPOT)
 226
 227     # GLIBCXX_CHECK_STDLIB_SUPPORT
 228     AC_DEFINE(HAVE_STRTOF)
 229     # AC_FUNC_MMAP
 230     AC_DEFINE(HAVE_MMAP)
 231
 232     AC_DEFINE(HAVE_ACOSF)
 233     AC_DEFINE(HAVE_ASINF)
 234     AC_DEFINE(HAVE_ATAN2F)
 235     AC_DEFINE(HAVE_ATANF)
 236     AC_DEFINE(HAVE_CEILF)
 237     AC_DEFINE(HAVE_COPYSIGN)
 238     AC_DEFINE(HAVE_COPYSIGNF)
 239     AC_DEFINE(HAVE_COSF)
 240     AC_DEFINE(HAVE_COSHF)
 241     AC_DEFINE(HAVE_EXPF)
 242     AC_DEFINE(HAVE_FABSF)
 243     AC_DEFINE(HAVE_FLOORF)
 244     AC_DEFINE(HAVE_FMODF)
 245     AC_DEFINE(HAVE_FREXPF)
 246     AC_DEFINE(HAVE_LDEXPF)
 247     AC_DEFINE(HAVE_LOG10F)
 248     AC_DEFINE(HAVE_LOGF)
 249     AC_DEFINE(HAVE_MODFF)
 250     AC_DEFINE(HAVE_POWF)
 251     AC_DEFINE(HAVE_SINF)
 252     AC_DEFINE(HAVE_SINHF)
 253     AC_DEFINE(HAVE_SQRTF)
 254     AC_DEFINE(HAVE_TANF)
 255     AC_DEFINE(HAVE_TANHF)
 256
 257     AC_DEFINE(HAVE_S_ISREG)
 258     AC_DEFINE(HAVE_S_IFREG)
 259
 260     AC_DEFINE(HAVE_ICONV)
 261   else
 262     GLIBCXX_CROSSCONFIG
 263   fi
 264
 265   # At some point, we should differentiate between architectures
 266   # like x86, which have long double versions, and alpha/powerpc/etc.,
 267   # which don't. For the time being, punt.
 268   if test x"long_double_math_on_this_cpu" = x"yes"; then
 269     AC_DEFINE(HAVE_ACOSL)
 270     AC_DEFINE(HAVE_ASINL)
 271     AC_DEFINE(HAVE_ATAN2L)
 272     AC_DEFINE(HAVE_ATANL)
 273     AC_DEFINE(HAVE_CEILL)
 274     AC_DEFINE(HAVE_COPYSIGNL)
 275     AC_DEFINE(HAVE_COSL)
 276     AC_DEFINE(HAVE_COSHL)
 277     AC_DEFINE(HAVE_EXPL)
 278     AC_DEFINE(HAVE_FABSL)
 279     AC_DEFINE(HAVE_FLOORL)
 280     AC_DEFINE(HAVE_FMODL)
 281     AC_DEFINE(HAVE_FREXPL)
 282     AC_DEFINE(HAVE_LDEXPL)
 283     AC_DEFINE(HAVE_LOG10L)
 284     AC_DEFINE(HAVE_LOGL)
 285     AC_DEFINE(HAVE_MODFL)
 286     AC_DEFINE(HAVE_POWL)
 287     AC_DEFINE(HAVE_SINCOSL)
 288     AC_DEFINE(HAVE_SINL)
 289     AC_DEFINE(HAVE_SINHL)
 290     AC_DEFINE(HAVE_SQRTL)
 291     AC_DEFINE(HAVE_TANL)
 292     AC_DEFINE(HAVE_TANHL)
 293   fi
 294
 295   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 296   AC_DEFINE(HAVE_GETIPINFO)
 297
 298 fi
 299
 300 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 301 GLIBCXX_ENABLE_SYMVERS([yes])
 302 GLIBCXX_ENABLE_VISIBILITY([yes])
 303
 304 ac_ldbl_compat=no
 305 case "$target" in
 306   powerpc*-*-linux* | \
 307   powerpc*-*-gnu* | \
 308   sparc*-*-linux* | \
 309   s390*-*-linux* | \
 310   alpha*-*-linux*)
 311   AC_TRY_COMPILE(, [
 312 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 313 #error no need for long double compatibility
 314 #endif
 315   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 316   if test "$ac_ldbl_compat" = yes; then
 317     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 318               [Define if compatibility should be provided for -mlong-double-64.])
 319     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 320   fi
 321 esac
 322 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 323
 324 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 325 GLIBCXX_CONFIGURE_TESTSUITE
 326
 327 # Propagate the target-specific source directories through the build chain.
 328 ATOMICITY_SRCDIR=config/${atomicity_dir}
 329 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 330 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 331 OS_INC_SRCDIR=config/${os_include_dir}
 332 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 333 AC_SUBST(ATOMICITY_SRCDIR)
 334 AC_SUBST(ATOMIC_WORD_SRCDIR)
 335 AC_SUBST(CPU_DEFINES_SRCDIR)
 336 AC_SUBST(ABI_TWEAKS_SRCDIR)
 337 AC_SUBST(OS_INC_SRCDIR)
 338
 339
 340 # Determine cross-compile flags and AM_CONDITIONALs.
 341 #AC_SUBST(GLIBCXX_IS_NATIVE)
 342 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 343 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 344 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 345 GLIBCXX_EVALUATE_CONDITIONALS
 346
 347 AC_CACHE_SAVE
 348
 349 if test ${multilib} = yes; then
 350   multilib_arg="--enable-multilib"
 351 else
 352   multilib_arg=
 353 fi
 354
 355 # Export all the install information.
 356 GLIBCXX_EXPORT_INSTALL_INFO
 357
 358 # Export all the include and flag information to Makefiles.
 359 GLIBCXX_EXPORT_INCLUDES
 360 GLIBCXX_EXPORT_FLAGS
 361
 362 if test "$enable_shared" = yes; then
 363   LIBSUPCXX_PICFLAGS="-prefer-pic"
 364 else
 365   LIBSUPCXX_PICFLAGS=
 366 fi
 367 AC_SUBST(LIBSUPCXX_PICFLAGS)
 368
 369 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 370 dnl which can all be called multiple times as needed, plus one (different)
 371 dnl AC_OUTPUT macro.  This one lists the files to be created:
 372 AC_CONFIG_FILES( \
 373   Makefile \
 374   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 375   )
 376 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 377
 378 dnl These commands are run at the end of config.status:
 379 AC_CONFIG_COMMANDS([default],
 380 [if test -n "$CONFIG_FILES"; then
 381    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 382    # that multilib installs will end up installed in the correct place.
 383    # The testsuite needs it for multilib-aware ABI baseline files.
 384    # To work around this not being passed down from config-ml.in ->
 385    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 386    # append it here.  Only modify Makefiles that have just been created.
 387    #
 388    # Also, get rid of this simulated-VPATH thing that automake does.
 389    cat > vpsed << \_EOF
 390 s!`test -f '$<' || echo '$(srcdir)/'`!!
 391 _EOF
 392    for i in $SUBDIRS; do
 393     case $CONFIG_FILES in
 394      *${i}/Makefile*)
 395        #echo "Adding MULTISUBDIR to $i/Makefile"
 396        sed -f vpsed $i/Makefile > tmp
 397        grep '^MULTISUBDIR =' Makefile >> tmp
 398        mv tmp $i/Makefile
 399        ;;
 400     esac
 401    done
 402    rm vpsed
 403  fi
 404  (cd include && ${MAKE-make})
 405 ],
 406 [
 407 # Variables needed in config.status (file generation) which aren't already
 408 # passed by autoconf.
 409 SUBDIRS="$SUBDIRS"
 410 ])
 411
 412 dnl And this actually makes things happen:
 413 AC_OUTPUT