libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize configure bits.
  15 dnl
  16 dnl GLIBCPP_CONFIGURE
  17 AC_DEFUN(GLIBCPP_CONFIGURE, [
  18   dnl Default to --enable-multilib
  19   AC_ARG_ENABLE(multilib,
  20   [  --enable-multilib       build hella library versions (default)],
  21   [case "${enableval}" in
  22     yes) multilib=yes ;;
  23     no)  multilib=no ;;
  24     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  25    esac], [multilib=yes])dnl
  26
  27 # When building with srcdir == objdir, links to the source files will
  28 # be created in directories within the target_subdir.  We have to
  29 # adjust toplevel_srcdir accordingly, so that configure finds
  30 # install-sh and other auxiliary files that live in the top-level
  31 # source directory.
  32 if test "${srcdir}" = "."; then
  33   if test -z "${with_target_subdir}"; then
  34     toprel=".."
  35   else
  36     if test "${with_target_subdir}" != "."; then
  37       toprel="${with_multisrctop}../.."
  38     else
  39       toprel="${with_multisrctop}.."
  40     fi
  41   fi
  42 else
  43   toprel=".."
  44 fi
  45 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  46 toplevel_srcdir=\${top_srcdir}/$toprel
  47 AC_SUBST(toplevel_srcdir)
  48
  49 # Export build and source directories.
  50 # These need to be absolute paths, yet at the same time need to
  51 # canonicalize only relative paths, because then amd will not unmount
  52 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  53 glibcpp_builddir=`pwd`
  54 case $srcdir in
  55 [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  56 *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  57 esac
  58 AC_SUBST(glibcpp_builddir)
  59 AC_SUBST(glibcpp_srcdir)
  60
  61 dnl This is here just to satisfy automake.
  62 ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  63
  64 # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.50+, can also
  65 # be 'cp -p' if linking isn't available.
  66 #ac_cv_prog_LN_S='cp -p'
  67 AC_PROG_LN_S
  68
  69 # We use these options to decide which functions to include.
  70 AC_ARG_WITH(target-subdir,
  71 [  --with-target-subdir=SUBDIR
  72                            configuring in a subdirectory])
  73 AC_ARG_WITH(cross-host,
  74 [  --with-cross-host=HOST  configuring with a cross compiler])
  75
  76   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  77   AC_SUBST(glibcpp_basedir)
  78
  79   # Never versions of autoconf add an underscore to these functions.
  80   # Prevent future problems ...
  81   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  82   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  83   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  84   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  85
  86 #  AC_PROG_CC
  87
  88 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  89 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  90 # are probably using a cross compiler, which will not be able to fully
  91 # link an executable.  This should really be fixed in autoconf
  92 # itself.
  93
  94 AC_DEFUN(LIB_AC_PROG_CC,
  95 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  96 dnl Fool anybody using AC_PROG_CC.
  97 AC_PROVIDE([AC_PROG_CC])
  98 AC_CHECK_PROG(CC, gcc, gcc)
  99 if test -z "$CC"; then
 100   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
 101   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
 102 fi
 103
 104 AC_PROG_CC_GNU
 105
 106 if test $ac_cv_prog_gcc = yes; then
 107   GCC=yes
 108 dnl Check whether -g works, even if CFLAGS is set, in case the package
 109 dnl plays around with CFLAGS (such as to build both debugging and
 110 dnl normal versions of a library), tasteless as that idea is.
 111   ac_test_CFLAGS="${CFLAGS+set}"
 112   ac_save_CFLAGS="$CFLAGS"
 113   CFLAGS=
 114   AC_PROG_CC_G
 115   if test "$ac_test_CFLAGS" = set; then
 116     CFLAGS="$ac_save_CFLAGS"
 117   elif test $ac_cv_prog_cc_g = yes; then
 118     CFLAGS="-g -O2"
 119   else
 120     CFLAGS="-O2"
 121   fi
 122 else
 123   GCC=
 124   test "${CFLAGS+set}" = set || CFLAGS="-g"
 125 fi
 126 ])
 127
 128 LIB_AC_PROG_CC
 129
 130 # Can't just call these here as g++ requires libstc++ to be built....
 131 #  AC_PROG_CXX
 132
 133 # Likewise for AC_PROG_CXX.
 134 AC_DEFUN(LIB_AC_PROG_CXX,
 135 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 136 dnl Fool anybody using AC_PROG_CXX.
 137 AC_PROVIDE([AC_PROG_CXX])
 138 # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 139 # flags that come in CXX while configuring libstdc++.  They're different
 140 # from those used for all other target libraries.  If CXX is set in
 141 # the environment, respect that here.
 142 glibcpp_CXX=$CXX
 143 AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 144 AC_SUBST(glibcpp_CXX)
 145 CXX=$glibcpp_CXX
 146 test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 147
 148 AC_PROG_CXX_GNU
 149
 150 if test $ac_cv_prog_gxx = yes; then
 151   GXX=yes
 152 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 153 dnl plays around with CXXFLAGS (such as to build both debugging and
 154 dnl normal versions of a library), tasteless as that idea is.
 155   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 156   ac_save_CXXFLAGS="$CXXFLAGS"
 157   CXXFLAGS=
 158   AC_PROG_CXX_G
 159   if test "$ac_test_CXXFLAGS" = set; then
 160     CXXFLAGS="$ac_save_CXXFLAGS"
 161   elif test $ac_cv_prog_cxx_g = yes; then
 162     CXXFLAGS="-g -O2"
 163   else
 164     CXXFLAGS="-O2"
 165   fi
 166 else
 167   GXX=
 168   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 169 fi
 170 ])
 171
 172 LIB_AC_PROG_CXX
 173
 174    # For some reason, gettext needs this.
 175    AC_ISC_POSIX
 176
 177   AC_CHECK_TOOL(AS, as)
 178   AC_CHECK_TOOL(AR, ar)
 179   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 180   AC_PROG_INSTALL
 181
 182   AM_MAINTAINER_MODE
 183
 184   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 185   # at least currently, we never actually build a program, so we never
 186   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 187   # fails, because we are probably configuring with a cross compiler
 188   # which cant create executables.  So we include AC_EXEEXT to keep
 189   # automake happy, but we dont execute it, since we dont care about
 190   # the result.
 191   if false; then
 192     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 193     # to nothing, so nothing would remain between `then' and `fi' if it
 194     # were not for the `:' below.
 195     :
 196     AC_EXEEXT
 197   fi
 198
 199   . [$]{glibcpp_basedir}/configure.host
 200
 201   case [$]{glibcpp_basedir} in
 202     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 203     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 204   esac
 205
 206   # This does for the target what configure.host does for the host.  In
 207   # addition to possibly modifying the same flags, it also sets up symlinks.
 208   GLIBCPP_CHECK_TARGET
 209
 210   #
 211 ])
 212
 213
 214 dnl
 215 dnl Check to see if g++ can compile this library, and if so, if any version-
 216 dnl specific precautions need to be taken.
 217 dnl
 218 dnl GLIBCPP_CHECK_COMPILER_VERSION
 219 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 220 if test ! -f stamp-sanity-compiler; then
 221   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 222   AC_LANG_SAVE
 223   AC_LANG_CPLUSPLUS
 224   AC_TRY_COMPILE(, [
 225   #if __GNUC__ < 3
 226     not_ok
 227   #endif
 228   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 229   AC_LANG_RESTORE
 230   AC_MSG_RESULT($gpp_satisfactory)
 231   touch stamp-sanity-compiler
 232 fi
 233 ])
 234
 235
 236 dnl
 237 dnl Tests for newer compiler features, or features that are present in newer
 238 dnl compiler versions but not older compiler versions still in use, should
 239 dnl be placed here.
 240 dnl
 241 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 242 dnl new inlining code or the new system_header pragma will die on -Werror.
 243 dnl Leave it out by default and use maint-mode to use it.
 244 dnl
 245 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 246 dnl compiler supports it and the user has not requested debug mode.
 247 dnl
 248 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 249 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 250   # All these tests are for C++; save the language and the compiler flags.
 251   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 252   # found in GLIBCPP_CONFIGURE.
 253   AC_LANG_SAVE
 254   AC_LANG_CPLUSPLUS
 255   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 256   ac_save_CXXFLAGS="$CXXFLAGS"
 257
 258   # Check for maintainer-mode bits.
 259   if test x"$USE_MAINTAINER_MODE" = xno; then
 260     WERROR=''
 261   else
 262     WERROR='-Werror'
 263   fi
 264
 265   # Check for -ffunction-sections -fdata-sections
 266   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 267   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 268   AC_TRY_COMPILE(, [int foo;
 269   ], [ac_fdsections=yes], [ac_fdsections=no])
 270   if test "$ac_test_CXXFLAGS" = set; then
 271     CXXFLAGS="$ac_save_CXXFLAGS"
 272   else
 273     # this is the suspicious part
 274     CXXFLAGS=''
 275   fi
 276   if test x"$ac_fdsections" = x"yes" &&
 277      test x"$enable_debug" = x"no"; then
 278     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 279   fi
 280   AC_MSG_RESULT($ac_fdsections)
 281
 282   AC_LANG_RESTORE
 283   AC_SUBST(WERROR)
 284   AC_SUBST(SECTION_FLAGS)
 285 ])
 286
 287
 288 dnl
 289 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 290 dnl the native linker is in use, all variables will be defined to something
 291 dnl safe (like an empty string).
 292 dnl
 293 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 294 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 295 dnl
 296 dnl GLIBCPP_CHECK_LINKER_FEATURES
 297 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 298   # If we're not using GNU ld, then there's no point in even trying these
 299   # tests.  Check for that first.  We should have already tested for gld
 300   # by now (in libtool), but require it now just to be safe...
 301   SECTION_LDFLAGS=''
 302   OPT_LDFLAGS=''
 303   AC_REQUIRE([AC_PROG_LD])
 304
 305   # Set --gc-sections.
 306   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 307     # GNU ld it is!  Joy and bunny rabbits!
 308
 309     # All these tests are for C++; save the language and the compiler flags.
 310     # Need to do this so that g++ won't try to link in libstdc++
 311     ac_test_CFLAGS="${CFLAGS+set}"
 312     ac_save_CFLAGS="$CFLAGS"
 313     CFLAGS='-x c++  -Wl,--gc-sections'
 314
 315     # Check for -Wl,--gc-sections
 316     # XXX This test is broken at the moment, as symbols required for
 317     # linking are now in libsupc++ (not built yet.....). In addition,
 318     # this test has cored on solaris in the past. In addition,
 319     # --gc-sections doesn't really work at the moment (keeps on discarding
 320     # used sections, first .eh_frame and now some of the glibc sections for
 321     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 322     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 323     AC_TRY_RUN([
 324      int main(void)
 325      {
 326        try { throw 1; }
 327        catch (...) { };
 328        return 0;
 329      }
 330     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 331     if test "$ac_test_CFLAGS" = set; then
 332       CFLAGS="$ac_save_CFLAGS"
 333     else
 334       # this is the suspicious part
 335       CFLAGS=''
 336     fi
 337     if test "$ac_sectionLDflags" = "yes"; then
 338       SECTION_LDFLAGS='-Wl,--gc-sections'
 339     fi
 340     AC_MSG_RESULT($ac_sectionLDflags)
 341   fi
 342
 343   # Set linker optimization flags.
 344   if test x"$ac_cv_prog_gnu_ld" = x"yes" &&
 345      test x"$enable_debug" = x"no"; then
 346     OPT_LDFLAGS='-Wl,-O1'
 347   fi
 348
 349   AC_SUBST(SECTION_LDFLAGS)
 350   AC_SUBST(OPT_LDFLAGS)
 351 ])
 352
 353
 354 dnl
 355 dnl Check to see if the (math function) argument passed is
 356 dnl declared when using the c++ compiler
 357 dnl ASSUMES argument is a math function with ONE parameter
 358 dnl
 359 dnl GLIBCPP_CHECK_MATH_DECL_1
 360 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 361   AC_MSG_CHECKING([for $1 declaration])
 362   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 363     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 364       AC_LANG_SAVE
 365       AC_LANG_CPLUSPLUS
 366       AC_TRY_COMPILE([#include <math.h>
 367                       #ifdef HAVE_IEEEFP_H
 368                       #include <ieeefp.h>
 369                       #endif
 370                      ],
 371                      [ $1(0);],
 372                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 373       AC_LANG_RESTORE
 374     ])
 375   fi
 376   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 377 ])
 378
 379 dnl
 380 dnl Check to see if the (math function) argument passed is
 381 dnl 1) declared when using the c++ compiler
 382 dnl 2) has "C" linkage
 383 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 384 dnl
 385 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 386 dnl
 387 dnl argument 1 is name of function to check
 388 dnl
 389 dnl ASSUMES argument is a math function with ONE parameter
 390 dnl
 391 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 392 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 393   GLIBCPP_CHECK_MATH_DECL_1($1)
 394   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 395     AC_CHECK_FUNCS($1)
 396   else
 397     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 398     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 399       AC_CHECK_FUNCS(_$1)
 400     fi
 401   fi
 402 ])
 403
 404
 405 dnl
 406 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 407 dnl of functions at once.  It's an all-or-nothing check -- either
 408 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 409 dnl Doing it this way saves significant configure time.
 410 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 411   AC_MSG_CHECKING([for $1 functions])
 412   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 413     AC_LANG_SAVE
 414     AC_LANG_CPLUSPLUS
 415     AC_TRY_COMPILE([#include <math.h>],
 416                    [ `for x in $3; do echo "$x (0);"; done` ],
 417                    [glibcpp_cv_func_$2_use=yes],
 418                    [glibcpp_cv_func_$2_use=no])
 419     AC_LANG_RESTORE])
 420   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 421   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 422     AC_CHECK_FUNCS($3)
 423   fi
 424 ])
 425
 426 dnl
 427 dnl Check to see if the (math function) argument passed is
 428 dnl declared when using the c++ compiler
 429 dnl ASSUMES argument is a math function with TWO parameters
 430 dnl
 431 dnl GLIBCPP_CHECK_MATH_DECL_2
 432 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 433   AC_MSG_CHECKING([for $1 declaration])
 434   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 435     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 436       AC_LANG_SAVE
 437       AC_LANG_CPLUSPLUS
 438       AC_TRY_COMPILE([#include <math.h>],
 439                      [ $1(0, 0);],
 440                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 441       AC_LANG_RESTORE
 442     ])
 443   fi
 444   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 445 ])
 446
 447 dnl
 448 dnl Check to see if the (math function) argument passed is
 449 dnl 1) declared when using the c++ compiler
 450 dnl 2) has "C" linkage
 451 dnl
 452 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 453 dnl
 454 dnl argument 1 is name of function to check
 455 dnl
 456 dnl ASSUMES argument is a math function with TWO parameters
 457 dnl
 458 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 459 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 460   GLIBCPP_CHECK_MATH_DECL_2($1)
 461   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 462     AC_CHECK_FUNCS($1)
 463   else
 464     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 465     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 466       AC_CHECK_FUNCS(_$1)
 467     fi
 468   fi
 469 ])
 470
 471
 472 dnl
 473 dnl Check to see if the (math function) argument passed is
 474 dnl declared when using the c++ compiler
 475 dnl ASSUMES argument is a math function with THREE parameters
 476 dnl
 477 dnl GLIBCPP_CHECK_MATH_DECL_3
 478 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 479   AC_MSG_CHECKING([for $1 declaration])
 480   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 481     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 482       AC_LANG_SAVE
 483       AC_LANG_CPLUSPLUS
 484       AC_TRY_COMPILE([#include <math.h>],
 485                      [ $1(0, 0, 0);],
 486                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 487       AC_LANG_RESTORE
 488     ])
 489   fi
 490   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 491 ])
 492
 493 dnl
 494 dnl Check to see if the (math function) argument passed is
 495 dnl 1) declared when using the c++ compiler
 496 dnl 2) has "C" linkage
 497 dnl
 498 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 499 dnl
 500 dnl argument 1 is name of function to check
 501 dnl
 502 dnl ASSUMES argument is a math function with THREE parameters
 503 dnl
 504 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 505 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 506   GLIBCPP_CHECK_MATH_DECL_3($1)
 507   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 508     AC_CHECK_FUNCS($1)
 509   else
 510     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 511     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 512       AC_CHECK_FUNCS(_$1)
 513     fi
 514   fi
 515 ])
 516
 517
 518 dnl
 519 dnl Check to see if the (stdlib function) argument passed is
 520 dnl 1) declared when using the c++ compiler
 521 dnl 2) has "C" linkage
 522 dnl
 523 dnl argument 1 is name of function to check
 524 dnl
 525 dnl ASSUMES argument is a math function with TWO parameters
 526 dnl
 527 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 528 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 529   AC_MSG_CHECKING([for $1 declaration])
 530   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 531     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 532       AC_LANG_SAVE
 533       AC_LANG_CPLUSPLUS
 534       AC_TRY_COMPILE([#include <stdlib.h>],
 535                      [ $1(0, 0);],
 536                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 537       AC_LANG_RESTORE
 538     ])
 539   fi
 540   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 541   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 542     AC_CHECK_FUNCS($1)
 543   fi
 544 ])
 545
 546
 547 dnl
 548 dnl Because the builtins are picky picky picky about the arguments they take,
 549 dnl do an explict linkage tests here.
 550 dnl Check to see if the (math function) argument passed is
 551 dnl 1) declared when using the c++ compiler
 552 dnl 2) has "C" linkage
 553 dnl
 554 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 555 dnl
 556 dnl argument 1 is name of function to check
 557 dnl
 558 dnl ASSUMES argument is a math function with ONE parameter
 559 dnl
 560 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 561 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 562   AC_MSG_CHECKING([for $1 declaration])
 563   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 564     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 565       AC_LANG_SAVE
 566       AC_LANG_CPLUSPLUS
 567       AC_TRY_COMPILE([#include <math.h>],
 568                      [ $1(0);],
 569                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 570       AC_LANG_RESTORE
 571     ])
 572   fi
 573   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 574   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 575     AC_MSG_CHECKING([for $1 linkage])
 576     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 577       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 578         AC_TRY_LINK([#include <math.h>],
 579                     [ $1(0);],
 580                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 581       ])
 582     fi
 583     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 584     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 585       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 586       AC_DEFINE_UNQUOTED(${ac_tr_func})
 587     fi
 588   fi
 589 ])
 590
 591
 592 dnl
 593 dnl Check to see what builtin math functions are supported
 594 dnl
 595 dnl check for __builtin_abs
 596 dnl check for __builtin_fabsf
 597 dnl check for __builtin_fabs
 598 dnl check for __builtin_fabl
 599 dnl check for __builtin_labs
 600 dnl check for __builtin_sqrtf
 601 dnl check for __builtin_sqrtl
 602 dnl check for __builtin_fsqrt
 603 dnl check for __builtin_sinf
 604 dnl check for __builtin_sin
 605 dnl check for __builtin_sinl
 606 dnl check for __builtin_cosf
 607 dnl check for __builtin_cos
 608 dnl check for __builtin_cosl
 609 dnl
 610 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 611 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 612   dnl Test for builtin math functions.
 613   dnl These are made in gcc/c-common.c
 614   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 615   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 616   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 617   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 618   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 619
 620   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 621   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fsqrt)
 622   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 623
 624   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 625   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 626   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 627
 628   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 629   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 630   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 631
 632   dnl There is, without a doubt, a more elegant way to have these
 633   dnl names exported so that they won't be stripped out of acconfig.h by
 634   dnl autoheader. I leave this as an exercise to somebody less frustrated
 635   dnl than I.... please email the libstdc++ list if you can figure out a
 636   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 637   dnl AC_CHECK_FUNC for things to steal.)
 638   dummyvar=no
 639   if test x$dummyvar = x"yes"; then
 640     AC_DEFINE(HAVE___BUILTIN_ABS)
 641     AC_DEFINE(HAVE___BUILTIN_LABS)
 642     AC_DEFINE(HAVE___BUILTIN_COS)
 643     AC_DEFINE(HAVE___BUILTIN_COSF)
 644     AC_DEFINE(HAVE___BUILTIN_COSL)
 645     AC_DEFINE(HAVE___BUILTIN_FABS)
 646     AC_DEFINE(HAVE___BUILTIN_FABSF)
 647     AC_DEFINE(HAVE___BUILTIN_FABSL)
 648     AC_DEFINE(HAVE___BUILTIN_SIN)
 649     AC_DEFINE(HAVE___BUILTIN_SINF)
 650     AC_DEFINE(HAVE___BUILTIN_SINL)
 651     AC_DEFINE(HAVE___BUILTIN_FSQRT)
 652     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 653     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 654   fi
 655 ])
 656
 657
 658 dnl
 659 dnl Check to see what the underlying c library
 660 dnl These checks need to do two things:
 661 dnl 1) make sure the name is declared when using the c++ compiler
 662 dnl 2) make sure the name has "C" linkage
 663 dnl This might seem like overkill but experience has shown that it's not...
 664 dnl
 665 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 666 dnl Define HAVE_STRTOF if "strtof" is declared and links
 667 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 668 dnl
 669 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 670 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 671   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 672   ac_save_CXXFLAGS="$CXXFLAGS"
 673   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 674
 675   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 676   AC_CHECK_FUNCS(drand48)
 677
 678   CXXFLAGS="$ac_save_CXXFLAGS"
 679 ])
 680
 681
 682 dnl
 683 dnl Check to see what the underlying c library or math library is like.
 684 dnl These checks need to do two things:
 685 dnl 1) make sure the name is declared when using the c++ compiler
 686 dnl 2) make sure the name has "C" linkage
 687 dnl This might seem like overkill but experience has shown that it's not...
 688 dnl
 689 dnl Define HAVE_CARGF etc if "cargf" is found.
 690 dnl
 691 dnl GLIBCPP_CHECK_MATH_SUPPORT
 692 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 693   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 694   ac_save_CXXFLAGS="$CXXFLAGS"
 695   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 696
 697   dnl Check libm
 698   AC_CHECK_LIB(m, sin, libm="-lm")
 699   ac_save_LIBS="$LIBS"
 700   LIBS="$LIBS $libm"
 701
 702   dnl Check to see if certain C math functions exist.
 703   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 704   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 705   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 706   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 707   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 708   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 709   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 710   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 711
 712   dnl Check to see if basic C math functions have float versions.
 713   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 714                                           float_trig,
 715                                           acosf asinf atanf \
 716                                           cosf sinf tanf \
 717                                           coshf sinhf tanhf)
 718   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 719                                           float_round,
 720                                           ceilf floorf)
 721   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 722   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 723   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 724   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 725   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 726   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 727   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 728   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 729   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 730   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 731   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 732   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 733   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 734   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 735   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 736
 737   dnl Check to see if basic C math functions have long double versions.
 738   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 739                                           long_double_trig,
 740                                           acosl asinl atanl \
 741                                           cosl sinl tanl \
 742                                           coshl sinhl tanhl)
 743   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 744                                           long_double_round,
 745                                           ceill floorl)
 746   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 747   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 748   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 749   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 750   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 751   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 752   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 753   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 754   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 755   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 756   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 757   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 758   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 759   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 760   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 761   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 762   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 763
 764   dnl Some runtimes have these functions with a preceding underscore. Please
 765   dnl keep this sync'd with the one above. And if you add any new symbol,
 766   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 767   dnl Check to see if certain C math functions exist.
 768
 769   dnl Check to see if basic C math functions have float versions.
 770   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 771                                           _float_trig,
 772                                           _acosf _asinf _atanf \
 773                                           _cosf _sinf _tanf \
 774                                           _coshf _sinhf _tanhf)
 775   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 776                                           _float_round,
 777                                           _ceilf _floorf)
 778
 779   dnl Check to see if basic C math functions have long double versions.
 780   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 781                                           _long_double_trig,
 782                                           _acosl _asinl _atanl \
 783                                           _cosl _sinl _tanl \
 784                                           _coshl _sinhl _tanhl)
 785   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 786                                           _long_double_round,
 787                                           _ceill _floorl)
 788
 789   LIBS="$ac_save_LIBS"
 790   CXXFLAGS="$ac_save_CXXFLAGS"
 791 ])
 792
 793
 794 dnl
 795 dnl Check to see if there is native support for complex
 796 dnl
 797 dnl Don't compile bits in math/* if native support exits.
 798 dnl
 799 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 800 dnl
 801 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 802 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 803   dnl Check for complex versions of math functions of platform.
 804   AC_CHECK_LIB(m, main)
 805   AC_REPLACE_MATHFUNCS(nan copysignf)
 806
 807   dnl Compile the long double complex functions only if the function
 808   dnl provides the non-complex long double functions that are needed.
 809   dnl Currently this includes copysignl, which should be
 810   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 811   USE_COMPLEX_LONG_DOUBLE=no
 812   if test x$ac_cv_func_copysignl = x"yes"; then
 813     USE_COMPLEX_LONG_DOUBLE=yes
 814     AC_REPLACE_MATHFUNCS(signbitl)
 815   fi
 816
 817   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 818 ])
 819
 820
 821 dnl Check to see what architecture and operating system we are compiling
 822 dnl for.  Also, if architecture- or OS-specific flags are required for
 823 dnl compilation, pick them up here.
 824 dnl
 825 dnl GLIBCPP_CHECK_TARGET
 826 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 827     . [$]{glibcpp_basedir}/configure.target
 828     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 829     AC_MSG_RESULT(OS config directory is $os_include_dir)
 830 ])
 831
 832
 833 dnl
 834 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 835 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 836 dnl must have been previously checked.)
 837 dnl
 838 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 839 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 840 dnl
 841 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 842 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 843
 844   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 845   dnl others even if wchar_t support is not on.
 846   AC_MSG_CHECKING([for mbstate_t])
 847   AC_TRY_COMPILE([#include <wchar.h>],
 848   [mbstate_t teststate;],
 849   have_mbstate_t=yes, have_mbstate_t=no)
 850   AC_MSG_RESULT($have_mbstate_t)
 851   if test x"$have_mbstate_t" = xyes; then
 852     AC_DEFINE(HAVE_MBSTATE_T)
 853   fi
 854
 855   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 856   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 857   AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 858
 859   dnl Only continue checking if the ISO C99 headers exist and support is on.
 860   if test x"$ac_has_wchar_h" = xyes &&
 861      test x"$ac_has_wctype_h" = xyes &&
 862      test x"$enable_c_mbchar" != xno; then
 863
 864     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 865     dnl numeric_limits can instantiate type_traits<wchar_t>
 866     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 867     AC_TRY_COMPILE([#include <wchar.h>],
 868     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 869     has_wchar_minmax=yes, has_wchar_minmax=no)
 870     AC_MSG_RESULT($has_wchar_minmax)
 871
 872     dnl Test wchar.h for WEOF, which is what we use to determine whether
 873     dnl to specialize for char_traits<wchar_t> or not.
 874     AC_MSG_CHECKING([for WEOF])
 875     AC_TRY_COMPILE([
 876       #include <wchar.h>
 877       #include <stddef.h>],
 878     [wint_t i = WEOF;],
 879     has_weof=yes, has_weof=no)
 880     AC_MSG_RESULT($has_weof)
 881
 882     dnl Tests for wide character functions used in char_traits<wchar_t>.
 883     ac_wfuncs=yes
 884     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 885     ac_wfuncs=no)
 886
 887     dnl Checks for names injected into std:: by the c_std headers.
 888     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 889     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 890     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 891     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 892     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 893     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 894     ac_wfuncs=no)
 895
 896     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 897     if test x"$has_weof" = xyes &&
 898        test x"$has_wchar_minmax" = xyes &&
 899        test x"$ac_wfuncs" = xyes; then
 900       ac_isoC99_wchar_t=yes
 901     else
 902       ac_isoC99_wchar_t=no
 903     fi
 904     AC_MSG_RESULT($ac_isoC99_wchar_t)
 905
 906     dnl Use iconv for wchar_t to char conversions. As such, check for
 907     dnl X/Open Portability Guide, version 2 features (XPG2).
 908     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 909     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 910
 911     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 912     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 913     ac_save_LIBS="$LIBS"
 914     LIBS="$LIBS $libiconv"
 915
 916     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 917     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 918
 919     LIBS="$ac_save_LIBS"
 920
 921     AC_MSG_CHECKING([for XPG2 wchar_t support])
 922     if test x"$ac_has_iconv_h" = xyes &&
 923        test x"$ac_has_langinfo_h" = xyes &&
 924        test x"$ac_XPG2funcs" = xyes; then
 925       ac_XPG2_wchar_t=yes
 926     else
 927       ac_XPG2_wchar_t=no
 928     fi
 929     AC_MSG_RESULT($ac_XPG2_wchar_t)
 930
 931     dnl At the moment, only enable wchar_t specializations if all the
 932     dnl above support is present.
 933     AC_MSG_CHECKING([for enabled wchar_t specializations])
 934     if test x"$ac_isoC99_wchar_t" = xyes &&
 935        test x"$ac_XPG2_wchar_t" = xyes; then
 936       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 937       AC_MSG_RESULT("yes")
 938     else
 939       AC_MSG_RESULT("no")
 940     fi
 941   else
 942     dnl Wide characters disabled by the user.
 943     AC_MSG_WARN([wchar_t support disabled.])
 944   fi
 945 ])
 946
 947
 948 dnl
 949 dnl Check for special debugging mode; not for production use.
 950 dnl
 951 dnl GLIBCPP_ENABLE_DEBUG
 952 dnl --enable-debug sets '-ggdb3 -O0'.
 953 dnl --disable-debug sets '-g' and whatever optimization options the
 954 dnl     compiler can handle.
 955 dnl  +  --enable-maintainer-mode automatically defaults this to on.
 956 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
 957 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
 958 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
 959 dnl       defaults to `no'.
 960 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
 961 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
 962 AC_ARG_ENABLE(debug,
 963 changequote(<<, >>)dnl
 964 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
 965 changequote([, ])dnl
 966 [case "${enableval}" in
 967  yes) enable_debug=yes ;;
 968  no)  enable_debug=no ;;
 969  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
 970  esac],
 971 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
 972
 973 dnl Option parsed, now set things appropriately
 974 case "${enable_debug}" in
 975     yes)
 976         DEBUG_FLAGS='-O0 -ggdb3'
 977         ;;
 978     no)
 979         DEBUG_FLAGS='-g'
 980         ;;
 981 esac
 982 AC_SUBST(DEBUG_FLAGS)
 983 ])
 984
 985
 986 dnl
 987 dnl Check for "unusual" flags to pass to the compiler while building.
 988 dnl
 989 dnl GLIBCPP_ENABLE_CXX_FLAGS
 990 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
 991 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
 992 dnl     Somehow this same set of flags must be passed when [re]building
 993 dnl     libgcc.
 994 dnl --disable-cxx-flags passes nothing.
 995 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
 996 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
 997 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
 998 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
 999 dnl       If "default flags" is an empty string (or "none"), the effect is
1000 dnl       the same as --disable or --enable=no.
1001 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1002 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1003 AC_ARG_ENABLE(cxx-flags,
1004 changequote(<<, >>)dnl
1005 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1006                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1007 changequote([, ])dnl
1008 [case "x$enableval" in
1009  xyes)
1010         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1011  xno|x)
1012         enable_cxx_flags='' ;;
1013  *)
1014         enable_cxx_flags="$enableval" ;;
1015  esac],
1016 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1017
1018 dnl Thinko on my part during design.  This kludge is the workaround.
1019 if test "$enable_cxx_flags" = "none"; then
1020   enable_cxx_flags='';
1021 fi
1022
1023 dnl Run through flags (either default or command-line) and set anything
1024 dnl extra (e.g., #defines) that must accompany particular g++ options.
1025 if test -n "$enable_cxx_flags"; then
1026     for f in $enable_cxx_flags; do
1027         case "$f" in
1028             -fhonor-std)  ;;
1029             -*)  ;;
1030             *)   # and we're trying to pass /what/ exactly?
1031                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1032         esac
1033     done
1034 fi
1035 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1036 AC_SUBST(EXTRA_CXX_FLAGS)
1037 ])
1038
1039
1040 dnl
1041 dnl Check for which locale library to use:  gnu or generic.
1042 dnl
1043 dnl GLIBCPP_ENABLE_CLOCALE
1044 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1045 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1046 dnl
1047 dnl default is generic
1048 dnl
1049 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1050   AC_MSG_CHECKING([for clocale to use])
1051   AC_ARG_ENABLE(clocale,
1052   [  --enable-clocale        enable model for target locale package.
1053   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1054   ],
1055   if test x$enable_clocale = xno; then
1056      enable_clocale=generic
1057   fi,
1058      enable_clocale=generic)
1059
1060   enable_clocale_flag=$enable_clocale
1061
1062   dnl Check if a valid locale package
1063   case x${enable_clocale_flag} in
1064     xgeneric)
1065       AC_MSG_RESULT(generic)
1066
1067       # Don't use gettext.
1068       USE_NLS=no
1069
1070       CLOCALE_H=config/locale/c_locale_generic.h
1071       CLOCALE_CC=config/locale/c_locale_generic.cc
1072       CCODECVT_H=config/locale/codecvt_specializations_generic.h
1073       CMESSAGES_H=config/locale/messages_members_generic.h
1074       CMESSAGES_CC=config/locale/messages_members_generic.cc
1075       CCOLLATE_CC=config/locale/collate_specializations_generic.cc
1076       ;;
1077     xgnu)
1078       AC_MSG_RESULT(gnu)
1079
1080       # Declare intention to use gettext, and add support for specific
1081       # languages.
1082       # For some reason, ALL_LINGUAS has to be before AM_GNU_GETTEXT
1083       ALL_LINGUAS="de fr"
1084       # Don't call AM_GNU_GETTEXT here. Instead, assume glibc.
1085       # Need to deal with MSGFMT, USE_NLS, and glibcpp_[P,M]OFILES
1086       USE_NLS=yes
1087
1088       # Export the build objects.
1089       for ling in $ALL_LINGUAS; do \
1090         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1091         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1092       done
1093       AC_SUBST(glibcpp_MOFILES)
1094       AC_SUBST(glibcpp_POFILES)
1095
1096       CLOCALE_H=config/locale/c_locale_gnu.h
1097       CLOCALE_CC=config/locale/c_locale_gnu.cc
1098       CCODECVT_H=config/locale/codecvt_specializations_ieee_1003.1-200x.h
1099       CMESSAGES_H=config/locale/messages_members_gnu.h
1100       CMESSAGES_CC=config/locale/messages_members_gnu.cc
1101       CCOLLATE_CC=config/locale/collate_specializations_gnu.cc
1102       ;;
1103     xieee_1003.1)
1104       AC_MSG_RESULT(generic)
1105
1106       # Don't use gettext.
1107       USE_NLS=no
1108
1109       CLOCALE_H=config/locale/c_locale_ieee_1003.1-200x.h
1110       CLOCALE_CC=config/locale/c_locale_ieee_1003.1-200x.cc
1111       CCODECVT_H=config/locale/codecvt_specializations_ieee_1003.1-200x.h
1112       CMESSAGES_H=config/locale/messages_members_ieee_1003.1-200x.h
1113       CMESSAGES_CC=config/locale/messages_members_ieee_1003.1-200x.cc
1114       CCOLLATE_CC=config/locale/collate_specializations_generic.cc
1115       ;;
1116     *)
1117       echo "$enable_clocale is an unknown locale package" 1>&2
1118       exit 1
1119       ;;
1120   esac
1121
1122   # This is where the testsuite looks for locale catalogs, using the
1123   # -DLOCALEDIR define during testsuite compilation.
1124   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1125   AC_SUBST(glibcpp_localedir)
1126
1127   AC_SUBST(USE_NLS)
1128   AC_SUBST(CLOCALE_H)
1129   AC_SUBST(CCODECVT_H)
1130   AC_SUBST(CMESSAGES_H)
1131   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1132   AC_LINK_FILES($CMESSAGES_CC, src/messages.cc)
1133   AC_LINK_FILES($CCOLLATE_CC, src/collate.cc)
1134 ])
1135
1136
1137 dnl
1138 dnl Check for which I/O library to use:  libio, or something specific.
1139 dnl
1140 dnl GLIBCPP_ENABLE_CSTDIO
1141 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1142 dnl
1143 dnl default is stdio
1144 dnl
1145 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1146   AC_MSG_CHECKING([for cstdio to use])
1147   AC_ARG_ENABLE(cstdio,
1148   [  --enable-cstdio         enable stdio for target io package.
1149   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1150   ],
1151   if test x$enable_cstdio = xno; then
1152      enable_cstdio=stdio
1153   fi,
1154      enable_cstdio=stdio)
1155
1156   enable_cstdio_flag=$enable_cstdio
1157
1158   dnl Check if a valid I/O package
1159   case x${enable_cstdio_flag} in
1160     xlibio)
1161       CSTDIO_H=config/io/c_io_libio.h
1162       BASIC_FILE_H=config/io/basic_file_libio.h
1163       BASIC_FILE_CC=config/io/basic_file_libio.cc
1164       AC_MSG_RESULT(libio)
1165
1166       # see if we are on a system with libio native (ie, linux)
1167       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1168
1169       # Need to check and see what version of glibc is being used. If
1170       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1171       # compile most of libio for linux systems.
1172       if test x$has_libio = x"yes"; then
1173         case "$target" in
1174           *-*-linux*)
1175               AC_MSG_CHECKING([for glibc version >= 2.2])
1176               AC_EGREP_CPP([ok], [
1177             #include <features.h>
1178               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1179                     ok
1180               #endif
1181               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1182               AC_MSG_RESULT($glibc_satisfactory)
1183             ;;
1184         esac
1185
1186         # XXX at the moment, admit defeat and force the recompilation
1187         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1188         glibc_satisfactory=no
1189
1190         if test x$glibc_satisfactory = x"yes"; then
1191            need_libio=no
1192            need_wlibio=no
1193         else
1194            need_libio=yes
1195            # bkoz XXX need to add checks to enable this
1196            # pme XXX here's a first pass at such a check
1197            if test x$enable_c_mbchar != xno; then
1198               need_wlibio=yes
1199            else
1200               need_wlibio=no
1201            fi
1202         fi
1203
1204       else
1205          # Using libio, but <libio.h> doesn't exist on the target system. . .
1206          need_libio=yes
1207          # bkoz XXX need to add checks to enable this
1208          # pme XXX here's a first pass at such a check
1209          if test x$enable_c_mbchar != xno; then
1210              need_wlibio=yes
1211          else
1212              need_wlibio=no
1213          fi
1214       fi
1215       ;;
1216     xstdio | x | xno | xnone | xyes)
1217       # default
1218       CSTDIO_H=config/io/c_io_stdio.h
1219       BASIC_FILE_H=config/io/basic_file_stdio.h
1220       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1221       AC_MSG_RESULT(stdio)
1222
1223       # We're not using stdio.
1224       need_libio=no
1225       need_wlibio=no
1226       ;;
1227     *)
1228       echo "$enable_cstdio is an unknown io package" 1>&2
1229       exit 1
1230       ;;
1231   esac
1232   AC_SUBST(CSTDIO_H)
1233   AC_SUBST(BASIC_FILE_H)
1234   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1235
1236   # 2000-08-04 bkoz hack
1237   CCODECVT_C=config/io/c_io_libio_codecvt.c
1238   AC_SUBST(CCODECVT_C)
1239   # 2000-08-04 bkoz hack
1240
1241   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1242                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1243   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1244   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1245   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1246     libio_la=../libio/libio.la
1247   else
1248     libio_la=
1249   fi
1250   AC_SUBST(libio_la)
1251 ])
1252
1253
1254 dnl
1255 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1256 dnl We must stage the required headers so that they will be installed
1257 dnl with the library (unlike libgcc, the STL implementation is provided
1258 dnl solely within headers).  Since we must not inject random user-space
1259 dnl macro names into user-provided C++ code, we first stage into <file>-in
1260 dnl and process to <file> with an output command.  The reason for a two-
1261 dnl stage process here is to correctly handle $srcdir!=$objdir without
1262 dnl having to write complex code (the sed commands to clean the macro
1263 dnl namespace are complex and fragile enough as it is).  We must also
1264 dnl add a relative path so that -I- is supported properly.
1265 dnl
1266 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1267   AC_MSG_CHECKING([for thread model used by GCC])
1268   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1269   AC_MSG_RESULT([$target_thread_file])
1270
1271   if test $target_thread_file != single; then
1272     AC_DEFINE(HAVE_GTHR_DEFAULT)
1273     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1274   fi
1275
1276   glibcpp_thread_h=gthr-$target_thread_file.h
1277   AC_SUBST(glibcpp_thread_h)
1278 ])
1279
1280
1281 dnl
1282 dnl Check for exception handling support.  If an explicit enable/disable
1283 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1284 dnl target may or may not support call frame exceptions.
1285 dnl
1286 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1287 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1288 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1289 dnl
1290 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1291 dnl
1292 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1293   AC_MSG_CHECKING([for exception model to use])
1294   AC_LANG_SAVE
1295   AC_LANG_CPLUSPLUS
1296   AC_ARG_ENABLE(sjlj-exceptions,
1297   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1298   [:],
1299   [dnl Botheration.  Now we've got to detect the exception model.
1300    dnl Link tests against libgcc.a are problematic since -- at least
1301    dnl as of this writing -- we've not been given proper -L bits for
1302    dnl single-tree newlib and libgloss.
1303    dnl
1304    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1305    dnl conftest files before we got a change to grep them first.
1306    cat > conftest.$ac_ext << EOF
1307 [#]line __oline__ "configure"
1308 struct S { ~S(); };
1309 void bar();
1310 void foo()
1311 {
1312   S s;
1313   bar();
1314 }
1315 EOF
1316    old_CXXFLAGS="$CXXFLAGS"
1317    CXXFLAGS=-S
1318    if AC_TRY_EVAL(ac_compile); then
1319      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1320        enable_sjlj_exceptions=yes
1321      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1322        enable_sjlj_exceptions=no
1323      fi
1324    fi
1325    CXXFLAGS="$old_CXXFLAGS"
1326    rm -f conftest*])
1327    if test x$enable_sjlj_exceptions = xyes; then
1328      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1329         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1330      ac_exception_model_name=sjlj
1331    elif test x$enable_sjlj_exceptions = xno; then
1332      ac_exception_model_name="call frame"
1333    else
1334      AC_MSG_ERROR([unable to detect exception model])
1335    fi
1336    AC_LANG_RESTORE
1337    AC_MSG_RESULT($ac_exception_model_name)
1338 ])
1339
1340
1341 dnl
1342 dnl Check for ISO/IEC 9899:1999 "C99" support.
1343 dnl
1344 dnl GLIBCPP_ENABLE_C99
1345 dnl --enable-c99 defines _GLIBCPP_USE_C99
1346 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1347 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1348 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1349 dnl       defaults to `no'.
1350 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1351 dnl
1352 dnl GLIBCPP_ENABLE_C99
1353 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1354   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1355
1356   AC_ARG_ENABLE(c99,
1357   changequote(<<, >>)dnl
1358   <<--enable-c99      turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1359   changequote([, ])dnl
1360   [case "$enableval" in
1361    yes) enable_c99=yes ;;
1362    no)  enable_c99=no ;;
1363    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1364    esac],
1365   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1366
1367   AC_LANG_SAVE
1368   AC_LANG_CPLUSPLUS
1369
1370   # Check for the existence of <math.h> functions used if C99 is enabled.
1371   ac_c99_math=yes;
1372   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1373   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1374   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1375   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1376   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1377   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1378   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1379   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1380   AC_TRY_COMPILE([#include <math.h>],
1381                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1382   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1383   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1384   AC_TRY_COMPILE([#include <math.h>],
1385                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1386   AC_TRY_COMPILE([#include <math.h>],
1387                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1388   AC_MSG_RESULT($ac_c99_math)
1389
1390   # Check for the existence in <stdio.h> of vscanf, et. al.
1391   ac_c99_stdio=yes;
1392   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1393   AC_TRY_COMPILE([#include <stdio.h>],
1394                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1395   AC_TRY_COMPILE([#include <stdio.h>
1396                   #include <stdarg.h>
1397                   void foo(char* fmt, ...)
1398                   {va_list args; va_start(args, fmt);
1399                   vfscanf(stderr, "%i", args);}],
1400                   [],, [ac_c99_stdio=no])
1401   AC_TRY_COMPILE([#include <stdio.h>
1402                   #include <stdarg.h>
1403                   void foo(char* fmt, ...)
1404                   {va_list args; va_start(args, fmt);
1405                   vscanf("%i", args);}],
1406                   [],, [ac_c99_stdio=no])
1407   AC_TRY_COMPILE([#include <stdio.h>
1408                   #include <stdarg.h>
1409                   void foo(char* fmt, ...)
1410                   {va_list args; va_start(args, fmt);
1411                   vsnprintf(fmt, 0, "%i", args);}],
1412                   [],, [ac_c99_stdio=no])
1413   AC_TRY_COMPILE([#include <stdio.h>
1414                   #include <stdarg.h>
1415                   void foo(char* fmt, ...)
1416                   {va_list args; va_start(args, fmt);
1417                   vsscanf(fmt, "%i", args);}],
1418                   [],, [ac_c99_stdio=no])
1419   AC_MSG_RESULT($ac_c99_stdio)
1420
1421   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1422   ac_c99_stdlib=yes;
1423   AC_MSG_CHECKING([for lldiv_t declaration])
1424   AC_CACHE_VAL(ac_c99_lldiv_t, [
1425   AC_TRY_COMPILE([#include <stdlib.h>],
1426                    [ lldiv_t mydivt;],
1427                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1428   ])
1429   AC_MSG_RESULT($ac_c99_lldiv_t)
1430
1431   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1432   AC_TRY_COMPILE([#include <stdlib.h>],
1433                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1434   AC_TRY_COMPILE([#include <stdlib.h>],
1435                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1436   AC_TRY_COMPILE([#include <stdlib.h>],
1437                  [char* tmp; strtoll("gnu", &tmp, 10);],, [ac_c99_stdlib=no])
1438   AC_TRY_COMPILE([#include <stdlib.h>],
1439                  [char* tmp; strtoull("gnu", &tmp, 10);],, [ac_c99_stdlib=no])
1440   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1441   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1442   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1443   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1444   if test x"$ac_c99_lldiv_t" = x"no"; then
1445     ac_c99_stdlib=no;
1446   fi;
1447   AC_MSG_RESULT($ac_c99_stdlib)
1448
1449   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1450   # XXX the wchar.h checks should be rolled into the general C99 bits.
1451   ac_c99_wchar=yes;
1452   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1453   AC_TRY_COMPILE([#include <wchar.h>],
1454                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1455   AC_TRY_COMPILE([#include <wchar.h>],
1456                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1457   AC_TRY_COMPILE([#include <wchar.h>],
1458                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1459   AC_MSG_RESULT($ac_c99_wchar)
1460
1461   AC_MSG_CHECKING([for enabled ISO C99 support])
1462   if test x"$ac_c99_math" = x"no" ||
1463      test x"$ac_c99_stdio" = x"no" ||
1464      test x"$ac_c99_stdlib" = x"no" ||
1465      test x"$ac_c99_wchar" = x"no"; then
1466     enable_c99=no;
1467   fi;
1468   AC_MSG_RESULT($enable_c99)
1469
1470   # Option parsed, now set things appropriately
1471   if test x"$enable_c99" = x"yes"; then
1472     AC_DEFINE(_GLIBCPP_USE_C99)
1473   fi
1474
1475   AC_LANG_RESTORE
1476 ])
1477
1478
1479 dnl
1480 dnl Check for template specializations for the 'long long' type extension.
1481 dnl NB: Must check for C99 support before calling _GLIBCPP_ENABLE_LONG_LONG
1482 dnl
1483 dnl GLIBCPP_ENABLE_LONG_LONG
1484 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1485 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1486 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1487 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1488 dnl       defaults to `no'.
1489 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1490 dnl
1491 dnl GLIBCPP_ENABLE_LONG_LONG
1492 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1493   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1494
1495   AC_ARG_ENABLE(long-long,
1496   changequote(<<, >>)dnl
1497   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1498   changequote([, ])dnl
1499   [case "$enableval" in
1500    yes) enable_long_long=yes ;;
1501    no)  enable_long_long=no ;;
1502    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1503    esac],
1504   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1505
1506   # iostreams require strtoll, strtoull to compile. If the
1507   # GLIBCPP_ENABLE_C99 tests found these, and if C99 support is enabled,
1508   # go ahead and allow long long to be used.
1509   if test x"$enable_c99" = x"no"; then
1510     enable_long_long=no;
1511   fi
1512
1513   # Option parsed, now set things appropriately
1514   AC_MSG_CHECKING([for enabled long long support])
1515   if test x"$enable_long_long" = xyes; then
1516     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1517   fi
1518   AC_MSG_RESULT($enable_long_long)
1519 ])
1520
1521
1522 dnl
1523 dnl Check for what kind of C headers to use.
1524 dnl
1525 dnl GLIBCPP_ENABLE_CHEADERS
1526 dnl --enable-cheaders= [does stuff].
1527 dnl --disable-cheaders [does not do anything, really].
1528 dnl  +  This will eventually need to be 'c_shadow' by default.
1529 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1530 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1531 dnl       If ommitted, it defaults to `c_std'.
1532 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1533 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1534 AC_MSG_CHECKING([for c header strategy to use])
1535 AC_ARG_ENABLE(cheaders,
1536 changequote(<<, >>)dnl
1537 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1538 changequote([, ])
1539   [case "$enableval" in
1540    c)
1541         enable_cheaders=c
1542         ;;
1543    c_std)
1544         enable_cheaders=c_std
1545         ;;
1546    c_shadow)
1547         enable_cheaders=c_shadow
1548         ;;
1549    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1550         ;;
1551   esac],
1552   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1553   AC_MSG_RESULT($enable_cheaders)
1554
1555   dnl Option parsed, now set things appropriately
1556   case "$enable_cheaders" in
1557     c_shadow)
1558         CSHADOW_FLAGS="-fno-builtin"
1559         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_shadow'
1560         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1561         ;;
1562     c_std)
1563         CSHADOW_FLAGS=""
1564         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1565         ;;
1566     c)
1567         CSHADOW_FLAGS=""
1568         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1569         ;;
1570   esac
1571
1572   AC_SUBST(CSHADOW_FLAGS)
1573   AC_SUBST(C_INCLUDE_DIR)
1574   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cheaders" = c_shadow)
1575 ])
1576
1577
1578 dnl
1579 dnl Check for wide character support.  Has the same effect as the option
1580 dnl in gcc's configure, but in a form that autoconf can mess with.
1581 dnl
1582 dnl GLIBCPP_ENABLE_C_MBCHAR
1583 dnl --enable-c-mbchar requests all the wchar_t stuff.
1584 dnl --disable-c-mbchar doesn't.
1585 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1586 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1587 dnl       defaults to `no'.
1588 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1589 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1590 AC_ARG_ENABLE(c-mbchar,
1591 changequote(<<, >>)dnl
1592 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1593 changequote([, ])dnl
1594 [case "$enableval" in
1595  yes) enable_c_mbchar=yes ;;
1596  no)  enable_c_mbchar=no ;;
1597  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1598  esac],
1599 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1600 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1601 ])
1602
1603
1604 dnl
1605 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1606 dnl
1607 dnl TOPLEVEL_INCLUDES
1608 dnl LIBMATH_INCLUDES
1609 dnl LIBSUPCXX_INCLUDES
1610 dnl LIBIO_INCLUDES
1611 dnl CSHADOW_INCLUDES
1612 dnl
1613 dnl GLIBCPP_EXPORT_INCLUDES
1614 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1615   # Root level of the build directory include sources.
1616   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1617
1618   # Passed down for canadian crosses.
1619   if test x"$CANADIAN" = xyes; then
1620     TOPLEVEL_INCLUDES='-I$(includedir)'
1621   fi
1622
1623   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1624
1625   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1626
1627   if test x"$need_libio" = xyes; then
1628     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1629     AC_SUBST(LIBIO_INCLUDES)
1630   fi
1631
1632   # Now, export this to all the little Makefiles....
1633   AC_SUBST(GLIBCPP_INCLUDES)
1634   AC_SUBST(TOPLEVEL_INCLUDES)
1635   AC_SUBST(LIBMATH_INCLUDES)
1636   AC_SUBST(LIBSUPCXX_INCLUDES)
1637 ])
1638
1639
1640 dnl
1641 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1642 dnl
1643 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1644   # Optimization flags that are probably a good idea for thrill-seekers. Just
1645   # uncomment the lines below and make, everything else is ready to go...
1646   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1647   OPTIMIZE_CXXFLAGS=
1648   AC_SUBST(OPTIMIZE_CXXFLAGS)
1649
1650   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1651   AC_SUBST(WARN_FLAGS)
1652 ])
1653
1654 dnl
1655 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1656 dnl  calculates gxx_install_dir
1657 dnl  exports glibcpp_toolexecdir
1658 dnl  exports glibcpp_toolexeclibdir
1659 dnl  exports glibcpp_prefixdir
1660 dnl
1661 dnl Assumes cross_compiling bits already done, and with_cross_host in
1662 dnl particular
1663 dnl
1664 dnl GLIBCPP_EXPORT_INSTALL_INFO
1665 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1666 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1667 # exported correctly in GLIBCPP_CONFIGURE.
1668 glibcpp_toolexecdir=no
1669 glibcpp_toolexeclibdir=no
1670 glibcpp_prefixdir=${prefix}
1671
1672 AC_MSG_CHECKING([for interface version number])
1673 libstdcxx_interface=$INTERFACE
1674 AC_MSG_RESULT($libstdcxx_interface)
1675
1676 # Process the option --with-gxx-include-dir=<path to include-files directory>
1677 AC_MSG_CHECKING([for --with-gxx-include-dir])
1678 AC_ARG_WITH(gxx-include-dir,
1679 [  --with-gxx-include-dir  the installation directory for include files],
1680 [case "${withval}" in
1681   yes)
1682     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1683     gxx_include_dir=no
1684     ;;
1685   no)
1686     gxx_include_dir=no
1687     ;;
1688   *)
1689     gxx_include_dir=${withval}
1690     ;;
1691 esac], [gxx_include_dir=no])
1692 AC_MSG_RESULT($gxx_include_dir)
1693
1694 # Process the option "--enable-version-specific-runtime-libs"
1695 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1696 AC_ARG_ENABLE(version-specific-runtime-libs,
1697 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1698 [case "$enableval" in
1699  yes) version_specific_libs=yes ;;
1700  no)  version_specific_libs=no ;;
1701  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1702  esac],
1703 version_specific_libs=no)dnl
1704 # Option set, now we can test it.
1705 AC_MSG_RESULT($version_specific_libs)
1706
1707 if test $version_specific_libs = yes; then
1708   # Need the gcc compiler version to know where to install libraries
1709   # and header files if --enable-version-specific-runtime-libs option
1710   # is selected.
1711   changequote(,)dnl
1712   gcc_version_trigger=${srcdir}/../gcc/version.c
1713   gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1714   gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1715   gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1716   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1717   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1718   changequote([,])dnl
1719 fi
1720
1721 # Default case for install directory for include files.
1722 if test $version_specific_libs = no &&
1723    test $gxx_include_dir = no; then
1724   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1725 fi
1726
1727 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1728 # Install a library built with a cross compiler in tooldir, not libdir.
1729 if test x"$glibcpp_toolexecdir" = x"no"; then
1730   if test -n "$with_cross_host" &&
1731      test x"$with_cross_host" != x"no"; then
1732     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1733     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1734   else
1735     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1736     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1737   fi
1738 fi
1739
1740 AC_MSG_CHECKING([for install location])
1741 AC_MSG_RESULT($gxx_include_dir)
1742
1743 AC_SUBST(glibcpp_prefixdir)
1744 AC_SUBST(gxx_include_dir)
1745 AC_SUBST(glibcpp_toolexecdir)
1746 AC_SUBST(glibcpp_toolexeclibdir)
1747 ])
1748
1749
1750 # Check for functions in math library.
1751 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1752 #
1753 # This file can be copied and used freely without restrictions.  It can
1754 # be used in projects which are not available under the GNU Public License
1755 # but which still want to provide support for the GNU gettext functionality.
1756 # Please note that the actual code is *not* freely available.
1757
1758 # serial 1
1759
1760 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1761 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1762 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1763 AC_SUBST(LIBMATHOBJS)dnl
1764 ])
1765
1766
1767
1768 dnl This macro searches for a GNU version of make.  If a match is found, the
1769 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1770 dnl set to "#". This is useful for  including a special features in a Makefile,
1771 dnl which cannot be handled by other versions of make.  The variable
1772 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1773 dnl the empty string otherwise.
1774 dnl
1775 dnl Here is an example of its use:
1776 dnl
1777 dnl Makefile.in might contain:
1778 dnl
1779 dnl     # A failsafe way of putting a dependency rule into a makefile
1780 dnl     $(DEPEND):
1781 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1782 dnl
1783 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1784 dnl     @ifGNUmake@ include $(DEPEND)
1785 dnl     @ifGNUmake@ endif
1786 dnl
1787 dnl Then configure.in would normally contain:
1788 dnl
1789 dnl     CHECK_GNU_MAKE()
1790 dnl     AC_OUTPUT(Makefile)
1791 dnl
1792 dnl Then perhaps to cause gnu make to override any other make, we could do
1793 dnl something like this (note that GNU make always looks for GNUmakefile first):
1794 dnl
1795 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1796 dnl             mv Makefile GNUmakefile
1797 dnl             echo .DEFAULT: > Makefile ;
1798 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1799 dnl     fi
1800 dnl
1801 dnl Then, if any (well almost any) other make is called, and GNU make also
1802 dnl exists, then the other make wraps the GNU make.
1803 dnl
1804 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1805 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1806 dnl
1807 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1808 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1809 dnl #### conditional's subshell (" --version" is not a command), using a
1810 dnl #### different option to grep(1).
1811 dnl #### -pme
1812 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1813 dnl #### ${MAKE:-make}).
1814 dnl #### -msokolov
1815 AC_DEFUN(
1816   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1817           _cv_gnu_make_command='' ;
1818 dnl Search all the common names for GNU make
1819           for a in "${MAKE-make}" make gmake gnumake ; do
1820                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1821                   then
1822                           _cv_gnu_make_command=$a ;
1823                           break;
1824                   fi
1825           done ;
1826   ) ;
1827 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1828 dnl string, '#' otherwise
1829   if test  "x$_cv_gnu_make_command" != "x"  ; then
1830           ifGNUmake='' ;
1831   else
1832           ifGNUmake='#' ;
1833   fi
1834   AC_SUBST(ifGNUmake)
1835 ])
1836
1837
1838 dnl Check for headers for, and arguments to, the setrlimit() function.
1839 dnl Used only in testsuite_hooks.h.
1840 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
1841   AC_TRY_COMPILE([#include <sys/resource.h>
1842                   #include <unistd.h>
1843                  ], [ int f = RLIMIT_$1 ; ],
1844                  [glibcpp_mresult=1], [glibcpp_mresult=0])
1845   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
1846                      [Only used in build directory testsuite_hooks.h.])
1847 ])
1848 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
1849   setrlimit_have_headers=yes
1850   AC_CHECK_HEADERS(sys/resource.h unistd.h,
1851                    [],
1852                    setrlimit_have_headers=no)
1853   # If don't have the headers, then we can't run the tests now, and we
1854   # won't be seeing any of these during testsuite compilation.
1855   if test $setrlimit_have_headers = yes; then
1856     # Can't do these in a loop, else the resulting syntax is wrong.
1857     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
1858     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
1859     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
1860     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
1861
1862     # Check for rlimit, setrlimit.
1863     AC_CACHE_VAL(ac_setrlimit, [
1864       AC_TRY_COMPILE([#include <sys/resource.h>
1865                       #include <unistd.h>
1866                      ],
1867                      [ struct rlimit r; setrlimit(0, &r);],
1868                      [ac_setrlimit=yes], [ac_setrlimit=no])
1869     ])
1870   fi
1871
1872   AC_MSG_CHECKING([for testsuite memory limit support])
1873   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
1874     ac_mem_limits=yes
1875     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
1876   else
1877     ac_mem_limits=no
1878   fi
1879   AC_MSG_RESULT($ac_mem_limits)
1880 ])
1881
1882
1883 dnl
1884 dnl Does any necessary configuration of the testsuite directory.  Generates
1885 dnl the testsuite_hooks.h header.
1886 dnl
1887 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
1888 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
1889   GLIBCPP_CHECK_SETRLIMIT
1890 ])
1891
1892
1893 sinclude(../libtool.m4)
1894 dnl The lines below arrange for aclocal not to bring an installed
1895 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1896 dnl add a definition of LIBTOOL to Makefile.in.
1897 ifelse(,,,[AC_SUBST(LIBTOOL)
1898 AC_DEFUN([AM_PROG_LIBTOOL])
1899 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1900 AC_DEFUN([AC_PROG_LD])
1901 ])
1902
1903
1904 # Check whether LC_MESSAGES is available in <locale.h>.
1905 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1906 #
1907 # This file file be copied and used freely without restrictions.  It can
1908 # be used in projects which are not available under the GNU Public License
1909 # but which still want to provide support for the GNU gettext functionality.
1910 # Please note that the actual code is *not* freely available.
1911
1912 # serial 1
1913
1914 AC_DEFUN(AC_LC_MESSAGES, [
1915   AC_CHECK_HEADER(locale.h, [
1916     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1917       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1918        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1919     if test $ac_cv_val_LC_MESSAGES = yes; then
1920       AC_DEFINE(HAVE_LC_MESSAGES)
1921     fi
1922   ])
1923 ])
1924
1925
1926 # Add --enable-maintainer-mode option to configure.
1927 # From Jim Meyering
1928
1929 # serial 1
1930
1931 AC_DEFUN(AM_MAINTAINER_MODE,
1932 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1933   dnl maintainer-mode is disabled by default
1934   AC_ARG_ENABLE(maintainer-mode,
1935 [  --enable-maintainer-mode enable make rules and dependencies not useful
1936                           (and sometimes confusing) to the casual installer],
1937       USE_MAINTAINER_MODE=$enableval,
1938       USE_MAINTAINER_MODE=no)
1939   AC_MSG_RESULT($USE_MAINTAINER_MODE)
1940   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
1941   MAINT=$MAINTAINER_MODE_TRUE
1942   AC_SUBST(MAINT)dnl
1943 ]
1944 )
1945
1946 # Define a conditional.
1947
1948 AC_DEFUN(AM_CONDITIONAL,
1949 [AC_SUBST($1_TRUE)
1950 AC_SUBST($1_FALSE)
1951 if $2; then
1952   $1_TRUE=
1953   $1_FALSE='#'
1954 else
1955   $1_TRUE='#'
1956   $1_FALSE=
1957 fi])
1958
1959 # Macro to add for using GNU gettext.
1960 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1961 #
1962 # This file file be copied and used freely without restrictions.  It can
1963 # be used in projects which are not available under the GNU Public License
1964 # but which still want to provide support for the GNU gettext functionality.
1965 # Please note that the actual code is *not* freely available.
1966
1967 # serial 3
1968
1969 AC_DEFUN(AM_WITH_NLS,
1970   [AC_MSG_CHECKING([whether NLS is requested])
1971     dnl Default is enabled NLS
1972     AC_ARG_ENABLE(nls,
1973       [  --disable-nls           do not use Native Language Support],
1974       USE_NLS=$enableval, USE_NLS=yes)
1975     AC_MSG_RESULT($USE_NLS)
1976     AC_SUBST(USE_NLS)
1977
1978     USE_INCLUDED_LIBINTL=no
1979
1980     dnl If we use NLS figure out what method
1981     if test "$USE_NLS" = "yes"; then
1982       AC_DEFINE(ENABLE_NLS)
1983       AC_MSG_CHECKING([whether included gettext is requested])
1984       AC_ARG_WITH(included-gettext,
1985         [  --with-included-gettext use the GNU gettext library included here],
1986         nls_cv_force_use_gnu_gettext=$withval,
1987         nls_cv_force_use_gnu_gettext=no)
1988       AC_MSG_RESULT($nls_cv_force_use_gnu_gettext)
1989
1990       nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
1991       if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
1992         dnl User does not insist on using GNU NLS library.  Figure out what
1993         dnl to use.  If gettext or catgets are available (in this order) we
1994         dnl use this.  Else we have to fall back to GNU NLS library.
1995         dnl catgets is only used if permitted by option --with-catgets.
1996         nls_cv_header_intl=
1997         nls_cv_header_libgt=
1998         CATOBJEXT=NONE
1999
2000         AC_CHECK_HEADER(libintl.h,
2001           [AC_CACHE_CHECK([for gettext in libc], gt_cv_func_gettext_libc,
2002             [AC_TRY_LINK([#include <libintl.h>], [return (int) gettext ("")],
2003                gt_cv_func_gettext_libc=yes, gt_cv_func_gettext_libc=no)])
2004
2005            if test "$gt_cv_func_gettext_libc" != "yes"; then
2006              AC_CHECK_LIB(intl, bindtextdomain,
2007                [AC_CACHE_CHECK([for gettext in libintl],
2008                  gt_cv_func_gettext_libintl,
2009                  [AC_TRY_LINK([], [return (int) gettext ("")],
2010                  gt_cv_func_gettext_libintl=yes,
2011                  gt_cv_func_gettext_libintl=no)])])
2012            fi
2013
2014            if test "$gt_cv_func_gettext_libc" = "yes" \
2015               || test "$gt_cv_func_gettext_libintl" = "yes"; then
2016               AC_DEFINE(HAVE_GETTEXT)
2017               AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
2018                 [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)dnl
2019               if test "$MSGFMT" != "no"; then
2020                 AC_CHECK_FUNCS(dcgettext)
2021                 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
2022                 AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
2023                   [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
2024                 AC_TRY_LINK(, [extern int _nl_msg_cat_cntr;
2025                                return _nl_msg_cat_cntr],
2026                   [CATOBJEXT=.gmo
2027                    DATADIRNAME=share],
2028                   [CATOBJEXT=.mo
2029                    DATADIRNAME=lib])
2030                 INSTOBJEXT=.mo
2031               fi
2032             fi
2033         ])
2034
2035         if test "$CATOBJEXT" = "NONE"; then
2036           AC_MSG_CHECKING([whether catgets can be used])
2037           AC_ARG_WITH(catgets,
2038             [  --with-catgets          use catgets functions if available],
2039             nls_cv_use_catgets=$withval, nls_cv_use_catgets=no)
2040           AC_MSG_RESULT($nls_cv_use_catgets)
2041
2042           if test "$nls_cv_use_catgets" = "yes"; then
2043             dnl No gettext in C library.  Try catgets next.
2044             AC_CHECK_LIB(i, main)
2045             AC_CHECK_FUNC(catgets,
2046               [AC_DEFINE(HAVE_CATGETS)
2047                INTLOBJS="\$(CATOBJS)"
2048                AC_PATH_PROG(GENCAT, gencat, no)dnl
2049                if test "$GENCAT" != "no"; then
2050                  AC_PATH_PROG(GMSGFMT, gmsgfmt, no)
2051                  if test "$GMSGFMT" = "no"; then
2052                    AM_PATH_PROG_WITH_TEST(GMSGFMT, msgfmt,
2053                     [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)
2054                  fi
2055                  AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
2056                    [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
2057                  USE_INCLUDED_LIBINTL=yes
2058                  CATOBJEXT=.cat
2059                  INSTOBJEXT=.cat
2060                  DATADIRNAME=lib
2061                  INTLDEPS='$(top_builddir)/intl/libintl.a'
2062                  INTLLIBS=$INTLDEPS
2063                  LIBS=`echo $LIBS | sed -e 's/-lintl//'`
2064                  nls_cv_header_intl=intl/libintl.h
2065                  nls_cv_header_libgt=intl/libgettext.h
2066                fi])
2067           fi
2068         fi
2069
2070         if test "$CATOBJEXT" = "NONE"; then
2071           dnl Neither gettext nor catgets in included in the C library.
2072           dnl Fall back on GNU gettext library.
2073           nls_cv_use_gnu_gettext=yes
2074         fi
2075       fi
2076
2077       if test "$nls_cv_use_gnu_gettext" = "yes"; then
2078         dnl Mark actions used to generate GNU NLS library.
2079         INTLOBJS="\$(GETTOBJS)"
2080         AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
2081           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], msgfmt)
2082         AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
2083         AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
2084           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
2085         AC_SUBST(MSGFMT)
2086         USE_INCLUDED_LIBINTL=yes
2087         CATOBJEXT=.gmo
2088         INSTOBJEXT=.mo
2089         DATADIRNAME=share
2090         INTLDEPS='$(top_builddir)/intl/libintl.a'
2091         INTLLIBS=$INTLDEPS
2092         LIBS=`echo $LIBS | sed -e 's/-lintl//'`
2093         nls_cv_header_intl=intl/libintl.h
2094         nls_cv_header_libgt=intl/libgettext.h
2095       fi
2096
2097       dnl Test whether we really found GNU xgettext.
2098       if test "$XGETTEXT" != ":"; then
2099         dnl If it is no GNU xgettext we define it as : so that the
2100         dnl Makefiles still can work.
2101         if $XGETTEXT --omit-header /dev/null 2> /dev/null; then
2102           : ;
2103         else
2104           AC_MSG_RESULT(
2105             [found xgettext programs is not GNU xgettext; ignore it])
2106           XGETTEXT=":"
2107         fi
2108       fi
2109
2110       # We need to process the po/ directory.
2111       POSUB=po
2112     else
2113       DATADIRNAME=share
2114       nls_cv_header_intl=intl/libintl.h
2115       nls_cv_header_libgt=intl/libgettext.h
2116     fi
2117
2118     # If this is used in GNU gettext we have to set USE_NLS to `yes'
2119     # because some of the sources are only built for this goal.
2120     if test "$PACKAGE" = gettext; then
2121       USE_NLS=yes
2122       USE_INCLUDED_LIBINTL=yes
2123     fi
2124
2125     dnl These rules are solely for the distribution goal.  While doing this
2126     dnl we only have to keep exactly one list of the available catalogs
2127     dnl in configure.in.
2128     for lang in $ALL_LINGUAS; do
2129       GMOFILES="$GMOFILES $lang.gmo"
2130       POFILES="$POFILES $lang.po"
2131     done
2132
2133     dnl Make all variables we use known to autoconf.
2134     AC_SUBST(USE_INCLUDED_LIBINTL)
2135     AC_SUBST(CATALOGS)
2136     AC_SUBST(CATOBJEXT)
2137     AC_SUBST(DATADIRNAME)
2138     AC_SUBST(GMOFILES)
2139     AC_SUBST(INSTOBJEXT)
2140     AC_SUBST(INTLDEPS)
2141     AC_SUBST(INTLLIBS)
2142     AC_SUBST(INTLOBJS)
2143     AC_SUBST(POFILES)
2144     AC_SUBST(POSUB)
2145   ])
2146
2147 AC_DEFUN(AM_GNU_GETTEXT,
2148   [AC_REQUIRE([AC_PROG_MAKE_SET])dnl
2149    AC_REQUIRE([AC_PROG_CC])dnl
2150    AC_REQUIRE([AC_PROG_RANLIB])dnl
2151    AC_REQUIRE([AC_ISC_POSIX])dnl
2152    AC_REQUIRE([AC_HEADER_STDC])dnl
2153    AC_REQUIRE([AC_C_CONST])dnl
2154    AC_REQUIRE([AC_C_INLINE])dnl
2155    AC_REQUIRE([AC_TYPE_OFF_T])dnl
2156    AC_REQUIRE([AC_TYPE_SIZE_T])dnl
2157    AC_REQUIRE([AC_FUNC_ALLOCA])dnl
2158    AC_REQUIRE([AC_FUNC_MMAP])dnl
2159
2160    AC_CHECK_HEADERS([argz.h limits.h locale.h nl_types.h malloc.h string.h \
2161 unistd.h values.h sys/param.h])
2162    AC_CHECK_FUNCS([getcwd munmap putenv setenv setlocale strchr strcasecmp \
2163 __argz_count __argz_stringify __argz_next])
2164
2165    if test "${ac_cv_func_stpcpy+set}" != "set"; then
2166      AC_CHECK_FUNCS(stpcpy)
2167    fi
2168    if test "${ac_cv_func_stpcpy}" = "yes"; then
2169      AC_DEFINE(HAVE_STPCPY)
2170    fi
2171
2172    AM_LC_MESSAGES
2173    AM_WITH_NLS
2174
2175    if test "x$CATOBJEXT" != "x"; then
2176      if test "x$ALL_LINGUAS" = "x"; then
2177        LINGUAS=
2178      else
2179        AC_MSG_CHECKING(for catalogs to be installed)
2180        NEW_LINGUAS=
2181        for lang in ${LINGUAS=$ALL_LINGUAS}; do
2182          case "$ALL_LINGUAS" in
2183           *$lang*) NEW_LINGUAS="$NEW_LINGUAS $lang" ;;
2184          esac
2185        done
2186        LINGUAS=$NEW_LINGUAS
2187        AC_MSG_RESULT($LINGUAS)
2188      fi
2189
2190      dnl Construct list of names of catalog files to be constructed.
2191      if test -n "$LINGUAS"; then
2192        for lang in $LINGUAS; do CATALOGS="$CATALOGS $lang$CATOBJEXT"; done
2193      fi
2194    fi
2195
2196    dnl The reference to <locale.h> in the installed <libintl.h> file
2197    dnl must be resolved because we cannot expect the users of this
2198    dnl to define HAVE_LOCALE_H.
2199    if test $ac_cv_header_locale_h = yes; then
2200      INCLUDE_LOCALE_H="#include <locale.h>"
2201    else
2202      INCLUDE_LOCALE_H="\
2203 /* The system does not provide the header <locale.h>.  Take care yourself.  */"
2204    fi
2205    AC_SUBST(INCLUDE_LOCALE_H)
2206
2207    dnl Determine which catalog format we have (if any is needed)
2208    dnl For now we know about two different formats:
2209    dnl   Linux libc-5 and the normal X/Open format
2210    test -d intl || mkdir intl
2211    if test "$CATOBJEXT" = ".cat"; then
2212      AC_CHECK_HEADER(linux/version.h, msgformat=linux, msgformat=xopen)
2213
2214      dnl Transform the SED scripts while copying because some dumb SEDs
2215      dnl cannot handle comments.
2216      sed -e '/^#/d' $srcdir/intl/$msgformat-msg.sed > intl/po2msg.sed
2217    fi
2218    dnl po2tbl.sed is always needed.
2219    sed -e '/^#.*[^\\]$/d' -e '/^#$/d' \
2220      $srcdir/intl/po2tbl.sed.in > intl/po2tbl.sed
2221
2222    dnl In the intl/Makefile.in we have a special dependency which makes
2223    dnl only sense for gettext.  We comment this out for non-gettext
2224    dnl packages.
2225    if test "$PACKAGE" = "gettext"; then
2226      GT_NO="#NO#"
2227      GT_YES=
2228    else
2229      GT_NO=
2230      GT_YES="#YES#"
2231    fi
2232    AC_SUBST(GT_NO)
2233    AC_SUBST(GT_YES)
2234
2235    dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
2236    dnl find the mkinstalldirs script in another subdir but ($top_srcdir).
2237    dnl Try to locate is.
2238    MKINSTALLDIRS=
2239    if test -n "$ac_aux_dir"; then
2240      MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
2241    fi
2242    if test -z "$MKINSTALLDIRS"; then
2243      MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
2244    fi
2245    AC_SUBST(MKINSTALLDIRS)
2246
2247    dnl *** For now the libtool support in intl/Makefile is not for real.
2248    l=
2249    AC_SUBST(l)
2250
2251    dnl Generate list of files to be processed by xgettext which will
2252    dnl be included in po/Makefile.
2253    test -d po || mkdir po
2254    if test "x$srcdir" != "x."; then
2255      if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
2256        posrcprefix="$srcdir/"
2257      else
2258        posrcprefix="../$srcdir/"
2259      fi
2260    else
2261      posrcprefix="../"
2262    fi
2263    rm -f po/POTFILES
2264    sed -e "/^#/d" -e "/^\$/d" -e "s,.*, $posrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
2265         < $srcdir/po/POTFILES.in > po/POTFILES
2266   ])
2267
2268 # Search path for a program which passes the given test.
2269 # Ulrich Drepper <drepper@cygnus.com>, 1996.
2270 #
2271 # This file file be copied and used freely without restrictions.  It can
2272 # be used in projects which are not available under the GNU Public License
2273 # but which still want to provide support for the GNU gettext functionality.
2274 # Please note that the actual code is *not* freely available.
2275
2276 # serial 1
2277
2278 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
2279 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
2280 AC_DEFUN(AM_PATH_PROG_WITH_TEST,
2281 [# Extract the first word of "$2", so it can be a program name with args.
2282 set dummy $2; ac_word=[$]2
2283 AC_MSG_CHECKING([for $ac_word])
2284 AC_CACHE_VAL(ac_cv_path_$1,
2285 [case "[$]$1" in
2286   /*)
2287   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
2288   ;;
2289   *)
2290   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
2291   for ac_dir in ifelse([$5], , $PATH, [$5]); do
2292     test -z "$ac_dir" && ac_dir=.
2293     if test -f $ac_dir/$ac_word; then
2294       if [$3]; then
2295         ac_cv_path_$1="$ac_dir/$ac_word"
2296         break
2297       fi
2298     fi
2299   done
2300   IFS="$ac_save_ifs"
2301 dnl If no 4th arg is given, leave the cache variable unset,
2302 dnl so AC_PATH_PROGS will keep looking.
2303 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
2304 ])dnl
2305   ;;
2306 esac])dnl
2307 $1="$ac_cv_path_$1"
2308 if test -n "[$]$1"; then
2309   AC_MSG_RESULT([$]$1)
2310 else
2311   AC_MSG_RESULT(no)
2312 fi
2313 AC_SUBST($1)dnl
2314 ])
2315
2316 # Check whether LC_MESSAGES is available in <locale.h>.
2317 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2318 #
2319 # This file file be copied and used freely without restrictions.  It can
2320 # be used in projects which are not available under the GNU Public License
2321 # but which still want to provide support for the GNU gettext functionality.
2322 # Please note that the actual code is *not* freely available.
2323
2324 # serial 1
2325
2326 AC_DEFUN(AM_LC_MESSAGES,
2327   [if test $ac_cv_header_locale_h = yes; then
2328     AC_CACHE_CHECK([for LC_MESSAGES], am_cv_val_LC_MESSAGES,
2329       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2330        am_cv_val_LC_MESSAGES=yes, am_cv_val_LC_MESSAGES=no)])
2331     if test $am_cv_val_LC_MESSAGES = yes; then
2332       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2333                 [Define if your locale.h file contains LC_MESSAGES.])
2334     fi
2335   fi])
2336
2337 # Do all the work for Automake.  This macro actually does too much --
2338 # some checks are only needed if your package does certain things.
2339 # But this isn't really a big deal.
2340
2341 # serial 1
2342
2343 dnl Usage:
2344 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
2345
2346 AC_DEFUN(AM_INIT_AUTOMAKE,
2347 [AC_REQUIRE([AC_PROG_INSTALL])
2348 PACKAGE=[$1]
2349 AC_SUBST(PACKAGE)
2350 VERSION=[$2]
2351 AC_SUBST(VERSION)
2352 dnl test to see if srcdir already configured
2353 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
2354   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
2355 fi
2356 ifelse([$3],,
2357 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
2358 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
2359 AC_REQUIRE([AM_SANITY_CHECK])
2360 AC_REQUIRE([AC_ARG_PROGRAM])
2361 dnl FIXME This is truly gross.
2362 missing_dir=`cd $ac_aux_dir && pwd`
2363 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
2364 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
2365 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
2366 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
2367 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
2368 AC_REQUIRE([AC_PROG_MAKE_SET])])
2369
2370 #
2371 # Check to make sure that the build environment is sane.
2372 #
2373
2374 AC_DEFUN(AM_SANITY_CHECK,
2375 [AC_MSG_CHECKING([whether build environment is sane])
2376 # Just in case
2377 sleep 1
2378 echo timestamp > conftestfile
2379 # Do `set' in a subshell so we don't clobber the current shell's
2380 # arguments.  Must try -L first in case configure is actually a
2381 # symlink; some systems play weird games with the mod time of symlinks
2382 # (eg FreeBSD returns the mod time of the symlink's containing
2383 # directory).
2384 if (
2385    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
2386    if test "[$]*" = "X"; then
2387       # -L didn't work.
2388       set X `ls -t $srcdir/configure conftestfile`
2389    fi
2390    if test "[$]*" != "X $srcdir/configure conftestfile" \
2391       && test "[$]*" != "X conftestfile $srcdir/configure"; then
2392
2393       # If neither matched, then we have a broken ls.  This can happen
2394       # if, for instance, CONFIG_SHELL is bash and it inherits a
2395       # broken ls alias from the environment.  This has actually
2396       # happened.  Such a system could not be considered "sane".
2397       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2398 alias in your environment])
2399    fi
2400
2401    test "[$]2" = conftestfile
2402    )
2403 then
2404    # Ok.
2405    :
2406 else
2407    AC_MSG_ERROR([newly created file is older than distributed files!
2408 Check your system clock])
2409 fi
2410 rm -f conftest*
2411 AC_MSG_RESULT(yes)])
2412
2413 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
2414 dnl The program must properly implement --version.
2415 AC_DEFUN(AM_MISSING_PROG,
2416 [AC_MSG_CHECKING(for working $2)
2417 # Run test in a subshell; some versions of sh will print an error if
2418 # an executable is not found, even if stderr is redirected.
2419 # Redirect stdin to placate older versions of autoconf.  Sigh.
2420 if ($2 --version) < /dev/null > /dev/null 2>&1; then
2421    $1=$2
2422    AC_MSG_RESULT(found)
2423 else
2424    $1="$3/missing $2"
2425    AC_MSG_RESULT(missing)
2426 fi
2427 AC_SUBST($1)])
2428
2429 # Like AC_CONFIG_HEADER, but automatically create stamp file.
2430
2431 AC_DEFUN(AM_CONFIG_HEADER,
2432 [AC_PREREQ([2.12])
2433 AC_CONFIG_HEADER([$1])
2434 dnl When config.status generates a header, we must update the stamp-h file.
2435 dnl This file resides in the same directory as the config header
2436 dnl that is generated.  We must strip everything past the first ":",
2437 dnl and everything past the last "/".
2438 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
2439 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
2440 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
2441 <<am_indx=1
2442 for am_file in <<$1>>; do
2443   case " <<$>>CONFIG_HEADERS " in
2444   *" <<$>>am_file "*<<)>>
2445     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
2446     ;;
2447   esac
2448   am_indx=`expr "<<$>>am_indx" + 1`
2449 done<<>>dnl>>)
2450 changequote([,]))])
2451