libquadmath/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GCC Quad-precision Math Library], 0.1,,[libquadmath])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
   9 #
  10 # You will slowly go insane if you do not grok the following fact:  when
  11 # building this library, the top-level /target/ becomes the library's /host/.
  12 #
  13 # configure then causes --target to default to --host, exactly like any
  14 # other package using autoconf.  Therefore, 'target' and 'host' will
  15 # always be the same.  This makes sense both for native and cross compilers
  16 # just think about it for a little while.  :-)
  17 #
  18 # Also, if this library is being configured as part of a cross compiler, the
  19 # top-level configure script will pass the "real" host as $with_cross_host.
  20 #
  21 # Do not delete or change the following two lines.  For why, see
  22 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  23 AC_CANONICAL_SYSTEM
  24 ACX_NONCANONICAL_TARGET
  25
  26 target_alias=${target_alias-$host_alias}
  27 AC_SUBST(target_alias)
  28
  29 AM_INIT_AUTOMAKE([1.9.0 foreign subdir-objects no-dist -Wall -Wno-override -Werror])
  30
  31 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  32 AC_ARG_ENABLE(version-specific-runtime-libs,
  33 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  34  [specify that runtime libraries should be installed in a compiler-specific directory]),
  35 [case "$enableval" in
  36  yes) version_specific_libs=yes ;;
  37  no)  version_specific_libs=no ;;
  38  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  39  esac],
  40 [version_specific_libs=no])
  41 AC_MSG_RESULT($version_specific_libs)
  42
  43 GCC_NO_EXECUTABLES
  44
  45 AC_USE_SYSTEM_EXTENSIONS
  46
  47 # See if makeinfo has been installed and is modern enough
  48 # that we can use it.
  49 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
  50                    [GNU texinfo.* \([0-9][0-9.]*\)],
  51                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
  52 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
  53
  54 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
  55
  56 # Configure libtool
  57 AM_PROG_LIBTOOL
  58 ACX_LT_HOST_FLAGS
  59 AC_SUBST(enable_shared)
  60 AC_SUBST(enable_static)
  61
  62 AM_MAINTAINER_MODE
  63 AM_ENABLE_MULTILIB(, ..)
  64
  65 AC_LANG_C
  66 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  67 # We must force CC to /not/ be precious variables; otherwise
  68 # the wrong, non-multilib-adjusted value will be used in multilibs.
  69 # As a side effect, we have to subst CFLAGS ourselves.
  70
  71 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  72 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  73 AC_PROG_CC
  74 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  75
  76 AC_SUBST(CFLAGS)
  77
  78 AM_PROG_CC_C_O
  79
  80 if test "x$GCC" != "xyes"; then
  81   AC_MSG_ERROR([libquadmath must be built with GCC])
  82 fi
  83 AC_PROG_CPP
  84
  85 # Calculate toolexeclibdir
  86 # Also toolexecdir, though it's only used in toolexeclibdir
  87 case ${version_specific_libs} in
  88   yes)
  89     # Need the gcc compiler version to know where to install libraries
  90     # and header files if --enable-version-specific-runtime-libs option
  91     # is selected.
  92     toolexecdir='$(libdir)/gcc/$(target_alias)'
  93     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  94     ;;
  95   no)
  96     if test -n "$with_cross_host" &&
  97        test x"$with_cross_host" != x"no"; then
  98       # Install a library built with a cross compiler in tooldir, not libdir.
  99       toolexecdir='$(exec_prefix)/$(target_alias)'
 100       toolexeclibdir='$(toolexecdir)/lib'
 101     else
 102       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 103       toolexeclibdir='$(libdir)'
 104     fi
 105     multi_os_directory=`$CC -print-multi-os-directory`
 106     case $multi_os_directory in
 107       .) ;; # Avoid trailing /.
 108       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 109     esac
 110     ;;
 111 esac
 112 AC_SUBST(toolexecdir)
 113 AC_SUBST(toolexeclibdir)
 114
 115 AC_CHECK_HEADERS(fenv.h langinfo.h wchar.h wctype.h limits.h ctype.h printf.h errno.h)
 116
 117 # If available, sqrtl and cbrtl speed up the calculation -
 118 # but they are not required
 119 if test x$gcc_no_link != xyes; then
 120   AC_CHECK_LIB([m],[sqrtl],[AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])])
 121   AC_CHECK_LIB([m],[cbrtl],[AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])])
 122   AC_CHECK_LIB([m],[feholdexcept],[AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])])
 123   AC_CHECK_LIB([m],[fesetround],[AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])])
 124   AC_CHECK_LIB([m],[feupdateenv],[AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])])
 125   AC_CHECK_LIB([m],[fesetenv],[AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])])
 126   AC_CHECK_LIB([m],[fetestexcept],[AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])])
 127 else
 128   if test "x$ac_cv_lib_m_sqrtl" = x""yes; then
 129     AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])
 130   fi
 131   if test "x$ac_cv_lib_m_cbrtl" = x""yes; then
 132     AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])
 133   fi
 134   if test "x$ac_cv_lib_m_feholdexcept" = x""yes; then
 135     AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])
 136   fi
 137   if test "x$ac_cv_lib_m_fesetround" = x""yes; then
 138     AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])
 139   fi
 140   if test "x$ac_cv_lib_m_feupdateenv" = x""yes; then
 141     AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])
 142   fi
 143   if test "x$ac_cv_lib_m_fesetenv" = x""yes; then
 144     AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])
 145   fi
 146   if test "x$ac_cv_lib_m_fetestexcept" = x""yes; then
 147     AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])
 148   fi
 149 fi
 150
 151 # Check for hidden visibility (copied from libssp).
 152 AC_MSG_CHECKING([whether hidden visibility is supported])
 153 AC_TRY_COMPILE([
 154 void __attribute__((visibility ("hidden"))) bar (void) {}],,
 155 [quadmath_hidden=yes],[quadmath_hidden=no])
 156 AC_MSG_RESULT($quadmath_hidden)
 157 if test x$quadmath_hidden = xyes; then
 158   AC_DEFINE([HAVE_HIDDEN_VISIBILITY],[1],[__attribute__((visibility ("hidden"))) supported])
 159 fi
 160
 161 # Check for symbol versioning (copied from libssp).
 162 AC_MSG_CHECKING([whether symbol versioning is supported])
 163 if test x$gcc_no_link = xyes; then
 164   # If we cannot link, we cannot build shared libraries, so do not use
 165   # symbol versioning.
 166   quadmath_use_symver=no
 167 else
 168   save_LDFLAGS="$LDFLAGS"
 169   LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 170   cat > conftest.map <<EOF
 171 FOO_1.0 {
 172   global: *foo*; bar; local: *;
 173 };
 174 EOF
 175   AC_TRY_LINK([int foo;],[],[quadmath_use_symver=gnu],[quadmath_use_symver=no])
 176   if test x$quadmath_use_symver = xno; then
 177     case "$target_os" in
 178       solaris2*)
 179         LDFLAGS="$save_LDFLAGS"
 180         LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 181         # Sun ld cannot handle wildcards and treats all entries as undefined.
 182         cat > conftest.map <<EOF
 183 FOO_1.0 {
 184   global: foo; local: *;
 185 };
 186 EOF
 187         AC_TRY_LINK([int foo;],[],[quadmath_use_symver=sun],[quadmath_use_symver=no])
 188         ;;
 189     esac
 190   fi
 191   LDFLAGS="$save_LDFLAGS"
 192 fi
 193 AC_MSG_RESULT($quadmath_use_symver)
 194 AM_CONDITIONAL(LIBQUAD_USE_SYMVER, [test "x$quadmath_use_symver" != xno])
 195 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_GNU, [test "x$quadmath_use_symver" = xgnu])
 196 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_SUN, [test "x$quadmath_use_symver" = xsun])
 197
 198 AC_CACHE_CHECK([whether __float128 is supported], [libquad_cv_have_float128],
 199   [GCC_TRY_COMPILE_OR_LINK([
 200     typedef _Complex float __attribute__((mode(TC))) __complex128;
 201
 202     __float128 foo (__float128 x)
 203     {
 204
 205      __complex128 z1, z2;
 206
 207      z1 = x;
 208      z2 = x / 7.Q;
 209      z2 /= z1;
 210
 211      return (__float128) z2;
 212     }
 213
 214     __float128 bar (__float128 x)
 215     {
 216       return x * __builtin_huge_valq ();
 217     }
 218   ],[
 219     foo (1.2Q);
 220     bar (1.2Q);
 221   ],[
 222     libquad_cv_have_float128=yes
 223   ],[
 224     libquad_cv_have_float128=no
 225 ])])
 226 AM_CONDITIONAL(BUILD_LIBQUADMATH, [test "x$libquad_cv_have_float128" = xyes])
 227
 228 # Check for printf hook support.
 229 AC_MSG_CHECKING([whether printf hooks are supported])
 230 AC_TRY_COMPILE([
 231 #include <printf.h>
 232 #include <stdarg.h>
 233 #include <stdlib.h>
 234 extern void flt128_va (void *, va_list *);
 235 extern int flt128_ais (const struct printf_info *, size_t, int *, int *);
 236 extern int flt128_printf_fp (FILE *, const struct printf_info *, const void *const *);
 237 ],[
 238 int pa_flt128 = register_printf_type (flt128_va);
 239 int mod_Q = register_printf_modifier (L"Q");
 240 int res = register_printf_specifier ('f', flt128_printf_fp, flt128_ais);
 241 ],
 242 [quadmath_printf_hooks=yes],[quadmath_printf_hooks=no])
 243 AC_MSG_RESULT($quadmath_printf_hooks)
 244 if test x$quadmath_printf_hooks = xyes; then
 245   AC_DEFINE([HAVE_PRINTF_HOOKS],[1],[GNU C Library stype printf hooks supported])
 246 fi
 247
 248 # Check for whether locale support for quadmath_snprintf or Q printf hooks
 249 # should be provided.
 250 AC_MSG_CHECKING([whether locale support for quadmath_snprintf should be added])
 251 AC_TRY_COMPILE([#include <langinfo.h>],[
 252 const char *s;
 253 s = nl_langinfo (DECIMAL_POINT);
 254 s = nl_langinfo (MON_DECIMAL_POINT);
 255 s = nl_langinfo (GROUPING);
 256 s = nl_langinfo (MON_GROUPING);
 257 s = nl_langinfo (THOUSANDS_SEP);
 258 s = nl_langinfo (MON_THOUSANDS_SEP);
 259 s = nl_langinfo (_NL_NUMERIC_DECIMAL_POINT_WC);
 260 s = nl_langinfo (_NL_MONETARY_DECIMAL_POINT_WC);
 261 s = nl_langinfo (_NL_NUMERIC_THOUSANDS_SEP_WC);
 262 s = nl_langinfo (_NL_MONETARY_THOUSANDS_SEP_WC);
 263 s = nl_langinfo (_NL_CTYPE_MB_CUR_MAX);
 264 (void) s;
 265 ],
 266 [quadmath_use_locale_support=yes],[quadmath_use_locale_support=no])
 267 AC_MSG_RESULT($quadmath_use_locale_support)
 268 if test x$quadmath_use_locale_support = xyes; then
 269   AC_DEFINE([USE_LOCALE_SUPPORT],[1],[whether nl_langinfo is sufficiently supported])
 270 fi
 271
 272 # Check for whether i18n number rewriting support for quadmath_snprintf
 273 # or Q printf hooks should be provided.
 274 AC_MSG_CHECKING([whether i18n number rewriting support for quadmath_snprintf should be added])
 275 AC_TRY_COMPILE([#include <langinfo.h>
 276 #include <limits.h>
 277 #include <string.h>
 278 #include <wchar.h>
 279 #include <wctype.h>],[
 280 const char *s;
 281 char decimal[MB_LEN_MAX];
 282 wctrans_t map = wctrans ("to_outpunct");
 283 wint_t wdecimal = towctrans (L'.', map);
 284 mbstate_t state;
 285 memset (&state, '\0', sizeof (state));
 286 wcrtomb (decimal, wdecimal, &state);
 287 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
 288 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
 289 (void) s;
 290 ],
 291 [quadmath_use_i18n_number_h=yes],[quadmath_use_i18n_number_h=no])
 292 AC_MSG_RESULT($quadmath_use_i18n_number_h)
 293 if test x$quadmath_use_i18n_number_h = xyes; then
 294   AC_DEFINE([USE_I18N_NUMBER_H],[1],[whether i18n number rewriting can be supported])
 295 fi
 296
 297 AC_CACHE_SAVE
 298
 299 if test ${multilib} = yes; then
 300   multilib_arg="--enable-multilib"
 301 else
 302   multilib_arg=
 303 fi
 304
 305
 306 # We would like our source tree to be readonly. However when releases or
 307 # pre-releases are generated, the flex/bison generated files as well as the
 308 # various formats of manuals need to be included along with the rest of the
 309 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 310 # just that.
 311 AC_MSG_CHECKING(generated-files-in-srcdir)
 312 AC_ARG_ENABLE(generated-files-in-srcdir,
 313 AS_HELP_STRING([--enable-generated-files-in-srcdir],
 314  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
 315 [case "$enableval" in
 316  yes) enable_generated_files_in_srcdir=yes ;;
 317  no)  enable_generated_files_in_srcdir=no ;;
 318  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 319  esac],
 320 [enable_generated_files_in_srcdir=no])
 321 AC_MSG_RESULT($enable_generated_files_in_srcdir)
 322 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
 323
 324
 325 AC_CONFIG_FILES(Makefile)
 326 AC_OUTPUT