libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -n "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67 dnl See if the user has requested runtime debugging.
  68 LIBGCJDEBUG="false"
  69 AC_SUBST(LIBGCJDEBUG)
  70 AC_ARG_ENABLE(libgcj-debug,
  71 [  --enable-libgcj-debug   enable runtime debugging code],
  72   if test "$enable_libgcj_debug" = yes; then
  73     AC_DEFINE(DEBUG)
  74     LIBGCJDEBUG="true"
  75   fi)
  76
  77 dnl See if the user has the interpreter included.
  78 AC_ARG_ENABLE(interpreter,
  79 [  --enable-interpreter    enable interpreter],
  80   if test "$enable_interpreter" = yes; then
  81     # This can also be set in configure.host.
  82     libgcj_interpreter=yes
  83   elif test "$enable_interpreter" = no; then
  84     libgcj_interpreter=no
  85   fi)
  86
  87 if test "$libgcj_interpreter" = yes; then
  88    AC_DEFINE(INTERPRETER)
  89 fi
  90
  91 AC_MSG_CHECKING([for exception model to use])
  92 AC_LANG_SAVE
  93 AC_LANG_CPLUSPLUS
  94 AC_ARG_ENABLE(sjlj-exceptions,
  95 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
  96 [:],
  97 [dnl Botheration.  Now we've got to detect the exception model.
  98 dnl Link tests against libgcc.a are problematic since -- at least
  99 dnl as of this writing -- we've not been given proper -L bits for
 100 dnl single-tree newlib and libgloss.
 101 dnl
 102 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 103 dnl conftest files before we got a change to grep them first.
 104 cat > conftest.$ac_ext << EOF
 105 [#]line __oline__ "configure"
 106 struct S { ~S(); };
 107 void bar();
 108 void foo()
 109 {
 110   S s;
 111   bar();
 112 }
 113 EOF
 114 old_CXXFLAGS="$CXXFLAGS"
 115 CXXFLAGS=-S
 116 if AC_TRY_EVAL(ac_compile); then
 117   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 118     enable_sjlj_exceptions=yes
 119   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 120     enable_sjlj_exceptions=no
 121   fi
 122 fi
 123 CXXFLAGS="$old_CXXFLAGS"
 124 rm -f conftest*])
 125 if test x$enable_sjlj_exceptions = xyes; then
 126   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 127         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 128   ac_exception_model_name=sjlj
 129 elif test x$enable_sjlj_exceptions = xno; then
 130   ac_exception_model_name="call frame"
 131 else
 132   AC_MSG_ERROR([unable to detect exception model])
 133 fi
 134 AC_LANG_RESTORE
 135 AC_MSG_RESULT($ac_exception_model_name)
 136
 137 AC_MSG_CHECKING([for data_start])
 138 LIBDATASTARTSPEC=
 139 NEEDS_DATA_START=
 140 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 141   [AC_MSG_RESULT(found it)],
 142   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 143    NEEDS_DATA_START=yes
 144    AC_MSG_RESULT(missing)])
 145 AC_SUBST(LIBDATASTARTSPEC)
 146
 147 dnl See if the user wants to disable java.net.  This is the mildly
 148 dnl ugly way that we admit that target-side configuration sucks.
 149 AC_ARG_ENABLE(java-net,
 150 [  --disable-java-net      disable java.net])
 151
 152 dnl Whether java.net is built by default can depend on the target.
 153 if test -n "$enable_java_net"; then
 154    enable_java_net=${enable_java_net_default-yes}
 155 fi
 156 if test "$enable_java_net" = no; then
 157    AC_DEFINE(DISABLE_JAVA_NET)
 158 fi
 159
 160 dnl See if the user wants to disable JVMPI support.
 161 AC_ARG_ENABLE(jvmpi,
 162 [  --disable-jvmpi         disable JVMPI support])
 163
 164 if test "$enable_jvmpi" != no; then
 165     AC_DEFINE(ENABLE_JVMPI)
 166 fi
 167
 168 dnl If the target is an eCos system, use the appropriate eCos
 169 dnl I/O routines.
 170 dnl FIXME: this should not be a local option but a global target
 171 dnl system; at present there is no eCos target.
 172 TARGET_ECOS="no"
 173 AC_ARG_WITH(ecos,
 174 [  --with-ecos             enable runtime eCos target support],
 175 TARGET_ECOS="$with_ecos"
 176 )
 177
 178 case "$TARGET_ECOS" in
 179    no)
 180       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 181       PROCESS=${PROCESS-Posix}
 182       ;;
 183    *)
 184       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 185       PROCESS=Ecos
 186       AC_DEFINE(ECOS)
 187       ;;
 188 esac
 189
 190 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 191 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 192 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 193 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 194
 195
 196 dnl These may not be defined in a non-ANS conformant embedded system.
 197 dnl FIXME: Should these case a runtime exception in that case?
 198 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 199 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 200
 201 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 202 dnl to create the link will fail.
 203 test -d java || mkdir java
 204 test -d java/io || mkdir java/io
 205 test -d gnu || mkdir gnu
 206 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 207
 208 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 209 test -d java/lang || mkdir java/lang
 210 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 211 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 212
 213 SYSTEMSPEC=
 214 AC_SUBST(SYSTEMSPEC)
 215
 216 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 217 AC_SUBST(LIBGCJTESTSPEC)
 218
 219 AC_ARG_WITH(system-zlib,
 220 [  --with-system-zlib      use installed libz])
 221 ZLIBSPEC=
 222 AC_SUBST(ZLIBSPEC)
 223 ZLIBTESTSPEC=
 224 AC_SUBST(ZLIBTESTSPEC)
 225
 226 dnl FIXME: this should be _libs on some hosts.
 227 libsubdir=.libs
 228
 229 dnl Allow the GC to be disabled.  Can be useful when debugging.
 230 AC_MSG_CHECKING([for garbage collector to use])
 231 AC_ARG_ENABLE(java-gc,
 232 changequote(<<,>>)dnl
 233 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 234 changequote([,])
 235   GC=$enableval,
 236   GC=boehm)
 237 GCLIBS=
 238 GCINCS=
 239 GCDEPS=
 240 GCOBJS=
 241 GCSPEC=
 242 JC1GCSPEC=
 243 GCTESTSPEC=
 244 case "$GC" in
 245  boehm)
 246     AC_MSG_RESULT(boehm)
 247     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 248     # We include the path to the boehm-gc build directory.
 249     # See Makefile.am to understand why.
 250     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 251     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 252     GCSPEC='-lgcjgc'
 253     JC1GCSPEC='-fuse-boehm-gc'
 254     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 255     dnl We also want to pick up some cpp flags required when including
 256     dnl boehm-config.h.  Yuck.
 257     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 258     GCOBJS=boehm.lo
 259     GCHDR=boehm-gc.h
 260     dnl The POSIX thread support needs to know this.
 261     AC_DEFINE(HAVE_BOEHM_GC)
 262     ;;
 263  no)
 264     AC_MSG_RESULT(none)
 265     GCOBJS=nogc.lo
 266     GCHDR=no-gc.h
 267     ;;
 268  *)
 269     AC_MSG_ERROR(unrecognized collector \"$GC\")
 270     ;;
 271 esac
 272 AC_SUBST(GCLIBS)
 273 AC_SUBST(GCINCS)
 274 AC_SUBST(GCDEPS)
 275 AC_SUBST(GCOBJS)
 276 AC_SUBST(GCSPEC)
 277 AC_SUBST(JC1GCSPEC)
 278 AC_SUBST(GCTESTSPEC)
 279 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 280
 281
 282 AC_MSG_CHECKING([for thread model used by GCC])
 283 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 284 AC_MSG_RESULT([$THREADS])
 285
 286 case "$THREADS" in
 287  no | none | single)
 288     THREADS=none
 289     ;;
 290  posix | pthreads)
 291     THREADS=posix
 292     case "$host" in
 293      *-*-linux*)
 294         AC_DEFINE(LINUX_THREADS)
 295         ;;
 296     esac
 297     ;;
 298  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 299     AC_MSG_ERROR(thread package $THREADS not yet supported)
 300     ;;
 301  *)
 302     AC_MSG_ERROR($THREADS is an unknown thread package)
 303     ;;
 304 esac
 305
 306 THREADLIBS=
 307 THREADINCS=
 308 THREADDEPS=
 309 THREADOBJS=
 310 THREADH=
 311 THREADSPEC=
 312 case "$THREADS" in
 313  posix)
 314     THREADLIBS=-lpthread
 315     THREADSPEC=-lpthread
 316     THREADOBJS=posix-threads.lo
 317     THREADH=posix-threads.h
 318     # MIT pthreads doesn't seem to have the mutexattr functions.
 319     # But for now we don't check for it.  We just assume you aren't
 320     # using MIT pthreads.
 321     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 322
 323     # If we're using the Boehm GC, then we happen to know that it
 324     # defines _REENTRANT, so we don't bother.  Eww.
 325     if test "$GC" != boehm; then
 326        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 327     fi
 328     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 329     ;;
 330
 331  none)
 332     THREADOBJS=no-threads.lo
 333     THREADH=no-threads.h
 334     ;;
 335 esac
 336 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 337 AC_SUBST(THREADLIBS)
 338 AC_SUBST(THREADINCS)
 339 AC_SUBST(THREADDEPS)
 340 AC_SUBST(THREADOBJS)
 341 AC_SUBST(THREADSPEC)
 342
 343 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 344
 345 CANADIAN=no
 346 NULL_TARGET=no
 347 NATIVE=yes
 348
 349 # We're in the tree with gcc, and need to include some of its headers.
 350 GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../gcc'
 351
 352 if test -n "${with_cross_host}"; then
 353    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 354    # may not work correctly, because the compiler may not be able to
 355    # link executables.
 356
 357    # We assume newlib.  This lets us hard-code the functions we know
 358    # we'll have.
 359    AC_DEFINE(HAVE_MEMMOVE)
 360    AC_DEFINE(HAVE_MEMCPY)
 361    AC_DEFINE(HAVE_STRERROR)
 362    AC_DEFINE(HAVE_GMTIME_R)
 363    AC_DEFINE(HAVE_LOCALTIME_R)
 364    dnl This is only for POSIX threads.
 365    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 366    dnl We also assume we are using gcc, which provides alloca.
 367    AC_DEFINE(HAVE_ALLOCA)
 368
 369    dnl Assume we do not have getuid and friends.
 370    AC_DEFINE(NO_GETUID)
 371
 372    ZLIBSPEC=-lzgcj
 373    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 374
 375    # If Canadian cross, then don't pick up tools from the build
 376    # directory.
 377    if test x"$build" != x"$with_cross_host" && x"$build" != x"$target"; then
 378       CANADIAN=yes
 379       GCC_UNWIND_INCLUDE=
 380       GCJ="${target_alias}-gcj"
 381    fi
 382    NATIVE=no
 383 else
 384    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 385    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 386    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 387    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 388    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 389    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 390    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 391    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 392    AC_CHECK_LIB(dl, dladdr, [
 393      AC_DEFINE(HAVE_DLADDR)])
 394    AC_CHECK_FILES(/proc/self/exe, [
 395      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 396
 397    AC_CHECK_FUNCS(gethostbyname_r, [
 398      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 399      # There are two different kinds of gethostbyname_r.
 400      # We look for the one that returns `int'.
 401      # Hopefully this check is robust enough.
 402      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 403        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 404
 405      case " $GCINCS " in
 406      *" -D_REENTRANT "*) ;;
 407      *)
 408         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 409         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 410         [libjava_cv_gethostbyname_r_needs_reentrant],
 411         [ AC_LANG_SAVE
 412           AC_LANG_CPLUSPLUS
 413           AC_TRY_COMPILE([#include <netdb.h>],
 414             [gethostbyname_r("", 0, 0);],
 415             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 416                 CPPFLAGS_SAVE="$CPPFLAGS"
 417                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 418                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 419                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 420                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 421                 CPPFLAGS="$CPPFLAGS_SAVE"
 422           ])
 423           AC_LANG_RESTORE
 424         ])
 425         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 426           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 427         fi
 428      ;;
 429      esac
 430
 431      AC_CACHE_CHECK([for struct hostent_data],
 432         [libjava_cv_struct_hostent_data], [dnl
 433         AC_TRY_COMPILE([
 434 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 435 # define _REENTRANT 1
 436 #endif
 437 #include <netdb.h>], [struct hostent_data data;],
 438           [libjava_cv_struct_hostent_data=yes],
 439           [libjava_cv_struct_hostent_data=no])])
 440      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 441        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 442          [Define if struct hostent_data is defined in netdb.h])
 443      fi
 444    ])
 445
 446    AC_CHECK_FUNCS(gethostbyaddr_r, [
 447      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 448      # There are two different kinds of gethostbyaddr_r.
 449      # We look for the one that returns `int'.
 450      # Hopefully this check is robust enough.
 451      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 452        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 453
 454    AC_CHECK_FUNCS(gethostname, [
 455      AC_DEFINE(HAVE_GETHOSTNAME)
 456      AC_EGREP_HEADER(gethostname, unistd.h, [
 457        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 458
 459    # Look for these functions in the thread library, but only bother
 460    # if using POSIX threads.
 461    if test "$THREADS" = posix; then
 462       save_LIBS="$LIBS"
 463       LIBS="$LIBS $THREADLIBS"
 464       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 465       # E.g., Solaris.
 466       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 467
 468       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 469       # Solaris 7 the name librt is preferred.
 470       AC_CHECK_FUNCS(sched_yield, , [
 471         AC_CHECK_LIB(rt, sched_yield, [
 472           AC_DEFINE(HAVE_SCHED_YIELD)
 473           THREADLIBS="$THREADLIBS -lrt"
 474           THREADSPEC="$THREADSPEC -lrt"], [
 475           AC_CHECK_LIB(posix4, sched_yield, [
 476             AC_DEFINE(HAVE_SCHED_YIELD)
 477             THREADLIBS="$THREADLIBS -lposix4"
 478             THREADSPEC="$THREADSPEC -lposix4"])])])
 479       LIBS="$save_LIBS"
 480
 481       # We can save a little space at runtime if the mutex has m_count
 482       # or __m_count.  This is a nice hack for Linux.
 483       AC_TRY_COMPILE([#include <pthread.h>], [
 484           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 485         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 486         AC_TRY_COMPILE([#include <pthread.h>], [
 487             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 488           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 489    fi
 490
 491    # We require a way to get the time.
 492    time_found=no
 493    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 494    if test "$time_found" = no; then
 495       AC_MSG_ERROR([no function found to get the time])
 496    fi
 497
 498    AC_CHECK_FUNCS(memmove)
 499
 500    # We require memcpy.
 501    memcpy_found=no
 502    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 503    if test "$memcpy_found" = no; then
 504       AC_MSG_ERROR([memcpy is required])
 505    fi
 506
 507    # Some library-finding code we stole from Tcl.
 508    #--------------------------------------------------------------------
 509    #    Check for the existence of the -lsocket and -lnsl libraries.
 510    #    The order here is important, so that they end up in the right
 511    #    order in the command line generated by make.  Here are some
 512    #    special considerations:
 513    #    1. Use "connect" and "accept" to check for -lsocket, and
 514    #       "gethostbyname" to check for -lnsl.
 515    #    2. Use each function name only once:  can't redo a check because
 516    #       autoconf caches the results of the last check and won't redo it.
 517    #    3. Use -lnsl and -lsocket only if they supply procedures that
 518    #       aren't already present in the normal libraries.  This is because
 519    #       IRIX 5.2 has libraries, but they aren't needed and they're
 520    #       bogus:  they goof up name resolution if used.
 521    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 522    #       To get around this problem, check for both libraries together
 523    #       if -lsocket doesn't work by itself.
 524    #--------------------------------------------------------------------
 525
 526    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 527     [gcj_cv_lib_sockets=
 528      gcj_checkBoth=0
 529      unset ac_cv_func_connect
 530      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 531      if test "$gcj_checkSocket" = 1; then
 532          unset ac_cv_func_connect
 533          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 534                       gcj_checkBoth=1)
 535      fi
 536      if test "$gcj_checkBoth" = 1; then
 537          gcj_oldLibs=$LIBS
 538          LIBS="$LIBS -lsocket -lnsl"
 539          unset ac_cv_func_accept
 540          AC_CHECK_FUNC(accept,
 541                        [gcj_checkNsl=0
 542                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 543          unset ac_cv_func_accept
 544          LIBS=$gcj_oldLibs
 545      fi
 546      unset ac_cv_func_gethostbyname
 547      gcj_oldLibs=$LIBS
 548      LIBS="$LIBS $gcj_cv_lib_sockets"
 549      AC_CHECK_FUNC(gethostbyname, ,
 550                    [AC_CHECK_LIB(nsl, main,
 551                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 552      unset ac_cv_func_gethostbyname
 553      LIBS=$gcj_oldLIBS
 554    ])
 555    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 556
 557    if test "$with_system_zlib" = yes; then
 558       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 559    else
 560       ZLIBSPEC=-lzgcj
 561       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 562    fi
 563
 564    # On Solaris, and maybe other architectures, the Boehm collector
 565    # requires -ldl.
 566    if test "$GC" = boehm; then
 567       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 568    fi
 569
 570    if test -z "${with_multisubdir}"; then
 571       builddotdot=.
 572    else
 573 changequote(<<,>>)
 574       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 575 changequote([,])
 576    fi
 577    if test -x "${builddotdot}/../../gcc/gcj"; then
 578       dir="`cd ${builddotdot}/../../gcc && pwd`"
 579       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 580    else
 581       CANADIAN=yes
 582       NULL_TARGET=yes
 583       GCJ="gcj -B`pwd`/"
 584    fi
 585 fi
 586
 587 # Create it, so that compile/link tests don't fail
 588 test -f libgcj.spec || touch libgcj.spec
 589
 590 # We must search the source tree for java.lang, since we still don't
 591 # have libgcj.jar nor java/lang/*.class
 592 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 593 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 594
 595 # Since some classes depend on this one, we need its source available
 596 # before we can do any GCJ compilation test :-(
 597 if test ! -f gnu/classpath/Configuration.java; then
 598   test -d gnu || mkdir gnu
 599   test -d gnu/classpath || mkdir gnu/classpath
 600   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 601         < $srcdir/gnu/classpath/Configuration.java.in \
 602         > gnu/classpath/Configuration.java
 603   # We do not want to redirect the output of the grep below to /dev/null,
 604   # but we add /dev/null to the input list so that grep will print the
 605   # filename of Configuration.java in case it finds any matches.
 606   if grep @ gnu/classpath/Configuration.java /dev/null; then
 607     AC_MSG_ERROR([configure.in is missing the substitutions above])
 608   fi
 609 fi
 610
 611 LT_AC_PROG_GCJ
 612
 613 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 614
 615 dnl FIXME: cross compilation
 616 AC_CHECK_SIZEOF(void *)
 617
 618 ZLIBS=
 619 ZDEPS=
 620 ZINCS=
 621 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 622    # We include the path to the zlib build directory.
 623    # See Makefile.am to understand why.
 624    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 625    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 626    ZINCS='-I$(top_srcdir)/../zlib'
 627 else
 628    ZLIBS="$ZLIBSPEC"
 629 fi
 630 AC_SUBST(ZLIBS)
 631 AC_SUBST(ZDEPS)
 632 AC_SUBST(ZINCS)
 633 AC_SUBST(DIVIDESPEC)
 634 AC_SUBST(EXCEPTIONSPEC)
 635
 636 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 637 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 638 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 639 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 640 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 641 AC_SUBST(GCC_UNWIND_INCLUDE)
 642
 643 # Determine gcj version number.
 644 changequote(<<,>>)
 645 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 646 changequote([,])
 647 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 648 AC_SUBST(GCJVERSION)
 649
 650 AC_SUBST(AM_RUNTESTFLAGS)
 651
 652 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 653 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 654 save_CFLAGS="$CFLAGS"
 655 CFLAGS="-x c++ -O2 -ffloat-store"
 656 AC_TRY_COMPILE([#include <math.h>], ,
 657   [AC_MSG_RESULT(no)],
 658   [AC_DEFINE(__NO_MATH_INLINES)
 659    AC_MSG_RESULT(yes)])
 660 CFLAGS="$save_CFLAGS"
 661
 662 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 663 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 664 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 665 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 666 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 667 dnl for now.  If you change this, you also must update natFile.cc.
 668 AC_CHECK_HEADERS(dirent.h)
 669
 670 AC_CHECK_TYPE([ssize_t], [int])
 671
 672 AC_MSG_CHECKING([for in_addr_t])
 673 AC_TRY_COMPILE([#include <sys/types.h>
 674 #if STDC_HEADERS
 675 #include <stdlib.h>
 676 #include <stddef.h>
 677 #endif
 678 #if HAVE_NETINET_IN_H
 679 #include <netinet/in.h>
 680 #endif], [in_addr_t foo;],
 681   [AC_DEFINE([HAVE_IN_ADDR_T])
 682    AC_MSG_RESULT(yes)],
 683   [AC_MSG_RESULT(no)])
 684
 685 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 686 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 687   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 688    AC_MSG_RESULT(yes)],
 689   [AC_MSG_RESULT(no)])
 690
 691 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 692 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 693   [AC_DEFINE(HAVE_INET6)
 694    AC_MSG_RESULT(yes)],
 695   [AC_MSG_RESULT(no)])
 696
 697 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 698 AC_TRY_COMPILE([#include <sys/types.h>
 699 #include <sys/socket.h>], [socklen_t x = 5;],
 700   [AC_DEFINE(HAVE_SOCKLEN_T)
 701    AC_MSG_RESULT(yes)],
 702   [AC_MSG_RESULT(no)])
 703
 704 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 705 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 706   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 707    AC_MSG_RESULT(yes)],
 708   [AC_MSG_RESULT(no)
 709    AC_MSG_CHECKING([for global timezone variable])
 710    dnl FIXME: we don't want a link check here because that won't work
 711    dnl when cross-compiling.  So instead we make an assumption that
 712    dnl the header file will mention timezone if it exists.
 713    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 714      [AC_DEFINE(HAVE_TIMEZONE)
 715       AC_MSG_RESULT(yes)],
 716      [AC_MSG_RESULT(no)])])
 717
 718 AC_FUNC_ALLOCA
 719
 720 AC_CHECK_PROGS(PERL, perl, false)
 721
 722 SYSDEP_SOURCES=
 723
 724 case "${host}" in
 725  i?86-*-linux*)
 726     SIGNAL_HANDLER=include/i386-signal.h
 727     ;;
 728  sparc-sun-solaris*)
 729     SIGNAL_HANDLER=include/sparc-signal.h
 730     ;;
 731 # ia64-*)
 732 #    SYSDEP_SOURCES=sysdep/ia64.c
 733 #    test -d sysdep || mkdir sysdep
 734 #    ;;
 735  powerpc-*-linux*)
 736     SIGNAL_HANDLER=include/dwarf2-signal.h
 737     ;;
 738  *)
 739     SIGNAL_HANDLER=include/default-signal.h
 740     ;;
 741 esac
 742
 743 # If we're using sjlj exceptions, forget what we just learned.
 744 if test "$libgcj_sjlj" = yes; then
 745    SIGNAL_HANDLER=include/default-signal.h
 746 fi
 747
 748 AC_SUBST(SYSDEP_SOURCES)
 749
 750 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 751
 752 if test "${multilib}" = "yes"; then
 753   multilib_arg="--enable-multilib"
 754 else
 755   multilib_arg=
 756 fi
 757
 758 AC_PATH_XTRA
 759
 760 dnl Determine which AWT peer libraries to build
 761 AC_ARG_ENABLE(java-awt,
 762 [  --enable-java-awt       list of AWT peer implementations to be built])
 763
 764 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 765 use_xlib_awt=""
 766 use_gtk_awt=""
 767
 768 for peer in $peerlibs ; do
 769   case $peer in
 770     xlib)
 771       if [test "$no_x" = yes]; then
 772         echo "*** xlib peers requested but no X library available" 1>&2
 773         exit 1
 774       else
 775         use_xlib_awt="yes"
 776       fi
 777       ;;
 778     gtk)
 779       # Nothing, yet...
 780       ;;
 781     *)
 782       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 783       exit 1
 784   esac
 785 done
 786
 787 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 788 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 789
 790
 791 here=`pwd`
 792 AC_SUBST(here)
 793
 794 # We get this from the environment.
 795 AC_SUBST(GCJFLAGS)
 796
 797 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 798 [if test -n "$CONFIG_FILES"; then
 799   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 800 fi
 801
 802 # Make subdirectories and `.d' files.  Look in both srcdir and
 803 # builddir for the .java files.
 804 h=`pwd`
 805 : > deps.mk
 806 ( (cd $srcdir && find . -name '*.java' -print) ;
 807   find . -name '*.java' -print) | \
 808    fgrep -v testsuite | \
 809    sed -e 's/\.java/.d/' | \
 810    while read f; do
 811       echo "include $f" >> deps.mk
 812       test -f $f || {
 813 changequote(<<,>>)
 814          d=`echo $f | sed -e 's,/[^/]*$,,'`
 815 changequote([,])
 816          $srcdir/../mkinstalldirs $d
 817          echo > $f
 818       }
 819    done
 820 ],
 821 srcdir=${srcdir}
 822 host=${host}
 823 target=${target}
 824 with_multisubdir=${with_multisubdir}
 825 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 826 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 827 libgcj_basedir=${libgcj_basedir}
 828 CC="${CC}"
 829 CXX="${CXX}"
 830 )