libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  27   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN(GLIBCXX_CONFIGURE, [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 387     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     # Checks for wide character functions that are not required
 394     # for basic wchar_t support.  Don't disable support if they are missing.
 395     # Injection of these is wrapped with guard macros.
 396     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 397
 398     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 399     if test x"$has_weof" = xyes &&
 400        test x"$has_wchar_minmax" = xyes &&
 401        test x"$ac_wfuncs" = xyes;
 402     then
 403       ac_isoC99_wchar_t=yes
 404     else
 405       ac_isoC99_wchar_t=no
 406     fi
 407     AC_MSG_RESULT($ac_isoC99_wchar_t)
 408
 409     # Use iconv for wchar_t to char conversions. As such, check for
 410     # X/Open Portability Guide, version 2 features (XPG2).
 411     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 412     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 413
 414     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 415     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 416     ac_save_LIBS="$LIBS"
 417     LIBS="$LIBS $libiconv"
 418
 419     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 420     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 421
 422     LIBS="$ac_save_LIBS"
 423
 424     AC_MSG_CHECKING([for XPG2 wchar_t support])
 425     if test x"$ac_has_iconv_h" = xyes &&
 426        test x"$ac_has_langinfo_h" = xyes &&
 427        test x"$ac_XPG2funcs" = xyes;
 428     then
 429       ac_XPG2_wchar_t=yes
 430     else
 431       ac_XPG2_wchar_t=no
 432     fi
 433     AC_MSG_RESULT($ac_XPG2_wchar_t)
 434
 435     # At the moment, only enable wchar_t specializations if all the
 436     # above support is present.
 437     if test x"$ac_isoC99_wchar_t" = xyes &&
 438        test x"$ac_XPG2_wchar_t" = xyes;
 439     then
 440       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 441       enable_wchar_t=yes
 442     fi
 443   fi
 444   AC_MSG_CHECKING([for enabled wchar_t specializations])
 445   AC_MSG_RESULT($enable_wchar_t)
 446 ])
 447
 448
 449 dnl
 450 dnl Check for headers for, and arguments to, the setrlimit() function.
 451 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 452 dnl
 453 dnl Defines:
 454 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 455 dnl  various HAVE_MEMLIMIT_* for individual limit names
 456 dnl
 457 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 458   AC_TRY_COMPILE(
 459     [#include <unistd.h>
 460      #include <sys/time.h>
 461      #include <sys/resource.h>
 462     ],
 463     [ int f = RLIMIT_$1 ; ],
 464     [glibcxx_mresult=1], [glibcxx_mresult=0])
 465   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 466                      [Only used in build directory testsuite_hooks.h.])
 467 ])
 468
 469 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 470   setrlimit_have_headers=yes
 471   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 472                    [],
 473                    [setrlimit_have_headers=no])
 474   # If don't have the headers, then we can't run the tests now, and we
 475   # won't be seeing any of these during testsuite compilation.
 476   if test $setrlimit_have_headers = yes; then
 477     # Can't do these in a loop, else the resulting syntax is wrong.
 478     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 479     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 480     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 481     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 482
 483     # Check for rlimit, setrlimit.
 484     AC_CACHE_VAL(ac_setrlimit, [
 485       AC_TRY_COMPILE(
 486         [#include <unistd.h>
 487          #include <sys/time.h>
 488          #include <sys/resource.h>
 489         ],
 490         [struct rlimit r;
 491          setrlimit(0, &r);],
 492         [ac_setrlimit=yes], [ac_setrlimit=no])
 493     ])
 494   fi
 495
 496   AC_MSG_CHECKING([for testsuite memory limit support])
 497   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 498     ac_mem_limits=yes
 499     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 500   else
 501     ac_mem_limits=no
 502   fi
 503   AC_MSG_RESULT($ac_mem_limits)
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 509 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 510 dnl
 511 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 512   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 513     AC_TRY_LINK(
 514       [#include <sys/stat.h>],
 515       [struct stat buffer;
 516        fstat(0, &buffer);
 517        S_ISREG(buffer.st_mode);],
 518       [glibcxx_cv_S_ISREG=yes],
 519       [glibcxx_cv_S_ISREG=no])
 520   ])
 521   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 522     AC_TRY_LINK(
 523       [#include <sys/stat.h>],
 524       [struct stat buffer;
 525        fstat(0, &buffer);
 526        S_IFREG & buffer.st_mode;],
 527       [glibcxx_cv_S_IFREG=yes],
 528       [glibcxx_cv_S_IFREG=no])
 529   ])
 530   if test $glibcxx_cv_S_ISREG = yes; then
 531     AC_DEFINE(HAVE_S_ISREG)
 532   elif test $glibcxx_cv_S_IFREG = yes; then
 533     AC_DEFINE(HAVE_S_IFREG)
 534   fi
 535 ])
 536
 537
 538 dnl
 539 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 540 dnl
 541 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 542   AC_CACHE_VAL(glibcxx_cv_POLL, [
 543     AC_TRY_LINK(
 544       [#include <poll.h>],
 545       [struct pollfd pfd[1];
 546        pfd[0].events = POLLIN;
 547        poll(pfd, 1, 0);],
 548       [glibcxx_cv_POLL=yes],
 549       [glibcxx_cv_POLL=no])
 550   ])
 551   if test $glibcxx_cv_POLL = yes; then
 552     AC_DEFINE(HAVE_POLL)
 553   fi
 554 ])
 555
 556
 557 dnl
 558 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 559 dnl
 560 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 561   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 562     AC_TRY_LINK(
 563       [#include <sys/uio.h>],
 564       [struct iovec iov[2];
 565        writev(0, iov, 0);],
 566       [glibcxx_cv_WRITEV=yes],
 567       [glibcxx_cv_WRITEV=no])
 568   ])
 569   if test $glibcxx_cv_WRITEV = yes; then
 570     AC_DEFINE(HAVE_WRITEV)
 571   fi
 572 ])
 573
 574
 575 dnl
 576 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 577 dnl
 578 AC_DEFUN(GLIBCXX_CHECK_INT64_T, [
 579   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 580     AC_TRY_COMPILE(
 581       [#include <stdint.h>],
 582       [int64_t var;],
 583       [glibcxx_cv_INT64_T=yes],
 584       [glibcxx_cv_INT64_T=no])
 585   ])
 586   if test $glibcxx_cv_INT64_T = yes; then
 587     AC_DEFINE(HAVE_INT64_T)
 588   fi
 589 ])
 590
 591
 592 dnl
 593 dnl Check whether LFS support is available.
 594 dnl
 595 AC_DEFUN(GLIBCXX_CHECK_LFS, [
 596   AC_LANG_SAVE
 597   AC_LANG_CPLUSPLUS
 598   AC_CACHE_VAL(glibcxx_cv_LFS, [
 599     AC_TRY_LINK(
 600       [#include <unistd.h>
 601        #include <stdio.h>
 602       ],
 603       [FILE* fp;
 604        fopen64("t", "w");
 605        fseeko64(fp, 0, SEEK_CUR);
 606        ftello64(fp);
 607        lseek64(1, 0, SEEK_CUR);],
 608       [glibcxx_cv_LFS=yes],
 609       [glibcxx_cv_LFS=no])
 610   ])
 611   if test $glibcxx_cv_LFS = yes; then
 612     AC_DEFINE(_GLIBCXX_USE_LFS)
 613   fi
 614   AC_LANG_RESTORE
 615 ])
 616
 617
 618 dnl
 619 dnl Does any necessary configuration of the testsuite directory.  Generates
 620 dnl the testsuite_hooks.h header.
 621 dnl
 622 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 623 dnl
 624 dnl Sets:
 625 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 626 dnl Substs:
 627 dnl  baseline_dir
 628 dnl
 629 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 630   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 631     # Do checks for memory limit functions.
 632     GLIBCXX_CHECK_SETRLIMIT
 633
 634     # Look for setenv, so that extended locale tests can be performed.
 635     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 636
 637     if test $enable_symvers = no; then
 638       enable_abi_check=no
 639     else
 640       case "$host" in
 641         *-*-cygwin*)
 642           enable_abi_check=no ;;
 643         *)
 644           enable_abi_check=yes ;;
 645       esac
 646     fi
 647   else
 648     # Only build this as native, since automake does not understand
 649     # CXX_FOR_BUILD.
 650     enable_abi_check=no
 651   fi
 652
 653   # Export file names for ABI checking.
 654   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 655   AC_SUBST(baseline_dir)
 656
 657   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 658   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 659 ])
 660
 661
 662 dnl
 663 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 664 dnl
 665 dnl Substs:
 666 dnl  GLIBCXX_INCLUDES
 667 dnl  TOPLEVEL_INCLUDES
 668 dnl
 669 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 670   # Used for every C++ compile we perform.
 671   GLIBCXX_INCLUDES="\
 672 -I$glibcxx_builddir/include/$host_alias \
 673 -I$glibcxx_builddir/include \
 674 -I$glibcxx_srcdir/libsupc++"
 675
 676   # For Canadian crosses, pick this up too.
 677   if test $CANADIAN = yes; then
 678     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 679   fi
 680
 681   # Stuff in the actual top level.  Currently only used by libsupc++ to
 682   # get unwind* headers from the gcc dir.
 683   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 684   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 685
 686   # Now, export this to all the little Makefiles....
 687   AC_SUBST(GLIBCXX_INCLUDES)
 688   AC_SUBST(TOPLEVEL_INCLUDES)
 689 ])
 690
 691
 692 dnl
 693 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 694 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 695 dnl
 696 dnl Substs:
 697 dnl  OPTIMIZE_CXXFLAGS
 698 dnl  WARN_FLAGS
 699 dnl
 700 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 701   # Optimization flags that are probably a good idea for thrill-seekers. Just
 702   # uncomment the lines below and make, everything else is ready to go...
 703   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 704   OPTIMIZE_CXXFLAGS=
 705   AC_SUBST(OPTIMIZE_CXXFLAGS)
 706
 707   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 708   AC_SUBST(WARN_FLAGS)
 709 ])
 710
 711
 712 dnl
 713 dnl All installation directory information is determined here.
 714 dnl
 715 dnl Substs:
 716 dnl  gxx_install_dir
 717 dnl  glibcxx_prefixdir
 718 dnl  glibcxx_toolexecdir
 719 dnl  glibcxx_toolexeclibdir
 720 dnl
 721 dnl Assumes cross_compiling bits already done, and with_cross_host in
 722 dnl particular.
 723 dnl
 724 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 725   glibcxx_toolexecdir=no
 726   glibcxx_toolexeclibdir=no
 727   glibcxx_prefixdir=$prefix
 728
 729   AC_MSG_CHECKING([for gxx-include-dir])
 730   AC_ARG_WITH([gxx-include-dir],
 731     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 732                    [installation directory for include files]),
 733     [case "$withval" in
 734       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 735       no)  gxx_include_dir=no ;;
 736       *)   gxx_include_dir=$withval ;;
 737      esac],
 738     [gxx_include_dir=no])
 739   AC_MSG_RESULT($gxx_include_dir)
 740
 741   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 742   AC_ARG_ENABLE([version-specific-runtime-libs],
 743     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 744                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 745     [case "$enableval" in
 746       yes) version_specific_libs=yes ;;
 747       no)  version_specific_libs=no ;;
 748       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 749      esac],
 750     [version_specific_libs=no])
 751   AC_MSG_RESULT($version_specific_libs)
 752
 753   # Default case for install directory for include files.
 754   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 755     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 756   fi
 757
 758   # Version-specific runtime libs processing.
 759   if test $version_specific_libs = yes; then
 760     # Need the gcc compiler version to know where to install libraries
 761     # and header files if --enable-version-specific-runtime-libs option
 762     # is selected.
 763     if test x"$gxx_include_dir" = x"no"; then
 764       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 765     fi
 766     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 767     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 768   fi
 769
 770   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 771   # Install a library built with a cross compiler in tooldir, not libdir.
 772   if test x"$glibcxx_toolexecdir" = x"no"; then
 773     if test -n "$with_cross_host" &&
 774        test x"$with_cross_host" != x"no"; then
 775       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 776       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 777     else
 778       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 779       glibcxx_toolexeclibdir='${libdir}'
 780     fi
 781     multi_os_directory=`$CXX -print-multi-os-directory`
 782     case $multi_os_directory in
 783       .) ;; # Avoid trailing /.
 784       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 785     esac
 786   fi
 787
 788   AC_MSG_CHECKING([for install location])
 789   AC_MSG_RESULT($gxx_include_dir)
 790
 791   AC_SUBST(glibcxx_prefixdir)
 792   AC_SUBST(gxx_include_dir)
 793   AC_SUBST(glibcxx_toolexecdir)
 794   AC_SUBST(glibcxx_toolexeclibdir)
 795 ])
 796
 797
 798 dnl
 799 dnl GLIBCXX_ENABLE
 800 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 801 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 802 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 803 dnl
 804 dnl See docs/html/17_intro/configury.html#enable for documentation.
 805 dnl
 806 m4_define([GLIBCXX_ENABLE],[dnl
 807 m4_define([_g_switch],[--enable-$1])dnl
 808 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 809  AC_ARG_ENABLE($1,_g_help,
 810   m4_bmatch([$5],
 811    [^permit ],
 812      [[
 813       case "$enableval" in
 814        m4_bpatsubst([$5],[permit ])) ;;
 815        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 816           dnl Idea for future:  generate a URL pointing to
 817           dnl "onlinedocs/configopts.html#whatever"
 818       esac
 819      ]],
 820    [^$],
 821      [[
 822       case "$enableval" in
 823        yes|no) ;;
 824        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 825       esac
 826      ]],
 827    [[$5]]),
 828   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 829 m4_undefine([_g_switch])dnl
 830 m4_undefine([_g_help])dnl
 831 ])
 832
 833
 834 dnl
 835 dnl Check for ISO/IEC 9899:1999 "C99" support.
 836 dnl
 837 dnl --enable-c99 defines _GLIBCXX_USE_C99
 838 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 839 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 840 dnl       Where DEFAULT is either `yes' or `no'.
 841 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 842 dnl
 843 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 844   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 845
 846   AC_LANG_SAVE
 847   AC_LANG_CPLUSPLUS
 848
 849   # Check for the existence of <math.h> functions used if C99 is enabled.
 850   ac_c99_math=yes;
 851   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 852   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 853   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 856   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],
 860                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 861   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],
 864                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 865   AC_TRY_COMPILE([#include <math.h>],
 866                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 867   AC_MSG_RESULT($ac_c99_math)
 868
 869   if test x"$ac_c99_math" = x"yes"; then
 870     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 871   fi
 872
 873   # Check for the existence in <stdio.h> of vscanf, et. al.
 874   ac_c99_stdio=yes;
 875   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 876   AC_TRY_COMPILE([#include <stdio.h>],
 877                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 878   AC_TRY_COMPILE([#include <stdio.h>
 879                   #include <stdarg.h>
 880                   void foo(char* fmt, ...)
 881                   {va_list args; va_start(args, fmt);
 882                   vfscanf(stderr, "%i", args);}],
 883                   [],, [ac_c99_stdio=no])
 884   AC_TRY_COMPILE([#include <stdio.h>
 885                   #include <stdarg.h>
 886                   void foo(char* fmt, ...)
 887                   {va_list args; va_start(args, fmt);
 888                   vscanf("%i", args);}],
 889                   [],, [ac_c99_stdio=no])
 890   AC_TRY_COMPILE([#include <stdio.h>
 891                   #include <stdarg.h>
 892                   void foo(char* fmt, ...)
 893                   {va_list args; va_start(args, fmt);
 894                   vsnprintf(fmt, 0, "%i", args);}],
 895                   [],, [ac_c99_stdio=no])
 896   AC_TRY_COMPILE([#include <stdio.h>
 897                   #include <stdarg.h>
 898                   void foo(char* fmt, ...)
 899                   {va_list args; va_start(args, fmt);
 900                   vsscanf(fmt, "%i", args);}],
 901                   [],, [ac_c99_stdio=no])
 902   AC_MSG_RESULT($ac_c99_stdio)
 903
 904   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 905   ac_c99_stdlib=yes;
 906   AC_MSG_CHECKING([for lldiv_t declaration])
 907   AC_CACHE_VAL(ac_c99_lldiv_t, [
 908   AC_TRY_COMPILE([#include <stdlib.h>],
 909                    [ lldiv_t mydivt;],
 910                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 911   ])
 912   AC_MSG_RESULT($ac_c99_lldiv_t)
 913
 914   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 915   AC_TRY_COMPILE([#include <stdlib.h>],
 916                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 917   AC_TRY_COMPILE([#include <stdlib.h>],
 918                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 919   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 920   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 921   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 922   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 923   if test x"$ac_c99_lldiv_t" = x"no"; then
 924     ac_c99_stdlib=no;
 925   fi;
 926   AC_MSG_RESULT($ac_c99_stdlib)
 927
 928   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 929   # XXX the wchar.h checks should be rolled into the general C99 bits.
 930   ac_c99_wchar=yes;
 931   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 932   AC_TRY_COMPILE([#include <wchar.h>],
 933                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 934   AC_TRY_COMPILE([#include <wchar.h>],
 935                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 936   AC_TRY_COMPILE([#include <wchar.h>],
 937                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 938   AC_MSG_RESULT($ac_c99_wchar)
 939
 940   AC_MSG_CHECKING([for enabled ISO C99 support])
 941   if test x"$ac_c99_math" = x"no" ||
 942      test x"$ac_c99_stdio" = x"no" ||
 943      test x"$ac_c99_stdlib" = x"no" ||
 944      test x"$ac_c99_wchar" = x"no"; then
 945     enable_c99=no;
 946   fi;
 947   AC_MSG_RESULT($enable_c99)
 948
 949   if test x"$ac_99_math" = x"yes"; then
 950     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 951   fi
 952
 953   # Option parsed, now set things appropriately
 954   if test x"$enable_c99" = x"yes"; then
 955     AC_DEFINE(_GLIBCXX_USE_C99)
 956   fi
 957
 958   AC_LANG_RESTORE
 959 ])
 960
 961
 962 dnl
 963 dnl Check for what type of C headers to use.
 964 dnl
 965 dnl --enable-cheaders= [does stuff].
 966 dnl --disable-cheaders [does not do anything, really].
 967 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 968 dnl       Where DEFAULT is either `c' or `c_std'.
 969 dnl
 970 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 971   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 972     [construct "C" headers for g++], [permit c|c_std])
 973   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 974
 975   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 976
 977   AC_SUBST(C_INCLUDE_DIR)
 978   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 979   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 980   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 981 ])
 982
 983
 984 dnl
 985 dnl Check for which locale library to use.  The choice is mapped to
 986 dnl a subdirectory of config/locale.
 987 dnl
 988 dnl Default is generic.
 989 dnl
 990 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 991   AC_MSG_CHECKING([for C locale to use])
 992   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 993     [use MODEL for target locale package],
 994     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 995
 996   # If they didn't use this option switch, or if they specified --enable
 997   # with no specific model, we'll have to look for one.  If they
 998   # specified --disable (???), do likewise.
 999   if test $enable_clocale = no || test $enable_clocale = yes; then
1000      enable_clocale=auto
1001   fi
1002
1003   # Either a known package, or "auto"
1004   enable_clocale_flag=$enable_clocale
1005
1006   # Probe for locale support if no specific model is specified.
1007   # Default to "generic".
1008   if test $enable_clocale_flag = auto; then
1009     case x${target_os} in
1010       xlinux* | xgnu* | xkfreebsd*-gnu | xknetbsd*-gnu)
1011         AC_EGREP_CPP([_GLIBCXX_ok], [
1012         #include <features.h>
1013         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1014           _GLIBCXX_ok
1015         #endif
1016         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1017
1018         # Test for bugs early in glibc-2.2.x series
1019           if test x$enable_clocale_flag = xgnu; then
1020           AC_TRY_RUN([
1021           #define _GNU_SOURCE 1
1022           #include <locale.h>
1023           #include <string.h>
1024           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1025           extern __typeof(newlocale) __newlocale;
1026           extern __typeof(duplocale) __duplocale;
1027           extern __typeof(strcoll_l) __strcoll_l;
1028           #endif
1029           int main()
1030           {
1031               const char __one[] = "Äuglein Augmen";
1032               const char __two[] = "Äuglein";
1033               int i;
1034               int j;
1035               __locale_t        loc;
1036                __locale_t        loc_dup;
1037               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1038               loc_dup = __duplocale(loc);
1039               i = __strcoll_l(__one, __two, loc);
1040               j = __strcoll_l(__one, __two, loc_dup);
1041               return 0;
1042           }
1043           ],
1044           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1045           [enable_clocale_flag=generic])
1046           fi
1047
1048         # ... at some point put __strxfrm_l tests in as well.
1049         ;;
1050       *)
1051         enable_clocale_flag=generic
1052         ;;
1053     esac
1054   fi
1055
1056   # Deal with gettext issues.  Default to not using it (=no) until we detect
1057   # support for it later.  Let the user turn it off via --e/d, but let that
1058   # default to on for easier handling.
1059   USE_NLS=no
1060   AC_ARG_ENABLE(nls,
1061     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1062     [],
1063     [enable_nls=yes])
1064
1065   # Set configure bits for specified locale package
1066   case ${enable_clocale_flag} in
1067     generic)
1068       AC_MSG_RESULT(generic)
1069
1070       CLOCALE_H=config/locale/generic/c_locale.h
1071       CLOCALE_CC=config/locale/generic/c_locale.cc
1072       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1073       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1074       CCOLLATE_CC=config/locale/generic/collate_members.cc
1075       CCTYPE_CC=config/locale/generic/ctype_members.cc
1076       CMESSAGES_H=config/locale/generic/messages_members.h
1077       CMESSAGES_CC=config/locale/generic/messages_members.cc
1078       CMONEY_CC=config/locale/generic/monetary_members.cc
1079       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1080       CTIME_H=config/locale/generic/time_members.h
1081       CTIME_CC=config/locale/generic/time_members.cc
1082       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1083       ;;
1084     gnu)
1085       AC_MSG_RESULT(gnu)
1086
1087       # Declare intention to use gettext, and add support for specific
1088       # languages.
1089       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1090       ALL_LINGUAS="de fr"
1091
1092       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1093       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1094       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1095         USE_NLS=yes
1096       fi
1097       # Export the build objects.
1098       for ling in $ALL_LINGUAS; do \
1099         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1100         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1101       done
1102       AC_SUBST(glibcxx_MOFILES)
1103       AC_SUBST(glibcxx_POFILES)
1104
1105       CLOCALE_H=config/locale/gnu/c_locale.h
1106       CLOCALE_CC=config/locale/gnu/c_locale.cc
1107       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1108       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1109       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1110       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1111       CMESSAGES_H=config/locale/gnu/messages_members.h
1112       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1113       CMONEY_CC=config/locale/gnu/monetary_members.cc
1114       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1115       CTIME_H=config/locale/gnu/time_members.h
1116       CTIME_CC=config/locale/gnu/time_members.cc
1117       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1118       ;;
1119     ieee_1003.1-2001)
1120       AC_MSG_RESULT(IEEE 1003.1)
1121
1122       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1123       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1124       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1125       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1126       CCOLLATE_CC=config/locale/generic/collate_members.cc
1127       CCTYPE_CC=config/locale/generic/ctype_members.cc
1128       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1129       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1130       CMONEY_CC=config/locale/generic/monetary_members.cc
1131       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1132       CTIME_H=config/locale/generic/time_members.h
1133       CTIME_CC=config/locale/generic/time_members.cc
1134       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1135       ;;
1136   esac
1137
1138   # This is where the testsuite looks for locale catalogs, using the
1139   # -DLOCALEDIR define during testsuite compilation.
1140   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1141   AC_SUBST(glibcxx_localedir)
1142
1143   # A standalone libintl (e.g., GNU libintl) may be in use.
1144   if test $USE_NLS = yes; then
1145     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1146     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1147   fi
1148   if test $USE_NLS = yes; then
1149     AC_DEFINE(_GLIBCXX_USE_NLS)
1150   fi
1151
1152   AC_SUBST(USE_NLS)
1153   AC_SUBST(CLOCALE_H)
1154   AC_SUBST(CCODECVT_H)
1155   AC_SUBST(CMESSAGES_H)
1156   AC_SUBST(CCODECVT_CC)
1157   AC_SUBST(CCOLLATE_CC)
1158   AC_SUBST(CCTYPE_CC)
1159   AC_SUBST(CMESSAGES_CC)
1160   AC_SUBST(CMONEY_CC)
1161   AC_SUBST(CNUMERIC_CC)
1162   AC_SUBST(CTIME_H)
1163   AC_SUBST(CTIME_CC)
1164   AC_SUBST(CLOCALE_CC)
1165   AC_SUBST(CLOCALE_INTERNAL_H)
1166 ])
1167
1168
1169 dnl
1170 dnl Check for whether the Boost-derived checks should be turned on.
1171 dnl
1172 dnl --enable-concept-checks turns them on.
1173 dnl --disable-concept-checks leaves them off.
1174 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1175 dnl       Where DEFAULT is either `yes' or `no'.
1176 dnl
1177 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1178   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1179   if test $enable_concept_checks = yes; then
1180     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1181   fi
1182 ])
1183
1184
1185 dnl
1186 dnl Check for which I/O library to use:  stdio, or something specific.
1187 dnl
1188 dnl Default is stdio.
1189 dnl
1190 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1191   AC_MSG_CHECKING([for underlying I/O to use])
1192   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1193     [use target-specific I/O package], [permit stdio])
1194
1195   # Now that libio has been removed, you can have any color you want as long
1196   # as it's black.  This is one big no-op until other packages are added, but
1197   # showing the framework never hurts.
1198   case ${enable_cstdio} in
1199     stdio)
1200       CSTDIO_H=config/io/c_io_stdio.h
1201       BASIC_FILE_H=config/io/basic_file_stdio.h
1202       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1203       AC_MSG_RESULT(stdio)
1204       ;;
1205   esac
1206
1207   AC_SUBST(CSTDIO_H)
1208   AC_SUBST(BASIC_FILE_H)
1209   AC_SUBST(BASIC_FILE_CC)
1210 ])
1211
1212
1213 dnl
1214 dnl Check for "unusual" flags to pass to the compiler while building.
1215 dnl
1216 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1217 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1218 dnl --disable-cxx-flags passes nothing.
1219 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1220 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1221 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1222 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1223 dnl       If "default flags" is an empty string, the effect is the same
1224 dnl       as --disable or --enable=no.
1225 dnl
1226 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1227   AC_MSG_CHECKING([for extra compiler flags for building])
1228   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1229     [pass compiler FLAGS when building library],
1230     [case "x$enable_cxx_flags" in
1231       xno | x)   enable_cxx_flags= ;;
1232       x-*)       ;;
1233       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1234      esac])
1235
1236   # Run through flags (either default or command-line) and set anything
1237   # extra (e.g., #defines) that must accompany particular g++ options.
1238   if test -n "$enable_cxx_flags"; then
1239     for f in $enable_cxx_flags; do
1240       case "$f" in
1241         -fhonor-std)  ;;
1242         -*)  ;;
1243         *)   # and we're trying to pass /what/ exactly?
1244              AC_MSG_ERROR([compiler flags start with a -]) ;;
1245       esac
1246     done
1247   fi
1248
1249   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1250   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1251   AC_SUBST(EXTRA_CXX_FLAGS)
1252 ])
1253
1254
1255 dnl
1256 dnl Check for wide character support.  Has the same effect as the option
1257 dnl in gcc's configure, but in a form that autoconf can mess with.
1258 dnl
1259 dnl --enable-c-mbchar requests all the wchar_t stuff.
1260 dnl --disable-c-mbchar doesn't.
1261 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1262 dnl       Where DEFAULT is either `yes' or `no'.
1263 dnl
1264 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1265   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1266   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1267 ])
1268
1269
1270 dnl
1271 dnl Check to see if debugging libraries are to be built.
1272 dnl
1273 dnl --enable-libstdcxx-debug
1274 dnl builds a separate set of debugging libraries in addition to the
1275 dnl normal (shared, static) libstdc++ binaries.
1276 dnl
1277 dnl --disable-libstdcxx-debug
1278 dnl builds only one (non-debug) version of libstdc++.
1279 dnl
1280 dnl --enable-libstdcxx-debug-flags=FLAGS
1281 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1282 dnl
1283 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1284 dnl       Where DEFAULT is either `yes' or `no'.
1285 dnl
1286 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1287   AC_MSG_CHECKING([for additional debug build])
1288   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1289   AC_MSG_RESULT($enable_libstdcxx_debug)
1290   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1291 ])
1292
1293
1294 dnl
1295 dnl Check for explicit debug flags.
1296 dnl
1297 dnl --enable-libstdcxx-debug-flags='-O1'
1298 dnl is a general method for passing flags to be used when
1299 dnl building debug libraries with --enable-debug.
1300 dnl
1301 dnl --disable-libstdcxx-debug-flags does nothing.
1302 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1303 dnl       If "default flags" is an empty string, the effect is the same
1304 dnl       as --disable or --enable=no.
1305 dnl
1306 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1307   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1308     [pass compiler FLAGS when building debug library],
1309     [case "x$enable_libstdcxx_debug_flags" in
1310       xno | x)    enable_libstdcxx_debug_flags= ;;
1311       x-*)        ;;
1312       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1313      esac])
1314
1315   # Option parsed, now set things appropriately
1316   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1317   AC_SUBST(DEBUG_FLAGS)
1318
1319   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1320 ])
1321
1322
1323 dnl
1324 dnl Check if the user only wants a freestanding library implementation.
1325 dnl
1326 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1327 dnl installing only the headers required by [17.4.1.3] and the language
1328 dnl support library.  More than that will be built (to keep the Makefiles
1329 dnl conveniently clean), but not installed.
1330 dnl
1331 dnl Sets:
1332 dnl  is_hosted  (yes/no)
1333 dnl
1334 dnl Defines:
1335 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1336 dnl
1337 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1338   AC_ARG_ENABLE([hosted-libstdcxx],
1339     AC_HELP_STRING([--disable-hosted-libstdcxx],
1340                    [only build freestanding C++ runtime support]),,
1341     [enable_hosted_libstdcxx=yes])
1342   if test "$enable_hosted_libstdcxx" = no; then
1343     AC_MSG_NOTICE([Only freestanding libraries will be built])
1344     is_hosted=no
1345     hosted_define=0
1346     enable_abi_check=no
1347     enable_libstdcxx_pch=no
1348   else
1349     is_hosted=yes
1350     hosted_define=1
1351   fi
1352   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1353   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1354     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1355 ])
1356
1357
1358 dnl
1359 dnl Check for template specializations for the 'long long' type extension.
1360 dnl The result determines only whether 'long long' I/O is enabled; things
1361 dnl like numeric_limits<> specializations are always available.
1362 dnl
1363 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1364 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1365 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1366 dnl       Where DEFAULT is either `yes' or `no'.
1367 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1368 dnl
1369 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1370   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1371
1372   AC_LANG_SAVE
1373   AC_LANG_CPLUSPLUS
1374
1375   AC_MSG_CHECKING([for enabled long long I/O support])
1376   # iostreams require strtoll, strtoull to compile
1377   AC_TRY_COMPILE([#include <stdlib.h>],
1378                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1379   AC_TRY_COMPILE([#include <stdlib.h>],
1380                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1381
1382   # Option parsed, now set things appropriately
1383   if test $enable_long_long = yes; then
1384     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1385   fi
1386   AC_MSG_RESULT($enable_long_long)
1387
1388   AC_LANG_RESTORE
1389 ])
1390
1391
1392 dnl
1393 dnl Check to see if building and using a C++ precompiled header can be done.
1394 dnl
1395 dnl --enable-libstdcxx-pch=yes
1396 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1397 dnl may work, after some light-hearted attempts to puzzle out compiler
1398 dnl support, flip bits on in include/Makefile.am
1399 dnl
1400 dnl --disable-libstdcxx-pch
1401 dnl turns off attempts to use or build stdc++.h.gch.
1402 dnl
1403 dnl Substs:
1404 dnl  glibcxx_PCHFLAGS
1405 dnl
1406 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1407   AC_MSG_CHECKING([for enabled PCH])
1408   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1409   AC_MSG_RESULT([$enable_libstdcxx_pch])
1410
1411   if test $enable_libstdcxx_pch = yes; then
1412     AC_CACHE_CHECK([for compiler with PCH support],
1413       [glibcxx_cv_prog_CXX_pch],
1414       [ac_save_CXXFLAGS="$CXXFLAGS"
1415        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1416        AC_LANG_SAVE
1417        AC_LANG_CPLUSPLUS
1418        echo '#include <math.h>' > conftest.h
1419        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1420                           -o conftest.h.gch 1>&5 2>&1 &&
1421                 echo '#error "pch failed"' > conftest.h &&
1422           echo '#include "conftest.h"' > conftest.cc &&
1423                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1424        then
1425          glibcxx_cv_prog_CXX_pch=yes
1426        else
1427          glibcxx_cv_prog_CXX_pch=no
1428        fi
1429        rm -f conftest*
1430        CXXFLAGS=$ac_save_CXXFLAGS
1431        AC_LANG_RESTORE
1432       ])
1433     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1434   fi
1435
1436   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1437   if test $enable_libstdcxx_pch = yes; then
1438     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1439   else
1440     glibcxx_PCHFLAGS=""
1441   fi
1442   AC_SUBST(glibcxx_PCHFLAGS)
1443 ])
1444
1445
1446 dnl
1447 dnl Check for exception handling support.  If an explicit enable/disable
1448 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1449 dnl target may or may not support call frame exceptions.
1450 dnl
1451 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1452 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1453 dnl Neither one forces an attempt at detection.
1454 dnl
1455 dnl Defines:
1456 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1457 dnl
1458 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1459   AC_MSG_CHECKING([for exception model to use])
1460   AC_LANG_SAVE
1461   AC_LANG_CPLUSPLUS
1462   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1463     [force use of builtin_setjmp for exceptions],
1464     [permit yes|no|auto])
1465
1466   if test $enable_sjlj_exceptions = auto; then
1467     # Botheration.  Now we've got to detect the exception model.  Link tests
1468     # against libgcc.a are problematic since we've not been given proper -L
1469     # bits for single-tree newlib and libgloss.
1470     #
1471     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1472     cat > conftest.$ac_ext << EOF
1473 [#]line __oline__ "configure"
1474 struct S { ~S(); };
1475 void bar();
1476 void foo()
1477 {
1478   S s;
1479   bar();
1480 }
1481 EOF
1482     old_CXXFLAGS="$CXXFLAGS"
1483     CXXFLAGS=-S
1484     if AC_TRY_EVAL(ac_compile); then
1485       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1486         enable_sjlj_exceptions=yes
1487       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1488         enable_sjlj_exceptions=no
1489       fi
1490     fi
1491     CXXFLAGS="$old_CXXFLAGS"
1492     rm -f conftest*
1493   fi
1494
1495   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1496   # to two different models.
1497   case $enable_sjlj_exceptions in
1498     yes)
1499       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1500         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1501       ac_exception_model_name=sjlj
1502       ;;
1503     no)
1504       ac_exception_model_name="call frame"
1505       ;;
1506     *)
1507       AC_MSG_ERROR([unable to detect exception model])
1508       ;;
1509   esac
1510  AC_LANG_RESTORE
1511  AC_MSG_RESULT($ac_exception_model_name)
1512 ])
1513
1514
1515 dnl
1516 dnl Add version tags to symbols in shared library (or not), additionally
1517 dnl marking other symbols as private/local (or not).
1518 dnl
1519 dnl --enable-symvers=style adds a version script to the linker call when
1520 dnl       creating the shared library.  The choice of version script is
1521 dnl       controlled by 'style'.
1522 dnl --disable-symvers does not.
1523 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1524 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1525 dnl       choose a default style based on linker characteristics.  Passing
1526 dnl       'no' disables versioning.
1527 dnl
1528 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1529
1530 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1531   [enables symbol versioning of the shared library],
1532   [permit yes|no|gnu])
1533
1534 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1535 # don't know enough about $LD to do tricks...
1536 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1537 # FIXME  The following test is too strict, in theory.
1538 if test $enable_shared = no ||
1539         test "x$LD" = x ||
1540         test x$glibcxx_gnu_ld_version = x; then
1541   enable_symvers=no
1542 fi
1543
1544 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1545 if test $enable_symvers != no; then
1546   AC_MSG_CHECKING([for shared libgcc])
1547   ac_save_CFLAGS="$CFLAGS"
1548   CFLAGS=' -lgcc_s'
1549   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1550   CFLAGS="$ac_save_CFLAGS"
1551   AC_MSG_RESULT($glibcxx_shared_libgcc)
1552 fi
1553
1554 # For GNU ld, we need at least this version.  The format is described in
1555 # GLIBCXX_CHECK_LINKER_FEATURES above.
1556 glibcxx_min_gnu_ld_version=21400
1557 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1558
1559 # Check to see if unspecified "yes" value can win, given results above.
1560 # Change "yes" into either "no" or a style name.
1561 if test $enable_symvers = yes; then
1562   if test $with_gnu_ld = yes &&
1563      test $glibcxx_shared_libgcc = yes;
1564   then
1565     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1566       enable_symvers=gnu
1567     else
1568       # The right tools, the right setup, but too old.  Fallbacks?
1569       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1570       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1571       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1572       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1573       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1574         # Globbing fix is present, proper block support is not.
1575         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1576         dnl enable_symvers=???
1577         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1578         enable_symvers=no
1579       else
1580         # 2.11 or older.
1581         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1582         enable_symvers=no
1583       fi
1584     fi
1585   else
1586     # just fail for now
1587     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1588     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1589     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1590     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1591     enable_symvers=no
1592   fi
1593 fi
1594
1595 # Everything parsed; figure out what file to use.
1596 case $enable_symvers in
1597   no)
1598     SYMVER_MAP=config/linker-map.dummy
1599     ;;
1600   gnu)
1601     SYMVER_MAP=config/linker-map.gnu
1602     AC_DEFINE(_GLIBCXX_SYMVER)
1603     ;;
1604 esac
1605
1606 AC_SUBST(SYMVER_MAP)
1607 AC_SUBST(port_specific_symbol_files)
1608 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1609 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1610 ])
1611
1612
1613 dnl
1614 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1615 dnl We must stage the required headers so that they will be installed
1616 dnl with the library (unlike libgcc, the STL implementation is provided
1617 dnl solely within headers).  Since we must not inject random user-space
1618 dnl macro names into user-provided C++ code, we first stage into <file>-in
1619 dnl and process to <file> with an output command.  The reason for a two-
1620 dnl stage process here is to correctly handle $srcdir!=$objdir without
1621 dnl having to write complex code (the sed commands to clean the macro
1622 dnl namespace are complex and fragile enough as it is).  We must also
1623 dnl add a relative path so that -I- is supported properly.
1624 dnl
1625 dnl Substs:
1626 dnl  glibcxx_thread_h
1627 dnl
1628 dnl Defines:
1629 dnl  HAVE_GTHR_DEFAULT
1630 dnl  _GLIBCXX_SUPPORTS_WEAK
1631 dnl
1632 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1633   AC_MSG_CHECKING([for thread model used by GCC])
1634   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1635   AC_MSG_RESULT([$target_thread_file])
1636
1637   if test $target_thread_file != single; then
1638     AC_DEFINE(HAVE_GTHR_DEFAULT)
1639     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1640   fi
1641
1642   glibcxx_thread_h=gthr-$target_thread_file.h
1643   AC_SUBST(glibcxx_thread_h)
1644 ])
1645
1646
1647 # Check whether LC_MESSAGES is available in <locale.h>.
1648 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1649 #
1650 # This file file be copied and used freely without restrictions.  It can
1651 # be used in projects which are not available under the GNU Public License
1652 # but which still want to provide support for the GNU gettext functionality.
1653 # Please note that the actual code is *not* freely available.
1654
1655 # serial 1
1656 AC_DEFUN(AC_LC_MESSAGES, [
1657   AC_CHECK_HEADER(locale.h, [
1658     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1659       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1660        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1661     if test $ac_cv_val_LC_MESSAGES = yes; then
1662       AC_DEFINE(HAVE_LC_MESSAGES)
1663     fi
1664   ])
1665 ])
1666
1667
1668 sinclude([../libtool.m4])
1669 dnl The lines below arrange for aclocal not to bring an installed
1670 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1671 dnl add a definition of LIBTOOL to Makefile.in.
1672 ifelse(,,,[AC_SUBST(LIBTOOL)
1673 AC_DEFUN([AM_PROG_LIBTOOL])
1674 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1675 AC_DEFUN([AC_PROG_LD])
1676 ])
1677
1678 dnl vim:et:ts=2:sw=2