libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:17:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  no-dist:  we don't want 'dist' and related rules.
  76 #  -Wall:  turns on all automake warnings...
  77 #  -Wno-portability:  ...except this one, since GNU make is now required.
  78 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  79 AH_TEMPLATE(PACKAGE, [Name of package])
  80 AH_TEMPLATE(VERSION, [Version number of package])
  81
  82 # -fno-builtin must be present here so that a non-conflicting form of
  83 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  84
  85 save_CXXFLAGS="$CXXFLAGS"
  86 CXXFLAGS="$CXXFLAGS -fno-builtin"
  87 AC_PROG_CC
  88 AC_PROG_CXX
  89 CXXFLAGS="$save_CXXFLAGS"
  90
  91 # Runs configure.host, and assorted other critical bits.  Sets
  92 # up critical shell variables.
  93 GLIBCXX_CONFIGURE
  94
  95 if test "x${with_newlib}" != "xyes"; then
  96   AC_LIBTOOL_DLOPEN
  97 fi
  98 AM_PROG_LIBTOOL
  99 ACX_LT_HOST_FLAGS
 100 AC_SUBST(enable_shared)
 101 AC_SUBST(enable_static)
 102
 103 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 104 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 105
 106 # Possibly disable most of the library.
 107 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 108 ## than just ignoring the results.  Faster /and/ more correct, win win.
 109 GLIBCXX_ENABLE_HOSTED
 110
 111 # Enable compiler support that doesn't require linking.
 112 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 113 GLIBCXX_ENABLE_PCH($is_hosted)
 114 GLIBCXX_ENABLE_THREADS
 115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 116 GLIBCXX_ENABLE_DECIMAL_FLOAT
 117
 118 # Checks for compiler support that doesn't require linking.
 119 GLIBCXX_CHECK_COMPILER_FEATURES
 120
 121 # Enable all the variable C++ runtime options that don't require linking.
 122 GLIBCXX_ENABLE_CSTDIO
 123 GLIBCXX_ENABLE_CLOCALE
 124 GLIBCXX_ENABLE_ALLOCATOR
 125 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 126 GLIBCXX_ENABLE_LONG_LONG([yes])
 127 GLIBCXX_ENABLE_WCHAR_T([yes])
 128 GLIBCXX_ENABLE_C99([yes])
 129 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 130 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 131 GLIBCXX_ENABLE_DEBUG([no])
 132 GLIBCXX_ENABLE_PARALLEL([yes])
 133 GLIBCXX_ENABLE_CXX_FLAGS
 134 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 135 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 136
 137 # Checks for operating systems support that doesn't require linking.
 138 GLIBCXX_CHECK_SYSTEM_ERROR
 139
 140 # For the streamoff typedef.
 141 GLIBCXX_CHECK_INT64_T
 142
 143 # For LFS support.
 144 GLIBCXX_CHECK_LFS
 145
 146 # For showmanyc_helper().
 147 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 148 GLIBCXX_CHECK_POLL
 149 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 150
 151 # For xsputn_2().
 152 AC_CHECK_HEADERS(sys/uio.h)
 153 GLIBCXX_CHECK_WRITEV
 154
 155 # For C99 support to TR1.
 156 GLIBCXX_CHECK_C99_TR1
 157
 158 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 159 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 160
 161 # For gettimeofday support.
 162 GLIBCXX_CHECK_GETTIMEOFDAY
 163
 164 # For clock_gettime, nanosleep and sched_yield support.
 165 # NB: The default is [no], because otherwise it requires linking.
 166 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 167
 168 # For gthread support
 169 GLIBCXX_CHECK_GTHREADS
 170
 171 AC_LC_MESSAGES
 172
 173 # For hardware_concurrency
 174 AC_CHECK_HEADERS(sys/sysinfo.h)
 175 GLIBCXX_CHECK_GET_NPROCS
 176 AC_CHECK_HEADERS(unistd.h)
 177 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 178
 179 # Check for available headers.
 180 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 181 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 182 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 183 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 184 wchar.h wctype.h])
 185
 186 # Only do link tests if native. Else, hardcode.
 187 if $GLIBCXX_IS_NATIVE; then
 188
 189   # We can do more elaborate tests that assume a working linker.
 190   CANADIAN=no
 191
 192   GLIBCXX_CHECK_LINKER_FEATURES
 193   GLIBCXX_CHECK_MATH_SUPPORT
 194   GLIBCXX_CHECK_STDLIB_SUPPORT
 195
 196   # For /dev/random and /dev/urandom for TR1.
 197   GLIBCXX_CHECK_RANDOM_TR1
 198
 199   # For TLS support.
 200   GCC_CHECK_TLS
 201
 202   # For iconv support.
 203   AM_ICONV
 204
 205 else
 206
 207   # This lets us hard-code the functionality we know we'll have in the cross
 208   # target environment.  "Let" is a sugar-coated word placed on an especially
 209   # dull and tedious hack, actually.
 210   #
 211   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 212   # that involve linking, can't be used:
 213   #    "cannot open sim-crt0.o"
 214   #    "cannot open crt0.o"
 215   # etc.  All this is because there currently exists no unified, consistent
 216   # way for top level CC information to be passed down to target directories:
 217   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 218   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 219   # crosses can be removed.
 220
 221   # If Canadian cross, then don't pick up tools from the build directory.
 222   # Used only in GLIBCXX_EXPORT_INCLUDES.
 223   if test -n "$with_cross_host" &&
 224      test x"$build_alias" != x"$with_cross_host" &&
 225      test x"$build" != x"$target";
 226   then
 227     CANADIAN=yes
 228   else
 229     CANADIAN=no
 230   fi
 231
 232   # Construct crosses by hand, eliminating bits that need ld...
 233   # GLIBCXX_CHECK_MATH_SUPPORT
 234
 235   # First, test for "known" system libraries.  We may be using newlib even
 236   # on a hosted environment.
 237   if test "x${with_newlib}" = "xyes"; then
 238     os_include_dir="os/newlib"
 239     AC_DEFINE(HAVE_HYPOT)
 240
 241     # GLIBCXX_CHECK_STDLIB_SUPPORT
 242     AC_DEFINE(HAVE_STRTOF)
 243
 244     AC_DEFINE(HAVE_ACOSF)
 245     AC_DEFINE(HAVE_ASINF)
 246     AC_DEFINE(HAVE_ATAN2F)
 247     AC_DEFINE(HAVE_ATANF)
 248     AC_DEFINE(HAVE_CEILF)
 249     AC_DEFINE(HAVE_COSF)
 250     AC_DEFINE(HAVE_COSHF)
 251     AC_DEFINE(HAVE_EXPF)
 252     AC_DEFINE(HAVE_FABSF)
 253     AC_DEFINE(HAVE_FLOORF)
 254     AC_DEFINE(HAVE_FMODF)
 255     AC_DEFINE(HAVE_FREXPF)
 256     AC_DEFINE(HAVE_LDEXPF)
 257     AC_DEFINE(HAVE_LOG10F)
 258     AC_DEFINE(HAVE_LOGF)
 259     AC_DEFINE(HAVE_MODFF)
 260     AC_DEFINE(HAVE_POWF)
 261     AC_DEFINE(HAVE_SINF)
 262     AC_DEFINE(HAVE_SINHF)
 263     AC_DEFINE(HAVE_SQRTF)
 264     AC_DEFINE(HAVE_TANF)
 265     AC_DEFINE(HAVE_TANHF)
 266
 267     AC_DEFINE(HAVE_ICONV)
 268   else
 269     GLIBCXX_CROSSCONFIG
 270   fi
 271
 272   # At some point, we should differentiate between architectures
 273   # like x86, which have long double versions, and alpha/powerpc/etc.,
 274   # which don't. For the time being, punt.
 275   if test x"long_double_math_on_this_cpu" = x"yes"; then
 276     AC_DEFINE(HAVE_ACOSL)
 277     AC_DEFINE(HAVE_ASINL)
 278     AC_DEFINE(HAVE_ATAN2L)
 279     AC_DEFINE(HAVE_ATANL)
 280     AC_DEFINE(HAVE_CEILL)
 281     AC_DEFINE(HAVE_COSL)
 282     AC_DEFINE(HAVE_COSHL)
 283     AC_DEFINE(HAVE_EXPL)
 284     AC_DEFINE(HAVE_FABSL)
 285     AC_DEFINE(HAVE_FLOORL)
 286     AC_DEFINE(HAVE_FMODL)
 287     AC_DEFINE(HAVE_FREXPL)
 288     AC_DEFINE(HAVE_LDEXPL)
 289     AC_DEFINE(HAVE_LOG10L)
 290     AC_DEFINE(HAVE_LOGL)
 291     AC_DEFINE(HAVE_MODFL)
 292     AC_DEFINE(HAVE_POWL)
 293     AC_DEFINE(HAVE_SINCOSL)
 294     AC_DEFINE(HAVE_SINL)
 295     AC_DEFINE(HAVE_SINHL)
 296     AC_DEFINE(HAVE_SQRTL)
 297     AC_DEFINE(HAVE_TANL)
 298     AC_DEFINE(HAVE_TANHL)
 299   fi
 300 fi
 301
 302 # Check for _Unwind_GetIPInfo.
 303 GCC_CHECK_UNWIND_GETIPINFO
 304
 305
 306 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 307
 308 GCC_HEADER_STDINT(include/gstdint.h)
 309
 310 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 311 GLIBCXX_ENABLE_SYMVERS([yes])
 312 GLIBCXX_ENABLE_VISIBILITY([yes])
 313
 314 ac_ldbl_compat=no
 315 case "$target" in
 316   powerpc*-*-linux* | \
 317   sparc*-*-linux* | \
 318   s390*-*-linux* | \
 319   alpha*-*-linux*)
 320   AC_TRY_COMPILE(, [
 321 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 322 #error no need for long double compatibility
 323 #endif
 324   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 325   if test "$ac_ldbl_compat" = yes; then
 326     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 327               [Define if compatibility should be provided for -mlong-double-64.])
 328     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 329   fi
 330 esac
 331 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 332
 333 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 334 GLIBCXX_CONFIGURE_TESTSUITE
 335
 336 # Define documentation rules conditionally.
 337
 338 # See if makeinfo has been installed and is modern enough
 339 # that we can use it.
 340 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 341                    [GNU texinfo.* \([0-9][0-9.]*\)],
 342                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 343 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 344
 345 # Check for doxygen
 346 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 347 AC_CHECK_PROG([DOT], dot, yes, no)
 348
 349 # Check for docbook
 350 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 351 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 352 GLIBCXX_CONFIGURE_DOCBOOK
 353
 354 # Check for xml/html dependencies.
 355 AM_CONDITIONAL(BUILD_XML,
 356                test $ac_cv_prog_DOXYGEN = "yes" &&
 357                test $ac_cv_prog_DOT = "yes" &&
 358                test $ac_cv_prog_XSLTPROC = "yes" &&
 359                test $ac_cv_prog_XMLLINT = "yes" &&
 360                test $glibcxx_stylesheets = "yes")
 361
 362 AM_CONDITIONAL(BUILD_HTML,
 363                test $ac_cv_prog_DOXYGEN = "yes" &&
 364                test $ac_cv_prog_DOT = "yes" &&
 365                test $ac_cv_prog_XSLTPROC = "yes" &&
 366                test $ac_cv_prog_XMLLINT = "yes" &&
 367                test $glibcxx_stylesheets = "yes")
 368
 369 # Check for man dependencies.
 370 AM_CONDITIONAL(BUILD_MAN,
 371                test $ac_cv_prog_DOXYGEN = "yes" &&
 372                test $ac_cv_prog_DOT = "yes")
 373
 374 # Check for pdf/epub dependencies.
 375 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 376 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 377 AM_CONDITIONAL(BUILD_PDF,
 378                test $ac_cv_prog_DBLATEX = "yes" &&
 379                test $ac_cv_prog_PDFLATEX = "yes")
 380
 381 AC_CHECK_PROG([RUBY], ruby, yes, no)
 382 AC_CHECK_PROG([DBTOEPUB], dbtoepub, yes, no)
 383 AM_CONDITIONAL(BUILD_EPUB,
 384                test $ac_cv_prog_RUBY = "yes" &&
 385                test $ac_cv_prog_DBTOEPUB = "yes")
 386
 387
 388 # Propagate the target-specific source directories through the build chain.
 389 ATOMICITY_SRCDIR=config/${atomicity_dir}
 390 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 391 ATOMIC_FLAGS=${atomic_flags}
 392 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 393 OS_INC_SRCDIR=config/${os_include_dir}
 394 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 395 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 396 AC_SUBST(ATOMICITY_SRCDIR)
 397 AC_SUBST(ATOMIC_WORD_SRCDIR)
 398 AC_SUBST(ATOMIC_FLAGS)
 399 AC_SUBST(CPU_DEFINES_SRCDIR)
 400 AC_SUBST(ABI_TWEAKS_SRCDIR)
 401 AC_SUBST(OS_INC_SRCDIR)
 402 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 403
 404
 405 # Determine cross-compile flags and AM_CONDITIONALs.
 406 #AC_SUBST(GLIBCXX_IS_NATIVE)
 407 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 408 GLIBCXX_EVALUATE_CONDITIONALS
 409
 410 AC_CACHE_SAVE
 411
 412 if test ${multilib} = yes; then
 413   multilib_arg="--enable-multilib"
 414 else
 415   multilib_arg=
 416 fi
 417
 418 # Export all the install information.
 419 GLIBCXX_EXPORT_INSTALL_INFO
 420
 421 # Export all the include and flag information to Makefiles.
 422 GLIBCXX_EXPORT_INCLUDES
 423 GLIBCXX_EXPORT_FLAGS
 424
 425 if test "$enable_shared" = yes; then
 426   LIBSUPCXX_PICFLAGS="-prefer-pic"
 427 else
 428   LIBSUPCXX_PICFLAGS=
 429 fi
 430 AC_SUBST(LIBSUPCXX_PICFLAGS)
 431
 432 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 433 dnl which can all be called multiple times as needed, plus one (different)
 434 dnl AC_OUTPUT macro.  This one lists the files to be created:
 435 AC_CONFIG_FILES(Makefile)
 436 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 437 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 438
 439 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 440 # that multilib installs will end up installed in the correct place.
 441 # The testsuite needs it for multilib-aware ABI baseline files.
 442 # To work around this not being passed down from config-ml.in ->
 443 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 444 # append it here.  Only modify Makefiles that have just been created.
 445 #
 446 # Also, get rid of this simulated-VPATH thing that automake does.
 447 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 448   [cat > vpsed$$ << \_EOF
 449 s!`test -f '$<' || echo '$(srcdir)/'`!!
 450 _EOF
 451    sed -f vpsed$$ $ac_file > tmp$$
 452    mv tmp$$ $ac_file
 453    rm vpsed$$
 454    echo 'MULTISUBDIR =' >> $ac_file
 455    ml_norecursion=yes
 456    . ${multi_basedir}/config-ml.in
 457    AS_UNSET([ml_norecursion])
 458 ])
 459
 460 AC_CONFIG_COMMANDS([generate-headers],
 461   [(cd include && ${MAKE-make} pch_build= )])
 462
 463 dnl And this actually makes things happen:
 464 AC_OUTPUT