libstdc++-v3/aclocal.m4

   1 # generated automatically by aclocal 1.7.6 -*- Autoconf -*-
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 # Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  11 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  12 # PARTICULAR PURPOSE.
  13
  14
  15 dnl
  16 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
  17 dnl
  18 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
  19 dnl end of configure.  This lets tested variables be reassigned, and the
  20 dnl conditional will depend on the final state of the variable.  For a simple
  21 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
  22 dnl
  23 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  24 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  25   m4_divert_text([glibcxx_diversion],dnl
  26    AM_CONDITIONAL([$1],[$2])
  27   )dnl
  28 ])dnl
  29 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  30
  31
  32 dnl
  33 dnl Check to see what architecture and operating system we are compiling
  34 dnl for.  Also, if architecture- or OS-specific flags are required for
  35 dnl compilation, pick them up here.
  36 dnl
  37 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  38   . $glibcxx_srcdir/configure.host
  39   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  40   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  41 ])
  42
  43
  44 dnl
  45 dnl Initialize basic configure bits.
  46 dnl
  47 dnl Substs:
  48 dnl  multi_basedir
  49 dnl
  50 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  51   # Sets up multi_basedir, which is srcdir/.. plus the usual
  52   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  53   AM_ENABLE_MULTILIB(, ..)
  54
  55   # The generated code is exactly the same, except that automake's looks in
  56   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  57   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  58   # know what they are or what the other differences might be (and they keep
  59   # changing anyhow).
  60   #
  61   # Looking in multi_basedir seems smarter, so actually execute that branch.
  62   if false; then
  63     # this is for automake
  64     AC_CONFIG_AUX_DIR(..)
  65   else
  66     # this is for autoconf
  67     AC_CONFIG_AUX_DIRS(${multi_basedir})
  68   fi
  69
  70   dnl XXX Turn this on.
  71   dnl AC_LANG_CPLUSPLUS
  72 ])
  73
  74
  75 dnl
  76 dnl Initialize the rest of the library configury.  At this point we have
  77 dnl variables like $host.
  78 dnl
  79 dnl Sets:
  80 dnl  gcc_version          (x.y.z format)
  81 dnl  SUBDIRS
  82 dnl Substs:
  83 dnl  glibcxx_builddir     (absolute path)
  84 dnl  glibcxx_srcdir       (absolute path)
  85 dnl  toplevel_srcdir      (absolute path)
  86 dnl  with_cross_host
  87 dnl  with_newlib
  88 dnl  with_target_subdir
  89 dnl plus
  90 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  91 dnl  - default settings for all AM_CONFITIONAL test variables
  92 dnl  - lots of tools, like CC and CXX
  93 dnl
  94 AC_DEFUN(GLIBCXX_CONFIGURE, [
  95   # Keep these sync'd with the list in Makefile.am.  The first provides an
  96   # expandable list at autoconf time; the second provides an expandable list
  97   # (i.e., shell variable) at configure time.
  98   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  99   SUBDIRS='glibcxx_SUBDIRS'
 100
 101   # These need to be absolute paths, yet at the same time need to
 102   # canonicalize only relative paths, because then amd will not unmount
 103   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 104   glibcxx_builddir=`${PWDCMD-pwd}`
 105   case $srcdir in
 106     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
 107     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 108   esac
 109   toplevel_srcdir=${glibcxx_srcdir}/..
 110   AC_SUBST(glibcxx_builddir)
 111   AC_SUBST(glibcxx_srcdir)
 112   AC_SUBST(toplevel_srcdir)
 113
 114   # We use these options to decide which functions to include.  They are
 115   # set from the top level.
 116   AC_ARG_WITH([target-subdir],
 117     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 118                    [configuring in a subdirectory]))
 119
 120   AC_ARG_WITH([cross-host],
 121     AC_HELP_STRING([--with-cross-host=HOST],
 122                    [configuring with a cross compiler]))
 123
 124   AC_ARG_WITH([newlib],
 125     AC_HELP_STRING([--with-newlib],
 126                    [assume newlib as a system C library]))
 127
 128   # We're almost certainly being configured before anything else which uses
 129   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 130   # we not cache the value of CXX that we "discover" here, because it's set
 131   # to something unique for us and libjava.  Other target libraries need to
 132   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 133   # process by sneakily renaming the cache variable.  This also lets us debug
 134   # the value of "our" CXX in postmortems.
 135   #
 136   # We must also force CXX to /not/ be a precious variable, otherwise the
 137   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 138   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 139   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 140   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 141   #
 142   # -fno-builtin must be present here so that a non-conflicting form of
 143   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 144
 145   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 146   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 147   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 148   save_CXXFLAGS="$CXXFLAGS"
 149   CXXFLAGS="$CXXFLAGS -fno-builtin"
 150   AC_PROG_CC
 151   AC_PROG_CXX
 152   CXXFLAGS="$save_CXXFLAGS"
 153   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 154   AC_SUBST(CFLAGS)
 155   AC_SUBST(CXXFLAGS)
 156
 157   # For directory versioning (e.g., headers) and other variables.
 158   AC_MSG_CHECKING([for GCC version number])
 159   gcc_version=`$CXX -dumpversion`
 160   AC_MSG_RESULT($gcc_version)
 161
 162   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 163   # available).  Uncomment the next line to force a particular method.
 164   AC_PROG_LN_S
 165   #LN_S='cp -p'
 166
 167   AC_CHECK_TOOL(AS, as)
 168   AC_CHECK_TOOL(AR, ar)
 169   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 170
 171   AM_MAINTAINER_MODE
 172
 173   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 174   # which are themselves conditionally expanded.
 175   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 176   ## other macros from doing the same.  This should be automated.)  -pme
 177   need_libmath=no
 178   enable_wchar_t=no
 179   #enable_libstdcxx_debug=no
 180   #enable_libstdcxx_pch=no
 181   #enable_cheaders=c
 182   #c_compatibility=no
 183   #enable_abi_check=no
 184   #enable_symvers=no
 185   #enable_hosted_libstdcxx=yes
 186
 187   # Find platform-specific directories containing configuration info.
 188   # Also possibly modify flags used elsewhere, as needed by the platform.
 189   GLIBCXX_CHECK_HOST
 190 ])
 191
 192
 193 m4_include([linkage.m4])
 194 m4_include([../config/no-executables.m4])
 195
 196
 197 dnl
 198 dnl Tests for newer compiler features, or features that are present in newer
 199 dnl compiler versions but not older compiler versions still in use, should
 200 dnl be placed here.
 201 dnl
 202 dnl Defines:
 203 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 204 dnl   new inlining code or the new system_header pragma will die on -Werror.
 205 dnl   Leave it out by default and use maint-mode to use it.
 206 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 207 dnl   compiler supports it and the user has not requested debug mode.
 208 dnl
 209 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 210   # All these tests are for C++; save the language and the compiler flags.
 211   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 212   # found in GLIBCXX_CONFIGURE.
 213   AC_LANG_SAVE
 214   AC_LANG_CPLUSPLUS
 215   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 216   ac_save_CXXFLAGS="$CXXFLAGS"
 217
 218   # Check for maintainer-mode bits.
 219   if test x"$USE_MAINTAINER_MODE" = xno; then
 220     WERROR=''
 221   else
 222     WERROR='-Werror'
 223   fi
 224
 225   # Check for -ffunction-sections -fdata-sections
 226   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 227   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 228   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 229   if test "$ac_test_CXXFLAGS" = set; then
 230     CXXFLAGS="$ac_save_CXXFLAGS"
 231   else
 232     # this is the suspicious part
 233     CXXFLAGS=''
 234   fi
 235   if test x"$ac_fdsections" = x"yes"; then
 236     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 237   fi
 238   AC_MSG_RESULT($ac_fdsections)
 239
 240   AC_LANG_RESTORE
 241   AC_SUBST(WERROR)
 242   AC_SUBST(SECTION_FLAGS)
 243 ])
 244
 245
 246 dnl
 247 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 248 dnl the native linker is in use, all variables will be defined to something
 249 dnl safe (like an empty string).
 250 dnl
 251 dnl Defines:
 252 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 253 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 254 dnl  LD (as a side effect of testing)
 255 dnl Sets:
 256 dnl  with_gnu_ld
 257 dnl  glibcxx_gnu_ld_version (possibly)
 258 dnl
 259 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 260 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 261 dnl
 262 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 263   # If we're not using GNU ld, then there's no point in even trying these
 264   # tests.  Check for that first.  We should have already tested for gld
 265   # by now (in libtool), but require it now just to be safe...
 266   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 267   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 268   AC_REQUIRE([AC_PROG_LD])
 269   AC_REQUIRE([AC_PROG_AWK])
 270
 271   # The name set by libtool depends on the version of libtool.  Shame on us
 272   # for depending on an impl detail, but c'est la vie.  Older versions used
 273   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 274   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 275   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 276   # set (hence we're using an older libtool), then set it.
 277   if test x${with_gnu_ld+set} != xset; then
 278     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 279       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 280       with_gnu_ld=no
 281     else
 282       with_gnu_ld=$ac_cv_prog_gnu_ld
 283     fi
 284   fi
 285
 286   # Start by getting the version number.  I think the libtool test already
 287   # does some of this, but throws away the result.
 288   changequote(,)
 289   ldver=`$LD --version 2>/dev/null | head -1 | \
 290          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 291   changequote([,])
 292   glibcxx_gnu_ld_version=`echo $ldver | \
 293          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 294
 295   # Set --gc-sections.
 296   if test "$with_gnu_ld" = "notbroken"; then
 297     # GNU ld it is!  Joy and bunny rabbits!
 298
 299     # All these tests are for C++; save the language and the compiler flags.
 300     # Need to do this so that g++ won't try to link in libstdc++
 301     ac_test_CFLAGS="${CFLAGS+set}"
 302     ac_save_CFLAGS="$CFLAGS"
 303     CFLAGS='-x c++  -Wl,--gc-sections'
 304
 305     # Check for -Wl,--gc-sections
 306     # XXX This test is broken at the moment, as symbols required for linking
 307     # are now in libsupc++ (not built yet).  In addition, this test has
 308     # cored on solaris in the past.  In addition, --gc-sections doesn't
 309     # really work at the moment (keeps on discarding used sections, first
 310     # .eh_frame and now some of the glibc sections for iconv).
 311     # Bzzzzt.  Thanks for playing, maybe next time.
 312     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 313     AC_TRY_RUN([
 314      int main(void)
 315      {
 316        try { throw 1; }
 317        catch (...) { };
 318        return 0;
 319      }
 320     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 321     if test "$ac_test_CFLAGS" = set; then
 322       CFLAGS="$ac_save_CFLAGS"
 323     else
 324       # this is the suspicious part
 325       CFLAGS=''
 326     fi
 327     if test "$ac_sectionLDflags" = "yes"; then
 328       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 329     fi
 330     AC_MSG_RESULT($ac_sectionLDflags)
 331   fi
 332
 333   # Set linker optimization flags.
 334   if test x"$with_gnu_ld" = x"yes"; then
 335     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 336   fi
 337
 338   AC_SUBST(SECTION_LDFLAGS)
 339   AC_SUBST(OPT_LDFLAGS)
 340 ])
 341
 342
 343 dnl
 344 dnl Check to see if this target can enable the wchar_t parts.
 345 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 346 dnl must have been previously checked.)  By default, wide characters are
 347 dnl disabled.
 348 dnl
 349 dnl Defines:
 350 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 351 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 352 dnl
 353 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 354   # Test wchar.h for mbstate_t, which is needed for char_traits and
 355   # others even if wchar_t support is not on.
 356   AC_MSG_CHECKING([for mbstate_t])
 357   AC_TRY_COMPILE([#include <wchar.h>],
 358   [mbstate_t teststate;],
 359   have_mbstate_t=yes, have_mbstate_t=no)
 360   AC_MSG_RESULT($have_mbstate_t)
 361   if test x"$have_mbstate_t" = xyes; then
 362     AC_DEFINE(HAVE_MBSTATE_T)
 363   fi
 364
 365   # Sanity check for existence of ISO C99 headers for extended encoding.
 366   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 367   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 368
 369   # Only continue checking if the ISO C99 headers exist and support is on.
 370   if test x"$ac_has_wchar_h" = xyes &&
 371      test x"$ac_has_wctype_h" = xyes &&
 372      test x"$enable_c_mbchar" != xno; then
 373
 374     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 375     # numeric_limits can instantiate type_traits<wchar_t>
 376     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 377     AC_TRY_COMPILE([#include <wchar.h>],
 378     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 379     has_wchar_minmax=yes, has_wchar_minmax=no)
 380     AC_MSG_RESULT($has_wchar_minmax)
 381
 382     # Test wchar.h for WEOF, which is what we use to determine whether
 383     # to specialize for char_traits<wchar_t> or not.
 384     AC_MSG_CHECKING([for WEOF])
 385     AC_TRY_COMPILE([
 386       #include <wchar.h>
 387       #include <stddef.h>],
 388     [wint_t i = WEOF;],
 389     has_weof=yes, has_weof=no)
 390     AC_MSG_RESULT($has_weof)
 391
 392     # Tests for wide character functions used in char_traits<wchar_t>.
 393     ac_wfuncs=yes
 394     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 395     [],[ac_wfuncs=no])
 396
 397     # Checks for names injected into std:: by the c_std headers.
 398     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 399     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 400     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 401     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 402     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 403     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 404     [],[ac_wfuncs=no])
 405
 406     # Checks for wide character functions that are not required
 407     # for basic wchar_t support.  Don't disable support if they are missing.
 408     # Injection of these is wrapped with guard macros.
 409     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 410
 411     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 412     if test x"$has_weof" = xyes &&
 413        test x"$has_wchar_minmax" = xyes &&
 414        test x"$ac_wfuncs" = xyes;
 415     then
 416       ac_isoC99_wchar_t=yes
 417     else
 418       ac_isoC99_wchar_t=no
 419     fi
 420     AC_MSG_RESULT($ac_isoC99_wchar_t)
 421
 422     # Use iconv for wchar_t to char conversions. As such, check for
 423     # X/Open Portability Guide, version 2 features (XPG2).
 424     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 425     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 426
 427     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 428     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 429     ac_save_LIBS="$LIBS"
 430     LIBS="$LIBS $libiconv"
 431
 432     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 433     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 434
 435     LIBS="$ac_save_LIBS"
 436
 437     AC_MSG_CHECKING([for XPG2 wchar_t support])
 438     if test x"$ac_has_iconv_h" = xyes &&
 439        test x"$ac_has_langinfo_h" = xyes &&
 440        test x"$ac_XPG2funcs" = xyes;
 441     then
 442       ac_XPG2_wchar_t=yes
 443     else
 444       ac_XPG2_wchar_t=no
 445     fi
 446     AC_MSG_RESULT($ac_XPG2_wchar_t)
 447
 448     # At the moment, only enable wchar_t specializations if all the
 449     # above support is present.
 450     if test x"$ac_isoC99_wchar_t" = xyes &&
 451        test x"$ac_XPG2_wchar_t" = xyes;
 452     then
 453       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 454       enable_wchar_t=yes
 455     fi
 456   fi
 457   AC_MSG_CHECKING([for enabled wchar_t specializations])
 458   AC_MSG_RESULT($enable_wchar_t)
 459 ])
 460
 461
 462 dnl
 463 dnl Check for headers for, and arguments to, the setrlimit() function.
 464 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 465 dnl
 466 dnl Defines:
 467 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 468 dnl  various HAVE_MEMLIMIT_* for individual limit names
 469 dnl
 470 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 471   AC_TRY_COMPILE(
 472     [#include <unistd.h>
 473      #include <sys/time.h>
 474      #include <sys/resource.h>
 475     ],
 476     [ int f = RLIMIT_$1 ; ],
 477     [glibcxx_mresult=1], [glibcxx_mresult=0])
 478   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 479                      [Only used in build directory testsuite_hooks.h.])
 480 ])
 481
 482 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 483   setrlimit_have_headers=yes
 484   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 485                    [],
 486                    [setrlimit_have_headers=no])
 487   # If don't have the headers, then we can't run the tests now, and we
 488   # won't be seeing any of these during testsuite compilation.
 489   if test $setrlimit_have_headers = yes; then
 490     # Can't do these in a loop, else the resulting syntax is wrong.
 491     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 492     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 493     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 494     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 495
 496     # Check for rlimit, setrlimit.
 497     AC_CACHE_VAL(ac_setrlimit, [
 498       AC_TRY_COMPILE(
 499         [#include <unistd.h>
 500          #include <sys/time.h>
 501          #include <sys/resource.h>
 502         ],
 503         [struct rlimit r;
 504          setrlimit(0, &r);],
 505         [ac_setrlimit=yes], [ac_setrlimit=no])
 506     ])
 507   fi
 508
 509   AC_MSG_CHECKING([for testsuite memory limit support])
 510   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 511     ac_mem_limits=yes
 512     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 513   else
 514     ac_mem_limits=no
 515   fi
 516   AC_MSG_RESULT($ac_mem_limits)
 517 ])
 518
 519
 520 dnl
 521 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 522 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 523 dnl
 524 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 525   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 526     AC_TRY_LINK(
 527       [#include <sys/stat.h>],
 528       [struct stat buffer;
 529        fstat(0, &buffer);
 530        S_ISREG(buffer.st_mode);],
 531       [glibcxx_cv_S_ISREG=yes],
 532       [glibcxx_cv_S_ISREG=no])
 533   ])
 534   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 535     AC_TRY_LINK(
 536       [#include <sys/stat.h>],
 537       [struct stat buffer;
 538        fstat(0, &buffer);
 539        S_IFREG & buffer.st_mode;],
 540       [glibcxx_cv_S_IFREG=yes],
 541       [glibcxx_cv_S_IFREG=no])
 542   ])
 543   if test $glibcxx_cv_S_ISREG = yes; then
 544     AC_DEFINE(HAVE_S_ISREG)
 545   elif test $glibcxx_cv_S_IFREG = yes; then
 546     AC_DEFINE(HAVE_S_IFREG)
 547   fi
 548 ])
 549
 550
 551 dnl
 552 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 553 dnl
 554 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 555   AC_CACHE_VAL(glibcxx_cv_POLL, [
 556     AC_TRY_COMPILE(
 557       [#include <poll.h>],
 558       [struct pollfd pfd[1];
 559        pfd[0].events = POLLIN;
 560        poll(pfd, 1, 0);],
 561       [glibcxx_cv_POLL=yes],
 562       [glibcxx_cv_POLL=no])
 563   ])
 564   if test $glibcxx_cv_POLL = yes; then
 565     AC_DEFINE(HAVE_POLL)
 566   fi
 567 ])
 568
 569
 570 dnl
 571 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 572 dnl
 573 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 574   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 575     AC_TRY_COMPILE(
 576       [#include <sys/uio.h>],
 577       [struct iovec iov[2];
 578        writev(0, iov, 0);],
 579       [glibcxx_cv_WRITEV=yes],
 580       [glibcxx_cv_WRITEV=no])
 581   ])
 582   if test $glibcxx_cv_WRITEV = yes; then
 583     AC_DEFINE(HAVE_WRITEV)
 584   fi
 585 ])
 586
 587
 588 dnl
 589 dnl Does any necessary configuration of the testsuite directory.  Generates
 590 dnl the testsuite_hooks.h header.
 591 dnl
 592 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 593 dnl
 594 dnl Sets:
 595 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 596 dnl Substs:
 597 dnl  baseline_dir
 598 dnl
 599 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 600   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 601     # Do checks for memory limit functions.
 602     GLIBCXX_CHECK_SETRLIMIT
 603
 604     # Look for setenv, so that extended locale tests can be performed.
 605     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 606
 607     if test $enable_symvers = no; then
 608       enable_abi_check=no
 609     else
 610       case "$host" in
 611         *-*-cygwin*)
 612           enable_abi_check=no ;;
 613         *)
 614           enable_abi_check=yes ;;
 615       esac
 616     fi
 617   else
 618     # Only build this as native, since automake does not understand
 619     # CXX_FOR_BUILD.
 620     enable_abi_check=no
 621   fi
 622
 623   # Export file names for ABI checking.
 624   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 625   AC_SUBST(baseline_dir)
 626
 627   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 628   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 629 ])
 630
 631
 632 dnl
 633 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 634 dnl
 635 dnl Substs:
 636 dnl  GLIBCXX_INCLUDES
 637 dnl  TOPLEVEL_INCLUDES
 638 dnl
 639 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 640   # Used for every C++ compile we perform.
 641   GLIBCXX_INCLUDES="\
 642 -I$glibcxx_builddir/include/$host_alias \
 643 -I$glibcxx_builddir/include \
 644 -I$glibcxx_srcdir/libsupc++"
 645
 646   # For Canadian crosses, pick this up too.
 647   if test $CANADIAN = yes; then
 648     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 649   fi
 650
 651   # Stuff in the actual top level.  Currently only used by libsupc++ to
 652   # get unwind* headers from the gcc dir.
 653   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 654   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 655
 656   # Now, export this to all the little Makefiles....
 657   AC_SUBST(GLIBCXX_INCLUDES)
 658   AC_SUBST(TOPLEVEL_INCLUDES)
 659 ])
 660
 661
 662 dnl
 663 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 664 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 665 dnl
 666 dnl Substs:
 667 dnl  OPTIMIZE_CXXFLAGS
 668 dnl  WARN_FLAGS
 669 dnl
 670 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 671   # Optimization flags that are probably a good idea for thrill-seekers. Just
 672   # uncomment the lines below and make, everything else is ready to go...
 673   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 674   OPTIMIZE_CXXFLAGS=
 675   AC_SUBST(OPTIMIZE_CXXFLAGS)
 676
 677   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 678   AC_SUBST(WARN_FLAGS)
 679 ])
 680
 681
 682 dnl
 683 dnl All installation directory information is determined here.
 684 dnl
 685 dnl Substs:
 686 dnl  gxx_install_dir
 687 dnl  glibcxx_prefixdir
 688 dnl  glibcxx_toolexecdir
 689 dnl  glibcxx_toolexeclibdir
 690 dnl
 691 dnl Assumes cross_compiling bits already done, and with_cross_host in
 692 dnl particular.
 693 dnl
 694 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 695   glibcxx_toolexecdir=no
 696   glibcxx_toolexeclibdir=no
 697   glibcxx_prefixdir=$prefix
 698
 699   AC_MSG_CHECKING([for gxx-include-dir])
 700   AC_ARG_WITH([gxx-include-dir],
 701     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 702                    [installation directory for include files]),
 703     [case "$withval" in
 704       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 705       no)  gxx_include_dir=no ;;
 706       *)   gxx_include_dir=$withval ;;
 707      esac],
 708     [gxx_include_dir=no])
 709   AC_MSG_RESULT($gxx_include_dir)
 710
 711   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 712   AC_ARG_ENABLE([version-specific-runtime-libs],
 713     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 714                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 715     [case "$enableval" in
 716       yes) version_specific_libs=yes ;;
 717       no)  version_specific_libs=no ;;
 718       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 719      esac],
 720     [version_specific_libs=no])
 721   AC_MSG_RESULT($version_specific_libs)
 722
 723   # Default case for install directory for include files.
 724   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 725     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 726   fi
 727
 728   # Version-specific runtime libs processing.
 729   if test $version_specific_libs = yes; then
 730     # Need the gcc compiler version to know where to install libraries
 731     # and header files if --enable-version-specific-runtime-libs option
 732     # is selected.
 733     if test x"$gxx_include_dir" = x"no"; then
 734       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 735     fi
 736     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 737     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 738   fi
 739
 740   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 741   # Install a library built with a cross compiler in tooldir, not libdir.
 742   if test x"$glibcxx_toolexecdir" = x"no"; then
 743     if test -n "$with_cross_host" &&
 744        test x"$with_cross_host" != x"no"; then
 745       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 746       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 747     else
 748       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 749       glibcxx_toolexeclibdir='${libdir}'
 750     fi
 751     multi_os_directory=`$CXX -print-multi-os-directory`
 752     case $multi_os_directory in
 753       .) ;; # Avoid trailing /.
 754       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 755     esac
 756   fi
 757
 758   AC_MSG_CHECKING([for install location])
 759   AC_MSG_RESULT($gxx_include_dir)
 760
 761   AC_SUBST(glibcxx_prefixdir)
 762   AC_SUBST(gxx_include_dir)
 763   AC_SUBST(glibcxx_toolexecdir)
 764   AC_SUBST(glibcxx_toolexeclibdir)
 765 ])
 766
 767
 768 dnl
 769 dnl GLIBCXX_ENABLE
 770 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 771 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 772 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 773 dnl
 774 dnl See docs/html/17_intro/configury.html#enable for documentation.
 775 dnl
 776 m4_define([GLIBCXX_ENABLE],[dnl
 777 m4_define([_g_switch],[--enable-$1])dnl
 778 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 779  AC_ARG_ENABLE($1,_g_help,
 780   m4_bmatch([$5],
 781    [^permit ],
 782      [[
 783       case "$enableval" in
 784        m4_bpatsubst([$5],[permit ])) ;;
 785        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 786           dnl Idea for future:  generate a URL pointing to
 787           dnl "onlinedocs/configopts.html#whatever"
 788       esac
 789      ]],
 790    [^$],
 791      [[
 792       case "$enableval" in
 793        yes|no) ;;
 794        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 795       esac
 796      ]],
 797    [[$5]]),
 798   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 799 m4_undefine([_g_switch])dnl
 800 m4_undefine([_g_help])dnl
 801 ])
 802
 803
 804 dnl
 805 dnl Check for ISO/IEC 9899:1999 "C99" support.
 806 dnl
 807 dnl --enable-c99 defines _GLIBCXX_USE_C99
 808 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 809 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 810 dnl       Where DEFAULT is either `yes' or `no'.
 811 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 812 dnl
 813 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 814   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 815
 816   AC_LANG_SAVE
 817   AC_LANG_CPLUSPLUS
 818
 819   # Check for the existence of <math.h> functions used if C99 is enabled.
 820   ac_c99_math=yes;
 821   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 822   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 823   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 824   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 825   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 826   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 827   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 828   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 829   AC_TRY_COMPILE([#include <math.h>],
 830                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 831   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 832   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 833   AC_TRY_COMPILE([#include <math.h>],
 834                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 835   AC_TRY_COMPILE([#include <math.h>],
 836                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 837   AC_MSG_RESULT($ac_c99_math)
 838
 839   # Check for the existence in <stdio.h> of vscanf, et. al.
 840   ac_c99_stdio=yes;
 841   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 842   AC_TRY_COMPILE([#include <stdio.h>],
 843                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 844   AC_TRY_COMPILE([#include <stdio.h>
 845                   #include <stdarg.h>
 846                   void foo(char* fmt, ...)
 847                   {va_list args; va_start(args, fmt);
 848                   vfscanf(stderr, "%i", args);}],
 849                   [],, [ac_c99_stdio=no])
 850   AC_TRY_COMPILE([#include <stdio.h>
 851                   #include <stdarg.h>
 852                   void foo(char* fmt, ...)
 853                   {va_list args; va_start(args, fmt);
 854                   vscanf("%i", args);}],
 855                   [],, [ac_c99_stdio=no])
 856   AC_TRY_COMPILE([#include <stdio.h>
 857                   #include <stdarg.h>
 858                   void foo(char* fmt, ...)
 859                   {va_list args; va_start(args, fmt);
 860                   vsnprintf(fmt, 0, "%i", args);}],
 861                   [],, [ac_c99_stdio=no])
 862   AC_TRY_COMPILE([#include <stdio.h>
 863                   #include <stdarg.h>
 864                   void foo(char* fmt, ...)
 865                   {va_list args; va_start(args, fmt);
 866                   vsscanf(fmt, "%i", args);}],
 867                   [],, [ac_c99_stdio=no])
 868   AC_MSG_RESULT($ac_c99_stdio)
 869
 870   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 871   ac_c99_stdlib=yes;
 872   AC_MSG_CHECKING([for lldiv_t declaration])
 873   AC_CACHE_VAL(ac_c99_lldiv_t, [
 874   AC_TRY_COMPILE([#include <stdlib.h>],
 875                    [ lldiv_t mydivt;],
 876                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 877   ])
 878   AC_MSG_RESULT($ac_c99_lldiv_t)
 879
 880   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 881   AC_TRY_COMPILE([#include <stdlib.h>],
 882                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 883   AC_TRY_COMPILE([#include <stdlib.h>],
 884                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 885   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 886   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 887   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 888   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 889   if test x"$ac_c99_lldiv_t" = x"no"; then
 890     ac_c99_stdlib=no;
 891   fi;
 892   AC_MSG_RESULT($ac_c99_stdlib)
 893
 894   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 895   # XXX the wchar.h checks should be rolled into the general C99 bits.
 896   ac_c99_wchar=yes;
 897   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 898   AC_TRY_COMPILE([#include <wchar.h>],
 899                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 900   AC_TRY_COMPILE([#include <wchar.h>],
 901                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 902   AC_TRY_COMPILE([#include <wchar.h>],
 903                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 904   AC_MSG_RESULT($ac_c99_wchar)
 905
 906   AC_MSG_CHECKING([for enabled ISO C99 support])
 907   if test x"$ac_c99_math" = x"no" ||
 908      test x"$ac_c99_stdio" = x"no" ||
 909      test x"$ac_c99_stdlib" = x"no" ||
 910      test x"$ac_c99_wchar" = x"no"; then
 911     enable_c99=no;
 912   fi;
 913   AC_MSG_RESULT($enable_c99)
 914
 915   # Option parsed, now set things appropriately
 916   if test x"$enable_c99" = x"yes"; then
 917     AC_DEFINE(_GLIBCXX_USE_C99)
 918   fi
 919
 920   AC_LANG_RESTORE
 921 ])
 922
 923
 924 dnl
 925 dnl Check for what type of C headers to use.
 926 dnl
 927 dnl --enable-cheaders= [does stuff].
 928 dnl --disable-cheaders [does not do anything, really].
 929 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 930 dnl       Where DEFAULT is either `c' or `c_std'.
 931 dnl
 932 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 933   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 934     [construct "C" headers for g++], [permit c|c_std])
 935   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 936
 937   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 938
 939   AC_SUBST(C_INCLUDE_DIR)
 940   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 941   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 942   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 943 ])
 944
 945
 946 dnl
 947 dnl Check for which locale library to use.  The choice is mapped to
 948 dnl a subdirectory of config/locale.
 949 dnl
 950 dnl Default is generic.
 951 dnl
 952 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 953   AC_MSG_CHECKING([for C locale to use])
 954   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 955     [use MODEL for target locale package],
 956     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 957
 958   # If they didn't use this option switch, or if they specified --enable
 959   # with no specific model, we'll have to look for one.  If they
 960   # specified --disable (???), do likewise.
 961   if test $enable_clocale = no || test $enable_clocale = yes; then
 962      enable_clocale=auto
 963   fi
 964
 965   # Either a known package, or "auto"
 966   enable_clocale_flag=$enable_clocale
 967
 968   # Probe for locale support if no specific model is specified.
 969   # Default to "generic".
 970   if test $enable_clocale_flag = auto; then
 971     case x${target_os} in
 972       xlinux* | xgnu*)
 973         AC_EGREP_CPP([_GLIBCXX_ok], [
 974         #include <features.h>
 975         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 976           _GLIBCXX_ok
 977         #endif
 978         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
 979
 980         # Test for bugs early in glibc-2.2.x series
 981           if test x$enable_clocale_flag = xgnu; then
 982           AC_TRY_RUN([
 983           #define _GNU_SOURCE 1
 984           #include <locale.h>
 985           #include <string.h>
 986           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
 987           extern __typeof(newlocale) __newlocale;
 988           extern __typeof(duplocale) __duplocale;
 989           extern __typeof(strcoll_l) __strcoll_l;
 990           #endif
 991           int main()
 992           {
 993               const char __one[] = "Äuglein Augmen";
 994               const char __two[] = "Äuglein";
 995               int i;
 996               int j;
 997               __locale_t        loc;
 998                __locale_t        loc_dup;
 999               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1000               loc_dup = __duplocale(loc);
1001               i = __strcoll_l(__one, __two, loc);
1002               j = __strcoll_l(__one, __two, loc_dup);
1003               return 0;
1004           }
1005           ],
1006           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1007           [enable_clocale_flag=generic])
1008           fi
1009
1010         # ... at some point put __strxfrm_l tests in as well.
1011         ;;
1012       *)
1013         enable_clocale_flag=generic
1014         ;;
1015     esac
1016   fi
1017
1018   # Deal with gettext issues.  Default to not using it (=no) until we detect
1019   # support for it later.  Let the user turn it off via --e/d, but let that
1020   # default to on for easier handling.
1021   USE_NLS=no
1022   AC_ARG_ENABLE(nls,
1023     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1024     [],
1025     [enable_nls=yes])
1026
1027   # Set configure bits for specified locale package
1028   case ${enable_clocale_flag} in
1029     generic)
1030       AC_MSG_RESULT(generic)
1031
1032       CLOCALE_H=config/locale/generic/c_locale.h
1033       CLOCALE_CC=config/locale/generic/c_locale.cc
1034       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1035       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1036       CCOLLATE_CC=config/locale/generic/collate_members.cc
1037       CCTYPE_CC=config/locale/generic/ctype_members.cc
1038       CMESSAGES_H=config/locale/generic/messages_members.h
1039       CMESSAGES_CC=config/locale/generic/messages_members.cc
1040       CMONEY_CC=config/locale/generic/monetary_members.cc
1041       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1042       CTIME_H=config/locale/generic/time_members.h
1043       CTIME_CC=config/locale/generic/time_members.cc
1044       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1045       ;;
1046     gnu)
1047       AC_MSG_RESULT(gnu)
1048
1049       # Declare intention to use gettext, and add support for specific
1050       # languages.
1051       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1052       ALL_LINGUAS="de fr"
1053
1054       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1055       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1056       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1057         USE_NLS=yes
1058       fi
1059       # Export the build objects.
1060       for ling in $ALL_LINGUAS; do \
1061         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1062         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1063       done
1064       AC_SUBST(glibcxx_MOFILES)
1065       AC_SUBST(glibcxx_POFILES)
1066
1067       CLOCALE_H=config/locale/gnu/c_locale.h
1068       CLOCALE_CC=config/locale/gnu/c_locale.cc
1069       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1070       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1071       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1072       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1073       CMESSAGES_H=config/locale/gnu/messages_members.h
1074       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1075       CMONEY_CC=config/locale/gnu/monetary_members.cc
1076       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1077       CTIME_H=config/locale/gnu/time_members.h
1078       CTIME_CC=config/locale/gnu/time_members.cc
1079       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1080       ;;
1081     ieee_1003.1-2001)
1082       AC_MSG_RESULT(IEEE 1003.1)
1083
1084       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1085       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1086       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1087       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1088       CCOLLATE_CC=config/locale/generic/collate_members.cc
1089       CCTYPE_CC=config/locale/generic/ctype_members.cc
1090       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1091       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1092       CMONEY_CC=config/locale/generic/monetary_members.cc
1093       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1094       CTIME_H=config/locale/generic/time_members.h
1095       CTIME_CC=config/locale/generic/time_members.cc
1096       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1097       ;;
1098   esac
1099
1100   # This is where the testsuite looks for locale catalogs, using the
1101   # -DLOCALEDIR define during testsuite compilation.
1102   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1103   AC_SUBST(glibcxx_localedir)
1104
1105   # A standalone libintl (e.g., GNU libintl) may be in use.
1106   if test $USE_NLS = yes; then
1107     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1108     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1109   fi
1110   if test $USE_NLS = yes; then
1111     AC_DEFINE(_GLIBCXX_USE_NLS)
1112   fi
1113
1114   AC_SUBST(USE_NLS)
1115   AC_SUBST(CLOCALE_H)
1116   AC_SUBST(CCODECVT_H)
1117   AC_SUBST(CMESSAGES_H)
1118   AC_SUBST(CCODECVT_CC)
1119   AC_SUBST(CCOLLATE_CC)
1120   AC_SUBST(CCTYPE_CC)
1121   AC_SUBST(CMESSAGES_CC)
1122   AC_SUBST(CMONEY_CC)
1123   AC_SUBST(CNUMERIC_CC)
1124   AC_SUBST(CTIME_H)
1125   AC_SUBST(CTIME_CC)
1126   AC_SUBST(CLOCALE_CC)
1127   AC_SUBST(CLOCALE_INTERNAL_H)
1128 ])
1129
1130
1131 dnl
1132 dnl Check for whether the Boost-derived checks should be turned on.
1133 dnl
1134 dnl --enable-concept-checks turns them on.
1135 dnl --disable-concept-checks leaves them off.
1136 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1137 dnl       Where DEFAULT is either `yes' or `no'.
1138 dnl
1139 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1140   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1141   if test $enable_concept_checks = yes; then
1142     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1143   fi
1144 ])
1145
1146
1147 dnl
1148 dnl Check for which I/O library to use:  stdio, or something specific.
1149 dnl
1150 dnl Default is stdio.
1151 dnl
1152 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1153   AC_MSG_CHECKING([for underlying I/O to use])
1154   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1155     [use target-specific I/O package], [permit stdio])
1156
1157   # Now that libio has been removed, you can have any color you want as long
1158   # as it's black.  This is one big no-op until other packages are added, but
1159   # showing the framework never hurts.
1160   case ${enable_cstdio} in
1161     stdio)
1162       CSTDIO_H=config/io/c_io_stdio.h
1163       BASIC_FILE_H=config/io/basic_file_stdio.h
1164       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1165       AC_MSG_RESULT(stdio)
1166       ;;
1167   esac
1168
1169   dnl Set directory for fpos.h
1170   FPOS_H=$fpos_include_dir
1171
1172   AC_SUBST(CSTDIO_H)
1173   AC_SUBST(FPOS_H)
1174   AC_SUBST(BASIC_FILE_H)
1175   AC_SUBST(BASIC_FILE_CC)
1176 ])
1177
1178
1179 dnl
1180 dnl Check for "unusual" flags to pass to the compiler while building.
1181 dnl
1182 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1183 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1184 dnl --disable-cxx-flags passes nothing.
1185 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1186 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1187 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1188 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1189 dnl       If "default flags" is an empty string, the effect is the same
1190 dnl       as --disable or --enable=no.
1191 dnl
1192 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1193   AC_MSG_CHECKING([for extra compiler flags for building])
1194   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1195     [pass compiler FLAGS when building library],
1196     [case "x$enable_cxx_flags" in
1197       xno | x)   enable_cxx_flags= ;;
1198       x-*)       ;;
1199       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1200      esac])
1201
1202   # Run through flags (either default or command-line) and set anything
1203   # extra (e.g., #defines) that must accompany particular g++ options.
1204   if test -n "$enable_cxx_flags"; then
1205     for f in $enable_cxx_flags; do
1206       case "$f" in
1207         -fhonor-std)  ;;
1208         -*)  ;;
1209         *)   # and we're trying to pass /what/ exactly?
1210              AC_MSG_ERROR([compiler flags start with a -]) ;;
1211       esac
1212     done
1213   fi
1214
1215   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1216   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1217   AC_SUBST(EXTRA_CXX_FLAGS)
1218 ])
1219
1220
1221 dnl
1222 dnl Check for wide character support.  Has the same effect as the option
1223 dnl in gcc's configure, but in a form that autoconf can mess with.
1224 dnl
1225 dnl --enable-c-mbchar requests all the wchar_t stuff.
1226 dnl --disable-c-mbchar doesn't.
1227 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1228 dnl       Where DEFAULT is either `yes' or `no'.
1229 dnl
1230 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1231   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1232   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1233 ])
1234
1235
1236 dnl
1237 dnl Check to see if debugging libraries are to be built.
1238 dnl
1239 dnl --enable-libstdcxx-debug
1240 dnl builds a separate set of debugging libraries in addition to the
1241 dnl normal (shared, static) libstdc++ binaries.
1242 dnl
1243 dnl --disable-libstdcxx-debug
1244 dnl builds only one (non-debug) version of libstdc++.
1245 dnl
1246 dnl --enable-libstdcxx-debug-flags=FLAGS
1247 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1248 dnl
1249 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1250 dnl       Where DEFAULT is either `yes' or `no'.
1251 dnl
1252 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1253   AC_MSG_CHECKING([for additional debug build])
1254   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1255   AC_MSG_RESULT($enable_libstdcxx_debug)
1256   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1257 ])
1258
1259
1260 dnl
1261 dnl Check for explicit debug flags.
1262 dnl
1263 dnl --enable-libstdcxx-debug-flags='-O1'
1264 dnl is a general method for passing flags to be used when
1265 dnl building debug libraries with --enable-debug.
1266 dnl
1267 dnl --disable-libstdcxx-debug-flags does nothing.
1268 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1269 dnl       If "default flags" is an empty string, the effect is the same
1270 dnl       as --disable or --enable=no.
1271 dnl
1272 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1273   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1274     [pass compiler FLAGS when building debug library],
1275     [case "x$enable_libstdcxx_debug_flags" in
1276       xno | x)    enable_libstdcxx_debug_flags= ;;
1277       x-*)        ;;
1278       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1279      esac])
1280
1281   # Option parsed, now set things appropriately
1282   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1283   AC_SUBST(DEBUG_FLAGS)
1284
1285   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1286 ])
1287
1288
1289 dnl
1290 dnl Check if the user only wants a freestanding library implementation.
1291 dnl
1292 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1293 dnl installing only the headers required by [17.4.1.3] and the language
1294 dnl support library.  More than that will be built (to keep the Makefiles
1295 dnl conveniently clean), but not installed.
1296 dnl
1297 dnl Sets:
1298 dnl  is_hosted  (yes/no)
1299 dnl
1300 dnl Defines:
1301 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1302 dnl
1303 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1304   AC_ARG_ENABLE([hosted-libstdcxx],
1305     AC_HELP_STRING([--disable-hosted-libstdcxx],
1306                    [only build freestanding C++ runtime support]),,
1307     [enable_hosted_libstdcxx=yes])
1308   if test "$enable_hosted_libstdcxx" = no; then
1309     AC_MSG_NOTICE([Only freestanding libraries will be built])
1310     is_hosted=no
1311     hosted_define=0
1312     enable_abi_check=no
1313     enable_libstdcxx_pch=no
1314   else
1315     is_hosted=yes
1316     hosted_define=1
1317   fi
1318   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1319   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1320     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1321 ])
1322
1323
1324 dnl
1325 dnl Check for libunwind exception handling support.  If enabled, then
1326 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1327 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1328 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1329 dnl on libunwind as well as libgcc.
1330 dnl
1331 dnl --enable-libunwind-exceptions forces the use of libunwind.
1332 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1333 dnl
1334 dnl Substs:
1335 dnl  LIBUNWIND_FLAG
1336 dnl
1337 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1338   AC_MSG_CHECKING([for use of libunwind])
1339   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1340     [force use of libunwind for exceptions])
1341   AC_MSG_RESULT($use_libunwind_exceptions)
1342   if test $enable_libunwind_exceptions = yes; then
1343     LIBUNWIND_FLAG="-lunwind"
1344   else
1345     LIBUNWIND_FLAG=""
1346   fi
1347   AC_SUBST(LIBUNWIND_FLAG)
1348 ])
1349
1350
1351 dnl
1352 dnl Check for template specializations for the 'long long' type extension.
1353 dnl The result determines only whether 'long long' I/O is enabled; things
1354 dnl like numeric_limits<> specializations are always available.
1355 dnl
1356 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1357 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1358 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1359 dnl       Where DEFAULT is either `yes' or `no'.
1360 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1361 dnl
1362 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1363   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1364
1365   AC_LANG_SAVE
1366   AC_LANG_CPLUSPLUS
1367
1368   AC_MSG_CHECKING([for enabled long long I/O support])
1369   # iostreams require strtoll, strtoull to compile
1370   AC_TRY_COMPILE([#include <stdlib.h>],
1371                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1372   AC_TRY_COMPILE([#include <stdlib.h>],
1373                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1374
1375   # Option parsed, now set things appropriately
1376   if test $enable_long_long = yes; then
1377     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1378   fi
1379   AC_MSG_RESULT($enable_long_long)
1380
1381   AC_LANG_RESTORE
1382 ])
1383
1384
1385 dnl
1386 dnl Check to see if building and using a C++ precompiled header can be done.
1387 dnl
1388 dnl --enable-libstdcxx-pch=yes
1389 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1390 dnl may work, after some light-hearted attempts to puzzle out compiler
1391 dnl support, flip bits on in include/Makefile.am
1392 dnl
1393 dnl --disable-libstdcxx-pch
1394 dnl turns off attempts to use or build stdc++.h.gch.
1395 dnl
1396 dnl Substs:
1397 dnl  glibcxx_PCHFLAGS
1398 dnl
1399 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1400   AC_MSG_CHECKING([for enabled PCH])
1401   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1402   AC_MSG_RESULT([$enable_libstdcxx_pch])
1403
1404   if test $enable_libstdcxx_pch = yes; then
1405     AC_CACHE_CHECK([for compiler with PCH support],
1406       [glibcxx_cv_prog_CXX_pch],
1407       [ac_save_CXXFLAGS="$CXXFLAGS"
1408        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1409        AC_LANG_SAVE
1410        AC_LANG_CPLUSPLUS
1411        echo '#include <math.h>' > conftest.h
1412        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1413                           -o conftest.h.gch 1>&5 2>&1 &&
1414                 echo '#error "pch failed"' > conftest.h &&
1415           echo '#include "conftest.h"' > conftest.cc &&
1416                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1417        then
1418          glibcxx_cv_prog_CXX_pch=yes
1419        else
1420          glibcxx_cv_prog_CXX_pch=no
1421        fi
1422        rm -f conftest*
1423        CXXFLAGS=$ac_save_CXXFLAGS
1424        AC_LANG_RESTORE
1425       ])
1426     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1427   fi
1428
1429   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1430   if test $enable_libstdcxx_pch = yes; then
1431     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1432   else
1433     glibcxx_PCHFLAGS=""
1434   fi
1435   AC_SUBST(glibcxx_PCHFLAGS)
1436 ])
1437
1438
1439 dnl
1440 dnl Check for exception handling support.  If an explicit enable/disable
1441 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1442 dnl target may or may not support call frame exceptions.
1443 dnl
1444 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1445 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1446 dnl Neither one forces an attempt at detection.
1447 dnl
1448 dnl Defines:
1449 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1450 dnl
1451 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1452   AC_MSG_CHECKING([for exception model to use])
1453   AC_LANG_SAVE
1454   AC_LANG_CPLUSPLUS
1455   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1456     [force use of builtin_setjmp for exceptions],
1457     [permit yes|no|auto])
1458
1459   if test $enable_sjlj_exceptions = auto; then
1460     # Botheration.  Now we've got to detect the exception model.  Link tests
1461     # against libgcc.a are problematic since we've not been given proper -L
1462     # bits for single-tree newlib and libgloss.
1463     #
1464     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1465     cat > conftest.$ac_ext << EOF
1466 [#]line __oline__ "configure"
1467 struct S { ~S(); };
1468 void bar();
1469 void foo()
1470 {
1471   S s;
1472   bar();
1473 }
1474 EOF
1475     old_CXXFLAGS="$CXXFLAGS"
1476     CXXFLAGS=-S
1477     if AC_TRY_EVAL(ac_compile); then
1478       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1479         enable_sjlj_exceptions=yes
1480       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1481         enable_sjlj_exceptions=no
1482       fi
1483     fi
1484     CXXFLAGS="$old_CXXFLAGS"
1485     rm -f conftest*
1486   fi
1487
1488   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1489   # to two different models.
1490   case $enable_sjlj_exceptions in
1491     yes)
1492       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1493         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1494       ac_exception_model_name=sjlj
1495       ;;
1496     no)
1497       ac_exception_model_name="call frame"
1498       ;;
1499     *)
1500       AC_MSG_ERROR([unable to detect exception model])
1501       ;;
1502   esac
1503  AC_LANG_RESTORE
1504  AC_MSG_RESULT($ac_exception_model_name)
1505 ])
1506
1507
1508 dnl
1509 dnl Add version tags to symbols in shared library (or not), additionally
1510 dnl marking other symbols as private/local (or not).
1511 dnl
1512 dnl --enable-symvers=style adds a version script to the linker call when
1513 dnl       creating the shared library.  The choice of version script is
1514 dnl       controlled by 'style'.
1515 dnl --disable-symvers does not.
1516 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1517 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1518 dnl       choose a default style based on linker characteristics.  Passing
1519 dnl       'no' disables versioning.
1520 dnl
1521 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1522
1523 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1524   [enables symbol versioning of the shared library],
1525   [permit yes|no|gnu])
1526
1527 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1528 # don't know enough about $LD to do tricks...
1529 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1530 # FIXME  The following test is too strict, in theory.
1531 if test $enable_shared = no ||
1532         test "x$LD" = x ||
1533         test x$glibcxx_gnu_ld_version = x; then
1534   enable_symvers=no
1535 fi
1536
1537 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1538 if test $enable_symvers != no; then
1539   AC_MSG_CHECKING([for shared libgcc])
1540   ac_save_CFLAGS="$CFLAGS"
1541   CFLAGS=' -lgcc_s'
1542   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1543   CFLAGS="$ac_save_CFLAGS"
1544   AC_MSG_RESULT($glibcxx_shared_libgcc)
1545 fi
1546
1547 # For GNU ld, we need at least this version.  The format is described in
1548 # GLIBCXX_CHECK_LINKER_FEATURES above.
1549 glibcxx_min_gnu_ld_version=21400
1550 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1551
1552 # Check to see if unspecified "yes" value can win, given results above.
1553 # Change "yes" into either "no" or a style name.
1554 if test $enable_symvers = yes; then
1555   if test $with_gnu_ld = yes &&
1556      test $glibcxx_shared_libgcc = yes;
1557   then
1558     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1559       enable_symvers=gnu
1560     else
1561       # The right tools, the right setup, but too old.  Fallbacks?
1562       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1563       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1564       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1565       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1566       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1567         # Globbing fix is present, proper block support is not.
1568         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1569         dnl enable_symvers=???
1570         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1571         enable_symvers=no
1572       else
1573         # 2.11 or older.
1574         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1575         enable_symvers=no
1576       fi
1577     fi
1578   else
1579     # just fail for now
1580     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1581     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1582     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1583     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1584     enable_symvers=no
1585   fi
1586 fi
1587
1588 # Everything parsed; figure out what file to use.
1589 case $enable_symvers in
1590   no)
1591     SYMVER_MAP=config/linker-map.dummy
1592     ;;
1593   gnu)
1594     SYMVER_MAP=config/linker-map.gnu
1595     AC_DEFINE(_GLIBCXX_SYMVER)
1596     ;;
1597 esac
1598
1599 AC_SUBST(SYMVER_MAP)
1600 AC_SUBST(port_specific_symbol_files)
1601 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1602 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1603 ])
1604
1605
1606 dnl
1607 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1608 dnl We must stage the required headers so that they will be installed
1609 dnl with the library (unlike libgcc, the STL implementation is provided
1610 dnl solely within headers).  Since we must not inject random user-space
1611 dnl macro names into user-provided C++ code, we first stage into <file>-in
1612 dnl and process to <file> with an output command.  The reason for a two-
1613 dnl stage process here is to correctly handle $srcdir!=$objdir without
1614 dnl having to write complex code (the sed commands to clean the macro
1615 dnl namespace are complex and fragile enough as it is).  We must also
1616 dnl add a relative path so that -I- is supported properly.
1617 dnl
1618 dnl Substs:
1619 dnl  glibcxx_thread_h
1620 dnl
1621 dnl Defines:
1622 dnl  HAVE_GTHR_DEFAULT
1623 dnl  _GLIBCXX_SUPPORTS_WEAK
1624 dnl
1625 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1626   AC_MSG_CHECKING([for thread model used by GCC])
1627   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1628   AC_MSG_RESULT([$target_thread_file])
1629
1630   if test $target_thread_file != single; then
1631     AC_DEFINE(HAVE_GTHR_DEFAULT)
1632     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1633   fi
1634
1635   glibcxx_thread_h=gthr-$target_thread_file.h
1636   AC_SUBST(glibcxx_thread_h)
1637 ])
1638
1639
1640 # Check whether LC_MESSAGES is available in <locale.h>.
1641 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1642 #
1643 # This file file be copied and used freely without restrictions.  It can
1644 # be used in projects which are not available under the GNU Public License
1645 # but which still want to provide support for the GNU gettext functionality.
1646 # Please note that the actual code is *not* freely available.
1647
1648 # serial 1
1649 AC_DEFUN(AC_LC_MESSAGES, [
1650   AC_CHECK_HEADER(locale.h, [
1651     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1652       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1653        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1654     if test $ac_cv_val_LC_MESSAGES = yes; then
1655       AC_DEFINE(HAVE_LC_MESSAGES)
1656     fi
1657   ])
1658 ])
1659
1660
1661 sinclude([../libtool.m4])
1662 dnl The lines below arrange for aclocal not to bring an installed
1663 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1664 dnl add a definition of LIBTOOL to Makefile.in.
1665 ifelse(,,,[AC_SUBST(LIBTOOL)
1666 AC_DEFUN([AM_PROG_LIBTOOL])
1667 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1668 AC_DEFUN([AC_PROG_LD])
1669 ])
1670
1671 dnl vim:et:ts=2:sw=2
1672
1673 # AM_CONDITIONAL                                              -*- Autoconf -*-
1674
1675 # Copyright 1997, 2000, 2001 Free Software Foundation, Inc.
1676
1677 # This program is free software; you can redistribute it and/or modify
1678 # it under the terms of the GNU General Public License as published by
1679 # the Free Software Foundation; either version 2, or (at your option)
1680 # any later version.
1681
1682 # This program is distributed in the hope that it will be useful,
1683 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1684 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1685 # GNU General Public License for more details.
1686
1687 # You should have received a copy of the GNU General Public License
1688 # along with this program; if not, write to the Free Software
1689 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1690 # 02111-1307, USA.
1691
1692 # serial 5
1693
1694 AC_PREREQ(2.52)
1695
1696 # AM_CONDITIONAL(NAME, SHELL-CONDITION)
1697 # -------------------------------------
1698 # Define a conditional.
1699 AC_DEFUN([AM_CONDITIONAL],
1700 [ifelse([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
1701         [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
1702 AC_SUBST([$1_TRUE])
1703 AC_SUBST([$1_FALSE])
1704 if $2; then
1705   $1_TRUE=
1706   $1_FALSE='#'
1707 else
1708   $1_TRUE='#'
1709   $1_FALSE=
1710 fi
1711 AC_CONFIG_COMMANDS_PRE(
1712 [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
1713   AC_MSG_ERROR([conditional "$1" was never defined.
1714 Usually this means the macro was only invoked conditionally.])
1715 fi])])
1716
1717 # Copyright 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
1718
1719 # This program is free software; you can redistribute it and/or modify
1720 # it under the terms of the GNU General Public License as published by
1721 # the Free Software Foundation; either version 2, or (at your option)
1722 # any later version.
1723
1724 # This program is distributed in the hope that it will be useful,
1725 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1726 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1727 # GNU General Public License for more details.
1728
1729 # You should have received a copy of the GNU General Public License
1730 # along with this program; if not, write to the Free Software
1731 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1732 # 02111-1307, USA.
1733
1734 # serial 3
1735
1736 # AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
1737 # ---------------------------------------------------
1738 # Add --enable-multilib to configure.
1739 AC_DEFUN([AM_ENABLE_MULTILIB],
1740 [# Default to --enable-multilib
1741 AC_ARG_ENABLE(multilib,
1742 [  --enable-multilib         build many library versions (default)],
1743 [case "$enableval" in
1744   yes) multilib=yes ;;
1745   no)  multilib=no ;;
1746   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
1747  esac],
1748               [multilib=yes])
1749
1750 # We may get other options which we leave undocumented:
1751 # --with-target-subdir, --with-multisrctop, --with-multisubdir
1752 # See config-ml.in if you want the gory details.
1753
1754 if test "$srcdir" = "."; then
1755   if test "$with_target_subdir" != "."; then
1756     multi_basedir="$srcdir/$with_multisrctop../$2"
1757   else
1758     multi_basedir="$srcdir/$with_multisrctop$2"
1759   fi
1760 else
1761   multi_basedir="$srcdir/$2"
1762 fi
1763 AC_SUBST(multi_basedir)
1764
1765 AC_OUTPUT_COMMANDS([
1766 # Only add multilib support code if we just rebuilt the top-level
1767 # Makefile.
1768 case " $CONFIG_FILES " in
1769  *" ]m4_default([$1],Makefile)[ "*)
1770    ac_file=]m4_default([$1],Makefile)[ . ${multi_basedir}/config-ml.in
1771    ;;
1772 esac],
1773                    [
1774 srcdir="$srcdir"
1775 host="$host"
1776 target="$target"
1777 with_multisubdir="$with_multisubdir"
1778 with_multisrctop="$with_multisrctop"
1779 with_target_subdir="$with_target_subdir"
1780 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1781 multi_basedir="$multi_basedir"
1782 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1783 CC="$CC"])])dnl
1784
1785 # Add --enable-maintainer-mode option to configure.
1786 # From Jim Meyering
1787
1788 # Copyright 1996, 1998, 2000, 2001, 2002  Free Software Foundation, Inc.
1789
1790 # This program is free software; you can redistribute it and/or modify
1791 # it under the terms of the GNU General Public License as published by
1792 # the Free Software Foundation; either version 2, or (at your option)
1793 # any later version.
1794
1795 # This program is distributed in the hope that it will be useful,
1796 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1797 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1798 # GNU General Public License for more details.
1799
1800 # You should have received a copy of the GNU General Public License
1801 # along with this program; if not, write to the Free Software
1802 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1803 # 02111-1307, USA.
1804
1805 # serial 2
1806
1807 AC_DEFUN([AM_MAINTAINER_MODE],
1808 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1809   dnl maintainer-mode is disabled by default
1810   AC_ARG_ENABLE(maintainer-mode,
1811 [  --enable-maintainer-mode enable make rules and dependencies not useful
1812                           (and sometimes confusing) to the casual installer],
1813       USE_MAINTAINER_MODE=$enableval,
1814       USE_MAINTAINER_MODE=no)
1815   AC_MSG_RESULT([$USE_MAINTAINER_MODE])
1816   AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
1817   MAINT=$MAINTAINER_MODE_TRUE
1818   AC_SUBST(MAINT)dnl
1819 ]
1820 )
1821
1822 AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
1823
1824 # Do all the work for Automake.                            -*- Autoconf -*-
1825
1826 # This macro actually does too much some checks are only needed if
1827 # your package does certain things.  But this isn't really a big deal.
1828
1829 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
1830 # Free Software Foundation, Inc.
1831
1832 # This program is free software; you can redistribute it and/or modify
1833 # it under the terms of the GNU General Public License as published by
1834 # the Free Software Foundation; either version 2, or (at your option)
1835 # any later version.
1836
1837 # This program is distributed in the hope that it will be useful,
1838 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1839 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1840 # GNU General Public License for more details.
1841
1842 # You should have received a copy of the GNU General Public License
1843 # along with this program; if not, write to the Free Software
1844 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1845 # 02111-1307, USA.
1846
1847 # serial 10
1848
1849 AC_PREREQ([2.54])
1850
1851 # Autoconf 2.50 wants to disallow AM_ names.  We explicitly allow
1852 # the ones we care about.
1853 m4_pattern_allow([^AM_[A-Z]+FLAGS$])dnl
1854
1855 # AM_INIT_AUTOMAKE(PACKAGE, VERSION, [NO-DEFINE])
1856 # AM_INIT_AUTOMAKE([OPTIONS])
1857 # -----------------------------------------------
1858 # The call with PACKAGE and VERSION arguments is the old style
1859 # call (pre autoconf-2.50), which is being phased out.  PACKAGE
1860 # and VERSION should now be passed to AC_INIT and removed from
1861 # the call to AM_INIT_AUTOMAKE.
1862 # We support both call styles for the transition.  After
1863 # the next Automake release, Autoconf can make the AC_INIT
1864 # arguments mandatory, and then we can depend on a new Autoconf
1865 # release and drop the old call support.
1866 AC_DEFUN([AM_INIT_AUTOMAKE],
1867 [AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
1868  AC_REQUIRE([AC_PROG_INSTALL])dnl
1869 # test to see if srcdir already configured
1870 if test "`cd $srcdir && pwd`" != "`pwd`" &&
1871    test -f $srcdir/config.status; then
1872   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
1873 fi
1874
1875 # test whether we have cygpath
1876 if test -z "$CYGPATH_W"; then
1877   if (cygpath --version) >/dev/null 2>/dev/null; then
1878     CYGPATH_W='cygpath -w'
1879   else
1880     CYGPATH_W=echo
1881   fi
1882 fi
1883 AC_SUBST([CYGPATH_W])
1884
1885 # Define the identity of the package.
1886 dnl Distinguish between old-style and new-style calls.
1887 m4_ifval([$2],
1888 [m4_ifval([$3], [_AM_SET_OPTION([no-define])])dnl
1889  AC_SUBST([PACKAGE], [$1])dnl
1890  AC_SUBST([VERSION], [$2])],
1891 [_AM_SET_OPTIONS([$1])dnl
1892  AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
1893  AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
1894
1895 _AM_IF_OPTION([no-define],,
1896 [AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
1897  AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])dnl
1898
1899 # Some tools Automake needs.
1900 AC_REQUIRE([AM_SANITY_CHECK])dnl
1901 AC_REQUIRE([AC_ARG_PROGRAM])dnl
1902 AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version})
1903 AM_MISSING_PROG(AUTOCONF, autoconf)
1904 AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version})
1905 AM_MISSING_PROG(AUTOHEADER, autoheader)
1906 AM_MISSING_PROG(MAKEINFO, makeinfo)
1907 AM_MISSING_PROG(AMTAR, tar)
1908 AM_PROG_INSTALL_SH
1909 AM_PROG_INSTALL_STRIP
1910 # We need awk for the "check" target.  The system "awk" is bad on
1911 # some platforms.
1912 AC_REQUIRE([AC_PROG_AWK])dnl
1913 AC_REQUIRE([AC_PROG_MAKE_SET])dnl
1914 AC_REQUIRE([AM_SET_LEADING_DOT])dnl
1915
1916 _AM_IF_OPTION([no-dependencies],,
1917 [AC_PROVIDE_IFELSE([AC_PROG_CC],
1918                   [_AM_DEPENDENCIES(CC)],
1919                   [define([AC_PROG_CC],
1920                           defn([AC_PROG_CC])[_AM_DEPENDENCIES(CC)])])dnl
1921 AC_PROVIDE_IFELSE([AC_PROG_CXX],
1922                   [_AM_DEPENDENCIES(CXX)],
1923                   [define([AC_PROG_CXX],
1924                           defn([AC_PROG_CXX])[_AM_DEPENDENCIES(CXX)])])dnl
1925 ])
1926 ])
1927
1928
1929 # When config.status generates a header, we must update the stamp-h file.
1930 # This file resides in the same directory as the config header
1931 # that is generated.  The stamp files are numbered to have different names.
1932
1933 # Autoconf calls _AC_AM_CONFIG_HEADER_HOOK (when defined) in the
1934 # loop where config.status creates the headers, so we can generate
1935 # our stamp files there.
1936 AC_DEFUN([_AC_AM_CONFIG_HEADER_HOOK],
1937 [# Compute $1's index in $config_headers.
1938 _am_stamp_count=1
1939 for _am_header in $config_headers :; do
1940   case $_am_header in
1941     $1 | $1:* )
1942       break ;;
1943     * )
1944       _am_stamp_count=`expr $_am_stamp_count + 1` ;;
1945   esac
1946 done
1947 echo "timestamp for $1" >`AS_DIRNAME([$1])`/stamp-h[]$_am_stamp_count])
1948
1949 # Copyright 2002  Free Software Foundation, Inc.
1950
1951 # This program is free software; you can redistribute it and/or modify
1952 # it under the terms of the GNU General Public License as published by
1953 # the Free Software Foundation; either version 2, or (at your option)
1954 # any later version.
1955
1956 # This program is distributed in the hope that it will be useful,
1957 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1958 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1959 # GNU General Public License for more details.
1960
1961 # You should have received a copy of the GNU General Public License
1962 # along with this program; if not, write to the Free Software
1963 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1964
1965 # AM_AUTOMAKE_VERSION(VERSION)
1966 # ----------------------------
1967 # Automake X.Y traces this macro to ensure aclocal.m4 has been
1968 # generated from the m4 files accompanying Automake X.Y.
1969 AC_DEFUN([AM_AUTOMAKE_VERSION],[am__api_version="1.7"])
1970
1971 # AM_SET_CURRENT_AUTOMAKE_VERSION
1972 # -------------------------------
1973 # Call AM_AUTOMAKE_VERSION so it can be traced.
1974 # This function is AC_REQUIREd by AC_INIT_AUTOMAKE.
1975 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
1976          [AM_AUTOMAKE_VERSION([1.7.6])])
1977
1978 # Helper functions for option handling.                    -*- Autoconf -*-
1979
1980 # Copyright 2001, 2002  Free Software Foundation, Inc.
1981
1982 # This program is free software; you can redistribute it and/or modify
1983 # it under the terms of the GNU General Public License as published by
1984 # the Free Software Foundation; either version 2, or (at your option)
1985 # any later version.
1986
1987 # This program is distributed in the hope that it will be useful,
1988 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1989 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1990 # GNU General Public License for more details.
1991
1992 # You should have received a copy of the GNU General Public License
1993 # along with this program; if not, write to the Free Software
1994 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1995 # 02111-1307, USA.
1996
1997 # serial 2
1998
1999 # _AM_MANGLE_OPTION(NAME)
2000 # -----------------------
2001 AC_DEFUN([_AM_MANGLE_OPTION],
2002 [[_AM_OPTION_]m4_bpatsubst($1, [[^a-zA-Z0-9_]], [_])])
2003
2004 # _AM_SET_OPTION(NAME)
2005 # ------------------------------
2006 # Set option NAME.  Presently that only means defining a flag for this option.
2007 AC_DEFUN([_AM_SET_OPTION],
2008 [m4_define(_AM_MANGLE_OPTION([$1]), 1)])
2009
2010 # _AM_SET_OPTIONS(OPTIONS)
2011 # ----------------------------------
2012 # OPTIONS is a space-separated list of Automake options.
2013 AC_DEFUN([_AM_SET_OPTIONS],
2014 [AC_FOREACH([_AM_Option], [$1], [_AM_SET_OPTION(_AM_Option)])])
2015
2016 # _AM_IF_OPTION(OPTION, IF-SET, [IF-NOT-SET])
2017 # -------------------------------------------
2018 # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
2019 AC_DEFUN([_AM_IF_OPTION],
2020 [m4_ifset(_AM_MANGLE_OPTION([$1]), [$2], [$3])])
2021
2022 #
2023 # Check to make sure that the build environment is sane.
2024 #
2025
2026 # Copyright 1996, 1997, 2000, 2001 Free Software Foundation, Inc.
2027
2028 # This program is free software; you can redistribute it and/or modify
2029 # it under the terms of the GNU General Public License as published by
2030 # the Free Software Foundation; either version 2, or (at your option)
2031 # any later version.
2032
2033 # This program is distributed in the hope that it will be useful,
2034 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2035 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2036 # GNU General Public License for more details.
2037
2038 # You should have received a copy of the GNU General Public License
2039 # along with this program; if not, write to the Free Software
2040 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2041 # 02111-1307, USA.
2042
2043 # serial 3
2044
2045 # AM_SANITY_CHECK
2046 # ---------------
2047 AC_DEFUN([AM_SANITY_CHECK],
2048 [AC_MSG_CHECKING([whether build environment is sane])
2049 # Just in case
2050 sleep 1
2051 echo timestamp > conftest.file
2052 # Do `set' in a subshell so we don't clobber the current shell's
2053 # arguments.  Must try -L first in case configure is actually a
2054 # symlink; some systems play weird games with the mod time of symlinks
2055 # (eg FreeBSD returns the mod time of the symlink's containing
2056 # directory).
2057 if (
2058    set X `ls -Lt $srcdir/configure conftest.file 2> /dev/null`
2059    if test "$[*]" = "X"; then
2060       # -L didn't work.
2061       set X `ls -t $srcdir/configure conftest.file`
2062    fi
2063    rm -f conftest.file
2064    if test "$[*]" != "X $srcdir/configure conftest.file" \
2065       && test "$[*]" != "X conftest.file $srcdir/configure"; then
2066
2067       # If neither matched, then we have a broken ls.  This can happen
2068       # if, for instance, CONFIG_SHELL is bash and it inherits a
2069       # broken ls alias from the environment.  This has actually
2070       # happened.  Such a system could not be considered "sane".
2071       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2072 alias in your environment])
2073    fi
2074
2075    test "$[2]" = conftest.file
2076    )
2077 then
2078    # Ok.
2079    :
2080 else
2081    AC_MSG_ERROR([newly created file is older than distributed files!
2082 Check your system clock])
2083 fi
2084 AC_MSG_RESULT(yes)])
2085
2086 #  -*- Autoconf -*-
2087
2088
2089 # Copyright 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
2090
2091 # This program is free software; you can redistribute it and/or modify
2092 # it under the terms of the GNU General Public License as published by
2093 # the Free Software Foundation; either version 2, or (at your option)
2094 # any later version.
2095
2096 # This program is distributed in the hope that it will be useful,
2097 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2098 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2099 # GNU General Public License for more details.
2100
2101 # You should have received a copy of the GNU General Public License
2102 # along with this program; if not, write to the Free Software
2103 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2104 # 02111-1307, USA.
2105
2106 # serial 3
2107
2108 # AM_MISSING_PROG(NAME, PROGRAM)
2109 # ------------------------------
2110 AC_DEFUN([AM_MISSING_PROG],
2111 [AC_REQUIRE([AM_MISSING_HAS_RUN])
2112 $1=${$1-"${am_missing_run}$2"}
2113 AC_SUBST($1)])
2114
2115
2116 # AM_MISSING_HAS_RUN
2117 # ------------------
2118 # Define MISSING if not defined so far and test if it supports --run.
2119 # If it does, set am_missing_run to use it, otherwise, to nothing.
2120 AC_DEFUN([AM_MISSING_HAS_RUN],
2121 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
2122 test x"${MISSING+set}" = xset || MISSING="\${SHELL} $am_aux_dir/missing"
2123 # Use eval to expand $SHELL
2124 if eval "$MISSING --run true"; then
2125   am_missing_run="$MISSING --run "
2126 else
2127   am_missing_run=
2128   AC_MSG_WARN([`missing' script is too old or missing])
2129 fi
2130 ])
2131
2132 # AM_AUX_DIR_EXPAND
2133
2134 # Copyright 2001 Free Software Foundation, Inc.
2135
2136 # This program is free software; you can redistribute it and/or modify
2137 # it under the terms of the GNU General Public License as published by
2138 # the Free Software Foundation; either version 2, or (at your option)
2139 # any later version.
2140
2141 # This program is distributed in the hope that it will be useful,
2142 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2143 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2144 # GNU General Public License for more details.
2145
2146 # You should have received a copy of the GNU General Public License
2147 # along with this program; if not, write to the Free Software
2148 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2149 # 02111-1307, USA.
2150
2151 # For projects using AC_CONFIG_AUX_DIR([foo]), Autoconf sets
2152 # $ac_aux_dir to `$srcdir/foo'.  In other projects, it is set to
2153 # `$srcdir', `$srcdir/..', or `$srcdir/../..'.
2154 #
2155 # Of course, Automake must honor this variable whenever it calls a
2156 # tool from the auxiliary directory.  The problem is that $srcdir (and
2157 # therefore $ac_aux_dir as well) can be either absolute or relative,
2158 # depending on how configure is run.  This is pretty annoying, since
2159 # it makes $ac_aux_dir quite unusable in subdirectories: in the top
2160 # source directory, any form will work fine, but in subdirectories a
2161 # relative path needs to be adjusted first.
2162 #
2163 # $ac_aux_dir/missing
2164 #    fails when called from a subdirectory if $ac_aux_dir is relative
2165 # $top_srcdir/$ac_aux_dir/missing
2166 #    fails if $ac_aux_dir is absolute,
2167 #    fails when called from a subdirectory in a VPATH build with
2168 #          a relative $ac_aux_dir
2169 #
2170 # The reason of the latter failure is that $top_srcdir and $ac_aux_dir
2171 # are both prefixed by $srcdir.  In an in-source build this is usually
2172 # harmless because $srcdir is `.', but things will broke when you
2173 # start a VPATH build or use an absolute $srcdir.
2174 #
2175 # So we could use something similar to $top_srcdir/$ac_aux_dir/missing,
2176 # iff we strip the leading $srcdir from $ac_aux_dir.  That would be:
2177 #   am_aux_dir='\$(top_srcdir)/'`expr "$ac_aux_dir" : "$srcdir//*\(.*\)"`
2178 # and then we would define $MISSING as
2179 #   MISSING="\${SHELL} $am_aux_dir/missing"
2180 # This will work as long as MISSING is not called from configure, because
2181 # unfortunately $(top_srcdir) has no meaning in configure.
2182 # However there are other variables, like CC, which are often used in
2183 # configure, and could therefore not use this "fixed" $ac_aux_dir.
2184 #
2185 # Another solution, used here, is to always expand $ac_aux_dir to an
2186 # absolute PATH.  The drawback is that using absolute paths prevent a
2187 # configured tree to be moved without reconfiguration.
2188
2189 # Rely on autoconf to set up CDPATH properly.
2190 AC_PREREQ([2.50])
2191
2192 AC_DEFUN([AM_AUX_DIR_EXPAND], [
2193 # expand $ac_aux_dir to an absolute path
2194 am_aux_dir=`cd $ac_aux_dir && pwd`
2195 ])
2196
2197 # AM_PROG_INSTALL_SH
2198 # ------------------
2199 # Define $install_sh.
2200
2201 # Copyright 2001 Free Software Foundation, Inc.
2202
2203 # This program is free software; you can redistribute it and/or modify
2204 # it under the terms of the GNU General Public License as published by
2205 # the Free Software Foundation; either version 2, or (at your option)
2206 # any later version.
2207
2208 # This program is distributed in the hope that it will be useful,
2209 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2210 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2211 # GNU General Public License for more details.
2212
2213 # You should have received a copy of the GNU General Public License
2214 # along with this program; if not, write to the Free Software
2215 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2216 # 02111-1307, USA.
2217
2218 AC_DEFUN([AM_PROG_INSTALL_SH],
2219 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
2220 install_sh=${install_sh-"$am_aux_dir/install-sh"}
2221 AC_SUBST(install_sh)])
2222
2223 # AM_PROG_INSTALL_STRIP
2224
2225 # Copyright 2001 Free Software Foundation, Inc.
2226
2227 # This program is free software; you can redistribute it and/or modify
2228 # it under the terms of the GNU General Public License as published by
2229 # the Free Software Foundation; either version 2, or (at your option)
2230 # any later version.
2231
2232 # This program is distributed in the hope that it will be useful,
2233 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2234 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2235 # GNU General Public License for more details.
2236
2237 # You should have received a copy of the GNU General Public License
2238 # along with this program; if not, write to the Free Software
2239 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2240 # 02111-1307, USA.
2241
2242 # One issue with vendor `install' (even GNU) is that you can't
2243 # specify the program used to strip binaries.  This is especially
2244 # annoying in cross-compiling environments, where the build's strip
2245 # is unlikely to handle the host's binaries.
2246 # Fortunately install-sh will honor a STRIPPROG variable, so we
2247 # always use install-sh in `make install-strip', and initialize
2248 # STRIPPROG with the value of the STRIP variable (set by the user).
2249 AC_DEFUN([AM_PROG_INSTALL_STRIP],
2250 [AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
2251 # Installed binaries are usually stripped using `strip' when the user
2252 # run `make install-strip'.  However `strip' might not be the right
2253 # tool to use in cross-compilation environments, therefore Automake
2254 # will honor the `STRIP' environment variable to overrule this program.
2255 dnl Don't test for $cross_compiling = yes, because it might be `maybe'.
2256 if test "$cross_compiling" != no; then
2257   AC_CHECK_TOOL([STRIP], [strip], :)
2258 fi
2259 INSTALL_STRIP_PROGRAM="\${SHELL} \$(install_sh) -c -s"
2260 AC_SUBST([INSTALL_STRIP_PROGRAM])])
2261
2262 #                                                          -*- Autoconf -*-
2263 # Copyright (C) 2003  Free Software Foundation, Inc.
2264
2265 # This program is free software; you can redistribute it and/or modify
2266 # it under the terms of the GNU General Public License as published by
2267 # the Free Software Foundation; either version 2, or (at your option)
2268 # any later version.
2269
2270 # This program is distributed in the hope that it will be useful,
2271 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2272 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2273 # GNU General Public License for more details.
2274
2275 # You should have received a copy of the GNU General Public License
2276 # along with this program; if not, write to the Free Software
2277 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2278 # 02111-1307, USA.
2279
2280 # serial 1
2281
2282 # Check whether the underlying file-system supports filenames
2283 # with a leading dot.  For instance MS-DOS doesn't.
2284 AC_DEFUN([AM_SET_LEADING_DOT],
2285 [rm -rf .tst 2>/dev/null
2286 mkdir .tst 2>/dev/null
2287 if test -d .tst; then
2288   am__leading_dot=.
2289 else
2290   am__leading_dot=_
2291 fi
2292 rmdir .tst 2>/dev/null
2293 AC_SUBST([am__leading_dot])])
2294
2295 # serial 5                                              -*- Autoconf -*-
2296
2297 # Copyright (C) 1999, 2000, 2001, 2002, 2003  Free Software Foundation, Inc.
2298
2299 # This program is free software; you can redistribute it and/or modify
2300 # it under the terms of the GNU General Public License as published by
2301 # the Free Software Foundation; either version 2, or (at your option)
2302 # any later version.
2303
2304 # This program is distributed in the hope that it will be useful,
2305 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2306 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2307 # GNU General Public License for more details.
2308
2309 # You should have received a copy of the GNU General Public License
2310 # along with this program; if not, write to the Free Software
2311 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2312 # 02111-1307, USA.
2313
2314
2315 # There are a few dirty hacks below to avoid letting `AC_PROG_CC' be
2316 # written in clear, in which case automake, when reading aclocal.m4,
2317 # will think it sees a *use*, and therefore will trigger all it's
2318 # C support machinery.  Also note that it means that autoscan, seeing
2319 # CC etc. in the Makefile, will ask for an AC_PROG_CC use...
2320
2321
2322
2323 # _AM_DEPENDENCIES(NAME)
2324 # ----------------------
2325 # See how the compiler implements dependency checking.
2326 # NAME is "CC", "CXX", "GCJ", or "OBJC".
2327 # We try a few techniques and use that to set a single cache variable.
2328 #
2329 # We don't AC_REQUIRE the corresponding AC_PROG_CC since the latter was
2330 # modified to invoke _AM_DEPENDENCIES(CC); we would have a circular
2331 # dependency, and given that the user is not expected to run this macro,
2332 # just rely on AC_PROG_CC.
2333 AC_DEFUN([_AM_DEPENDENCIES],
2334 [AC_REQUIRE([AM_SET_DEPDIR])dnl
2335 AC_REQUIRE([AM_OUTPUT_DEPENDENCY_COMMANDS])dnl
2336 AC_REQUIRE([AM_MAKE_INCLUDE])dnl
2337 AC_REQUIRE([AM_DEP_TRACK])dnl
2338
2339 ifelse([$1], CC,   [depcc="$CC"   am_compiler_list=],
2340        [$1], CXX,  [depcc="$CXX"  am_compiler_list=],
2341        [$1], OBJC, [depcc="$OBJC" am_compiler_list='gcc3 gcc'],
2342        [$1], GCJ,  [depcc="$GCJ"  am_compiler_list='gcc3 gcc'],
2343                    [depcc="$$1"   am_compiler_list=])
2344
2345 AC_CACHE_CHECK([dependency style of $depcc],
2346                [am_cv_$1_dependencies_compiler_type],
2347 [if test -z "$AMDEP_TRUE" && test -f "$am_depcomp"; then
2348   # We make a subdir and do the tests there.  Otherwise we can end up
2349   # making bogus files that we don't know about and never remove.  For
2350   # instance it was reported that on HP-UX the gcc test will end up
2351   # making a dummy file named `D' -- because `-MD' means `put the output
2352   # in D'.
2353   mkdir conftest.dir
2354   # Copy depcomp to subdir because otherwise we won't find it if we're
2355   # using a relative directory.
2356   cp "$am_depcomp" conftest.dir
2357   cd conftest.dir
2358   # We will build objects and dependencies in a subdirectory because
2359   # it helps to detect inapplicable dependency modes.  For instance
2360   # both Tru64's cc and ICC support -MD to output dependencies as a
2361   # side effect of compilation, but ICC will put the dependencies in
2362   # the current directory while Tru64 will put them in the object
2363   # directory.
2364   mkdir sub
2365
2366   am_cv_$1_dependencies_compiler_type=none
2367   if test "$am_compiler_list" = ""; then
2368      am_compiler_list=`sed -n ['s/^#*\([a-zA-Z0-9]*\))$/\1/p'] < ./depcomp`
2369   fi
2370   for depmode in $am_compiler_list; do
2371     # Setup a source with many dependencies, because some compilers
2372     # like to wrap large dependency lists on column 80 (with \), and
2373     # we should not choose a depcomp mode which is confused by this.
2374     #
2375     # We need to recreate these files for each test, as the compiler may
2376     # overwrite some of them when testing with obscure command lines.
2377     # This happens at least with the AIX C compiler.
2378     : > sub/conftest.c
2379     for i in 1 2 3 4 5 6; do
2380       echo '#include "conftst'$i'.h"' >> sub/conftest.c
2381       : > sub/conftst$i.h
2382     done
2383     echo "${am__include} ${am__quote}sub/conftest.Po${am__quote}" > confmf
2384
2385     case $depmode in
2386     nosideeffect)
2387       # after this tag, mechanisms are not by side-effect, so they'll
2388       # only be used when explicitly requested
2389       if test "x$enable_dependency_tracking" = xyes; then
2390         continue
2391       else
2392         break
2393       fi
2394       ;;
2395     none) break ;;
2396     esac
2397     # We check with `-c' and `-o' for the sake of the "dashmstdout"
2398     # mode.  It turns out that the SunPro C++ compiler does not properly
2399     # handle `-M -o', and we need to detect this.
2400     if depmode=$depmode \
2401        source=sub/conftest.c object=sub/conftest.${OBJEXT-o} \
2402        depfile=sub/conftest.Po tmpdepfile=sub/conftest.TPo \
2403        $SHELL ./depcomp $depcc -c -o sub/conftest.${OBJEXT-o} sub/conftest.c \
2404          >/dev/null 2>conftest.err &&
2405        grep sub/conftst6.h sub/conftest.Po > /dev/null 2>&1 &&
2406        grep sub/conftest.${OBJEXT-o} sub/conftest.Po > /dev/null 2>&1 &&
2407        ${MAKE-make} -s -f confmf > /dev/null 2>&1; then
2408       # icc doesn't choke on unknown options, it will just issue warnings
2409       # (even with -Werror).  So we grep stderr for any message
2410       # that says an option was ignored.
2411       if grep 'ignoring option' conftest.err >/dev/null 2>&1; then :; else
2412         am_cv_$1_dependencies_compiler_type=$depmode
2413         break
2414       fi
2415     fi
2416   done
2417
2418   cd ..
2419   rm -rf conftest.dir
2420 else
2421   am_cv_$1_dependencies_compiler_type=none
2422 fi
2423 ])
2424 AC_SUBST([$1DEPMODE], [depmode=$am_cv_$1_dependencies_compiler_type])
2425 AM_CONDITIONAL([am__fastdep$1], [
2426   test "x$enable_dependency_tracking" != xno \
2427   && test "$am_cv_$1_dependencies_compiler_type" = gcc3])
2428 ])
2429
2430
2431 # AM_SET_DEPDIR
2432 # -------------
2433 # Choose a directory name for dependency files.
2434 # This macro is AC_REQUIREd in _AM_DEPENDENCIES
2435 AC_DEFUN([AM_SET_DEPDIR],
2436 [AC_REQUIRE([AM_SET_LEADING_DOT])dnl
2437 AC_SUBST([DEPDIR], ["${am__leading_dot}deps"])dnl
2438 ])
2439
2440
2441 # AM_DEP_TRACK
2442 # ------------
2443 AC_DEFUN([AM_DEP_TRACK],
2444 [AC_ARG_ENABLE(dependency-tracking,
2445 [  --disable-dependency-tracking Speeds up one-time builds
2446   --enable-dependency-tracking  Do not reject slow dependency extractors])
2447 if test "x$enable_dependency_tracking" != xno; then
2448   am_depcomp="$ac_aux_dir/depcomp"
2449   AMDEPBACKSLASH='\'
2450 fi
2451 AM_CONDITIONAL([AMDEP], [test "x$enable_dependency_tracking" != xno])
2452 AC_SUBST([AMDEPBACKSLASH])
2453 ])
2454
2455 # Generate code to set up dependency tracking.   -*- Autoconf -*-
2456
2457 # Copyright 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
2458
2459 # This program is free software; you can redistribute it and/or modify
2460 # it under the terms of the GNU General Public License as published by
2461 # the Free Software Foundation; either version 2, or (at your option)
2462 # any later version.
2463
2464 # This program is distributed in the hope that it will be useful,
2465 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2466 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2467 # GNU General Public License for more details.
2468
2469 # You should have received a copy of the GNU General Public License
2470 # along with this program; if not, write to the Free Software
2471 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2472 # 02111-1307, USA.
2473
2474 #serial 2
2475
2476 # _AM_OUTPUT_DEPENDENCY_COMMANDS
2477 # ------------------------------
2478 AC_DEFUN([_AM_OUTPUT_DEPENDENCY_COMMANDS],
2479 [for mf in $CONFIG_FILES; do
2480   # Strip MF so we end up with the name of the file.
2481   mf=`echo "$mf" | sed -e 's/:.*$//'`
2482   # Check whether this is an Automake generated Makefile or not.
2483   # We used to match only the files named `Makefile.in', but
2484   # some people rename them; so instead we look at the file content.
2485   # Grep'ing the first line is not enough: some people post-process
2486   # each Makefile.in and add a new line on top of each file to say so.
2487   # So let's grep whole file.
2488   if grep '^#.*generated by automake' $mf > /dev/null 2>&1; then
2489     dirpart=`AS_DIRNAME("$mf")`
2490   else
2491     continue
2492   fi
2493   grep '^DEP_FILES *= *[[^ @%:@]]' < "$mf" > /dev/null || continue
2494   # Extract the definition of DEP_FILES from the Makefile without
2495   # running `make'.
2496   DEPDIR=`sed -n -e '/^DEPDIR = / s///p' < "$mf"`
2497   test -z "$DEPDIR" && continue
2498   # When using ansi2knr, U may be empty or an underscore; expand it
2499   U=`sed -n -e '/^U = / s///p' < "$mf"`
2500   test -d "$dirpart/$DEPDIR" || mkdir "$dirpart/$DEPDIR"
2501   # We invoke sed twice because it is the simplest approach to
2502   # changing $(DEPDIR) to its actual value in the expansion.
2503   for file in `sed -n -e '
2504     /^DEP_FILES = .*\\\\$/ {
2505       s/^DEP_FILES = //
2506       :loop
2507         s/\\\\$//
2508         p
2509         n
2510         /\\\\$/ b loop
2511       p
2512     }
2513     /^DEP_FILES = / s/^DEP_FILES = //p' < "$mf" | \
2514        sed -e 's/\$(DEPDIR)/'"$DEPDIR"'/g' -e 's/\$U/'"$U"'/g'`; do
2515     # Make sure the directory exists.
2516     test -f "$dirpart/$file" && continue
2517     fdir=`AS_DIRNAME(["$file"])`
2518     AS_MKDIR_P([$dirpart/$fdir])
2519     # echo "creating $dirpart/$file"
2520     echo '# dummy' > "$dirpart/$file"
2521   done
2522 done
2523 ])# _AM_OUTPUT_DEPENDENCY_COMMANDS
2524
2525
2526 # AM_OUTPUT_DEPENDENCY_COMMANDS
2527 # -----------------------------
2528 # This macro should only be invoked once -- use via AC_REQUIRE.
2529 #
2530 # This code is only required when automatic dependency tracking
2531 # is enabled.  FIXME.  This creates each `.P' file that we will
2532 # need in order to bootstrap the dependency handling code.
2533 AC_DEFUN([AM_OUTPUT_DEPENDENCY_COMMANDS],
2534 [AC_CONFIG_COMMANDS([depfiles],
2535      [test x"$AMDEP_TRUE" != x"" || _AM_OUTPUT_DEPENDENCY_COMMANDS],
2536      [AMDEP_TRUE="$AMDEP_TRUE" ac_aux_dir="$ac_aux_dir"])
2537 ])
2538
2539 # Check to see how 'make' treats includes.      -*- Autoconf -*-
2540
2541 # Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
2542
2543 # This program is free software; you can redistribute it and/or modify
2544 # it under the terms of the GNU General Public License as published by
2545 # the Free Software Foundation; either version 2, or (at your option)
2546 # any later version.
2547
2548 # This program is distributed in the hope that it will be useful,
2549 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2550 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2551 # GNU General Public License for more details.
2552
2553 # You should have received a copy of the GNU General Public License
2554 # along with this program; if not, write to the Free Software
2555 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2556 # 02111-1307, USA.
2557
2558 # serial 2
2559
2560 # AM_MAKE_INCLUDE()
2561 # -----------------
2562 # Check to see how make treats includes.
2563 AC_DEFUN([AM_MAKE_INCLUDE],
2564 [am_make=${MAKE-make}
2565 cat > confinc << 'END'
2566 am__doit:
2567         @echo done
2568 .PHONY: am__doit
2569 END
2570 # If we don't find an include directive, just comment out the code.
2571 AC_MSG_CHECKING([for style of include used by $am_make])
2572 am__include="#"
2573 am__quote=
2574 _am_result=none
2575 # First try GNU make style include.
2576 echo "include confinc" > confmf
2577 # We grep out `Entering directory' and `Leaving directory'
2578 # messages which can occur if `w' ends up in MAKEFLAGS.
2579 # In particular we don't look at `^make:' because GNU make might
2580 # be invoked under some other name (usually "gmake"), in which
2581 # case it prints its new name instead of `make'.
2582 if test "`$am_make -s -f confmf 2> /dev/null | grep -v 'ing directory'`" = "done"; then
2583    am__include=include
2584    am__quote=
2585    _am_result=GNU
2586 fi
2587 # Now try BSD make style include.
2588 if test "$am__include" = "#"; then
2589    echo '.include "confinc"' > confmf
2590    if test "`$am_make -s -f confmf 2> /dev/null`" = "done"; then
2591       am__include=.include
2592       am__quote="\""
2593       _am_result=BSD
2594    fi
2595 fi
2596 AC_SUBST([am__include])
2597 AC_SUBST([am__quote])
2598 AC_MSG_RESULT([$_am_result])
2599 rm -f confinc confmf
2600 ])
2601