libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
  12 AC_ARG_WITH(cross-host,
  13 [  --with-cross-host=HOST           Configuring with a cross compiler])
  14
  15 LIBGCJ_CONFIGURE(.)
  16
  17 AM_CONFIG_HEADER(include/config.h)
  18
  19 AM_PROG_LIBTOOL
  20
  21 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  22    COMPPATH=.
  23 else
  24    COMPPATH=..
  25 fi
  26 AC_SUBST(COMPPATH)
  27
  28 dnl The -no-testsuite modules omit the test subdir.
  29 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  30
  31 dnl See whether the user prefers size or speed for Character.
  32 dnl The default is size.
  33 AC_ARG_ENABLE(fast-character,
  34 [  --enable-fast-character          Prefer speed over size for Character],
  35 # Nothing
  36 , AC_DEFINE(COMPACT_CHARACTER))
  37
  38 dnl See if the user has requested runtime debugging.
  39 AC_ARG_ENABLE(libgcj-debug,
  40 [  --enable-libgcj-debug           Enable runtime debugging code],
  41   if test "$enable_libgcj_debug" = yes; then
  42      AC_DEFINE(DEBUG)
  43   fi)
  44
  45 dnl If the target is an eCos system, use the appropriate eCos
  46 dnl I/O routines.
  47 dnl FIXME: this should not be a local option but a global target
  48 dnl system; at present there is no eCos target.
  49 TARGET_ECOS="no"
  50 AC_ARG_WITH(ecos,
  51 [  --with-ecos      Enable runtime eCos target support.],
  52 TARGET_ECOS="$with_ecos"
  53 )
  54
  55 case "$TARGET_ECOS" in
  56    no)
  57       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
  58       PROCESS=Posix
  59       ;;
  60    *)
  61       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
  62       PROCESS=Ecos
  63       AC_DEFINE(ECOS)
  64       ;;
  65 esac
  66
  67 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
  68 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
  69 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
  70 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
  71
  72
  73 dnl These may not be defined in a non-ANS conformant embedded system.
  74 dnl FIXME: Should these case a runtime exception in that case?
  75 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
  76 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
  77
  78 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
  79 dnl to create the link will fail.
  80 test -d java || mkdir java
  81 test -d java/io || mkdir java/io
  82 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
  83
  84 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
  85 test -d java/lang || mkdir java/lang
  86 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
  87 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
  88
  89 SYSTEMSPEC=
  90 AC_SUBST(SYSTEMSPEC)
  91
  92 AC_ARG_WITH(system-zlib,
  93 [  --with-system-zlib               Use installed libz])
  94 ZLIBSPEC=
  95 AC_SUBST(ZLIBSPEC)
  96
  97 dnl FIXME: this should be _libs on some hosts.
  98 libsubdir=.libs
  99
 100 dnl Allow the GC to be disabled.  Can be useful when debugging.
 101 AC_MSG_CHECKING([for garbage collector to use])
 102 AC_ARG_ENABLE(java-gc,
 103 changequote(<<,>>)dnl
 104 <<  --enable-java-gc=TYPE    choose garbage collector [boehm]>>,
 105 changequote([,])
 106   GC=$enableval,
 107   GC=boehm)
 108 GCLIBS=
 109 GCINCS=
 110 GCDEPS=
 111 GCOBJS=
 112 GCSPEC=
 113 case "$GC" in
 114  boehm)
 115     AC_MSG_RESULT(boehm)
 116     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 117     # We include the path to the boehm-gc build directory.
 118     # See Makefile.am to understand why.
 119     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 120     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 121     GCSPEC='-lgcjgc'
 122     dnl We also want to pick up some cpp flags required when including
 123     dnl boehm-config.h.  Yuck.
 124     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 125     GCOBJS=boehm.lo
 126     GCHDR=boehm-gc.h
 127     dnl The POSIX thread support needs to know this.
 128     AC_DEFINE(HAVE_BOEHM_GC)
 129     ;;
 130  no)
 131     AC_MSG_RESULT(none)
 132     GCOBJS=nogc.lo
 133     GCHDR=no-gc.h
 134     ;;
 135  *)
 136     AC_MSG_ERROR(unrecognized collector \"$GC\")
 137     ;;
 138 esac
 139 AC_SUBST(GCLIBS)
 140 AC_SUBST(GCINCS)
 141 AC_SUBST(GCDEPS)
 142 AC_SUBST(GCOBJS)
 143 AC_SUBST(GCSPEC)
 144 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 145
 146
 147 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 148 dnl In particular both packages must make the same decision about which
 149 dnl thread package to use.
 150 AC_MSG_CHECKING([for threads package to use])
 151 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE    choose threading package],
 152   THREADS=$enableval,
 153   dnl FIXME: figure out native threads to use here.
 154   THREADS=no)
 155
 156 if test "$THREADS" = yes; then
 157    case "$host" in
 158     *-*-vxworks*)
 159        THREADS=vxworks
 160        ;;
 161     *-*-linux*)
 162        # FIXME: this isn't correct in all cases.
 163        THREADS=posix
 164        ;;
 165     *-*-win*)
 166        THREADS=win32
 167        ;;
 168     *-*-irix*)
 169        # FIXME: for now, choose POSIX, because we implement that.
 170        # Later, choose irix threads.
 171        THREADS=posix
 172        ;;
 173     *-*-solaris*)
 174        # FIXME: for now, choose POSIX, because we implement that.
 175        # Later, choose solaris threads.
 176        THREADS=posix
 177        ;;
 178     *)
 179        # For now.
 180        THREADS=none
 181        ;;
 182    esac
 183 fi
 184
 185 case "$THREADS" in
 186  no | none | single)
 187     THREADS=none
 188     ;;
 189  posix | pthreads)
 190     THREADS=posix
 191     case "$host" in
 192      *-*-linux*)
 193         AC_DEFINE(LINUX_THREADS)
 194         ;;
 195     esac
 196     ;;
 197  qt)
 198     ;;
 199  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 200     AC_MSG_ERROR(thread package $THREADS not yet supported)
 201     ;;
 202  *)
 203     AC_MSG_ERROR($THREADS is an unknown thread package)
 204     ;;
 205 esac
 206 AC_MSG_RESULT($THREADS)
 207
 208 THREADLIBS=
 209 THREADINCS=
 210 THREADDEPS=
 211 THREADOBJS=
 212 THREADH=
 213 THREADSPEC=
 214 case "$THREADS" in
 215  posix)
 216     THREADLIBS=-lpthread
 217     THREADSPEC=-lpthread
 218     THREADOBJS=posix-threads.lo
 219     THREADH=posix-threads.h
 220     # MIT pthreads doesn't seem to have the mutexattr functions.
 221     # But for now we don't check for it.  We just assume you aren't
 222     # using MIT pthreads.
 223     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 224     ;;
 225
 226  qt)
 227     THREADDEPS='$(top_builddir)/../qthreads/libgcjcoop.la'
 228     # We include the path to the qthreads build directory.
 229     # See Makefile.am to understand why.
 230     THREADLIBS="$THREADDEPS -L\$(here)/../qthreads/$libsubdir"
 231     THREADSPEC='-lgcjcoop'
 232     THREADOBJS=quick-threads.lo
 233     THREADINCS='-I$(top_srcdir)/../qthreads'
 234     THREADH=quick-threads.h
 235     ;;
 236
 237  none)
 238     THREADOBJS=no-threads.lo
 239     THREADH=no-threads.h
 240     ;;
 241 esac
 242 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 243 AC_SUBST(THREADLIBS)
 244 AC_SUBST(THREADINCS)
 245 AC_SUBST(THREADDEPS)
 246 AC_SUBST(THREADOBJS)
 247 AC_SUBST(THREADSPEC)
 248
 249 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 250
 251 CANADIAN=no
 252 NULL_TARGET=no
 253
 254 # Find eh-common.h and support headers.  If we're in the tree with
 255 # gcc, then look there.  Otherwise look in compat-include.  If all else
 256 # fails, just hope the user has set things up somehow.
 257 if test -r $srcdir/../gcc/eh-common.h; then
 258    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 259 else
 260    if test -d $srcdir/../compat-include; then
 261       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 262    else
 263       EH_COMMON_INCLUDE=
 264    fi
 265 fi
 266
 267 if test -n "${with_cross_host}"; then
 268    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 269    # may not work correctly, because the compiler may not be able to
 270    # link executables.
 271
 272    # We assume newlib.  This lets us hard-code the functions we know
 273    # we'll have.
 274    AC_DEFINE(HAVE_MEMMOVE)
 275    AC_DEFINE(HAVE_MEMCPY)
 276    AC_DEFINE(HAVE_STRERROR)
 277    AC_DEFINE(HAVE_CTIME_R)
 278    AC_DEFINE(HAVE_GMTIME_R)
 279    AC_DEFINE(HAVE_LOCALTIME_R)
 280    dnl This is only for POSIX threads.
 281    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 282    dnl We also assume we are using gcc, which provides alloca.
 283    AC_DEFINE(HAVE_ALLOCA)
 284
 285    ZLIBSPEC=-lgcj
 286
 287    # If Canadian cross, then don't pick up tools from the build
 288    # directory.
 289    if test "$build" != "$with_cross_host"; then
 290       CANADIAN=yes
 291       EH_COMMON_INCLUDE=
 292       GCJ="${target_alias}/gcj"
 293    else
 294       GCJ=
 295    fi
 296 else
 297    # Some POSIX thread systems don't have pthread_mutexattr_settype.
 298    # E.g., Solaris.
 299    AC_CHECK_FUNCS(strerror ioctl select open fsync sleep)
 300    AC_CHECK_FUNCS(ctime_r ctime, break)
 301    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r)
 302    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 303    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 304    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 305
 306    AC_CHECK_FUNCS(gethostbyname_r, [
 307      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 308      # There are two different kinds of gethostbyname_r.
 309      # We look for the one that returns `int'.
 310      # Hopefully this check is robust enough.
 311      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 312        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 313
 314      case " $GCINCS " in
 315      *" -D_REENTRANT "*) ;;
 316      *)
 317         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 318         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 319         [libjava_cv_gethostbyname_r_needs_reentrant],
 320         [ AC_LANG_SAVE
 321           AC_LANG_CPLUSPLUS
 322           AC_TRY_COMPILE([#include <netdb.h>],
 323             [gethostbyname_r("", 0, 0);],
 324             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 325                 CPPFLAGS_SAVE="$CPPFLAGS"
 326                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 327                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 328                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 329                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 330                 CPPFLAGS="$CPPFLAGS_SAVE"
 331           ])
 332           AC_LANG_RESTORE
 333         ])
 334         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 335           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 336         fi
 337      ;;
 338      esac
 339
 340      AC_CACHE_CHECK([for struct hostent_data],
 341         [libjava_cv_struct_hostent_data], [dnl
 342         AC_TRY_COMPILE([
 343 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 344 # define _REENTRANT 1
 345 #endif
 346 #include <netdb.h>], [struct hostent_data data;],
 347           [libjava_cv_struct_hostent_data=yes],
 348           [libjava_cv_struct_hostent_data=no])])
 349      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 350        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 351          [Define if struct hostent_data is defined in netdb.h])
 352      fi
 353    ])
 354
 355    AC_CHECK_FUNCS(gethostbyaddr_r, [
 356      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 357      # There are two different kinds of gethostbyaddr_r.
 358      # We look for the one that returns `int'.
 359      # Hopefully this check is robust enough.
 360      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 361        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 362
 363    AC_CHECK_FUNCS(gethostname, [
 364      AC_DEFINE(HAVE_GETHOSTNAME)
 365      AC_EGREP_HEADER(gethostname, unistd.h, [
 366        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 367
 368    # Look for these functions in the thread library.
 369    save_LIBS="$LIBS"
 370    LIBS="$LIBS $THREADLIBS"
 371    AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np sched_yield)
 372    # Look for sched_yield.  Sometimes it is in the posix4 library.
 373    AC_CHECK_FUNCS(sched_yield, , [
 374      AC_CHECK_LIB(posix4, sched_yield, [
 375        AC_DEFINE(HAVE_SCHED_YIELD)
 376        THREADLIBS="$THREADLIBS -lposix4"])])
 377    LIBS="$save_LIBS"
 378
 379    # We require a way to get the time.
 380    time_found=no
 381    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 382    if test "$time_found" = no; then
 383       AC_MSG_ERROR([no function found to get the time])
 384    fi
 385
 386    AC_CHECK_FUNCS(memmove)
 387
 388    # We require memcpy.
 389    memcpy_found=no
 390    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 391    if test "$memcpy_found" = no; then
 392       AC_MSG_ERROR([memcpy is required])
 393    fi
 394
 395    # Some library-finding code we stole from Tcl.
 396    #--------------------------------------------------------------------
 397    #    Check for the existence of the -lsocket and -lnsl libraries.
 398    #    The order here is important, so that they end up in the right
 399    #    order in the command line generated by make.  Here are some
 400    #    special considerations:
 401    #    1. Use "connect" and "accept" to check for -lsocket, and
 402    #       "gethostbyname" to check for -lnsl.
 403    #    2. Use each function name only once:  can't redo a check because
 404    #       autoconf caches the results of the last check and won't redo it.
 405    #    3. Use -lnsl and -lsocket only if they supply procedures that
 406    #       aren't already present in the normal libraries.  This is because
 407    #       IRIX 5.2 has libraries, but they aren't needed and they're
 408    #       bogus:  they goof up name resolution if used.
 409    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 410    #       To get around this problem, check for both libraries together
 411    #       if -lsocket doesn't work by itself.
 412    #--------------------------------------------------------------------
 413
 414    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 415     [gcj_cv_lib_sockets=
 416      gcj_checkBoth=0
 417      unset ac_cv_func_connect
 418      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 419      if test "$gcj_checkSocket" = 1; then
 420          unset ac_cv_func_connect
 421          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 422                       gcj_checkBoth=1)
 423      fi
 424      if test "$gcj_checkBoth" = 1; then
 425          gcj_oldLibs=$LIBS
 426          LIBS="$LIBS -lsocket -lnsl"
 427          unset ac_cv_func_accept
 428          AC_CHECK_FUNC(accept,
 429                        [gcj_checkNsl=0
 430                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 431          unset ac_cv_func_accept
 432          LIBS=$gcj_oldLibs
 433      fi
 434      unset ac_cv_func_gethostbyname
 435      gcj_oldLibs=$LIBS
 436      LIBS="$LIBS $gcj_cv_lib_sockets"
 437      AC_CHECK_FUNC(gethostbyname, ,
 438                    [AC_CHECK_LIB(nsl, main,
 439                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 440      unset ac_cv_func_gethostbyname
 441      LIBS=$gcj_oldLIBS
 442    ])
 443    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 444
 445    if test "$with_system_zlib" = yes; then
 446       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 447    else
 448       ZLIBSPEC=-lzgcj
 449    fi
 450
 451    # On Solaris, and maybe other architectures, the Boehm collector
 452    # requires -ldl.
 453    if test "$GC" = boehm; then
 454       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 455    fi
 456
 457    if test -d "$libgcj_basedir/../gcc/java"; then
 458       GCJ=
 459    else
 460       CANADIAN=yes
 461       NULL_TARGET=yes
 462       GCJ=gcj
 463    fi
 464 fi
 465
 466 ZLIBS=
 467 ZDEPS=
 468 ZINCS=
 469 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 470    # We include the path to the zlib build directory.
 471    # See Makefile.am to understand why.
 472    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 473    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 474    ZINCS='-I$(top_srcdir)/../zlib'
 475 else
 476    ZLIBS="$ZLIBSPEC"
 477 fi
 478 AC_SUBST(ZLIBS)
 479 AC_SUBST(ZDEPS)
 480 AC_SUBST(ZINCS)
 481
 482 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 483 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 484 AM_CONDITIONAL(NATIVE, test "$CANADIAN" = no || test "$NULL_TARGET" = yes)
 485 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 486 AC_SUBST(EH_COMMON_INCLUDE)
 487
 488 # Determine gcj version number.
 489 if test "$GCJ" = ""; then
 490    if test -z "${with_multisubdir}"; then
 491       builddotdot=.
 492    else
 493       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 494    fi
 495    dir="`cd ${builddotdot}/../../gcc && pwd`"
 496    GCJ="$dir/gcj -B$dir/"
 497 fi
 498 changequote(<<,>>)
 499 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 500 changequote([,])
 501 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 502
 503 AC_SUBST(AM_RUNTESTFLAGS)
 504
 505 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 506 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 507 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 508 AC_CHECK_HEADERS(unistd.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 509 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 510 dnl for now.  If you change this, you also must update natFile.cc.
 511 AC_CHECK_HEADERS(dirent.h)
 512
 513 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 514 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 515   [AC_DEFINE(HAVE_INET6)
 516    AC_MSG_RESULT(yes)],
 517   [AC_MSG_RESULT(no)])
 518
 519 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 520 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 521   [AC_DEFINE(HAVE_SOCKLEN_T)
 522    AC_MSG_RESULT(yes)],
 523   [AC_MSG_RESULT(no)])
 524
 525 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 526 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 527   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 528    AC_MSG_RESULT(yes)],
 529   [AC_MSG_RESULT(no)
 530    AC_MSG_CHECKING([for global timezone variable])
 531    dnl FIXME: we don't want a link check here because that won't work
 532    dnl when cross-compiling.  So instead we make an assumption that
 533    dnl the header file will mention timezone if it exists.
 534    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 535      [AC_DEFINE(HAVE_TIMEZONE)
 536       AC_MSG_RESULT(yes)],
 537      [AC_MSG_RESULT(no)])])
 538
 539 AC_FUNC_ALLOCA
 540
 541 AC_CHECK_PROGS(PERL, perl, false)
 542
 543 case "${host}" in
 544   i?86-*-linux*)
 545     SIGNAL_HANDLER=include/i386-signal.h
 546         ;;
 547   sparc-sun-solaris*)
 548     SIGNAL_HANDLER=include/sparc-signal.h
 549         ;;
 550   *)
 551     SIGNAL_HANDLER=include/default-signal.h
 552         ;;
 553 esac
 554
 555 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 556
 557 if test "${multilib}" = "yes"; then
 558   multilib_arg="--enable-multilib"
 559 else
 560   multilib_arg=
 561 fi
 562
 563 here=`pwd`
 564 AC_SUBST(here)
 565
 566 AC_OUTPUT(Makefile libgcj.spec testsuite/Makefile,
 567 [if test -n "$CONFIG_FILES"; then
 568   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 569 fi],
 570 srcdir=${srcdir}
 571 host=${host}
 572 target=${target}
 573 with_multisubdir=${with_multisubdir}
 574 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 575 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 576 libgcj_basedir=${libgcj_basedir}
 577 CC="${CC}"
 578 CXX="${CXX}"
 579 )