libstdc++-v3/config/linker-map.gnu

   1 ## Linker script for GNU ld 2.11.94+ only.
   2 ##
   3 ## Copyright (C) 2002 Free Software Foundation, Inc.
   4 ##
   5 ## This file is part of the libstdc++ version 3 distribution.
   6 ##
   7 ## This file is part of the GNU ISO C++ Library.  This library is free
   8 ## software; you can redistribute it and/or modify it under the
   9 ## terms of the GNU General Public License as published by the
  10 ## Free Software Foundation; either version 2, or (at your option)
  11 ## any later version.
  12 ##
  13 ## This library is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License along
  19 ## with this library; see the file COPYING.  If not, write to the Free
  20 ## Software Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  21 ## USA.
  22
  23 GLIBCPP_3.2 {
  24
  25   global:
  26
  27     # Names inside the 'extern' block are demangled names.
  28     # All but the last are terminated with a semicolon.
  29     extern "C++"
  30     {
  31       std::[A-Za-b]*;
  32       std::c[a-n]*;
  33       std::co[a-c]*;
  34       std::codecvt_byname*;
  35       std::codecvt::[A-Za-b]*;
  36       std::codecvt::[A-Zd-z]*;
  37       std::codecvt_c;
  38       std::codecvt_w;
  39       std::co[e-z]*;
  40       std::c[p-z]*;
  41       std::c_[a-z]*;
  42       std::[A-Zd-k]*;
  43       std::length_error*;
  44       std::logic_error*;
  45       std::locale::[A-Za-z]*;
  46       std::locale::_[A-Ra-z]*;
  47       std::locale::_S_classic;
  48       std::locale::_S_global;
  49       std::locale::_S_num_categories;
  50       std::locale::_S_normalize_category*;
  51       std::locale::_[T-Za-z]*;
  52       std::[A-Zm-z]*;
  53       std::__throw_*;
  54       std::__basic_file*;
  55       std::__num_base*;
  56       std::__timepunct*;
  57       std::__numeric_limits_base*;
  58       std::_S_bit_count;
  59       std::_S_first_one;
  60       std::__default_alloc_template*;
  61       std::__malloc_alloc_template*
  62     };
  63
  64     # Names not in an 'extern' block are mangled names.
  65
  66     # std::locale destructors
  67     _ZNSt6localeD*;
  68
  69     # std::codecvt<char> members.
  70     _ZNKSt7codecvtIcc11__mbstate_tE*;
  71     # std::codecvt<char>::~codecvt
  72     _ZNSt7codecvtIcc11__mbstate_tED*;
  73     # std::codecvt<char>::codecvt default
  74     _ZNSt7codecvtIcc11__mbstate_tEC1Ej;
  75     _ZNSt7codecvtIcc11__mbstate_tEC2Ej;
  76     # std::codecvt<char>::id
  77     _ZNSt7codecvtIcc11__mbstate_tE2idE;
  78
  79     # std::codecvt<wchar_t> members.
  80     _ZNKSt7codecvtIwc11__mbstate_tE*;
  81     # std::codecvt<wchar_t>::~codecvt
  82     _ZNSt7codecvtIwc11__mbstate_tED*;
  83     # std::codecvt<wchar_t>::codecvt default
  84     _ZNSt7codecvtIwc11__mbstate_tEC1Ej;
  85     _ZNSt7codecvtIwc11__mbstate_tEC2Ej;
  86     # std::codecvt<wchar_t>::id
  87     _ZNSt7codecvtIwc11__mbstate_tE2idE;
  88
  89      # std::use_facet<codecvt>
  90     _ZSt9use_facetISt7codecvtIcc11__mbstate_tEERKT_RKSt6locale;
  91     _ZSt9use_facetISt7codecvtIwc11__mbstate_tEERKT_RKSt6locale;
  92
  93     # std::has_facet*
  94     _ZSt9has_facet*;
  95
  96     # operator new(unsigned)
  97     _Znwj;
  98     # operator new(unsigned, std::nothrow_t const&)
  99     _ZnwjRKSt9nothrow_t;
 100     # operator new(unsigned long)
 101     _Znwm;
 102     # operator new(unsigned long, std::nothrow_t const&)
 103     _ZnwmRKSt9nothrow_t;
 104
 105     # operator delete(void*)
 106     _ZdlPv;
 107     # operator delete(void*, std::nothrow_t const&)
 108     _ZdlPvRKSt9nothrow_t;
 109
 110     # operator new[](unsigned)
 111     _Znaj;
 112     # operator new[](unsigned, std::nothrow_t const&)
 113     _ZnajRKSt9nothrow_t;
 114     # operator new[](unsigned long)
 115     _Znam;
 116     # operator new[](unsigned long, std::nothrow_t const&)
 117     _ZnamRKSt9nothrow_t;
 118
 119     # operator delete[](void*)
 120     _ZdaPv;
 121     # operator delete[](void*, std::nothrow_t const&)
 122     _ZdaPvRKSt9nothrow_t;
 123
 124     # vtable
 125     _ZTV*;
 126     _ZTT*;
 127
 128     # typeinfo
 129     _ZTI*;
 130     _ZTS*;
 131
 132     # function-scope static objects requires a guard variable.
 133     _ZGV*;
 134
 135     # virtual function thunks
 136     _ZTh*;
 137     _ZTv*;
 138     _ZTc*;
 139
 140     # std::__convert_to_v
 141     _ZSt14__convert_to_v*;
 142
 143   local:
 144     *;
 145 };
 146
 147 # Symbols added after GLIBCPP_3.2
 148 GLIBCPP_3.2.1 {
 149
 150   _ZNSt7codecvtIcc11__mbstate_tEC1EP15__locale_structj;
 151   _ZNSt7codecvtIcc11__mbstate_tEC2EP15__locale_structj;
 152   _ZNSt7codecvtIwc11__mbstate_tEC1EP15__locale_structj;
 153   _ZNSt7codecvtIwc11__mbstate_tEC2EP15__locale_structj;
 154
 155 } GLIBCPP_3.2;
 156
 157 # Symbols in the support library (libsupc++) have their own tag.
 158 CXXABI_1.2 {
 159
 160   global:
 161     __cxa_*;
 162     __gxx_personality_v0;
 163     __gxx_personality_sj0;
 164     __dynamic_cast;
 165
 166     # __gnu_cxx::_verbose_terminate_handler()
 167     _ZN9__gnu_cxx27__verbose_terminate_handlerEv;
 168
 169   local:
 170     *;
 171 };