libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Find platform-specific directories containing configuration info.
 129   # Also possibly modify flags used elsewhere, as needed by the platform.
 130   GLIBCXX_CHECK_HOST
 131 ])
 132
 133
 134 dnl
 135 dnl Tests for newer compiler features, or features that are present in newer
 136 dnl compiler versions but not older compiler versions still in use, should
 137 dnl be placed here.
 138 dnl
 139 dnl Defines:
 140 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 141 dnl   new inlining code or the new system_header pragma will die on -Werror.
 142 dnl   Leave it out by default and use maint-mode to use it.
 143 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 144 dnl   compiler supports it and the user has not requested debug mode.
 145 dnl
 146 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 147   # All these tests are for C++; save the language and the compiler flags.
 148   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 149   # found in GLIBCXX_CONFIGURE.
 150   AC_LANG_SAVE
 151   AC_LANG_CPLUSPLUS
 152   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 153   ac_save_CXXFLAGS="$CXXFLAGS"
 154
 155   # Check for maintainer-mode bits.
 156   if test x"$USE_MAINTAINER_MODE" = xno; then
 157     WERROR=''
 158   else
 159     WERROR='-Werror'
 160   fi
 161
 162   # Check for -ffunction-sections -fdata-sections
 163   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 164   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 165   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 166   if test "$ac_test_CXXFLAGS" = set; then
 167     CXXFLAGS="$ac_save_CXXFLAGS"
 168   else
 169     # this is the suspicious part
 170     CXXFLAGS=''
 171   fi
 172   if test x"$ac_fdsections" = x"yes"; then
 173     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 174   fi
 175   AC_MSG_RESULT($ac_fdsections)
 176
 177   AC_LANG_RESTORE
 178   AC_SUBST(WERROR)
 179   AC_SUBST(SECTION_FLAGS)
 180 ])
 181
 182
 183 dnl
 184 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 185 dnl the native linker is in use, all variables will be defined to something
 186 dnl safe (like an empty string).
 187 dnl
 188 dnl Defines:
 189 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 190 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 191 dnl  LD (as a side effect of testing)
 192 dnl Sets:
 193 dnl  with_gnu_ld
 194 dnl  glibcxx_gnu_ld_version (possibly)
 195 dnl
 196 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 197 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 198 dnl
 199 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 200   # If we're not using GNU ld, then there's no point in even trying these
 201   # tests.  Check for that first.  We should have already tested for gld
 202   # by now (in libtool), but require it now just to be safe...
 203   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 204   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 205   AC_REQUIRE([AC_PROG_LD])
 206   AC_REQUIRE([AC_PROG_AWK])
 207
 208   # The name set by libtool depends on the version of libtool.  Shame on us
 209   # for depending on an impl detail, but c'est la vie.  Older versions used
 210   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 211   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 212   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 213   # set (hence we're using an older libtool), then set it.
 214   if test x${with_gnu_ld+set} != xset; then
 215     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 216       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 217       with_gnu_ld=no
 218     else
 219       with_gnu_ld=$ac_cv_prog_gnu_ld
 220     fi
 221   fi
 222
 223   # Start by getting the version number.  I think the libtool test already
 224   # does some of this, but throws away the result.
 225   changequote(,)
 226   ldver=`$LD --version 2>/dev/null | head -1 | \
 227          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 228   changequote([,])
 229   glibcxx_gnu_ld_version=`echo $ldver | \
 230          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 231
 232   # Set --gc-sections.
 233   if test "$with_gnu_ld" = "notbroken"; then
 234     # GNU ld it is!  Joy and bunny rabbits!
 235
 236     # All these tests are for C++; save the language and the compiler flags.
 237     # Need to do this so that g++ won't try to link in libstdc++
 238     ac_test_CFLAGS="${CFLAGS+set}"
 239     ac_save_CFLAGS="$CFLAGS"
 240     CFLAGS='-x c++  -Wl,--gc-sections'
 241
 242     # Check for -Wl,--gc-sections
 243     # XXX This test is broken at the moment, as symbols required for linking
 244     # are now in libsupc++ (not built yet).  In addition, this test has
 245     # cored on solaris in the past.  In addition, --gc-sections doesn't
 246     # really work at the moment (keeps on discarding used sections, first
 247     # .eh_frame and now some of the glibc sections for iconv).
 248     # Bzzzzt.  Thanks for playing, maybe next time.
 249     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 250     AC_TRY_RUN([
 251      int main(void)
 252      {
 253        try { throw 1; }
 254        catch (...) { };
 255        return 0;
 256      }
 257     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 258     if test "$ac_test_CFLAGS" = set; then
 259       CFLAGS="$ac_save_CFLAGS"
 260     else
 261       # this is the suspicious part
 262       CFLAGS=''
 263     fi
 264     if test "$ac_sectionLDflags" = "yes"; then
 265       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 266     fi
 267     AC_MSG_RESULT($ac_sectionLDflags)
 268   fi
 269
 270   # Set linker optimization flags.
 271   if test x"$with_gnu_ld" = x"yes"; then
 272     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 273   fi
 274
 275   AC_SUBST(SECTION_LDFLAGS)
 276   AC_SUBST(OPT_LDFLAGS)
 277 ])
 278
 279
 280 dnl
 281 dnl Check to see if this target can enable the iconv specializations.
 282 dnl If --disable-c-mbchar was given, no wchar_t specialization is enabled.
 283 dnl (This must have been previously checked, along with the rest of C99
 284 dnl support.) By default, iconv support is disabled.
 285 dnl
 286 dnl Defines:
 287 dnl  _GLIBCXX_USE_ICONV if all the bits are found.
 288 dnl Substs:
 289 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 290 dnl
 291 AC_DEFUN([GLIBCXX_CHECK_ICONV_SUPPORT], [
 292
 293   enable_iconv=no
 294   # Only continue checking if the ISO C99 headers exist and support is on.
 295   if test x"$enable_wchar_t" = xyes; then
 296
 297     # Use iconv for wchar_t to char conversions. As such, check for
 298     # X/Open Portability Guide, version 2 features (XPG2).
 299     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 300     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 301
 302     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 303     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 304     ac_save_LIBS="$LIBS"
 305     LIBS="$LIBS $LIBICONV"
 306     AC_SUBST(LIBICONV)
 307
 308     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 309     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 310
 311     LIBS="$ac_save_LIBS"
 312
 313     if test x"$ac_has_iconv_h" = xyes &&
 314        test x"$ac_has_langinfo_h" = xyes &&
 315        test x"$ac_XPG2funcs" = xyes;
 316     then
 317       AC_DEFINE([_GLIBCXX_USE_ICONV],1,
 318                 [Define if iconv and related functions exist and are usable.])
 319       enable_iconv=yes
 320     fi
 321   fi
 322   AC_MSG_CHECKING([for enabled iconv specializations])
 323   AC_MSG_RESULT($enable_iconv)
 324 ])
 325
 326
 327 dnl
 328 dnl Check for headers for, and arguments to, the setrlimit() function.
 329 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 330 dnl
 331 dnl Defines:
 332 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 333 dnl  various HAVE_LIMIT_* for individual limit names
 334 dnl
 335 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 336   AC_TRY_COMPILE(
 337     [#include <unistd.h>
 338      #include <sys/time.h>
 339      #include <sys/resource.h>
 340     ],
 341     [ int f = RLIMIT_$1 ; ],
 342     [glibcxx_mresult=1], [glibcxx_mresult=0])
 343   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 344                      [Only used in build directory testsuite_hooks.h.])
 345 ])
 346
 347 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 348   setrlimit_have_headers=yes
 349   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 350                    [],
 351                    [setrlimit_have_headers=no])
 352   # If don't have the headers, then we can't run the tests now, and we
 353   # won't be seeing any of these during testsuite compilation.
 354   if test $setrlimit_have_headers = yes; then
 355     # Can't do these in a loop, else the resulting syntax is wrong.
 356     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 357     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 358     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 359     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 360     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 361
 362     # Check for rlimit, setrlimit.
 363     AC_CACHE_VAL(ac_setrlimit, [
 364       AC_TRY_COMPILE(
 365         [#include <unistd.h>
 366          #include <sys/time.h>
 367          #include <sys/resource.h>
 368         ],
 369         [struct rlimit r;
 370          setrlimit(0, &r);],
 371         [ac_setrlimit=yes], [ac_setrlimit=no])
 372     ])
 373   fi
 374
 375   AC_MSG_CHECKING([for testsuite resource limits support])
 376   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 377     ac_res_limits=yes
 378     AC_DEFINE(_GLIBCXX_RES_LIMITS)
 379   else
 380     ac_res_limits=no
 381   fi
 382   AC_MSG_RESULT($ac_res_limits)
 383 ])
 384
 385
 386 dnl
 387 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 388 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 389 dnl
 390 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 391   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 392     AC_TRY_LINK(
 393       [#include <sys/stat.h>],
 394       [struct stat buffer;
 395        fstat(0, &buffer);
 396        S_ISREG(buffer.st_mode);],
 397       [glibcxx_cv_S_ISREG=yes],
 398       [glibcxx_cv_S_ISREG=no])
 399   ])
 400   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 401     AC_TRY_LINK(
 402       [#include <sys/stat.h>],
 403       [struct stat buffer;
 404        fstat(0, &buffer);
 405        S_IFREG & buffer.st_mode;],
 406       [glibcxx_cv_S_IFREG=yes],
 407       [glibcxx_cv_S_IFREG=no])
 408   ])
 409   if test $glibcxx_cv_S_ISREG = yes; then
 410     AC_DEFINE(HAVE_S_ISREG)
 411   elif test $glibcxx_cv_S_IFREG = yes; then
 412     AC_DEFINE(HAVE_S_IFREG)
 413   fi
 414 ])
 415
 416
 417 dnl
 418 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 419 dnl
 420 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 421   AC_CACHE_VAL(glibcxx_cv_POLL, [
 422     AC_TRY_LINK(
 423       [#include <poll.h>],
 424       [struct pollfd pfd[1];
 425        pfd[0].events = POLLIN;
 426        poll(pfd, 1, 0);],
 427       [glibcxx_cv_POLL=yes],
 428       [glibcxx_cv_POLL=no])
 429   ])
 430   if test $glibcxx_cv_POLL = yes; then
 431     AC_DEFINE(HAVE_POLL)
 432   fi
 433 ])
 434
 435
 436 dnl
 437 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 438 dnl
 439 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 440   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 441     AC_TRY_LINK(
 442       [#include <sys/uio.h>],
 443       [struct iovec iov[2];
 444        writev(0, iov, 0);],
 445       [glibcxx_cv_WRITEV=yes],
 446       [glibcxx_cv_WRITEV=no])
 447   ])
 448   if test $glibcxx_cv_WRITEV = yes; then
 449     AC_DEFINE(HAVE_WRITEV)
 450   fi
 451 ])
 452
 453
 454 dnl
 455 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 456 dnl
 457 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 458   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 459     AC_TRY_COMPILE(
 460       [#include <stdint.h>],
 461       [int64_t var;],
 462       [glibcxx_cv_INT64_T=yes],
 463       [glibcxx_cv_INT64_T=no])
 464   ])
 465   if test $glibcxx_cv_INT64_T = yes; then
 466     AC_DEFINE(HAVE_INT64_T)
 467   fi
 468 ])
 469
 470
 471 dnl
 472 dnl Check whether LFS support is available.
 473 dnl
 474 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 475   AC_LANG_SAVE
 476   AC_LANG_CPLUSPLUS
 477   ac_save_CXXFLAGS="$CXXFLAGS"
 478   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 479   AC_CACHE_VAL(glibcxx_cv_LFS, [
 480     AC_TRY_LINK(
 481       [#include <unistd.h>
 482        #include <stdio.h>
 483        #include <sys/stat.h>
 484       ],
 485       [FILE* fp;
 486        fopen64("t", "w");
 487        fseeko64(fp, 0, SEEK_CUR);
 488        ftello64(fp);
 489        lseek64(1, 0, SEEK_CUR);
 490        struct stat64 buf;
 491        fstat64(1, &buf);],
 492       [glibcxx_cv_LFS=yes],
 493       [glibcxx_cv_LFS=no])
 494   ])
 495   if test $glibcxx_cv_LFS = yes; then
 496     AC_DEFINE(_GLIBCXX_USE_LFS)
 497   fi
 498   CXXFLAGS="$ac_save_CXXFLAGS"
 499   AC_LANG_RESTORE
 500 ])
 501
 502
 503 dnl
 504 dnl Check for whether a fully dynamic basic_string implementation should
 505 dnl be turned on, that does not put empty objects in per-process static
 506 dnl memory (mostly useful together with shared memory allocators, see PR
 507 dnl libstdc++/16612 for details).
 508 dnl
 509 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 510 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 511 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 512 dnl       Where DEFAULT is either `yes' or `no'.
 513 dnl
 514 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 515   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 516   if test $enable_fully_dynamic_string = yes; then
 517     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING)
 518   fi
 519 ])
 520
 521
 522 dnl
 523 dnl Does any necessary configuration of the testsuite directory.  Generates
 524 dnl the testsuite_hooks.h header.
 525 dnl
 526 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 527 dnl
 528 dnl Sets:
 529 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 530 dnl  GLIBCXX_TEST_WCHAR_T
 531 dnl  GLIBCXX_TEST_THREAD
 532 dnl Substs:
 533 dnl  baseline_dir
 534 dnl
 535 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 536   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 537     # Do checks for resource limit functions.
 538     GLIBCXX_CHECK_SETRLIMIT
 539
 540     # Look for setenv, so that extended locale tests can be performed.
 541     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 542
 543     if test $enable_symvers = no; then
 544       enable_abi_check=no
 545     else
 546       case "$host" in
 547         *-*-cygwin*)
 548           enable_abi_check=no ;;
 549         *)
 550           enable_abi_check=yes ;;
 551       esac
 552     fi
 553   else
 554     # Only build this as native, since automake does not understand
 555     # CXX_FOR_BUILD.
 556     enable_abi_check=no
 557   fi
 558
 559   # Export file names for ABI checking.
 560   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 561   AC_SUBST(baseline_dir)
 562
 563   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 564   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_THREAD, test $enable_thread = yes)
 565   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 566 ])
 567
 568
 569 dnl
 570 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 571 dnl
 572 dnl Substs:
 573 dnl  GLIBCXX_INCLUDES
 574 dnl  TOPLEVEL_INCLUDES
 575 dnl
 576 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 577   # Used for every C++ compile we perform.
 578   GLIBCXX_INCLUDES="\
 579 -I$glibcxx_builddir/include/$host_alias \
 580 -I$glibcxx_builddir/include \
 581 -I$glibcxx_srcdir/libsupc++"
 582
 583   # For Canadian crosses, pick this up too.
 584   if test $CANADIAN = yes; then
 585     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 586   fi
 587
 588   # Stuff in the actual top level.  Currently only used by libsupc++ to
 589   # get unwind* headers from the gcc dir.
 590   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 591   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 592
 593   # Now, export this to all the little Makefiles....
 594   AC_SUBST(GLIBCXX_INCLUDES)
 595   AC_SUBST(TOPLEVEL_INCLUDES)
 596 ])
 597
 598
 599 dnl
 600 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 601 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 602 dnl
 603 dnl Substs:
 604 dnl  OPTIMIZE_CXXFLAGS
 605 dnl  WARN_FLAGS
 606 dnl
 607 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 608   # Optimization flags that are probably a good idea for thrill-seekers. Just
 609   # uncomment the lines below and make, everything else is ready to go...
 610   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 611   OPTIMIZE_CXXFLAGS=
 612   AC_SUBST(OPTIMIZE_CXXFLAGS)
 613
 614   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 615   AC_SUBST(WARN_FLAGS)
 616 ])
 617
 618
 619 dnl
 620 dnl All installation directory information is determined here.
 621 dnl
 622 dnl Substs:
 623 dnl  gxx_install_dir
 624 dnl  glibcxx_prefixdir
 625 dnl  glibcxx_toolexecdir
 626 dnl  glibcxx_toolexeclibdir
 627 dnl
 628 dnl Assumes cross_compiling bits already done, and with_cross_host in
 629 dnl particular.
 630 dnl
 631 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 632   glibcxx_toolexecdir=no
 633   glibcxx_toolexeclibdir=no
 634   glibcxx_prefixdir=$prefix
 635
 636   AC_MSG_CHECKING([for gxx-include-dir])
 637   AC_ARG_WITH([gxx-include-dir],
 638     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 639                    [installation directory for include files]),
 640     [case "$withval" in
 641       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 642       no)  gxx_include_dir=no ;;
 643       *)   gxx_include_dir=$withval ;;
 644      esac],
 645     [gxx_include_dir=no])
 646   AC_MSG_RESULT($gxx_include_dir)
 647
 648   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 649   AC_ARG_ENABLE([version-specific-runtime-libs],
 650     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 651                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 652     [case "$enableval" in
 653       yes) version_specific_libs=yes ;;
 654       no)  version_specific_libs=no ;;
 655       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 656      esac],
 657     [version_specific_libs=no])
 658   AC_MSG_RESULT($version_specific_libs)
 659
 660   # Default case for install directory for include files.
 661   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 662     gxx_include_dir='${prefix}/include/c++/${gcc_version}'
 663   fi
 664
 665   # Version-specific runtime libs processing.
 666   if test $version_specific_libs = yes; then
 667     # Need the gcc compiler version to know where to install libraries
 668     # and header files if --enable-version-specific-runtime-libs option
 669     # is selected.  FIXME: these variables are misnamed, there are
 670     # no executables installed in _toolexecdir or _toolexeclibdir.
 671     if test x"$gxx_include_dir" = x"no"; then
 672       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 673     fi
 674     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 675     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 676   fi
 677
 678   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 679   # Install a library built with a cross compiler in tooldir, not libdir.
 680   if test x"$glibcxx_toolexecdir" = x"no"; then
 681     if test -n "$with_cross_host" &&
 682        test x"$with_cross_host" != x"no"; then
 683       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 684       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 685     else
 686       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 687       glibcxx_toolexeclibdir='${libdir}'
 688     fi
 689     multi_os_directory=`$CXX -print-multi-os-directory`
 690     case $multi_os_directory in
 691       .) ;; # Avoid trailing /.
 692       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 693     esac
 694   fi
 695
 696   AC_MSG_CHECKING([for install location])
 697   AC_MSG_RESULT($gxx_include_dir)
 698
 699   AC_SUBST(glibcxx_prefixdir)
 700   AC_SUBST(gxx_include_dir)
 701   AC_SUBST(glibcxx_toolexecdir)
 702   AC_SUBST(glibcxx_toolexeclibdir)
 703 ])
 704
 705
 706 dnl
 707 dnl GLIBCXX_ENABLE
 708 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 709 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 710 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 711 dnl
 712 dnl See docs/html/17_intro/configury.html#enable for documentation.
 713 dnl
 714 m4_define([GLIBCXX_ENABLE],[dnl
 715 m4_define([_g_switch],[--enable-$1])dnl
 716 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 717  AC_ARG_ENABLE($1,_g_help,
 718   m4_bmatch([$5],
 719    [^permit ],
 720      [[
 721       case "$enableval" in
 722        m4_bpatsubst([$5],[permit ])) ;;
 723        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 724           dnl Idea for future:  generate a URL pointing to
 725           dnl "onlinedocs/configopts.html#whatever"
 726       esac
 727      ]],
 728    [^$],
 729      [[
 730       case "$enableval" in
 731        yes|no) ;;
 732        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 733       esac
 734      ]],
 735    [[$5]]),
 736   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 737 m4_undefine([_g_switch])dnl
 738 m4_undefine([_g_help])dnl
 739 ])
 740
 741
 742 dnl
 743 dnl Check for ISO/IEC 9899:1999 "C99" support.
 744 dnl
 745 dnl --enable-c99 defines _GLIBCXX_USE_C99
 746 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 747 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 748 dnl       Where DEFAULT is either `yes' or `no'.
 749 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 750 dnl
 751 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 752   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 753
 754   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos
 755   # even if C99 support is turned off.
 756   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 757   AC_MSG_CHECKING([for mbstate_t])
 758   AC_TRY_COMPILE([#include <wchar.h>],
 759   [mbstate_t teststate;],
 760   have_mbstate_t=yes, have_mbstate_t=no)
 761   AC_MSG_RESULT($have_mbstate_t)
 762   if test x"$have_mbstate_t" = xyes; then
 763     AC_DEFINE(HAVE_MBSTATE_T)
 764   fi
 765
 766   if test x"$enable_c99" = x"yes"; then
 767
 768   AC_LANG_SAVE
 769   AC_LANG_CPLUSPLUS
 770
 771   # Check for the existence of <math.h> functions used if C99 is enabled.
 772   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 773   AC_CACHE_VAL(ac_c99_math, [
 774   AC_TRY_COMPILE([#include <math.h>],
 775                  [fpclassify(0.0);
 776                   isfinite(0.0);
 777                   isinf(0.0);
 778                   isnan(0.0);
 779                   isnormal(0.0);
 780                   signbit(0.0);
 781                   isgreater(0.0,0.0);
 782                   isgreaterequal(0.0,0.0);
 783                   isless(0.0,0.0);
 784                   islessequal(0.0,0.0);
 785                   islessgreater(0.0,0.0);
 786                   islessgreater(0.0,0.0);
 787                   isunordered(0.0,0.0);
 788                  ],[ac_c99_math=yes], [ac_c99_math=no])
 789   ])
 790   AC_MSG_RESULT($ac_c99_math)
 791   if test x"$ac_c99_math" = x"yes"; then
 792     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 793   fi
 794
 795   # Check for the existence of <complex.h> complex functions.
 796   # This is necessary even though libstdc++ uses the builtin versions
 797   # of these functions, because if the builtin cannot be used, a reference
 798   # to the library function is emitted.
 799   # In addition, need to explicitly specify "C" compilation for this
 800   # one, or else the backwards C++ <complex.h> include will be selected.
 801   save_CXXFLAGS="$CXXFLAGS"
 802   CXXFLAGS="$CXXFLAGS -x c"
 803   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 804   ac_c99_complex=no;
 805   if test x"$ac_has_complex_h" = x"yes"; then
 806     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 807     AC_TRY_COMPILE([#include <complex.h>],
 808                    [typedef __complex__ float float_type; float_type tmpf;
 809                     cabsf(tmpf);
 810                     cargf(tmpf);
 811                     ccosf(tmpf);
 812                     ccoshf(tmpf);
 813                     cexpf(tmpf);
 814                     csinf(tmpf);
 815                     csinhf(tmpf);
 816                     csqrtf(tmpf);
 817                     ctanf(tmpf);
 818                     ctanhf(tmpf);
 819                     cpowf(tmpf, tmpf);
 820                     typedef __complex__ double double_type; double_type tmpd;
 821                     cabs(tmpd);
 822                     carg(tmpd);
 823                     ccos(tmpd);
 824                     ccosh(tmpd);
 825                     cexp(tmpd);
 826                     csin(tmpd);
 827                     csinh(tmpd);
 828                     csqrt(tmpd);
 829                     ctan(tmpd);
 830                     ctanh(tmpd);
 831                     cpow(tmpd, tmpd);
 832                     typedef __complex__ long double ld_type; ld_type tmpld;
 833                     cabsl(tmpld);
 834                     cargl(tmpld);
 835                     ccosl(tmpld);
 836                     ccoshl(tmpld);
 837                     cexpl(tmpld);
 838                     csinl(tmpld);
 839                     csinhl(tmpld);
 840                     csqrtl(tmpld);
 841                     ctanl(tmpld);
 842                     ctanhl(tmpld);
 843                     cpowl(tmpld, tmpld);
 844                    ],[ac_c99_complex=yes], [ac_c99_complex=no])
 845   fi
 846   CXXFLAGS="$save_CXXFLAGS"
 847   AC_MSG_RESULT($ac_c99_complex)
 848   if test x"$ac_c99_complex" = x"yes"; then
 849     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX)
 850   fi
 851
 852   # Check for the existence in <stdio.h> of vscanf, et. al.
 853   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 854   AC_CACHE_VAL(ac_c99_stdio, [
 855   AC_TRY_COMPILE([#include <stdio.h>
 856                   #include <stdarg.h>
 857                   void foo(char* fmt, ...)
 858                   {
 859                     va_list args; va_start(args, fmt);
 860                     vfscanf(stderr, "%i", args);
 861                     vscanf("%i", args);
 862                     vsnprintf(fmt, 0, "%i", args);
 863                     vsscanf(fmt, "%i", args);
 864                   }],
 865                  [snprintf("12", 0, "%i");],
 866                  [ac_c99_stdio=yes], [ac_c99_stdio=no])
 867   ])
 868   AC_MSG_RESULT($ac_c99_stdio)
 869
 870   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 871   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 872   AC_CACHE_VAL(ac_c99_stdlib, [
 873   AC_TRY_COMPILE([#include <stdlib.h>],
 874                  [char* tmp;
 875                   strtof("gnu", &tmp);
 876                   strtold("gnu", &tmp);
 877                   llabs(10);
 878                   lldiv(10,1);
 879                   atoll("10");
 880                   _Exit(0);
 881                   lldiv_t mydivt;],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 882   ])
 883   AC_MSG_RESULT($ac_c99_stdlib)
 884
 885   # Check for the existence in <wchar.h> of wcstoull, WEOF, etc.
 886   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 887   ac_c99_wchar=no;
 888   if test x"$ac_has_wchar_h" = xyes &&
 889      test x"$ac_has_wctype_h" = xyes; then
 890     AC_TRY_COMPILE([#include <wchar.h>
 891                     #include <stddef.h>
 892                     wint_t i;
 893                     long l = WEOF;
 894                     long j = WCHAR_MIN;
 895                     long k = WCHAR_MAX;
 896                     namespace test
 897                     {
 898                       using ::btowc;
 899                       using ::fgetwc;
 900                       using ::fgetws;
 901                       using ::fputwc;
 902                       using ::fputws;
 903                       using ::fwide;
 904                       using ::fwprintf;
 905                       using ::fwscanf;
 906                       using ::getwc;
 907                       using ::getwchar;
 908                       using ::mbrlen;
 909                       using ::mbrtowc;
 910                       using ::mbsinit;
 911                       using ::mbsrtowcs;
 912                       using ::putwc;
 913                       using ::putwchar;
 914                       using ::swprintf;
 915                       using ::swscanf;
 916                       using ::ungetwc;
 917                       using ::vfwprintf;
 918                       using ::vswprintf;
 919                       using ::vwprintf;
 920                       using ::wcrtomb;
 921                       using ::wcscat;
 922                       using ::wcschr;
 923                       using ::wcscmp;
 924                       using ::wcscoll;
 925                       using ::wcscpy;
 926                       using ::wcscspn;
 927                       using ::wcsftime;
 928                       using ::wcslen;
 929                       using ::wcsncat;
 930                       using ::wcsncmp;
 931                       using ::wcsncpy;
 932                       using ::wcspbrk;
 933                       using ::wcsrchr;
 934                       using ::wcsrtombs;
 935                       using ::wcsspn;
 936                       using ::wcsstr;
 937                       using ::wcstod;
 938                       using ::wcstok;
 939                       using ::wcstol;
 940                       using ::wcstold;
 941                       using ::wcstoll;
 942                       using ::wcstoul;
 943                       using ::wcstoull;
 944                       using ::wcsxfrm;
 945                       using ::wctob;
 946                       using ::wmemchr;
 947                       using ::wmemcmp;
 948                       using ::wmemcpy;
 949                       using ::wmemmove;
 950                       using ::wmemset;
 951                       using ::wprintf;
 952                       using ::wscanf;
 953                     }
 954                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 955
 956     # Checks for wide character functions that may not be present.
 957     # Injection of these is wrapped with guard macros.
 958     # NB: only put functions here, instead of immediately above, if
 959     # absolutely necessary.
 960     AC_TRY_COMPILE([#include <wchar.h>
 961                     namespace test { using ::vfwscanf; } ], [],
 962                    [AC_DEFINE(HAVE_VFWSCANF,1,
 963                         [Defined if vfwscanf exists.])],[])
 964
 965     AC_TRY_COMPILE([#include <wchar.h>
 966                     namespace test { using ::vswscanf; } ], [],
 967                    [AC_DEFINE(HAVE_VSWSCANF,1,
 968                         [Defined if vswscanf exists.])],[])
 969
 970     AC_TRY_COMPILE([#include <wchar.h>
 971                     namespace test { using ::vwscanf; } ], [],
 972                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
 973
 974     AC_TRY_COMPILE([#include <wchar.h>
 975                     namespace test { using ::wcstof; } ], [],
 976                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
 977
 978     AC_TRY_COMPILE([#include <wctype.h>],
 979                    [ wint_t t; int i = iswblank(t);],
 980                    [AC_DEFINE(HAVE_ISWBLANK,1,
 981                         [Defined if iswblank exists.])],[])
 982
 983     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
 984     AC_MSG_RESULT($ac_c99_wchar)
 985   fi
 986
 987   # Option parsed, now set things appropriately.
 988   if test x"$ac_c99_math" = x"no" ||
 989      test x"$ac_c99_complex" = x"no" ||
 990      test x"$ac_c99_stdio" = x"no" ||
 991      test x"$ac_c99_stdlib" = x"no" ||
 992      test x"$ac_c99_wchar" = x"no"; then
 993     enable_c99=no;
 994   else
 995     AC_DEFINE(_GLIBCXX_USE_C99)
 996   fi
 997
 998   AC_LANG_RESTORE
 999   fi
1000
1001   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1002   AC_MSG_RESULT($enable_c99)
1003 ])
1004
1005
1006 dnl
1007 dnl Check for what type of C headers to use.
1008 dnl
1009 dnl --enable-cheaders= [does stuff].
1010 dnl --disable-cheaders [does not do anything, really].
1011 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1012 dnl       Where DEFAULT is either `c' or `c_std'.
1013 dnl
1014 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1015   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1016     [construct "C" headers for g++], [permit c|c_std])
1017   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1018
1019   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1020
1021   AC_SUBST(C_INCLUDE_DIR)
1022   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1023   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1024   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1025 ])
1026
1027
1028 dnl
1029 dnl Check for which locale library to use.  The choice is mapped to
1030 dnl a subdirectory of config/locale.
1031 dnl
1032 dnl Default is generic.
1033 dnl
1034 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1035   AC_MSG_CHECKING([for C locale to use])
1036   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1037     [use MODEL for target locale package],
1038     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1039
1040   # If they didn't use this option switch, or if they specified --enable
1041   # with no specific model, we'll have to look for one.  If they
1042   # specified --disable (???), do likewise.
1043   if test $enable_clocale = no || test $enable_clocale = yes; then
1044      enable_clocale=auto
1045   fi
1046
1047   # Either a known package, or "auto"
1048   enable_clocale_flag=$enable_clocale
1049
1050   # Probe for locale support if no specific model is specified.
1051   # Default to "generic".
1052   if test $enable_clocale_flag = auto; then
1053     case ${target_os} in
1054       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1055         AC_EGREP_CPP([_GLIBCXX_ok], [
1056         #include <features.h>
1057         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1058           _GLIBCXX_ok
1059         #endif
1060         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1061
1062         # Test for bugs early in glibc-2.2.x series
1063           if test $enable_clocale_flag = gnu; then
1064           AC_TRY_RUN([
1065           #define _GNU_SOURCE 1
1066           #include <locale.h>
1067           #include <string.h>
1068           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1069           extern __typeof(newlocale) __newlocale;
1070           extern __typeof(duplocale) __duplocale;
1071           extern __typeof(strcoll_l) __strcoll_l;
1072           #endif
1073           int main()
1074           {
1075               const char __one[] = "Äuglein Augmen";
1076               const char __two[] = "Äuglein";
1077               int i;
1078               int j;
1079               __locale_t        loc;
1080                __locale_t        loc_dup;
1081               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1082               loc_dup = __duplocale(loc);
1083               i = __strcoll_l(__one, __two, loc);
1084               j = __strcoll_l(__one, __two, loc_dup);
1085               return 0;
1086           }
1087           ],
1088           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1089           [enable_clocale_flag=generic])
1090           fi
1091
1092         # ... at some point put __strxfrm_l tests in as well.
1093         ;;
1094       darwin* | freebsd*)
1095         enable_clocale_flag=darwin
1096         ;;
1097       *)
1098         enable_clocale_flag=generic
1099         ;;
1100     esac
1101   fi
1102
1103   # Deal with gettext issues.  Default to not using it (=no) until we detect
1104   # support for it later.  Let the user turn it off via --e/d, but let that
1105   # default to on for easier handling.
1106   USE_NLS=no
1107   AC_ARG_ENABLE(nls,
1108     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1109     [],
1110     [enable_nls=yes])
1111
1112   # Set configure bits for specified locale package
1113   case ${enable_clocale_flag} in
1114     generic)
1115       AC_MSG_RESULT(generic)
1116
1117       CLOCALE_H=config/locale/generic/c_locale.h
1118       CLOCALE_CC=config/locale/generic/c_locale.cc
1119       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1120       CCOLLATE_CC=config/locale/generic/collate_members.cc
1121       CCTYPE_CC=config/locale/generic/ctype_members.cc
1122       CMESSAGES_H=config/locale/generic/messages_members.h
1123       CMESSAGES_CC=config/locale/generic/messages_members.cc
1124       CMONEY_CC=config/locale/generic/monetary_members.cc
1125       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1126       CTIME_H=config/locale/generic/time_members.h
1127       CTIME_CC=config/locale/generic/time_members.cc
1128       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1129       ;;
1130     darwin)
1131       AC_MSG_RESULT(darwin or freebsd)
1132
1133       CLOCALE_H=config/locale/generic/c_locale.h
1134       CLOCALE_CC=config/locale/generic/c_locale.cc
1135       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1136       CCOLLATE_CC=config/locale/generic/collate_members.cc
1137       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1138       CMESSAGES_H=config/locale/generic/messages_members.h
1139       CMESSAGES_CC=config/locale/generic/messages_members.cc
1140       CMONEY_CC=config/locale/generic/monetary_members.cc
1141       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1142       CTIME_H=config/locale/generic/time_members.h
1143       CTIME_CC=config/locale/generic/time_members.cc
1144       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1145       ;;
1146
1147     gnu)
1148       AC_MSG_RESULT(gnu)
1149
1150       # Declare intention to use gettext, and add support for specific
1151       # languages.
1152       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1153       ALL_LINGUAS="de fr"
1154
1155       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1156       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1157       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1158         USE_NLS=yes
1159       fi
1160       # Export the build objects.
1161       for ling in $ALL_LINGUAS; do \
1162         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1163         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1164       done
1165       AC_SUBST(glibcxx_MOFILES)
1166       AC_SUBST(glibcxx_POFILES)
1167
1168       CLOCALE_H=config/locale/gnu/c_locale.h
1169       CLOCALE_CC=config/locale/gnu/c_locale.cc
1170       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1171       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1172       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1173       CMESSAGES_H=config/locale/gnu/messages_members.h
1174       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1175       CMONEY_CC=config/locale/gnu/monetary_members.cc
1176       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1177       CTIME_H=config/locale/gnu/time_members.h
1178       CTIME_CC=config/locale/gnu/time_members.cc
1179       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1180       ;;
1181     ieee_1003.1-2001)
1182       AC_MSG_RESULT(IEEE 1003.1)
1183
1184       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1185       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1186       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1187       CCOLLATE_CC=config/locale/generic/collate_members.cc
1188       CCTYPE_CC=config/locale/generic/ctype_members.cc
1189       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1190       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1191       CMONEY_CC=config/locale/generic/monetary_members.cc
1192       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1193       CTIME_H=config/locale/generic/time_members.h
1194       CTIME_CC=config/locale/generic/time_members.cc
1195       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1196       ;;
1197   esac
1198
1199   # This is where the testsuite looks for locale catalogs, using the
1200   # -DLOCALEDIR define during testsuite compilation.
1201   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1202   AC_SUBST(glibcxx_localedir)
1203
1204   # A standalone libintl (e.g., GNU libintl) may be in use.
1205   if test $USE_NLS = yes; then
1206     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1207     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1208   fi
1209   if test $USE_NLS = yes; then
1210     AC_DEFINE(_GLIBCXX_USE_NLS)
1211   fi
1212
1213   AC_SUBST(USE_NLS)
1214   AC_SUBST(CLOCALE_H)
1215   AC_SUBST(CMESSAGES_H)
1216   AC_SUBST(CCODECVT_CC)
1217   AC_SUBST(CCOLLATE_CC)
1218   AC_SUBST(CCTYPE_CC)
1219   AC_SUBST(CMESSAGES_CC)
1220   AC_SUBST(CMONEY_CC)
1221   AC_SUBST(CNUMERIC_CC)
1222   AC_SUBST(CTIME_H)
1223   AC_SUBST(CTIME_CC)
1224   AC_SUBST(CLOCALE_CC)
1225   AC_SUBST(CLOCALE_INTERNAL_H)
1226 ])
1227
1228
1229 dnl
1230 dnl Check for which std::allocator base class to use.  The choice is
1231 dnl mapped from a subdirectory of include/ext.
1232 dnl
1233 dnl Default is new.
1234 dnl
1235 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1236   AC_MSG_CHECKING([for std::allocator base class])
1237   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1238     [use KIND for target std::allocator base],
1239     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1240
1241   # If they didn't use this option switch, or if they specified --enable
1242   # with no specific model, we'll have to look for one.  If they
1243   # specified --disable (???), do likewise.
1244   if test $enable_libstdcxx_allocator = no ||
1245      test $enable_libstdcxx_allocator = yes;
1246   then
1247      enable_libstdcxx_allocator=auto
1248   fi
1249
1250   # Either a known package, or "auto". Auto implies the default choice
1251   # for a particular platform.
1252   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1253
1254   # Probe for host-specific support if no specific model is specified.
1255   # Default to "new".
1256   if test $enable_libstdcxx_allocator_flag = auto; then
1257     case ${target_os} in
1258       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1259         enable_libstdcxx_allocator_flag=mt
1260         ;;
1261       *)
1262         enable_libstdcxx_allocator_flag=new
1263         ;;
1264     esac
1265   fi
1266   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1267
1268
1269   # Set configure bits for specified locale package
1270   case ${enable_libstdcxx_allocator_flag} in
1271     bitmap)
1272       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1273       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1274       ;;
1275     malloc)
1276       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1277       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1278       ;;
1279     mt)
1280       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1281       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1282       ;;
1283     new)
1284       ALLOCATOR_H=config/allocator/new_allocator_base.h
1285       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1286       ;;
1287     pool)
1288       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1289       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1290       ;;
1291   esac
1292
1293   AC_SUBST(ALLOCATOR_H)
1294   AC_SUBST(ALLOCATOR_NAME)
1295 ])
1296
1297
1298 dnl
1299 dnl Check for whether the Boost-derived checks should be turned on.
1300 dnl
1301 dnl --enable-concept-checks turns them on.
1302 dnl --disable-concept-checks leaves them off.
1303 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1304 dnl       Where DEFAULT is either `yes' or `no'.
1305 dnl
1306 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1307   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1308   if test $enable_concept_checks = yes; then
1309     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1310   fi
1311 ])
1312
1313
1314 dnl
1315 dnl Check for which I/O library to use:  stdio, or something specific.
1316 dnl
1317 dnl Default is stdio.
1318 dnl
1319 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1320   AC_MSG_CHECKING([for underlying I/O to use])
1321   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1322     [use target-specific I/O package], [permit stdio])
1323
1324   # Now that libio has been removed, you can have any color you want as long
1325   # as it's black.  This is one big no-op until other packages are added, but
1326   # showing the framework never hurts.
1327   case ${enable_cstdio} in
1328     stdio)
1329       CSTDIO_H=config/io/c_io_stdio.h
1330       BASIC_FILE_H=config/io/basic_file_stdio.h
1331       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1332       AC_MSG_RESULT(stdio)
1333       ;;
1334   esac
1335
1336   AC_SUBST(CSTDIO_H)
1337   AC_SUBST(BASIC_FILE_H)
1338   AC_SUBST(BASIC_FILE_CC)
1339 ])
1340
1341
1342 dnl
1343 dnl Check for "unusual" flags to pass to the compiler while building.
1344 dnl
1345 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1346 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1347 dnl --disable-cxx-flags passes nothing.
1348 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1349 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1350 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1351 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1352 dnl       If "default flags" is an empty string, the effect is the same
1353 dnl       as --disable or --enable=no.
1354 dnl
1355 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1356   AC_MSG_CHECKING([for extra compiler flags for building])
1357   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1358     [pass compiler FLAGS when building library],
1359     [case "x$enable_cxx_flags" in
1360       xno | x)   enable_cxx_flags= ;;
1361       x-*)       ;;
1362       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1363      esac])
1364
1365   # Run through flags (either default or command-line) and set anything
1366   # extra (e.g., #defines) that must accompany particular g++ options.
1367   if test -n "$enable_cxx_flags"; then
1368     for f in $enable_cxx_flags; do
1369       case "$f" in
1370         -fhonor-std)  ;;
1371         -*)  ;;
1372         *)   # and we're trying to pass /what/ exactly?
1373              AC_MSG_ERROR([compiler flags start with a -]) ;;
1374       esac
1375     done
1376   fi
1377
1378   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1379   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1380   AC_SUBST(EXTRA_CXX_FLAGS)
1381 ])
1382
1383
1384 dnl
1385 dnl Check to see if debugging libraries are to be built.
1386 dnl
1387 dnl --enable-libstdcxx-debug
1388 dnl builds a separate set of debugging libraries in addition to the
1389 dnl normal (shared, static) libstdc++ binaries.
1390 dnl
1391 dnl --disable-libstdcxx-debug
1392 dnl builds only one (non-debug) version of libstdc++.
1393 dnl
1394 dnl --enable-libstdcxx-debug-flags=FLAGS
1395 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1396 dnl
1397 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1398 dnl       Where DEFAULT is either `yes' or `no'.
1399 dnl
1400 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1401   AC_MSG_CHECKING([for additional debug build])
1402   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1403   AC_MSG_RESULT($enable_libstdcxx_debug)
1404   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1405 ])
1406
1407
1408 dnl
1409 dnl Check for explicit debug flags.
1410 dnl
1411 dnl --enable-libstdcxx-debug-flags='-O1'
1412 dnl is a general method for passing flags to be used when
1413 dnl building debug libraries with --enable-debug.
1414 dnl
1415 dnl --disable-libstdcxx-debug-flags does nothing.
1416 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1417 dnl       If "default flags" is an empty string, the effect is the same
1418 dnl       as --disable or --enable=no.
1419 dnl
1420 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1421   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1422     [pass compiler FLAGS when building debug library],
1423     [case "x$enable_libstdcxx_debug_flags" in
1424       xno | x)    enable_libstdcxx_debug_flags= ;;
1425       x-*)        ;;
1426       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1427      esac])
1428
1429   # Option parsed, now set things appropriately
1430   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1431   AC_SUBST(DEBUG_FLAGS)
1432
1433   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1434 ])
1435
1436
1437 dnl
1438 dnl Check if the user only wants a freestanding library implementation.
1439 dnl
1440 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1441 dnl installing only the headers required by [17.4.1.3] and the language
1442 dnl support library.  More than that will be built (to keep the Makefiles
1443 dnl conveniently clean), but not installed.
1444 dnl
1445 dnl Sets:
1446 dnl  is_hosted  (yes/no)
1447 dnl
1448 dnl Defines:
1449 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1450 dnl
1451 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1452   AC_ARG_ENABLE([hosted-libstdcxx],
1453     AC_HELP_STRING([--disable-hosted-libstdcxx],
1454                    [only build freestanding C++ runtime support]),,
1455     [case "$host" in
1456         arm*-*-symbianelf*)
1457             enable_hosted_libstdcxx=no
1458             ;;
1459         *)
1460             enable_hosted_libstdcxx=yes
1461             ;;
1462      esac])
1463   if test "$enable_hosted_libstdcxx" = no; then
1464     AC_MSG_NOTICE([Only freestanding libraries will be built])
1465     is_hosted=no
1466     hosted_define=0
1467     enable_abi_check=no
1468     enable_libstdcxx_pch=no
1469   else
1470     is_hosted=yes
1471     hosted_define=1
1472   fi
1473   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1474   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1475     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1476 ])
1477
1478
1479 dnl
1480 dnl Check for template specializations for the 'long long' type.
1481 dnl The result determines only whether 'long long' I/O is enabled; things
1482 dnl like numeric_limits<> specializations are always available.
1483 dnl
1484 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1485 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1486 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1487 dnl       Where DEFAULT is either `yes' or `no'.
1488 dnl
1489 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1490   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1491   if test $enable_long_long = yes; then
1492     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1493   fi
1494   AC_MSG_CHECKING([for enabled long long specializations])
1495   AC_MSG_RESULT([$enable_long_long])
1496 ])
1497
1498
1499 dnl
1500 dnl Check for template specializations for the 'wchar_t' type.
1501 dnl
1502 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1503 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1504 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1505 dnl       Where DEFAULT is either `yes' or `no'.
1506 dnl
1507 dnl Necessary support (probed along with C99 support) must also be present.
1508 dnl
1509 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
1510   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
1511   if test x"$ac_c99_wchar" = x"yes" && test x"$enable_wchar_t" = x"yes"; then
1512     AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
1513   fi
1514   AC_MSG_CHECKING([for enabled wchar_t specializations])
1515   AC_MSG_RESULT([$enable_wchar_t])
1516 ])
1517
1518
1519 dnl
1520 dnl Check to see if building and using a C++ precompiled header can be done.
1521 dnl
1522 dnl --enable-libstdcxx-pch=yes
1523 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1524 dnl may work, after some light-hearted attempts to puzzle out compiler
1525 dnl support, flip bits on in include/Makefile.am
1526 dnl
1527 dnl --disable-libstdcxx-pch
1528 dnl turns off attempts to use or build stdc++.h.gch.
1529 dnl
1530 dnl Substs:
1531 dnl  glibcxx_PCHFLAGS
1532 dnl
1533 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1534   AC_MSG_CHECKING([for enabled PCH])
1535   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1536   AC_MSG_RESULT([$enable_libstdcxx_pch])
1537
1538   if test $enable_libstdcxx_pch = yes; then
1539     AC_CACHE_CHECK([for compiler with PCH support],
1540       [glibcxx_cv_prog_CXX_pch],
1541       [ac_save_CXXFLAGS="$CXXFLAGS"
1542        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1543        AC_LANG_SAVE
1544        AC_LANG_CPLUSPLUS
1545        echo '#include <math.h>' > conftest.h
1546        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1547                           -o conftest.h.gch 1>&5 2>&1 &&
1548                 echo '#error "pch failed"' > conftest.h &&
1549           echo '#include "conftest.h"' > conftest.cc &&
1550                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1551        then
1552          glibcxx_cv_prog_CXX_pch=yes
1553        else
1554          glibcxx_cv_prog_CXX_pch=no
1555        fi
1556        rm -f conftest*
1557        CXXFLAGS=$ac_save_CXXFLAGS
1558        AC_LANG_RESTORE
1559       ])
1560     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1561   fi
1562
1563   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1564   if test $enable_libstdcxx_pch = yes; then
1565     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1566   else
1567     glibcxx_PCHFLAGS=""
1568   fi
1569   AC_SUBST(glibcxx_PCHFLAGS)
1570 ])
1571
1572
1573 dnl
1574 dnl Check for exception handling support.  If an explicit enable/disable
1575 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1576 dnl target may or may not support call frame exceptions.
1577 dnl
1578 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1579 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1580 dnl Neither one forces an attempt at detection.
1581 dnl
1582 dnl Defines:
1583 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1584 dnl
1585 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1586   AC_MSG_CHECKING([for exception model to use])
1587   AC_LANG_SAVE
1588   AC_LANG_CPLUSPLUS
1589   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1590     [force use of builtin_setjmp for exceptions],
1591     [permit yes|no|auto])
1592
1593   if test $enable_sjlj_exceptions = auto; then
1594     # Botheration.  Now we've got to detect the exception model.  Link tests
1595     # against libgcc.a are problematic since we've not been given proper -L
1596     # bits for single-tree newlib and libgloss.
1597     #
1598     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1599     cat > conftest.$ac_ext << EOF
1600 [#]line __oline__ "configure"
1601 struct S { ~S(); };
1602 void bar();
1603 void foo()
1604 {
1605   S s;
1606   bar();
1607 }
1608 EOF
1609     old_CXXFLAGS="$CXXFLAGS"
1610     CXXFLAGS=-S
1611     if AC_TRY_EVAL(ac_compile); then
1612       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1613         enable_sjlj_exceptions=yes
1614       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1615         enable_sjlj_exceptions=no
1616       fi
1617     fi
1618     CXXFLAGS="$old_CXXFLAGS"
1619     rm -f conftest*
1620   fi
1621
1622   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1623   # to two different models.
1624   case $enable_sjlj_exceptions in
1625     yes)
1626       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1627         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1628       ac_exception_model_name=sjlj
1629       ;;
1630     no)
1631       ac_exception_model_name="call frame"
1632       ;;
1633     *)
1634       AC_MSG_ERROR([unable to detect exception model])
1635       ;;
1636   esac
1637  AC_LANG_RESTORE
1638  AC_MSG_RESULT($ac_exception_model_name)
1639 ])
1640
1641
1642 dnl
1643 dnl Add version tags to symbols in shared library (or not), additionally
1644 dnl marking other symbols as private/local (or not).
1645 dnl
1646 dnl --enable-symvers=style adds a version script to the linker call when
1647 dnl       creating the shared library.  The choice of version script is
1648 dnl       controlled by 'style'.
1649 dnl --disable-symvers does not.
1650 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1651 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1652 dnl       choose a default style based on linker characteristics.  Passing
1653 dnl       'no' disables versioning.
1654 dnl
1655 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1656
1657 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1658   [enables symbol versioning of the shared library],
1659   [permit yes|no|gnu])
1660
1661 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1662 # don't know enough about $LD to do tricks...
1663 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1664 # FIXME  The following test is too strict, in theory.
1665 if test $enable_shared = no ||
1666         test "x$LD" = x ||
1667         test x$glibcxx_gnu_ld_version = x; then
1668   enable_symvers=no
1669 fi
1670
1671 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1672 if test $enable_symvers != no; then
1673   AC_MSG_CHECKING([for shared libgcc])
1674   ac_save_CFLAGS="$CFLAGS"
1675   CFLAGS=' -lgcc_s'
1676   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1677   CFLAGS="$ac_save_CFLAGS"
1678   if test $glibcxx_shared_libgcc = no; then
1679     cat > conftest.c <<EOF
1680 int main (void) { return 0; }
1681 EOF
1682 changequote(,)dnl
1683     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1684                              -shared -shared-libgcc -o conftest.so \
1685                              conftest.c -v 2>&1 >/dev/null \
1686                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1687 changequote([,])dnl
1688     rm -f conftest.c conftest.so
1689     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1690       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1691       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1692       CFLAGS="$ac_save_CFLAGS"
1693     fi
1694   fi
1695   AC_MSG_RESULT($glibcxx_shared_libgcc)
1696 fi
1697
1698 # For GNU ld, we need at least this version.  The format is described in
1699 # GLIBCXX_CHECK_LINKER_FEATURES above.
1700 glibcxx_min_gnu_ld_version=21400
1701 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1702
1703 # Check to see if unspecified "yes" value can win, given results above.
1704 # Change "yes" into either "no" or a style name.
1705 if test $enable_symvers = yes; then
1706   if test $with_gnu_ld = yes &&
1707      test $glibcxx_shared_libgcc = yes;
1708   then
1709     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1710       enable_symvers=gnu
1711     else
1712       # The right tools, the right setup, but too old.  Fallbacks?
1713       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1714       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1715       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1716       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1717       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1718         # Globbing fix is present, proper block support is not.
1719         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1720         dnl enable_symvers=???
1721         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1722         enable_symvers=no
1723       else
1724         # 2.11 or older.
1725         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1726         enable_symvers=no
1727       fi
1728     fi
1729   else
1730     # just fail for now
1731     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1732     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1733     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1734     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1735     enable_symvers=no
1736   fi
1737 fi
1738
1739 # Everything parsed; figure out what file to use.
1740 case $enable_symvers in
1741   no)
1742     SYMVER_MAP=config/linker-map.dummy
1743     ;;
1744   gnu)
1745     SYMVER_MAP=config/linker-map.gnu
1746     AC_DEFINE(_GLIBCXX_SYMVER)
1747     ;;
1748 esac
1749
1750 AC_SUBST(SYMVER_MAP)
1751 AC_SUBST(port_specific_symbol_files)
1752 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1753 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1754 ])
1755
1756
1757 dnl
1758 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1759 dnl We must stage the required headers so that they will be installed
1760 dnl with the library (unlike libgcc, the STL implementation is provided
1761 dnl solely within headers).  Since we must not inject random user-space
1762 dnl macro names into user-provided C++ code, we first stage into <file>-in
1763 dnl and process to <file> with an output command.  The reason for a two-
1764 dnl stage process here is to correctly handle $srcdir!=$objdir without
1765 dnl having to write complex code (the sed commands to clean the macro
1766 dnl namespace are complex and fragile enough as it is).  We must also
1767 dnl add a relative path so that -I- is supported properly.
1768 dnl
1769 dnl Substs:
1770 dnl  glibcxx_thread_h
1771 dnl
1772 dnl Defines:
1773 dnl  HAVE_GTHR_DEFAULT
1774 dnl
1775 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1776   AC_MSG_CHECKING([for thread model used by GCC])
1777   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1778   AC_MSG_RESULT([$target_thread_file])
1779
1780   if test $target_thread_file != single; then
1781     AC_DEFINE(HAVE_GTHR_DEFAULT)
1782   fi
1783
1784   glibcxx_thread_h=gthr-$target_thread_file.h
1785
1786   dnl Check for __GTHREADS define.
1787   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
1788   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
1789     enable_thread=yes
1790   else
1791    enable_thread=no
1792   fi
1793
1794   AC_SUBST(glibcxx_thread_h)
1795 ])
1796
1797
1798 # Check whether LC_MESSAGES is available in <locale.h>.
1799 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1800 #
1801 # This file file be copied and used freely without restrictions.  It can
1802 # be used in projects which are not available under the GNU Public License
1803 # but which still want to provide support for the GNU gettext functionality.
1804 # Please note that the actual code is *not* freely available.
1805
1806 # serial 1
1807 AC_DEFUN([AC_LC_MESSAGES], [
1808   AC_CHECK_HEADER(locale.h, [
1809     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1810       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1811        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1812     if test $ac_cv_val_LC_MESSAGES = yes; then
1813       AC_DEFINE(HAVE_LC_MESSAGES)
1814     fi
1815   ])
1816 ])
1817
1818
1819 dnl vim:et:ts=2:sw=2