libobjc/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Objective C.
   6 #
   7 #GNU Objective C is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Objective C is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Objective C; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(objc/objc.h)
  24 #AC_CONFIG_HEADER(config.h)
  25
  26 if test "${srcdir}" = "." ; then
  27   if test "${with_target_subdir}" != "." ; then
  28     topsrcdir=${with_multisrctop}../..
  29   else
  30     topsrcdir=${with_multisrctop}..
  31   fi
  32 else
  33   topsrcdir=${srcdir}/..
  34 fi
  35 dnl This is needed for a multilibbed build in the source tree so
  36 dnl that install-sh and config.sub get found.
  37 AC_CONFIG_AUX_DIR($topsrcdir)
  38
  39 # If the language specific compiler does not exist, but the "gcc" directory does,
  40 # we do not build anything. Note, $r is set by the top-level Makefile.
  41 compiler_name=cc1obj
  42 rm -f skip-this-dir
  43 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  44 AC_CACHE_VAL(objc_cv_compiler_exists,
  45         [objc_cv_compiler_exists=yes
  46         if test -n "$r"; then
  47                 if test -d "$r"/gcc; then
  48                         if test -f "$r"/gcc/$compiler_name; then
  49                                 true
  50                         else
  51                                 objc_cv_compiler_exists=no
  52                                 echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  53                         fi
  54                 fi
  55         fi
  56         ])
  57 AC_MSG_RESULT($objc_cv_compiler_exists)
  58 if test x$objc_cv_compiler_exists = xno
  59 then
  60         rm -f Makefile conftest* confdefs* core
  61         exit 0
  62 fi
  63
  64 dnl Checks for programs.
  65 # For ObjC we'll set CC to point at the built gcc, but this will get it into
  66 # the makefiles
  67 AC_PROG_CC
  68
  69 test "$AR" || AR=ar
  70 AC_SUBST(AR)
  71 if test "$RANLIB"; then :
  72   AC_SUBST(RANLIB)
  73 else
  74   AC_PROG_RANLIB
  75 fi
  76 AC_PROG_INSTALL
  77
  78 dnl Checks for libraries.
  79
  80 dnl Checks for header files.
  81 # Sanity check for the cross-compilation case:
  82 AC_CHECK_HEADER(stdio.h,:,
  83   [AC_MSG_ERROR([Can't find stdio.h.
  84 You must have a usable C system for the target already installed, at least
  85 including headers and, preferably, the library, before you can configure
  86 the Objective C runtime system.  If necessary, install gcc now with
  87 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
  88
  89 AC_HEADER_STDC
  90
  91 # Determine the name of the GCC thread file.
  92
  93 dir=`pwd`
  94 if test x"${with_multisubdir}" = "x" ; then
  95   gccobjdir=`echo $dir/../../gcc`
  96 else
  97   gccobjdir=`echo $dir | sed -e s:${with_multisubdir}::`/../../gcc
  98 fi
  99
 100 AC_CACHE_CHECK([for thread file],objc_cv_thread_file,
 101 [if test -f $gccobjdir/Makefile
 102 then
 103   objc_cv_thread_file=`grep \^GCC_THREAD_FILE $gccobjdir/Makefile | awk -F= '{ print $2 }'`
 104 else
 105   AC_MSG_ERROR([not found])
 106 fi])
 107 OBJC_THREAD_FILE=$objc_cv_thread_file
 108 AC_SUBST(OBJC_THREAD_FILE)
 109
 110 AC_ARG_ENABLE(objc-gc,
 111 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 112                           the GNU Objective-C runtime.],
 113 if [[[ x$enable_objc_gc = xno ]]]; then
 114         OBJC_BOEHM_GC=''
 115 else
 116         OBJC_BOEHM_GC=libobjc_gc.a
 117 fi,
 118 OBJC_BOEHM_GC='')
 119 AC_SUBST(OBJC_BOEHM_GC)
 120
 121
 122 # We need multilib support, but only if configuring for the target.
 123 AC_OUTPUT(Makefile,
 124 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 125 if test -n "$CONFIG_FILES"; then
 126   if test -n "${with_target_subdir}"; then
 127     # FIXME: We shouldn't need to set ac_file
 128     ac_file=Makefile
 129     . ${topsrcdir}/config-ml.in
 130   fi
 131 fi],
 132 srcdir=${srcdir}
 133 host=${host}
 134 target=${target}
 135 with_target_subdir=${with_target_subdir}
 136 with_multisubdir=${with_multisubdir}
 137 ac_configure_args="--enable-multilib ${ac_configure_args}"
 138 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 139 topsrcdir=${topsrcdir}
 140 )
 141
 142 dnl Local Variables:
 143 dnl comment-start: "dnl "
 144 dnl comment-end: ""
 145 dnl comment-start-skip: "\\bdnl\\b\\s *"
 146 dnl End: