libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -n "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66 dnl See if the user has requested runtime debugging.
  67 AC_ARG_ENABLE(libgcj-debug,
  68 [  --enable-libgcj-debug   enable runtime debugging code],
  69   if test "$enable_libgcj_debug" = yes; then
  70      AC_DEFINE(DEBUG)
  71   fi)
  72
  73 dnl See if the user has the interpreter included.
  74 AC_ARG_ENABLE(interpreter,
  75 [  --enable-interpreter    enable interpreter],
  76   if test "$enable_interpreter" = yes; then
  77     # This can also be set in configure.host.
  78     libgcj_interpreter=yes
  79   elif test "$enable_interpreter" = no; then
  80     libgcj_interpreter=no
  81   fi)
  82
  83 if test "$libgcj_interpreter" = yes; then
  84    AC_DEFINE(INTERPRETER)
  85 fi
  86
  87 EXCEPTIONSPEC=
  88 dnl See if we should use setjmp/longjmp exceptions
  89 AC_ARG_ENABLE(sjlj-exceptions,
  90 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  91   if test "$enable_sjlj_exceptions" = yes; then
  92      # This can be set in configure.host.
  93      libgcj_sjlj=yes
  94   fi)
  95
  96 if test "$libgcj_sjlj" = yes; then
  97    EXCEPTIONSPEC="-fsjlj-exceptions"
  98    AC_DEFINE(SJLJ_EXCEPTIONS)
  99 fi
 100
 101 FORCELIBGCCSPEC=
 102 dnl Work around libgcc design flaw.
 103 if test "$ac_cv_prog_gnu_ld" = yes; then
 104    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 105 fi
 106
 107 AC_MSG_CHECKING([for data_start])
 108 LIBDATASTARTSPEC=
 109 NEEDS_DATA_START=
 110 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 111   [AC_MSG_RESULT(found it)],
 112   [LIBDATASTARTSPEC="-u data_start -lgcjdata"
 113    NEEDS_DATA_START=yes
 114    AC_MSG_RESULT(missing)])
 115 AC_SUBST(LIBDATASTARTSPEC)
 116
 117 dnl See if the user wants to disable java.net.  This is the mildly
 118 dnl ugly way that we admit that target-side configuration sucks.
 119 AC_ARG_ENABLE(java-net,
 120 [  --disable-java-net      disable java.net])
 121
 122 dnl Whether java.net is built by default can depend on the target.
 123 if test -n "$enable_java_net"; then
 124    enable_java_net=${enable_java_net_default-yes}
 125 fi
 126 if test "$enable_java_net" = no; then
 127    AC_DEFINE(DISABLE_JAVA_NET)
 128 fi
 129
 130 dnl If the target is an eCos system, use the appropriate eCos
 131 dnl I/O routines.
 132 dnl FIXME: this should not be a local option but a global target
 133 dnl system; at present there is no eCos target.
 134 TARGET_ECOS="no"
 135 AC_ARG_WITH(ecos,
 136 [  --with-ecos             enable runtime eCos target support],
 137 TARGET_ECOS="$with_ecos"
 138 )
 139
 140 case "$TARGET_ECOS" in
 141    no)
 142       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 143       PROCESS=${PROCESS-Posix}
 144       ;;
 145    *)
 146       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 147       PROCESS=Ecos
 148       AC_DEFINE(ECOS)
 149       ;;
 150 esac
 151
 152 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 153 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 154 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 155 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 156
 157
 158 dnl These may not be defined in a non-ANS conformant embedded system.
 159 dnl FIXME: Should these case a runtime exception in that case?
 160 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 161 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 162
 163 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 164 dnl to create the link will fail.
 165 test -d java || mkdir java
 166 test -d java/io || mkdir java/io
 167 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 168
 169 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 170 test -d java/lang || mkdir java/lang
 171 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 172 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 173
 174 SYSTEMSPEC=
 175 AC_SUBST(SYSTEMSPEC)
 176
 177 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 178 AC_SUBST(LIBGCJTESTSPEC)
 179
 180 AC_ARG_WITH(system-zlib,
 181 [  --with-system-zlib      use installed libz])
 182 ZLIBSPEC=
 183 AC_SUBST(ZLIBSPEC)
 184 ZLIBTESTSPEC=
 185 AC_SUBST(ZLIBTESTSPEC)
 186
 187 dnl FIXME: this should be _libs on some hosts.
 188 libsubdir=.libs
 189
 190 dnl Allow the GC to be disabled.  Can be useful when debugging.
 191 AC_MSG_CHECKING([for garbage collector to use])
 192 AC_ARG_ENABLE(java-gc,
 193 changequote(<<,>>)dnl
 194 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 195 changequote([,])
 196   GC=$enableval,
 197   GC=boehm)
 198 GCLIBS=
 199 GCINCS=
 200 GCDEPS=
 201 GCOBJS=
 202 GCSPEC=
 203 GCTESTSPEC=
 204 case "$GC" in
 205  boehm)
 206     AC_MSG_RESULT(boehm)
 207     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 208     # We include the path to the boehm-gc build directory.
 209     # See Makefile.am to understand why.
 210     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 211     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 212     GCSPEC='-lgcjgc'
 213     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 214     dnl We also want to pick up some cpp flags required when including
 215     dnl boehm-config.h.  Yuck.
 216     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 217     GCOBJS=boehm.lo
 218     GCHDR=boehm-gc.h
 219     dnl The POSIX thread support needs to know this.
 220     AC_DEFINE(HAVE_BOEHM_GC)
 221     ;;
 222  no)
 223     AC_MSG_RESULT(none)
 224     GCOBJS=nogc.lo
 225     GCHDR=no-gc.h
 226     ;;
 227  *)
 228     AC_MSG_ERROR(unrecognized collector \"$GC\")
 229     ;;
 230 esac
 231 AC_SUBST(GCLIBS)
 232 AC_SUBST(GCINCS)
 233 AC_SUBST(GCDEPS)
 234 AC_SUBST(GCOBJS)
 235 AC_SUBST(GCSPEC)
 236 AC_SUBST(GCTESTSPEC)
 237 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 238
 239
 240 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 241 dnl In particular both packages must make the same decision about which
 242 dnl thread package to use.
 243 AC_MSG_CHECKING([for threads package to use])
 244 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 245   THREADS=$enableval,
 246   dnl FIXME: figure out native threads to use here.
 247   THREADS=no)
 248
 249 if test "$THREADS" = yes; then
 250    case "$host" in
 251     *-*-vxworks*)
 252        THREADS=vxworks
 253        ;;
 254     *-*-linux*)
 255        # FIXME: this isn't correct in all cases.
 256        THREADS=posix
 257        ;;
 258     *-*-win*)
 259        THREADS=win32
 260        ;;
 261     *-*-irix*)
 262        # FIXME: for now, choose POSIX, because we implement that.
 263        # Later, choose irix threads.
 264        THREADS=posix
 265        ;;
 266     *-*-solaris*)
 267        # FIXME: for now, choose POSIX, because we implement that.
 268        # Later, choose solaris threads.
 269        THREADS=posix
 270        ;;
 271     *)
 272        # For now.
 273        THREADS=none
 274        ;;
 275    esac
 276 fi
 277
 278 case "$THREADS" in
 279  no | none | single)
 280     THREADS=none
 281     ;;
 282  posix | pthreads)
 283     THREADS=posix
 284     case "$host" in
 285      *-*-linux*)
 286         AC_DEFINE(LINUX_THREADS)
 287         ;;
 288     esac
 289     ;;
 290  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 291     AC_MSG_ERROR(thread package $THREADS not yet supported)
 292     ;;
 293  *)
 294     AC_MSG_ERROR($THREADS is an unknown thread package)
 295     ;;
 296 esac
 297 AC_MSG_RESULT($THREADS)
 298
 299 THREADLIBS=
 300 THREADINCS=
 301 THREADDEPS=
 302 THREADOBJS=
 303 THREADH=
 304 THREADSPEC=
 305 case "$THREADS" in
 306  posix)
 307     THREADLIBS=-lpthread
 308     THREADSPEC=-lpthread
 309     THREADOBJS=posix-threads.lo
 310     THREADH=posix-threads.h
 311     # MIT pthreads doesn't seem to have the mutexattr functions.
 312     # But for now we don't check for it.  We just assume you aren't
 313     # using MIT pthreads.
 314     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 315     ;;
 316
 317  none)
 318     THREADOBJS=no-threads.lo
 319     THREADH=no-threads.h
 320     ;;
 321 esac
 322 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 323 AC_SUBST(THREADLIBS)
 324 AC_SUBST(THREADINCS)
 325 AC_SUBST(THREADDEPS)
 326 AC_SUBST(THREADOBJS)
 327 AC_SUBST(THREADSPEC)
 328
 329 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 330
 331 CANADIAN=no
 332 NULL_TARGET=no
 333 NATIVE=yes
 334
 335 # Find eh-common.h and support headers.  If we're in the tree with
 336 # gcc, then look there.  Otherwise look in compat-include.  If all else
 337 # fails, just hope the user has set things up somehow.
 338 if test -r $srcdir/../gcc/eh-common.h; then
 339    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 340 else
 341    if test -d $srcdir/../compat-include; then
 342       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 343    else
 344       EH_COMMON_INCLUDE=
 345    fi
 346 fi
 347
 348 if test -n "${with_cross_host}"; then
 349    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 350    # may not work correctly, because the compiler may not be able to
 351    # link executables.
 352
 353    # We assume newlib.  This lets us hard-code the functions we know
 354    # we'll have.
 355    AC_DEFINE(HAVE_MEMMOVE)
 356    AC_DEFINE(HAVE_MEMCPY)
 357    AC_DEFINE(HAVE_STRERROR)
 358    AC_DEFINE(HAVE_GMTIME_R)
 359    AC_DEFINE(HAVE_LOCALTIME_R)
 360    dnl This is only for POSIX threads.
 361    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 362    dnl We also assume we are using gcc, which provides alloca.
 363    AC_DEFINE(HAVE_ALLOCA)
 364
 365    dnl Assume we do not have getuid and friends.
 366    AC_DEFINE(NO_GETUID)
 367
 368    ZLIBSPEC=-lzgcj
 369    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 370
 371    # If Canadian cross, then don't pick up tools from the build
 372    # directory.
 373    if test "$build" != "$with_cross_host"; then
 374       CANADIAN=yes
 375       EH_COMMON_INCLUDE=
 376       GCJ="${target_alias}-gcj"
 377    else
 378       GCJ=
 379    fi
 380    NATIVE=no
 381 else
 382    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 383    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 384    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath iconv)
 385    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 386    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 387    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 388    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 389    AC_CHECK_LIB(dl, dladdr, [
 390      AC_DEFINE(HAVE_DLADDR)])
 391    AC_CHECK_FILES(/proc/self/exe, [
 392      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 393
 394    AC_CHECK_FUNCS(gethostbyname_r, [
 395      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 396      # There are two different kinds of gethostbyname_r.
 397      # We look for the one that returns `int'.
 398      # Hopefully this check is robust enough.
 399      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 400        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 401
 402      case " $GCINCS " in
 403      *" -D_REENTRANT "*) ;;
 404      *)
 405         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 406         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 407         [libjava_cv_gethostbyname_r_needs_reentrant],
 408         [ AC_LANG_SAVE
 409           AC_LANG_CPLUSPLUS
 410           AC_TRY_COMPILE([#include <netdb.h>],
 411             [gethostbyname_r("", 0, 0);],
 412             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 413                 CPPFLAGS_SAVE="$CPPFLAGS"
 414                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 415                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 416                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 417                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 418                 CPPFLAGS="$CPPFLAGS_SAVE"
 419           ])
 420           AC_LANG_RESTORE
 421         ])
 422         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 423           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 424         fi
 425      ;;
 426      esac
 427
 428      AC_CACHE_CHECK([for struct hostent_data],
 429         [libjava_cv_struct_hostent_data], [dnl
 430         AC_TRY_COMPILE([
 431 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 432 # define _REENTRANT 1
 433 #endif
 434 #include <netdb.h>], [struct hostent_data data;],
 435           [libjava_cv_struct_hostent_data=yes],
 436           [libjava_cv_struct_hostent_data=no])])
 437      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 438        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 439          [Define if struct hostent_data is defined in netdb.h])
 440      fi
 441    ])
 442
 443    AC_CHECK_FUNCS(gethostbyaddr_r, [
 444      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 445      # There are two different kinds of gethostbyaddr_r.
 446      # We look for the one that returns `int'.
 447      # Hopefully this check is robust enough.
 448      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 449        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 450
 451    AC_CHECK_FUNCS(gethostname, [
 452      AC_DEFINE(HAVE_GETHOSTNAME)
 453      AC_EGREP_HEADER(gethostname, unistd.h, [
 454        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 455
 456    # Look for these functions in the thread library, but only bother
 457    # if using POSIX threads.
 458    if test "$THREADS" = posix; then
 459       save_LIBS="$LIBS"
 460       LIBS="$LIBS $THREADLIBS"
 461       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 462       # E.g., Solaris.
 463       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 464
 465       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 466       # Solaris 7 the name librt is preferred.
 467       AC_CHECK_FUNCS(sched_yield, , [
 468         AC_CHECK_LIB(rt, sched_yield, [
 469           AC_DEFINE(HAVE_SCHED_YIELD)
 470           THREADLIBS="$THREADLIBS -lrt"
 471           THREADSPEC="$THREADSPEC -lrt"], [
 472           AC_CHECK_LIB(posix4, sched_yield, [
 473             AC_DEFINE(HAVE_SCHED_YIELD)
 474             THREADLIBS="$THREADLIBS -lposix4"
 475             THREADSPEC="$THREADSPEC -lposix4"])])])
 476       LIBS="$save_LIBS"
 477
 478       # We can save a little space at runtime if the mutex has m_count
 479       # or __m_count.  This is a nice hack for Linux.
 480       AC_TRY_COMPILE([#include <pthread.h>], [
 481           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 482         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 483         AC_TRY_COMPILE([#include <pthread.h>], [
 484             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 485           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 486    fi
 487
 488    # We require a way to get the time.
 489    time_found=no
 490    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 491    if test "$time_found" = no; then
 492       AC_MSG_ERROR([no function found to get the time])
 493    fi
 494
 495    AC_CHECK_FUNCS(memmove)
 496
 497    # We require memcpy.
 498    memcpy_found=no
 499    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 500    if test "$memcpy_found" = no; then
 501       AC_MSG_ERROR([memcpy is required])
 502    fi
 503
 504    # Some library-finding code we stole from Tcl.
 505    #--------------------------------------------------------------------
 506    #    Check for the existence of the -lsocket and -lnsl libraries.
 507    #    The order here is important, so that they end up in the right
 508    #    order in the command line generated by make.  Here are some
 509    #    special considerations:
 510    #    1. Use "connect" and "accept" to check for -lsocket, and
 511    #       "gethostbyname" to check for -lnsl.
 512    #    2. Use each function name only once:  can't redo a check because
 513    #       autoconf caches the results of the last check and won't redo it.
 514    #    3. Use -lnsl and -lsocket only if they supply procedures that
 515    #       aren't already present in the normal libraries.  This is because
 516    #       IRIX 5.2 has libraries, but they aren't needed and they're
 517    #       bogus:  they goof up name resolution if used.
 518    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 519    #       To get around this problem, check for both libraries together
 520    #       if -lsocket doesn't work by itself.
 521    #--------------------------------------------------------------------
 522
 523    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 524     [gcj_cv_lib_sockets=
 525      gcj_checkBoth=0
 526      unset ac_cv_func_connect
 527      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 528      if test "$gcj_checkSocket" = 1; then
 529          unset ac_cv_func_connect
 530          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 531                       gcj_checkBoth=1)
 532      fi
 533      if test "$gcj_checkBoth" = 1; then
 534          gcj_oldLibs=$LIBS
 535          LIBS="$LIBS -lsocket -lnsl"
 536          unset ac_cv_func_accept
 537          AC_CHECK_FUNC(accept,
 538                        [gcj_checkNsl=0
 539                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 540          unset ac_cv_func_accept
 541          LIBS=$gcj_oldLibs
 542      fi
 543      unset ac_cv_func_gethostbyname
 544      gcj_oldLibs=$LIBS
 545      LIBS="$LIBS $gcj_cv_lib_sockets"
 546      AC_CHECK_FUNC(gethostbyname, ,
 547                    [AC_CHECK_LIB(nsl, main,
 548                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 549      unset ac_cv_func_gethostbyname
 550      LIBS=$gcj_oldLIBS
 551    ])
 552    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 553
 554    if test "$with_system_zlib" = yes; then
 555       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 556    else
 557       ZLIBSPEC=-lzgcj
 558       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 559    fi
 560
 561    # On Solaris, and maybe other architectures, the Boehm collector
 562    # requires -ldl.
 563    if test "$GC" = boehm; then
 564       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 565    fi
 566
 567    if test -d "$libgcj_basedir/../gcc/java"; then
 568       GCJ=
 569    else
 570       CANADIAN=yes
 571       NULL_TARGET=yes
 572       GCJ=gcj
 573    fi
 574 fi
 575
 576 ZLIBS=
 577 ZDEPS=
 578 ZINCS=
 579 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 580    # We include the path to the zlib build directory.
 581    # See Makefile.am to understand why.
 582    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 583    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 584    ZINCS='-I$(top_srcdir)/../zlib'
 585 else
 586    ZLIBS="$ZLIBSPEC"
 587 fi
 588 AC_SUBST(ZLIBS)
 589 AC_SUBST(ZDEPS)
 590 AC_SUBST(ZINCS)
 591 AC_SUBST(DIVIDESPEC)
 592 AC_SUBST(EXCEPTIONSPEC)
 593 AC_SUBST(FORCELIBGCCSPEC)
 594
 595 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 596 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 597 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 598 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 599 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 600 AC_SUBST(EH_COMMON_INCLUDE)
 601
 602 # Determine gcj version number.
 603 if test "$GCJ" = ""; then
 604    if test -z "${with_multisubdir}"; then
 605       builddotdot=.
 606    else
 607 changequote(<<,>>)
 608       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 609 changequote([,])
 610    fi
 611    dir="`cd ${builddotdot}/../../gcc && pwd`"
 612    GCJ="$dir/gcj -B$dir/"
 613 fi
 614 changequote(<<,>>)
 615 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 616 changequote([,])
 617 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 618
 619 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 620 # we want to continue to support that version.
 621 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 622 cat > conftest.java << 'END'
 623 public class conftest { }
 624 END
 625 use_fuse=yes
 626 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 627    conftest.java > /dev/null 2>&1 \
 628    || use_fuse=no
 629 rm -f conftest.java
 630 if test "$use_fuse" = no; then
 631    DIVIDESPEC=
 632 fi
 633 AC_MSG_RESULT($use_fuse)
 634
 635 AC_SUBST(AM_RUNTESTFLAGS)
 636
 637 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 638 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 639 save_CFLAGS="$CFLAGS"
 640 CFLAGS="-x c++ -O2 -ffloat-store"
 641 AC_TRY_COMPILE([#include <math.h>], ,
 642   [AC_MSG_RESULT(no)],
 643   [AC_DEFINE(__NO_MATH_INLINES)
 644    AC_MSG_RESULT(yes)])
 645 CFLAGS="$save_CFLAGS"
 646
 647 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 648 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 649 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 650 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 651 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 652 dnl for now.  If you change this, you also must update natFile.cc.
 653 AC_CHECK_HEADERS(dirent.h)
 654
 655 AC_CHECK_TYPE([ssize_t], [int])
 656
 657 AC_MSG_CHECKING([for in_addr_t])
 658 AC_TRY_COMPILE([#include <sys/types.h>
 659 #if STDC_HEADERS
 660 #include <stdlib.h>
 661 #include <stddef.h>
 662 #endif
 663 #if HAVE_NETINET_IN_H
 664 #include <netinet/in.h>
 665 #endif], [in_addr_t foo;],
 666   [AC_DEFINE([HAVE_IN_ADDR_T])
 667    AC_MSG_RESULT(yes)],
 668   [AC_MSG_RESULT(no)])
 669
 670 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 671 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 672   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 673    AC_MSG_RESULT(yes)],
 674   [AC_MSG_RESULT(no)])
 675
 676 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 677 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 678   [AC_DEFINE(HAVE_INET6)
 679    AC_MSG_RESULT(yes)],
 680   [AC_MSG_RESULT(no)])
 681
 682 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 683 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 684   [AC_DEFINE(HAVE_SOCKLEN_T)
 685    AC_MSG_RESULT(yes)],
 686   [AC_MSG_RESULT(no)])
 687
 688 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 689 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 690   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 691    AC_MSG_RESULT(yes)],
 692   [AC_MSG_RESULT(no)
 693    AC_MSG_CHECKING([for global timezone variable])
 694    dnl FIXME: we don't want a link check here because that won't work
 695    dnl when cross-compiling.  So instead we make an assumption that
 696    dnl the header file will mention timezone if it exists.
 697    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 698      [AC_DEFINE(HAVE_TIMEZONE)
 699       AC_MSG_RESULT(yes)],
 700      [AC_MSG_RESULT(no)])])
 701
 702 AC_FUNC_ALLOCA
 703
 704 AC_CHECK_PROGS(PERL, perl, false)
 705
 706 if test "$enable_sjlj_exceptions" = yes; then
 707    SIGNAL_HANDLER=include/default-signal.h
 708 else
 709    case "${host}" in
 710     i?86-*-linux*)
 711        SIGNAL_HANDLER=include/i386-signal.h
 712        ;;
 713     sparc-sun-solaris*)
 714        SIGNAL_HANDLER=include/sparc-signal.h
 715        ;;
 716     *)
 717        SIGNAL_HANDLER=include/default-signal.h
 718        ;;
 719    esac
 720 fi
 721
 722 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 723
 724 if test "${multilib}" = "yes"; then
 725   multilib_arg="--enable-multilib"
 726 else
 727   multilib_arg=
 728 fi
 729
 730 here=`pwd`
 731 AC_SUBST(here)
 732
 733 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gcj/Makefile include/Makefile testsuite/Makefile,
 734 [if test -n "$CONFIG_FILES"; then
 735   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 736 fi],
 737 srcdir=${srcdir}
 738 host=${host}
 739 target=${target}
 740 with_multisubdir=${with_multisubdir}
 741 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 742 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 743 libgcj_basedir=${libgcj_basedir}
 744 CC="${CC}"
 745 CXX="${CXX}"
 746 )