libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4-p5
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999, 2001 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize configure bits.
  15 dnl
  16 dnl GLIBCPP_CONFIGURE
  17 AC_DEFUN(GLIBCPP_CONFIGURE, [
  18   dnl Default to --enable-multilib
  19   AC_ARG_ENABLE(multilib,
  20   [  --enable-multilib       build hella library versions (default)],
  21   [case "${enableval}" in
  22     yes) multilib=yes ;;
  23     no)  multilib=no ;;
  24     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  25    esac], [multilib=yes])dnl
  26
  27   # When building with srcdir == objdir, links to the source files will
  28   # be created in directories within the target_subdir.  We have to
  29   # adjust toplevel_srcdir accordingly, so that configure finds
  30   # install-sh and other auxiliary files that live in the top-level
  31   # source directory.
  32   if test "${srcdir}" = "."; then
  33     if test -z "${with_target_subdir}"; then
  34       toprel=".."
  35     else
  36       if test "${with_target_subdir}" != "."; then
  37         toprel="${with_multisrctop}../.."
  38       else
  39         toprel="${with_multisrctop}.."
  40       fi
  41     fi
  42   else
  43     toprel=".."
  44   fi
  45   AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  46   toplevel_srcdir=\${top_srcdir}/$toprel
  47   AC_SUBST(toplevel_srcdir)
  48
  49   # Export build and source directories.
  50   # These need to be absolute paths, yet at the same time need to
  51   # canonicalize only relative paths, because then amd will not unmount
  52   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  53   glibcpp_builddir=`pwd`
  54   case $srcdir in
  55   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  56   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  57   esac
  58   AC_SUBST(glibcpp_builddir)
  59   AC_SUBST(glibcpp_srcdir)
  60
  61   dnl This is here just to satisfy automake.
  62   ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  63
  64   AC_PROG_AWK
  65   # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.5x, can also
  66   # be 'cp -p' if linking isn't available.
  67   #ac_cv_prog_LN_S='cp -p'
  68   AC_PROG_LN_S
  69
  70   # We use these options to decide which functions to include.
  71   AC_ARG_WITH(target-subdir,
  72   [  --with-target-subdir=SUBDIR
  73                           configuring in a subdirectory])
  74   AC_ARG_WITH(cross-host,
  75   [  --with-cross-host=HOST  configuring with a cross compiler])
  76
  77   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  78   AC_SUBST(glibcpp_basedir)
  79
  80   # Never versions of autoconf add an underscore to these functions.
  81   # Prevent future problems ...
  82   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  83   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  84   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  85   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  86
  87   # AC_PROG_CC
  88   # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  89   # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  90   # are probably using a cross compiler, which will not be able to fully
  91   # link an executable.  This is addressed in later versions of autoconf.
  92
  93   AC_DEFUN(LIB_AC_PROG_CC,
  94   [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  95   dnl Fool anybody using AC_PROG_CC.
  96   AC_PROVIDE([AC_PROG_CC])
  97   AC_CHECK_PROG(CC, gcc, gcc)
  98   if test -z "$CC"; then
  99     AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
 100     test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
 101   fi
 102
 103   AC_PROG_CC_GNU
 104
 105   if test $ac_cv_prog_gcc = yes; then
 106     GCC=yes
 107   dnl Check whether -g works, even if CFLAGS is set, in case the package
 108   dnl plays around with CFLAGS (such as to build both debugging and
 109   dnl normal versions of a library), tasteless as that idea is.
 110     ac_test_CFLAGS="${CFLAGS+set}"
 111     ac_save_CFLAGS="$CFLAGS"
 112     CFLAGS=
 113     AC_PROG_CC_G
 114     if test "$ac_test_CFLAGS" = set; then
 115       CFLAGS="$ac_save_CFLAGS"
 116     elif test $ac_cv_prog_cc_g = yes; then
 117       CFLAGS="-g -O2"
 118     else
 119       CFLAGS="-O2"
 120     fi
 121   else
 122     GCC=
 123     test "${CFLAGS+set}" = set || CFLAGS="-g"
 124   fi
 125   ])
 126
 127   LIB_AC_PROG_CC
 128
 129   # Likewise for AC_PROG_CXX.  We can't just call it directly because g++
 130   # will try to link in libstdc++.
 131   AC_DEFUN(LIB_AC_PROG_CXX,
 132   [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 133   dnl Fool anybody using AC_PROG_CXX.
 134   AC_PROVIDE([AC_PROG_CXX])
 135   # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 136   # flags that come in CXX while configuring libstdc++.  They're different
 137   # from those used for all other target libraries.  If CXX is set in
 138   # the environment, respect that here.
 139   glibcpp_CXX=$CXX
 140   AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 141   AC_SUBST(glibcpp_CXX)
 142   CXX=$glibcpp_CXX
 143   test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 144
 145   AC_PROG_CXX_GNU
 146
 147   if test $ac_cv_prog_gxx = yes; then
 148     GXX=yes
 149     dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 150     dnl plays around with CXXFLAGS (such as to build both debugging and
 151     dnl normal versions of a library), tasteless as that idea is.
 152     ac_test_CXXFLAGS="${CXXFLAGS+set}"
 153     ac_save_CXXFLAGS="$CXXFLAGS"
 154     CXXFLAGS=
 155     AC_PROG_CXX_G
 156     if test "$ac_test_CXXFLAGS" = set; then
 157       CXXFLAGS="$ac_save_CXXFLAGS"
 158     elif test $ac_cv_prog_cxx_g = yes; then
 159       CXXFLAGS="-g -O2"
 160     else
 161       CXXFLAGS="-O2"
 162     fi
 163   else
 164     GXX=
 165     test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 166   fi
 167   ])
 168
 169   LIB_AC_PROG_CXX
 170
 171   # For some reason, gettext needs this.
 172   AC_ISC_POSIX
 173
 174   AC_CHECK_TOOL(AS, as)
 175   AC_CHECK_TOOL(AR, ar)
 176   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 177   AC_PROG_INSTALL
 178
 179   AM_MAINTAINER_MODE
 180
 181   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 182   # at least currently, we never actually build a program, so we never
 183   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 184   # fails, because we are probably configuring with a cross compiler
 185   # which can't create executables.  So we include AC_EXEEXT to keep
 186   # automake happy, but we don't execute it, since we don't care about
 187   # the result.
 188   if false; then
 189     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 190     # to nothing, so nothing would remain between `then' and `fi' if it
 191     # were not for the `:' below.
 192     :
 193     AC_EXEEXT
 194   fi
 195
 196   . [$]{glibcpp_basedir}/configure.host
 197
 198   case [$]{glibcpp_basedir} in
 199     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 200     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 201   esac
 202
 203   # This does for the target what configure.host does for the host.  In
 204   # addition to possibly modifying the same flags, it also sets up symlinks.
 205   GLIBCPP_CHECK_TARGET
 206
 207 ])
 208
 209
 210 dnl
 211 dnl Check to see if g++ can compile this library, and if so, if any version-
 212 dnl specific precautions need to be taken.
 213 dnl
 214 dnl GLIBCPP_CHECK_COMPILER_VERSION
 215 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 216 if test ! -f stamp-sanity-compiler; then
 217   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 218   AC_LANG_SAVE
 219   AC_LANG_CPLUSPLUS
 220   AC_TRY_COMPILE(, [
 221   #if __GNUC__ < 3
 222     not_ok
 223   #endif
 224   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 225   AC_LANG_RESTORE
 226   AC_MSG_RESULT($gpp_satisfactory)
 227   touch stamp-sanity-compiler
 228 fi
 229 ])
 230
 231
 232 dnl
 233 dnl Tests for newer compiler features, or features that are present in newer
 234 dnl compiler versions but not older compiler versions still in use, should
 235 dnl be placed here.
 236 dnl
 237 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 238 dnl new inlining code or the new system_header pragma will die on -Werror.
 239 dnl Leave it out by default and use maint-mode to use it.
 240 dnl
 241 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 242 dnl compiler supports it and the user has not requested debug mode.
 243 dnl
 244 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 245 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 246   # All these tests are for C++; save the language and the compiler flags.
 247   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 248   # found in GLIBCPP_CONFIGURE.
 249   AC_LANG_SAVE
 250   AC_LANG_CPLUSPLUS
 251   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 252   ac_save_CXXFLAGS="$CXXFLAGS"
 253
 254   # Check for maintainer-mode bits.
 255   if test x"$USE_MAINTAINER_MODE" = xno; then
 256     WERROR=''
 257   else
 258     WERROR='-Werror'
 259   fi
 260
 261   # Check for -ffunction-sections -fdata-sections
 262   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 263   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 264   AC_TRY_COMPILE(, [int foo;
 265   ], [ac_fdsections=yes], [ac_fdsections=no])
 266   if test "$ac_test_CXXFLAGS" = set; then
 267     CXXFLAGS="$ac_save_CXXFLAGS"
 268   else
 269     # this is the suspicious part
 270     CXXFLAGS=''
 271   fi
 272   if test x"$ac_fdsections" = x"yes" &&
 273      test x"$enable_debug" = x"no"; then
 274     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 275   fi
 276   AC_MSG_RESULT($ac_fdsections)
 277
 278   AC_LANG_RESTORE
 279   AC_SUBST(WERROR)
 280   AC_SUBST(SECTION_FLAGS)
 281 ])
 282
 283
 284 dnl
 285 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 286 dnl the native linker is in use, all variables will be defined to something
 287 dnl safe (like an empty string).
 288 dnl
 289 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 290 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 291 dnl Define LD, with_gnu_ld, and (possibly) glibcpp_gnu_ld_version as
 292 dnl side-effects of testing.
 293 dnl
 294 dnl GLIBCPP_CHECK_LINKER_FEATURES
 295 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 296   # If we're not using GNU ld, then there's no point in even trying these
 297   # tests.  Check for that first.  We should have already tested for gld
 298   # by now (in libtool), but require it now just to be safe...
 299   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 300   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 301   AC_REQUIRE([AC_PROG_LD])
 302
 303   # The name set by libtool depends on the version of libtool.  Shame on us
 304   # for depending on an impl detail, but c'est la vie.  Older versions used
 305   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 306   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 307   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 308   # set (hence we're using an older libtool), then set it.
 309   if test x${with_gnu_ld+set} != xset; then
 310     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 311       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 312       with_gnu_ld=no
 313     else
 314       with_gnu_ld=$ac_cv_prog_gnu_ld
 315     fi
 316   fi
 317
 318   # Start by getting the version number.  I think the libtool test already
 319   # does some of this, but throws away the result.
 320   changequote(,)
 321   ldver=`$LD --version 2>/dev/null | head -1 | \
 322          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 323   changequote([,])
 324   glibcpp_gnu_ld_version=`echo $ldver | \
 325          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 326
 327   # Set --gc-sections.
 328   if test "$with_gnu_ld" = "notbroken"; then
 329     # GNU ld it is!  Joy and bunny rabbits!
 330
 331     # All these tests are for C++; save the language and the compiler flags.
 332     # Need to do this so that g++ won't try to link in libstdc++
 333     ac_test_CFLAGS="${CFLAGS+set}"
 334     ac_save_CFLAGS="$CFLAGS"
 335     CFLAGS='-x c++  -Wl,--gc-sections'
 336
 337     # Check for -Wl,--gc-sections
 338     # XXX This test is broken at the moment, as symbols required for
 339     # linking are now in libsupc++ (not built yet.....). In addition,
 340     # this test has cored on solaris in the past. In addition,
 341     # --gc-sections doesn't really work at the moment (keeps on discarding
 342     # used sections, first .eh_frame and now some of the glibc sections for
 343     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 344     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 345     AC_TRY_RUN([
 346      int main(void)
 347      {
 348        try { throw 1; }
 349        catch (...) { };
 350        return 0;
 351      }
 352     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 353     if test "$ac_test_CFLAGS" = set; then
 354       CFLAGS="$ac_save_CFLAGS"
 355     else
 356       # this is the suspicious part
 357       CFLAGS=''
 358     fi
 359     if test "$ac_sectionLDflags" = "yes"; then
 360       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 361     fi
 362     AC_MSG_RESULT($ac_sectionLDflags)
 363   fi
 364
 365   # Set linker optimization flags.
 366   if test x"$with_gnu_ld" = x"yes" && test x"$enable_debug" = x"no"; then
 367     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 368   fi
 369
 370   AC_SUBST(SECTION_LDFLAGS)
 371   AC_SUBST(OPT_LDFLAGS)
 372 ])
 373
 374
 375 dnl
 376 dnl Check to see if the (math function) argument passed is
 377 dnl declared when using the c++ compiler
 378 dnl ASSUMES argument is a math function with ONE parameter
 379 dnl
 380 dnl GLIBCPP_CHECK_MATH_DECL_1
 381 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 382   AC_MSG_CHECKING([for $1 declaration])
 383   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 384     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 385       AC_LANG_SAVE
 386       AC_LANG_CPLUSPLUS
 387       AC_TRY_COMPILE([#include <math.h>
 388                       #ifdef HAVE_IEEEFP_H
 389                       #include <ieeefp.h>
 390                       #endif
 391                      ],
 392                      [ $1(0);],
 393                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 394       AC_LANG_RESTORE
 395     ])
 396   fi
 397   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 398 ])
 399
 400 dnl
 401 dnl Check to see if the (math function) argument passed is
 402 dnl 1) declared when using the c++ compiler
 403 dnl 2) has "C" linkage
 404 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 405 dnl
 406 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 407 dnl
 408 dnl argument 1 is name of function to check
 409 dnl
 410 dnl ASSUMES argument is a math function with ONE parameter
 411 dnl
 412 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 413 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 414   GLIBCPP_CHECK_MATH_DECL_1($1)
 415   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 416     AC_CHECK_FUNCS($1)
 417   else
 418     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 419     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 420       AC_CHECK_FUNCS(_$1)
 421     fi
 422   fi
 423 ])
 424
 425
 426 dnl
 427 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 428 dnl of functions at once.  It's an all-or-nothing check -- either
 429 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 430 dnl Doing it this way saves significant configure time.
 431 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 432   AC_MSG_CHECKING([for $1 functions])
 433   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 434     AC_LANG_SAVE
 435     AC_LANG_CPLUSPLUS
 436     AC_TRY_COMPILE([#include <math.h>],
 437                    [ `for x in $3; do echo "$x (0);"; done` ],
 438                    [glibcpp_cv_func_$2_use=yes],
 439                    [glibcpp_cv_func_$2_use=no])
 440     AC_LANG_RESTORE])
 441   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 442   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 443     AC_CHECK_FUNCS($3)
 444   fi
 445 ])
 446
 447 dnl
 448 dnl Check to see if the (math function) argument passed is
 449 dnl declared when using the c++ compiler
 450 dnl ASSUMES argument is a math function with TWO parameters
 451 dnl
 452 dnl GLIBCPP_CHECK_MATH_DECL_2
 453 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 454   AC_MSG_CHECKING([for $1 declaration])
 455   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 456     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 457       AC_LANG_SAVE
 458       AC_LANG_CPLUSPLUS
 459       AC_TRY_COMPILE([#include <math.h>],
 460                      [ $1(0, 0);],
 461                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 462       AC_LANG_RESTORE
 463     ])
 464   fi
 465   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 466 ])
 467
 468 dnl
 469 dnl Check to see if the (math function) argument passed is
 470 dnl 1) declared when using the c++ compiler
 471 dnl 2) has "C" linkage
 472 dnl
 473 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 474 dnl
 475 dnl argument 1 is name of function to check
 476 dnl
 477 dnl ASSUMES argument is a math function with TWO parameters
 478 dnl
 479 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 480 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 481   GLIBCPP_CHECK_MATH_DECL_2($1)
 482   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 483     AC_CHECK_FUNCS($1)
 484   else
 485     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 486     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 487       AC_CHECK_FUNCS(_$1)
 488     fi
 489   fi
 490 ])
 491
 492
 493 dnl
 494 dnl Check to see if the (math function) argument passed is
 495 dnl declared when using the c++ compiler
 496 dnl ASSUMES argument is a math function with THREE parameters
 497 dnl
 498 dnl GLIBCPP_CHECK_MATH_DECL_3
 499 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 500   AC_MSG_CHECKING([for $1 declaration])
 501   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 502     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 503       AC_LANG_SAVE
 504       AC_LANG_CPLUSPLUS
 505       AC_TRY_COMPILE([#include <math.h>],
 506                      [ $1(0, 0, 0);],
 507                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 508       AC_LANG_RESTORE
 509     ])
 510   fi
 511   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 512 ])
 513
 514 dnl
 515 dnl Check to see if the (math function) argument passed is
 516 dnl 1) declared when using the c++ compiler
 517 dnl 2) has "C" linkage
 518 dnl
 519 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 520 dnl
 521 dnl argument 1 is name of function to check
 522 dnl
 523 dnl ASSUMES argument is a math function with THREE parameters
 524 dnl
 525 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 526 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 527   GLIBCPP_CHECK_MATH_DECL_3($1)
 528   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 529     AC_CHECK_FUNCS($1)
 530   else
 531     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 532     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 533       AC_CHECK_FUNCS(_$1)
 534     fi
 535   fi
 536 ])
 537
 538
 539 dnl
 540 dnl Check to see if the (stdlib function) argument passed is
 541 dnl 1) declared when using the c++ compiler
 542 dnl 2) has "C" linkage
 543 dnl
 544 dnl argument 1 is name of function to check
 545 dnl
 546 dnl ASSUMES argument is a math function with TWO parameters
 547 dnl
 548 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 549 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 550   AC_MSG_CHECKING([for $1 declaration])
 551   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 552     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 553       AC_LANG_SAVE
 554       AC_LANG_CPLUSPLUS
 555       AC_TRY_COMPILE([#include <stdlib.h>],
 556                      [ $1(0, 0);],
 557                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 558       AC_LANG_RESTORE
 559     ])
 560   fi
 561   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 562   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 563     AC_CHECK_FUNCS($1)
 564   fi
 565 ])
 566
 567
 568 dnl
 569 dnl Check to see if the (stdlib function) argument passed is
 570 dnl 1) declared when using the c++ compiler
 571 dnl 2) has "C" linkage
 572 dnl
 573 dnl argument 1 is name of function to check
 574 dnl
 575 dnl ASSUMES argument is a function with THREE parameters
 576 dnl
 577 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3
 578 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3, [
 579   AC_MSG_CHECKING([for $1 declaration])
 580   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 581     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 582       AC_LANG_SAVE
 583       AC_LANG_CPLUSPLUS
 584       AC_TRY_COMPILE([#include <stdlib.h>],
 585                      [ $1(0, 0, 0);],
 586                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 587       AC_LANG_RESTORE
 588     ])
 589   fi
 590   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 591   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 592     AC_CHECK_FUNCS($1)
 593   fi
 594 ])
 595
 596
 597 dnl
 598 dnl Because the builtins are picky picky picky about the arguments they take,
 599 dnl do an explict linkage tests here.
 600 dnl Check to see if the (math function) argument passed is
 601 dnl 1) declared when using the c++ compiler
 602 dnl 2) has "C" linkage
 603 dnl
 604 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 605 dnl
 606 dnl argument 1 is name of function to check
 607 dnl
 608 dnl ASSUMES argument is a math function with ONE parameter
 609 dnl
 610 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 611 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 612   AC_MSG_CHECKING([for $1 declaration])
 613   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 614     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 615       AC_LANG_SAVE
 616       AC_LANG_CPLUSPLUS
 617       AC_TRY_COMPILE([#include <math.h>],
 618                      [ $1(0);],
 619                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 620       AC_LANG_RESTORE
 621     ])
 622   fi
 623   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 624   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 625     AC_MSG_CHECKING([for $1 linkage])
 626     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 627       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 628         AC_TRY_LINK([#include <math.h>],
 629                     [ $1(0);],
 630                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 631       ])
 632     fi
 633     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 634     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 635       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 636       AC_DEFINE_UNQUOTED(${ac_tr_func})
 637     fi
 638   fi
 639 ])
 640
 641
 642 dnl
 643 dnl Check to see what builtin math functions are supported
 644 dnl
 645 dnl check for __builtin_abs
 646 dnl check for __builtin_fabsf
 647 dnl check for __builtin_fabs
 648 dnl check for __builtin_fabl
 649 dnl check for __builtin_labs
 650 dnl check for __builtin_sqrtf
 651 dnl check for __builtin_sqrtl
 652 dnl check for __builtin_sqrt
 653 dnl check for __builtin_sinf
 654 dnl check for __builtin_sin
 655 dnl check for __builtin_sinl
 656 dnl check for __builtin_cosf
 657 dnl check for __builtin_cos
 658 dnl check for __builtin_cosl
 659 dnl
 660 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 661 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 662   dnl Test for builtin math functions.
 663   dnl These are made in gcc/c-common.c
 664   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 665   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 666   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 667   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 668   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 669
 670   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 671   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 672   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 673
 674   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 675   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 676   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 677
 678   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 679   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 680   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 681
 682   dnl There is, without a doubt, a more elegant way to have these
 683   dnl names exported so that they won't be stripped out of acconfig.h by
 684   dnl autoheader. I leave this as an exercise to somebody less frustrated
 685   dnl than I.... please email the libstdc++ list if you can figure out a
 686   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 687   dnl AC_CHECK_FUNC for things to steal.)
 688   dummyvar=no
 689   if test x$dummyvar = x"yes"; then
 690     AC_DEFINE(HAVE___BUILTIN_ABS)
 691     AC_DEFINE(HAVE___BUILTIN_LABS)
 692     AC_DEFINE(HAVE___BUILTIN_COS)
 693     AC_DEFINE(HAVE___BUILTIN_COSF)
 694     AC_DEFINE(HAVE___BUILTIN_COSL)
 695     AC_DEFINE(HAVE___BUILTIN_FABS)
 696     AC_DEFINE(HAVE___BUILTIN_FABSF)
 697     AC_DEFINE(HAVE___BUILTIN_FABSL)
 698     AC_DEFINE(HAVE___BUILTIN_SIN)
 699     AC_DEFINE(HAVE___BUILTIN_SINF)
 700     AC_DEFINE(HAVE___BUILTIN_SINL)
 701     AC_DEFINE(HAVE___BUILTIN_SQRT)
 702     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 703     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 704   fi
 705 ])
 706
 707
 708 dnl
 709 dnl Check to see what the underlying c library
 710 dnl These checks need to do two things:
 711 dnl 1) make sure the name is declared when using the c++ compiler
 712 dnl 2) make sure the name has "C" linkage
 713 dnl This might seem like overkill but experience has shown that it's not...
 714 dnl
 715 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 716 dnl Define HAVE_STRTOF if "strtof" is declared and links
 717 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 718 dnl
 719 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 720 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 721   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 722   ac_save_CXXFLAGS="$CXXFLAGS"
 723   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 724
 725   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 726   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtof)
 727   AC_CHECK_FUNCS(drand48)
 728
 729   CXXFLAGS="$ac_save_CXXFLAGS"
 730 ])
 731
 732
 733 dnl
 734 dnl Check to see what the underlying c library or math library is like.
 735 dnl These checks need to do two things:
 736 dnl 1) make sure the name is declared when using the c++ compiler
 737 dnl 2) make sure the name has "C" linkage
 738 dnl This might seem like overkill but experience has shown that it's not...
 739 dnl
 740 dnl Define HAVE_CARGF etc if "cargf" is found.
 741 dnl
 742 dnl GLIBCPP_CHECK_MATH_SUPPORT
 743 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 744   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 745   ac_save_CXXFLAGS="$CXXFLAGS"
 746   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 747
 748   dnl Check libm
 749   AC_CHECK_LIB(m, sin, libm="-lm")
 750   ac_save_LIBS="$LIBS"
 751   LIBS="$LIBS $libm"
 752
 753   dnl Check to see if certain C math functions exist.
 754   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 755   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 756   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 757   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 758   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 759   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 760   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 761   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 762
 763   dnl Check to see if basic C math functions have float versions.
 764   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 765                                           float_trig,
 766                                           acosf asinf atanf \
 767                                           cosf sinf tanf \
 768                                           coshf sinhf tanhf)
 769   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 770                                           float_round,
 771                                           ceilf floorf)
 772   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 773   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 774   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 775   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 776   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 777   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 778   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 779   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 780   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 781   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 782   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 783   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 784   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 785   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 786   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 787   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 788
 789   dnl Check to see if basic C math functions have long double versions.
 790   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 791                                           long_double_trig,
 792                                           acosl asinl atanl \
 793                                           cosl sinl tanl \
 794                                           coshl sinhl tanhl)
 795   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 796                                           long_double_round,
 797                                           ceill floorl)
 798   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 799   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 800   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 801   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 802   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 803   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 804   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 805   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 806   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 807   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 808   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 809   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 810   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 811   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 812   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 813   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 814   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 815
 816   dnl Some runtimes have these functions with a preceding underscore. Please
 817   dnl keep this sync'd with the one above. And if you add any new symbol,
 818   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 819   dnl Check to see if certain C math functions exist.
 820
 821   dnl Check to see if basic C math functions have float versions.
 822   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 823                                           _float_trig,
 824                                           _acosf _asinf _atanf \
 825                                           _cosf _sinf _tanf \
 826                                           _coshf _sinhf _tanhf)
 827   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 828                                           _float_round,
 829                                           _ceilf _floorf)
 830
 831   dnl Check to see if basic C math functions have long double versions.
 832   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 833                                           _long_double_trig,
 834                                           _acosl _asinl _atanl \
 835                                           _cosl _sinl _tanl \
 836                                           _coshl _sinhl _tanhl)
 837   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 838                                           _long_double_round,
 839                                           _ceill _floorl)
 840
 841   LIBS="$ac_save_LIBS"
 842   CXXFLAGS="$ac_save_CXXFLAGS"
 843 ])
 844
 845
 846 dnl
 847 dnl Check to see if there is native support for complex
 848 dnl
 849 dnl Don't compile bits in math/* if native support exits.
 850 dnl
 851 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 852 dnl
 853 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 854 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 855   dnl Check for complex versions of math functions of platform.
 856   AC_CHECK_LIB(m, main)
 857   AC_REPLACE_MATHFUNCS(nan copysignf)
 858
 859   dnl For __signbit to signbit conversions.
 860   AC_CHECK_FUNCS([__signbit], , [LIBMATHOBJS="$LIBMATHOBJS signbit.lo"])
 861   AC_CHECK_FUNCS([__signbitf], , [LIBMATHOBJS="$LIBMATHOBJS signbitf.lo"])
 862
 863   dnl Compile the long double complex functions only if the function
 864   dnl provides the non-complex long double functions that are needed.
 865   dnl Currently this includes copysignl, which should be
 866   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 867   if test x$ac_cv_func_copysignl = x"yes"; then
 868     AC_CHECK_FUNCS([__signbitl], , [LIBMATHOBJS="$LIBMATHOBJS signbitl.lo"])
 869   fi
 870
 871   AC_SUBST(LIBMATHOBJS)
 872 ])
 873
 874
 875 dnl Check to see what architecture and operating system we are compiling
 876 dnl for.  Also, if architecture- or OS-specific flags are required for
 877 dnl compilation, pick them up here.
 878 dnl
 879 dnl GLIBCPP_CHECK_TARGET
 880 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 881     . [$]{glibcpp_basedir}/configure.target
 882     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 883     AC_MSG_RESULT(OS config directory is $os_include_dir)
 884 ])
 885
 886
 887 dnl
 888 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 889 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 890 dnl must have been previously checked.)
 891 dnl
 892 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 893 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 894 dnl
 895 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 896 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 897
 898   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 899   dnl others even if wchar_t support is not on.
 900   AC_MSG_CHECKING([for mbstate_t])
 901   AC_TRY_COMPILE([#include <wchar.h>],
 902   [mbstate_t teststate;],
 903   have_mbstate_t=yes, have_mbstate_t=no)
 904   AC_MSG_RESULT($have_mbstate_t)
 905   if test x"$have_mbstate_t" = xyes; then
 906     AC_DEFINE(HAVE_MBSTATE_T)
 907   fi
 908
 909   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 910   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 911   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 912
 913   dnl Only continue checking if the ISO C99 headers exist and support is on.
 914   if test x"$ac_has_wchar_h" = xyes &&
 915      test x"$ac_has_wctype_h" = xyes &&
 916      test x"$enable_c_mbchar" != xno; then
 917
 918     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 919     dnl numeric_limits can instantiate type_traits<wchar_t>
 920     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 921     AC_TRY_COMPILE([#include <wchar.h>],
 922     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 923     has_wchar_minmax=yes, has_wchar_minmax=no)
 924     AC_MSG_RESULT($has_wchar_minmax)
 925
 926     dnl Test wchar.h for WEOF, which is what we use to determine whether
 927     dnl to specialize for char_traits<wchar_t> or not.
 928     AC_MSG_CHECKING([for WEOF])
 929     AC_TRY_COMPILE([
 930       #include <wchar.h>
 931       #include <stddef.h>],
 932     [wint_t i = WEOF;],
 933     has_weof=yes, has_weof=no)
 934     AC_MSG_RESULT($has_weof)
 935
 936     dnl Tests for wide character functions used in char_traits<wchar_t>.
 937     ac_wfuncs=yes
 938     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 939     ac_wfuncs=no)
 940
 941     dnl Checks for names injected into std:: by the c_std headers.
 942     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 943     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 944     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 945     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 946     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 947     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 948     ac_wfuncs=no)
 949
 950     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 951     if test x"$has_weof" = xyes &&
 952        test x"$has_wchar_minmax" = xyes &&
 953        test x"$ac_wfuncs" = xyes; then
 954       ac_isoC99_wchar_t=yes
 955     else
 956       ac_isoC99_wchar_t=no
 957     fi
 958     AC_MSG_RESULT($ac_isoC99_wchar_t)
 959
 960     dnl Use iconv for wchar_t to char conversions. As such, check for
 961     dnl X/Open Portability Guide, version 2 features (XPG2).
 962     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 963     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 964
 965     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 966     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 967     ac_save_LIBS="$LIBS"
 968     LIBS="$LIBS $libiconv"
 969
 970     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 971     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 972
 973     LIBS="$ac_save_LIBS"
 974
 975     AC_MSG_CHECKING([for XPG2 wchar_t support])
 976     if test x"$ac_has_iconv_h" = xyes &&
 977        test x"$ac_has_langinfo_h" = xyes &&
 978        test x"$ac_XPG2funcs" = xyes; then
 979       ac_XPG2_wchar_t=yes
 980     else
 981       ac_XPG2_wchar_t=no
 982     fi
 983     AC_MSG_RESULT($ac_XPG2_wchar_t)
 984
 985     dnl At the moment, only enable wchar_t specializations if all the
 986     dnl above support is present.
 987     AC_MSG_CHECKING([for enabled wchar_t specializations])
 988     if test x"$ac_isoC99_wchar_t" = xyes &&
 989        test x"$ac_XPG2_wchar_t" = xyes; then
 990       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 991       AC_MSG_RESULT("yes")
 992     else
 993       AC_MSG_RESULT("no")
 994     fi
 995   else
 996     dnl Wide characters disabled by the user.
 997     AC_MSG_WARN([wchar_t support disabled.])
 998   fi
 999 ])
