libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  27   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN(GLIBCXX_CONFIGURE, [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 387     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     # Checks for wide character functions that are not required
 394     # for basic wchar_t support.  Don't disable support if they are missing.
 395     # Injection of these is wrapped with guard macros.
 396     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 397
 398     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 399     if test x"$has_weof" = xyes &&
 400        test x"$has_wchar_minmax" = xyes &&
 401        test x"$ac_wfuncs" = xyes;
 402     then
 403       ac_isoC99_wchar_t=yes
 404     else
 405       ac_isoC99_wchar_t=no
 406     fi
 407     AC_MSG_RESULT($ac_isoC99_wchar_t)
 408
 409     # Use iconv for wchar_t to char conversions. As such, check for
 410     # X/Open Portability Guide, version 2 features (XPG2).
 411     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 412     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 413
 414     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 415     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 416     ac_save_LIBS="$LIBS"
 417     LIBS="$LIBS $libiconv"
 418
 419     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 420     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 421
 422     LIBS="$ac_save_LIBS"
 423
 424     AC_MSG_CHECKING([for XPG2 wchar_t support])
 425     if test x"$ac_has_iconv_h" = xyes &&
 426        test x"$ac_has_langinfo_h" = xyes &&
 427        test x"$ac_XPG2funcs" = xyes;
 428     then
 429       ac_XPG2_wchar_t=yes
 430     else
 431       ac_XPG2_wchar_t=no
 432     fi
 433     AC_MSG_RESULT($ac_XPG2_wchar_t)
 434
 435     # At the moment, only enable wchar_t specializations if all the
 436     # above support is present.
 437     if test x"$ac_isoC99_wchar_t" = xyes &&
 438        test x"$ac_XPG2_wchar_t" = xyes;
 439     then
 440       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 441       enable_wchar_t=yes
 442     fi
 443   fi
 444   AC_MSG_CHECKING([for enabled wchar_t specializations])
 445   AC_MSG_RESULT($enable_wchar_t)
 446 ])
 447
 448
 449 dnl
 450 dnl Check for headers for, and arguments to, the setrlimit() function.
 451 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 452 dnl
 453 dnl Defines:
 454 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 455 dnl  various HAVE_MEMLIMIT_* for individual limit names
 456 dnl
 457 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 458   AC_TRY_COMPILE(
 459     [#include <unistd.h>
 460      #include <sys/time.h>
 461      #include <sys/resource.h>
 462     ],
 463     [ int f = RLIMIT_$1 ; ],
 464     [glibcxx_mresult=1], [glibcxx_mresult=0])
 465   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 466                      [Only used in build directory testsuite_hooks.h.])
 467 ])
 468
 469 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 470   setrlimit_have_headers=yes
 471   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 472                    [],
 473                    [setrlimit_have_headers=no])
 474   # If don't have the headers, then we can't run the tests now, and we
 475   # won't be seeing any of these during testsuite compilation.
 476   if test $setrlimit_have_headers = yes; then
 477     # Can't do these in a loop, else the resulting syntax is wrong.
 478     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 479     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 480     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 481     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 482
 483     # Check for rlimit, setrlimit.
 484     AC_CACHE_VAL(ac_setrlimit, [
 485       AC_TRY_COMPILE(
 486         [#include <unistd.h>
 487          #include <sys/time.h>
 488          #include <sys/resource.h>
 489         ],
 490         [struct rlimit r;
 491          setrlimit(0, &r);],
 492         [ac_setrlimit=yes], [ac_setrlimit=no])
 493     ])
 494   fi
 495
 496   AC_MSG_CHECKING([for testsuite memory limit support])
 497   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 498     ac_mem_limits=yes
 499     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 500   else
 501     ac_mem_limits=no
 502   fi
 503   AC_MSG_RESULT($ac_mem_limits)
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 509 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 510 dnl
 511 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 512   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 513     AC_TRY_LINK(
 514       [#include <sys/stat.h>],
 515       [struct stat buffer;
 516        fstat(0, &buffer);
 517        S_ISREG(buffer.st_mode);],
 518       [glibcxx_cv_S_ISREG=yes],
 519       [glibcxx_cv_S_ISREG=no])
 520   ])
 521   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 522     AC_TRY_LINK(
 523       [#include <sys/stat.h>],
 524       [struct stat buffer;
 525        fstat(0, &buffer);
 526        S_IFREG & buffer.st_mode;],
 527       [glibcxx_cv_S_IFREG=yes],
 528       [glibcxx_cv_S_IFREG=no])
 529   ])
 530   if test $glibcxx_cv_S_ISREG = yes; then
 531     AC_DEFINE(HAVE_S_ISREG)
 532   elif test $glibcxx_cv_S_IFREG = yes; then
 533     AC_DEFINE(HAVE_S_IFREG)
 534   fi
 535 ])
 536
 537
 538 dnl
 539 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 540 dnl
 541 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 542   AC_CACHE_VAL(glibcxx_cv_POLL, [
 543     AC_TRY_LINK(
 544       [#include <poll.h>],
 545       [struct pollfd pfd[1];
 546        pfd[0].events = POLLIN;
 547        poll(pfd, 1, 0);],
 548       [glibcxx_cv_POLL=yes],
 549       [glibcxx_cv_POLL=no])
 550   ])
 551   if test $glibcxx_cv_POLL = yes; then
 552     AC_DEFINE(HAVE_POLL)
 553   fi
 554 ])
 555
 556
 557 dnl
 558 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 559 dnl
 560 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 561   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 562     AC_TRY_LINK(
 563       [#include <sys/uio.h>],
 564       [struct iovec iov[2];
 565        writev(0, iov, 0);],
 566       [glibcxx_cv_WRITEV=yes],
 567       [glibcxx_cv_WRITEV=no])
 568   ])
 569   if test $glibcxx_cv_WRITEV = yes; then
 570     AC_DEFINE(HAVE_WRITEV)
 571   fi
 572 ])
 573
 574
 575 dnl
 576 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 577 dnl
 578 AC_DEFUN(GLIBCXX_CHECK_INT64_T, [
 579   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 580     AC_TRY_COMPILE(
 581       [#include <stdint.h>],
 582       [int64_t var;],
 583       [glibcxx_cv_INT64_T=yes],
 584       [glibcxx_cv_INT64_T=no])
 585   ])
 586   if test $glibcxx_cv_INT64_T = yes; then
 587     AC_DEFINE(HAVE_INT64_T)
 588   fi
 589 ])
 590
 591
 592 dnl
 593 dnl Check whether LFS support is available.
 594 dnl
 595 AC_DEFUN(GLIBCXX_CHECK_LFS, [
 596   AC_LANG_SAVE
 597   AC_LANG_CPLUSPLUS
 598   AC_CACHE_VAL(glibcxx_cv_LFS, [
 599     AC_TRY_LINK(
 600       [#include <unistd.h>
 601        #include <stdio.h>
 602       ],
 603       [FILE* fp;
 604        fopen64("t", "w");
 605        fseeko64(fp, 0, SEEK_CUR);
 606        ftello64(fp);
 607        lseek64(1, 0, SEEK_CUR);],
 608       [glibcxx_cv_LFS=yes],
 609       [glibcxx_cv_LFS=no])
 610   ])
 611   if test $glibcxx_cv_LFS = yes; then
 612     AC_DEFINE(_GLIBCXX_USE_LFS)
 613   fi
 614   AC_LANG_RESTORE
 615 ])
 616
 617
 618 dnl
 619 dnl Does any necessary configuration of the testsuite directory.  Generates
 620 dnl the testsuite_hooks.h header.
 621 dnl
 622 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 623 dnl
 624 dnl Sets:
 625 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 626 dnl Substs:
 627 dnl  baseline_dir
 628 dnl
 629 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 630   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 631     # Do checks for memory limit functions.
 632     GLIBCXX_CHECK_SETRLIMIT
 633
 634     # Look for setenv, so that extended locale tests can be performed.
 635     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 636
 637     if test $enable_symvers = no; then
 638       enable_abi_check=no
 639     else
 640       case "$host" in
 641         *-*-cygwin*)
 642           enable_abi_check=no ;;
 643         *)
 644           enable_abi_check=yes ;;
 645       esac
 646     fi
 647   else
 648     # Only build this as native, since automake does not understand
 649     # CXX_FOR_BUILD.
 650     enable_abi_check=no
 651   fi
 652
 653   # Export file names for ABI checking.
 654   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 655   AC_SUBST(baseline_dir)
 656
 657   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 658   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 659 ])
 660
 661
 662 dnl
 663 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 664 dnl
 665 dnl Substs:
 666 dnl  GLIBCXX_INCLUDES
 667 dnl  TOPLEVEL_INCLUDES
 668 dnl
 669 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 670   # Used for every C++ compile we perform.
 671   GLIBCXX_INCLUDES="\
 672 -I$glibcxx_builddir/include/$host_alias \
 673 -I$glibcxx_builddir/include \
 674 -I$glibcxx_srcdir/libsupc++"
 675
 676   # For Canadian crosses, pick this up too.
 677   if test $CANADIAN = yes; then
 678     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 679   fi
 680
 681   # Stuff in the actual top level.  Currently only used by libsupc++ to
 682   # get unwind* headers from the gcc dir.
 683   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 684   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 685
 686   # Now, export this to all the little Makefiles....
 687   AC_SUBST(GLIBCXX_INCLUDES)
 688   AC_SUBST(TOPLEVEL_INCLUDES)
 689 ])
 690
 691
 692 dnl
 693 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 694 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 695 dnl
 696 dnl Substs:
 697 dnl  OPTIMIZE_CXXFLAGS
 698 dnl  WARN_FLAGS
 699 dnl
 700 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 701   # Optimization flags that are probably a good idea for thrill-seekers. Just
 702   # uncomment the lines below and make, everything else is ready to go...
 703   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 704   OPTIMIZE_CXXFLAGS=
 705   AC_SUBST(OPTIMIZE_CXXFLAGS)
 706
 707   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 708   AC_SUBST(WARN_FLAGS)
 709 ])
 710
 711
 712 dnl
 713 dnl All installation directory information is determined here.
 714 dnl
 715 dnl Substs:
 716 dnl  gxx_install_dir
 717 dnl  glibcxx_prefixdir
 718 dnl  glibcxx_toolexecdir
 719 dnl  glibcxx_toolexeclibdir
 720 dnl
 721 dnl Assumes cross_compiling bits already done, and with_cross_host in
 722 dnl particular.
 723 dnl
 724 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 725   glibcxx_toolexecdir=no
 726   glibcxx_toolexeclibdir=no
 727   glibcxx_prefixdir=$prefix
 728
 729   AC_MSG_CHECKING([for gxx-include-dir])
 730   AC_ARG_WITH([gxx-include-dir],
 731     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 732                    [installation directory for include files]),
 733     [case "$withval" in
 734       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 735       no)  gxx_include_dir=no ;;
 736       *)   gxx_include_dir=$withval ;;
 737      esac],
 738     [gxx_include_dir=no])
 739   AC_MSG_RESULT($gxx_include_dir)
 740
 741   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 742   AC_ARG_ENABLE([version-specific-runtime-libs],
 743     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 744                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 745     [case "$enableval" in
 746       yes) version_specific_libs=yes ;;
 747       no)  version_specific_libs=no ;;
 748       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 749      esac],
 750     [version_specific_libs=no])
 751   AC_MSG_RESULT($version_specific_libs)
 752
 753   # Default case for install directory for include files.
 754   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 755     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 756   fi
 757
 758   # Version-specific runtime libs processing.
 759   if test $version_specific_libs = yes; then
 760     # Need the gcc compiler version to know where to install libraries
 761     # and header files if --enable-version-specific-runtime-libs option
 762     # is selected.
 763     if test x"$gxx_include_dir" = x"no"; then
 764       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 765     fi
 766     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 767     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 768   fi
 769
 770   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 771   # Install a library built with a cross compiler in tooldir, not libdir.
 772   if test x"$glibcxx_toolexecdir" = x"no"; then
 773     if test -n "$with_cross_host" &&
 774        test x"$with_cross_host" != x"no"; then
 775       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 776       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 777     else
 778       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 779       glibcxx_toolexeclibdir='${libdir}'
 780     fi
 781     multi_os_directory=`$CXX -print-multi-os-directory`
 782     case $multi_os_directory in
 783       .) ;; # Avoid trailing /.
 784       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 785     esac
 786   fi
 787
 788   AC_MSG_CHECKING([for install location])
 789   AC_MSG_RESULT($gxx_include_dir)
 790
 791   AC_SUBST(glibcxx_prefixdir)
 792   AC_SUBST(gxx_include_dir)
 793   AC_SUBST(glibcxx_toolexecdir)
 794   AC_SUBST(glibcxx_toolexeclibdir)
 795 ])
 796
 797
 798 dnl
 799 dnl GLIBCXX_ENABLE
 800 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 801 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 802 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 803 dnl
 804 dnl See docs/html/17_intro/configury.html#enable for documentation.
 805 dnl
 806 m4_define([GLIBCXX_ENABLE],[dnl
 807 m4_define([_g_switch],[--enable-$1])dnl
 808 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 809  AC_ARG_ENABLE($1,_g_help,
 810   m4_bmatch([$5],
 811    [^permit ],
 812      [[
 813       case "$enableval" in
 814        m4_bpatsubst([$5],[permit ])) ;;
 815        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 816           dnl Idea for future:  generate a URL pointing to
 817           dnl "onlinedocs/configopts.html#whatever"
 818       esac
 819      ]],
 820    [^$],
 821      [[
 822       case "$enableval" in
 823        yes|no) ;;
 824        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 825       esac
 826      ]],
 827    [[$5]]),
 828   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 829 m4_undefine([_g_switch])dnl
 830 m4_undefine([_g_help])dnl
 831 ])
 832
 833
 834 dnl
 835 dnl Check for ISO/IEC 9899:1999 "C99" support.
 836 dnl
 837 dnl --enable-c99 defines _GLIBCXX_USE_C99
 838 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 839 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 840 dnl       Where DEFAULT is either `yes' or `no'.
 841 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 842 dnl
 843 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 844   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 845
 846   AC_LANG_SAVE
 847   AC_LANG_CPLUSPLUS
 848
 849   # Check for the existence of <math.h> functions used if C99 is enabled.
 850   ac_c99_math=yes;
 851   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 852   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 853   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 856   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],
 860                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 861   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],
 864                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 865   AC_TRY_COMPILE([#include <math.h>],
 866                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 867   AC_MSG_RESULT($ac_c99_math)
 868
 869   # Check for the existence in <stdio.h> of vscanf, et. al.
 870   ac_c99_stdio=yes;
 871   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 872   AC_TRY_COMPILE([#include <stdio.h>],
 873                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 874   AC_TRY_COMPILE([#include <stdio.h>
 875                   #include <stdarg.h>
 876                   void foo(char* fmt, ...)
 877                   {va_list args; va_start(args, fmt);
 878                   vfscanf(stderr, "%i", args);}],
 879                   [],, [ac_c99_stdio=no])
 880   AC_TRY_COMPILE([#include <stdio.h>
 881                   #include <stdarg.h>
 882                   void foo(char* fmt, ...)
 883                   {va_list args; va_start(args, fmt);
 884                   vscanf("%i", args);}],
 885                   [],, [ac_c99_stdio=no])
 886   AC_TRY_COMPILE([#include <stdio.h>
 887                   #include <stdarg.h>
 888                   void foo(char* fmt, ...)
 889                   {va_list args; va_start(args, fmt);
 890                   vsnprintf(fmt, 0, "%i", args);}],
 891                   [],, [ac_c99_stdio=no])
 892   AC_TRY_COMPILE([#include <stdio.h>
 893                   #include <stdarg.h>
 894                   void foo(char* fmt, ...)
 895                   {va_list args; va_start(args, fmt);
 896                   vsscanf(fmt, "%i", args);}],
 897                   [],, [ac_c99_stdio=no])
 898   AC_MSG_RESULT($ac_c99_stdio)
 899
 900   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 901   ac_c99_stdlib=yes;
 902   AC_MSG_CHECKING([for lldiv_t declaration])
 903   AC_CACHE_VAL(ac_c99_lldiv_t, [
 904   AC_TRY_COMPILE([#include <stdlib.h>],
 905                    [ lldiv_t mydivt;],
 906                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 907   ])
 908   AC_MSG_RESULT($ac_c99_lldiv_t)
 909
 910   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 911   AC_TRY_COMPILE([#include <stdlib.h>],
 912                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 913   AC_TRY_COMPILE([#include <stdlib.h>],
 914                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 915   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 916   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 917   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 918   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 919   if test x"$ac_c99_lldiv_t" = x"no"; then
 920     ac_c99_stdlib=no;
 921   fi;
 922   AC_MSG_RESULT($ac_c99_stdlib)
 923
 924   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 925   # XXX the wchar.h checks should be rolled into the general C99 bits.
 926   ac_c99_wchar=yes;
 927   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 928   AC_TRY_COMPILE([#include <wchar.h>],
 929                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 930   AC_TRY_COMPILE([#include <wchar.h>],
 931                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 932   AC_TRY_COMPILE([#include <wchar.h>],
 933                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 934   AC_MSG_RESULT($ac_c99_wchar)
 935
 936   AC_MSG_CHECKING([for enabled ISO C99 support])
 937   if test x"$ac_c99_math" = x"no" ||
 938      test x"$ac_c99_stdio" = x"no" ||
 939      test x"$ac_c99_stdlib" = x"no" ||
 940      test x"$ac_c99_wchar" = x"no"; then
 941     enable_c99=no;
 942   fi;
 943   AC_MSG_RESULT($enable_c99)
 944
 945   # Option parsed, now set things appropriately
 946   if test x"$enable_c99" = x"yes"; then
 947     AC_DEFINE(_GLIBCXX_USE_C99)
 948   fi
 949
 950   AC_LANG_RESTORE
 951 ])
 952
 953
 954 dnl
 955 dnl Check for what type of C headers to use.
 956 dnl
 957 dnl --enable-cheaders= [does stuff].
 958 dnl --disable-cheaders [does not do anything, really].
 959 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 960 dnl       Where DEFAULT is either `c' or `c_std'.
 961 dnl
 962 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 963   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 964     [construct "C" headers for g++], [permit c|c_std])
 965   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 966
 967   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 968
 969   AC_SUBST(C_INCLUDE_DIR)
 970   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 971   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 972   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 973 ])
 974
 975
 976 dnl
 977 dnl Check for which locale library to use.  The choice is mapped to
 978 dnl a subdirectory of config/locale.
 979 dnl
 980 dnl Default is generic.
 981 dnl
 982 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 983   AC_MSG_CHECKING([for C locale to use])
 984   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 985     [use MODEL for target locale package],
 986     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 987
 988   # If they didn't use this option switch, or if they specified --enable
 989   # with no specific model, we'll have to look for one.  If they
 990   # specified --disable (???), do likewise.
 991   if test $enable_clocale = no || test $enable_clocale = yes; then
 992      enable_clocale=auto
 993   fi
 994
 995   # Either a known package, or "auto"
 996   enable_clocale_flag=$enable_clocale
 997
 998   # Probe for locale support if no specific model is specified.
 999   # Default to "generic".
1000   if test $enable_clocale_flag = auto; then
1001     case x${target_os} in
1002       xlinux* | xgnu* | xkfreebsd*-gnu | xknetbsd*-gnu)
1003         AC_EGREP_CPP([_GLIBCXX_ok], [
1004         #include <features.h>
1005         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1006           _GLIBCXX_ok
1007         #endif
1008         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1009
1010         # Test for bugs early in glibc-2.2.x series
1011           if test x$enable_clocale_flag = xgnu; then
1012           AC_TRY_RUN([
1013           #define _GNU_SOURCE 1
1014           #include <locale.h>
1015           #include <string.h>
1016           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1017           extern __typeof(newlocale) __newlocale;
1018           extern __typeof(duplocale) __duplocale;
1019           extern __typeof(strcoll_l) __strcoll_l;
1020           #endif
1021           int main()
1022           {
1023               const char __one[] = "Äuglein Augmen";
1024               const char __two[] = "Äuglein";
1025               int i;
1026               int j;
1027               __locale_t        loc;
1028                __locale_t        loc_dup;
1029               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1030               loc_dup = __duplocale(loc);
1031               i = __strcoll_l(__one, __two, loc);
1032               j = __strcoll_l(__one, __two, loc_dup);
1033               return 0;
1034           }
1035           ],
1036           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1037           [enable_clocale_flag=generic])
1038           fi
1039
1040         # ... at some point put __strxfrm_l tests in as well.
1041         ;;
1042       *)
1043         enable_clocale_flag=generic
1044         ;;
1045     esac
1046   fi
1047
1048   # Deal with gettext issues.  Default to not using it (=no) until we detect
1049   # support for it later.  Let the user turn it off via --e/d, but let that
1050   # default to on for easier handling.
1051   USE_NLS=no
1052   AC_ARG_ENABLE(nls,
1053     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1054     [],
1055     [enable_nls=yes])
1056
1057   # Set configure bits for specified locale package
1058   case ${enable_clocale_flag} in
1059     generic)
1060       AC_MSG_RESULT(generic)
1061
1062       CLOCALE_H=config/locale/generic/c_locale.h
1063       CLOCALE_CC=config/locale/generic/c_locale.cc
1064       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1065       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1066       CCOLLATE_CC=config/locale/generic/collate_members.cc
1067       CCTYPE_CC=config/locale/generic/ctype_members.cc
1068       CMESSAGES_H=config/locale/generic/messages_members.h
1069       CMESSAGES_CC=config/locale/generic/messages_members.cc
1070       CMONEY_CC=config/locale/generic/monetary_members.cc
1071       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1072       CTIME_H=config/locale/generic/time_members.h
1073       CTIME_CC=config/locale/generic/time_members.cc
1074       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1075       ;;
1076     gnu)
1077       AC_MSG_RESULT(gnu)
1078
1079       # Declare intention to use gettext, and add support for specific
1080       # languages.
1081       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1082       ALL_LINGUAS="de fr"
1083
1084       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1085       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1086       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1087         USE_NLS=yes
1088       fi
1089       # Export the build objects.
1090       for ling in $ALL_LINGUAS; do \
1091         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1092         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1093       done
1094       AC_SUBST(glibcxx_MOFILES)
1095       AC_SUBST(glibcxx_POFILES)
1096
1097       CLOCALE_H=config/locale/gnu/c_locale.h
1098       CLOCALE_CC=config/locale/gnu/c_locale.cc
1099       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1100       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1101       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1102       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1103       CMESSAGES_H=config/locale/gnu/messages_members.h
1104       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1105       CMONEY_CC=config/locale/gnu/monetary_members.cc
1106       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1107       CTIME_H=config/locale/gnu/time_members.h
1108       CTIME_CC=config/locale/gnu/time_members.cc
1109       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1110       ;;
1111     ieee_1003.1-2001)
1112       AC_MSG_RESULT(IEEE 1003.1)
1113
1114       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1115       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1116       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1117       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1118       CCOLLATE_CC=config/locale/generic/collate_members.cc
1119       CCTYPE_CC=config/locale/generic/ctype_members.cc
1120       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1121       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1122       CMONEY_CC=config/locale/generic/monetary_members.cc
1123       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1124       CTIME_H=config/locale/generic/time_members.h
1125       CTIME_CC=config/locale/generic/time_members.cc
1126       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1127       ;;
1128   esac
1129
1130   # This is where the testsuite looks for locale catalogs, using the
1131   # -DLOCALEDIR define during testsuite compilation.
1132   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1133   AC_SUBST(glibcxx_localedir)
1134
1135   # A standalone libintl (e.g., GNU libintl) may be in use.
1136   if test $USE_NLS = yes; then
1137     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1138     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1139   fi
1140   if test $USE_NLS = yes; then
1141     AC_DEFINE(_GLIBCXX_USE_NLS)
1142   fi
1143
1144   AC_SUBST(USE_NLS)
1145   AC_SUBST(CLOCALE_H)
1146   AC_SUBST(CCODECVT_H)
1147   AC_SUBST(CMESSAGES_H)
1148   AC_SUBST(CCODECVT_CC)
1149   AC_SUBST(CCOLLATE_CC)
1150   AC_SUBST(CCTYPE_CC)
1151   AC_SUBST(CMESSAGES_CC)
1152   AC_SUBST(CMONEY_CC)
1153   AC_SUBST(CNUMERIC_CC)
1154   AC_SUBST(CTIME_H)
1155   AC_SUBST(CTIME_CC)
1156   AC_SUBST(CLOCALE_CC)
1157   AC_SUBST(CLOCALE_INTERNAL_H)
1158 ])
1159
1160
1161 dnl
1162 dnl Check for whether the Boost-derived checks should be turned on.
1163 dnl
1164 dnl --enable-concept-checks turns them on.
1165 dnl --disable-concept-checks leaves them off.
1166 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1167 dnl       Where DEFAULT is either `yes' or `no'.
1168 dnl
1169 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1170   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1171   if test $enable_concept_checks = yes; then
1172     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1173   fi
1174 ])
1175
1176
1177 dnl
1178 dnl Check for which I/O library to use:  stdio, or something specific.
1179 dnl
1180 dnl Default is stdio.
1181 dnl
1182 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1183   AC_MSG_CHECKING([for underlying I/O to use])
1184   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1185     [use target-specific I/O package], [permit stdio])
1186
1187   # Now that libio has been removed, you can have any color you want as long
1188   # as it's black.  This is one big no-op until other packages are added, but
1189   # showing the framework never hurts.
1190   case ${enable_cstdio} in
1191     stdio)
1192       CSTDIO_H=config/io/c_io_stdio.h
1193       BASIC_FILE_H=config/io/basic_file_stdio.h
1194       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1195       AC_MSG_RESULT(stdio)
1196       ;;
1197   esac
1198
1199   AC_SUBST(CSTDIO_H)
1200   AC_SUBST(BASIC_FILE_H)
1201   AC_SUBST(BASIC_FILE_CC)
1202 ])
1203
1204
1205 dnl
1206 dnl Check for "unusual" flags to pass to the compiler while building.
1207 dnl
1208 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1209 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1210 dnl --disable-cxx-flags passes nothing.
1211 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1212 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1213 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1214 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1215 dnl       If "default flags" is an empty string, the effect is the same
1216 dnl       as --disable or --enable=no.
1217 dnl
1218 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1219   AC_MSG_CHECKING([for extra compiler flags for building])
1220   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1221     [pass compiler FLAGS when building library],
1222     [case "x$enable_cxx_flags" in
1223       xno | x)   enable_cxx_flags= ;;
1224       x-*)       ;;
1225       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1226      esac])
1227
1228   # Run through flags (either default or command-line) and set anything
1229   # extra (e.g., #defines) that must accompany particular g++ options.
1230   if test -n "$enable_cxx_flags"; then
1231     for f in $enable_cxx_flags; do
1232       case "$f" in
1233         -fhonor-std)  ;;
1234         -*)  ;;
1235         *)   # and we're trying to pass /what/ exactly?
1236              AC_MSG_ERROR([compiler flags start with a -]) ;;
1237       esac
1238     done
1239   fi
1240
1241   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1242   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1243   AC_SUBST(EXTRA_CXX_FLAGS)
1244 ])
1245
1246
1247 dnl
1248 dnl Check for wide character support.  Has the same effect as the option
1249 dnl in gcc's configure, but in a form that autoconf can mess with.
1250 dnl
1251 dnl --enable-c-mbchar requests all the wchar_t stuff.
1252 dnl --disable-c-mbchar doesn't.
1253 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1254 dnl       Where DEFAULT is either `yes' or `no'.
1255 dnl
1256 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1257   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1258   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1259 ])
1260
1261
1262 dnl
1263 dnl Check to see if debugging libraries are to be built.
1264 dnl
1265 dnl --enable-libstdcxx-debug
1266 dnl builds a separate set of debugging libraries in addition to the
1267 dnl normal (shared, static) libstdc++ binaries.
1268 dnl
1269 dnl --disable-libstdcxx-debug
1270 dnl builds only one (non-debug) version of libstdc++.
1271 dnl
1272 dnl --enable-libstdcxx-debug-flags=FLAGS
1273 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1274 dnl
1275 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1276 dnl       Where DEFAULT is either `yes' or `no'.
1277 dnl
1278 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1279   AC_MSG_CHECKING([for additional debug build])
1280   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1281   AC_MSG_RESULT($enable_libstdcxx_debug)
1282   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1283 ])
1284
1285
1286 dnl
1287 dnl Check for explicit debug flags.
1288 dnl
1289 dnl --enable-libstdcxx-debug-flags='-O1'
1290 dnl is a general method for passing flags to be used when
1291 dnl building debug libraries with --enable-debug.
1292 dnl
1293 dnl --disable-libstdcxx-debug-flags does nothing.
1294 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1295 dnl       If "default flags" is an empty string, the effect is the same
1296 dnl       as --disable or --enable=no.
1297 dnl
1298 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1299   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1300     [pass compiler FLAGS when building debug library],
1301     [case "x$enable_libstdcxx_debug_flags" in
1302       xno | x)    enable_libstdcxx_debug_flags= ;;
1303       x-*)        ;;
1304       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1305      esac])
1306
1307   # Option parsed, now set things appropriately
1308   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1309   AC_SUBST(DEBUG_FLAGS)
1310
1311   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1312 ])
1313
1314
1315 dnl
1316 dnl Check if the user only wants a freestanding library implementation.
1317 dnl
1318 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1319 dnl installing only the headers required by [17.4.1.3] and the language
1320 dnl support library.  More than that will be built (to keep the Makefiles
1321 dnl conveniently clean), but not installed.
1322 dnl
1323 dnl Sets:
1324 dnl  is_hosted  (yes/no)
1325 dnl
1326 dnl Defines:
1327 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1328 dnl
1329 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1330   AC_ARG_ENABLE([hosted-libstdcxx],
1331     AC_HELP_STRING([--disable-hosted-libstdcxx],
1332                    [only build freestanding C++ runtime support]),,
1333     [enable_hosted_libstdcxx=yes])
1334   if test "$enable_hosted_libstdcxx" = no; then
1335     AC_MSG_NOTICE([Only freestanding libraries will be built])
1336     is_hosted=no
1337     hosted_define=0
1338     enable_abi_check=no
1339     enable_libstdcxx_pch=no
1340   else
1341     is_hosted=yes
1342     hosted_define=1
1343   fi
1344   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1345   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1346     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1347 ])
1348
1349
1350 dnl
1351 dnl Check for libunwind exception handling support.  If enabled, then
1352 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1353 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1354 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1355 dnl on libunwind as well as libgcc.
1356 dnl
1357 dnl --enable-libunwind-exceptions forces the use of libunwind.
1358 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1359 dnl
1360 dnl Substs:
1361 dnl  LIBUNWIND_FLAG
1362 dnl
1363 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1364   AC_MSG_CHECKING([for use of libunwind])
1365   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1366     [force use of libunwind for exceptions])
1367   AC_MSG_RESULT($use_libunwind_exceptions)
1368   if test $enable_libunwind_exceptions = yes; then
1369     LIBUNWIND_FLAG="-lunwind"
1370   else
1371     LIBUNWIND_FLAG=""
1372   fi
1373   AC_SUBST(LIBUNWIND_FLAG)
1374 ])
1375
1376
1377 dnl
1378 dnl Check for template specializations for the 'long long' type extension.
1379 dnl The result determines only whether 'long long' I/O is enabled; things
1380 dnl like numeric_limits<> specializations are always available.
1381 dnl
1382 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1383 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1384 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1385 dnl       Where DEFAULT is either `yes' or `no'.
1386 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1387 dnl
1388 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1389   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1390
1391   AC_LANG_SAVE
1392   AC_LANG_CPLUSPLUS
1393
1394   AC_MSG_CHECKING([for enabled long long I/O support])
1395   # iostreams require strtoll, strtoull to compile
1396   AC_TRY_COMPILE([#include <stdlib.h>],
1397                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1398   AC_TRY_COMPILE([#include <stdlib.h>],
1399                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1400
1401   # Option parsed, now set things appropriately
1402   if test $enable_long_long = yes; then
1403     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1404   fi
1405   AC_MSG_RESULT($enable_long_long)
1406
1407   AC_LANG_RESTORE
1408 ])
1409
1410
1411 dnl
1412 dnl Check to see if building and using a C++ precompiled header can be done.
1413 dnl
1414 dnl --enable-libstdcxx-pch=yes
1415 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1416 dnl may work, after some light-hearted attempts to puzzle out compiler
1417 dnl support, flip bits on in include/Makefile.am
1418 dnl
1419 dnl --disable-libstdcxx-pch
1420 dnl turns off attempts to use or build stdc++.h.gch.
1421 dnl
1422 dnl Substs:
1423 dnl  glibcxx_PCHFLAGS
1424 dnl
1425 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1426   AC_MSG_CHECKING([for enabled PCH])
1427   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1428   AC_MSG_RESULT([$enable_libstdcxx_pch])
1429
1430   if test $enable_libstdcxx_pch = yes; then
1431     AC_CACHE_CHECK([for compiler with PCH support],
1432       [glibcxx_cv_prog_CXX_pch],
1433       [ac_save_CXXFLAGS="$CXXFLAGS"
1434        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1435        AC_LANG_SAVE
1436        AC_LANG_CPLUSPLUS
1437        echo '#include <math.h>' > conftest.h
1438        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1439                           -o conftest.h.gch 1>&5 2>&1 &&
1440                 echo '#error "pch failed"' > conftest.h &&
1441           echo '#include "conftest.h"' > conftest.cc &&
1442                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1443        then
1444          glibcxx_cv_prog_CXX_pch=yes
1445        else
1446          glibcxx_cv_prog_CXX_pch=no
1447        fi
1448        rm -f conftest*
1449        CXXFLAGS=$ac_save_CXXFLAGS
1450        AC_LANG_RESTORE
1451       ])
1452     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1453   fi
1454
1455   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1456   if test $enable_libstdcxx_pch = yes; then
1457     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1458   else
1459     glibcxx_PCHFLAGS=""
1460   fi
1461   AC_SUBST(glibcxx_PCHFLAGS)
1462 ])
1463
1464
1465 dnl
1466 dnl Check for exception handling support.  If an explicit enable/disable
1467 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1468 dnl target may or may not support call frame exceptions.
1469 dnl
1470 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1471 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1472 dnl Neither one forces an attempt at detection.
1473 dnl
1474 dnl Defines:
1475 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1476 dnl
1477 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1478   AC_MSG_CHECKING([for exception model to use])
1479   AC_LANG_SAVE
1480   AC_LANG_CPLUSPLUS
1481   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1482     [force use of builtin_setjmp for exceptions],
1483     [permit yes|no|auto])
1484
1485   if test $enable_sjlj_exceptions = auto; then
1486     # Botheration.  Now we've got to detect the exception model.  Link tests
1487     # against libgcc.a are problematic since we've not been given proper -L
1488     # bits for single-tree newlib and libgloss.
1489     #
1490     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1491     cat > conftest.$ac_ext << EOF
1492 [#]line __oline__ "configure"
1493 struct S { ~S(); };
1494 void bar();
1495 void foo()
1496 {
1497   S s;
1498   bar();
1499 }
1500 EOF
1501     old_CXXFLAGS="$CXXFLAGS"
1502     CXXFLAGS=-S
1503     if AC_TRY_EVAL(ac_compile); then
1504       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1505         enable_sjlj_exceptions=yes
1506       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1507         enable_sjlj_exceptions=no
1508       fi
1509     fi
1510     CXXFLAGS="$old_CXXFLAGS"
1511     rm -f conftest*
1512   fi
1513
1514   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1515   # to two different models.
1516   case $enable_sjlj_exceptions in
1517     yes)
1518       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1519         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1520       ac_exception_model_name=sjlj
1521       ;;
1522     no)
1523       ac_exception_model_name="call frame"
1524       ;;
1525     *)
1526       AC_MSG_ERROR([unable to detect exception model])
1527       ;;
1528   esac
1529  AC_LANG_RESTORE
1530  AC_MSG_RESULT($ac_exception_model_name)
1531 ])
1532
1533
1534 dnl
1535 dnl Add version tags to symbols in shared library (or not), additionally
1536 dnl marking other symbols as private/local (or not).
1537 dnl
1538 dnl --enable-symvers=style adds a version script to the linker call when
1539 dnl       creating the shared library.  The choice of version script is
1540 dnl       controlled by 'style'.
1541 dnl --disable-symvers does not.
1542 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1543 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1544 dnl       choose a default style based on linker characteristics.  Passing
1545 dnl       'no' disables versioning.
1546 dnl
1547 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1548
1549 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1550   [enables symbol versioning of the shared library],
1551   [permit yes|no|gnu])
1552
1553 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1554 # don't know enough about $LD to do tricks...
1555 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1556 # FIXME  The following test is too strict, in theory.
1557 if test $enable_shared = no ||
1558         test "x$LD" = x ||
1559         test x$glibcxx_gnu_ld_version = x; then
1560   enable_symvers=no
1561 fi
1562
1563 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1564 if test $enable_symvers != no; then
1565   AC_MSG_CHECKING([for shared libgcc])
1566   ac_save_CFLAGS="$CFLAGS"
1567   CFLAGS=' -lgcc_s'
1568   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1569   CFLAGS="$ac_save_CFLAGS"
1570   AC_MSG_RESULT($glibcxx_shared_libgcc)
1571 fi
1572
1573 # For GNU ld, we need at least this version.  The format is described in
1574 # GLIBCXX_CHECK_LINKER_FEATURES above.
1575 glibcxx_min_gnu_ld_version=21400
1576 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1577
1578 # Check to see if unspecified "yes" value can win, given results above.
1579 # Change "yes" into either "no" or a style name.
1580 if test $enable_symvers = yes; then
1581   if test $with_gnu_ld = yes &&
1582      test $glibcxx_shared_libgcc = yes;
1583   then
1584     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1585       enable_symvers=gnu
1586     else
1587       # The right tools, the right setup, but too old.  Fallbacks?
1588       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1589       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1590       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1591       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1592       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1593         # Globbing fix is present, proper block support is not.
1594         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1595         dnl enable_symvers=???
1596         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1597         enable_symvers=no
1598       else
1599         # 2.11 or older.
1600         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1601         enable_symvers=no
1602       fi
1603     fi
1604   else
1605     # just fail for now
1606     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1607     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1608     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1609     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1610     enable_symvers=no
1611   fi
1612 fi
1613
1614 # Everything parsed; figure out what file to use.
1615 case $enable_symvers in
1616   no)
1617     SYMVER_MAP=config/linker-map.dummy
1618     ;;
1619   gnu)
1620     SYMVER_MAP=config/linker-map.gnu
1621     AC_DEFINE(_GLIBCXX_SYMVER)
1622     ;;
1623 esac
1624
1625 AC_SUBST(SYMVER_MAP)
1626 AC_SUBST(port_specific_symbol_files)
1627 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1628 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1629 ])
1630
1631
1632 dnl
1633 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1634 dnl We must stage the required headers so that they will be installed
1635 dnl with the library (unlike libgcc, the STL implementation is provided
1636 dnl solely within headers).  Since we must not inject random user-space
1637 dnl macro names into user-provided C++ code, we first stage into <file>-in
1638 dnl and process to <file> with an output command.  The reason for a two-
1639 dnl stage process here is to correctly handle $srcdir!=$objdir without
1640 dnl having to write complex code (the sed commands to clean the macro
1641 dnl namespace are complex and fragile enough as it is).  We must also
1642 dnl add a relative path so that -I- is supported properly.
1643 dnl
1644 dnl Substs:
1645 dnl  glibcxx_thread_h
1646 dnl
1647 dnl Defines:
1648 dnl  HAVE_GTHR_DEFAULT
1649 dnl  _GLIBCXX_SUPPORTS_WEAK
1650 dnl
1651 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1652   AC_MSG_CHECKING([for thread model used by GCC])
1653   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1654   AC_MSG_RESULT([$target_thread_file])
1655
1656   if test $target_thread_file != single; then
1657     AC_DEFINE(HAVE_GTHR_DEFAULT)
1658     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1659   fi
1660
1661   glibcxx_thread_h=gthr-$target_thread_file.h
1662   AC_SUBST(glibcxx_thread_h)
1663 ])
1664
1665
1666 # Check whether LC_MESSAGES is available in <locale.h>.
1667 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1668 #
1669 # This file file be copied and used freely without restrictions.  It can
1670 # be used in projects which are not available under the GNU Public License
1671 # but which still want to provide support for the GNU gettext functionality.
1672 # Please note that the actual code is *not* freely available.
1673
1674 # serial 1
1675 AC_DEFUN(AC_LC_MESSAGES, [
1676   AC_CHECK_HEADER(locale.h, [
1677     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1678       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1679        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1680     if test $ac_cv_val_LC_MESSAGES = yes; then
1681       AC_DEFINE(HAVE_LC_MESSAGES)
1682     fi
1683   ])
1684 ])
1685
1686
1687 sinclude([../libtool.m4])
1688 dnl The lines below arrange for aclocal not to bring an installed
1689 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1690 dnl add a definition of LIBTOOL to Makefile.in.
1691 ifelse(,,,[AC_SUBST(LIBTOOL)
1692 AC_DEFUN([AM_PROG_LIBTOOL])
1693 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1694 AC_DEFUN([AC_PROG_LD])
1695 ])
1696
1697 dnl vim:et:ts=2:sw=2