libstdc++-v3/config/linker-map.gnu

   1 ## Linker script for GNU ld 2.11.94+ only.
   2 ##
   3 ## Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   4 ##
   5 ## This file is part of the libstdc++ version 3 distribution.
   6 ##
   7 ## This file is part of the GNU ISO C++ Library.  This library is free
   8 ## software; you can redistribute it and/or modify it under the
   9 ## terms of the GNU General Public License as published by the
  10 ## Free Software Foundation; either version 2, or (at your option)
  11 ## any later version.
  12 ##
  13 ## This library is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License along
  19 ## with this library; see the file COPYING.  If not, write to the Free
  20 ## Software Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  21 ## USA.
  22
  23 GLIBCPP_3.4 {
  24
  25   global:
  26
  27     # Names inside the 'extern' block are demangled names.
  28     # All but the last are terminated with a semicolon.
  29     extern "C++"
  30     {
  31       std::[A-Za]*;
  32       std::ba[a-r]*;
  33       std::basic_[a-r]*;
  34       std::basic_streambuf*;
  35       std::basic_stringbuf*;
  36       std::basic_stringstream*;
  37       std::basic_[t-z]*;
  38       std::ba[t-z]*;
  39       std::b[b-z]*;
  40       std::[A-Zc-k]*;
  41       std::length_error*;
  42       std::logic_error*;
  43       std::locale::[A-Za-e]*;
  44       std::locale::facet::[A-Za-z]*;
  45       std::locale::facet::_M*;
  46       std::locale::facet::_S_c_locale;
  47       std::locale::facet::_S_clone_c_locale*;
  48       std::locale::facet::_S_create_c_locale*;
  49       std::locale::facet::_S_destroy_c_locale*;
  50       std::locale::[A-Zg-h]*;
  51       std::locale::id::[A-Za-z]*;
  52       std::locale::id::_S_highwater;
  53       std::locale::[A-Zj-z]*;
  54       std::locale::_[A-Ha-z]*;
  55       std::locale::_Impl::[A-Za-z]*;
  56       std::locale::_Impl::_M_[A-Za-z]*;
  57       std::locale::_[J-Ra-z]*;
  58       std::locale::_S_normalize_category*;
  59       std::locale::_[T-Za-z]*;
  60       std::[A-Zm-z]*;
  61       std::__throw_*;
  62       std::__basic_file*;
  63       std::__num_base*;
  64       std::__timepunct*;
  65       std::__numeric_limits_base*;
  66
  67       # Needed only when generic cpu's atomicity.h is in use.
  68       __gnu_cxx::_Atomic_add_mutex;
  69       __gnu_cxx::_Atomic_add_mutex_once;
  70       __gnu_cxx::__gthread_atomic_add_mutex_once
  71     };
  72
  73     # Names not in an 'extern' block are mangled names.
  74
  75     # std::locale destructors
  76     _ZNSt6localeD*;
  77
  78     # std::locale::facet destructors
  79     _ZNSt6locale5facetD*;
  80
  81     # std::locale::_Impl constructors, destrutors
  82     _ZNSt6locale5_ImplC*;
  83     _ZNSt6locale5_ImplD*;
  84
  85     # bool has_facet
  86     _ZSt9has_facet*;
  87
  88     # std::string, std::wstring minus static data members
  89     _ZNKS[sb]*;
  90     _ZNS[sb]D*;
  91     _ZNS[sb]C*;
  92     _ZStplI[cw]St11char_traitsI[cw]ESaI[cw]EESbIT_T0_T1_EPKS3_RKS6_;
  93     _ZStplI[cw]St11char_traitsI[cw]ESaI[cw]EESbIT_T0_T1_ES3_RKS6_;
  94     _ZNS[sb]I[cw]St11char_traitsI[cw]ESaI[cw]EE[A-Ra-z]*;
  95     _ZNS[sb]I[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9][A-Ra-z]*;
  96     _ZNS[sb]I[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9][0-9][A-Ra-z]*;
  97     _ZNS[sb]I[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9]_[A-Ra-z]*;
  98     _ZNS[sb]I[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9][0-9]_[A-Ra-z]*;
  99     _ZNS[sb]I[cw]St11char_traitsI[cw]ESaI[cw]EE20_S_empty_rep_storageE;
 100
 101     # std::__pool_alloc
 102     _ZNSt12__pool_allocILb1ELi0EE10deallocateEPv[jm]*;
 103     _ZNSt12__pool_allocILb1ELi0EE8allocateE[jm]*;
 104     _ZNSt12__pool_allocILb1ELi0EE5_Lock*;
 105     _ZNSt12__pool_allocILb1ELi0EE12_S_force_newE;
 106     _ZNSt12__pool_allocILb1ELi0EE12_S_free_listE;
 107     _ZNSt12__pool_allocILb1ELi0EE7_S_lockE;
 108     _ZNSt12__pool_allocILb1ELi0EE9_S_refillE[jm];
 109
 110     # operator new(size_t)
 111     _Znw[jm];
 112     # operator new(size_t, std::nothrow_t const&)
 113     _Znw[jm]RKSt9nothrow_t;
 114
 115     # operator delete(void*)
 116     _ZdlPv;
 117     # operator delete(void*, std::nothrow_t const&)
 118     _ZdlPvRKSt9nothrow_t;
 119
 120     # operator new[](size_t)
 121     _Zna[jm];
 122     # operator new[](size_t, std::nothrow_t const&)
 123     _Zna[jm]RKSt9nothrow_t;
 124
 125     # operator delete[](void*)
 126     _ZdaPv;
 127     # operator delete[](void*, std::nothrow_t const&)
 128     _ZdaPvRKSt9nothrow_t;
 129
 130     # vtable
 131     _ZTV*;
 132     _ZTT*;
 133
 134     # typeinfo
 135     _ZTI*;
 136     _ZTS*;
 137
 138     # function-scope static objects requires a guard variable.
 139     _ZGV*;
 140
 141     # virtual function thunks
 142     _ZTh*;
 143     _ZTv*;
 144     _ZTc*;
 145
 146     # std::__convert_to_v
 147     _ZSt14__convert_to_v*;
 148
 149     # stub functions from libmath
 150     sinf;
 151     sinl;
 152     sinhf;
 153     sinhl;
 154     cosf;
 155     cosl;
 156     coshf;
 157     coshl;
 158     tanf;
 159     tanl;
 160     tanhf;
 161     tanhl;
 162     atan2f;
 163     atan2l;
 164     expf;
 165     expl;
 166     hypotf;
 167     hypotl;
 168     hypot;
 169     logf;
 170     logl;
 171     log10f;
 172     log10l;
 173     powf;
 174     powl;
 175     sqrtf;
 176     sqrtl;
 177     copysignf;
 178     nan;
 179     __signbit;
 180     __signbitf;
 181     __signbitl;
 182
 183   local:
 184     *;
 185 };
 186
 187
 188 # Symbols in the support library (libsupc++) have their own tag.
 189 CXXABI_1.3 {
 190
 191   global:
 192     __cxa_allocate_exception;
 193     __cxa_bad_cast;
 194     __cxa_bad_typeid;
 195     __cxa_begin_catch;
 196     __cxa_call_unexpected;
 197     __cxa_current_exception_type;
 198     __cxa_demangle;
 199     __cxa_end_catch;
 200     __cxa_free_exception;
 201     __cxa_get_globals;
 202     __cxa_get_globals_fast;
 203     __cxa_guard_abort;
 204     __cxa_guard_acquire;
 205     __cxa_guard_release;
 206     __cxa_pure_virtual;
 207     __cxa_rethrow;
 208     __cxa_throw;
 209     __cxa_vec_cctor;
 210     __cxa_vec_cleanup;
 211     __cxa_vec_ctor;
 212     __cxa_vec_delete2;
 213     __cxa_vec_delete3;
 214     __cxa_vec_delete;
 215     __cxa_vec_dtor;
 216     __cxa_vec_new2;
 217     __cxa_vec_new3;
 218     __cxa_vec_new;
 219     __gxx_personality_v0;
 220     __gxx_personality_sj0;
 221     __dynamic_cast;
 222
 223     # __gnu_cxx::_verbose_terminate_handler()
 224     _ZN9__gnu_cxx27__verbose_terminate_handlerEv;
 225
 226   local:
 227     *;
 228 };