libstdc++-v3/config/linker-map.gnu

   1 ## Linker script for GNU ld 2.11.94+ only.
   2 ##
   3 ## Copyright (C) 2002 Free Software Foundation, Inc.
   4 ##
   5 ## This file is part of the libstdc++ version 3 distribution.
   6 ##
   7 ## This file is part of the GNU ISO C++ Library.  This library is free
   8 ## software; you can redistribute it and/or modify it under the
   9 ## terms of the GNU General Public License as published by the
  10 ## Free Software Foundation; either version 2, or (at your option)
  11 ## any later version.
  12 ##
  13 ## This library is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License along
  19 ## with this library; see the file COPYING.  If not, write to the Free
  20 ## Software Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  21 ## USA.
  22
  23
  24 GLIBCPP_3.1 {
  25
  26   global:
  27
  28     # Names inside the 'extern' block are demangled names.
  29     # All but the last are terminated with a semicolon.
  30     extern "C++"
  31     {
  32       std::[A-Za-z]*;
  33       std::__throw_*;
  34       std::__basic_file*;
  35       std::__num_base*;
  36       std::__timepunct*;
  37       std::__numeric_limits_base*;
  38       std::_S_bit_count;
  39       std::_S_first_one;
  40       std::__default_alloc_template*;
  41       std::__malloc_alloc_template*
  42     };
  43
  44     # Names not in an 'extern' block are mangled names.
  45     _ZSt9has_facet*;
  46
  47     # operator new(unsigned)
  48     _Znwj;
  49     # operator new(unsigned, std::nothrow_t const&)
  50     _ZnwjRKSt9nothrow_t;
  51     # operator new(unsigned long)
  52     _Znwm;
  53     # operator new(unsigned long, std::nothrow_t const&)
  54     _ZnwmRKSt9nothrow_t;
  55
  56     # operator delete(void*)
  57     _ZdlPv;
  58     # operator delete(void*, std::nothrow_t const&)
  59     _ZdlPvRKSt9nothrow_t;
  60
  61     # operator new[](unsigned)
  62     _Znaj;
  63     # operator new[](unsigned, std::nothrow_t const&)
  64     _ZnajRKSt9nothrow_t;
  65     # operator new[](unsigned long)
  66     _Znam;
  67     # operator new[](unsigned long, std::nothrow_t const&)
  68     _ZnamRKSt9nothrow_t;
  69
  70     # operator delete[](void*)
  71     _ZdaPv;
  72     # operator delete[](void*, std::nothrow_t const&)
  73     _ZdaPvRKSt9nothrow_t;
  74
  75     # vtable
  76     _ZTV*;
  77     _ZTT*;
  78
  79     # typeinfo
  80     _ZTI*;
  81     _ZTS*;
  82
  83     # function-scope static objects requires a guard variable.
  84     _ZGV*;
  85
  86     # virtual function thunks
  87     _ZTh*;
  88     _ZTv*;
  89     _ZTc*;
  90
  91     # std::__convert_to_v
  92     _ZSt14__convert_to_v*;
  93
  94   local:
  95     *;
  96 };
  97
  98
  99 # Symbols in the support library (libsupc++) have their own tag.
 100 CXXABI_1 {
 101
 102   global:
 103     __cxa_*;
 104     __gxx_personality_v0;
 105     __gxx_personality_sj0;
 106     __dynamic_cast;
 107
 108     # __gnu_cxx::_verbose_terminate_handler()
 109     _ZN9__gnu_cxx27__verbose_terminate_handlerEv;
 110
 111   local:
 112     *;
 113 };