libmudflap/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I .. -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT(libmudflap, 1.0)
   6 AC_CONFIG_SRCDIR(mf-runtime.c)
   7 AC_CANONICAL_SYSTEM
   8 ACX_NONCANONICAL_TARGET
   9
  10 AM_INIT_AUTOMAKE([no-dist])
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 AC_ARG_ENABLE(version-specific-runtime-libs,
  14 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  15 [case "$enableval" in
  16  yes) version_specific_libs=yes ;;
  17  no)  version_specific_libs=no ;;
  18  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  19  esac],
  20 [version_specific_libs=no])
  21 AC_MSG_RESULT($version_specific_libs)
  22
  23 AM_MAINTAINER_MODE
  24 AC_EXEEXT
  25
  26 AM_ENABLE_MULTILIB(, ..)
  27
  28 target_alias=${target_alias-$host_alias}
  29 AC_SUBST(target_alias)
  30
  31 AC_CONFIG_HEADERS(config.h)
  32
  33 AC_LANG_C
  34 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  35 # We must force CC to /not/ be precious variables; otherwise
  36 # the wrong, non-multilib-adjusted value will be used in multilibs.
  37 # As a side effect, we have to subst CFLAGS ourselves.
  38
  39 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  40 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  41 AC_PROG_CC
  42 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  43
  44 AC_SUBST(CFLAGS)
  45
  46 if test "x$GCC" != "xyes"; then
  47   AC_MSG_ERROR([libmudflap must be built with GCC])
  48 fi
  49 AC_PROG_CPP
  50
  51 # Some hosts don't have dlsym(RTLD_NEXT, "symbol") for use in
  52 # symbol interposition.  We disable shared libraries for these.
  53 AC_MSG_CHECKING([whether dlsym(RTLD_NEXT,...) is available])
  54 AC_TRY_COMPILE([
  55 #define _GNU_SOURCE
  56 #include <dlfcn.h>
  57 ],
  58 [void *foo = dlsym (RTLD_NEXT, "exit");],
  59 [AC_MSG_RESULT(yes)],
  60 [AC_MSG_RESULT(no)
  61 enable_shared=no])
  62
  63 AC_CHECK_HEADERS(stdint.h execinfo.h signal.h dlfcn.h dirent.h pwd.h grp.h \
  64   netdb.h sys/ipc.h sys/sem.h sys/shm.h sys/wait.h ctype.h mntent.h \
  65   sys/mnttab.h sys/socket.h netinet/in.h arpa/inet.h dlfcn.h sys/mman.h)
  66
  67 AC_CHECK_FUNCS(backtrace backtrace_symbols gettimeofday signal)
  68 AC_CHECK_FUNCS(fopen64 fseeko64 ftello64 stat64 freopen64)
  69 AC_CHECK_FUNCS(setbuf setbuffer setlinebuf setvbuf)
  70 AC_CHECK_FUNCS(strnlen memrchr strncpy memmem sethostname)
  71 AC_CHECK_FUNCS(__ctype_b_loc __ctype_tolower_loc __ctype_toupper_loc)
  72 AC_CHECK_FUNCS(getlogin cuserid getpwnam getpwuid getpwent getgrnam getgrgid getgrent)
  73 AC_CHECK_FUNCS(getlogin_r getpwnam_r getpwuid_r getgrnam_r getgrgid_r)
  74 AC_CHECK_FUNCS(getservent getservbyname getservbyport getaddrinfo gai_strerror)
  75 AC_CHECK_FUNCS(getprotoent getprotobyname getprotobynumber)
  76 AC_CHECK_FUNCS(getmntent setmntent addmntent)
  77 AC_CHECK_FUNCS(inet_ntoa mmap munmap)
  78 AC_CHECK_FUNCS(__libc_freeres)
  79
  80 AC_TRY_COMPILE([#include <sys/types.h>
  81 #include <sys/ipc.h>
  82 #include <sys/sem.h>],[union semun foo;], [mf_have_semun=1], [mf_have_semun=0])
  83 if test $mf_have_semun = 1
  84 then
  85   AC_DEFINE(HAVE_UNION_SEMUN, 1, [union semun defined in sys/ipc.h or sys/sem.h])
  86 fi
  87
  88
  89 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
  90 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
  91 #include <sys/types.h>
  92 #include <sys/socket.h>], [socklen_t x = 5;],
  93   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
  94    AC_MSG_RESULT(yes)],
  95   [AC_MSG_RESULT(no)])
  96
  97 AC_LIBTOOL_DLOPEN
  98 AM_PROG_LIBTOOL
  99 AC_SUBST(enable_shared)
 100 AC_SUBST(enable_static)
 101
 102 AC_CHECK_HEADER(stdint.h, [MF_HAVE_STDINT_H=1], [MF_HAVE_STDINT_H=0])
 103 AC_SUBST(MF_HAVE_STDINT_H)
 104 if test $MF_HAVE_STDINT_H = 1
 105 then
 106    MF_HAVE_UINTPTR_T=1
 107 else
 108    AC_TRY_COMPILE([#include <sys/types.h>], [uintptr_t k = 0;],
 109         [MF_HAVE_UINTPTR_T=1], [MF_HAVE_UINTPTR_T=0])
 110 fi
 111 AC_SUBST(MF_HAVE_UINTPTR_T)
 112
 113 if test ! -d pth
 114 then
 115   # libmudflapth objects are built in this subdirectory
 116   mkdir pth
 117 fi
 118
 119 AC_CHECK_HEADERS(pthread.h)
 120
 121 AC_MSG_CHECKING([for thread model used by GCC])
 122 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 123 AC_MSG_RESULT([$target_thread_file])
 124
 125 # We only support posix threads, or no threads at all.
 126 posix_threads=
 127 case ${target_thread_file} in
 128   posix)
 129     posix_threads=yes
 130     ;;
 131   single)
 132     ;;
 133   *)
 134     echo "${target_thread_file} is an unsupported thread package" 1>&2
 135     exit 1
 136     ;;
 137 esac
 138
 139 AM_CONDITIONAL(LIBMUDFLAPTH, [test "x$posix_threads" != "x"])
 140 if test "x$posix_threads" != "x"
 141 then
 142         build_libmudflapth=1
 143 else
 144         build_libmudflapth=0
 145 fi
 146 AC_SUBST(build_libmudflapth)
 147
 148 AC_CHECK_LIB(dl, dlsym)
 149
 150 AC_CHECK_FUNC(connect,, AC_CHECK_LIB(socket, connect))
 151
 152 # Calculate toolexeclibdir
 153 # Also toolexecdir, though it's only used in toolexeclibdir
 154 case ${version_specific_libs} in
 155   yes)
 156     # Need the gcc compiler version to know where to install libraries
 157     # and header files if --enable-version-specific-runtime-libs option
 158     # is selected.
 159     toolexecdir='$(libdir)/gcc/$(target_alias)'
 160     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 161     ;;
 162   no)
 163     if test -n "$with_cross_host" &&
 164        test x"$with_cross_host" != x"no"; then
 165       # Install a library built with a cross compiler in tooldir, not libdir.
 166       toolexecdir='$(exec_prefix)/$(target_alias)'
 167       toolexeclibdir='$(toolexecdir)/lib'
 168     else
 169       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 170       toolexeclibdir='$(libdir)'
 171     fi
 172     multi_os_directory=`$CC -print-multi-os-directory`
 173     case $multi_os_directory in
 174       .) ;; # Avoid trailing /.
 175       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 176     esac
 177     ;;
 178 esac
 179 AC_SUBST(toolexecdir)
 180 AC_SUBST(toolexeclibdir)
 181
 182 includedir=${toolexecdir}/include
 183 AC_SUBST(includedir)
 184
 185 pthread_create_version='""'
 186 if test "x$enable_shared" = "xyes" && test "x$posix_threads" != "x"; then
 187   # NB: don't check for -lpthread here, because then it would be
 188   # added to LIBS.  For the thread-unaware libmudflap.la, we don't
 189   # want it there.
 190
 191   # glibc-related hacks.  dlsym() may pick the wrong version of
 192   # interposed functions like pthread_create on modern glibc.
 193   # We need to find the proper symbol version string, and use
 194   # the nonstandard dlvsym().
 195   AC_CHECK_FUNCS(dlvsym)
 196   AC_CHECK_TOOL(NM, nm)
 197   if test "x$ac_cv_have_dlvsym" != "x"; then
 198     # Try compiling a simple pthreads program.  Find the shared libraries it
 199     # ends up with.  Then use "nm" on those libraries to extract the
 200     # default symbol versioning suffix ("@@"), if any.  But that's tricky.
 201     # Rather, run nm on the resulting executable.  Unfortunately, autoconf
 202     # doesn't appear to have a macro that builds a test executable for
 203     # subsequent analysis ... so we do it by hand here.
 204     cat >> conftest.c << EOF
 205 #include <pthread.h>
 206 int main () { void *p = (void *) & pthread_create; return (int) p; }
 207 EOF
 208     oldLIBS="$LIBS"
 209     LIBS="$LIBS -lpthread"
 210     pthread_create_version="\"\""
 211     AC_MSG_CHECKING(pthread_create symbol version)
 212     if eval $ac_link 2>&5 && test -s conftest${ac_exeext}; then
 213       version=`$NM conftest${ac_exeect} | grep 'pthread_create@@' | sed -e 's/^.*@@//'`
 214       if test "x$version" != "x"; then
 215         pthread_create_version="\"$version\""
 216       fi
 217     fi
 218     AC_MSG_RESULT($pthread_create_version)
 219     LIBS="$oldLIBS"
 220   fi
 221 fi
 222 AC_DEFINE_UNQUOTED(PTHREAD_CREATE_VERSION, $pthread_create_version, [pthread_create symbol version])
 223
 224
 225 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
 226 # similarly to how libstdc++ does it
 227 ac_test_CFLAGS="${CFLAGS+set}"
 228 ac_save_CFLAGS="$CFLAGS"
 229
 230 # Check for -ffunction-sections -fdata-sections
 231 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
 232 CFLAGS='-Werror -ffunction-sections -fdata-sections'
 233 AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 234 if test "$ac_test_CFLAGS" = set; then
 235   CFLAGS="$ac_save_CFLAGS"
 236 else
 237   # this is the suspicious part
 238   CFLAGS=""
 239 fi
 240 if test x"$ac_fdsections" = x"yes"; then
 241   SECTION_FLAGS='-ffunction-sections -fdata-sections'
 242 fi
 243 AC_MSG_RESULT($ac_fdsections)
 244 AC_SUBST(SECTION_FLAGS)
 245
 246
 247 # Check for the name of the symbol used for the entry point.
 248 AC_CACHE_CHECK([for the name of the symbol used for the entry point],
 249   [mudflap_cv_entry_point], [
 250 for name in _start __start unknown; do
 251   AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char $name@<:@@:>@;], [$name@<:@0@:>@ = 0;])],
 252                  [break])
 253 done
 254 mudflap_cv_entry_point="$name"])
 255 if test "$mudflap_cv_entry_point" = unknown; then
 256   AC_MSG_ERROR([none of the known symbol names works])
 257 fi
 258 AC_DEFINE_UNQUOTED([ENTRY_POINT], [$mudflap_cv_entry_point],
 259   [Define to the name of the symbol used for the entry point.])
 260
 261
 262 if test ${multilib} = yes; then
 263   multilib_arg="--enable-multilib"
 264 else
 265   multilib_arg=
 266 fi
 267
 268 # See if we support thread-local storage.
 269 GCC_CHECK_TLS
 270 GCC_CHECK_EMUTLS
 271
 272 AC_CONFIG_FILES([Makefile testsuite/Makefile testsuite/mfconfig.exp])
 273 AC_OUTPUT