libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  27   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN(GLIBCXX_CONFIGURE, [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 387     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 394     if test x"$has_weof" = xyes &&
 395        test x"$has_wchar_minmax" = xyes &&
 396        test x"$ac_wfuncs" = xyes;
 397     then
 398       ac_isoC99_wchar_t=yes
 399     else
 400       ac_isoC99_wchar_t=no
 401     fi
 402     AC_MSG_RESULT($ac_isoC99_wchar_t)
 403
 404     # Use iconv for wchar_t to char conversions. As such, check for
 405     # X/Open Portability Guide, version 2 features (XPG2).
 406     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 407     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 408
 409     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 410     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 411     ac_save_LIBS="$LIBS"
 412     LIBS="$LIBS $libiconv"
 413
 414     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 415     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 416
 417     LIBS="$ac_save_LIBS"
 418
 419     AC_MSG_CHECKING([for XPG2 wchar_t support])
 420     if test x"$ac_has_iconv_h" = xyes &&
 421        test x"$ac_has_langinfo_h" = xyes &&
 422        test x"$ac_XPG2funcs" = xyes;
 423     then
 424       ac_XPG2_wchar_t=yes
 425     else
 426       ac_XPG2_wchar_t=no
 427     fi
 428     AC_MSG_RESULT($ac_XPG2_wchar_t)
 429
 430     # At the moment, only enable wchar_t specializations if all the
 431     # above support is present.
 432     if test x"$ac_isoC99_wchar_t" = xyes &&
 433        test x"$ac_XPG2_wchar_t" = xyes;
 434     then
 435       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 436       enable_wchar_t=yes
 437     fi
 438   fi
 439   AC_MSG_CHECKING([for enabled wchar_t specializations])
 440   AC_MSG_RESULT($enable_wchar_t)
 441 ])
 442
 443
 444 dnl
 445 dnl Check for headers for, and arguments to, the setrlimit() function.
 446 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 447 dnl
 448 dnl Defines:
 449 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 450 dnl  various HAVE_MEMLIMIT_* for individual limit names
 451 dnl
 452 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 453   AC_TRY_COMPILE(
 454     [#include <unistd.h>
 455      #include <sys/time.h>
 456      #include <sys/resource.h>
 457     ],
 458     [ int f = RLIMIT_$1 ; ],
 459     [glibcxx_mresult=1], [glibcxx_mresult=0])
 460   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 461                      [Only used in build directory testsuite_hooks.h.])
 462 ])
 463
 464 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 465   setrlimit_have_headers=yes
 466   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 467                    [],
 468                    [setrlimit_have_headers=no])
 469   # If don't have the headers, then we can't run the tests now, and we
 470   # won't be seeing any of these during testsuite compilation.
 471   if test $setrlimit_have_headers = yes; then
 472     # Can't do these in a loop, else the resulting syntax is wrong.
 473     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 474     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 475     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 476     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 477
 478     # Check for rlimit, setrlimit.
 479     AC_CACHE_VAL(ac_setrlimit, [
 480       AC_TRY_COMPILE(
 481         [#include <unistd.h>
 482          #include <sys/time.h>
 483          #include <sys/resource.h>
 484         ],
 485         [struct rlimit r;
 486          setrlimit(0, &r);],
 487         [ac_setrlimit=yes], [ac_setrlimit=no])
 488     ])
 489   fi
 490
 491   AC_MSG_CHECKING([for testsuite memory limit support])
 492   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 493     ac_mem_limits=yes
 494     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 495   else
 496     ac_mem_limits=no
 497   fi
 498   AC_MSG_RESULT($ac_mem_limits)
 499 ])
 500
 501
 502 dnl
 503 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 504 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 505 dnl
 506 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 507   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 508     AC_TRY_LINK(
 509       [#include <sys/stat.h>],
 510       [struct stat buffer;
 511        fstat(0, &buffer);
 512        S_ISREG(buffer.st_mode);],
 513       [glibcxx_cv_S_ISREG=yes],
 514       [glibcxx_cv_S_ISREG=no])
 515   ])
 516   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 517     AC_TRY_LINK(
 518       [#include <sys/stat.h>],
 519       [struct stat buffer;
 520        fstat(0, &buffer);
 521        S_IFREG & buffer.st_mode;],
 522       [glibcxx_cv_S_IFREG=yes],
 523       [glibcxx_cv_S_IFREG=no])
 524   ])
 525   if test $glibcxx_cv_S_ISREG = yes; then
 526     AC_DEFINE(HAVE_S_ISREG)
 527   elif test $glibcxx_cv_S_IFREG = yes; then
 528     AC_DEFINE(HAVE_S_IFREG)
 529   fi
 530 ])
 531
 532
 533 dnl
 534 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 535 dnl
 536 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 537   AC_CACHE_VAL(glibcxx_cv_POLL, [
 538     AC_TRY_COMPILE(
 539       [#include <poll.h>],
 540       [struct pollfd pfd[1];
 541        pfd[0].events = POLLIN;
 542        poll(pfd, 1, 0);],
 543       [glibcxx_cv_POLL=yes],
 544       [glibcxx_cv_POLL=no])
 545   ])
 546   if test $glibcxx_cv_POLL = yes; then
 547     AC_DEFINE(HAVE_POLL)
 548   fi
 549 ])
 550
 551
 552 dnl
 553 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 554 dnl
 555 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 556   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 557     AC_TRY_COMPILE(
 558       [#include <sys/uio.h>],
 559       [struct iovec iov[2];
 560        writev(0, iov, 0);],
 561       [glibcxx_cv_WRITEV=yes],
 562       [glibcxx_cv_WRITEV=no])
 563   ])
 564   if test $glibcxx_cv_WRITEV = yes; then
 565     AC_DEFINE(HAVE_WRITEV)
 566   fi
 567 ])
 568
 569
 570 dnl
 571 dnl Does any necessary configuration of the testsuite directory.  Generates
 572 dnl the testsuite_hooks.h header.
 573 dnl
 574 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 575 dnl
 576 dnl Sets:
 577 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 578 dnl Substs:
 579 dnl  baseline_dir
 580 dnl
 581 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 582   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 583     # Do checks for memory limit functions.
 584     GLIBCXX_CHECK_SETRLIMIT
 585
 586     # Look for setenv, so that extended locale tests can be performed.
 587     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 588   fi
 589
 590   # Export file names for ABI checking.
 591   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 592   AC_SUBST(baseline_dir)
 593
 594   # Determine if checking the ABI is desirable.
 595   if test $enable_symvers = no || test $is_hosted = no; then
 596     enable_abi_check=no
 597   else
 598     case "$host" in
 599       *-*-cygwin*)
 600         enable_abi_check=no ;;
 601       *)
 602         enable_abi_check=yes ;;
 603     esac
 604   fi
 605
 606   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 607   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 608 ])
 609
 610
 611 dnl
 612 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 613 dnl
 614 dnl Substs:
 615 dnl  GLIBCXX_INCLUDES
 616 dnl  TOPLEVEL_INCLUDES
 617 dnl
 618 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 619   # Used for every C++ compile we perform.
 620   GLIBCXX_INCLUDES="\
 621 -I$glibcxx_builddir/include/$host_alias \
 622 -I$glibcxx_builddir/include \
 623 -I$glibcxx_srcdir/libsupc++"
 624
 625   # For Canadian crosses, pick this up too.
 626   if test $CANADIAN = yes; then
 627     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 628   fi
 629
 630   # Stuff in the actual top level.  Currently only used by libsupc++ to
 631   # get unwind* headers from the gcc dir.
 632   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 633   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 634
 635   # Now, export this to all the little Makefiles....
 636   AC_SUBST(GLIBCXX_INCLUDES)
 637   AC_SUBST(TOPLEVEL_INCLUDES)
 638 ])
 639
 640
 641 dnl
 642 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 643 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 644 dnl
 645 dnl Substs:
 646 dnl  OPTIMIZE_CXXFLAGS
 647 dnl  WARN_FLAGS
 648 dnl
 649 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 650   # Optimization flags that are probably a good idea for thrill-seekers. Just
 651   # uncomment the lines below and make, everything else is ready to go...
 652   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 653   OPTIMIZE_CXXFLAGS=
 654   AC_SUBST(OPTIMIZE_CXXFLAGS)
 655
 656   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings'
 657   AC_SUBST(WARN_FLAGS)
 658 ])
 659
 660
 661 dnl
 662 dnl All installation directory information is determined here.
 663 dnl
 664 dnl Substs:
 665 dnl  gxx_install_dir
 666 dnl  glibcxx_prefixdir
 667 dnl  glibcxx_toolexecdir
 668 dnl  glibcxx_toolexeclibdir
 669 dnl
 670 dnl Assumes cross_compiling bits already done, and with_cross_host in
 671 dnl particular.
 672 dnl
 673 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 674   glibcxx_toolexecdir=no
 675   glibcxx_toolexeclibdir=no
 676   glibcxx_prefixdir=$prefix
 677
 678   AC_MSG_CHECKING([for gxx-include-dir])
 679   AC_ARG_WITH([gxx-include-dir],
 680     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 681                    [installation directory for include files]),
 682     [case "$withval" in
 683       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 684       no)  gxx_include_dir=no ;;
 685       *)   gxx_include_dir=$withval ;;
 686      esac],
 687     [gxx_include_dir=no])
 688   AC_MSG_RESULT($gxx_include_dir)
 689
 690   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 691   AC_ARG_ENABLE([version-specific-runtime-libs],
 692     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 693                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 694     [case "$enableval" in
 695       yes) version_specific_libs=yes ;;
 696       no)  version_specific_libs=no ;;
 697       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 698      esac],
 699     [version_specific_libs=no])
 700   AC_MSG_RESULT($version_specific_libs)
 701
 702   # Default case for install directory for include files.
 703   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 704     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 705   fi
 706
 707   # Version-specific runtime libs processing.
 708   if test $version_specific_libs = yes; then
 709     # Need the gcc compiler version to know where to install libraries
 710     # and header files if --enable-version-specific-runtime-libs option
 711     # is selected.
 712     if test x"$gxx_include_dir" = x"no"; then
 713       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 714     fi
 715     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 716     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 717   fi
 718
 719   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 720   # Install a library built with a cross compiler in tooldir, not libdir.
 721   if test x"$glibcxx_toolexecdir" = x"no"; then
 722     if test -n "$with_cross_host" &&
 723        test x"$with_cross_host" != x"no"; then
 724       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 725       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 726     else
 727       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 728       glibcxx_toolexeclibdir='${libdir}'
 729     fi
 730     multi_os_directory=`$CXX -print-multi-os-directory`
 731     case $multi_os_directory in
 732       .) ;; # Avoid trailing /.
 733       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 734     esac
 735   fi
 736
 737   AC_MSG_CHECKING([for install location])
 738   AC_MSG_RESULT($gxx_include_dir)
 739
 740   AC_SUBST(glibcxx_prefixdir)
 741   AC_SUBST(gxx_include_dir)
 742   AC_SUBST(glibcxx_toolexecdir)
 743   AC_SUBST(glibcxx_toolexeclibdir)
 744 ])
 745
 746
 747 dnl
 748 dnl GLIBCXX_ENABLE
 749 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 750 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 751 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 752 dnl
 753 dnl See docs/html/17_intro/configury.html#enable for documentation.
 754 dnl
 755 m4_define([GLIBCXX_ENABLE],[dnl
 756 m4_define([_g_switch],[--enable-$1])dnl
 757 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 758  AC_ARG_ENABLE($1,_g_help,
 759   m4_bmatch([$5],
 760    [^permit ],
 761      [[
 762       case "$enableval" in
 763        m4_bpatsubst([$5],[permit ])) ;;
 764        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 765           dnl Idea for future:  generate a URL pointing to
 766           dnl "onlinedocs/configopts.html#whatever"
 767       esac
 768      ]],
 769    [^$],
 770      [[
 771       case "$enableval" in
 772        yes|no) ;;
 773        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 774       esac
 775      ]],
 776    [[$5]]),
 777   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 778 m4_undefine([_g_switch])dnl
 779 m4_undefine([_g_help])dnl
 780 ])
 781
 782
 783 dnl
 784 dnl Check for ISO/IEC 9899:1999 "C99" support.
 785 dnl
 786 dnl --enable-c99 defines _GLIBCXX_USE_C99
 787 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 788 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 789 dnl       Where DEFAULT is either `yes' or `no'.
 790 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 791 dnl
 792 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 793   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 794
 795   AC_LANG_SAVE
 796   AC_LANG_CPLUSPLUS
 797
 798   # Check for the existence of <math.h> functions used if C99 is enabled.
 799   ac_c99_math=yes;
 800   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 801   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 802   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 803   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 804   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 805   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 806   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 807   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 808   AC_TRY_COMPILE([#include <math.h>],
 809                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 810   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 811   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 812   AC_TRY_COMPILE([#include <math.h>],
 813                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 814   AC_TRY_COMPILE([#include <math.h>],
 815                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 816   AC_MSG_RESULT($ac_c99_math)
 817
 818   # Check for the existence in <stdio.h> of vscanf, et. al.
 819   ac_c99_stdio=yes;
 820   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 821   AC_TRY_COMPILE([#include <stdio.h>],
 822                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 823   AC_TRY_COMPILE([#include <stdio.h>
 824                   #include <stdarg.h>
 825                   void foo(char* fmt, ...)
 826                   {va_list args; va_start(args, fmt);
 827                   vfscanf(stderr, "%i", args);}],
 828                   [],, [ac_c99_stdio=no])
 829   AC_TRY_COMPILE([#include <stdio.h>
 830                   #include <stdarg.h>
 831                   void foo(char* fmt, ...)
 832                   {va_list args; va_start(args, fmt);
 833                   vscanf("%i", args);}],
 834                   [],, [ac_c99_stdio=no])
 835   AC_TRY_COMPILE([#include <stdio.h>
 836                   #include <stdarg.h>
 837                   void foo(char* fmt, ...)
 838                   {va_list args; va_start(args, fmt);
 839                   vsnprintf(fmt, 0, "%i", args);}],
 840                   [],, [ac_c99_stdio=no])
 841   AC_TRY_COMPILE([#include <stdio.h>
 842                   #include <stdarg.h>
 843                   void foo(char* fmt, ...)
 844                   {va_list args; va_start(args, fmt);
 845                   vsscanf(fmt, "%i", args);}],
 846                   [],, [ac_c99_stdio=no])
 847   AC_MSG_RESULT($ac_c99_stdio)
 848
 849   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 850   ac_c99_stdlib=yes;
 851   AC_MSG_CHECKING([for lldiv_t declaration])
 852   AC_CACHE_VAL(ac_c99_lldiv_t, [
 853   AC_TRY_COMPILE([#include <stdlib.h>],
 854                    [ lldiv_t mydivt;],
 855                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 856   ])
 857   AC_MSG_RESULT($ac_c99_lldiv_t)
 858
 859   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 860   AC_TRY_COMPILE([#include <stdlib.h>],
 861                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 862   AC_TRY_COMPILE([#include <stdlib.h>],
 863                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 864   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 865   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 866   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 867   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 868   if test x"$ac_c99_lldiv_t" = x"no"; then
 869     ac_c99_stdlib=no;
 870   fi;
 871   AC_MSG_RESULT($ac_c99_stdlib)
 872
 873   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 874   # XXX the wchar.h checks should be rolled into the general C99 bits.
 875   ac_c99_wchar=yes;
 876   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 877   AC_TRY_COMPILE([#include <wchar.h>],
 878                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 879   AC_TRY_COMPILE([#include <wchar.h>],
 880                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 881   AC_TRY_COMPILE([#include <wchar.h>],
 882                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 883   AC_MSG_RESULT($ac_c99_wchar)
 884
 885   AC_MSG_CHECKING([for enabled ISO C99 support])
 886   if test x"$ac_c99_math" = x"no" ||
 887      test x"$ac_c99_stdio" = x"no" ||
 888      test x"$ac_c99_stdlib" = x"no" ||
 889      test x"$ac_c99_wchar" = x"no"; then
 890     enable_c99=no;
 891   fi;
 892   AC_MSG_RESULT($enable_c99)
 893
 894   # Option parsed, now set things appropriately
 895   if test x"$enable_c99" = x"yes"; then
 896     AC_DEFINE(_GLIBCXX_USE_C99)
 897   fi
 898
 899   AC_LANG_RESTORE
 900 ])
 901
 902
 903 dnl
 904 dnl Check for what type of C headers to use.
 905 dnl
 906 dnl --enable-cheaders= [does stuff].
 907 dnl --disable-cheaders [does not do anything, really].
 908 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 909 dnl       Where DEFAULT is either `c' or `c_std'.
 910 dnl
 911 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 912   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 913     [construct "C" headers for g++], [permit c|c_std])
 914   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 915
 916   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 917
 918   AC_SUBST(C_INCLUDE_DIR)
 919   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 920   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 921   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 922 ])
 923
 924
 925 dnl
 926 dnl Check for which locale library to use.  The choice is mapped to
 927 dnl a subdirectory of config/locale.
 928 dnl
 929 dnl Default is generic.
 930 dnl
 931 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 932   AC_MSG_CHECKING([for C locale to use])
 933   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 934     [use MODEL for target locale package],
 935     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 936
 937   # If they didn't use this option switch, or if they specified --enable
 938   # with no specific model, we'll have to look for one.  If they
 939   # specified --disable (???), do likewise.
 940   if test $enable_clocale = no || test $enable_clocale = yes; then
 941      enable_clocale=auto
 942   fi
 943
 944   # Either a known package, or "auto"
 945   enable_clocale_flag=$enable_clocale
 946
 947   # Probe for locale support if no specific model is specified.
 948   # Default to "generic".
 949   if test $enable_clocale_flag = auto; then
 950     case x${target_os} in
 951       xlinux* | xgnu*)
 952         AC_EGREP_CPP([_GLIBCXX_ok], [
 953         #include <features.h>
 954         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 955           _GLIBCXX_ok
 956         #endif
 957         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
 958
 959         # Test for bugs early in glibc-2.2.x series
 960           if test x$enable_clocale_flag = xgnu; then
 961           AC_TRY_RUN([
 962           #define _GNU_SOURCE 1
 963           #include <locale.h>
 964           #include <string.h>
 965           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
 966           extern __typeof(newlocale) __newlocale;
 967           extern __typeof(duplocale) __duplocale;
 968           extern __typeof(strcoll_l) __strcoll_l;
 969           #endif
 970           int main()
 971           {
 972               const char __one[] = "Äuglein Augmen";
 973               const char __two[] = "Äuglein";
 974               int i;
 975               int j;
 976               __locale_t        loc;
 977                __locale_t        loc_dup;
 978               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
 979               loc_dup = __duplocale(loc);
 980               i = __strcoll_l(__one, __two, loc);
 981               j = __strcoll_l(__one, __two, loc_dup);
 982               return 0;
 983           }
 984           ],
 985           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
 986           [enable_clocale_flag=generic])
 987           fi
 988
 989         # ... at some point put __strxfrm_l tests in as well.
 990         ;;
 991       *)
 992         enable_clocale_flag=generic
 993         ;;
 994     esac
 995   fi
 996
 997   # Deal with gettext issues.  Default to not using it (=no) until we detect
 998   # support for it later.  Let the user turn it off via --e/d, but let that
 999   # default to on for easier handling.
1000   USE_NLS=no
1001   AC_ARG_ENABLE(nls,
1002     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1003     [],
1004     [enable_nls=yes])
1005
1006   # Set configure bits for specified locale package
1007   case ${enable_clocale_flag} in
1008     generic)
1009       AC_MSG_RESULT(generic)
1010
1011       CLOCALE_H=config/locale/generic/c_locale.h
1012       CLOCALE_CC=config/locale/generic/c_locale.cc
1013       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1014       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1015       CCOLLATE_CC=config/locale/generic/collate_members.cc
1016       CCTYPE_CC=config/locale/generic/ctype_members.cc
1017       CMESSAGES_H=config/locale/generic/messages_members.h
1018       CMESSAGES_CC=config/locale/generic/messages_members.cc
1019       CMONEY_CC=config/locale/generic/monetary_members.cc
1020       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1021       CTIME_H=config/locale/generic/time_members.h
1022       CTIME_CC=config/locale/generic/time_members.cc
1023       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1024       ;;
1025     gnu)
1026       AC_MSG_RESULT(gnu)
1027
1028       # Declare intention to use gettext, and add support for specific
1029       # languages.
1030       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1031       ALL_LINGUAS="de fr"
1032
1033       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1034       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1035       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1036         USE_NLS=yes
1037       fi
1038       # Export the build objects.
1039       for ling in $ALL_LINGUAS; do \
1040         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1041         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1042       done
1043       AC_SUBST(glibcxx_MOFILES)
1044       AC_SUBST(glibcxx_POFILES)
1045
1046       CLOCALE_H=config/locale/gnu/c_locale.h
1047       CLOCALE_CC=config/locale/gnu/c_locale.cc
1048       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1049       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1050       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1051       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1052       CMESSAGES_H=config/locale/gnu/messages_members.h
1053       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1054       CMONEY_CC=config/locale/gnu/monetary_members.cc
1055       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1056       CTIME_H=config/locale/gnu/time_members.h
1057       CTIME_CC=config/locale/gnu/time_members.cc
1058       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1059       ;;
1060     ieee_1003.1-2001)
1061       AC_MSG_RESULT(IEEE 1003.1)
1062
1063       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1064       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1065       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1066       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1067       CCOLLATE_CC=config/locale/generic/collate_members.cc
1068       CCTYPE_CC=config/locale/generic/ctype_members.cc
1069       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1070       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1071       CMONEY_CC=config/locale/generic/monetary_members.cc
1072       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1073       CTIME_H=config/locale/generic/time_members.h
1074       CTIME_CC=config/locale/generic/time_members.cc
1075       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1076       ;;
1077   esac
1078
1079   # This is where the testsuite looks for locale catalogs, using the
1080   # -DLOCALEDIR define during testsuite compilation.
1081   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1082   AC_SUBST(glibcxx_localedir)
1083
1084   # A standalone libintl (e.g., GNU libintl) may be in use.
1085   if test $USE_NLS = yes; then
1086     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1087     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1088   fi
1089   if test $USE_NLS = yes; then
1090     AC_DEFINE(_GLIBCXX_USE_NLS)
1091   fi
1092
1093   AC_SUBST(USE_NLS)
1094   AC_SUBST(CLOCALE_H)
1095   AC_SUBST(CCODECVT_H)
1096   AC_SUBST(CMESSAGES_H)
1097   AC_SUBST(CCODECVT_CC)
1098   AC_SUBST(CCOLLATE_CC)
1099   AC_SUBST(CCTYPE_CC)
1100   AC_SUBST(CMESSAGES_CC)
1101   AC_SUBST(CMONEY_CC)
1102   AC_SUBST(CNUMERIC_CC)
1103   AC_SUBST(CTIME_H)
1104   AC_SUBST(CTIME_CC)
1105   AC_SUBST(CLOCALE_CC)
1106   AC_SUBST(CLOCALE_INTERNAL_H)
1107 ])
1108
1109
1110 dnl
1111 dnl Check for whether the Boost-derived checks should be turned on.
1112 dnl
1113 dnl --enable-concept-checks turns them on.
1114 dnl --disable-concept-checks leaves them off.
1115 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1116 dnl       Where DEFAULT is either `yes' or `no'.
1117 dnl
1118 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1119   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1120   if test $enable_concept_checks = yes; then
1121     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1122   fi
1123 ])
1124
1125
1126 dnl
1127 dnl Check for which I/O library to use:  stdio, or something specific.
1128 dnl
1129 dnl Default is stdio.
1130 dnl
1131 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1132   AC_MSG_CHECKING([for underlying I/O to use])
1133   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1134     [use target-specific I/O package], [permit stdio])
1135
1136   # Now that libio has been removed, you can have any color you want as long
1137   # as it's black.  This is one big no-op until other packages are added, but
1138   # showing the framework never hurts.
1139   case ${enable_cstdio} in
1140     stdio)
1141       CSTDIO_H=config/io/c_io_stdio.h
1142       BASIC_FILE_H=config/io/basic_file_stdio.h
1143       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1144       AC_MSG_RESULT(stdio)
1145       ;;
1146   esac
1147
1148   dnl Set directory for fpos.h
1149   FPOS_H=$fpos_include_dir
1150
1151   AC_SUBST(CSTDIO_H)
1152   AC_SUBST(FPOS_H)
1153   AC_SUBST(BASIC_FILE_H)
1154   AC_SUBST(BASIC_FILE_CC)
1155 ])
1156
1157
1158 dnl
1159 dnl Check for "unusual" flags to pass to the compiler while building.
1160 dnl
1161 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1162 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1163 dnl --disable-cxx-flags passes nothing.
1164 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1165 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1166 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1167 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1168 dnl       If "default flags" is an empty string, the effect is the same
1169 dnl       as --disable or --enable=no.
1170 dnl
1171 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1172   AC_MSG_CHECKING([for extra compiler flags for building])
1173   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1174     [pass compiler FLAGS when building library],
1175     [case "x$enable_cxx_flags" in
1176       xno | x)   enable_cxx_flags= ;;
1177       x-*)       ;;
1178       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1179      esac])
1180
1181   # Run through flags (either default or command-line) and set anything
1182   # extra (e.g., #defines) that must accompany particular g++ options.
1183   if test -n "$enable_cxx_flags"; then
1184     for f in $enable_cxx_flags; do
1185       case "$f" in
1186         -fhonor-std)  ;;
1187         -*)  ;;
1188         *)   # and we're trying to pass /what/ exactly?
1189              AC_MSG_ERROR([compiler flags start with a -]) ;;
1190       esac
1191     done
1192   fi
1193
1194   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1195   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1196   AC_SUBST(EXTRA_CXX_FLAGS)
1197 ])
1198
1199
1200 dnl
1201 dnl Check for wide character support.  Has the same effect as the option
1202 dnl in gcc's configure, but in a form that autoconf can mess with.
1203 dnl
1204 dnl --enable-c-mbchar requests all the wchar_t stuff.
1205 dnl --disable-c-mbchar doesn't.
1206 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1207 dnl       Where DEFAULT is either `yes' or `no'.
1208 dnl
1209 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1210   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1211   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1212 ])
1213
1214
1215 dnl
1216 dnl Check to see if debugging libraries are to be built.
1217 dnl
1218 dnl --enable-libstdcxx-debug
1219 dnl builds a separate set of debugging libraries in addition to the
1220 dnl normal (shared, static) libstdc++ binaries.
1221 dnl
1222 dnl --disable-libstdcxx-debug
1223 dnl builds only one (non-debug) version of libstdc++.
1224 dnl
1225 dnl --enable-libstdcxx-debug-flags=FLAGS
1226 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1227 dnl
1228 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1229 dnl       Where DEFAULT is either `yes' or `no'.
1230 dnl
1231 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1232   AC_MSG_CHECKING([for additional debug build])
1233   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1234   AC_MSG_RESULT($enable_libstdcxx_debug)
1235   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1236 ])
1237
1238
1239 dnl
1240 dnl Check for explicit debug flags.
1241 dnl
1242 dnl --enable-libstdcxx-debug-flags='-O1'
1243 dnl is a general method for passing flags to be used when
1244 dnl building debug libraries with --enable-debug.
1245 dnl
1246 dnl --disable-libstdcxx-debug-flags does nothing.
1247 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1248 dnl       If "default flags" is an empty string, the effect is the same
1249 dnl       as --disable or --enable=no.
1250 dnl
1251 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1252   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1253     [pass compiler FLAGS when building debug library],
1254     [case "x$enable_libstdcxx_debug_flags" in
1255       xno | x)    enable_libstdcxx_debug_flags= ;;
1256       x-*)        ;;
1257       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1258      esac])
1259
1260   # Option parsed, now set things appropriately
1261   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1262   AC_SUBST(DEBUG_FLAGS)
1263
1264   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1265 ])
1266
1267
1268 dnl
1269 dnl Check if the user only wants a freestanding library implementation.
1270 dnl
1271 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1272 dnl installing only the headers required by [17.4.1.3] and the language
1273 dnl support library.  More than that will be built (to keep the Makefiles
1274 dnl conveniently clean), but not installed.
1275 dnl
1276 dnl Sets:
1277 dnl  is_hosted  (yes/no)
1278 dnl
1279 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1280   AC_ARG_ENABLE([hosted-libstdcxx],
1281     AC_HELP_STRING([--disable-hosted-libstdcxx],
1282                    [only build freestanding C++ runtime support]),,
1283     [enable_hosted_libstdcxx=yes])
1284   if test "$enable_hosted_libstdcxx" = no; then
1285     AC_MSG_NOTICE([Only freestanding libraries will be built])
1286     is_hosted=no
1287     enable_abi_check=no
1288     enable_libstdcxx_pch=no
1289   else
1290     is_hosted=yes
1291   fi
1292   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1293 ])
1294
1295
1296 dnl
1297 dnl Check for libunwind exception handling support.  If enabled, then
1298 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1299 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1300 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1301 dnl on libunwind as well as libgcc.
1302 dnl
1303 dnl --enable-libunwind-exceptions forces the use of libunwind.
1304 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1305 dnl
1306 dnl Substs:
1307 dnl  LIBUNWIND_FLAG
1308 dnl
1309 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1310   AC_MSG_CHECKING([for use of libunwind])
1311   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1312     [force use of libunwind for exceptions])
1313   AC_MSG_RESULT($use_libunwind_exceptions)
1314   if test $enable_libunwind_exceptions = yes; then
1315     LIBUNWIND_FLAG="-lunwind"
1316   else
1317     LIBUNWIND_FLAG=""
1318   fi
1319   AC_SUBST(LIBUNWIND_FLAG)
1320 ])
1321
1322
1323 dnl
1324 dnl Check for template specializations for the 'long long' type extension.
1325 dnl The result determines only whether 'long long' I/O is enabled; things
1326 dnl like numeric_limits<> specializations are always available.
1327 dnl
1328 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1329 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1330 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1331 dnl       Where DEFAULT is either `yes' or `no'.
1332 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1333 dnl
1334 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1335   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1336
1337   AC_LANG_SAVE
1338   AC_LANG_CPLUSPLUS
1339
1340   AC_MSG_CHECKING([for enabled long long I/O support])
1341   # iostreams require strtoll, strtoull to compile
1342   AC_TRY_COMPILE([#include <stdlib.h>],
1343                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1344   AC_TRY_COMPILE([#include <stdlib.h>],
1345                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1346
1347   # Option parsed, now set things appropriately
1348   if test $enable_long_long = yes; then
1349     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1350   fi
1351   AC_MSG_RESULT($enable_long_long)
1352
1353   AC_LANG_RESTORE
1354 ])
1355
1356
1357 dnl
1358 dnl Check to see if building and using a C++ precompiled header can be done.
1359 dnl
1360 dnl --enable-libstdcxx-pch=yes
1361 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1362 dnl may work, after some light-hearted attempts to puzzle out compiler
1363 dnl support, flip bits on in include/Makefile.am
1364 dnl
1365 dnl --disable-libstdcxx-pch
1366 dnl turns off attempts to use or build stdc++.h.gch.
1367 dnl
1368 dnl Substs:
1369 dnl  glibcxx_PCHFLAGS
1370 dnl
1371 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1372   AC_MSG_CHECKING([for enabled PCH])
1373   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1374   AC_MSG_RESULT([$enable_libstdcxx_pch])
1375
1376   if test $enable_libstdcxx_pch = yes; then
1377     AC_CACHE_CHECK([for compiler with PCH support],
1378       [glibcxx_cv_prog_CXX_pch],
1379       [ac_save_CXXFLAGS="$CXXFLAGS"
1380        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1381        AC_LANG_SAVE
1382        AC_LANG_CPLUSPLUS
1383        echo '#include <math.h>' > conftest.h
1384        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1385                           -o conftest.h.gch 1>&5 2>&1 &&
1386                 echo '#error "pch failed"' > conftest.h &&
1387           echo '#include "conftest.h"' > conftest.cc &&
1388                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1389        then
1390          glibcxx_cv_prog_CXX_pch=yes
1391        else
1392          glibcxx_cv_prog_CXX_pch=no
1393        fi
1394        rm -f conftest*
1395        CXXFLAGS=$ac_save_CXXFLAGS
1396        AC_LANG_RESTORE
1397       ])
1398     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1399   fi
1400
1401   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1402   if test $enable_libstdcxx_pch = yes; then
1403     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1404   else
1405     glibcxx_PCHFLAGS=""
1406   fi
1407   AC_SUBST(glibcxx_PCHFLAGS)
1408 ])
1409
1410
1411 dnl
1412 dnl Check for exception handling support.  If an explicit enable/disable
1413 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1414 dnl target may or may not support call frame exceptions.
1415 dnl
1416 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1417 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1418 dnl Neither one forces an attempt at detection.
1419 dnl
1420 dnl Defines:
1421 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1422 dnl
1423 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1424   AC_MSG_CHECKING([for exception model to use])
1425   AC_LANG_SAVE
1426   AC_LANG_CPLUSPLUS
1427   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1428     [force use of builtin_setjmp for exceptions],
1429     [permit yes|no|auto])
1430
1431   if test $enable_sjlj_exceptions = auto; then
1432     # Botheration.  Now we've got to detect the exception model.  Link tests
1433     # against libgcc.a are problematic since we've not been given proper -L
1434     # bits for single-tree newlib and libgloss.
1435     #
1436     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1437     cat > conftest.$ac_ext << EOF
1438 [#]line __oline__ "configure"
1439 struct S { ~S(); };
1440 void bar();
1441 void foo()
1442 {
1443   S s;
1444   bar();
1445 }
1446 EOF
1447     old_CXXFLAGS="$CXXFLAGS"
1448     CXXFLAGS=-S
1449     if AC_TRY_EVAL(ac_compile); then
1450       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1451         enable_sjlj_exceptions=yes
1452       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1453         enable_sjlj_exceptions=no
1454       fi
1455     fi
1456     CXXFLAGS="$old_CXXFLAGS"
1457     rm -f conftest*
1458   fi
1459
1460   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1461   # to two different models.
1462   case $enable_sjlj_exceptions in
1463     yes)
1464       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1465         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1466       ac_exception_model_name=sjlj
1467       ;;
1468     no)
1469       ac_exception_model_name="call frame"
1470       ;;
1471     *)
1472       AC_MSG_ERROR([unable to detect exception model])
1473       ;;
1474   esac
1475  AC_LANG_RESTORE
1476  AC_MSG_RESULT($ac_exception_model_name)
1477 ])
1478
1479
1480 dnl
1481 dnl Add version tags to symbols in shared library (or not), additionally
1482 dnl marking other symbols as private/local (or not).
1483 dnl
1484 dnl --enable-symvers=style adds a version script to the linker call when
1485 dnl       creating the shared library.  The choice of version script is
1486 dnl       controlled by 'style'.
1487 dnl --disable-symvers does not.
1488 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1489 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1490 dnl       choose a default style based on linker characteristics.  Passing
1491 dnl       'no' disables versioning.
1492 dnl
1493 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1494
1495 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1496   [enables symbol versioning of the shared library],
1497   [permit yes|no|gnu])
1498
1499 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1500 # don't know enough about $LD to do tricks...
1501 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1502 # FIXME  The following test is too strict, in theory.
1503 if test $enable_shared = no ||
1504         test "x$LD" = x ||
1505         test x$glibcxx_gnu_ld_version = x; then
1506   enable_symvers=no
1507 fi
1508
1509 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1510 if test $enable_symvers != no; then
1511   AC_MSG_CHECKING([for shared libgcc])
1512   ac_save_CFLAGS="$CFLAGS"
1513   CFLAGS=' -lgcc_s'
1514   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1515   CFLAGS="$ac_save_CFLAGS"
1516   AC_MSG_RESULT($glibcxx_shared_libgcc)
1517 fi
1518
1519 # For GNU ld, we need at least this version.  The format is described in
1520 # GLIBCXX_CHECK_LINKER_FEATURES above.
1521 glibcxx_min_gnu_ld_version=21400
1522 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1523
1524 # Check to see if unspecified "yes" value can win, given results above.
1525 # Change "yes" into either "no" or a style name.
1526 if test $enable_symvers = yes; then
1527   if test $with_gnu_ld = yes &&
1528      test $glibcxx_shared_libgcc = yes;
1529   then
1530     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1531       enable_symvers=gnu
1532     else
1533       # The right tools, the right setup, but too old.  Fallbacks?
1534       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1535       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1536       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1537       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1538       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1539         # Globbing fix is present, proper block support is not.
1540         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1541         dnl enable_symvers=???
1542         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1543         enable_symvers=no
1544       else
1545         # 2.11 or older.
1546         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1547         enable_symvers=no
1548       fi
1549     fi
1550   else
1551     # just fail for now
1552     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1553     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1554     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1555     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1556     enable_symvers=no
1557   fi
1558 fi
1559
1560 # Everything parsed; figure out what file to use.
1561 case $enable_symvers in
1562   no)
1563     SYMVER_MAP=config/linker-map.dummy
1564     ;;
1565   gnu)
1566     SYMVER_MAP=config/linker-map.gnu
1567     AC_DEFINE(_GLIBCXX_SYMVER)
1568     ;;
1569 esac
1570
1571 AC_SUBST(SYMVER_MAP)
1572 AC_SUBST(port_specific_symbol_files)
1573 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1574 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1575 ])
1576
1577
1578 dnl
1579 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1580 dnl We must stage the required headers so that they will be installed
1581 dnl with the library (unlike libgcc, the STL implementation is provided
1582 dnl solely within headers).  Since we must not inject random user-space
1583 dnl macro names into user-provided C++ code, we first stage into <file>-in
1584 dnl and process to <file> with an output command.  The reason for a two-
1585 dnl stage process here is to correctly handle $srcdir!=$objdir without
1586 dnl having to write complex code (the sed commands to clean the macro
1587 dnl namespace are complex and fragile enough as it is).  We must also
1588 dnl add a relative path so that -I- is supported properly.
1589 dnl
1590 dnl Substs:
1591 dnl  glibcxx_thread_h
1592 dnl
1593 dnl Defines:
1594 dnl  HAVE_GTHR_DEFAULT
1595 dnl  _GLIBCXX_SUPPORTS_WEAK
1596 dnl
1597 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1598   AC_MSG_CHECKING([for thread model used by GCC])
1599   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1600   AC_MSG_RESULT([$target_thread_file])
1601
1602   if test $target_thread_file != single; then
1603     AC_DEFINE(HAVE_GTHR_DEFAULT)
1604     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1605   fi
1606
1607   glibcxx_thread_h=gthr-$target_thread_file.h
1608   AC_SUBST(glibcxx_thread_h)
1609 ])
1610
1611
1612 # Check whether LC_MESSAGES is available in <locale.h>.
1613 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1614 #
1615 # This file file be copied and used freely without restrictions.  It can
1616 # be used in projects which are not available under the GNU Public License
1617 # but which still want to provide support for the GNU gettext functionality.
1618 # Please note that the actual code is *not* freely available.
1619
1620 # serial 1
1621 AC_DEFUN(AC_LC_MESSAGES, [
1622   AC_CHECK_HEADER(locale.h, [
1623     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1624       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1625        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1626     if test $ac_cv_val_LC_MESSAGES = yes; then
1627       AC_DEFINE(HAVE_LC_MESSAGES)
1628     fi
1629   ])
1630 ])
1631
1632
1633 sinclude([../libtool.m4])
1634 dnl The lines below arrange for aclocal not to bring an installed
1635 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1636 dnl add a definition of LIBTOOL to Makefile.in.
1637 ifelse(,,,[AC_SUBST(LIBTOOL)
1638 AC_DEFUN([AM_PROG_LIBTOOL])
1639 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1640 AC_DEFUN([AC_PROG_LD])
1641 ])
1642
1643 dnl vim:et:ts=2:sw=2