1000
1001
1002 dnl
1003 dnl Check for special debugging mode; not for production use.
1004 dnl
1005 dnl GLIBCPP_ENABLE_DEBUG
1006 dnl --enable-debug sets '-ggdb3 -O0'.
1007 dnl --disable-debug sets '-g' and whatever optimization options the
1008 dnl     compiler can handle.
1009 dnl  +  --enable-maintainer-mode automatically defaults this to on.
1010 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
1011 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1012 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1013 dnl       defaults to `no'.
1014 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1015 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1016 AC_ARG_ENABLE(debug,
1017 changequote(<<, >>)dnl
1018 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1019 changequote([, ])dnl
1020 [case "${enableval}" in
1021  yes) enable_debug=yes ;;
1022  no)  enable_debug=no ;;
1023  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1024  esac],
1025 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1026
1027 dnl Option parsed, now set things appropriately
1028 case "${enable_debug}" in
1029     yes)
1030         DEBUG_FLAGS='-O0 -ggdb3'
1031         ;;
1032     no)
1033         DEBUG_FLAGS='-g'
1034         ;;
1035 esac
1036 AC_SUBST(DEBUG_FLAGS)
1037 ])
1038
1039
1040 dnl
1041 dnl Check for "unusual" flags to pass to the compiler while building.
1042 dnl
1043 dnl GLIBCPP_ENABLE_CXX_FLAGS
1044 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1045 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1046 dnl     Somehow this same set of flags must be passed when [re]building
1047 dnl     libgcc.
1048 dnl --disable-cxx-flags passes nothing.
1049 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1050 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1051 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1052 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1053 dnl       If "default flags" is an empty string (or "none"), the effect is
1054 dnl       the same as --disable or --enable=no.
1055 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1056 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1057 AC_ARG_ENABLE(cxx-flags,
1058 changequote(<<, >>)dnl
1059 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1060                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1061 changequote([, ])dnl
1062 [case "x$enableval" in
1063  xyes)
1064         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1065  xno|x)
1066         enable_cxx_flags='' ;;
1067  *)
1068         enable_cxx_flags="$enableval" ;;
1069  esac],
1070 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1071
1072 dnl Thinko on my part during design.  This kludge is the workaround.
1073 if test "$enable_cxx_flags" = "none"; then
1074   enable_cxx_flags='';
1075 fi
1076
1077 dnl Run through flags (either default or command-line) and set anything
1078 dnl extra (e.g., #defines) that must accompany particular g++ options.
1079 if test -n "$enable_cxx_flags"; then
1080     for f in $enable_cxx_flags; do
1081         case "$f" in
1082             -fhonor-std)  ;;
1083             -*)  ;;
1084             *)   # and we're trying to pass /what/ exactly?
1085                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1086         esac
1087     done
1088 fi
1089 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1090 AC_SUBST(EXTRA_CXX_FLAGS)
1091 ])
1092
1093
1094 dnl
1095 dnl Check for which locale library to use:  gnu or generic.
1096 dnl
1097 dnl GLIBCPP_ENABLE_CLOCALE
1098 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1099 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1100 dnl
1101 dnl default is generic
1102 dnl
1103 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1104   AC_MSG_CHECKING([for clocale to use])
1105   AC_ARG_ENABLE(clocale,
1106   [  --enable-clocale        enable model for target locale package.
1107   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1108   ],
1109   if test x$enable_clocale = xno; then
1110      enable_clocale=no
1111   fi,
1112      enable_clocale=no)
1113
1114   enable_clocale_flag=$enable_clocale
1115
1116   dnl Probe for locale support if no specific model is specified.
1117   dnl Default to "generic"
1118   if test x$enable_clocale_flag = xno; then
1119     case x${target_os} in
1120       xlinux* | xgnu*)
1121         AC_EGREP_CPP([_GLIBCPP_ok], [
1122         #include <features.h>
1123         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1124           _GLIBCPP_ok
1125         #endif
1126         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1127
1128         # Test for bugs early in glibc-2.2.x series
1129         if test x$enable_clocale_flag = xgnu; then
1130           AC_TRY_RUN([
1131           #define _GNU_SOURCE 1
1132           #include <locale.h>
1133           int main()
1134           {
1135             const char __one[] = "Äuglein Augmen";
1136             const char __two[] = "Äuglein";
1137             int i;
1138             int j;
1139             __locale_t  loc;
1140             __locale_t  loc_dup;
1141             loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1142             loc_dup = __duplocale(loc);
1143             i = __strcoll_l(__one, __two, loc);
1144             j = __strcoll_l(__one, __two, loc_dup);
1145             return 0;
1146           }
1147           ],
1148           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1149           [enable_clocale_flag=generic])
1150         fi
1151
1152         # ... at some point put __strxfrm_l tests in as well.
1153         ;;
1154       *)
1155         enable_clocale_flag=generic
1156         ;;
1157     esac
1158   fi
1159
1160   dnl Set configure bits for specified locale package
1161   case x${enable_clocale_flag} in
1162     xgeneric)
1163       AC_MSG_RESULT(generic)
1164
1165       # Don't use gettext.
1166       USE_NLS=no
1167
1168       CLOCALE_H=config/locale/generic/c_locale.h
1169       CLOCALE_CC=config/locale/generic/c_locale.cc
1170       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1171       CCOLLATE_CC=config/locale/generic/collate_members.cc
1172       CCTYPE_CC=config/locale/generic/ctype_members.cc
1173       CMESSAGES_H=config/locale/generic/messages_members.h
1174       CMESSAGES_CC=config/locale/generic/messages_members.cc
1175       CMONEY_CC=config/locale/generic/monetary_members.cc
1176       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1177       CTIME_CC=config/locale/generic/time_members.cc
1178       ;;
1179     xgnu)
1180       AC_MSG_RESULT(gnu)
1181
1182       # Declare intention to use gettext, and add support for specific
1183       # languages.
1184       # For some reason, ALL_LINGUAS has to be before AM_GNU_GETTEXT
1185       ALL_LINGUAS="de fr"
1186       # Don't call AM_GNU_GETTEXT here. Instead, assume glibc.
1187       # Need to deal with MSGFMT, USE_NLS, and glibcpp_[P,M]OFILES
1188       USE_NLS=yes
1189
1190       # Export the build objects.
1191       for ling in $ALL_LINGUAS; do \
1192         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1193         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1194       done
1195       AC_SUBST(glibcpp_MOFILES)
1196       AC_SUBST(glibcpp_POFILES)
1197
1198       CLOCALE_H=config/locale/gnu/c_locale.h
1199       CLOCALE_CC=config/locale/gnu/c_locale.cc
1200       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1201       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1202       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1203       CMESSAGES_H=config/locale/gnu/messages_members.h
1204       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1205       CMONEY_CC=config/locale/gnu/monetary_members.cc
1206       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1207       CTIME_CC=config/locale/gnu/time_members.cc
1208       ;;
1209     xieee_1003.1-2001)
1210       AC_MSG_RESULT(generic)
1211
1212       # Don't use gettext.
1213       USE_NLS=no
1214
1215       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1216       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1217       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1218       CCOLLATE_CC=config/locale/generic/collate_members.cc
1219       CCTYPE_CC=config/locale/generic/ctype_members.cc
1220       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1221       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1222       CMONEY_CC=config/locale/generic/monetary_members.cc
1223       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1224       CTIME_CC=config/locale/generic/time_members.cc
1225       ;;
1226     *)
1227       echo "$enable_clocale is an unknown locale package" 1>&2
1228       exit 1
1229       ;;
1230   esac
1231
1232   # This is where the testsuite looks for locale catalogs, using the
1233   # -DLOCALEDIR define during testsuite compilation.
1234   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1235   AC_SUBST(glibcpp_localedir)
1236
1237   AC_SUBST(USE_NLS)
1238   AC_SUBST(CLOCALE_H)
1239   AC_SUBST(CCODECVT_H)
1240   AC_SUBST(CMESSAGES_H)
1241   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1242   AC_LINK_FILES($CCOLLATE_CC, src/collate.cc)
1243   AC_LINK_FILES($CCTYPE_CC, src/ctype.cc)
1244   AC_LINK_FILES($CMESSAGES_CC, src/messages.cc)
1245   AC_LINK_FILES($CMONEY_CC, src/monetary.cc)
1246   AC_LINK_FILES($CNUMERIC_CC, src/numeric.cc)
1247   AC_LINK_FILES($CTIME_CC, src/time.cc)
1248 ])
1249
1250
1251 dnl
1252 dnl Check for which I/O library to use:  libio, or something specific.
1253 dnl
1254 dnl GLIBCPP_ENABLE_CSTDIO
1255 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1256 dnl
1257 dnl default is stdio
1258 dnl
1259 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1260   AC_MSG_CHECKING([for cstdio to use])
1261   AC_ARG_ENABLE(cstdio,
1262   [  --enable-cstdio         enable stdio for target io package.
1263   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1264   ],
1265   if test x$enable_cstdio = xno; then
1266      enable_cstdio=stdio
1267   fi,
1268      enable_cstdio=stdio)
1269
1270   enable_cstdio_flag=$enable_cstdio
1271
1272   dnl Check if a valid I/O package
1273   case x${enable_cstdio_flag} in
1274     xlibio)
1275       CSTDIO_H=config/io/c_io_libio.h
1276       BASIC_FILE_H=config/io/basic_file_libio.h
1277       BASIC_FILE_CC=config/io/basic_file_libio.cc
1278       AC_MSG_RESULT(libio)
1279
1280       # see if we are on a system with libio native (ie, linux)
1281       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1282
1283       # Need to check and see what version of glibc is being used. If
1284       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1285       # compile most of libio for linux systems.
1286       if test x$has_libio = x"yes"; then
1287         case "$target" in
1288           *-*-linux*)
1289               AC_MSG_CHECKING([for glibc version >= 2.2])
1290               AC_EGREP_CPP([ok], [
1291             #include <features.h>
1292               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1293                     ok
1294               #endif
1295               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1296               AC_MSG_RESULT($glibc_satisfactory)
1297             ;;
1298         esac
1299
1300         # XXX at the moment, admit defeat and force the recompilation
1301         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1302         glibc_satisfactory=no
1303
1304         if test x$glibc_satisfactory = x"yes"; then
1305            need_libio=no
1306            need_wlibio=no
1307         else
1308            need_libio=yes
1309            # bkoz XXX need to add checks to enable this
1310            # pme XXX here's a first pass at such a check
1311            if test x$enable_c_mbchar != xno; then
1312               need_wlibio=yes
1313            else
1314               need_wlibio=no
1315            fi
1316         fi
1317
1318       else
1319          # Using libio, but <libio.h> doesn't exist on the target system. . .
1320          need_libio=yes
1321          # bkoz XXX need to add checks to enable this
1322          # pme XXX here's a first pass at such a check
1323          if test x$enable_c_mbchar != xno; then
1324              need_wlibio=yes
1325          else
1326              need_wlibio=no
1327          fi
1328       fi
1329       ;;
1330     xstdio | x | xno | xnone | xyes)
1331       # default
1332       CSTDIO_H=config/io/c_io_stdio.h
1333       BASIC_FILE_H=config/io/basic_file_stdio.h
1334       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1335       AC_MSG_RESULT(stdio)
1336
1337       # We're not using stdio.
1338       need_libio=no
1339       need_wlibio=no
1340       ;;
1341     *)
1342       echo "$enable_cstdio is an unknown io package" 1>&2
1343       exit 1
1344       ;;
1345   esac
1346   AC_SUBST(CSTDIO_H)
1347   AC_SUBST(BASIC_FILE_H)
1348   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1349
1350   # 2000-08-04 bkoz hack
1351   CCODECVT_C=config/io/c_io_libio_codecvt.c
1352   AC_SUBST(CCODECVT_C)
1353   # 2000-08-04 bkoz hack
1354
1355   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1356                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1357   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1358   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1359   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1360     libio_la=../libio/libio.la
1361   else
1362     libio_la=
1363   fi
1364   AC_SUBST(libio_la)
1365 ])
1366
1367
1368 dnl
1369 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1370 dnl We must stage the required headers so that they will be installed
1371 dnl with the library (unlike libgcc, the STL implementation is provided
1372 dnl solely within headers).  Since we must not inject random user-space
1373 dnl macro names into user-provided C++ code, we first stage into <file>-in
1374 dnl and process to <file> with an output command.  The reason for a two-
1375 dnl stage process here is to correctly handle $srcdir!=$objdir without
1376 dnl having to write complex code (the sed commands to clean the macro
1377 dnl namespace are complex and fragile enough as it is).  We must also
1378 dnl add a relative path so that -I- is supported properly.
1379 dnl
1380 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1381   AC_MSG_CHECKING([for thread model used by GCC])
1382   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1383   AC_MSG_RESULT([$target_thread_file])
1384
1385   if test $target_thread_file != single; then
1386     AC_DEFINE(HAVE_GTHR_DEFAULT)
1387     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1388   fi
1389
1390   glibcpp_thread_h=gthr-$target_thread_file.h
1391   AC_SUBST(glibcpp_thread_h)
1392 ])
1393
1394
1395 dnl
1396 dnl Check for exception handling support.  If an explicit enable/disable
1397 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1398 dnl target may or may not support call frame exceptions.
1399 dnl
1400 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1401 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1402 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1403 dnl
1404 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1405 dnl
1406 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1407   AC_MSG_CHECKING([for exception model to use])
1408   AC_LANG_SAVE
1409   AC_LANG_CPLUSPLUS
1410   AC_ARG_ENABLE(sjlj-exceptions,
1411   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1412   [:],
1413   [dnl Botheration.  Now we've got to detect the exception model.
1414    dnl Link tests against libgcc.a are problematic since -- at least
1415    dnl as of this writing -- we've not been given proper -L bits for
1416    dnl single-tree newlib and libgloss.
1417    dnl
1418    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1419    dnl conftest files before we got a change to grep them first.
1420    cat > conftest.$ac_ext << EOF
1421 [#]line __oline__ "configure"
1422 struct S { ~S(); };
1423 void bar();
1424 void foo()
1425 {
1426   S s;
1427   bar();
1428 }
1429 EOF
1430    old_CXXFLAGS="$CXXFLAGS"
1431    CXXFLAGS=-S
1432    if AC_TRY_EVAL(ac_compile); then
1433      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1434        enable_sjlj_exceptions=yes
1435      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1436        enable_sjlj_exceptions=no
1437      fi
1438    fi
1439    CXXFLAGS="$old_CXXFLAGS"
1440    rm -f conftest*])
1441    if test x$enable_sjlj_exceptions = xyes; then
1442      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1443         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1444      ac_exception_model_name=sjlj
1445    elif test x$enable_sjlj_exceptions = xno; then
1446      ac_exception_model_name="call frame"
1447    else
1448      AC_MSG_ERROR([unable to detect exception model])
1449    fi
1450    AC_LANG_RESTORE
1451    AC_MSG_RESULT($ac_exception_model_name)
1452 ])
1453
1454
1455 dnl
1456 dnl Check for libunwind exception handling support. If enabled then
1457 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1458 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1459 dnl libunwind instead of libgcc and that libstdc++ has a dependency
1460 dnl on libunwind as well as libgcc.
1461 dnl
1462 dnl GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS
1463 dnl --enable-libunwind-exceptions forces the use of libunwind.
1464 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1465 dnl
1466 dnl Define _GLIBCPP_LIBUNWIND_EXCEPTIONS if requested.
1467 dnl
1468 AC_DEFUN(GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS, [
1469   AC_MSG_CHECKING([for use of libunwind])
1470   AC_ARG_ENABLE(libunwind-exceptions,
1471   [  --enable-libunwind-exceptions  force use of libunwind for exceptions],
1472   use_libunwind_exceptions=$enableval,
1473   use_libunwind_exceptions=no)
1474   AC_MSG_RESULT($use_libunwind_exceptions)
1475   dnl Option parsed, now set things appropriately
1476   if test x"$use_libunwind_exceptions" = xyes; then
1477     LIBUNWIND_FLAG="-lunwind"
1478   else
1479     LIBUNWIND_FLAG=""
1480   fi
1481   AC_SUBST(LIBUNWIND_FLAG)
1482 ])
1483
1484 dnl
1485 dnl Check for ISO/IEC 9899:1999 "C99" support.
1486 dnl
1487 dnl GLIBCPP_ENABLE_C99
1488 dnl --enable-c99 defines _GLIBCPP_USE_C99
1489 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1490 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1491 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1492 dnl       defaults to `no'.
1493 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1494 dnl
1495 dnl GLIBCPP_ENABLE_C99
1496 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1497   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1498
1499   AC_ARG_ENABLE(c99,
1500   changequote(<<, >>)dnl
1501   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1502   changequote([, ])dnl
1503   [case "$enableval" in
1504    yes) enable_c99=yes ;;
1505    no)  enable_c99=no ;;
1506    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1507    esac],
1508   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1509
1510   AC_LANG_SAVE
1511   AC_LANG_CPLUSPLUS
1512
1513   # Check for the existence of <math.h> functions used if C99 is enabled.
1514   ac_c99_math=yes;
1515   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1516   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1517   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1518   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1519   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1520   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1521   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1522   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1523   AC_TRY_COMPILE([#include <math.h>],
1524                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1525   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1526   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1527   AC_TRY_COMPILE([#include <math.h>],
1528                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1529   AC_TRY_COMPILE([#include <math.h>],
1530                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1531   AC_MSG_RESULT($ac_c99_math)
1532
1533   # Check for the existence in <stdio.h> of vscanf, et. al.
1534   ac_c99_stdio=yes;
1535   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1536   AC_TRY_COMPILE([#include <stdio.h>],
1537                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1538   AC_TRY_COMPILE([#include <stdio.h>
1539                   #include <stdarg.h>
1540                   void foo(char* fmt, ...)
1541                   {va_list args; va_start(args, fmt);
1542                   vfscanf(stderr, "%i", args);}],
1543                   [],, [ac_c99_stdio=no])
1544   AC_TRY_COMPILE([#include <stdio.h>
1545                   #include <stdarg.h>
1546                   void foo(char* fmt, ...)
1547                   {va_list args; va_start(args, fmt);
1548                   vscanf("%i", args);}],
1549                   [],, [ac_c99_stdio=no])
1550   AC_TRY_COMPILE([#include <stdio.h>
1551                   #include <stdarg.h>
1552                   void foo(char* fmt, ...)
1553                   {va_list args; va_start(args, fmt);
1554                   vsnprintf(fmt, 0, "%i", args);}],
1555                   [],, [ac_c99_stdio=no])
1556   AC_TRY_COMPILE([#include <stdio.h>
1557                   #include <stdarg.h>
1558                   void foo(char* fmt, ...)
1559                   {va_list args; va_start(args, fmt);
1560                   vsscanf(fmt, "%i", args);}],
1561                   [],, [ac_c99_stdio=no])
1562   AC_MSG_RESULT($ac_c99_stdio)
1563
1564   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1565   ac_c99_stdlib=yes;
1566   AC_MSG_CHECKING([for lldiv_t declaration])
1567   AC_CACHE_VAL(ac_c99_lldiv_t, [
1568   AC_TRY_COMPILE([#include <stdlib.h>],
1569                    [ lldiv_t mydivt;],
1570                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1571   ])
1572   AC_MSG_RESULT($ac_c99_lldiv_t)
1573
1574   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1575   AC_TRY_COMPILE([#include <stdlib.h>],
1576                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1577   AC_TRY_COMPILE([#include <stdlib.h>],
1578                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1579   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1580   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1581   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1582   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1583   if test x"$ac_c99_lldiv_t" = x"no"; then
1584     ac_c99_stdlib=no;
1585   fi;
1586   AC_MSG_RESULT($ac_c99_stdlib)
1587
1588   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1589   # XXX the wchar.h checks should be rolled into the general C99 bits.
1590   ac_c99_wchar=yes;
1591   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1592   AC_TRY_COMPILE([#include <wchar.h>],
1593                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1594   AC_TRY_COMPILE([#include <wchar.h>],
1595                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1596   AC_TRY_COMPILE([#include <wchar.h>],
1597                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1598   AC_MSG_RESULT($ac_c99_wchar)
1599
1600   AC_MSG_CHECKING([for enabled ISO C99 support])
1601   if test x"$ac_c99_math" = x"no" ||
1602      test x"$ac_c99_stdio" = x"no" ||
1603      test x"$ac_c99_stdlib" = x"no" ||
1604      test x"$ac_c99_wchar" = x"no"; then
1605     enable_c99=no;
1606   fi;
1607   AC_MSG_RESULT($enable_c99)
1608
1609   # Option parsed, now set things appropriately
1610   if test x"$enable_c99" = x"yes"; then
1611     AC_DEFINE(_GLIBCPP_USE_C99)
1612   fi
1613
1614   AC_LANG_RESTORE
1615 ])
1616
1617
1618 dnl
1619 dnl Check for template specializations for the 'long long' type extension.
1620 dnl The result determines only whether 'long long' I/O is enabled; things
1621 dnl like numeric_limits<> specializations are always available.
1622 dnl
1623 dnl GLIBCPP_ENABLE_LONG_LONG
1624 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1625 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1626 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1627 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1628 dnl       defaults to `no'.
1629 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1630 dnl
1631 dnl GLIBCPP_ENABLE_LONG_LONG
1632 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1633   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1634
1635   AC_ARG_ENABLE(long-long,
1636   changequote(<<, >>)dnl
1637   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1638   changequote([, ])dnl
1639   [case "$enableval" in
1640    yes) enable_long_long=yes ;;
1641    no)  enable_long_long=no ;;
1642    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1643    esac],
1644   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1645
1646   AC_LANG_SAVE
1647   AC_LANG_CPLUSPLUS
1648
1649   AC_MSG_CHECKING([for enabled long long I/O support])
1650   # iostreams require strtoll, strtoull to compile
1651   AC_TRY_COMPILE([#include <stdlib.h>],
1652                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1653   AC_TRY_COMPILE([#include <stdlib.h>],
1654                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1655
1656   # Option parsed, now set things appropriately
1657   if test x"$enable_long_long" = xyes; then
1658     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1659   fi
1660   AC_MSG_RESULT($enable_long_long)
1661
1662   AC_LANG_RESTORE
1663 ])
1664
1665
1666 dnl
1667 dnl Check for what kind of C headers to use.
1668 dnl
1669 dnl GLIBCPP_ENABLE_CHEADERS
1670 dnl --enable-cheaders= [does stuff].
1671 dnl --disable-cheaders [does not do anything, really].
1672 dnl  +  This will eventually need to be 'c_shadow' by default.
1673 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1674 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1675 dnl       If ommitted, it defaults to `c_std'.
1676 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1677 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1678 AC_MSG_CHECKING([for c header strategy to use])
1679 AC_ARG_ENABLE(cheaders,
1680 changequote(<<, >>)dnl
1681 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1682 changequote([, ])
1683   [case "$enableval" in
1684    c)
1685         enable_cheaders=c
1686         ;;
1687    c_std)
1688         enable_cheaders=c_std
1689         ;;
1690    c_shadow)
1691         enable_cheaders=c_shadow
1692         ;;
1693    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1694         ;;
1695   esac],
1696   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1697   AC_MSG_RESULT($enable_cheaders)
1698
1699   dnl Option parsed, now set things appropriately
1700   case "$enable_cheaders" in
1701     c_shadow)
1702         CSHADOW_FLAGS="-fno-builtin"
1703         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_shadow'
1704         ;;
1705     c_std)
1706         CSHADOW_FLAGS=""
1707         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1708         ;;
1709     c)
1710         CSHADOW_FLAGS=""
1711         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1712         ;;
1713   esac
1714
1715   AC_SUBST(CSHADOW_FLAGS)
1716   AC_SUBST(C_INCLUDE_DIR)
1717   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C, test "$enable_cheaders" = c)
1718   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C_STD, test "$enable_cheaders" = c_std)
1719 ])
1720
1721
1722 dnl
1723 dnl Check for wide character support.  Has the same effect as the option
1724 dnl in gcc's configure, but in a form that autoconf can mess with.
1725 dnl
1726 dnl GLIBCPP_ENABLE_C_MBCHAR
1727 dnl --enable-c-mbchar requests all the wchar_t stuff.
1728 dnl --disable-c-mbchar doesn't.
1729 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1730 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1731 dnl       defaults to `no'.
1732 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1733 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1734 AC_ARG_ENABLE(c-mbchar,
1735 changequote(<<, >>)dnl
1736 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1737 changequote([, ])dnl
1738 [case "$enableval" in
1739  yes) enable_c_mbchar=yes ;;
1740  no)  enable_c_mbchar=no ;;
1741  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1742  esac],
1743 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1744 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1745 ])
1746
1747
1748 dnl
1749 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1750 dnl
1751 dnl TOPLEVEL_INCLUDES
1752 dnl LIBMATH_INCLUDES
1753 dnl LIBSUPCXX_INCLUDES
1754 dnl LIBIO_INCLUDES
1755 dnl CSHADOW_INCLUDES
1756 dnl
1757 dnl GLIBCPP_EXPORT_INCLUDES
1758 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1759   # Root level of the build directory include sources.
1760   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1761
1762   # Passed down for canadian crosses.
1763   if test x"$CANADIAN" = xyes; then
1764     TOPLEVEL_INCLUDES='-I$(includedir)'
1765   fi
1766
1767   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1768
1769   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1770
1771   if test x"$need_libio" = xyes; then
1772     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1773     AC_SUBST(LIBIO_INCLUDES)
1774   fi
1775
1776   # Now, export this to all the little Makefiles....
1777   AC_SUBST(GLIBCPP_INCLUDES)
1778   AC_SUBST(TOPLEVEL_INCLUDES)
1779   AC_SUBST(LIBMATH_INCLUDES)
1780   AC_SUBST(LIBSUPCXX_INCLUDES)
1781 ])
1782
1783
1784 dnl
1785 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1786 dnl
1787 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1788   # Optimization flags that are probably a good idea for thrill-seekers. Just
1789   # uncomment the lines below and make, everything else is ready to go...
1790   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1791   OPTIMIZE_CXXFLAGS=
1792   AC_SUBST(OPTIMIZE_CXXFLAGS)
1793
1794   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1795   AC_SUBST(WARN_FLAGS)
1796 ])
1797
1798 dnl
1799 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1800 dnl  calculates gxx_install_dir
1801 dnl  exports glibcpp_toolexecdir
1802 dnl  exports glibcpp_toolexeclibdir
1803 dnl  exports glibcpp_prefixdir
1804 dnl
1805 dnl Assumes cross_compiling bits already done, and with_cross_host in
1806 dnl particular
1807 dnl
1808 dnl GLIBCPP_EXPORT_INSTALL_INFO
1809 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1810 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1811 # exported correctly in GLIBCPP_CONFIGURE.
1812 glibcpp_toolexecdir=no
1813 glibcpp_toolexeclibdir=no
1814 glibcpp_prefixdir=${prefix}
1815
1816 AC_MSG_CHECKING([for interface version number])
1817 libstdcxx_interface=$INTERFACE
1818 AC_MSG_RESULT($libstdcxx_interface)
1819
1820 # Process the option --with-gxx-include-dir=<path to include-files directory>
1821 AC_MSG_CHECKING([for --with-gxx-include-dir])
1822 AC_ARG_WITH(gxx-include-dir,
1823 [  --with-gxx-include-dir  the installation directory for include files],
1824 [case "${withval}" in
1825   yes)
1826     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1827     gxx_include_dir=no
1828     ;;
1829   no)
1830     gxx_include_dir=no
1831     ;;
1832   *)
1833     gxx_include_dir=${withval}
1834     ;;
1835 esac], [gxx_include_dir=no])
1836 AC_MSG_RESULT($gxx_include_dir)
1837
1838 # Process the option "--enable-version-specific-runtime-libs"
1839 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1840 AC_ARG_ENABLE(version-specific-runtime-libs,
1841 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1842 [case "$enableval" in
1843  yes) version_specific_libs=yes ;;
1844  no)  version_specific_libs=no ;;
1845  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1846  esac],
1847 version_specific_libs=no)dnl
1848 # Option set, now we can test it.
1849 AC_MSG_RESULT($version_specific_libs)
1850
1851 if test $version_specific_libs = yes; then
1852   # Need the gcc compiler version to know where to install libraries
1853   # and header files if --enable-version-specific-runtime-libs option
1854   # is selected.
1855   changequote(,)dnl
1856   gcc_version_trigger=${srcdir}/../gcc/version.c
1857   gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1858   gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1859   gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1860   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1861   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1862   changequote([,])dnl
1863 fi
1864
1865 # Default case for install directory for include files.
1866 if test $version_specific_libs = no &&
1867    test $gxx_include_dir = no; then
1868   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1869 fi
1870
1871 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1872 # Install a library built with a cross compiler in tooldir, not libdir.
1873 if test x"$glibcpp_toolexecdir" = x"no"; then
1874   if test -n "$with_cross_host" &&
1875      test x"$with_cross_host" != x"no"; then
1876     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1877     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1878   else
1879     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1880     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1881   fi
1882 fi
1883
1884 AC_MSG_CHECKING([for install location])
1885 AC_MSG_RESULT($gxx_include_dir)
1886
1887 AC_SUBST(glibcpp_prefixdir)
1888 AC_SUBST(gxx_include_dir)
1889 AC_SUBST(glibcpp_toolexecdir)
1890 AC_SUBST(glibcpp_toolexeclibdir)
1891 ])
1892
1893
1894 # Check for functions in math library.
1895 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1896 #
1897 # This file can be copied and used freely without restrictions.  It can
1898 # be used in projects which are not available under the GNU Public License
1899 # but which still want to provide support for the GNU gettext functionality.
1900 # Please note that the actual code is *not* freely available.
1901
1902 # serial 1
1903
1904 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1905 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1906 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])])
1907
1908
1909 dnl This macro searches for a GNU version of make.  If a match is found, the
1910 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1911 dnl set to "#". This is useful for  including a special features in a Makefile,
1912 dnl which cannot be handled by other versions of make.  The variable
1913 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1914 dnl the empty string otherwise.
1915 dnl
1916 dnl Here is an example of its use:
1917 dnl
1918 dnl Makefile.in might contain:
1919 dnl
1920 dnl     # A failsafe way of putting a dependency rule into a makefile
1921 dnl     $(DEPEND):
1922 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1923 dnl
1924 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1925 dnl     @ifGNUmake@ include $(DEPEND)
1926 dnl     @ifGNUmake@ endif
1927 dnl
1928 dnl Then configure.in would normally contain:
1929 dnl
1930 dnl     CHECK_GNU_MAKE()
1931 dnl     AC_OUTPUT(Makefile)
1932 dnl
1933 dnl Then perhaps to cause gnu make to override any other make, we could do
1934 dnl something like this (note that GNU make always looks for GNUmakefile first):
1935 dnl
1936 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1937 dnl             mv Makefile GNUmakefile
1938 dnl             echo .DEFAULT: > Makefile ;
1939 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1940 dnl     fi
1941 dnl
1942 dnl Then, if any (well almost any) other make is called, and GNU make also
1943 dnl exists, then the other make wraps the GNU make.
1944 dnl
1945 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1946 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1947 dnl
1948 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1949 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1950 dnl #### conditional's subshell (" --version" is not a command), using a
1951 dnl #### different option to grep(1).
1952 dnl #### -pme
1953 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1954 dnl #### ${MAKE:-make}).
1955 dnl #### -msokolov
1956 AC_DEFUN(
1957   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1958           _cv_gnu_make_command='' ;
1959 dnl Search all the common names for GNU make
1960           for a in "${MAKE-make}" make gmake gnumake ; do
1961                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1962                   then
1963                           _cv_gnu_make_command=$a ;
1964                           break;
1965                   fi
1966           done ;
1967   ) ;
1968 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1969 dnl string, '#' otherwise
1970   if test  "x$_cv_gnu_make_command" != "x"  ; then
1971           ifGNUmake='' ;
1972   else
1973           ifGNUmake='#' ;
1974   fi
1975   AC_SUBST(ifGNUmake)
1976 ])
1977
1978
1979 dnl Check for headers for, and arguments to, the setrlimit() function.
1980 dnl Used only in testsuite_hooks.h.
1981 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
1982   AC_TRY_COMPILE([#include <sys/resource.h>
1983                   #include <unistd.h>
1984                  ], [ int f = RLIMIT_$1 ; ],
1985                  [glibcpp_mresult=1], [glibcpp_mresult=0])
1986   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
1987                      [Only used in build directory testsuite_hooks.h.])
1988 ])
1989 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
1990   setrlimit_have_headers=yes
1991   AC_CHECK_HEADERS(sys/resource.h unistd.h,
1992                    [],
1993                    setrlimit_have_headers=no)
1994   # If don't have the headers, then we can't run the tests now, and we
1995   # won't be seeing any of these during testsuite compilation.
1996   if test $setrlimit_have_headers = yes; then
1997     # Can't do these in a loop, else the resulting syntax is wrong.
1998     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
1999     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
2000     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
2001     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
2002
2003     # Check for rlimit, setrlimit.
2004     AC_CACHE_VAL(ac_setrlimit, [
2005       AC_TRY_COMPILE([#include <sys/resource.h>
2006                       #include <unistd.h>
2007                      ],
2008                      [ struct rlimit r; setrlimit(0, &r);],
2009                      [ac_setrlimit=yes], [ac_setrlimit=no])
2010     ])
2011   fi
2012
2013   AC_MSG_CHECKING([for testsuite memory limit support])
2014   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
2015     ac_mem_limits=yes
2016     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
2017   else
2018     ac_mem_limits=no
2019   fi
2020   AC_MSG_RESULT($ac_mem_limits)
2021 ])
2022
2023
2024 dnl
2025 dnl Does any necessary configuration of the testsuite directory.  Generates
2026 dnl the testsuite_hooks.h header.
2027 dnl
2028 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
2029 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
2030   GLIBCPP_CHECK_SETRLIMIT
2031
2032   # Look for setenv, so that extended locale tests can be performed.
2033   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
2034 ])
2035
2036
2037 sinclude(../libtool.m4)
2038 dnl The lines below arrange for aclocal not to bring an installed
2039 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
2040 dnl add a definition of LIBTOOL to Makefile.in.
2041 ifelse(,,,[AC_SUBST(LIBTOOL)
2042 AC_DEFUN([AM_PROG_LIBTOOL])
2043 AC_DEFUN([AC_LIBTOOL_DLOPEN])
2044 AC_DEFUN([AC_PROG_LD])
2045 ])
2046
2047
2048 # Check whether LC_MESSAGES is available in <locale.h>.
2049 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2050 #
2051 # This file file be copied and used freely without restrictions.  It can
2052 # be used in projects which are not available under the GNU Public License
2053 # but which still want to provide support for the GNU gettext functionality.
2054 # Please note that the actual code is *not* freely available.
2055
2056 # serial 1
2057
2058 AC_DEFUN(AC_LC_MESSAGES, [
2059   AC_CHECK_HEADER(locale.h, [
2060     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2061       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2062        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2063     if test $ac_cv_val_LC_MESSAGES = yes; then
2064       AC_DEFINE(HAVE_LC_MESSAGES)
2065     fi
2066   ])
2067 ])
2068
2069
2070 dnl
2071 dnl Check for whether the Boost-derived checks should be turned on.
2072 dnl
2073 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
2074 dnl --enable-concept-checks turns them on.
2075 dnl --disable-concept-checks leaves them off.
2076 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2077 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2078 dnl       defaults to `no'.
2079 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
2080 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
2081 AC_ARG_ENABLE(concept-checks,
2082 changequote(<<, >>)dnl
2083 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
2084 changequote([, ])dnl
2085 [case "$enableval" in
2086  yes) enable_concept_checks=yes ;;
2087  no)  enable_concept_checks=no ;;
2088  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
2089  esac],
2090 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
2091 dnl Option parsed, now set things appropriately
2092 if test x"$enable_concept_checks" = xyes; then
2093   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
2094 fi
2095 ])
2096
2097
2098 dnl
2099 dnl Add version tags to symbols in shared library (or not), additionally
2100 dnl marking other symbols as private/local (or not).
2101 dnl
2102 dnl GLIBCPP_ENABLE_SYMVERS
2103 dnl --enable-symvers=style adds a version script to the linker call when
2104 dnl       creating the shared library.  The choice of version script is
2105 dnl       controlled by 'style'.
2106 dnl --disable-symvers does not.
2107 dnl  +  Usage:  GLIBCPP_ENABLE_SYMVERS[(DEFAULT)]
2108 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2109 dnl       defaults to `no'.  Passing `yes' tries to choose a default style
2110 dnl       based on linker characteristics.  Passing 'no' disables versioning.
2111 AC_DEFUN(GLIBCPP_ENABLE_SYMVERS, [dnl
2112 define([GLIBCPP_ENABLE_SYMVERS_DEFAULT], ifelse($1, yes, yes, no))dnl
2113 AC_ARG_ENABLE(symvers,
2114 changequote(<<, >>)dnl
2115 <<  --enable-symvers=style  enables symbol versioning of the shared library [default=>>GLIBCPP_ENABLE_SYMVERS_DEFAULT],
2116 changequote([, ])dnl
2117 [case "$enableval" in
2118  yes) enable_symvers=yes ;;
2119  no)  enable_symvers=no ;;
2120  # other names here, just as sanity checks
2121  #gnu|sun|etcetera) enable_symvers=$enableval ;;
2122  gnu) enable_symvers=$enableval ;;
2123  *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]) ;;
2124  esac],
2125 enable_symvers=GLIBCPP_ENABLE_SYMVERS_DEFAULT)dnl
2126
2127 # If we never went through the GLIBCPP_CHECK_LINKER_FEATURES macro, then we
2128 # don't know enough about $LD to do tricks...
2129 if test x$enable_shared = xno ||
2130         test x$LD = x ||
2131         test x$glibcpp_gnu_ld_version = x; then
2132   enable_symvers=no
2133 fi
2134
2135 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2136 AC_MSG_CHECKING([for shared libgcc])
2137 ac_save_CFLAGS="$CFLAGS"
2138 CFLAGS=' -lgcc_s'
2139 AC_TRY_LINK( , [return 0], glibcpp_shared_libgcc=yes, glibcpp_shared_libgcc=no)
2140 CFLAGS="$ac_save_CFLAGS"
2141 AC_MSG_RESULT($glibcpp_shared_libgcc)
2142
2143 # For GNU ld, we need at least this version.  It's 2.12 in the same format
2144 # as the tested-for version.  See GLIBCPP_CHECK_LINKER_FEATURES for more.
2145 glibcpp_min_gnu_ld_version=21200
2146
2147 # Check to see if unspecified "yes" value can win, given results
2148 # above.
2149 if test $enable_symvers = yes ; then
2150   if test $with_gnu_ld = yes &&
2151     test $glibcpp_shared_libgcc = yes ;
2152   then
2153     if test $glibcpp_gnu_ld_version -ge $glibcpp_min_gnu_ld_version ; then
2154         enable_symvers=gnu
2155     else
2156       ac_test_CFLAGS="${CFLAGS+set}"
2157       ac_save_CFLAGS="$CFLAGS"
2158       CFLAGS='-shared -Wl,--version-script,conftest.map'
2159       enable_symvers=no
2160       changequote(,)
2161       echo 'FOO { global: f[a-z]o; local: *; };' > conftest.map
2162       changequote([,])
2163       AC_TRY_LINK([int foo;],, enable_symvers=gnu)
2164       if test "$ac_test_CFLAGS" = set; then
2165         CFLAGS="$ac_save_CFLAGS"
2166       else
2167         # this is the suspicious part
2168         CFLAGS=''
2169       fi
2170       rm -f conftest.map
2171     fi
2172   else
2173     # just fail for now
2174     enable_symvers=no
2175   fi
2176 fi
2177
2178 dnl Everything parsed; figure out what file to use.
2179 case $enable_symvers in
2180   no)
2181       LINKER_MAP=config/linker-map.dummy
2182       ;;
2183   gnu)
2184       LINKER_MAP=config/linker-map.gnu
2185       ;;
2186 esac
2187
2188 AC_LINK_FILES($LINKER_MAP, src/linker.map)
2189 AM_CONDITIONAL(GLIBCPP_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
2190 AC_MSG_CHECKING([versioning on shared library symbols])
2191 AC_MSG_RESULT($enable_symvers)
2192 ])
2193
2194
2195 #serial 1
2196 # This test replaces the one in autoconf.
2197 # Currently this macro should have the same name as the autoconf macro
2198 # because gettext's gettext.m4 (distributed in the automake package)
2199 # still uses it.  Otherwise, the use in gettext.m4 makes autoheader
2200 # give these diagnostics:
2201 #   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
2202 #   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
2203
2204 undefine([AC_ISC_POSIX])
2205
2206 AC_DEFUN([AC_ISC_POSIX],
2207   [
2208     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
2209     AC_CHECK_LIB(cposix, strerror, [LIBS="$LIBS -lcposix"])
2210   ]
2211 )
2212
2213 # Add --enable-maintainer-mode option to configure.
2214 # From Jim Meyering
2215
2216 # serial 1
2217
2218 AC_DEFUN([AM_MAINTAINER_MODE],
2219 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2220   dnl maintainer-mode is disabled by default
2221   AC_ARG_ENABLE(maintainer-mode,
2222 [  --enable-maintainer-mode enable make rules and dependencies not useful
2223                           (and sometimes confusing) to the casual installer],
2224       USE_MAINTAINER_MODE=$enableval,
2225       USE_MAINTAINER_MODE=no)
2226   AC_MSG_RESULT($USE_MAINTAINER_MODE)
2227   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
2228   MAINT=$MAINTAINER_MODE_TRUE
2229   AC_SUBST(MAINT)dnl
2230 ]
2231 )
2232
2233 # Define a conditional.
2234
2235 AC_DEFUN([AM_CONDITIONAL],
2236 [AC_SUBST($1_TRUE)
2237 AC_SUBST($1_FALSE)
2238 if $2; then
2239   $1_TRUE=
2240   $1_FALSE='#'
2241 else
2242   $1_TRUE='#'
2243   $1_FALSE=
2244 fi])
2245
2246 # Macro to add for using GNU gettext.
2247 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2248 #
2249 # This file can be copied and used freely without restrictions.  It can
2250 # be used in projects which are not available under the GNU Public License
2251 # but which still want to provide support for the GNU gettext functionality.
2252 # Please note that the actual code is *not* freely available.
2253
2254 # serial 9
2255
2256 dnl Usage: AM_WITH_NLS([TOOLSYMBOL], [NEEDSYMBOL], [LIBDIR]).
2257 dnl If TOOLSYMBOL is specified and is 'use-libtool', then a libtool library
2258 dnl    $(top_builddir)/intl/libintl.la will be created (shared and/or static,
2259 dnl    depending on --{enable,disable}-{shared,static} and on the presence of
2260 dnl    AM-DISABLE-SHARED). Otherwise, a static library
2261 dnl    $(top_builddir)/intl/libintl.a will be created.
2262 dnl If NEEDSYMBOL is specified and is 'need-ngettext', then GNU gettext
2263 dnl    implementations (in libc or libintl) without the ngettext() function
2264 dnl    will be ignored.
2265 dnl LIBDIR is used to find the intl libraries.  If empty,
2266 dnl    the value `$(top_builddir)/intl/' is used.
2267 dnl
2268 dnl The result of the configuration is one of three cases:
2269 dnl 1) GNU gettext, as included in the intl subdirectory, will be compiled
2270 dnl    and used.
2271 dnl    Catalog format: GNU --> install in $(datadir)
2272 dnl    Catalog extension: .mo after installation, .gmo in source tree
2273 dnl 2) GNU gettext has been found in the system's C library.
2274 dnl    Catalog format: GNU --> install in $(datadir)
2275 dnl    Catalog extension: .mo after installation, .gmo in source tree
2276 dnl 3) No internationalization, always use English msgid.
2277 dnl    Catalog format: none
2278 dnl    Catalog extension: none
2279 dnl The use of .gmo is historical (it was needed to avoid overwriting the
2280 dnl GNU format catalogs when building on a platform with an X/Open gettext),
2281 dnl but we keep it in order not to force irrelevant filename changes on the
2282 dnl maintainers.
2283 dnl
2284 AC_DEFUN([AM_WITH_NLS],
2285   [AC_MSG_CHECKING([whether NLS is requested])
2286     dnl Default is enabled NLS
2287     AC_ARG_ENABLE(nls,
2288       [  --disable-nls           do not use Native Language Support],
2289       USE_NLS=$enableval, USE_NLS=yes)
2290     AC_MSG_RESULT($USE_NLS)
2291     AC_SUBST(USE_NLS)
2292
2293     BUILD_INCLUDED_LIBINTL=no
2294     USE_INCLUDED_LIBINTL=no
2295     INTLLIBS=
2296
2297     dnl If we use NLS figure out what method
2298     if test "$USE_NLS" = "yes"; then
2299       AC_DEFINE(ENABLE_NLS, 1,
2300         [Define to 1 if translation of program messages to the user's native language
2301    is requested.])
2302       AC_MSG_CHECKING([whether included gettext is requested])
2303       AC_ARG_WITH(included-gettext,
2304         [  --with-included-gettext use the GNU gettext library included here],
2305         nls_cv_force_use_gnu_gettext=$withval,
2306         nls_cv_force_use_gnu_gettext=no)
2307       AC_MSG_RESULT($nls_cv_force_use_gnu_gettext)
2308
2309       nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
2310       if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
2311         dnl User does not insist on using GNU NLS library.  Figure out what
2312         dnl to use.  If GNU gettext is available we use this.  Else we have
2313         dnl to fall back to GNU NLS library.
2314         CATOBJEXT=NONE
2315
2316         dnl Add a version number to the cache macros.
2317         define(gt_cv_func_gnugettext_libc, [gt_cv_func_gnugettext]ifelse([$2], need-ngettext, 2, 1)[_libc])
2318         define(gt_cv_func_gnugettext_libintl, [gt_cv_func_gnugettext]ifelse([$2], need-ngettext, 2, 1)[_libintl])
2319
2320         AC_CHECK_HEADER(libintl.h,
2321           [AC_CACHE_CHECK([for GNU gettext in libc], gt_cv_func_gnugettext_libc,
2322             [AC_TRY_LINK([#include <libintl.h>
2323 extern int _nl_msg_cat_cntr;],
2324                [bindtextdomain ("", "");
2325 return (int) gettext ("")]ifelse([$2], need-ngettext, [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr],
2326                gt_cv_func_gnugettext_libc=yes,
2327                gt_cv_func_gnugettext_libc=no)])
2328
2329            if test "$gt_cv_func_gnugettext_libc" != "yes"; then
2330              AC_CACHE_CHECK([for GNU gettext in libintl],
2331                gt_cv_func_gnugettext_libintl,
2332                [gt_save_LIBS="$LIBS"
2333                 LIBS="$LIBS -lintl $LIBICONV"
2334                 AC_TRY_LINK([#include <libintl.h>
2335 extern int _nl_msg_cat_cntr;],
2336                   [bindtextdomain ("", "");
2337 return (int) gettext ("")]ifelse([$2], need-ngettext, [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr],
2338                   gt_cv_func_gnugettext_libintl=yes,
2339                   gt_cv_func_gnugettext_libintl=no)
2340                 LIBS="$gt_save_LIBS"])
2341            fi
2342
2343            dnl If an already present or preinstalled GNU gettext() is found,
2344            dnl use it.  But if this macro is used in GNU gettext, and GNU
2345            dnl gettext is already preinstalled in libintl, we update this
2346            dnl libintl.  (Cf. the install rule in intl/Makefile.in.)
2347            if test "$gt_cv_func_gnugettext_libc" = "yes" \
2348               || { test "$gt_cv_func_gnugettext_libintl" = "yes" \
2349                    && test "$PACKAGE" != gettext; }; then
2350              AC_DEFINE(HAVE_GETTEXT, 1,
2351                [Define if the GNU gettext() function is already present or preinstalled.])
2352
2353              if test "$gt_cv_func_gnugettext_libintl" = "yes"; then
2354                dnl If iconv() is in a separate libiconv library, then anyone
2355                dnl linking with libintl{.a,.so} also needs to link with
2356                dnl libiconv.
2357                INTLLIBS="-lintl $LIBICONV"
2358              fi
2359
2360              gt_save_LIBS="$LIBS"
2361              LIBS="$LIBS $INTLLIBS"
2362              AC_CHECK_FUNCS(dcgettext)
2363              LIBS="$gt_save_LIBS"
2364
2365              AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
2366                [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)dnl
2367              if test "$MSGFMT" != "no"; then
2368                AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
2369              fi
2370
2371              AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
2372                [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
2373
2374              CATOBJEXT=.gmo
2375            fi
2376         ])
2377
2378         if test "$CATOBJEXT" = "NONE"; then
2379           dnl GNU gettext is not found in the C library.
2380           dnl Fall back on GNU gettext library.
2381           nls_cv_use_gnu_gettext=yes
2382         fi
2383       fi
2384
2385       if test "$nls_cv_use_gnu_gettext" = "yes"; then
2386         dnl Mark actions used to generate GNU NLS library.
2387         INTLOBJS="\$(GETTOBJS)"
2388         AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
2389           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], msgfmt)
2390         AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
2391         AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
2392           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
2393         AC_SUBST(MSGFMT)
2394         BUILD_INCLUDED_LIBINTL=yes
2395         USE_INCLUDED_LIBINTL=yes
2396         CATOBJEXT=.gmo
2397         INTLLIBS="ifelse([$3],[],\$(top_builddir)/intl,[$3])/libintl.ifelse([$1], use-libtool, [l], [])a $LIBICONV"
2398         LIBS=`echo " $LIBS " | sed -e 's/ -lintl / /' -e 's/^ //' -e 's/ $//'`
2399       fi
2400
2401       dnl Test whether we really found GNU xgettext.
2402       if test "$XGETTEXT" != ":"; then
2403         dnl If it is no GNU xgettext we define it as : so that the
2404         dnl Makefiles still can work.
2405         if $XGETTEXT --omit-header /dev/null 2> /dev/null; then
2406           : ;
2407         else
2408           AC_MSG_RESULT(
2409             [found xgettext program is not GNU xgettext; ignore it])
2410           XGETTEXT=":"
2411         fi
2412       fi
2413
2414       dnl We need to process the po/ directory.
2415       POSUB=po
2416     fi
2417     AC_OUTPUT_COMMANDS(
2418      [for ac_file in $CONFIG_FILES; do
2419         # Support "outfile[:infile[:infile...]]"
2420         case "$ac_file" in
2421           *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
2422         esac
2423         # PO directories have a Makefile.in generated from Makefile.in.in.
2424         case "$ac_file" in */Makefile.in)
2425           # Adjust a relative srcdir.
2426           ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
2427           ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
2428           ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
2429           case "$ac_given_srcdir" in
2430             .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
2431             /*) top_srcdir="$ac_given_srcdir" ;;
2432             *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
2433           esac
2434           if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
2435             rm -f "$ac_dir/POTFILES"
2436             echo creating "$ac_dir/POTFILES"
2437             sed -e "/^#/d" -e "/^[      ]*\$/d" -e "s,.*,     $top_srcdir/& \\\\," -e "\$s/\(.*\) \\\\/\1/" < "$ac_given_srcdir/$ac_dir/POTFILES.in" > "$ac_dir/POTFILES"
2438             echo creating "$ac_dir/Makefile"
2439             sed -e "/POTFILES =/r $ac_dir/POTFILES" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
2440           fi
2441           ;;
2442         esac
2443       done])
2444
2445
2446     dnl If this is used in GNU gettext we have to set BUILD_INCLUDED_LIBINTL
2447     dnl to 'yes' because some of the testsuite requires it.
2448     if test "$PACKAGE" = gettext; then
2449       BUILD_INCLUDED_LIBINTL=yes
2450     fi
2451
2452     dnl intl/plural.c is generated from intl/plural.y. It requires bison,
2453     dnl because plural.y uses bison specific features. It requires at least
2454     dnl bison-1.26 because earlier versions generate a plural.c that doesn't
2455     dnl compile.
2456     dnl bison is only needed for the maintainer (who touches plural.y). But in
2457     dnl order to avoid separate Makefiles or --enable-maintainer-mode, we put
2458     dnl the rule in general Makefile. Now, some people carelessly touch the
2459     dnl files or have a broken "make" program, hence the plural.c rule will
2460     dnl sometimes fire. To avoid an error, defines BISON to ":" if it is not
2461     dnl present or too old.
2462     AC_CHECK_PROGS([INTLBISON], [bison])
2463     if test -z "$INTLBISON"; then
2464       ac_verc_fail=yes
2465     else
2466       dnl Found it, now check the version.
2467       AC_MSG_CHECKING([version of bison])
2468 changequote(<<,>>)dnl
2469       ac_prog_version=`$INTLBISON --version 2>&1 | sed -n 's/^.*GNU Bison .* \([0-9]*\.[0-9.]*\).*$/\1/p'`
2470       case $ac_prog_version in
2471         '') ac_prog_version="v. ?.??, bad"; ac_verc_fail=yes;;
2472         1.2[6-9]* | 1.[3-9][0-9]* | [2-9].*)
2473 changequote([,])dnl
2474            ac_prog_version="$ac_prog_version, ok"; ac_verc_fail=no;;
2475         *) ac_prog_version="$ac_prog_version, bad"; ac_verc_fail=yes;;
2476       esac
2477       AC_MSG_RESULT([$ac_prog_version])
2478     fi
2479     if test $ac_verc_fail = yes; then
2480       INTLBISON=:
2481     fi
2482
2483     dnl These rules are solely for the distribution goal.  While doing this
2484     dnl we only have to keep exactly one list of the available catalogs
2485     dnl in configure.in.
2486     for lang in $ALL_LINGUAS; do
2487       GMOFILES="$GMOFILES $lang.gmo"
2488       POFILES="$POFILES $lang.po"
2489     done
2490
2491     dnl Make all variables we use known to autoconf.
2492     AC_SUBST(BUILD_INCLUDED_LIBINTL)
2493     AC_SUBST(USE_INCLUDED_LIBINTL)
2494     AC_SUBST(CATALOGS)
2495     AC_SUBST(CATOBJEXT)
2496     AC_SUBST(GMOFILES)
2497     AC_SUBST(INTLLIBS)
2498     AC_SUBST(INTLOBJS)
2499     AC_SUBST(POFILES)
2500     AC_SUBST(POSUB)
2501
2502     dnl For backward compatibility. Some configure.ins may be using this.
2503     nls_cv_header_intl=
2504     nls_cv_header_libgt=
2505
2506     dnl For backward compatibility. Some Makefiles may be using this.
2507     DATADIRNAME=share
2508     AC_SUBST(DATADIRNAME)
2509
2510     dnl For backward compatibility. Some Makefiles may be using this.
2511     INSTOBJEXT=.mo
2512     AC_SUBST(INSTOBJEXT)
2513
2514     dnl For backward compatibility. Some Makefiles may be using this.
2515     GENCAT=gencat
2516     AC_SUBST(GENCAT)
2517   ])
2518
2519 dnl Usage: Just like AM_WITH_NLS, which see.
2520 AC_DEFUN([AM_GNU_GETTEXT],
2521   [AC_REQUIRE([AC_PROG_MAKE_SET])dnl
2522    AC_REQUIRE([AC_PROG_CC])dnl
2523    AC_REQUIRE([AC_CANONICAL_HOST])dnl
2524    AC_REQUIRE([AC_PROG_RANLIB])dnl
2525    AC_REQUIRE([AC_ISC_POSIX])dnl
2526    AC_REQUIRE([AC_HEADER_STDC])dnl
2527    AC_REQUIRE([AC_C_CONST])dnl
2528    AC_REQUIRE([AC_C_INLINE])dnl
2529    AC_REQUIRE([AC_TYPE_OFF_T])dnl
2530    AC_REQUIRE([AC_TYPE_SIZE_T])dnl
2531    AC_REQUIRE([AC_FUNC_ALLOCA])dnl
2532    AC_REQUIRE([AC_FUNC_MMAP])dnl
2533    AC_REQUIRE([jm_GLIBC21])dnl
2534
2535    AC_CHECK_HEADERS([argz.h limits.h locale.h nl_types.h malloc.h stddef.h \
2536 stdlib.h string.h unistd.h sys/param.h])
2537    AC_CHECK_FUNCS([feof_unlocked fgets_unlocked getcwd getegid geteuid \
2538 getgid getuid mempcpy munmap putenv setenv setlocale stpcpy strchr strcasecmp \
2539 strdup strtoul tsearch __argz_count __argz_stringify __argz_next])
2540
2541    AM_ICONV
2542    AM_LANGINFO_CODESET
2543    AM_LC_MESSAGES
2544    AM_WITH_NLS([$1],[$2],[$3])
2545
2546    if test "x$CATOBJEXT" != "x"; then
2547      if test "x$ALL_LINGUAS" = "x"; then
2548        LINGUAS=
2549      else
2550        AC_MSG_CHECKING(for catalogs to be installed)
2551        NEW_LINGUAS=
2552        for presentlang in $ALL_LINGUAS; do
2553          useit=no
2554          for desiredlang in ${LINGUAS-$ALL_LINGUAS}; do
2555            # Use the presentlang catalog if desiredlang is
2556            #   a. equal to presentlang, or
2557            #   b. a variant of presentlang (because in this case,
2558            #      presentlang can be used as a fallback for messages
2559            #      which are not translated in the desiredlang catalog).
2560            case "$desiredlang" in
2561              "$presentlang"*) useit=yes;;
2562            esac
2563          done
2564          if test $useit = yes; then
2565            NEW_LINGUAS="$NEW_LINGUAS $presentlang"
2566          fi
2567        done
2568        LINGUAS=$NEW_LINGUAS
2569        AC_MSG_RESULT($LINGUAS)
2570      fi
2571
2572      dnl Construct list of names of catalog files to be constructed.
2573      if test -n "$LINGUAS"; then
2574        for lang in $LINGUAS; do CATALOGS="$CATALOGS $lang$CATOBJEXT"; done
2575      fi
2576    fi
2577
2578    dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
2579    dnl find the mkinstalldirs script in another subdir but $(top_srcdir).
2580    dnl Try to locate is.
2581    MKINSTALLDIRS=
2582    if test -n "$ac_aux_dir"; then
2583      MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
2584    fi
2585    if test -z "$MKINSTALLDIRS"; then
2586      MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
2587    fi
2588    AC_SUBST(MKINSTALLDIRS)
2589
2590    dnl Enable libtool support if the surrounding package wishes it.
2591    INTL_LIBTOOL_SUFFIX_PREFIX=ifelse([$1], use-libtool, [l], [])
2592    AC_SUBST(INTL_LIBTOOL_SUFFIX_PREFIX)
2593   ])
2594
2595 # Search path for a program which passes the given test.
2596 # Ulrich Drepper <drepper@cygnus.com>, 1996.
2597 #
2598 # This file can be copied and used freely without restrictions.  It can
2599 # be used in projects which are not available under the GNU Public License
2600 # but which still want to provide support for the GNU gettext functionality.
2601 # Please note that the actual code is *not* freely available.
2602
2603 # serial 1
2604
2605 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
2606 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
2607 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
2608 [# Extract the first word of "$2", so it can be a program name with args.
2609 set dummy $2; ac_word=[$]2
2610 AC_MSG_CHECKING([for $ac_word])
2611 AC_CACHE_VAL(ac_cv_path_$1,
2612 [case "[$]$1" in
2613   /*)
2614   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
2615   ;;
2616   *)
2617   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
2618   for ac_dir in ifelse([$5], , $PATH, [$5]); do
2619     test -z "$ac_dir" && ac_dir=.
2620     if test -f $ac_dir/$ac_word; then
2621       if [$3]; then
2622         ac_cv_path_$1="$ac_dir/$ac_word"
2623         break
2624       fi
2625     fi
2626   done
2627   IFS="$ac_save_ifs"
2628 dnl If no 4th arg is given, leave the cache variable unset,
2629 dnl so AC_PATH_PROGS will keep looking.
2630 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
2631 ])dnl
2632   ;;
2633 esac])dnl
2634 $1="$ac_cv_path_$1"
2635 if test -n "[$]$1"; then
2636   AC_MSG_RESULT([$]$1)
2637 else
2638   AC_MSG_RESULT(no)
2639 fi
2640 AC_SUBST($1)dnl
2641 ])
2642
2643 #serial 2
2644
2645 # Test for the GNU C Library, version 2.1 or newer.
2646 # From Bruno Haible.
2647
2648 AC_DEFUN([jm_GLIBC21],
2649   [
2650     AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
2651       ac_cv_gnu_library_2_1,
2652       [AC_EGREP_CPP([Lucky GNU user],
2653         [
2654 #include <features.h>
2655 #ifdef __GNU_LIBRARY__
2656  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
2657   Lucky GNU user
2658  #endif
2659 #endif
2660         ],
2661         ac_cv_gnu_library_2_1=yes,
2662         ac_cv_gnu_library_2_1=no)
2663       ]
2664     )
2665     AC_SUBST(GLIBC21)
2666     GLIBC21="$ac_cv_gnu_library_2_1"
2667   ]
2668 )
2669
2670 #serial AM2
2671
2672 dnl From Bruno Haible.
2673
2674 AC_DEFUN([AM_ICONV],
2675 [
2676   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
2677   dnl those with the standalone portable GNU libiconv installed).
2678
2679   AC_ARG_WITH([libiconv-prefix],
2680 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
2681     for dir in `echo "$withval" | tr : ' '`; do
2682       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
2683       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
2684     done
2685    ])
2686
2687   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
2688     am_cv_func_iconv="no, consider installing GNU libiconv"
2689     am_cv_lib_iconv=no
2690     AC_TRY_LINK([#include <stdlib.h>
2691 #include <iconv.h>],
2692       [iconv_t cd = iconv_open("","");
2693        iconv(cd,NULL,NULL,NULL,NULL);
2694        iconv_close(cd);],
2695       am_cv_func_iconv=yes)
2696     if test "$am_cv_func_iconv" != yes; then
2697       am_save_LIBS="$LIBS"
2698       LIBS="$LIBS -liconv"
2699       AC_TRY_LINK([#include <stdlib.h>
2700 #include <iconv.h>],
2701         [iconv_t cd = iconv_open("","");
2702          iconv(cd,NULL,NULL,NULL,NULL);
2703          iconv_close(cd);],
2704         am_cv_lib_iconv=yes
2705         am_cv_func_iconv=yes)
2706       LIBS="$am_save_LIBS"
2707     fi
2708   ])
2709   if test "$am_cv_func_iconv" = yes; then
2710     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
2711     AC_MSG_CHECKING([for iconv declaration])
2712     AC_CACHE_VAL(am_cv_proto_iconv, [
2713       AC_TRY_COMPILE([
2714 #include <stdlib.h>
2715 #include <iconv.h>
2716 extern
2717 #ifdef __cplusplus
2718 "C"
2719 #endif
2720 #if defined(__STDC__) || defined(__cplusplus)
2721 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
2722 #else
2723 size_t iconv();
2724 #endif
2725 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
2726       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
2727     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
2728     AC_MSG_RESULT([$]{ac_t:-
2729          }[$]am_cv_proto_iconv)
2730     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
2731       [Define as const if the declaration of iconv() needs const.])
2732   fi
2733   LIBICONV=
2734   if test "$am_cv_lib_iconv" = yes; then
2735     LIBICONV="-liconv"
2736   fi
2737   AC_SUBST(LIBICONV)
2738 ])
2739
2740 #serial AM1
2741
2742 dnl From Bruno Haible.
2743
2744 AC_DEFUN([AM_LANGINFO_CODESET],
2745 [
2746   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
2747     [AC_TRY_LINK([#include <langinfo.h>],
2748       [char* cs = nl_langinfo(CODESET);],
2749       am_cv_langinfo_codeset=yes,
2750       am_cv_langinfo_codeset=no)
2751     ])
2752   if test $am_cv_langinfo_codeset = yes; then
2753     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2754       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2755   fi
2756 ])
2757
2758 # Check whether LC_MESSAGES is available in <locale.h>.
2759 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2760 #
2761 # This file can be copied and used freely without restrictions.  It can
2762 # be used in projects which are not available under the GNU Public License
2763 # but which still want to provide support for the GNU gettext functionality.
2764 # Please note that the actual code is *not* freely available.
2765
2766 # serial 2
2767
2768 AC_DEFUN([AM_LC_MESSAGES],
2769   [if test $ac_cv_header_locale_h = yes; then
2770     AC_CACHE_CHECK([for LC_MESSAGES], am_cv_val_LC_MESSAGES,
2771       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2772        am_cv_val_LC_MESSAGES=yes, am_cv_val_LC_MESSAGES=no)])
2773     if test $am_cv_val_LC_MESSAGES = yes; then
2774       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2775         [Define if your <locale.h> file defines LC_MESSAGES.])
2776     fi
2777   fi])
2778
2779 # Do all the work for Automake.  This macro actually does too much --
2780 # some checks are only needed if your package does certain things.
2781 # But this isn't really a big deal.
2782
2783 # serial 1
2784
2785 dnl Usage:
2786 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
2787
2788 AC_DEFUN([AM_INIT_AUTOMAKE],
2789 [AC_REQUIRE([AC_PROG_INSTALL])
2790 PACKAGE=[$1]
2791 AC_SUBST(PACKAGE)
2792 VERSION=[$2]
2793 AC_SUBST(VERSION)
2794 dnl test to see if srcdir already configured
2795 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
2796   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
2797 fi
2798 ifelse([$3],,
2799 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
2800 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
2801 AC_REQUIRE([AM_SANITY_CHECK])
2802 AC_REQUIRE([AC_ARG_PROGRAM])
2803 dnl FIXME This is truly gross.
2804 missing_dir=`cd $ac_aux_dir && pwd`
2805 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
2806 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
2807 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
2808 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
2809 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
2810 AC_REQUIRE([AC_PROG_MAKE_SET])])
2811
2812 #
2813 # Check to make sure that the build environment is sane.
2814 #
2815
2816 AC_DEFUN([AM_SANITY_CHECK],
2817 [AC_MSG_CHECKING([whether build environment is sane])
2818 # Just in case
2819 sleep 1
2820 echo timestamp > conftestfile
2821 # Do `set' in a subshell so we don't clobber the current shell's
2822 # arguments.  Must try -L first in case configure is actually a
2823 # symlink; some systems play weird games with the mod time of symlinks
2824 # (eg FreeBSD returns the mod time of the symlink's containing
2825 # directory).
2826 if (
2827    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
2828    if test "[$]*" = "X"; then
2829       # -L didn't work.
2830       set X `ls -t $srcdir/configure conftestfile`
2831    fi
2832    if test "[$]*" != "X $srcdir/configure conftestfile" \
2833       && test "[$]*" != "X conftestfile $srcdir/configure"; then
2834
2835       # If neither matched, then we have a broken ls.  This can happen
2836       # if, for instance, CONFIG_SHELL is bash and it inherits a
2837       # broken ls alias from the environment.  This has actually
2838       # happened.  Such a system could not be considered "sane".
2839       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2840 alias in your environment])
2841    fi
2842
2843    test "[$]2" = conftestfile
2844    )
2845 then
2846    # Ok.
2847    :
2848 else
2849    AC_MSG_ERROR([newly created file is older than distributed files!
2850 Check your system clock])
2851 fi
2852 rm -f conftest*
2853 AC_MSG_RESULT(yes)])
2854
2855 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
2856 dnl The program must properly implement --version.
2857 AC_DEFUN([AM_MISSING_PROG],
2858 [AC_MSG_CHECKING(for working $2)
2859 # Run test in a subshell; some versions of sh will print an error if
2860 # an executable is not found, even if stderr is redirected.
2861 # Redirect stdin to placate older versions of autoconf.  Sigh.
2862 if ($2 --version) < /dev/null > /dev/null 2>&1; then
2863    $1=$2
2864    AC_MSG_RESULT(found)
2865 else
2866    $1="$3/missing $2"
2867    AC_MSG_RESULT(missing)
2868 fi
2869 AC_SUBST($1)])
2870
2871 # Like AC_CONFIG_HEADER, but automatically create stamp file.
2872
2873 AC_DEFUN([AM_CONFIG_HEADER],
2874 [AC_PREREQ([2.12])
2875 AC_CONFIG_HEADER([$1])
2876 dnl When config.status generates a header, we must update the stamp-h file.
2877 dnl This file resides in the same directory as the config header
2878 dnl that is generated.  We must strip everything past the first ":",
2879 dnl and everything past the last "/".
2880 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
2881 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
2882 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
2883 <<am_indx=1
2884 for am_file in <<$1>>; do
2885   case " <<$>>CONFIG_HEADERS " in
2886   *" <<$>>am_file "*<<)>>
2887     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
2888     ;;
2889   esac
2890   am_indx=`expr "<<$>>am_indx" + 1`
2891 done<<>>dnl>>)
2892 changequote([,]))])
2893