libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   3 dnl
   4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   5 dnl end of configure.  This lets tested variables be reassigned, and the
   6 dnl conditional will depend on the final state of the variable.  For a simple
   7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   8 dnl
   9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  11   m4_divert_text([glibcxx_diversion],dnl
  12    AM_CONDITIONAL([$1],[$2])
  13   )dnl
  14 ])dnl
  15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  16
  17
  18 dnl
  19 dnl Check to see what architecture and operating system we are compiling
  20 dnl for.  Also, if architecture- or OS-specific flags are required for
  21 dnl compilation, pick them up here.
  22 dnl
  23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  24   . $glibcxx_srcdir/configure.host
  25   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  26   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  27 ])
  28
  29 dnl
  30 dnl Initialize the rest of the library configury.  At this point we have
  31 dnl variables like $host.
  32 dnl
  33 dnl Sets:
  34 dnl  SUBDIRS
  35 dnl Substs:
  36 dnl  glibcxx_builddir     (absolute path)
  37 dnl  glibcxx_srcdir       (absolute path)
  38 dnl  toplevel_srcdir      (absolute path)
  39 dnl  with_cross_host
  40 dnl  with_newlib
  41 dnl  with_target_subdir
  42 dnl plus
  43 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  44 dnl  - default settings for all AM_CONFITIONAL test variables
  45 dnl  - lots of tools, like CC and CXX
  46 dnl
  47 AC_DEFUN([GLIBCXX_CONFIGURE], [
  48   # Keep these sync'd with the list in Makefile.am.  The first provides an
  49   # expandable list at autoconf time; the second provides an expandable list
  50   # (i.e., shell variable) at configure time.
  51   m4_define([glibcxx_SUBDIRS],[include libsupc++ python src doc po testsuite])
  52   SUBDIRS='glibcxx_SUBDIRS'
  53
  54   # These need to be absolute paths, yet at the same time need to
  55   # canonicalize only relative paths, because then amd will not unmount
  56   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  57   glibcxx_builddir=`${PWDCMD-pwd}`
  58   case $srcdir in
  59     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  60     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  61   esac
  62   toplevel_srcdir=${glibcxx_srcdir}/..
  63   AC_SUBST(glibcxx_builddir)
  64   AC_SUBST(glibcxx_srcdir)
  65   AC_SUBST(toplevel_srcdir)
  66
  67   # We use these options to decide which functions to include.  They are
  68   # set from the top level.
  69   AC_ARG_WITH([target-subdir],
  70     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  71                    [configuring in a subdirectory]))
  72
  73   AC_ARG_WITH([cross-host],
  74     AC_HELP_STRING([--with-cross-host=HOST],
  75                    [configuring with a cross compiler]))
  76
  77   AC_ARG_WITH([newlib],
  78     AC_HELP_STRING([--with-newlib],
  79                    [assume newlib as a system C library]))
  80
  81   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
  82   # available).  Uncomment the next line to force a particular method.
  83   AC_PROG_LN_S
  84   #LN_S='cp -p'
  85
  86   AC_CHECK_TOOL(AS, as)
  87   AC_CHECK_TOOL(AR, ar)
  88   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
  89
  90   AM_MAINTAINER_MODE
  91
  92   # Set up safe default values for all subsequent AM_CONDITIONAL tests
  93   # which are themselves conditionally expanded.
  94   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
  95   ## other macros from doing the same.  This should be automated.)  -pme
  96
  97   # Check for C library flavor since Linux platforms use different configuration
  98   # directories depending on the C library in use.
  99   AC_EGREP_CPP([_using_uclibc], [
 100   #include <stdio.h>
 101   #if __UCLIBC__
 102     _using_uclibc
 103   #endif
 104   ], uclibc=yes, uclibc=no)
 105
 106   AC_EGREP_CPP([_using_bionic], [
 107   #include <stdio.h>
 108   #if __BIONIC__
 109     _using_bionic
 110   #endif
 111   ], bionic=yes, bionic=no)
 112
 113   # Find platform-specific directories containing configuration info.
 114   # Also possibly modify flags used elsewhere, as needed by the platform.
 115   GLIBCXX_CHECK_HOST
 116 ])
 117
 118
 119 dnl
 120 dnl Tests for newer compiler features, or features that are present in newer
 121 dnl compiler versions but not older compiler versions still in use, should
 122 dnl be placed here.
 123 dnl
 124 dnl Defines:
 125 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 126 dnl   new inlining code or the new system_header pragma will die on -Werror.
 127 dnl   Leave it out by default and use maint-mode to use it.
 128 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 129 dnl   compiler supports it and the user has not requested debug mode.
 130 dnl
 131 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 132   # All these tests are for C++; save the language and the compiler flags.
 133   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 134   # found in GLIBCXX_CONFIGURE.
 135   AC_LANG_SAVE
 136   AC_LANG_CPLUSPLUS
 137   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 138   ac_save_CXXFLAGS="$CXXFLAGS"
 139
 140   # Check for maintainer-mode bits.
 141   if test x"$USE_MAINTAINER_MODE" = xno; then
 142     WERROR=''
 143   else
 144     WERROR='-Werror'
 145   fi
 146
 147   # Check for -ffunction-sections -fdata-sections
 148   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 149   CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
 150   AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
 151   if test "$ac_test_CXXFLAGS" = set; then
 152     CXXFLAGS="$ac_save_CXXFLAGS"
 153   else
 154     # this is the suspicious part
 155     CXXFLAGS=''
 156   fi
 157   if test x"$ac_fdsections" = x"yes"; then
 158     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 159   fi
 160   AC_MSG_RESULT($ac_fdsections)
 161
 162   AC_LANG_RESTORE
 163   AC_SUBST(WERROR)
 164   AC_SUBST(SECTION_FLAGS)
 165 ])
 166
 167
 168 dnl
 169 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 170 dnl the native linker is in use, all variables will be defined to something
 171 dnl safe (like an empty string).
 172 dnl
 173 dnl Defines:
 174 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 175 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 176 dnl  LD (as a side effect of testing)
 177 dnl Sets:
 178 dnl  with_gnu_ld
 179 dnl  glibcxx_ld_is_gold (set to "no" or "yes")
 180 dnl  glibcxx_gnu_ld_version (possibly)
 181 dnl
 182 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 183 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 184 dnl
 185 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 186   # If we're not using GNU ld, then there's no point in even trying these
 187   # tests.  Check for that first.  We should have already tested for gld
 188   # by now (in libtool), but require it now just to be safe...
 189   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 190   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 191   AC_REQUIRE([AC_PROG_LD])
 192   AC_REQUIRE([AC_PROG_AWK])
 193
 194   # The name set by libtool depends on the version of libtool.  Shame on us
 195   # for depending on an impl detail, but c'est la vie.  Older versions used
 196   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 197   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 198   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 199   # set (hence we're using an older libtool), then set it.
 200   if test x${with_gnu_ld+set} != xset; then
 201     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 202       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 203       with_gnu_ld=no
 204     else
 205       with_gnu_ld=$ac_cv_prog_gnu_ld
 206     fi
 207   fi
 208
 209   # Start by getting the version number.  I think the libtool test already
 210   # does some of this, but throws away the result.
 211   glibcxx_ld_is_gold=no
 212   if test x"$with_gnu_ld" = x"yes"; then
 213     AC_MSG_CHECKING([for ld version])
 214     changequote(,)
 215     if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
 216       glibcxx_ld_is_gold=yes
 217     fi
 218     ldver=`$LD --version 2>/dev/null |
 219            sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 220     changequote([,])
 221     glibcxx_gnu_ld_version=`echo $ldver | \
 222            $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 223     AC_MSG_RESULT($glibcxx_gnu_ld_version)
 224   fi
 225
 226   # Set --gc-sections.
 227   glibcxx_have_gc_sections=no
 228   if test "$glibcxx_ld_is_gold" = "yes"; then
 229     if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
 230       glibcxx_have_gc_sections=yes
 231     fi
 232   else
 233     glibcxx_gcsections_min_ld=21602
 234     if test x"$with_gnu_ld" = x"yes" &&
 235         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 236       glibcxx_have_gc_sections=yes
 237     fi
 238   fi
 239   if test "$glibcxx_have_gc_sections" = "yes"; then
 240     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 241     # NB: This flag only works reliably after 2.16.1. Configure tests
 242     # for this are difficult, so hard wire a value that should work.
 243
 244     ac_test_CFLAGS="${CFLAGS+set}"
 245     ac_save_CFLAGS="$CFLAGS"
 246     CFLAGS='-Wl,--gc-sections'
 247
 248     # Check for -Wl,--gc-sections
 249     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 250     AC_TRY_LINK([ int one(void) { return 1; }
 251      int two(void) { return 2; }
 252         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 253     if test "$ac_gcsections" = "yes"; then
 254       rm -f conftest.c
 255       touch conftest.c
 256       if $CC -c conftest.c; then
 257         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 258            grep "Warning: gc-sections option ignored" > /dev/null; then
 259           ac_gcsections=no
 260         fi
 261       fi
 262       rm -f conftest.c conftest.o conftest
 263     fi
 264     if test "$ac_gcsections" = "yes"; then
 265       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 266     fi
 267     AC_MSG_RESULT($ac_gcsections)
 268
 269     if test "$ac_test_CFLAGS" = set; then
 270       CFLAGS="$ac_save_CFLAGS"
 271     else
 272       # this is the suspicious part
 273       CFLAGS=''
 274     fi
 275   fi
 276
 277   # Set -z,relro.
 278   # Note this is only for shared objects.
 279   ac_ld_relro=no
 280   if test x"$with_gnu_ld" = x"yes"; then
 281     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 282     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 283     if test -n "$cxx_z_relo"; then
 284       OPT_LDFLAGS="-Wl,-z,relro"
 285       ac_ld_relro=yes
 286     fi
 287     AC_MSG_RESULT($ac_ld_relro)
 288   fi
 289
 290   # Set linker optimization flags.
 291   if test x"$with_gnu_ld" = x"yes"; then
 292     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 293   fi
 294
 295   AC_SUBST(SECTION_LDFLAGS)
 296   AC_SUBST(OPT_LDFLAGS)
 297 ])
 298
 299
 300 dnl
 301 dnl Check for headers for, and arguments to, the setrlimit() function.
 302 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 303 dnl
 304 dnl Defines:
 305 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 306 dnl  various HAVE_LIMIT_* for individual limit names
 307 dnl
 308 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 309   AC_MSG_CHECKING([for RLIMIT_$1])
 310   AC_TRY_COMPILE(
 311     [#include <unistd.h>
 312      #include <sys/time.h>
 313      #include <sys/resource.h>
 314     ],
 315     [ int f = RLIMIT_$1 ; ],
 316     [glibcxx_mresult=1], [glibcxx_mresult=0])
 317   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 318                      [Only used in build directory testsuite_hooks.h.])
 319   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 320   AC_MSG_RESULT($res)
 321 ])
 322
 323 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 324   setrlimit_have_headers=yes
 325   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 326                    [],
 327                    [setrlimit_have_headers=no])
 328   # If don't have the headers, then we can't run the tests now, and we
 329   # won't be seeing any of these during testsuite compilation.
 330   if test $setrlimit_have_headers = yes; then
 331     # Can't do these in a loop, else the resulting syntax is wrong.
 332     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 333     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 334     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 335     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 336     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 337
 338     # Check for rlimit, setrlimit.
 339     AC_CACHE_VAL(glibcxx_cv_setrlimit, [
 340       AC_TRY_COMPILE(
 341         [#include <unistd.h>
 342          #include <sys/time.h>
 343          #include <sys/resource.h>
 344         ],
 345         [struct rlimit r;
 346          setrlimit(0, &r);],
 347         [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
 348     ])
 349   fi
 350
 351   AC_MSG_CHECKING([for testsuite resource limits support])
 352   if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
 353     ac_res_limits=yes
 354     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 355               [Define if using setrlimit to set resource limits during
 356               "make check"])
 357   else
 358     ac_res_limits=no
 359   fi
 360   AC_MSG_RESULT($ac_res_limits)
 361 ])
 362
 363
 364 dnl
 365 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 366 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 367 dnl
 368 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 369
 370   AC_LANG_SAVE
 371   AC_LANG_CPLUSPLUS
 372   ac_save_CXXFLAGS="$CXXFLAGS"
 373   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 374
 375   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 376   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 377     GCC_TRY_COMPILE_OR_LINK(
 378       [#include <sys/stat.h>],
 379       [struct stat buffer;
 380        fstat(0, &buffer);
 381        S_ISREG(buffer.st_mode);],
 382       [glibcxx_cv_S_ISREG=yes],
 383       [glibcxx_cv_S_ISREG=no])
 384   ])
 385   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 386     GCC_TRY_COMPILE_OR_LINK(
 387       [#include <sys/stat.h>],
 388       [struct stat buffer;
 389        fstat(0, &buffer);
 390        S_IFREG & buffer.st_mode;],
 391       [glibcxx_cv_S_IFREG=yes],
 392       [glibcxx_cv_S_IFREG=no])
 393   ])
 394   res=no
 395   if test $glibcxx_cv_S_ISREG = yes; then
 396     AC_DEFINE(HAVE_S_ISREG, 1,
 397               [Define if S_IFREG is available in <sys/stat.h>.])
 398     res=S_ISREG
 399   elif test $glibcxx_cv_S_IFREG = yes; then
 400     AC_DEFINE(HAVE_S_IFREG, 1,
 401               [Define if S_IFREG is available in <sys/stat.h>.])
 402     res=S_IFREG
 403   fi
 404   AC_MSG_RESULT($res)
 405
 406   CXXFLAGS="$ac_save_CXXFLAGS"
 407   AC_LANG_RESTORE
 408 ])
 409
 410
 411 dnl
 412 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 413 dnl
 414 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 415
 416   AC_LANG_SAVE
 417   AC_LANG_CPLUSPLUS
 418   ac_save_CXXFLAGS="$CXXFLAGS"
 419   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 420
 421   AC_MSG_CHECKING([for poll])
 422   AC_CACHE_VAL(glibcxx_cv_POLL, [
 423     GCC_TRY_COMPILE_OR_LINK(
 424       [#include <poll.h>],
 425       [struct pollfd pfd[1];
 426        pfd[0].events = POLLIN;
 427        poll(pfd, 1, 0);],
 428       [glibcxx_cv_POLL=yes],
 429       [glibcxx_cv_POLL=no])
 430   ])
 431   if test $glibcxx_cv_POLL = yes; then
 432     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 433   fi
 434   AC_MSG_RESULT($glibcxx_cv_POLL)
 435
 436   CXXFLAGS="$ac_save_CXXFLAGS"
 437   AC_LANG_RESTORE
 438 ])
 439
 440
 441 dnl
 442 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 443 dnl
 444 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 445
 446   AC_LANG_SAVE
 447   AC_LANG_CPLUSPLUS
 448   ac_save_CXXFLAGS="$CXXFLAGS"
 449   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 450
 451   AC_MSG_CHECKING([for writev])
 452   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 453     GCC_TRY_COMPILE_OR_LINK(
 454       [#include <sys/uio.h>],
 455       [struct iovec iov[2];
 456        writev(0, iov, 0);],
 457       [glibcxx_cv_WRITEV=yes],
 458       [glibcxx_cv_WRITEV=no])
 459   ])
 460   if test $glibcxx_cv_WRITEV = yes; then
 461     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 462   fi
 463   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 464
 465   CXXFLAGS="$ac_save_CXXFLAGS"
 466   AC_LANG_RESTORE
 467 ])
 468
 469
 470 dnl
 471 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 472 dnl Also check whether int64_t is actually a typedef to long or long long.
 473 dnl
 474 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 475
 476   AC_LANG_SAVE
 477   AC_LANG_CPLUSPLUS
 478
 479   AC_MSG_CHECKING([for int64_t])
 480   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 481     AC_TRY_COMPILE(
 482       [#include <stdint.h>],
 483       [int64_t var;],
 484       [glibcxx_cv_INT64_T=yes],
 485       [glibcxx_cv_INT64_T=no])
 486   ])
 487
 488   if test $glibcxx_cv_INT64_T = yes; then
 489     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 490     AC_MSG_RESULT($glibcxx_cv_INT64_T)
 491
 492     AC_MSG_CHECKING([for int64_t as long])
 493     AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
 494       AC_TRY_COMPILE(
 495         [#include <stdint.h>
 496         template<typename, typename> struct same { enum { value = -1 }; };
 497         template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
 498         int array[same<int64_t, long>::value];], [],
 499         [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
 500     ])
 501
 502     if test $glibcxx_cv_int64_t_long = yes; then
 503       AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
 504       AC_MSG_RESULT($glibcxx_cv_int64_t_long)
 505     fi
 506
 507     AC_MSG_CHECKING([for int64_t as long long])
 508     AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
 509       AC_TRY_COMPILE(
 510         [#include <stdint.h>
 511         template<typename, typename> struct same { enum { value = -1 }; };
 512         template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
 513         int array[same<int64_t, long long>::value];], [],
 514         [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
 515     ])
 516
 517     if test $glibcxx_cv_int64_t_long_long = yes; then
 518       AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
 519       AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
 520     fi
 521   fi
 522
 523   AC_LANG_RESTORE
 524 ])
 525
 526
 527 dnl
 528 dnl Check whether LFS support is available.
 529 dnl
 530 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 531   AC_LANG_SAVE
 532   AC_LANG_CPLUSPLUS
 533   ac_save_CXXFLAGS="$CXXFLAGS"
 534   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 535   AC_MSG_CHECKING([for LFS support])
 536   AC_CACHE_VAL(glibcxx_cv_LFS, [
 537     GCC_TRY_COMPILE_OR_LINK(
 538       [#include <unistd.h>
 539        #include <stdio.h>
 540        #include <sys/stat.h>
 541       ],
 542       [FILE* fp;
 543        fopen64("t", "w");
 544        fseeko64(fp, 0, SEEK_CUR);
 545        ftello64(fp);
 546        lseek64(1, 0, SEEK_CUR);
 547        struct stat64 buf;
 548        fstat64(1, &buf);],
 549       [glibcxx_cv_LFS=yes],
 550       [glibcxx_cv_LFS=no])
 551   ])
 552   if test $glibcxx_cv_LFS = yes; then
 553     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 554   fi
 555   AC_MSG_RESULT($glibcxx_cv_LFS)
 556   CXXFLAGS="$ac_save_CXXFLAGS"
 557   AC_LANG_RESTORE
 558 ])
 559
 560
 561 dnl
 562 dnl Check for whether a fully dynamic basic_string implementation should
 563 dnl be turned on, that does not put empty objects in per-process static
 564 dnl memory (mostly useful together with shared memory allocators, see PR
 565 dnl libstdc++/16612 for details).
 566 dnl
 567 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 568 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 569 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 570 dnl       Where DEFAULT is either `yes' or `no'.
 571 dnl
 572 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 573   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 574   if test $enable_fully_dynamic_string = yes; then
 575     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 576               [Define if a fully dynamic basic_string is wanted.])
 577   fi
 578 ])
 579
 580
 581 dnl
 582 dnl Does any necessary configuration of the testsuite directory.  Generates
 583 dnl the testsuite_hooks.h header.
 584 dnl
 585 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 586 dnl
 587 dnl Sets:
 588 dnl  enable_abi_check
 589 dnl  GLIBCXX_TEST_WCHAR_T
 590 dnl  GLIBCXX_TEST_THREAD
 591 dnl Substs:
 592 dnl  baseline_dir
 593 dnl  baseline_subdir_switch
 594 dnl
 595 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 596   if $GLIBCXX_IS_NATIVE ; then
 597     # Do checks for resource limit functions.
 598     GLIBCXX_CHECK_SETRLIMIT
 599
 600     # Look for setenv, so that extended locale tests can be performed.
 601     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 602   fi
 603
 604   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 605      test $enable_symvers != no; then
 606     case "$host" in
 607       *-*-cygwin*)
 608         enable_abi_check=no ;;
 609       *)
 610         enable_abi_check=yes ;;
 611     esac
 612   else
 613     # Only build this as native, since automake does not understand
 614     # CXX_FOR_BUILD.
 615     enable_abi_check=no
 616   fi
 617
 618   # Export file names for ABI checking.
 619   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
 620   AC_SUBST(baseline_dir)
 621   baseline_subdir_switch="$abi_baseline_subdir_switch"
 622   AC_SUBST(baseline_subdir_switch)
 623 ])
 624
 625
 626 dnl
 627 dnl Does any necessary configuration of the documentation directory.
 628 dnl
 629 dnl XSLTPROC must be set before this
 630 dnl
 631 dnl Sets:
 632 dnl  glibcxx_stylesheets
 633 dnl Substs:
 634 dnl  XSL_STYLE_DIR
 635 dnl
 636 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
 637
 638 AC_MSG_CHECKING([for stylesheets used in generation of documentation])
 639 glibcxx_stylesheets=no
 640 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
 641   glibcxx_stylesheets=yes
 642 fi
 643 AC_MSG_RESULT($glibcxx_stylesheets)
 644
 645 AC_MSG_CHECKING([for local stylesheet directory])
 646 glibcxx_local_stylesheets=no
 647 if test x"$glibcxx_stylesheets" = x"yes"; then
 648   if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
 649     glibcxx_local_stylesheets=yes
 650     XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
 651   fi
 652   if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
 653     glibcxx_local_stylesheets=yes
 654     XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
 655   fi
 656 fi
 657 AC_MSG_RESULT($glibcxx_local_stylesheets)
 658
 659 if test x"$glibcxx_local_stylesheets" = x"yes"; then
 660   AC_SUBST(XSL_STYLE_DIR)
 661   AC_MSG_NOTICE($XSL_STYLE_DIR)
 662 else
 663   glibcxx_stylesheets=no
 664 fi
 665 ])
 666
 667
 668 dnl
 669 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 670 dnl
 671 dnl Substs:
 672 dnl  GLIBCXX_INCLUDES
 673 dnl  TOPLEVEL_INCLUDES
 674 dnl
 675 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 676   # Used for every C++ compile we perform.
 677   GLIBCXX_INCLUDES="\
 678 -I$glibcxx_builddir/include/$host_alias \
 679 -I$glibcxx_builddir/include \
 680 -I$glibcxx_srcdir/libsupc++"
 681
 682   # For Canadian crosses, pick this up too.
 683   if test $CANADIAN = yes; then
 684     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 685   fi
 686
 687   # Stuff in the actual top level.  Currently only used by libsupc++ to
 688   # get unwind* headers from the gcc dir.
 689   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 690   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 691
 692   # Now, export this to all the little Makefiles....
 693   AC_SUBST(GLIBCXX_INCLUDES)
 694   AC_SUBST(TOPLEVEL_INCLUDES)
 695 ])
 696
 697
 698 dnl
 699 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 700 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 701 dnl
 702 dnl Substs:
 703 dnl  OPTIMIZE_CXXFLAGS
 704 dnl  WARN_FLAGS
 705 dnl
 706 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 707   # Optimization flags that are probably a good idea for thrill-seekers. Just
 708   # uncomment the lines below and make, everything else is ready to go...
 709   # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
 710   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 711   AC_SUBST(OPTIMIZE_CXXFLAGS)
 712
 713   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 714   AC_SUBST(WARN_FLAGS)
 715 ])
 716
 717
 718 dnl
 719 dnl All installation directory information is determined here.
 720 dnl
 721 dnl Substs:
 722 dnl  gxx_install_dir
 723 dnl  glibcxx_prefixdir
 724 dnl  glibcxx_toolexecdir
 725 dnl  glibcxx_toolexeclibdir
 726 dnl
 727 dnl Assumes cross_compiling bits already done, and with_cross_host in
 728 dnl particular.
 729 dnl
 730 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
 731 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
 732 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 733   glibcxx_toolexecdir=no
 734   glibcxx_toolexeclibdir=no
 735   glibcxx_prefixdir=$prefix
 736
 737   AC_MSG_CHECKING([for gxx-include-dir])
 738   AC_ARG_WITH([gxx-include-dir],
 739     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 740                    [installation directory for include files]),
 741     [case "$withval" in
 742       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 743       no)  gxx_include_dir=no ;;
 744       *)   gxx_include_dir=$withval ;;
 745      esac],
 746     [gxx_include_dir=no])
 747   AC_MSG_RESULT($gxx_include_dir)
 748
 749   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 750   AC_ARG_ENABLE([version-specific-runtime-libs],
 751     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 752                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 753     [case "$enableval" in
 754       yes) version_specific_libs=yes ;;
 755       no)  version_specific_libs=no ;;
 756       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 757      esac],
 758     [version_specific_libs=no])
 759   AC_MSG_RESULT($version_specific_libs)
 760
 761   # Default case for install directory for include files.
 762   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 763     gxx_include_dir='include/c++/${gcc_version}'
 764     if test -n "$with_cross_host" &&
 765        test x"$with_cross_host" != x"no"; then
 766       gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
 767     else
 768       gxx_include_dir='${prefix}/'"$gxx_include_dir"
 769     fi
 770   fi
 771
 772   # Version-specific runtime libs processing.
 773   if test $version_specific_libs = yes; then
 774     # Need the gcc compiler version to know where to install libraries
 775     # and header files if --enable-version-specific-runtime-libs option
 776     # is selected.  FIXME: these variables are misnamed, there are
 777     # no executables installed in _toolexecdir or _toolexeclibdir.
 778     if test x"$gxx_include_dir" = x"no"; then
 779       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 780     fi
 781     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 782     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 783   fi
 784
 785   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 786   # Install a library built with a cross compiler in tooldir, not libdir.
 787   if test x"$glibcxx_toolexecdir" = x"no"; then
 788     if test -n "$with_cross_host" &&
 789        test x"$with_cross_host" != x"no"; then
 790       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 791       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 792     else
 793       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 794       glibcxx_toolexeclibdir='${libdir}'
 795     fi
 796     multi_os_directory=`$CXX -print-multi-os-directory`
 797     case $multi_os_directory in
 798       .) ;; # Avoid trailing /.
 799       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 800     esac
 801   fi
 802
 803   AC_MSG_CHECKING([for install location])
 804   AC_MSG_RESULT($gxx_include_dir)
 805
 806   AC_SUBST(glibcxx_prefixdir)
 807   AC_SUBST(gxx_include_dir)
 808   AC_SUBST(glibcxx_toolexecdir)
 809   AC_SUBST(glibcxx_toolexeclibdir)
 810 ])
 811
 812
 813 dnl
 814 dnl GLIBCXX_ENABLE
 815 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 816 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 817 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 818 dnl
 819 dnl See docs/html/17_intro/configury.html#enable for documentation.
 820 dnl
 821 m4_define([GLIBCXX_ENABLE],[dnl
 822 m4_define([_g_switch],[--enable-$1])dnl
 823 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
 824  AC_ARG_ENABLE([$1],m4_dquote(_g_help),
 825   m4_bmatch([$5],
 826    [^permit ],
 827      [[
 828       case "$enableval" in
 829        m4_bpatsubst([$5],[permit ])) ;;
 830        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 831           dnl Idea for future:  generate a URL pointing to
 832           dnl "onlinedocs/configopts.html#whatever"
 833       esac
 834      ]],
 835    [^$],
 836      [[
 837       case "$enableval" in
 838        yes|no) ;;
 839        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 840       esac
 841      ]],
 842    [[$5]]),
 843   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 844 m4_undefine([_g_switch])dnl
 845 m4_undefine([_g_help])dnl
 846 ])
 847
 848
 849 dnl
 850 dnl Check for ISO/IEC 9899:1999 "C99" support.
 851 dnl
 852 dnl --enable-c99 defines _GLIBCXX_USE_C99
 853 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 854 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 855 dnl       Where DEFAULT is either `yes' or `no'.
 856 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 857 dnl
 858 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 859   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 860
 861   if test x"$enable_c99" = x"yes"; then
 862
 863   AC_LANG_SAVE
 864   AC_LANG_CPLUSPLUS
 865
 866   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
 867   # undefined and fake C99 facilities - like pre-standard snprintf - may be
 868   # spuriously enabled.
 869   # Long term, -std=c++0x could be even better, could manage to explicitely
 870   # request C99 facilities to the underlying C headers.
 871   ac_save_CXXFLAGS="$CXXFLAGS"
 872   CXXFLAGS="$CXXFLAGS -std=c++98"
 873   ac_save_LIBS="$LIBS"
 874   ac_save_gcc_no_link="$gcc_no_link"
 875
 876   if test x$gcc_no_link != xyes; then
 877     # Use -fno-exceptions to that the C driver can link these tests without
 878     # hitting undefined references to personality routines.
 879     CXXFLAGS="$CXXFLAGS -fno-exceptions"
 880     AC_CHECK_LIB(m, sin, [
 881       LIBS="$LIBS -lm"
 882     ], [
 883       # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
 884       gcc_no_link=yes
 885     ])
 886   fi
 887
 888   # Check for the existence of <math.h> functions used if C99 is enabled.
 889   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 890   AC_CACHE_VAL(glibcxx_cv_c99_math, [
 891   GCC_TRY_COMPILE_OR_LINK(
 892      [#include <math.h>
 893       volatile double d1, d2;
 894       volatile int i;],
 895      [i = fpclassify(d1);
 896       i = isfinite(d1);
 897       i = isinf(d1);
 898       i = isnan(d1);
 899       i = isnormal(d1);
 900       i = signbit(d1);
 901       i = isgreater(d1, d2);
 902       i = isgreaterequal(d1, d2);
 903       i = isless(d1, d2);
 904       i = islessequal(d1, d2);
 905       i = islessgreater(d1, d2);
 906       i = islessgreater(d1, d2);
 907       i = isunordered(d1, d2);
 908      ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
 909   ])
 910   AC_MSG_RESULT($glibcxx_cv_c99_math)
 911   if test x"$glibcxx_cv_c99_math" = x"yes"; then
 912     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 913               [Define if C99 functions or macros in <math.h> should be imported
 914               in <cmath> in namespace std.])
 915   fi
 916
 917   # Check for the existence of <complex.h> complex math functions.
 918   # This is necessary even though libstdc++ uses the builtin versions
 919   # of these functions, because if the builtin cannot be used, a reference
 920   # to the library function is emitted.
 921   AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
 922   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 923   glibcxx_cv_c99_complex=no;
 924   if test x"$ac_has_complex_h" = x"yes"; then
 925     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 926     GCC_TRY_COMPILE_OR_LINK(
 927        [#include <complex.h>
 928         typedef __complex__ float float_type;
 929         typedef __complex__ double double_type;
 930         typedef __complex__ long double ld_type;
 931         volatile float_type tmpf;
 932         volatile double_type tmpd;
 933         volatile ld_type tmpld;
 934         volatile float f;
 935         volatile double d;
 936         volatile long double ld;],
 937        [f = cabsf(tmpf);
 938         f = cargf(tmpf);
 939         tmpf = ccosf(tmpf);
 940         tmpf = ccoshf(tmpf);
 941         tmpf = cexpf(tmpf);
 942         tmpf = clogf(tmpf);
 943         tmpf = csinf(tmpf);
 944         tmpf = csinhf(tmpf);
 945         tmpf = csqrtf(tmpf);
 946         tmpf = ctanf(tmpf);
 947         tmpf = ctanhf(tmpf);
 948         tmpf = cpowf(tmpf, tmpf);
 949         tmpf = cprojf(tmpf);
 950         d = cabs(tmpd);
 951         d = carg(tmpd);
 952         tmpd = ccos(tmpd);
 953         tmpd = ccosh(tmpd);
 954         tmpd = cexp(tmpd);
 955         tmpd = clog(tmpd);
 956         tmpd = csin(tmpd);
 957         tmpd = csinh(tmpd);
 958         tmpd = csqrt(tmpd);
 959         tmpd = ctan(tmpd);
 960         tmpd = ctanh(tmpd);
 961         tmpd = cpow(tmpd, tmpd);
 962         tmpd = cproj(tmpd);
 963         ld = cabsl(tmpld);
 964         ld = cargl(tmpld);
 965         tmpld = ccosl(tmpld);
 966         tmpld = ccoshl(tmpld);
 967         tmpld = cexpl(tmpld);
 968         tmpld = clogl(tmpld);
 969         tmpld = csinl(tmpld);
 970         tmpld = csinhl(tmpld);
 971         tmpld = csqrtl(tmpld);
 972         tmpld = ctanl(tmpld);
 973         tmpld = ctanhl(tmpld);
 974         tmpld = cpowl(tmpld, tmpld);
 975         tmpld = cprojl(tmpld);
 976        ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
 977   fi
 978   AC_MSG_RESULT($glibcxx_cv_c99_complex)
 979   if test x"$glibcxx_cv_c99_complex" = x"yes"; then
 980     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 981               [Define if C99 functions in <complex.h> should be used in
 982               <complex>. Using compiler builtins for these functions requires
 983               corresponding C99 library functions to be present.])
 984   fi
 985
 986   # Check for the existence in <stdio.h> of vscanf, et. al.
 987   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 988   AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
 989   GCC_TRY_COMPILE_OR_LINK(
 990      [#include <stdio.h>
 991       #include <stdarg.h>
 992       void foo(char* fmt, ...)
 993       {
 994         va_list args; va_start(args, fmt);
 995         vfscanf(stderr, "%i", args);
 996         vscanf("%i", args);
 997         vsnprintf(fmt, 0, "%i", args);
 998         vsscanf(fmt, "%i", args);
 999       }],
1000      [snprintf("12", 0, "%i");],
1001      [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1002   ])
1003   AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1004
1005   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1006   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1007   AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1008   GCC_TRY_COMPILE_OR_LINK(
1009      [#include <stdlib.h>
1010       volatile float f;
1011       volatile long double ld;
1012       volatile unsigned long long ll;
1013       lldiv_t mydivt;],
1014      [char* tmp;
1015       f = strtof("gnu", &tmp);
1016       ld = strtold("gnu", &tmp);
1017       ll = strtoll("gnu", &tmp, 10);
1018       ll = strtoull("gnu", &tmp, 10);
1019       ll = llabs(10);
1020       mydivt = lldiv(10,1);
1021       ll = mydivt.quot;
1022       ll = mydivt.rem;
1023       ll = atoll("10");
1024       _Exit(0);
1025       ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1026   ])
1027   AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1028
1029   # Check for the existence in <wchar.h> of wcstold, etc.
1030   glibcxx_cv_c99_wchar=no;
1031   if test x"$ac_has_wchar_h" = xyes &&
1032      test x"$ac_has_wctype_h" = xyes; then
1033     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1034     AC_TRY_COMPILE([#include <wchar.h>
1035                     namespace test
1036                     {
1037                       using ::wcstold;
1038                       using ::wcstoll;
1039                       using ::wcstoull;
1040                     }
1041                    ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1042
1043     # Checks for wide character functions that may not be present.
1044     # Injection of these is wrapped with guard macros.
1045     # NB: only put functions here, instead of immediately above, if
1046     # absolutely necessary.
1047     AC_TRY_COMPILE([#include <wchar.h>
1048                     namespace test { using ::vfwscanf; } ], [],
1049                    [AC_DEFINE(HAVE_VFWSCANF,1,
1050                         [Defined if vfwscanf exists.])],[])
1051
1052     AC_TRY_COMPILE([#include <wchar.h>
1053                     namespace test { using ::vswscanf; } ], [],
1054                    [AC_DEFINE(HAVE_VSWSCANF,1,
1055                         [Defined if vswscanf exists.])],[])
1056
1057     AC_TRY_COMPILE([#include <wchar.h>
1058                     namespace test { using ::vwscanf; } ], [],
1059                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1060
1061     AC_TRY_COMPILE([#include <wchar.h>
1062                     namespace test { using ::wcstof; } ], [],
1063                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1064
1065     AC_TRY_COMPILE([#include <wctype.h>],
1066                    [ wint_t t; int i = iswblank(t);],
1067                    [AC_DEFINE(HAVE_ISWBLANK,1,
1068                         [Defined if iswblank exists.])],[])
1069
1070     AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1071   fi
1072
1073   # Option parsed, now set things appropriately.
1074   if test x"$glibcxx_cv_c99_math" = x"no" ||
1075      test x"$glibcxx_cv_c99_complex" = x"no" ||
1076      test x"$glibcxx_cv_c99_stdio" = x"no" ||
1077      test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1078      test x"$glibcxx_cv_c99_wchar" = x"no"; then
1079     enable_c99=no;
1080   else
1081     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1082     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1083     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1084   fi
1085
1086   gcc_no_link="$ac_save_gcc_no_link"
1087   LIBS="$ac_save_LIBS"
1088   CXXFLAGS="$ac_save_CXXFLAGS"
1089   AC_LANG_RESTORE
1090   fi
1091
1092   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1093   AC_MSG_RESULT($enable_c99)
1094 ])
1095
1096
1097 dnl
1098 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1099 dnl implementation of 20.8.5 [time.clock], and 30.2.2 [thread.thread.this]
1100 dnl in the current C++0x working draft.
1101 dnl
1102 dnl --enable-libstdcxx-time
1103 dnl --enable-libstdcxx-time=yes
1104 dnl        checks for the availability of monotonic and realtime clocks,
1105 dnl        nanosleep and sched_yield in libc and libposix4 and, in case, links
1106 dnl       the latter
1107 dnl --enable-libstdcxx-time=rt
1108 dnl        also searches (and, in case, links) librt.  Note that this is
1109 dnl        not always desirable because, in glibc, for example, in turn it
1110 dnl        triggers the linking of libpthread too, which activates locking,
1111 dnl        a large overhead for single-thread programs.
1112 dnl --enable-libstdcxx-time=no
1113 dnl --disable-libstdcxx-time
1114 dnl        disables the checks completely
1115 dnl
1116 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1117
1118   AC_MSG_CHECKING([for clock_gettime, nanosleep and sched_yield])
1119   GLIBCXX_ENABLE(libstdcxx-time,$1,[[[=KIND]]],
1120     [use KIND for check type],
1121     [permit yes|no|rt])
1122
1123   AC_LANG_SAVE
1124   AC_LANG_CPLUSPLUS
1125   ac_save_CXXFLAGS="$CXXFLAGS"
1126   CXXFLAGS="$CXXFLAGS -fno-exceptions"
1127   ac_save_LIBS="$LIBS"
1128
1129   ac_has_clock_monotonic=no
1130   ac_has_clock_realtime=no
1131   AC_MSG_RESULT($enable_libstdcxx_time)
1132
1133   if test x"$enable_libstdcxx_time" != x"no"; then
1134
1135     if test x"$enable_libstdcxx_time" = x"rt"; then
1136       AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1137       AC_SEARCH_LIBS(nanosleep, [rt posix4])
1138     else
1139       AC_SEARCH_LIBS(clock_gettime, [posix4])
1140       AC_SEARCH_LIBS(nanosleep, [posix4])
1141     fi
1142
1143     case "$ac_cv_search_clock_gettime" in
1144       -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1145       ;;
1146     esac
1147     case "$ac_cv_search_nanosleep" in
1148       -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1149       ;;
1150     esac
1151
1152     AC_SEARCH_LIBS(sched_yield, [rt posix4])
1153
1154     case "$ac_cv_search_sched_yield" in
1155       -lposix4*)
1156       GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1157       AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1158                 [ Defined if sched_yield is available. ])
1159       ;;
1160       -lrt*)
1161       if test x"$enable_libstdcxx_time" = x"rt"; then
1162         GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1163         AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1164                   [ Defined if sched_yield is available. ])
1165       fi
1166       ;;
1167       *)
1168       AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1169                 [ Defined if sched_yield is available. ])
1170       ;;
1171     esac
1172
1173     AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1174
1175     if test x"$ac_has_unistd_h" = x"yes"; then
1176       AC_MSG_CHECKING([for monotonic clock])
1177       AC_TRY_LINK(
1178         [#include <unistd.h>
1179          #include <time.h>
1180         ],
1181         [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1182           timespec tp;
1183          #endif
1184           clock_gettime(CLOCK_MONOTONIC, &tp);
1185         ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1186
1187       AC_MSG_RESULT($ac_has_clock_monotonic)
1188
1189       AC_MSG_CHECKING([for realtime clock])
1190       AC_TRY_LINK(
1191         [#include <unistd.h>
1192          #include <time.h>
1193         ],
1194         [#if _POSIX_TIMERS > 0
1195           timespec tp;
1196          #endif
1197           clock_gettime(CLOCK_REALTIME, &tp);
1198         ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1199
1200       AC_MSG_RESULT($ac_has_clock_realtime)
1201
1202       AC_MSG_CHECKING([for nanosleep])
1203       AC_TRY_LINK(
1204         [#include <unistd.h>
1205          #include <time.h>
1206         ],
1207         [#if _POSIX_TIMERS > 0
1208           timespec tp;
1209          #endif
1210           nanosleep(&tp, 0);
1211         ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1212
1213       AC_MSG_RESULT($ac_has_nanosleep)
1214     fi
1215   fi
1216
1217   if test x"$ac_has_clock_monotonic" = x"yes"; then
1218     AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1219       [ Defined if clock_gettime has monotonic clock support. ])
1220   fi
1221
1222   if test x"$ac_has_clock_realtime" = x"yes"; then
1223     AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1224       [ Defined if clock_gettime has realtime clock support. ])
1225   fi
1226
1227   if test x"$ac_has_nanosleep" = x"yes"; then
1228     AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1229       [ Defined if nanosleep is available. ])
1230   fi
1231
1232   AC_SUBST(GLIBCXX_LIBS)
1233
1234   CXXFLAGS="$ac_save_CXXFLAGS"
1235   LIBS="$ac_save_LIBS"
1236   AC_LANG_RESTORE
1237 ])
1238
1239 dnl
1240 dnl Check for gettimeofday, used in the implementation of 20.8.5
1241 dnl [time.clock] in the current C++0x working draft.
1242 dnl
1243 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1244
1245   AC_MSG_CHECKING([for gettimeofday])
1246
1247   AC_LANG_SAVE
1248   AC_LANG_CPLUSPLUS
1249   ac_save_CXXFLAGS="$CXXFLAGS"
1250   CXXFLAGS="$CXXFLAGS -fno-exceptions"
1251
1252   ac_has_gettimeofday=no;
1253   AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1254   if test x"$ac_has_sys_time_h" = x"yes"; then
1255     AC_MSG_CHECKING([for gettimeofday])
1256     GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1257       [timeval tv; gettimeofday(&tv, 0);],
1258       [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1259
1260     AC_MSG_RESULT($ac_has_gettimeofday)
1261   fi
1262
1263   if test x"$ac_has_gettimeofday" = x"yes"; then
1264     AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1265       [ Defined if gettimeofday is available. ])
1266   fi
1267
1268   CXXFLAGS="$ac_save_CXXFLAGS"
1269   AC_LANG_RESTORE
1270 ])
1271
1272 dnl
1273 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1274 dnl facilities in Chapter 8, "C compatibility".
1275 dnl
1276 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1277
1278   AC_LANG_SAVE
1279   AC_LANG_CPLUSPLUS
1280
1281   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1282   # undefined and fake C99 facilities may be spuriously enabled.
1283   ac_save_CXXFLAGS="$CXXFLAGS"
1284   CXXFLAGS="$CXXFLAGS -std=c++98"
1285
1286   # Check for the existence of <complex.h> complex math functions used
1287   # by tr1/complex.
1288   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1289   ac_c99_complex_tr1=no;
1290   if test x"$ac_has_complex_h" = x"yes"; then
1291     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1292     AC_TRY_COMPILE([#include <complex.h>],
1293                    [typedef __complex__ float float_type; float_type tmpf;
1294                     cacosf(tmpf);
1295                     casinf(tmpf);
1296                     catanf(tmpf);
1297                     cacoshf(tmpf);
1298                     casinhf(tmpf);
1299                     catanhf(tmpf);
1300                     typedef __complex__ double double_type; double_type tmpd;
1301                     cacos(tmpd);
1302                     casin(tmpd);
1303                     catan(tmpd);
1304                     cacosh(tmpd);
1305                     casinh(tmpd);
1306                     catanh(tmpd);
1307                     typedef __complex__ long double ld_type; ld_type tmpld;
1308                     cacosl(tmpld);
1309                     casinl(tmpld);
1310                     catanl(tmpld);
1311                     cacoshl(tmpld);
1312                     casinhl(tmpld);
1313                     catanhl(tmpld);
1314                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1315   fi
1316   AC_MSG_RESULT($ac_c99_complex_tr1)
1317   if test x"$ac_c99_complex_tr1" = x"yes"; then
1318     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1319               [Define if C99 functions in <complex.h> should be used in
1320               <tr1/complex>. Using compiler builtins for these functions
1321               requires corresponding C99 library functions to be present.])
1322   fi
1323
1324   # Check for the existence of <ctype.h> functions.
1325   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1326   AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1327   AC_TRY_COMPILE([#include <ctype.h>],
1328                  [int ch;
1329                   int ret;
1330                   ret = isblank(ch);
1331                  ],[glibcxx_cv_c99_ctype_tr1=yes],
1332                    [glibcxx_cv_c99_ctype_tr1=no])
1333   ])
1334   AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1335   if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1336     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1337               [Define if C99 functions in <ctype.h> should be imported in
1338               <tr1/cctype> in namespace std::tr1.])
1339   fi
1340
1341   # Check for the existence of <fenv.h> functions.
1342   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1343   ac_c99_fenv_tr1=no;
1344   if test x"$ac_has_fenv_h" = x"yes"; then
1345     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1346     AC_TRY_COMPILE([#include <fenv.h>],
1347                    [int except, mode;
1348                     fexcept_t* pflag;
1349                     fenv_t* penv;
1350                     int ret;
1351                     ret = feclearexcept(except);
1352                     ret = fegetexceptflag(pflag, except);
1353                     ret = feraiseexcept(except);
1354                     ret = fesetexceptflag(pflag, except);
1355                     ret = fetestexcept(except);
1356                     ret = fegetround();
1357                     ret = fesetround(mode);
1358                     ret = fegetenv(penv);
1359                     ret = feholdexcept(penv);
1360                     ret = fesetenv(penv);
1361                     ret = feupdateenv(penv);
1362                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1363   fi
1364   AC_MSG_RESULT($ac_c99_fenv_tr1)
1365   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1366     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1367               [Define if C99 functions in <fenv.h> should be imported in
1368               <tr1/cfenv> in namespace std::tr1.])
1369   fi
1370
1371   # Check for the existence of <stdint.h> types.
1372   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1373   AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1374   AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1375                   #define __STDC_CONSTANT_MACROS
1376                   #include <stdint.h>],
1377                  [typedef int8_t          my_int8_t;
1378                   my_int8_t               i8 = INT8_MIN;
1379                   i8 = INT8_MAX;
1380                   typedef int16_t         my_int16_t;
1381                   my_int16_t              i16 = INT16_MIN;
1382                   i16 = INT16_MAX;
1383                   typedef int32_t         my_int32_t;
1384                   my_int32_t              i32 = INT32_MIN;
1385                   i32 = INT32_MAX;
1386                   typedef int64_t         my_int64_t;
1387                   my_int64_t              i64 = INT64_MIN;
1388                   i64 = INT64_MAX;
1389                   typedef int_fast8_t     my_int_fast8_t;
1390                   my_int_fast8_t          if8 = INT_FAST8_MIN;
1391                   if8 = INT_FAST8_MAX;
1392                   typedef int_fast16_t    my_int_fast16_t;
1393                   my_int_fast16_t         if16 = INT_FAST16_MIN;
1394                   if16 = INT_FAST16_MAX;
1395                   typedef int_fast32_t    my_int_fast32_t;
1396                   my_int_fast32_t         if32 = INT_FAST32_MIN;
1397                   if32 = INT_FAST32_MAX;
1398                   typedef int_fast64_t    my_int_fast64_t;
1399                   my_int_fast64_t         if64 = INT_FAST64_MIN;
1400                   if64 = INT_FAST64_MAX;
1401                   typedef int_least8_t    my_int_least8_t;
1402                   my_int_least8_t         il8 = INT_LEAST8_MIN;
1403                   il8 = INT_LEAST8_MAX;
1404                   typedef int_least16_t   my_int_least16_t;
1405                   my_int_least16_t        il16 = INT_LEAST16_MIN;
1406                   il16 = INT_LEAST16_MAX;
1407                   typedef int_least32_t   my_int_least32_t;
1408                   my_int_least32_t        il32 = INT_LEAST32_MIN;
1409                   il32 = INT_LEAST32_MAX;
1410                   typedef int_least64_t   my_int_least64_t;
1411                   my_int_least64_t        il64 = INT_LEAST64_MIN;
1412                   il64 = INT_LEAST64_MAX;
1413                   typedef intmax_t        my_intmax_t;
1414                   my_intmax_t             im = INTMAX_MAX;
1415                   im = INTMAX_MIN;
1416                   typedef intptr_t        my_intptr_t;
1417                   my_intptr_t             ip = INTPTR_MAX;
1418                   ip = INTPTR_MIN;
1419                   typedef uint8_t         my_uint8_t;
1420                   my_uint8_t              ui8 = UINT8_MAX;
1421                   ui8 = UINT8_MAX;
1422                   typedef uint16_t        my_uint16_t;
1423                   my_uint16_t             ui16 = UINT16_MAX;
1424                   ui16 = UINT16_MAX;
1425                   typedef uint32_t        my_uint32_t;
1426                   my_uint32_t             ui32 = UINT32_MAX;
1427                   ui32 = UINT32_MAX;
1428                   typedef uint64_t        my_uint64_t;
1429                   my_uint64_t             ui64 = UINT64_MAX;
1430                   ui64 = UINT64_MAX;
1431                   typedef uint_fast8_t    my_uint_fast8_t;
1432                   my_uint_fast8_t         uif8 = UINT_FAST8_MAX;
1433                   uif8 = UINT_FAST8_MAX;
1434                   typedef uint_fast16_t   my_uint_fast16_t;
1435                   my_uint_fast16_t        uif16 = UINT_FAST16_MAX;
1436                   uif16 = UINT_FAST16_MAX;
1437                   typedef uint_fast32_t   my_uint_fast32_t;
1438                   my_uint_fast32_t        uif32 = UINT_FAST32_MAX;
1439                   uif32 = UINT_FAST32_MAX;
1440                   typedef uint_fast64_t   my_uint_fast64_t;
1441                   my_uint_fast64_t        uif64 = UINT_FAST64_MAX;
1442                   uif64 = UINT_FAST64_MAX;
1443                   typedef uint_least8_t   my_uint_least8_t;
1444                   my_uint_least8_t        uil8 = UINT_LEAST8_MAX;
1445                   uil8 = UINT_LEAST8_MAX;
1446                   typedef uint_least16_t  my_uint_least16_t;
1447                   my_uint_least16_t       uil16 = UINT_LEAST16_MAX;
1448                   uil16 = UINT_LEAST16_MAX;
1449                   typedef uint_least32_t  my_uint_least32_t;
1450                   my_uint_least32_t       uil32 = UINT_LEAST32_MAX;
1451                   uil32 = UINT_LEAST32_MAX;
1452                   typedef uint_least64_t  my_uint_least64_t;
1453                   my_uint_least64_t       uil64 = UINT_LEAST64_MAX;
1454                   uil64 = UINT_LEAST64_MAX;
1455                   typedef uintmax_t       my_uintmax_t;
1456                   my_uintmax_t            uim = UINTMAX_MAX;
1457                   uim = UINTMAX_MAX;
1458                   typedef uintptr_t       my_uintptr_t;
1459                   my_uintptr_t            uip = UINTPTR_MAX;
1460                   uip = UINTPTR_MAX;
1461                  ],[glibcxx_cv_c99_stdint_tr1=yes],
1462                    [glibcxx_cv_c99_stdint_tr1=no])
1463   ])
1464   AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1465   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1466     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1467               [Define if C99 types in <stdint.h> should be imported in
1468               <tr1/cstdint> in namespace std::tr1.])
1469   fi
1470
1471   # Check for the existence of <math.h> functions.
1472   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1473   AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1474   AC_TRY_COMPILE([#include <math.h>],
1475                  [typedef double_t  my_double_t;
1476                   typedef float_t   my_float_t;
1477                   acosh(0.0);
1478                   acoshf(0.0f);
1479                   acoshl(0.0l);
1480                   asinh(0.0);
1481                   asinhf(0.0f);
1482                   asinhl(0.0l);
1483                   atanh(0.0);
1484                   atanhf(0.0f);
1485                   atanhl(0.0l);
1486                   cbrt(0.0);
1487                   cbrtf(0.0f);
1488                   cbrtl(0.0l);
1489                   copysign(0.0, 0.0);
1490                   copysignf(0.0f, 0.0f);
1491                   copysignl(0.0l, 0.0l);
1492                   erf(0.0);
1493                   erff(0.0f);
1494                   erfl(0.0l);
1495                   erfc(0.0);
1496                   erfcf(0.0f);
1497                   erfcl(0.0l);
1498                   exp2(0.0);
1499                   exp2f(0.0f);
1500                   exp2l(0.0l);
1501                   expm1(0.0);
1502                   expm1f(0.0f);
1503                   expm1l(0.0l);
1504                   fdim(0.0, 0.0);
1505                   fdimf(0.0f, 0.0f);
1506                   fdiml(0.0l, 0.0l);
1507                   fma(0.0, 0.0, 0.0);
1508                   fmaf(0.0f, 0.0f, 0.0f);
1509                   fmal(0.0l, 0.0l, 0.0l);
1510                   fmax(0.0, 0.0);
1511                   fmaxf(0.0f, 0.0f);
1512                   fmaxl(0.0l, 0.0l);
1513                   fmin(0.0, 0.0);
1514                   fminf(0.0f, 0.0f);
1515                   fminl(0.0l, 0.0l);
1516                   hypot(0.0, 0.0);
1517                   hypotf(0.0f, 0.0f);
1518                   hypotl(0.0l, 0.0l);
1519                   ilogb(0.0);
1520                   ilogbf(0.0f);
1521                   ilogbl(0.0l);
1522                   lgamma(0.0);
1523                   lgammaf(0.0f);
1524                   lgammal(0.0l);
1525                   llrint(0.0);
1526                   llrintf(0.0f);
1527                   llrintl(0.0l);
1528                   llround(0.0);
1529                   llroundf(0.0f);
1530                   llroundl(0.0l);
1531                   log1p(0.0);
1532                   log1pf(0.0f);
1533                   log1pl(0.0l);
1534                   log2(0.0);
1535                   log2f(0.0f);
1536                   log2l(0.0l);
1537                   logb(0.0);
1538                   logbf(0.0f);
1539                   logbl(0.0l);
1540                   lrint(0.0);
1541                   lrintf(0.0f);
1542                   lrintl(0.0l);
1543                   lround(0.0);
1544                   lroundf(0.0f);
1545                   lroundl(0.0l);
1546                   nan(0);
1547                   nanf(0);
1548                   nanl(0);
1549                   nearbyint(0.0);
1550                   nearbyintf(0.0f);
1551                   nearbyintl(0.0l);
1552                   nextafter(0.0, 0.0);
1553                   nextafterf(0.0f, 0.0f);
1554                   nextafterl(0.0l, 0.0l);
1555                   nexttoward(0.0, 0.0);
1556                   nexttowardf(0.0f, 0.0f);
1557                   nexttowardl(0.0l, 0.0l);
1558                   remainder(0.0, 0.0);
1559                   remainderf(0.0f, 0.0f);
1560                   remainderl(0.0l, 0.0l);
1561                   remquo(0.0, 0.0, 0);
1562                   remquof(0.0f, 0.0f, 0);
1563                   remquol(0.0l, 0.0l, 0);
1564                   rint(0.0);
1565                   rintf(0.0f);
1566                   rintl(0.0l);
1567                   round(0.0);
1568                   roundf(0.0f);
1569                   roundl(0.0l);
1570                   scalbln(0.0, 0l);
1571                   scalblnf(0.0f, 0l);
1572                   scalblnl(0.0l, 0l);
1573                   scalbn(0.0, 0);
1574                   scalbnf(0.0f, 0);
1575                   scalbnl(0.0l, 0);
1576                   tgamma(0.0);
1577                   tgammaf(0.0f);
1578                   tgammal(0.0l);
1579                   trunc(0.0);
1580                   truncf(0.0f);
1581                   truncl(0.0l);
1582                  ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1583   ])
1584   AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1585   if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1586     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1587               [Define if C99 functions or macros in <math.h> should be imported
1588               in <tr1/cmath> in namespace std::tr1.])
1589   fi
1590
1591   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1592   # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1593   ac_c99_inttypes_tr1=no;
1594   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1595     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1596     AC_TRY_COMPILE([#include <inttypes.h>],
1597                    [intmax_t i, numer, denom, base;
1598                     const char* s;
1599                     char** endptr;
1600                     intmax_t ret = imaxabs(i);
1601                     imaxdiv_t dret = imaxdiv(numer, denom);
1602                     ret = strtoimax(s, endptr, base);
1603                     uintmax_t uret = strtoumax(s, endptr, base);
1604                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1605   fi
1606   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1607   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1608     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1609               [Define if C99 functions in <inttypes.h> should be imported in
1610               <tr1/cinttypes> in namespace std::tr1.])
1611   fi
1612
1613   # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1614   # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1615   ac_c99_inttypes_wchar_t_tr1=no;
1616   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1617     AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1618     AC_TRY_COMPILE([#include <inttypes.h>],
1619                    [intmax_t base;
1620                     const wchar_t* s;
1621                     wchar_t** endptr;
1622                     intmax_t ret = wcstoimax(s, endptr, base);
1623                     uintmax_t uret = wcstoumax(s, endptr, base);
1624                    ],[ac_c99_inttypes_wchar_t_tr1=yes],
1625                      [ac_c99_inttypes_wchar_t_tr1=no])
1626   fi
1627   AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1628   if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1629     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1630               [Define if wchar_t C99 functions in <inttypes.h> should be
1631               imported in <tr1/cinttypes> in namespace std::tr1.])
1632   fi
1633
1634   # Check for the existence of the <stdbool.h> header.
1635   AC_CHECK_HEADERS(stdbool.h)
1636
1637   CXXFLAGS="$ac_save_CXXFLAGS"
1638   AC_LANG_RESTORE
1639 ])
1640
1641 dnl
1642 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1643 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1644 dnl
1645 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1646
1647   AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1648   AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1649     if test -r /dev/random && test -r /dev/urandom; then
1650       glibcxx_cv_random_tr1=yes;
1651     else
1652       glibcxx_cv_random_tr1=no;
1653     fi
1654   ])
1655   AC_MSG_RESULT($glibcxx_cv_random_tr1)
1656
1657   if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1658     AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1659               [Define if /dev/random and /dev/urandom are available for
1660                the random_device of TR1 (Chapter 5.1).])
1661   fi
1662
1663 ])
1664
1665 dnl
1666 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1667 dnl
1668 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1669
1670   AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1671   AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1672                  [#include <stdio.h>],
1673                  [AC_MSG_ERROR([computing EOF failed])])
1674   ])
1675   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1676                      [Define to the value of the EOF integer constant.])
1677
1678   AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1679   AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1680                  [#include <stdio.h>],
1681                  [AC_MSG_ERROR([computing SEEK_CUR failed])])
1682   ])
1683   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1684                      [Define to the value of the SEEK_CUR integer constant.])
1685
1686   AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1687   AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1688                  [#include <stdio.h>],
1689                  [AC_MSG_ERROR([computing SEEK_END failed])])
1690   ])
1691   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1692                      [Define to the value of the SEEK_END integer constant.])
1693 ])
1694
1695 dnl
1696 dnl Check whether macros, etc are present for <system_error>
1697 dnl
1698 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1699
1700 m4_pushdef([n_syserr], [1])dnl
1701 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1702                       ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1703                       EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY],
1704 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1705 AC_MSG_CHECKING([for syserr])
1706 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1707 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1708                                    [int i = syserr;])],
1709                   [glibcxx_cv_system_error[]n_syserr=yes],
1710                   [glibcxx_cv_system_error[]n_syserr=no])
1711 ])
1712 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1713 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1714   AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1715 fi
1716 m4_define([n_syserr], m4_incr(n_syserr))dnl
1717 m4_popdef([SYSERR])dnl
1718 ])
1719 m4_popdef([n_syserr])dnl
1720 ])
1721
1722 dnl
1723 dnl Check for what type of C headers to use.
1724 dnl
1725 dnl --enable-cheaders= [does stuff].
1726 dnl --disable-cheaders [does not do anything, really].
1727 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1728 dnl       Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1729 dnl
1730 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1731   GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1732     [construct "C" headers for g++], [permit c|c_std|c_global])
1733   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1734
1735   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1736
1737   # Allow overrides to configure.host here.
1738   if test $enable_cheaders = c_global; then
1739      c_compatibility=yes
1740   fi
1741
1742   AC_SUBST(C_INCLUDE_DIR)
1743   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1744   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1745   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1746   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1747 ])
1748
1749
1750 dnl
1751 dnl Check for which locale library to use.  The choice is mapped to
1752 dnl a subdirectory of config/locale.
1753 dnl
1754 dnl Default is generic.
1755 dnl
1756 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1757   GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1758     [use MODEL for target locale package],
1759     [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1760
1761   # Deal with gettext issues.  Default to not using it (=no) until we detect
1762   # support for it later.  Let the user turn it off via --e/d, but let that
1763   # default to on for easier handling.
1764   USE_NLS=no
1765   AC_ARG_ENABLE(nls,
1766     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1767     [],
1768     [enable_nls=yes])
1769
1770   # Either a known package, or "auto"
1771   if test $enable_clocale = no || test $enable_clocale = yes; then
1772      enable_clocale=auto
1773   fi
1774   enable_clocale_flag=$enable_clocale
1775
1776   # Probe for locale model to use if none specified.
1777   # Default to "generic".
1778   if test $enable_clocale_flag = auto; then
1779     case ${target_os} in
1780       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1781         enable_clocale_flag=gnu
1782         ;;
1783       darwin* | freebsd*)
1784         enable_clocale_flag=darwin
1785         ;;
1786       *)
1787         if test x"$with_newlib" = x"yes"; then
1788           enable_clocale_flag=newlib
1789         else
1790           enable_clocale_flag=generic
1791         fi
1792         ;;
1793     esac
1794   fi
1795
1796   # Sanity check model, and test for special functionality.
1797   if test $enable_clocale_flag = gnu; then
1798     AC_EGREP_CPP([_GLIBCXX_ok], [
1799     #include <features.h>
1800     #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
1801       _GLIBCXX_ok
1802     #endif
1803     ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1804
1805     # Set it to scream when it hurts.
1806     ac_save_CFLAGS="$CFLAGS"
1807     CFLAGS="-Wimplicit-function-declaration -Werror"
1808
1809     # Use strxfrm_l if available.
1810     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1811                     #include <string.h>
1812                     #include <locale.h>],
1813                     [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1814                     AC_DEFINE(HAVE_STRXFRM_L, 1,
1815                     [Define if strxfrm_l is available in <string.h>.]),)
1816
1817     # Use strerror_l if available.
1818     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1819                     #include <string.h>
1820                     #include <locale.h>],
1821                     [__locale_t loc; strerror_l(5, loc);],
1822                     AC_DEFINE(HAVE_STRERROR_L, 1,
1823                     [Define if strerror_l is available in <string.h>.]),)
1824
1825     CFLAGS="$ac_save_CFLAGS"
1826   fi
1827
1828   # Perhaps use strerror_r if available, and strerror_l isn't.
1829   ac_save_CFLAGS="$CFLAGS"
1830   CFLAGS="-Wimplicit-function-declaration -Werror"
1831   AC_TRY_COMPILE([#define _GNU_SOURCE 1
1832                   #include <string.h>
1833                   #include <locale.h>],
1834                   [char s[128]; strerror_r(5, s, 128);],
1835                   AC_DEFINE(HAVE_STRERROR_R, 1,
1836                   [Define if strerror_r is available in <string.h>.]),)
1837   CFLAGS="$ac_save_CFLAGS"
1838
1839   # Set configure bits for specified locale package
1840   AC_MSG_CHECKING([for C locale to use])
1841   case ${enable_clocale_flag} in
1842     generic)
1843       AC_MSG_RESULT(generic)
1844
1845       CLOCALE_H=config/locale/generic/c_locale.h
1846       CLOCALE_CC=config/locale/generic/c_locale.cc
1847       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1848       CCOLLATE_CC=config/locale/generic/collate_members.cc
1849       CCTYPE_CC=config/locale/generic/ctype_members.cc
1850       CMESSAGES_H=config/locale/generic/messages_members.h
1851       CMESSAGES_CC=config/locale/generic/messages_members.cc
1852       CMONEY_CC=config/locale/generic/monetary_members.cc
1853       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1854       CTIME_H=config/locale/generic/time_members.h
1855       CTIME_CC=config/locale/generic/time_members.cc
1856       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1857       ;;
1858     darwin)
1859       AC_MSG_RESULT(darwin or freebsd)
1860
1861       CLOCALE_H=config/locale/generic/c_locale.h
1862       CLOCALE_CC=config/locale/generic/c_locale.cc
1863       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1864       CCOLLATE_CC=config/locale/generic/collate_members.cc
1865       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1866       CMESSAGES_H=config/locale/generic/messages_members.h
1867       CMESSAGES_CC=config/locale/generic/messages_members.cc
1868       CMONEY_CC=config/locale/generic/monetary_members.cc
1869       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1870       CTIME_H=config/locale/generic/time_members.h
1871       CTIME_CC=config/locale/generic/time_members.cc
1872       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1873       ;;
1874
1875     gnu)
1876       AC_MSG_RESULT(gnu)
1877
1878       # Declare intention to use gettext, and add support for specific
1879       # languages.
1880       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1881       ALL_LINGUAS="de fr"
1882
1883       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1884       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1885       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1886         USE_NLS=yes
1887       fi
1888       # Export the build objects.
1889       for ling in $ALL_LINGUAS; do \
1890         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1891         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1892       done
1893       AC_SUBST(glibcxx_MOFILES)
1894       AC_SUBST(glibcxx_POFILES)
1895
1896       CLOCALE_H=config/locale/gnu/c_locale.h
1897       CLOCALE_CC=config/locale/gnu/c_locale.cc
1898       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1899       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1900       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1901       CMESSAGES_H=config/locale/gnu/messages_members.h
1902       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1903       CMONEY_CC=config/locale/gnu/monetary_members.cc
1904       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1905       CTIME_H=config/locale/gnu/time_members.h
1906       CTIME_CC=config/locale/gnu/time_members.cc
1907       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1908       ;;
1909     ieee_1003.1-2001)
1910       AC_MSG_RESULT(IEEE 1003.1)
1911
1912       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1913       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1914       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1915       CCOLLATE_CC=config/locale/generic/collate_members.cc
1916       CCTYPE_CC=config/locale/generic/ctype_members.cc
1917       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1918       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1919       CMONEY_CC=config/locale/generic/monetary_members.cc
1920       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1921       CTIME_H=config/locale/generic/time_members.h
1922       CTIME_CC=config/locale/generic/time_members.cc
1923       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1924       ;;
1925     newlib)
1926       AC_MSG_RESULT(newlib)
1927
1928       CLOCALE_H=config/locale/generic/c_locale.h
1929       CLOCALE_CC=config/locale/generic/c_locale.cc
1930       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1931       CCOLLATE_CC=config/locale/generic/collate_members.cc
1932       CCTYPE_CC=config/locale/newlib/ctype_members.cc
1933       CMESSAGES_H=config/locale/generic/messages_members.h
1934       CMESSAGES_CC=config/locale/generic/messages_members.cc
1935       CMONEY_CC=config/locale/generic/monetary_members.cc
1936       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1937       CTIME_H=config/locale/generic/time_members.h
1938       CTIME_CC=config/locale/generic/time_members.cc
1939       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1940       ;;
1941   esac
1942
1943   # This is where the testsuite looks for locale catalogs, using the
1944   # -DLOCALEDIR define during testsuite compilation.
1945   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1946   AC_SUBST(glibcxx_localedir)
1947
1948   # A standalone libintl (e.g., GNU libintl) may be in use.
1949   if test $USE_NLS = yes; then
1950     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1951     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1952   fi
1953   if test $USE_NLS = yes; then
1954     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1955               [Define if NLS translations are to be used.])
1956   fi
1957
1958   AC_SUBST(USE_NLS)
1959   AC_SUBST(CLOCALE_H)
1960   AC_SUBST(CMESSAGES_H)
1961   AC_SUBST(CCODECVT_CC)
1962   AC_SUBST(CCOLLATE_CC)
1963   AC_SUBST(CCTYPE_CC)
1964   AC_SUBST(CMESSAGES_CC)
1965   AC_SUBST(CMONEY_CC)
1966   AC_SUBST(CNUMERIC_CC)
1967   AC_SUBST(CTIME_H)
1968   AC_SUBST(CTIME_CC)
1969   AC_SUBST(CLOCALE_CC)
1970   AC_SUBST(CLOCALE_INTERNAL_H)
1971 ])
1972
1973
1974 dnl
1975 dnl Check for which std::allocator base class to use.  The choice is
1976 dnl mapped from a subdirectory of include/ext.
1977 dnl
1978 dnl Default is new.
1979 dnl
1980 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1981   AC_MSG_CHECKING([for std::allocator base class])
1982   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
1983     [use KIND for target std::allocator base],
1984     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1985
1986   # If they didn't use this option switch, or if they specified --enable
1987   # with no specific model, we'll have to look for one.  If they
1988   # specified --disable (???), do likewise.
1989   if test $enable_libstdcxx_allocator = no ||
1990      test $enable_libstdcxx_allocator = yes;
1991   then
1992      enable_libstdcxx_allocator=auto
1993   fi
1994
1995   # Either a known package, or "auto". Auto implies the default choice
1996   # for a particular platform.
1997   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1998
1999   # Probe for host-specific support if no specific model is specified.
2000   # Default to "new".
2001   if test $enable_libstdcxx_allocator_flag = auto; then
2002     case ${target_os} in
2003       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2004         enable_libstdcxx_allocator_flag=new
2005         ;;
2006       *)
2007         enable_libstdcxx_allocator_flag=new
2008         ;;
2009     esac
2010   fi
2011   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2012
2013
2014   # Set configure bits for specified locale package
2015   case ${enable_libstdcxx_allocator_flag} in
2016     bitmap)
2017       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2018       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2019       ;;
2020     malloc)
2021       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2022       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2023       ;;
2024     mt)
2025       ALLOCATOR_H=config/allocator/mt_allocator_base.h
2026       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2027       ;;
2028     new)
2029       ALLOCATOR_H=config/allocator/new_allocator_base.h
2030       ALLOCATOR_NAME=__gnu_cxx::new_allocator
2031       ;;
2032     pool)
2033       ALLOCATOR_H=config/allocator/pool_allocator_base.h
2034       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2035       ;;
2036   esac
2037
2038   AC_SUBST(ALLOCATOR_H)
2039   AC_SUBST(ALLOCATOR_NAME)
2040 ])
2041
2042
2043 dnl
2044 dnl Check for whether the Boost-derived checks should be turned on.
2045 dnl
2046 dnl --enable-concept-checks turns them on.
2047 dnl --disable-concept-checks leaves them off.
2048 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2049 dnl       Where DEFAULT is either `yes' or `no'.
2050 dnl
2051 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2052   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2053   if test $enable_concept_checks = yes; then
2054     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2055               [Define to use concept checking code from the boost libraries.])
2056   fi
2057 ])
2058
2059 dnl
2060 dnl Use extern templates.
2061 dnl
2062 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2063 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2064
2065 dnl  +  Usage:  GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2066 dnl       Where DEFAULT is `yes' or `no'.
2067 dnl
2068 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2069
2070   GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2071
2072   AC_MSG_CHECKING([for extern template support])
2073   AC_MSG_RESULT([$enable_extern_template])
2074
2075   GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2076 ])
2077
2078 dnl
2079 dnl Check for parallel mode pre-requisites, including OpenMP support.
2080 dnl
2081 dnl  +  Usage:  GLIBCXX_ENABLE_PARALLEL
2082 dnl
2083 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2084
2085   enable_parallel=no;
2086
2087   # See if configured libgomp/omp.h exists. (libgomp may be in
2088   # noconfigdirs but not explicitly disabled.)
2089   if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2090     enable_parallel=yes;
2091   else
2092     AC_MSG_NOTICE([target-libgomp not built])
2093   fi
2094
2095   AC_MSG_CHECKING([for parallel mode support])
2096   AC_MSG_RESULT([$enable_parallel])
2097   GLIBCXX_CONDITIONAL(ENABLE_PARALLEL, test $enable_parallel = yes)
2098 ])
2099
2100
2101 dnl
2102 dnl Check for which I/O library to use:  stdio, or something specific.
2103 dnl
2104 dnl Default is stdio.
2105 dnl
2106 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2107   AC_MSG_CHECKING([for underlying I/O to use])
2108   GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2109     [use target-specific I/O package], [permit stdio])
2110
2111   # Now that libio has been removed, you can have any color you want as long
2112   # as it's black.  This is one big no-op until other packages are added, but
2113   # showing the framework never hurts.
2114   case ${enable_cstdio} in
2115     stdio)
2116       CSTDIO_H=config/io/c_io_stdio.h
2117       BASIC_FILE_H=config/io/basic_file_stdio.h
2118       BASIC_FILE_CC=config/io/basic_file_stdio.cc
2119       AC_MSG_RESULT(stdio)
2120       ;;
2121   esac
2122
2123   AC_SUBST(CSTDIO_H)
2124   AC_SUBST(BASIC_FILE_H)
2125   AC_SUBST(BASIC_FILE_CC)
2126 ])
2127
2128
2129 dnl
2130 dnl Check for "unusual" flags to pass to the compiler while building.
2131 dnl
2132 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2133 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2134 dnl --disable-cxx-flags passes nothing.
2135 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2136 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2137 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2138 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2139 dnl       If "default flags" is an empty string, the effect is the same
2140 dnl       as --disable or --enable=no.
2141 dnl
2142 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2143   AC_MSG_CHECKING([for extra compiler flags for building])
2144   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2145     [pass compiler FLAGS when building library],
2146     [case "x$enable_cxx_flags" in
2147       xno | x)   enable_cxx_flags= ;;
2148       x-*)       ;;
2149       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2150      esac])
2151
2152   # Run through flags (either default or command-line) and set anything
2153   # extra (e.g., #defines) that must accompany particular g++ options.
2154   if test -n "$enable_cxx_flags"; then
2155     for f in $enable_cxx_flags; do
2156       case "$f" in
2157         -fhonor-std)  ;;
2158         -*)  ;;
2159         *)   # and we're trying to pass /what/ exactly?
2160              AC_MSG_ERROR([compiler flags start with a -]) ;;
2161       esac
2162     done
2163   fi
2164
2165   EXTRA_CXX_FLAGS="$enable_cxx_flags"
2166   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2167   AC_SUBST(EXTRA_CXX_FLAGS)
2168 ])
2169
2170
2171 dnl
2172 dnl Check to see if debugging libraries are to be built.
2173 dnl
2174 dnl --enable-libstdcxx-debug
2175 dnl builds a separate set of debugging libraries in addition to the
2176 dnl normal (shared, static) libstdc++ binaries.
2177 dnl
2178 dnl --disable-libstdcxx-debug
2179 dnl builds only one (non-debug) version of libstdc++.
2180 dnl
2181 dnl --enable-libstdcxx-debug-flags=FLAGS
2182 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2183 dnl
2184 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2185 dnl       Where DEFAULT is either `yes' or `no'.
2186 dnl
2187 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2188   AC_MSG_CHECKING([for additional debug build])
2189   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2190   AC_MSG_RESULT($enable_libstdcxx_debug)
2191   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2192 ])
2193
2194
2195 dnl
2196 dnl Check for explicit debug flags.
2197 dnl
2198 dnl --enable-libstdcxx-debug-flags='-O1'
2199 dnl is a general method for passing flags to be used when
2200 dnl building debug libraries with --enable-debug.
2201 dnl
2202 dnl --disable-libstdcxx-debug-flags does nothing.
2203 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2204 dnl       If "default flags" is an empty string, the effect is the same
2205 dnl       as --disable or --enable=no.
2206 dnl
2207 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2208   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2209     [pass compiler FLAGS when building debug library],
2210     [case "x$enable_libstdcxx_debug_flags" in
2211       xno | x)    enable_libstdcxx_debug_flags= ;;
2212       x-*)        ;;
2213       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2214      esac])
2215
2216   # Option parsed, now set things appropriately
2217   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2218   AC_SUBST(DEBUG_FLAGS)
2219
2220   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2221 ])
2222
2223
2224 dnl
2225 dnl Check if the user only wants a freestanding library implementation.
2226 dnl
2227 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2228 dnl installing only the headers required by [17.4.1.3] and the language
2229 dnl support library.  More than that will be built (to keep the Makefiles
2230 dnl conveniently clean), but not installed.
2231 dnl
2232 dnl Sets:
2233 dnl  is_hosted  (yes/no)
2234 dnl
2235 dnl Defines:
2236 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
2237 dnl
2238 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2239   AC_ARG_ENABLE([hosted-libstdcxx],
2240     AC_HELP_STRING([--disable-hosted-libstdcxx],
2241                    [only build freestanding C++ runtime support]),,
2242     [case "$host" in
2243         arm*-*-symbianelf*)
2244             enable_hosted_libstdcxx=no
2245             ;;
2246         *)
2247             enable_hosted_libstdcxx=yes
2248             ;;
2249      esac])
2250   if test "$enable_hosted_libstdcxx" = no; then
2251     AC_MSG_NOTICE([Only freestanding libraries will be built])
2252     is_hosted=no
2253     hosted_define=0
2254     enable_abi_check=no
2255     enable_libstdcxx_pch=no
2256   else
2257     is_hosted=yes
2258     hosted_define=1
2259   fi
2260   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2261   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2262     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2263 ])
2264
2265
2266 dnl
2267 dnl Check for template specializations for the 'long long' type.
2268 dnl The result determines only whether 'long long' I/O is enabled; things
2269 dnl like numeric_limits<> specializations are always available.
2270 dnl
2271 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2272 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2273 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2274 dnl       Where DEFAULT is either `yes' or `no'.
2275 dnl
2276 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2277   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2278   if test $enable_long_long = yes; then
2279     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2280               [Define if code specialized for long long should be used.])
2281   fi
2282   AC_MSG_CHECKING([for enabled long long specializations])
2283   AC_MSG_RESULT([$enable_long_long])
2284 ])
2285
2286
2287 dnl
2288 dnl Check for decimal floating point.
2289 dnl See:
2290 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2291 dnl
2292 dnl This checks to see if the host supports decimal floating point types.
2293 dnl
2294 dnl Defines:
2295 dnl  _GLIBCXX_USE_DECIMAL_FLOAT
2296 dnl
2297 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2298
2299   # Fake what AC_TRY_COMPILE does, without linking as this is
2300   # unnecessary for this test.
2301
2302     cat > conftest.$ac_ext << EOF
2303 [#]line __oline__ "configure"
2304 int main()
2305 {
2306   _Decimal32 d1;
2307   _Decimal64 d2;
2308   _Decimal128 d3;
2309   return 0;
2310 }
2311 EOF
2312
2313     AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2314     if AC_TRY_EVAL(ac_compile); then
2315       AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2316       [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2317       enable_dfp=yes
2318     else
2319       enable_dfp=no
2320     fi
2321     AC_MSG_RESULT($enable_dfp)
2322     rm -f conftest*
2323 ])
2324
2325 dnl
2326 dnl Check for template specializations for the 'wchar_t' type.
2327 dnl
2328 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2329 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2330 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2331 dnl       Where DEFAULT is either `yes' or `no'.
2332 dnl
2333 dnl Necessary support must also be present.
2334 dnl
2335 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2336   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2337
2338   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2339   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2340   AC_MSG_CHECKING([for mbstate_t])
2341   AC_TRY_COMPILE([#include <wchar.h>],
2342   [mbstate_t teststate;],
2343   have_mbstate_t=yes, have_mbstate_t=no)
2344   AC_MSG_RESULT($have_mbstate_t)
2345   if test x"$have_mbstate_t" = xyes; then
2346     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2347   fi
2348
2349   # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2350   # ac_has_wchar_h.
2351   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2352
2353   if test x"$enable_wchar_t" = x"yes"; then
2354
2355     AC_LANG_SAVE
2356     AC_LANG_CPLUSPLUS
2357
2358     if test x"$ac_has_wchar_h" = xyes &&
2359        test x"$ac_has_wctype_h" = xyes; then
2360       AC_TRY_COMPILE([#include <wchar.h>
2361                       #include <stddef.h>
2362                       wint_t i;
2363                       long l = WEOF;
2364                       long j = WCHAR_MIN;
2365                       long k = WCHAR_MAX;
2366                       namespace test
2367                       {
2368                         using ::btowc;
2369                         using ::fgetwc;
2370                         using ::fgetws;
2371                         using ::fputwc;
2372                         using ::fputws;
2373                         using ::fwide;
2374                         using ::fwprintf;
2375                         using ::fwscanf;
2376                         using ::getwc;
2377                         using ::getwchar;
2378                         using ::mbrlen;
2379                         using ::mbrtowc;
2380                         using ::mbsinit;
2381                         using ::mbsrtowcs;
2382                         using ::putwc;
2383                         using ::putwchar;
2384                         using ::swprintf;
2385                         using ::swscanf;
2386                         using ::ungetwc;
2387                         using ::vfwprintf;
2388                         using ::vswprintf;
2389                         using ::vwprintf;
2390                         using ::wcrtomb;
2391                         using ::wcscat;
2392                         using ::wcschr;
2393                         using ::wcscmp;
2394                         using ::wcscoll;
2395                         using ::wcscpy;
2396                         using ::wcscspn;
2397                         using ::wcsftime;
2398                         using ::wcslen;
2399                         using ::wcsncat;
2400                         using ::wcsncmp;
2401                         using ::wcsncpy;
2402                         using ::wcspbrk;
2403                         using ::wcsrchr;
2404                         using ::wcsrtombs;
2405                         using ::wcsspn;
2406                         using ::wcsstr;
2407                         using ::wcstod;
2408                         using ::wcstok;
2409                         using ::wcstol;
2410                         using ::wcstoul;
2411                         using ::wcsxfrm;
2412                         using ::wctob;
2413                         using ::wmemchr;
2414                         using ::wmemcmp;
2415                         using ::wmemcpy;
2416                         using ::wmemmove;
2417                         using ::wmemset;
2418                         using ::wprintf;
2419                         using ::wscanf;
2420                       }
2421                      ],[],[], [enable_wchar_t=no])
2422     else
2423       enable_wchar_t=no
2424     fi
2425
2426     AC_LANG_RESTORE
2427   fi
2428
2429   if test x"$enable_wchar_t" = x"yes"; then
2430     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2431               [Define if code specialized for wchar_t should be used.])
2432   fi
2433
2434   AC_MSG_CHECKING([for enabled wchar_t specializations])
2435   AC_MSG_RESULT([$enable_wchar_t])
2436 ])
2437
2438
2439 dnl
2440 dnl Check to see if building and using a C++ precompiled header can be done.
2441 dnl
2442 dnl --enable-libstdcxx-pch=yes
2443 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2444 dnl may work, after some light-hearted attempts to puzzle out compiler
2445 dnl support, flip bits on in include/Makefile.am
2446 dnl
2447 dnl --disable-libstdcxx-pch
2448 dnl turns off attempts to use or build stdc++.h.gch.
2449 dnl
2450 dnl Substs:
2451 dnl  glibcxx_PCHFLAGS
2452 dnl
2453 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2454   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2455   if test $enable_libstdcxx_pch = yes; then
2456     AC_CACHE_CHECK([for compiler with PCH support],
2457       [glibcxx_cv_prog_CXX_pch],
2458       [ac_save_CXXFLAGS="$CXXFLAGS"
2459        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2460        AC_LANG_SAVE
2461        AC_LANG_CPLUSPLUS
2462        echo '#include <math.h>' > conftest.h
2463        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2464                           -o conftest.h.gch 1>&5 2>&1 &&
2465                 echo '#error "pch failed"' > conftest.h &&
2466           echo '#include "conftest.h"' > conftest.cc &&
2467                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2468        then
2469          glibcxx_cv_prog_CXX_pch=yes
2470        else
2471          glibcxx_cv_prog_CXX_pch=no
2472        fi
2473        rm -f conftest*
2474        CXXFLAGS=$ac_save_CXXFLAGS
2475        AC_LANG_RESTORE
2476       ])
2477     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2478   fi
2479
2480   AC_MSG_CHECKING([for enabled PCH])
2481   AC_MSG_RESULT([$enable_libstdcxx_pch])
2482
2483   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2484   if test $enable_libstdcxx_pch = yes; then
2485     glibcxx_PCHFLAGS="-include bits/stdc++.h"
2486   else
2487     glibcxx_PCHFLAGS=""
2488   fi
2489   AC_SUBST(glibcxx_PCHFLAGS)
2490 ])
2491
2492
2493 dnl
2494 dnl Check for atomic builtins.
2495 dnl See:
2496 dnl http://gcc.gnu.org/onlinedocs/gcc/Atomic-Builtins.html#Atomic-Builtins
2497 dnl
2498 dnl This checks to see if the host supports the compiler-generated
2499 dnl builtins for atomic operations for various integral sizes. Note, this
2500 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2501 dnl that are used should be checked.
2502 dnl
2503 dnl Note:
2504 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2505 dnl
2506 dnl Defines:
2507 dnl  _GLIBCXX_ATOMIC_BUILTINS_1
2508 dnl  _GLIBCXX_ATOMIC_BUILTINS_2
2509 dnl  _GLIBCXX_ATOMIC_BUILTINS_4
2510 dnl  _GLIBCXX_ATOMIC_BUILTINS_8
2511 dnl
2512 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2513   AC_LANG_SAVE
2514   AC_LANG_CPLUSPLUS
2515   old_CXXFLAGS="$CXXFLAGS"
2516
2517   # Do link tests if possible, instead asm tests, limited to some platforms
2518   # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2519   # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2520   atomic_builtins_link_tests=no
2521   if test x$gcc_no_link != xyes; then
2522     # Can do link tests. Limit to some tested platforms
2523     case "$host" in
2524       *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2525         atomic_builtins_link_tests=yes
2526         ;;
2527     esac
2528   fi
2529
2530   if test x$atomic_builtins_link_tests = xyes; then
2531
2532   # Do link tests.
2533
2534   CXXFLAGS="$CXXFLAGS -fno-exceptions"
2535
2536   AC_MSG_CHECKING([for atomic builtins for bool])
2537   AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2538     AC_TRY_LINK(
2539       [ ],
2540       [typedef bool atomic_type;
2541        atomic_type c1;
2542        atomic_type c2;
2543        const atomic_type c3(0);
2544        __sync_fetch_and_add(&c1, c2);
2545        __sync_val_compare_and_swap(&c1, c3, c2);
2546        __sync_lock_test_and_set(&c1, c3);
2547        __sync_lock_release(&c1);
2548        __sync_synchronize();],
2549       [glibcxx_cv_atomic_bool=yes],
2550       [glibcxx_cv_atomic_bool=no])
2551   ])
2552   if test $glibcxx_cv_atomic_bool = yes; then
2553     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_1, 1,
2554       [Define if builtin atomic operations for bool are supported on this host.])
2555   fi
2556   AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2557
2558   AC_MSG_CHECKING([for atomic builtins for short])
2559   AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2560     AC_TRY_LINK(
2561       [ ],
2562       [typedef short atomic_type;
2563        atomic_type c1;
2564        atomic_type c2;
2565        const atomic_type c3(0);
2566        __sync_fetch_and_add(&c1, c2);
2567        __sync_val_compare_and_swap(&c1, c3, c2);
2568        __sync_lock_test_and_set(&c1, c3);
2569        __sync_lock_release(&c1);
2570        __sync_synchronize();],
2571       [glibcxx_cv_atomic_short=yes],
2572       [glibcxx_cv_atomic_short=no])
2573   ])
2574   if test $glibcxx_cv_atomic_short = yes; then
2575     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_2, 1,
2576       [Define if builtin atomic operations for short are supported on this host.])
2577   fi
2578   AC_MSG_RESULT($glibcxx_cv_atomic_short)
2579
2580   AC_MSG_CHECKING([for atomic builtins for int])
2581   AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2582     AC_TRY_LINK(
2583       [ ],
2584       [typedef int atomic_type;
2585        atomic_type c1;
2586        atomic_type c2;
2587        const atomic_type c3(0);
2588        __sync_fetch_and_add(&c1, c2);
2589        __sync_val_compare_and_swap(&c1, c3, c2);
2590        __sync_lock_test_and_set(&c1, c3);
2591        __sync_lock_release(&c1);
2592        __sync_synchronize();],
2593       [glibcxx_cv_atomic_int=yes],
2594       [glibcxx_cv_atomic_int=no])
2595   ])
2596   if test $glibcxx_cv_atomic_int = yes; then
2597     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_4, 1,
2598       [Define if builtin atomic operations for int are supported on this host.])
2599   fi
2600   AC_MSG_RESULT($glibcxx_cv_atomic_int)
2601
2602   AC_MSG_CHECKING([for atomic builtins for long long])
2603   AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2604     AC_TRY_LINK(
2605       [ ],
2606       [typedef long long atomic_type;
2607        atomic_type c1;
2608        atomic_type c2;
2609        const atomic_type c3(0);
2610        __sync_fetch_and_add(&c1, c2);
2611        __sync_val_compare_and_swap(&c1, c3, c2);
2612        __sync_lock_test_and_set(&c1, c3);
2613        __sync_lock_release(&c1);
2614        __sync_synchronize();],
2615       [glibcxx_cv_atomic_long_long=yes],
2616       [glibcxx_cv_atomic_long_long=no])
2617   ])
2618   if test $glibcxx_cv_atomic_long_long = yes; then
2619     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_8, 1,
2620       [Define if builtin atomic operations for long long are supported on this host.])
2621   fi
2622   AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2623
2624   else
2625
2626   # Do asm tests.
2627
2628   # Compile unoptimized.
2629   CXXFLAGS='-O0 -S'
2630
2631   # Fake what AC_TRY_COMPILE does.
2632
2633     cat > conftest.$ac_ext << EOF
2634 [#]line __oline__ "configure"
2635 int main()
2636 {
2637   typedef bool atomic_type;
2638   atomic_type c1;
2639   atomic_type c2;
2640   const atomic_type c3(0);
2641   __sync_fetch_and_add(&c1, c2);
2642   __sync_val_compare_and_swap(&c1, c3, c2);
2643   __sync_lock_test_and_set(&c1, c3);
2644   __sync_lock_release(&c1);
2645   __sync_synchronize();
2646   return 0;
2647 }
2648 EOF
2649
2650     AC_MSG_CHECKING([for atomic builtins for bool])
2651     if AC_TRY_EVAL(ac_compile); then
2652       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2653         glibcxx_cv_atomic_bool=no
2654       else
2655       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_1, 1,
2656       [Define if builtin atomic operations for bool are supported on this host.])
2657         glibcxx_cv_atomic_bool=yes
2658       fi
2659     fi
2660     AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2661     rm -f conftest*
2662
2663     cat > conftest.$ac_ext << EOF
2664 [#]line __oline__ "configure"
2665 int main()
2666 {
2667   typedef short atomic_type;
2668   atomic_type c1;
2669   atomic_type c2;
2670   const atomic_type c3(0);
2671   __sync_fetch_and_add(&c1, c2);
2672   __sync_val_compare_and_swap(&c1, c3, c2);
2673   __sync_lock_test_and_set(&c1, c3);
2674   __sync_lock_release(&c1);
2675   __sync_synchronize();
2676   return 0;
2677 }
2678 EOF
2679
2680     AC_MSG_CHECKING([for atomic builtins for short])
2681     if AC_TRY_EVAL(ac_compile); then
2682       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2683         glibcxx_cv_atomic_short=no
2684       else
2685       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_2, 1,
2686       [Define if builtin atomic operations for short are supported on this host.])
2687         glibcxx_cv_atomic_short=yes
2688       fi
2689     fi
2690     AC_MSG_RESULT($glibcxx_cv_atomic_short)
2691     rm -f conftest*
2692
2693     cat > conftest.$ac_ext << EOF
2694 [#]line __oline__ "configure"
2695 int main()
2696 {
2697   // NB: _Atomic_word not necessarily int.
2698   typedef int atomic_type;
2699   atomic_type c1;
2700   atomic_type c2;
2701   const atomic_type c3(0);
2702   __sync_fetch_and_add(&c1, c2);
2703   __sync_val_compare_and_swap(&c1, c3, c2);
2704   __sync_lock_test_and_set(&c1, c3);
2705   __sync_lock_release(&c1);
2706   __sync_synchronize();
2707   return 0;
2708 }
2709 EOF
2710
2711     AC_MSG_CHECKING([for atomic builtins for int])
2712     if AC_TRY_EVAL(ac_compile); then
2713       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2714         glibcxx_cv_atomic_int=no
2715       else
2716       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_4, 1,
2717         [Define if builtin atomic operations for int are supported on this host.])
2718         glibcxx_cv_atomic_int=yes
2719       fi
2720     fi
2721     AC_MSG_RESULT($glibcxx_cv_atomic_int)
2722     rm -f conftest*
2723
2724     cat > conftest.$ac_ext << EOF
2725 [#]line __oline__ "configure"
2726 int main()
2727 {
2728   typedef long long atomic_type;
2729   atomic_type c1;
2730   atomic_type c2;
2731   const atomic_type c3(0);
2732   __sync_fetch_and_add(&c1, c2);
2733   __sync_val_compare_and_swap(&c1, c3, c2);
2734   __sync_lock_test_and_set(&c1, c3);
2735   __sync_lock_release(&c1);
2736   __sync_synchronize();
2737   return 0;
2738 }
2739 EOF
2740
2741     AC_MSG_CHECKING([for atomic builtins for long long])
2742     if AC_TRY_EVAL(ac_compile); then
2743       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2744         glibcxx_cv_atomic_long_long=no
2745       else
2746       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_8, 1,
2747       [Define if builtin atomic operations for long long are supported on this host.])
2748         glibcxx_cv_atomic_long_long=yes
2749       fi
2750     fi
2751     AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2752     rm -f conftest*
2753
2754   fi
2755
2756   CXXFLAGS="$old_CXXFLAGS"
2757   AC_LANG_RESTORE
2758
2759   # Set atomicity_dir to builtins if either of above tests pass.
2760   if test $glibcxx_cv_atomic_int = yes || test $glibcxx_cv_atomic_bool = yes ; then
2761     atomicity_dir=cpu/generic/atomicity_builtins
2762   fi
2763
2764   # If still generic, set to mutex.
2765   if test $atomicity_dir = "cpu/generic" ; then
2766     atomicity_dir=cpu/generic/atomicity_mutex
2767     AC_MSG_WARN([No native atomic operations are provided for this platform.])
2768       if test "x$target_thread_file" = xsingle; then
2769         AC_MSG_WARN([They cannot be faked when thread support is disabled.])
2770         AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
2771       else
2772         AC_MSG_WARN([They will be faked using a mutex.])
2773         AC_MSG_WARN([Performance of certain classes will degrade as a result.])
2774       fi
2775   fi
2776
2777 ])
2778
2779
2780 dnl
2781 dnl Check for exception handling support.  If an explicit enable/disable
2782 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
2783 dnl target may or may not support call frame exceptions.
2784 dnl
2785 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2786 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2787 dnl Neither one forces an attempt at detection.
2788 dnl
2789 dnl Defines:
2790 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2791 dnl
2792 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2793   AC_MSG_CHECKING([for exception model to use])
2794   AC_LANG_SAVE
2795   AC_LANG_CPLUSPLUS
2796   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2797     [force use of builtin_setjmp for exceptions],
2798     [permit yes|no|auto])
2799
2800   if test $enable_sjlj_exceptions = auto; then
2801     # Botheration.  Now we've got to detect the exception model.  Link tests
2802     # against libgcc.a are problematic since we've not been given proper -L
2803     # bits for single-tree newlib and libgloss.
2804     #
2805     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2806     cat > conftest.$ac_ext << EOF
2807 [#]line __oline__ "configure"
2808 struct S { ~S(); };
2809 void bar();
2810 void foo()
2811 {
2812   S s;
2813   bar();
2814 }
2815 EOF
2816     old_CXXFLAGS="$CXXFLAGS"
2817     CXXFLAGS=-S
2818     if AC_TRY_EVAL(ac_compile); then
2819       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2820         enable_sjlj_exceptions=yes
2821       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2822         enable_sjlj_exceptions=no
2823       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2824         enable_sjlj_exceptions=no
2825       fi
2826     fi
2827     CXXFLAGS="$old_CXXFLAGS"
2828     rm -f conftest*
2829   fi
2830
2831   # This is a tad weird, for hysterical raisins.  We have to map
2832   # enable/disable to two different models.
2833   case $enable_sjlj_exceptions in
2834     yes)
2835       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
2836         [Define if the compiler is configured for setjmp/longjmp exceptions.])
2837       ac_exception_model_name=sjlj
2838       ;;
2839     no)
2840       ac_exception_model_name="call frame"
2841       ;;
2842     *)
2843       AC_MSG_ERROR([unable to detect exception model])
2844       ;;
2845   esac
2846  AC_LANG_RESTORE
2847  AC_MSG_RESULT($ac_exception_model_name)
2848 ])
2849
2850
2851 dnl
2852 dnl Allow visibility attributes to be used on namespaces, objects, etc.
2853 dnl
2854 dnl --enable-visibility enables attempt to use visibility attributes.
2855 dnl --disable-visibility turns off all use of visibility attributes.
2856 dnl  +  Usage:  GLIBCXX_ENABLE_VISIBILITY[(DEFAULT)]
2857 dnl       Where DEFAULT is 'yes'.
2858 dnl
2859 AC_DEFUN([GLIBCXX_ENABLE_VISIBILITY], [
2860 GLIBCXX_ENABLE(visibility,$1,,[enables visibility safe usage])
2861
2862 if test x$enable_visibility = xyes ; then
2863   dnl all hail libgfortran
2864   dnl Check whether the target supports hidden visibility.
2865   AC_CACHE_CHECK([whether the target supports hidden visibility],
2866                  glibcxx_cv_have_attribute_visibility, [
2867   save_CFLAGS="$CFLAGS"
2868   CFLAGS="$CFLAGS -Werror"
2869   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
2870                  [], glibcxx_cv_have_attribute_visibility=yes,
2871                  glibcxx_cv_have_attribute_visibility=no)
2872   CFLAGS="$save_CFLAGS"])
2873   if test $glibcxx_cv_have_attribute_visibility = no; then
2874     enable_visibility=no
2875   fi
2876 fi
2877
2878 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_visibility = yes)
2879 AC_MSG_NOTICE([visibility supported: $enable_visibility])
2880 ])
2881
2882
2883 dnl
2884 dnl Add version tags to symbols in shared library (or not), additionally
2885 dnl marking other symbols as private/local (or not).
2886 dnl
2887 dnl --enable-symvers=style adds a version script to the linker call when
2888 dnl       creating the shared library.  The choice of version script is
2889 dnl       controlled by 'style'.
2890 dnl --disable-symvers does not.
2891 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
2892 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
2893 dnl       choose a default style based on linker characteristics.  Passing
2894 dnl       'no' disables versioning.
2895 dnl
2896 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
2897
2898 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
2899   [enables symbol versioning of the shared library],
2900   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
2901
2902 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
2903 # don't know enough about $LD to do tricks...
2904 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
2905 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
2906 # with extern "C++" in version scripts.
2907 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
2908
2909 # Turn a 'yes' into a suitable default.
2910 if test x$enable_symvers = xyes ; then
2911   if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
2912     enable_symvers=no
2913   else
2914     if test $with_gnu_ld = yes ; then
2915       case ${target_os} in
2916         hpux*)
2917           enable_symvers=no ;;
2918         *)
2919           enable_symvers=gnu ;;
2920       esac
2921     else
2922       case ${target_os} in
2923         darwin*)
2924           enable_symvers=darwin ;;
2925         # Sun symbol versioning exists since Solaris 2.5.
2926         solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
2927           # make_sunver.pl needs GNU c++filt to support extern "C++" in
2928           # version scripts, so disable symbol versioning if none can be
2929           # found.
2930           if test -z "$ac_cv_path_CXXFILT"; then
2931             AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
2932             AC_MSG_WARN([=== no GNU c++filt could  be found.])
2933             AC_MSG_WARN([=== Symbol versioning will be disabled.])
2934             enable_symvers=no
2935           else
2936             enable_symvers=sun
2937           fi
2938           ;;
2939         *)
2940           enable_symvers=no ;;
2941       esac
2942     fi
2943   fi
2944 fi
2945
2946 # Check to see if 'darwin' or 'darwin-export' can win.
2947 if test x$enable_symvers = xdarwin-export ; then
2948     enable_symvers=darwin
2949 fi
2950
2951 # Check if 'sun' was requested on non-Solaris 2 platforms.
2952 if test x$enable_symvers = xsun ; then
2953   case ${target_os} in
2954     solaris2*)
2955       # All fine.
2956       ;;
2957     *)
2958       # Unlikely to work.
2959       AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
2960       AC_MSG_WARN([=== you are not targetting Solaris 2.])
2961       AC_MSG_WARN([=== Symbol versioning will be disabled.])
2962       enable_symvers=no
2963       ;;
2964   esac
2965 fi
2966
2967 # Check to see if 'gnu' can win.
2968 if test $enable_symvers = gnu ||
2969   test $enable_symvers = gnu-versioned-namespace ||
2970   test $enable_symvers = sun; then
2971   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2972   AC_MSG_CHECKING([for shared libgcc])
2973   ac_save_CFLAGS="$CFLAGS"
2974   CFLAGS=' -lgcc_s'
2975   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
2976   CFLAGS="$ac_save_CFLAGS"
2977   if test $glibcxx_shared_libgcc = no; then
2978     cat > conftest.c <<EOF
2979 int main (void) { return 0; }
2980 EOF
2981 changequote(,)dnl
2982     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
2983                              -shared -shared-libgcc -o conftest.so \
2984                              conftest.c -v 2>&1 >/dev/null \
2985                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
2986 changequote([,])dnl
2987     rm -f conftest.c conftest.so
2988     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
2989       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
2990       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
2991       CFLAGS="$ac_save_CFLAGS"
2992     fi
2993   fi
2994   AC_MSG_RESULT($glibcxx_shared_libgcc)
2995
2996   # For GNU ld, we need at least this version.  The format is described in
2997   # GLIBCXX_CHECK_LINKER_FEATURES above.
2998   glibcxx_min_gnu_ld_version=21400
2999
3000   # If no shared libgcc, can't win.
3001   if test $glibcxx_shared_libgcc != yes; then
3002       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3003       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3004       AC_MSG_WARN([=== Symbol versioning will be disabled.])
3005       enable_symvers=no
3006   elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3007     : All interesting versions of Sun ld support sun style symbol versioning.
3008   elif test $with_gnu_ld != yes ; then
3009     # just fail for now
3010     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3011     AC_MSG_WARN([=== you are not using the GNU linker.])
3012     AC_MSG_WARN([=== Symbol versioning will be disabled.])
3013     enable_symvers=no
3014   elif test $glibcxx_ld_is_gold = yes ; then
3015     : All versions of gold support symbol versioning.
3016   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3017     # The right tools, the right setup, but too old.  Fallbacks?
3018     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3019     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3020     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3021     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3022     AC_MSG_WARN([=== Symbol versioning will be disabled.])
3023     enable_symvers=no
3024   fi
3025 fi
3026
3027 # Everything parsed; figure out what file to use.
3028 case $enable_symvers in
3029   no)
3030     SYMVER_FILE=config/abi/pre/none.ver
3031     ;;
3032   gnu)
3033     SYMVER_FILE=config/abi/pre/gnu.ver
3034     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3035               [Define to use GNU versioning in the shared library.])
3036     ;;
3037   gnu-versioned-namespace)
3038     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3039     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3040               [Define to use GNU namespace versioning in the shared library.])
3041     ;;
3042   darwin)
3043     SYMVER_FILE=config/abi/pre/gnu.ver
3044     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3045               [Define to use darwin versioning in the shared library.])
3046     ;;
3047   sun)
3048     SYMVER_FILE=config/abi/pre/gnu.ver
3049     AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3050               [Define to use Sun versioning in the shared library.])
3051     ;;
3052 esac
3053
3054 if test x$enable_symvers != xno ; then
3055   AC_DEFINE(_GLIBCXX_SYMVER, 1,
3056          [Define to use symbol versioning in the shared library.])
3057 fi
3058
3059 AC_CACHE_CHECK([whether the target supports .symver directive],
3060                glibcxx_cv_have_as_symver_directive, [
3061   AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3062                  [], glibcxx_cv_have_as_symver_directive=yes,
3063                  glibcxx_cv_have_as_symver_directive=no)])
3064 if test $glibcxx_cv_have_as_symver_directive = yes; then
3065   AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3066     [Define to 1 if the target assembler supports .symver directive.])
3067 fi
3068
3069 AC_SUBST(SYMVER_FILE)
3070 AC_SUBST(port_specific_symbol_files)
3071 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3072 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3073 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3074 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3075 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3076 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3077
3078 if test $enable_symvers != no ; then
3079    case ${target_os} in
3080      # The Solaris 2 runtime linker doesn't support the GNU extension of
3081      # binding the same symbol to different versions
3082      solaris2*)
3083        symvers_renaming=no  ;;
3084      # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3085      *)
3086        AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3087          [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3088        symvers_renaming=yes  ;;
3089     esac
3090 else
3091     symvers_renaming=no
3092 fi
3093 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SOL2, test $symvers_renaming = no)
3094
3095 # Now, set up compatibility support, if any.
3096 # In addition, need this to deal with std::size_t mangling in
3097 # src/compatibility.cc.  In a perfect world, could use
3098 # typeid(std::size_t).name()[0] to do direct substitution.
3099 AC_MSG_CHECKING([for size_t as unsigned int])
3100 ac_save_CFLAGS="$CFLAGS"
3101 CFLAGS="-Werror"
3102 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3103                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3104 CFLAGS=$ac_save_CFLAGS
3105 if test "$glibcxx_size_t_is_i" = yes; then
3106   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3107 fi
3108 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3109
3110 AC_MSG_CHECKING([for ptrdiff_t as int])
3111 ac_save_CFLAGS="$CFLAGS"
3112 CFLAGS="-Werror"
3113 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3114                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3115 CFLAGS=$ac_save_CFLAGS
3116 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3117   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3118 fi
3119 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3120 ])
3121
3122
3123 dnl
3124 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3125 dnl We must stage the required headers so that they will be installed
3126 dnl with the library (unlike libgcc, the STL implementation is provided
3127 dnl solely within headers).  Since we must not inject random user-space
3128 dnl macro names into user-provided C++ code, we first stage into <file>-in
3129 dnl and process to <file> with an output command.  The reason for a two-
3130 dnl stage process here is to correctly handle $srcdir!=$objdir without
3131 dnl having to write complex code (the sed commands to clean the macro
3132 dnl namespace are complex and fragile enough as it is).  We must also
3133 dnl add a relative path so that -I- is supported properly.
3134 dnl
3135 dnl Substs:
3136 dnl  glibcxx_thread_h
3137 dnl
3138 dnl Defines:
3139 dnl  HAVE_GTHR_DEFAULT
3140 dnl
3141 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3142   AC_MSG_CHECKING([for thread model used by GCC])
3143   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3144   AC_MSG_RESULT([$target_thread_file])
3145
3146   if test $target_thread_file != single; then
3147     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
3148               [Define if gthr-default.h exists
3149               (meaning that threading support is enabled).])
3150   fi
3151
3152   glibcxx_thread_h=gthr-$target_thread_file.h
3153
3154   dnl Check for __GTHREADS define.
3155   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
3156   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
3157     enable_thread=yes
3158   else
3159    enable_thread=no
3160   fi
3161
3162   AC_SUBST(glibcxx_thread_h)
3163 ])
3164
3165
3166 dnl
3167 dnl Check if gthread implementation defines the types and functions
3168 dnl required by the c++0x thread library.  Conforming gthread
3169 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3170 dnl
3171 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3172   AC_LANG_SAVE
3173   AC_LANG_CPLUSPLUS
3174
3175   ac_save_CXXFLAGS="$CXXFLAGS"
3176   CXXFLAGS="$CXXFLAGS -fno-exceptions -I${toplevel_srcdir}/gcc"
3177
3178   AC_MSG_CHECKING([check whether it can be safely assumed that mutex_timedlock is available])
3179
3180   AC_TRY_COMPILE([#include <unistd.h>],
3181     [
3182       #if !defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS < 0
3183       #error
3184       #endif
3185     ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3186
3187   AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3188                      [Define to 1 if mutex_timedlock is available.])
3189
3190   if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3191   else res_mutex_timedlock=no ; fi
3192   AC_MSG_RESULT([$res_mutex_timedlock])
3193
3194   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3195   case $target_thread_file in
3196     posix)
3197       CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3198   esac
3199
3200   AC_MSG_CHECKING([for gthreads library])
3201
3202   AC_TRY_COMPILE([
3203                   #include "gthr.h"
3204                   #include <unistd.h>
3205                  ],
3206     [
3207       #ifndef __GTHREADS_CXX0X
3208       #error
3209       #endif
3210
3211       // In case of POSIX threads check _POSIX_TIMEOUTS too.
3212       #if (defined(_PTHREADS) \
3213            && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3214       #error
3215       #endif
3216     ], [ac_has_gthreads=yes], [ac_has_gthreads=no])
3217
3218   AC_MSG_RESULT([$ac_has_gthreads])
3219
3220   if test x"$ac_has_gthreads" = x"yes"; then
3221     AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3222               [Define if gthreads library is available.])
3223   fi
3224
3225   CXXFLAGS="$ac_save_CXXFLAGS"
3226   AC_LANG_RESTORE
3227 ])
3228
3229
3230 # Check whether LC_MESSAGES is available in <locale.h>.
3231 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3232 #
3233 # This file file be copied and used freely without restrictions.  It can
3234 # be used in projects which are not available under the GNU Public License
3235 # but which still want to provide support for the GNU gettext functionality.
3236 # Please note that the actual code is *not* freely available.
3237 AC_DEFUN([AC_LC_MESSAGES], [
3238   AC_CHECK_HEADER(locale.h, [
3239     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3240       [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3241        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3242     if test $ac_cv_val_LC_MESSAGES = yes; then
3243       AC_DEFINE(HAVE_LC_MESSAGES, 1,
3244                 [Define if LC_MESSAGES is available in <locale.h>.])
3245     fi
3246   ])
3247 ])
3248
3249 dnl
3250 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3251 dnl
3252 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3253
3254   AC_LANG_SAVE
3255   AC_LANG_CPLUSPLUS
3256   ac_save_CXXFLAGS="$CXXFLAGS"
3257   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3258
3259   AC_MSG_CHECKING([for get_nprocs])
3260   AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3261     GCC_TRY_COMPILE_OR_LINK(
3262       [#include <sys/sysinfo.h>],
3263       [int n = get_nprocs();],
3264       [glibcxx_cv_GET_NPROCS=yes],
3265       [glibcxx_cv_GET_NPROCS=no])
3266   ])
3267   if test $glibcxx_cv_GET_NPROCS = yes; then
3268     AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3269   fi
3270   AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3271
3272   CXXFLAGS="$ac_save_CXXFLAGS"
3273   AC_LANG_RESTORE
3274 ])
3275
3276 dnl
3277 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3278 dnl
3279 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3280
3281   AC_LANG_SAVE
3282   AC_LANG_CPLUSPLUS
3283   ac_save_CXXFLAGS="$CXXFLAGS"
3284   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3285
3286   AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3287   AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3288     GCC_TRY_COMPILE_OR_LINK(
3289       [#include <unistd.h>],
3290       [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3291       [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3292       [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3293   ])
3294   if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3295     AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN  is available in <unistd.h>.])
3296   fi
3297   AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3298
3299   CXXFLAGS="$ac_save_CXXFLAGS"
3300   AC_LANG_RESTORE
3301 ])
3302
3303
3304 # Macros from the top-level gcc directory.
3305 m4_include([../config/gc++filt.m4])
3306 m4_include([../config/tls.m4])