libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Find platform-specific directories containing configuration info.
 129   # Also possibly modify flags used elsewhere, as needed by the platform.
 130   GLIBCXX_CHECK_HOST
 131 ])
 132
 133
 134 dnl
 135 dnl Tests for newer compiler features, or features that are present in newer
 136 dnl compiler versions but not older compiler versions still in use, should
 137 dnl be placed here.
 138 dnl
 139 dnl Defines:
 140 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 141 dnl   new inlining code or the new system_header pragma will die on -Werror.
 142 dnl   Leave it out by default and use maint-mode to use it.
 143 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 144 dnl   compiler supports it and the user has not requested debug mode.
 145 dnl
 146 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 147   # All these tests are for C++; save the language and the compiler flags.
 148   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 149   # found in GLIBCXX_CONFIGURE.
 150   AC_LANG_SAVE
 151   AC_LANG_CPLUSPLUS
 152   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 153   ac_save_CXXFLAGS="$CXXFLAGS"
 154
 155   # Check for maintainer-mode bits.
 156   if test x"$USE_MAINTAINER_MODE" = xno; then
 157     WERROR=''
 158   else
 159     WERROR='-Werror'
 160   fi
 161
 162   # Check for -ffunction-sections -fdata-sections
 163   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 164   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 165   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 166   if test "$ac_test_CXXFLAGS" = set; then
 167     CXXFLAGS="$ac_save_CXXFLAGS"
 168   else
 169     # this is the suspicious part
 170     CXXFLAGS=''
 171   fi
 172   if test x"$ac_fdsections" = x"yes"; then
 173     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 174   fi
 175   AC_MSG_RESULT($ac_fdsections)
 176
 177   AC_LANG_RESTORE
 178   AC_SUBST(WERROR)
 179   AC_SUBST(SECTION_FLAGS)
 180 ])
 181
 182
 183 dnl
 184 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 185 dnl the native linker is in use, all variables will be defined to something
 186 dnl safe (like an empty string).
 187 dnl
 188 dnl Defines:
 189 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 190 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 191 dnl  LD (as a side effect of testing)
 192 dnl Sets:
 193 dnl  with_gnu_ld
 194 dnl  glibcxx_gnu_ld_version (possibly)
 195 dnl
 196 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 197 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 198 dnl
 199 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 200   # If we're not using GNU ld, then there's no point in even trying these
 201   # tests.  Check for that first.  We should have already tested for gld
 202   # by now (in libtool), but require it now just to be safe...
 203   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 204   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 205   AC_REQUIRE([AC_PROG_LD])
 206   AC_REQUIRE([AC_PROG_AWK])
 207
 208   # The name set by libtool depends on the version of libtool.  Shame on us
 209   # for depending on an impl detail, but c'est la vie.  Older versions used
 210   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 211   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 212   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 213   # set (hence we're using an older libtool), then set it.
 214   if test x${with_gnu_ld+set} != xset; then
 215     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 216       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 217       with_gnu_ld=no
 218     else
 219       with_gnu_ld=$ac_cv_prog_gnu_ld
 220     fi
 221   fi
 222
 223   # Start by getting the version number.  I think the libtool test already
 224   # does some of this, but throws away the result.
 225   AC_MSG_CHECKING([for ld version])
 226   changequote(,)
 227   ldver=`$LD --version 2>/dev/null | head -1 | \
 228          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 229   changequote([,])
 230   glibcxx_gnu_ld_version=`echo $ldver | \
 231          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 232   AC_MSG_RESULT($glibcxx_gnu_ld_version)
 233
 234   # Set --gc-sections.
 235   glibcxx_gcsections_min_ld=21602
 236   if test x"$with_gnu_ld" = x"yes" &&
 237         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 238
 239     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 240     # NB: This flag only works reliably after 2.16.1. Configure tests
 241     # for this are difficult, so hard wire a value that should work.
 242
 243     # All these tests are for C++, but run with the "C" compiler driver.
 244     # Need to do this so that g++ won't try to link in libstdc++/libsupc++.
 245     ac_test_CFLAGS="${CFLAGS+set}"
 246     ac_save_CFLAGS="$CFLAGS"
 247     CFLAGS='-x c++ -Wl,--gc-sections'
 248
 249     # Check for -Wl,--gc-sections
 250     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 251     AC_TRY_LINK([ int one(void) { return 1; }
 252      int two(void) { return 2; }
 253         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 254     if test "$ac_gcsections" = "yes"; then
 255       rm -f conftest.c
 256       touch conftest.c
 257       if $CC -c conftest.c; then
 258         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 259            grep "Warning: gc-sections option ignored" > /dev/null; then
 260           ac_gcsections=no
 261         fi
 262       fi
 263       rm -f conftest.c conftest.o conftest
 264     fi
 265     if test "$ac_gcsections" = "yes"; then
 266       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 267     fi
 268     AC_MSG_RESULT($ac_gcsections)
 269
 270     if test "$ac_test_CFLAGS" = set; then
 271       CFLAGS="$ac_save_CFLAGS"
 272     else
 273       # this is the suspicious part
 274       CFLAGS=''
 275     fi
 276   fi
 277
 278   # Set -z,relro.
 279   # Note this is only for shared objects.
 280   ac_ld_relro=no
 281   if test x"$with_gnu_ld" = x"yes"; then
 282     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 283     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 284     if test -n "$cxx_z_relo"; then
 285       OPT_LDFLAGS="-Wl,-z,relro"
 286       ac_ld_relro=yes
 287     fi
 288     AC_MSG_RESULT($ac_ld_relro)
 289   fi
 290
 291   # Set linker optimization flags.
 292   if test x"$with_gnu_ld" = x"yes"; then
 293     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 294   fi
 295
 296   AC_SUBST(SECTION_LDFLAGS)
 297   AC_SUBST(OPT_LDFLAGS)
 298 ])
 299
 300
 301 dnl
 302 dnl Check to see if this target can enable the iconv specializations.
 303 dnl If --disable-c-mbchar was given, no wchar_t specialization is enabled.
 304 dnl (This must have been previously checked, along with the rest of C99
 305 dnl support.) By default, iconv support is disabled.
 306 dnl
 307 dnl Defines:
 308 dnl  _GLIBCXX_USE_ICONV if all the bits are found.
 309 dnl Substs:
 310 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 311 dnl
 312 AC_DEFUN([GLIBCXX_CHECK_ICONV_SUPPORT], [
 313
 314   enable_iconv=no
 315   # Only continue checking if the ISO C99 headers exist and support is on.
 316   if test x"$enable_wchar_t" = xyes; then
 317
 318     # Use iconv for wchar_t to char conversions. As such, check for
 319     # X/Open Portability Guide, version 2 features (XPG2).
 320     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 321     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 322
 323     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 324     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 325     ac_save_LIBS="$LIBS"
 326     LIBS="$LIBS $LIBICONV"
 327     AC_SUBST(LIBICONV)
 328
 329     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 330     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 331
 332     LIBS="$ac_save_LIBS"
 333
 334     if test x"$ac_has_iconv_h" = xyes &&
 335        test x"$ac_has_langinfo_h" = xyes &&
 336        test x"$ac_XPG2funcs" = xyes;
 337     then
 338       AC_DEFINE([_GLIBCXX_USE_ICONV],1,
 339                 [Define if iconv and related functions exist and are usable.])
 340       enable_iconv=yes
 341     fi
 342   fi
 343   AC_MSG_CHECKING([for enabled iconv specializations])
 344   AC_MSG_RESULT($enable_iconv)
 345 ])
 346
 347
 348 dnl
 349 dnl Check for headers for, and arguments to, the setrlimit() function.
 350 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 351 dnl
 352 dnl Defines:
 353 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 354 dnl  various HAVE_LIMIT_* for individual limit names
 355 dnl
 356 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 357   AC_MSG_CHECKING([for RLIMIT_$1])
 358   AC_TRY_COMPILE(
 359     [#include <unistd.h>
 360      #include <sys/time.h>
 361      #include <sys/resource.h>
 362     ],
 363     [ int f = RLIMIT_$1 ; ],
 364     [glibcxx_mresult=1], [glibcxx_mresult=0])
 365   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 366                      [Only used in build directory testsuite_hooks.h.])
 367   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 368   AC_MSG_RESULT($res)
 369 ])
 370
 371 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 372   setrlimit_have_headers=yes
 373   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 374                    [],
 375                    [setrlimit_have_headers=no])
 376   # If don't have the headers, then we can't run the tests now, and we
 377   # won't be seeing any of these during testsuite compilation.
 378   if test $setrlimit_have_headers = yes; then
 379     # Can't do these in a loop, else the resulting syntax is wrong.
 380     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 381     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 382     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 383     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 384     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 385
 386     # Check for rlimit, setrlimit.
 387     AC_CACHE_VAL(ac_setrlimit, [
 388       AC_TRY_COMPILE(
 389         [#include <unistd.h>
 390          #include <sys/time.h>
 391          #include <sys/resource.h>
 392         ],
 393         [struct rlimit r;
 394          setrlimit(0, &r);],
 395         [ac_setrlimit=yes], [ac_setrlimit=no])
 396     ])
 397   fi
 398
 399   AC_MSG_CHECKING([for testsuite resource limits support])
 400   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 401     ac_res_limits=yes
 402     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 403               [Define if using setrlimit to set resource limits during
 404               "make check"])
 405   else
 406     ac_res_limits=no
 407   fi
 408   AC_MSG_RESULT($ac_res_limits)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 414 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 415 dnl
 416 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 417   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 418   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 419     AC_TRY_LINK(
 420       [#include <sys/stat.h>],
 421       [struct stat buffer;
 422        fstat(0, &buffer);
 423        S_ISREG(buffer.st_mode);],
 424       [glibcxx_cv_S_ISREG=yes],
 425       [glibcxx_cv_S_ISREG=no])
 426   ])
 427   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 428     AC_TRY_LINK(
 429       [#include <sys/stat.h>],
 430       [struct stat buffer;
 431        fstat(0, &buffer);
 432        S_IFREG & buffer.st_mode;],
 433       [glibcxx_cv_S_IFREG=yes],
 434       [glibcxx_cv_S_IFREG=no])
 435   ])
 436   res=no
 437   if test $glibcxx_cv_S_ISREG = yes; then
 438     AC_DEFINE(HAVE_S_ISREG, 1,
 439               [Define if S_IFREG is available in <sys/stat.h>.])
 440     res=S_ISREG
 441   elif test $glibcxx_cv_S_IFREG = yes; then
 442     AC_DEFINE(HAVE_S_IFREG, 1,
 443               [Define if S_IFREG is available in <sys/stat.h>.])
 444     res=S_IFREG
 445   fi
 446   AC_MSG_RESULT($res)
 447 ])
 448
 449
 450 dnl
 451 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 452 dnl
 453 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 454   AC_MSG_CHECKING([for poll])
 455   AC_CACHE_VAL(glibcxx_cv_POLL, [
 456     AC_TRY_LINK(
 457       [#include <poll.h>],
 458       [struct pollfd pfd[1];
 459        pfd[0].events = POLLIN;
 460        poll(pfd, 1, 0);],
 461       [glibcxx_cv_POLL=yes],
 462       [glibcxx_cv_POLL=no])
 463   ])
 464   if test $glibcxx_cv_POLL = yes; then
 465     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 466   fi
 467   AC_MSG_RESULT($glibcxx_cv_POLL)
 468 ])
 469
 470
 471 dnl
 472 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 473 dnl
 474 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 475   AC_MSG_CHECKING([for writev])
 476   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 477     AC_TRY_LINK(
 478       [#include <sys/uio.h>],
 479       [struct iovec iov[2];
 480        writev(0, iov, 0);],
 481       [glibcxx_cv_WRITEV=yes],
 482       [glibcxx_cv_WRITEV=no])
 483   ])
 484   if test $glibcxx_cv_WRITEV = yes; then
 485     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 486   fi
 487   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 488 ])
 489
 490
 491 dnl
 492 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 493 dnl
 494 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 495   AC_MSG_CHECKING([for int64_t])
 496   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 497     AC_TRY_COMPILE(
 498       [#include <stdint.h>],
 499       [int64_t var;],
 500       [glibcxx_cv_INT64_T=yes],
 501       [glibcxx_cv_INT64_T=no])
 502   ])
 503   if test $glibcxx_cv_INT64_T = yes; then
 504     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 505   fi
 506   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether LFS support is available.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 514   AC_LANG_SAVE
 515   AC_LANG_CPLUSPLUS
 516   ac_save_CXXFLAGS="$CXXFLAGS"
 517   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 518   AC_MSG_CHECKING([for LFS support])
 519   AC_CACHE_VAL(glibcxx_cv_LFS, [
 520     AC_TRY_LINK(
 521       [#include <unistd.h>
 522        #include <stdio.h>
 523        #include <sys/stat.h>
 524       ],
 525       [FILE* fp;
 526        fopen64("t", "w");
 527        fseeko64(fp, 0, SEEK_CUR);
 528        ftello64(fp);
 529        lseek64(1, 0, SEEK_CUR);
 530        struct stat64 buf;
 531        fstat64(1, &buf);],
 532       [glibcxx_cv_LFS=yes],
 533       [glibcxx_cv_LFS=no])
 534   ])
 535   if test $glibcxx_cv_LFS = yes; then
 536     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 537   fi
 538   AC_MSG_RESULT($glibcxx_cv_LFS)
 539   CXXFLAGS="$ac_save_CXXFLAGS"
 540   AC_LANG_RESTORE
 541 ])
 542
 543
 544 dnl
 545 dnl Check for whether a fully dynamic basic_string implementation should
 546 dnl be turned on, that does not put empty objects in per-process static
 547 dnl memory (mostly useful together with shared memory allocators, see PR
 548 dnl libstdc++/16612 for details).
 549 dnl
 550 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 551 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 552 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 553 dnl       Where DEFAULT is either `yes' or `no'.
 554 dnl
 555 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 556   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 557   if test $enable_fully_dynamic_string = yes; then
 558     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 559               [Define if a fully dynamic basic_string is wanted.])
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Does any necessary configuration of the testsuite directory.  Generates
 566 dnl the testsuite_hooks.h header.
 567 dnl
 568 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 569 dnl
 570 dnl Sets:
 571 dnl  enable_abi_check
 572 dnl  GLIBCXX_TEST_WCHAR_T
 573 dnl  GLIBCXX_TEST_THREAD
 574 dnl Substs:
 575 dnl  baseline_dir
 576 dnl
 577 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 578   if $GLIBCXX_IS_NATIVE ; then
 579     # Do checks for resource limit functions.
 580     GLIBCXX_CHECK_SETRLIMIT
 581
 582     # Look for setenv, so that extended locale tests can be performed.
 583     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 584   fi
 585
 586   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 587      test $enable_symvers != no; then
 588     case "$host" in
 589       *-*-cygwin*)
 590         enable_abi_check=no ;;
 591       *)
 592         enable_abi_check=yes ;;
 593     esac
 594   else
 595     # Only build this as native, since automake does not understand
 596     # CXX_FOR_BUILD.
 597     enable_abi_check=no
 598   fi
 599
 600   # Export file names for ABI checking.
 601   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 602   AC_SUBST(baseline_dir)
 603 ])
 604
 605
 606 dnl
 607 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 608 dnl
 609 dnl Substs:
 610 dnl  GLIBCXX_INCLUDES
 611 dnl  TOPLEVEL_INCLUDES
 612 dnl
 613 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 614   # Used for every C++ compile we perform.
 615   GLIBCXX_INCLUDES="\
 616 -I$glibcxx_builddir/include/$host_alias \
 617 -I$glibcxx_builddir/include \
 618 -I$glibcxx_srcdir/libsupc++"
 619
 620   # For Canadian crosses, pick this up too.
 621   if test $CANADIAN = yes; then
 622     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 623   fi
 624
 625   # Stuff in the actual top level.  Currently only used by libsupc++ to
 626   # get unwind* headers from the gcc dir.
 627   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 628   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 629
 630   # Now, export this to all the little Makefiles....
 631   AC_SUBST(GLIBCXX_INCLUDES)
 632   AC_SUBST(TOPLEVEL_INCLUDES)
 633 ])
 634
 635
 636 dnl
 637 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 638 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 639 dnl
 640 dnl Substs:
 641 dnl  OPTIMIZE_CXXFLAGS
 642 dnl  WARN_FLAGS
 643 dnl
 644 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 645   # Optimization flags that are probably a good idea for thrill-seekers. Just
 646   # uncomment the lines below and make, everything else is ready to go...
 647   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 648   OPTIMIZE_CXXFLAGS=
 649   AC_SUBST(OPTIMIZE_CXXFLAGS)
 650
 651   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 652   AC_SUBST(WARN_FLAGS)
 653 ])
 654
 655
 656 dnl
 657 dnl All installation directory information is determined here.
 658 dnl
 659 dnl Substs:
 660 dnl  gxx_install_dir
 661 dnl  glibcxx_prefixdir
 662 dnl  glibcxx_toolexecdir
 663 dnl  glibcxx_toolexeclibdir
 664 dnl
 665 dnl Assumes cross_compiling bits already done, and with_cross_host in
 666 dnl particular.
 667 dnl
 668 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 669   glibcxx_toolexecdir=no
 670   glibcxx_toolexeclibdir=no
 671   glibcxx_prefixdir=$prefix
 672
 673   AC_MSG_CHECKING([for gxx-include-dir])
 674   AC_ARG_WITH([gxx-include-dir],
 675     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 676                    [installation directory for include files]),
 677     [case "$withval" in
 678       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 679       no)  gxx_include_dir=no ;;
 680       *)   gxx_include_dir=$withval ;;
 681      esac],
 682     [gxx_include_dir=no])
 683   AC_MSG_RESULT($gxx_include_dir)
 684
 685   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 686   AC_ARG_ENABLE([version-specific-runtime-libs],
 687     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 688                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 689     [case "$enableval" in
 690       yes) version_specific_libs=yes ;;
 691       no)  version_specific_libs=no ;;
 692       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 693      esac],
 694     [version_specific_libs=no])
 695   AC_MSG_RESULT($version_specific_libs)
 696
 697   # Default case for install directory for include files.
 698   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 699     gxx_include_dir='${prefix}/include/c++/${gcc_version}'
 700   fi
 701
 702   # Version-specific runtime libs processing.
 703   if test $version_specific_libs = yes; then
 704     # Need the gcc compiler version to know where to install libraries
 705     # and header files if --enable-version-specific-runtime-libs option
 706     # is selected.  FIXME: these variables are misnamed, there are
 707     # no executables installed in _toolexecdir or _toolexeclibdir.
 708     if test x"$gxx_include_dir" = x"no"; then
 709       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 710     fi
 711     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 712     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 713   fi
 714
 715   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 716   # Install a library built with a cross compiler in tooldir, not libdir.
 717   if test x"$glibcxx_toolexecdir" = x"no"; then
 718     if test -n "$with_cross_host" &&
 719        test x"$with_cross_host" != x"no"; then
 720       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 721       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 722     else
 723       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 724       glibcxx_toolexeclibdir='${libdir}'
 725     fi
 726     multi_os_directory=`$CXX -print-multi-os-directory`
 727     case $multi_os_directory in
 728       .) ;; # Avoid trailing /.
 729       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 730     esac
 731   fi
 732
 733   AC_MSG_CHECKING([for install location])
 734   AC_MSG_RESULT($gxx_include_dir)
 735
 736   AC_SUBST(glibcxx_prefixdir)
 737   AC_SUBST(gxx_include_dir)
 738   AC_SUBST(glibcxx_toolexecdir)
 739   AC_SUBST(glibcxx_toolexeclibdir)
 740 ])
 741
 742
 743 dnl
 744 dnl GLIBCXX_ENABLE
 745 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 746 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 747 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 748 dnl
 749 dnl See docs/html/17_intro/configury.html#enable for documentation.
 750 dnl
 751 m4_define([GLIBCXX_ENABLE],[dnl
 752 m4_define([_g_switch],[--enable-$1])dnl
 753 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 754  AC_ARG_ENABLE($1,_g_help,
 755   m4_bmatch([$5],
 756    [^permit ],
 757      [[
 758       case "$enableval" in
 759        m4_bpatsubst([$5],[permit ])) ;;
 760        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 761           dnl Idea for future:  generate a URL pointing to
 762           dnl "onlinedocs/configopts.html#whatever"
 763       esac
 764      ]],
 765    [^$],
 766      [[
 767       case "$enableval" in
 768        yes|no) ;;
 769        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 770       esac
 771      ]],
 772    [[$5]]),
 773   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 774 m4_undefine([_g_switch])dnl
 775 m4_undefine([_g_help])dnl
 776 ])
 777
 778
 779 dnl
 780 dnl Check for ISO/IEC 9899:1999 "C99" support.
 781 dnl
 782 dnl --enable-c99 defines _GLIBCXX_USE_C99
 783 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 784 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 785 dnl       Where DEFAULT is either `yes' or `no'.
 786 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 787 dnl
 788 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 789   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 790
 791   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos
 792   # even if C99 support is turned off.
 793   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 794   AC_MSG_CHECKING([for mbstate_t])
 795   AC_TRY_COMPILE([#include <wchar.h>],
 796   [mbstate_t teststate;],
 797   have_mbstate_t=yes, have_mbstate_t=no)
 798   AC_MSG_RESULT($have_mbstate_t)
 799   if test x"$have_mbstate_t" = xyes; then
 800     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 801   fi
 802
 803   if test x"$enable_c99" = x"yes"; then
 804
 805   AC_LANG_SAVE
 806   AC_LANG_CPLUSPLUS
 807
 808   # Check for the existence of <math.h> functions used if C99 is enabled.
 809   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 810   AC_CACHE_VAL(ac_c99_math, [
 811   AC_TRY_COMPILE([#include <math.h>],
 812                  [fpclassify(0.0);
 813                   isfinite(0.0);
 814                   isinf(0.0);
 815                   isnan(0.0);
 816                   isnormal(0.0);
 817                   signbit(0.0);
 818                   isgreater(0.0,0.0);
 819                   isgreaterequal(0.0,0.0);
 820                   isless(0.0,0.0);
 821                   islessequal(0.0,0.0);
 822                   islessgreater(0.0,0.0);
 823                   islessgreater(0.0,0.0);
 824                   isunordered(0.0,0.0);
 825                  ],[ac_c99_math=yes], [ac_c99_math=no])
 826   ])
 827   AC_MSG_RESULT($ac_c99_math)
 828   if test x"$ac_c99_math" = x"yes"; then
 829     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 830               [Define if C99 functions or macros in <math.h> should be imported
 831               in <cmath> in namespace std.])
 832   fi
 833
 834   # Check for the existence of <complex.h> complex math functions.
 835   # This is necessary even though libstdc++ uses the builtin versions
 836   # of these functions, because if the builtin cannot be used, a reference
 837   # to the library function is emitted.
 838   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 839   ac_c99_complex=no;
 840   if test x"$ac_has_complex_h" = x"yes"; then
 841     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 842     AC_TRY_COMPILE([#include <complex.h>],
 843                    [typedef __complex__ float float_type; float_type tmpf;
 844                     cabsf(tmpf);
 845                     cargf(tmpf);
 846                     ccosf(tmpf);
 847                     ccoshf(tmpf);
 848                     cexpf(tmpf);
 849                     clogf(tmpf);
 850                     csinf(tmpf);
 851                     csinhf(tmpf);
 852                     csqrtf(tmpf);
 853                     ctanf(tmpf);
 854                     ctanhf(tmpf);
 855                     cpowf(tmpf, tmpf);
 856                     typedef __complex__ double double_type; double_type tmpd;
 857                     cabs(tmpd);
 858                     carg(tmpd);
 859                     ccos(tmpd);
 860                     ccosh(tmpd);
 861                     cexp(tmpd);
 862                     clog(tmpd);
 863                     csin(tmpd);
 864                     csinh(tmpd);
 865                     csqrt(tmpd);
 866                     ctan(tmpd);
 867                     ctanh(tmpd);
 868                     cpow(tmpd, tmpd);
 869                     typedef __complex__ long double ld_type; ld_type tmpld;
 870                     cabsl(tmpld);
 871                     cargl(tmpld);
 872                     ccosl(tmpld);
 873                     ccoshl(tmpld);
 874                     cexpl(tmpld);
 875                     clogl(tmpld);
 876                     csinl(tmpld);
 877                     csinhl(tmpld);
 878                     csqrtl(tmpld);
 879                     ctanl(tmpld);
 880                     ctanhl(tmpld);
 881                     cpowl(tmpld, tmpld);
 882                    ],[ac_c99_complex=yes], [ac_c99_complex=no])
 883   fi
 884   AC_MSG_RESULT($ac_c99_complex)
 885   if test x"$ac_c99_complex" = x"yes"; then
 886     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 887               [Define if C99 functions in <complex.h> should be used in
 888               <complex>. Using compiler builtins for these functions requires
 889               corresponding C99 library functions to be present.])
 890   fi
 891
 892   # Check for the existence in <stdio.h> of vscanf, et. al.
 893   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 894   AC_CACHE_VAL(ac_c99_stdio, [
 895   AC_TRY_COMPILE([#include <stdio.h>
 896                   #include <stdarg.h>
 897                   void foo(char* fmt, ...)
 898                   {
 899                     va_list args; va_start(args, fmt);
 900                     vfscanf(stderr, "%i", args);
 901                     vscanf("%i", args);
 902                     vsnprintf(fmt, 0, "%i", args);
 903                     vsscanf(fmt, "%i", args);
 904                   }],
 905                  [snprintf("12", 0, "%i");],
 906                  [ac_c99_stdio=yes], [ac_c99_stdio=no])
 907   ])
 908   AC_MSG_RESULT($ac_c99_stdio)
 909
 910   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 911   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 912   AC_CACHE_VAL(ac_c99_stdlib, [
 913   AC_TRY_COMPILE([#include <stdlib.h>],
 914                  [char* tmp;
 915                   strtof("gnu", &tmp);
 916                   strtold("gnu", &tmp);
 917                   strtoll("gnu", &tmp, 10);
 918                   strtoull("gnu", &tmp, 10);
 919                   llabs(10);
 920                   lldiv(10,1);
 921                   atoll("10");
 922                   _Exit(0);
 923                   lldiv_t mydivt;],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 924   ])
 925   AC_MSG_RESULT($ac_c99_stdlib)
 926
 927   # Check for the existence in <wchar.h> of wcstoull, WEOF, etc.
 928   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 929   ac_c99_wchar=no;
 930   if test x"$ac_has_wchar_h" = xyes &&
 931      test x"$ac_has_wctype_h" = xyes; then
 932     AC_TRY_COMPILE([#include <wchar.h>
 933                     #include <stddef.h>
 934                     wint_t i;
 935                     long l = WEOF;
 936                     long j = WCHAR_MIN;
 937                     long k = WCHAR_MAX;
 938                     namespace test
 939                     {
 940                       using ::btowc;
 941                       using ::fgetwc;
 942                       using ::fgetws;
 943                       using ::fputwc;
 944                       using ::fputws;
 945                       using ::fwide;
 946                       using ::fwprintf;
 947                       using ::fwscanf;
 948                       using ::getwc;
 949                       using ::getwchar;
 950                       using ::mbrlen;
 951                       using ::mbrtowc;
 952                       using ::mbsinit;
 953                       using ::mbsrtowcs;
 954                       using ::putwc;
 955                       using ::putwchar;
 956                       using ::swprintf;
 957                       using ::swscanf;
 958                       using ::ungetwc;
 959                       using ::vfwprintf;
 960                       using ::vswprintf;
 961                       using ::vwprintf;
 962                       using ::wcrtomb;
 963                       using ::wcscat;
 964                       using ::wcschr;
 965                       using ::wcscmp;
 966                       using ::wcscoll;
 967                       using ::wcscpy;
 968                       using ::wcscspn;
 969                       using ::wcsftime;
 970                       using ::wcslen;
 971                       using ::wcsncat;
 972                       using ::wcsncmp;
 973                       using ::wcsncpy;
 974                       using ::wcspbrk;
 975                       using ::wcsrchr;
 976                       using ::wcsrtombs;
 977                       using ::wcsspn;
 978                       using ::wcsstr;
 979                       using ::wcstod;
 980                       using ::wcstok;
 981                       using ::wcstol;
 982                       using ::wcstold;
 983                       using ::wcstoll;
 984                       using ::wcstoul;
 985                       using ::wcstoull;
 986                       using ::wcsxfrm;
 987                       using ::wctob;
 988                       using ::wmemchr;
 989                       using ::wmemcmp;
 990                       using ::wmemcpy;
 991                       using ::wmemmove;
 992                       using ::wmemset;
 993                       using ::wprintf;
 994                       using ::wscanf;
 995                     }
 996                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 997
 998     # Checks for wide character functions that may not be present.
 999     # Injection of these is wrapped with guard macros.
1000     # NB: only put functions here, instead of immediately above, if
1001     # absolutely necessary.
1002     AC_TRY_COMPILE([#include <wchar.h>
1003                     namespace test { using ::vfwscanf; } ], [],
1004                    [AC_DEFINE(HAVE_VFWSCANF,1,
1005                         [Defined if vfwscanf exists.])],[])
1006
1007     AC_TRY_COMPILE([#include <wchar.h>
1008                     namespace test { using ::vswscanf; } ], [],
1009                    [AC_DEFINE(HAVE_VSWSCANF,1,
1010                         [Defined if vswscanf exists.])],[])
1011
1012     AC_TRY_COMPILE([#include <wchar.h>
1013                     namespace test { using ::vwscanf; } ], [],
1014                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1015
1016     AC_TRY_COMPILE([#include <wchar.h>
1017                     namespace test { using ::wcstof; } ], [],
1018                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1019
1020     AC_TRY_COMPILE([#include <wctype.h>],
1021                    [ wint_t t; int i = iswblank(t);],
1022                    [AC_DEFINE(HAVE_ISWBLANK,1,
1023                         [Defined if iswblank exists.])],[])
1024
1025     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1026     AC_MSG_RESULT($ac_c99_wchar)
1027   fi
1028
1029   # Option parsed, now set things appropriately.
1030   if test x"$ac_c99_math" = x"no" ||
1031      test x"$ac_c99_complex" = x"no" ||
1032      test x"$ac_c99_stdio" = x"no" ||
1033      test x"$ac_c99_stdlib" = x"no" ||
1034      test x"$ac_c99_wchar" = x"no"; then
1035     enable_c99=no;
1036   else
1037     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1038     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1039     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1040   fi
1041
1042   AC_LANG_RESTORE
1043   fi
1044
1045   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1046   AC_MSG_RESULT($enable_c99)
1047 ])
1048
1049
1050 dnl
1051 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1052 dnl facilities in Chapter 8, "C compatibility".
1053 dnl
1054 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1055
1056   AC_LANG_SAVE
1057   AC_LANG_CPLUSPLUS
1058
1059   # Check for the existence of <complex.h> complex math functions used
1060   # by tr1/complex.
1061   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1062   ac_c99_complex_tr1=no;
1063   if test x"$ac_has_complex_h" = x"yes"; then
1064     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1065     AC_TRY_COMPILE([#include <complex.h>],
1066                    [typedef __complex__ float float_type; float_type tmpf;
1067                     cacosf(tmpf);
1068                     casinf(tmpf);
1069                     catanf(tmpf);
1070                     cacoshf(tmpf);
1071                     casinhf(tmpf);
1072                     catanhf(tmpf);
1073                     typedef __complex__ double double_type; double_type tmpd;
1074                     cacos(tmpd);
1075                     casin(tmpd);
1076                     catan(tmpd);
1077                     cacosh(tmpd);
1078                     casinh(tmpd);
1079                     catanh(tmpd);
1080                     typedef __complex__ long double ld_type; ld_type tmpld;
1081                     cacosl(tmpld);
1082                     casinl(tmpld);
1083                     catanl(tmpld);
1084                     cacoshl(tmpld);
1085                     casinhl(tmpld);
1086                     catanhl(tmpld);
1087                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1088   fi
1089   AC_MSG_RESULT($ac_c99_complex_tr1)
1090   if test x"$ac_c99_complex_tr1" = x"yes"; then
1091     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1092               [Define if C99 functions in <complex.h> should be used in
1093               <tr1/complex>. Using compiler builtins for these functions
1094               requires corresponding C99 library functions to be present.])
1095   fi
1096
1097   # Check for the existence of <ctype.h> functions.
1098   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1099   AC_CACHE_VAL(ac_c99_ctype_tr1, [
1100   AC_TRY_COMPILE([#include <ctype.h>],
1101                  [int ch;
1102                   int ret;
1103                   ret = isblank(ch);
1104                  ],[ac_c99_ctype_tr1=yes], [ac_c99_ctype_tr1=no])
1105   ])
1106   AC_MSG_RESULT($ac_c99_ctype_tr1)
1107   if test x"$ac_c99_ctype_tr1" = x"yes"; then
1108     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1109               [Define if C99 functions in <ctype.h> should be imported in
1110               <tr1/cctype> in namespace std::tr1.])
1111   fi
1112
1113   # Check for the existence of <fenv.h> functions.
1114   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1115   ac_c99_fenv_tr1=no;
1116   if test x"$ac_has_fenv_h" = x"yes"; then
1117     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1118     AC_TRY_COMPILE([#include <fenv.h>],
1119                    [int except, mode;
1120                     fexcept_t* pflag;
1121                     fenv_t* penv;
1122                     int ret;
1123                     ret = feclearexcept(except);
1124                     ret = fegetexceptflag(pflag, except);
1125                     ret = feraiseexcept(except);
1126                     ret = fesetexceptflag(pflag, except);
1127                     ret = fetestexcept(except);
1128                     ret = fegetround();
1129                     ret = fesetround(mode);
1130                     ret = fegetenv(penv);
1131                     ret = feholdexcept(penv);
1132                     ret = fesetenv(penv);
1133                     ret = feupdateenv(penv);
1134                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1135   fi
1136   AC_MSG_RESULT($ac_c99_fenv_tr1)
1137   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1138     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1139               [Define if C99 functions in <fenv.h> should be imported in
1140               <tr1/cfenv> in namespace std::tr1.])
1141   fi
1142
1143   # Check for the existence of <stdint.h> types.
1144   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1145   AC_CACHE_VAL(ac_c99_stdint_tr1, [
1146   AC_TRY_COMPILE([#include <stdint.h>],
1147                  [typedef int8_t          my_int8_t;
1148                   typedef int16_t         my_int16_t;
1149                   typedef int32_t         my_int32_t;
1150                   typedef int64_t         my_int64_t;
1151                   typedef int_fast8_t     my_int_fast8_t;
1152                   typedef int_fast16_t    my_int_fast16_t;
1153                   typedef int_fast32_t    my_int_fast32_t;
1154                   typedef int_fast64_t    my_int_fast64_t;
1155                   typedef int_least8_t    my_int_least8_t;
1156                   typedef int_least16_t   my_int_least16_t;
1157                   typedef int_least32_t   my_int_least32_t;
1158                   typedef int_least64_t   my_int_least64_t;
1159                   typedef intmax_t        my_intmax_t;
1160                   typedef intptr_t        my_intptr_t;
1161                   typedef uint8_t         my_uint8_t;
1162                   typedef uint16_t        my_uint16_t;
1163                   typedef uint32_t        my_uint32_t;
1164                   typedef uint64_t        my_uint64_t;
1165                   typedef uint_fast8_t    my_uint_fast8_t;
1166                   typedef uint_fast16_t   my_uint_fast16_t;
1167                   typedef uint_fast32_t   my_uint_fast32_t;
1168                   typedef uint_fast64_t   my_uint_fast64_t;
1169                   typedef uint_least8_t   my_uint_least8_t;
1170                   typedef uint_least16_t  my_uint_least16_t;
1171                   typedef uint_least32_t  my_uint_least32_t;
1172                   typedef uint_least64_t  my_uint_least64_t;
1173                   typedef uintmax_t       my_uintmax_t;
1174                   typedef uintptr_t       my_uintptr_t;
1175                  ],[ac_c99_stdint_tr1=yes], [ac_c99_stdint_tr1=no])
1176   ])
1177   AC_MSG_RESULT($ac_c99_stdint_tr1)
1178   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1179     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1180               [Define if C99 types in <stdint.h> should be imported in
1181               <tr1/cstdint> in namespace std::tr1.])
1182   fi
1183
1184   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1185   # sense if the previous check fails, per C99, 7.8/1).
1186   ac_c99_inttypes_tr1=no;
1187   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1188     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1189     AC_TRY_COMPILE([#include <inttypes.h>],
1190                    [intmax_t i, numer, denom, base;
1191                     const char* s;
1192                     char** endptr;
1193                     intmax_t ret = imaxabs(i);
1194                     imaxdiv_t dret = imaxdiv(numer, denom);
1195                     ret = strtoimax(s, endptr, base);
1196                     uintmax_t uret = strtoumax(s, endptr, base);
1197                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1198   fi
1199   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1200   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1201     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1202               [Define if C99 functions in <inttypes.h> should be imported in
1203               <tr1/cinttypes> in namespace std::tr1.])
1204   fi
1205
1206   # Check for the existence of <wchar.h> functions.
1207   AC_MSG_CHECKING([for ISO C99 support to TR1 in <wchar.h>])
1208   AC_CACHE_VAL(ac_c99_wchar_tr1, [
1209   AC_TRY_COMPILE([#include <wchar.h>
1210                   #include <stdio.h>
1211                   #include <stdarg.h>],
1212                  [const wchar_t* nptr;
1213                   const wchar_t* format;
1214                   const wchar_t* s;
1215                   wchar_t** endptr;
1216                   FILE* stream;
1217                   va_list arg;
1218                   int base;
1219                   float fret = wcstof(nptr, endptr);
1220                   long double ldret = wcstold(nptr, endptr);
1221                   int ret = vfwscanf(stream, format, arg);
1222                   ret = vswscanf(s, format, arg);
1223                   ret = vwscanf(format, arg);
1224                   long long llret = wcstoll(nptr, endptr, base);
1225                   unsigned long long ullret = wcstoull(nptr, endptr, base);
1226                  ],[ac_c99_wchar_tr1=yes], [ac_c99_wchar_tr1=no])
1227   ])
1228   AC_MSG_RESULT($ac_c99_wchar_tr1)
1229   if test x"$ac_c99_wchar_tr1" = x"yes"; then
1230     AC_DEFINE(_GLIBCXX_USE_C99_WCHAR_TR1, 1,
1231               [Define if C99 functions in <wchar.h> should be imported in
1232               <tr1/cwchar> in namespace std::tr1.])
1233   fi
1234
1235   # Check for the existence of <wctype.h> functions.
1236   AC_MSG_CHECKING([for ISO C99 support to TR1 in <wctype.h>])
1237   AC_CACHE_VAL(ac_c99_wctype_tr1, [
1238   AC_TRY_COMPILE([#include <wctype.h>],
1239                  [wint_t ch;
1240                   int ret = iswblank(ch);
1241                  ],[ac_c99_wctype_tr1=yes], [ac_c99_wctype_tr1=no])
1242   ])
1243   AC_MSG_RESULT($ac_c99_wctype_tr1)
1244   if test x"$ac_c99_wctype_tr1" = x"yes"; then
1245     AC_DEFINE(_GLIBCXX_USE_C99_WCTYPE_TR1, 1,
1246               [Define if C99 functions in <wctype.h> should be imported in
1247               <tr1/cwctype> in namespace std::tr1.])
1248   fi
1249
1250   AC_LANG_RESTORE
1251 ])
1252
1253
1254 dnl
1255 dnl Check for what type of C headers to use.
1256 dnl
1257 dnl --enable-cheaders= [does stuff].
1258 dnl --disable-cheaders [does not do anything, really].
1259 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1260 dnl       Where DEFAULT is either `c' or `c_std'.
1261 dnl
1262 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1263   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1264     [construct "C" headers for g++], [permit c|c_std])
1265   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1266
1267   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1268
1269   AC_SUBST(C_INCLUDE_DIR)
1270   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1271   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1272   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1273 ])
1274
1275
1276 dnl
1277 dnl Check for which locale library to use.  The choice is mapped to
1278 dnl a subdirectory of config/locale.
1279 dnl
1280 dnl Default is generic.
1281 dnl
1282 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1283   AC_MSG_CHECKING([for C locale to use])
1284   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1285     [use MODEL for target locale package],
1286     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1287
1288   # If they didn't use this option switch, or if they specified --enable
1289   # with no specific model, we'll have to look for one.  If they
1290   # specified --disable (???), do likewise.
1291   if test $enable_clocale = no || test $enable_clocale = yes; then
1292      enable_clocale=auto
1293   fi
1294
1295   # Either a known package, or "auto"
1296   enable_clocale_flag=$enable_clocale
1297
1298   # Probe for locale support if no specific model is specified.
1299   # Default to "generic".
1300   if test $enable_clocale_flag = auto; then
1301     case ${target_os} in
1302       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1303         AC_EGREP_CPP([_GLIBCXX_ok], [
1304         #include <features.h>
1305         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1306           _GLIBCXX_ok
1307         #endif
1308         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1309
1310         # Test for bugs early in glibc-2.2.x series
1311           if test $enable_clocale_flag = gnu; then
1312           AC_TRY_RUN([
1313           #define _GNU_SOURCE 1
1314           #include <locale.h>
1315           #include <string.h>
1316           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1317           extern __typeof(newlocale) __newlocale;
1318           extern __typeof(duplocale) __duplocale;
1319           extern __typeof(strcoll_l) __strcoll_l;
1320           #endif
1321           int main()
1322           {
1323               const char __one[] = "Äuglein Augmen";
1324               const char __two[] = "Äuglein";
1325               int i;
1326               int j;
1327               __locale_t        loc;
1328                __locale_t        loc_dup;
1329               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1330               loc_dup = __duplocale(loc);
1331               i = __strcoll_l(__one, __two, loc);
1332               j = __strcoll_l(__one, __two, loc_dup);
1333               return 0;
1334           }
1335           ],
1336           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1337           [enable_clocale_flag=generic])
1338           fi
1339
1340         # ... at some point put __strxfrm_l tests in as well.
1341         ;;
1342       darwin* | freebsd*)
1343         enable_clocale_flag=darwin
1344         ;;
1345       *)
1346         enable_clocale_flag=generic
1347         ;;
1348     esac
1349   fi
1350
1351   # Deal with gettext issues.  Default to not using it (=no) until we detect
1352   # support for it later.  Let the user turn it off via --e/d, but let that
1353   # default to on for easier handling.
1354   USE_NLS=no
1355   AC_ARG_ENABLE(nls,
1356     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1357     [],
1358     [enable_nls=yes])
1359
1360   # Set configure bits for specified locale package
1361   case ${enable_clocale_flag} in
1362     generic)
1363       AC_MSG_RESULT(generic)
1364
1365       CLOCALE_H=config/locale/generic/c_locale.h
1366       CLOCALE_CC=config/locale/generic/c_locale.cc
1367       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1368       CCOLLATE_CC=config/locale/generic/collate_members.cc
1369       CCTYPE_CC=config/locale/generic/ctype_members.cc
1370       CMESSAGES_H=config/locale/generic/messages_members.h
1371       CMESSAGES_CC=config/locale/generic/messages_members.cc
1372       CMONEY_CC=config/locale/generic/monetary_members.cc
1373       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1374       CTIME_H=config/locale/generic/time_members.h
1375       CTIME_CC=config/locale/generic/time_members.cc
1376       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1377       ;;
1378     darwin)
1379       AC_MSG_RESULT(darwin or freebsd)
1380
1381       CLOCALE_H=config/locale/generic/c_locale.h
1382       CLOCALE_CC=config/locale/generic/c_locale.cc
1383       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1384       CCOLLATE_CC=config/locale/generic/collate_members.cc
1385       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1386       CMESSAGES_H=config/locale/generic/messages_members.h
1387       CMESSAGES_CC=config/locale/generic/messages_members.cc
1388       CMONEY_CC=config/locale/generic/monetary_members.cc
1389       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1390       CTIME_H=config/locale/generic/time_members.h
1391       CTIME_CC=config/locale/generic/time_members.cc
1392       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1393       ;;
1394
1395     gnu)
1396       AC_MSG_RESULT(gnu)
1397
1398       # Declare intention to use gettext, and add support for specific
1399       # languages.
1400       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1401       ALL_LINGUAS="de fr"
1402
1403       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1404       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1405       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1406         USE_NLS=yes
1407       fi
1408       # Export the build objects.
1409       for ling in $ALL_LINGUAS; do \
1410         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1411         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1412       done
1413       AC_SUBST(glibcxx_MOFILES)
1414       AC_SUBST(glibcxx_POFILES)
1415
1416       CLOCALE_H=config/locale/gnu/c_locale.h
1417       CLOCALE_CC=config/locale/gnu/c_locale.cc
1418       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1419       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1420       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1421       CMESSAGES_H=config/locale/gnu/messages_members.h
1422       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1423       CMONEY_CC=config/locale/gnu/monetary_members.cc
1424       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1425       CTIME_H=config/locale/gnu/time_members.h
1426       CTIME_CC=config/locale/gnu/time_members.cc
1427       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1428       ;;
1429     ieee_1003.1-2001)
1430       AC_MSG_RESULT(IEEE 1003.1)
1431
1432       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1433       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1434       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1435       CCOLLATE_CC=config/locale/generic/collate_members.cc
1436       CCTYPE_CC=config/locale/generic/ctype_members.cc
1437       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1438       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1439       CMONEY_CC=config/locale/generic/monetary_members.cc
1440       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1441       CTIME_H=config/locale/generic/time_members.h
1442       CTIME_CC=config/locale/generic/time_members.cc
1443       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1444       ;;
1445   esac
1446
1447   # This is where the testsuite looks for locale catalogs, using the
1448   # -DLOCALEDIR define during testsuite compilation.
1449   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1450   AC_SUBST(glibcxx_localedir)
1451
1452   # A standalone libintl (e.g., GNU libintl) may be in use.
1453   if test $USE_NLS = yes; then
1454     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1455     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1456   fi
1457   if test $USE_NLS = yes; then
1458     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1459               [Define if NLS translations are to be used.])
1460   fi
1461
1462   AC_SUBST(USE_NLS)
1463   AC_SUBST(CLOCALE_H)
1464   AC_SUBST(CMESSAGES_H)
1465   AC_SUBST(CCODECVT_CC)
1466   AC_SUBST(CCOLLATE_CC)
1467   AC_SUBST(CCTYPE_CC)
1468   AC_SUBST(CMESSAGES_CC)
1469   AC_SUBST(CMONEY_CC)
1470   AC_SUBST(CNUMERIC_CC)
1471   AC_SUBST(CTIME_H)
1472   AC_SUBST(CTIME_CC)
1473   AC_SUBST(CLOCALE_CC)
1474   AC_SUBST(CLOCALE_INTERNAL_H)
1475 ])
1476
1477
1478 dnl
1479 dnl Check for which std::allocator base class to use.  The choice is
1480 dnl mapped from a subdirectory of include/ext.
1481 dnl
1482 dnl Default is new.
1483 dnl
1484 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1485   AC_MSG_CHECKING([for std::allocator base class])
1486   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1487     [use KIND for target std::allocator base],
1488     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1489
1490   # If they didn't use this option switch, or if they specified --enable
1491   # with no specific model, we'll have to look for one.  If they
1492   # specified --disable (???), do likewise.
1493   if test $enable_libstdcxx_allocator = no ||
1494      test $enable_libstdcxx_allocator = yes;
1495   then
1496      enable_libstdcxx_allocator=auto
1497   fi
1498
1499   # Either a known package, or "auto". Auto implies the default choice
1500   # for a particular platform.
1501   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1502
1503   # Probe for host-specific support if no specific model is specified.
1504   # Default to "new".
1505   if test $enable_libstdcxx_allocator_flag = auto; then
1506     case ${target_os} in
1507       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1508         enable_libstdcxx_allocator_flag=new
1509         ;;
1510       *)
1511         enable_libstdcxx_allocator_flag=new
1512         ;;
1513     esac
1514   fi
1515   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1516
1517
1518   # Set configure bits for specified locale package
1519   case ${enable_libstdcxx_allocator_flag} in
1520     bitmap)
1521       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1522       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1523       ;;
1524     malloc)
1525       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1526       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1527       ;;
1528     mt)
1529       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1530       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1531       ;;
1532     new)
1533       ALLOCATOR_H=config/allocator/new_allocator_base.h
1534       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1535       ;;
1536     pool)
1537       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1538       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1539       ;;
1540   esac
1541
1542   AC_SUBST(ALLOCATOR_H)
1543   AC_SUBST(ALLOCATOR_NAME)
1544 ])
1545
1546
1547 dnl
1548 dnl Check for whether the Boost-derived checks should be turned on.
1549 dnl
1550 dnl --enable-concept-checks turns them on.
1551 dnl --disable-concept-checks leaves them off.
1552 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1553 dnl       Where DEFAULT is either `yes' or `no'.
1554 dnl
1555 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1556   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1557   if test $enable_concept_checks = yes; then
1558     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1559               [Define to use concept checking code from the boost libraries.])
1560   fi
1561 ])
1562
1563
1564 dnl
1565 dnl Check for which I/O library to use:  stdio, or something specific.
1566 dnl
1567 dnl Default is stdio.
1568 dnl
1569 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1570   AC_MSG_CHECKING([for underlying I/O to use])
1571   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1572     [use target-specific I/O package], [permit stdio])
1573
1574   # Now that libio has been removed, you can have any color you want as long
1575   # as it's black.  This is one big no-op until other packages are added, but
1576   # showing the framework never hurts.
1577   case ${enable_cstdio} in
1578     stdio)
1579       CSTDIO_H=config/io/c_io_stdio.h
1580       BASIC_FILE_H=config/io/basic_file_stdio.h
1581       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1582       AC_MSG_RESULT(stdio)
1583       ;;
1584   esac
1585
1586   AC_SUBST(CSTDIO_H)
1587   AC_SUBST(BASIC_FILE_H)
1588   AC_SUBST(BASIC_FILE_CC)
1589 ])
1590
1591
1592 dnl
1593 dnl Check for "unusual" flags to pass to the compiler while building.
1594 dnl
1595 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1596 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1597 dnl --disable-cxx-flags passes nothing.
1598 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1599 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1600 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1601 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1602 dnl       If "default flags" is an empty string, the effect is the same
1603 dnl       as --disable or --enable=no.
1604 dnl
1605 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1606   AC_MSG_CHECKING([for extra compiler flags for building])
1607   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1608     [pass compiler FLAGS when building library],
1609     [case "x$enable_cxx_flags" in
1610       xno | x)   enable_cxx_flags= ;;
1611       x-*)       ;;
1612       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1613      esac])
1614
1615   # Run through flags (either default or command-line) and set anything
1616   # extra (e.g., #defines) that must accompany particular g++ options.
1617   if test -n "$enable_cxx_flags"; then
1618     for f in $enable_cxx_flags; do
1619       case "$f" in
1620         -fhonor-std)  ;;
1621         -*)  ;;
1622         *)   # and we're trying to pass /what/ exactly?
1623              AC_MSG_ERROR([compiler flags start with a -]) ;;
1624       esac
1625     done
1626   fi
1627
1628   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1629   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1630   AC_SUBST(EXTRA_CXX_FLAGS)
1631 ])
1632
1633
1634 dnl
1635 dnl Check to see if debugging libraries are to be built.
1636 dnl
1637 dnl --enable-libstdcxx-debug
1638 dnl builds a separate set of debugging libraries in addition to the
1639 dnl normal (shared, static) libstdc++ binaries.
1640 dnl
1641 dnl --disable-libstdcxx-debug
1642 dnl builds only one (non-debug) version of libstdc++.
1643 dnl
1644 dnl --enable-libstdcxx-debug-flags=FLAGS
1645 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1646 dnl
1647 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1648 dnl       Where DEFAULT is either `yes' or `no'.
1649 dnl
1650 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1651   AC_MSG_CHECKING([for additional debug build])
1652   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1653   AC_MSG_RESULT($enable_libstdcxx_debug)
1654   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1655 ])
1656
1657
1658 dnl
1659 dnl Check for explicit debug flags.
1660 dnl
1661 dnl --enable-libstdcxx-debug-flags='-O1'
1662 dnl is a general method for passing flags to be used when
1663 dnl building debug libraries with --enable-debug.
1664 dnl
1665 dnl --disable-libstdcxx-debug-flags does nothing.
1666 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1667 dnl       If "default flags" is an empty string, the effect is the same
1668 dnl       as --disable or --enable=no.
1669 dnl
1670 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1671   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1672     [pass compiler FLAGS when building debug library],
1673     [case "x$enable_libstdcxx_debug_flags" in
1674       xno | x)    enable_libstdcxx_debug_flags= ;;
1675       x-*)        ;;
1676       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1677      esac])
1678
1679   # Option parsed, now set things appropriately
1680   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1681   AC_SUBST(DEBUG_FLAGS)
1682
1683   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1684 ])
1685
1686
1687 dnl
1688 dnl Check if the user only wants a freestanding library implementation.
1689 dnl
1690 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1691 dnl installing only the headers required by [17.4.1.3] and the language
1692 dnl support library.  More than that will be built (to keep the Makefiles
1693 dnl conveniently clean), but not installed.
1694 dnl
1695 dnl Sets:
1696 dnl  is_hosted  (yes/no)
1697 dnl
1698 dnl Defines:
1699 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1700 dnl
1701 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1702   AC_ARG_ENABLE([hosted-libstdcxx],
1703     AC_HELP_STRING([--disable-hosted-libstdcxx],
1704                    [only build freestanding C++ runtime support]),,
1705     [case "$host" in
1706         arm*-*-symbianelf*)
1707             enable_hosted_libstdcxx=no
1708             ;;
1709         *)
1710             enable_hosted_libstdcxx=yes
1711             ;;
1712      esac])
1713   if test "$enable_hosted_libstdcxx" = no; then
1714     AC_MSG_NOTICE([Only freestanding libraries will be built])
1715     is_hosted=no
1716     hosted_define=0
1717     enable_abi_check=no
1718     enable_libstdcxx_pch=no
1719   else
1720     is_hosted=yes
1721     hosted_define=1
1722   fi
1723   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1724   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1725     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1726 ])
1727
1728
1729 dnl
1730 dnl Check for template specializations for the 'long long' type.
1731 dnl The result determines only whether 'long long' I/O is enabled; things
1732 dnl like numeric_limits<> specializations are always available.
1733 dnl
1734 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1735 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1736 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1737 dnl       Where DEFAULT is either `yes' or `no'.
1738 dnl
1739 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1740   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1741   if test $enable_long_long = yes; then
1742     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
1743               [Define if code specialized for long long should be used.])
1744   fi
1745   AC_MSG_CHECKING([for enabled long long specializations])
1746   AC_MSG_RESULT([$enable_long_long])
1747 ])
1748
1749
1750 dnl
1751 dnl Check for template specializations for the 'wchar_t' type.
1752 dnl
1753 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1754 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1755 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1756 dnl       Where DEFAULT is either `yes' or `no'.
1757 dnl
1758 dnl Necessary support (probed along with C99 support) must also be present.
1759 dnl
1760 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
1761   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
1762   if test x"$ac_c99_wchar" = x"yes" && test x"$enable_wchar_t" = x"yes"; then
1763     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
1764               [Define if code specialized for wchar_t should be used.])
1765   fi
1766   AC_MSG_CHECKING([for enabled wchar_t specializations])
1767   AC_MSG_RESULT([$enable_wchar_t])
1768 ])
1769
1770
1771 dnl
1772 dnl Check to see if building and using a C++ precompiled header can be done.
1773 dnl
1774 dnl --enable-libstdcxx-pch=yes
1775 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1776 dnl may work, after some light-hearted attempts to puzzle out compiler
1777 dnl support, flip bits on in include/Makefile.am
1778 dnl
1779 dnl --disable-libstdcxx-pch
1780 dnl turns off attempts to use or build stdc++.h.gch.
1781 dnl
1782 dnl Substs:
1783 dnl  glibcxx_PCHFLAGS
1784 dnl
1785 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1786   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1787   if test $enable_libstdcxx_pch = yes; then
1788     AC_CACHE_CHECK([for compiler with PCH support],
1789       [glibcxx_cv_prog_CXX_pch],
1790       [ac_save_CXXFLAGS="$CXXFLAGS"
1791        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1792        AC_LANG_SAVE
1793        AC_LANG_CPLUSPLUS
1794        echo '#include <math.h>' > conftest.h
1795        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1796                           -o conftest.h.gch 1>&5 2>&1 &&
1797                 echo '#error "pch failed"' > conftest.h &&
1798           echo '#include "conftest.h"' > conftest.cc &&
1799                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1800        then
1801          glibcxx_cv_prog_CXX_pch=yes
1802        else
1803          glibcxx_cv_prog_CXX_pch=no
1804        fi
1805        rm -f conftest*
1806        CXXFLAGS=$ac_save_CXXFLAGS
1807        AC_LANG_RESTORE
1808       ])
1809     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1810   fi
1811
1812   AC_MSG_CHECKING([for enabled PCH])
1813   AC_MSG_RESULT([$enable_libstdcxx_pch])
1814
1815   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1816   if test $enable_libstdcxx_pch = yes; then
1817     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1818   else
1819     glibcxx_PCHFLAGS=""
1820   fi
1821   AC_SUBST(glibcxx_PCHFLAGS)
1822 ])
1823
1824
1825 dnl
1826 dnl Check for exception handling support.  If an explicit enable/disable
1827 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1828 dnl target may or may not support call frame exceptions.
1829 dnl
1830 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1831 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1832 dnl Neither one forces an attempt at detection.
1833 dnl
1834 dnl Defines:
1835 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1836 dnl
1837 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1838   AC_MSG_CHECKING([for exception model to use])
1839   AC_LANG_SAVE
1840   AC_LANG_CPLUSPLUS
1841   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1842     [force use of builtin_setjmp for exceptions],
1843     [permit yes|no|auto])
1844
1845   if test $enable_sjlj_exceptions = auto; then
1846     # Botheration.  Now we've got to detect the exception model.  Link tests
1847     # against libgcc.a are problematic since we've not been given proper -L
1848     # bits for single-tree newlib and libgloss.
1849     #
1850     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1851     cat > conftest.$ac_ext << EOF
1852 [#]line __oline__ "configure"
1853 struct S { ~S(); };
1854 void bar();
1855 void foo()
1856 {
1857   S s;
1858   bar();
1859 }
1860 EOF
1861     old_CXXFLAGS="$CXXFLAGS"
1862     CXXFLAGS=-S
1863     if AC_TRY_EVAL(ac_compile); then
1864       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1865         enable_sjlj_exceptions=yes
1866       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1867         enable_sjlj_exceptions=no
1868       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
1869         enable_sjlj_exceptions=no
1870       fi
1871     fi
1872     CXXFLAGS="$old_CXXFLAGS"
1873     rm -f conftest*
1874   fi
1875
1876   # This is a tad weird, for hysterical raisins.  We have to map
1877   # enable/disable to two different models.
1878   case $enable_sjlj_exceptions in
1879     yes)
1880       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1881         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1882       ac_exception_model_name=sjlj
1883       ;;
1884     no)
1885       ac_exception_model_name="call frame"
1886       ;;
1887     *)
1888       AC_MSG_ERROR([unable to detect exception model])
1889       ;;
1890   esac
1891  AC_LANG_RESTORE
1892  AC_MSG_RESULT($ac_exception_model_name)
1893 ])
1894
1895
1896 dnl
1897 dnl Add version tags to symbols in shared library (or not), additionally
1898 dnl marking other symbols as private/local (or not).
1899 dnl
1900 dnl --enable-symvers=style adds a version script to the linker call when
1901 dnl       creating the shared library.  The choice of version script is
1902 dnl       controlled by 'style'.
1903 dnl --disable-symvers does not.
1904 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1905 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1906 dnl       choose a default style based on linker characteristics.  Passing
1907 dnl       'no' disables versioning.
1908 dnl
1909 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1910
1911 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1912   [enables symbol versioning of the shared library],
1913   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
1914
1915 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1916 # don't know enough about $LD to do tricks...
1917 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1918
1919 # Turn a 'yes' into a suitable default.
1920 if test x$enable_symvers = xyes ; then
1921   if test $enable_shared = no || test "x$LD" = x ; then
1922     enable_symvers=no
1923   else
1924     if test $with_gnu_ld = yes ; then
1925       enable_symvers=gnu
1926     else
1927       case ${target_os} in
1928         darwin*)
1929           enable_symvers=darwin ;;
1930         *)
1931           enable_symvers=no ;;
1932       esac
1933     fi
1934   fi
1935 fi
1936
1937 # Check to see if 'darwin' or 'darwin-export' can win.
1938 if test x$enable_symvers = xdarwin-export ; then
1939     enable_symvers=darwin
1940 fi
1941
1942 # Check to see if 'gnu' can win.
1943 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
1944   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1945   AC_MSG_CHECKING([for shared libgcc])
1946   ac_save_CFLAGS="$CFLAGS"
1947   CFLAGS=' -lgcc_s'
1948   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1949   CFLAGS="$ac_save_CFLAGS"
1950   if test $glibcxx_shared_libgcc = no; then
1951     cat > conftest.c <<EOF
1952 int main (void) { return 0; }
1953 EOF
1954 changequote(,)dnl
1955     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1956                              -shared -shared-libgcc -o conftest.so \
1957                              conftest.c -v 2>&1 >/dev/null \
1958                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1959 changequote([,])dnl
1960     rm -f conftest.c conftest.so
1961     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1962       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1963       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1964       CFLAGS="$ac_save_CFLAGS"
1965     fi
1966   fi
1967   AC_MSG_RESULT($glibcxx_shared_libgcc)
1968
1969   # For GNU ld, we need at least this version.  The format is described in
1970   # GLIBCXX_CHECK_LINKER_FEATURES above.
1971   glibcxx_min_gnu_ld_version=21400
1972
1973   # If no shared libgcc, can't win.
1974   if test $glibcxx_shared_libgcc != yes; then
1975       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
1976       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
1977       AC_MSG_WARN([=== Symbol versioning will be disabled.])
1978       enable_symvers=no
1979   elif test $with_gnu_ld != yes ; then
1980     # just fail for now
1981     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
1982     AC_MSG_WARN([=== you are not using the GNU linker.])
1983     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1984     enable_symvers=no
1985   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
1986     # The right tools, the right setup, but too old.  Fallbacks?
1987     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1988     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1989     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1990     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1991     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1992     enable_symvers=no
1993   fi
1994 fi
1995
1996 # Everything parsed; figure out what file to use.
1997 case $enable_symvers in
1998   no)
1999     SYMVER_FILE=config/abi/pre/none.ver
2000     ;;
2001   gnu)
2002     SYMVER_FILE=config/abi/pre/gnu.ver
2003     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
2004               [Define to use GNU versioning in the shared library.])
2005     ;;
2006   gnu-versioned-namespace)
2007     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
2008     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
2009               [Define to use GNU namespace versioning in the shared library.])
2010     ;;
2011   darwin)
2012     SYMVER_FILE=config/abi/pre/gnu.ver
2013     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
2014               [Define to use darwin versioning in the shared library.])
2015     ;;
2016 esac
2017
2018 if test x$enable_symvers != xno ; then
2019   AC_DEFINE(_GLIBCXX_SYMVER, 1,
2020          [Define to use symbol versioning in the shared library.])
2021 fi
2022
2023 AC_SUBST(SYMVER_FILE)
2024 AC_SUBST(port_specific_symbol_files)
2025 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
2026 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
2027 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
2028 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
2029 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
2030
2031 # Now, set up compatibility support, if any.
2032 # In addition, need this to deal with std::size_t mangling in
2033 # src/compatibility.cc.  In a perfect world, could use
2034 # typeid(std::size_t).name()[0] to do direct substitution.
2035 AC_MSG_CHECKING([for size_t as unsigned int])
2036 ac_save_CFLAGS="$CFLAGS"
2037 CFLAGS="-Werror"
2038 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
2039                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
2040 CFLAGS=$ac_save_CFLAGS
2041 if test "$glibcxx_size_t_is_i" = yes; then
2042   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
2043 fi
2044 AC_MSG_RESULT([$glibcxx_size_t_is_i])
2045
2046 AC_MSG_CHECKING([for ptrdiff_t as int])
2047 ac_save_CFLAGS="$CFLAGS"
2048 CFLAGS="-Werror"
2049 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
2050                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
2051 CFLAGS=$ac_save_CFLAGS
2052 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
2053   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
2054 fi
2055 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
2056 ])
2057
2058
2059 dnl
2060 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
2061 dnl We must stage the required headers so that they will be installed
2062 dnl with the library (unlike libgcc, the STL implementation is provided
2063 dnl solely within headers).  Since we must not inject random user-space
2064 dnl macro names into user-provided C++ code, we first stage into <file>-in
2065 dnl and process to <file> with an output command.  The reason for a two-
2066 dnl stage process here is to correctly handle $srcdir!=$objdir without
2067 dnl having to write complex code (the sed commands to clean the macro
2068 dnl namespace are complex and fragile enough as it is).  We must also
2069 dnl add a relative path so that -I- is supported properly.
2070 dnl
2071 dnl Substs:
2072 dnl  glibcxx_thread_h
2073 dnl
2074 dnl Defines:
2075 dnl  HAVE_GTHR_DEFAULT
2076 dnl
2077 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
2078   AC_MSG_CHECKING([for thread model used by GCC])
2079   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
2080   AC_MSG_RESULT([$target_thread_file])
2081
2082   if test $target_thread_file != single; then
2083     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
2084               [Define if gthr-default.h exists
2085               (meaning that threading support is enabled).])
2086   fi
2087
2088   glibcxx_thread_h=gthr-$target_thread_file.h
2089
2090   dnl Check for __GTHREADS define.
2091   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
2092   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
2093     enable_thread=yes
2094   else
2095    enable_thread=no
2096   fi
2097
2098   AC_SUBST(glibcxx_thread_h)
2099 ])
2100
2101
2102 # Check whether LC_MESSAGES is available in <locale.h>.
2103 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2104 #
2105 # This file file be copied and used freely without restrictions.  It can
2106 # be used in projects which are not available under the GNU Public License
2107 # but which still want to provide support for the GNU gettext functionality.
2108 # Please note that the actual code is *not* freely available.
2109
2110 # serial 1
2111 AC_DEFUN([AC_LC_MESSAGES], [
2112   AC_CHECK_HEADER(locale.h, [
2113     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2114       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2115        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2116     if test $ac_cv_val_LC_MESSAGES = yes; then
2117       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2118                 [Define if LC_MESSAGES is available in <locale.h>.])
2119     fi
2120   ])
2121 ])
2122
2123 # Macros from the top-level gcc directory.
2124 m4_include([../config/tls.m4])
2125