libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -n "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67 dnl See if the user has requested runtime debugging.
  68 AC_ARG_ENABLE(libgcj-debug,
  69 [  --enable-libgcj-debug   enable runtime debugging code],
  70   if test "$enable_libgcj_debug" = yes; then
  71      AC_DEFINE(DEBUG)
  72   fi)
  73
  74 dnl See if the user has the interpreter included.
  75 AC_ARG_ENABLE(interpreter,
  76 [  --enable-interpreter    enable interpreter],
  77   if test "$enable_interpreter" = yes; then
  78     # This can also be set in configure.host.
  79     libgcj_interpreter=yes
  80   elif test "$enable_interpreter" = no; then
  81     libgcj_interpreter=no
  82   fi)
  83
  84 if test "$libgcj_interpreter" = yes; then
  85    AC_DEFINE(INTERPRETER)
  86 fi
  87
  88 EXCEPTIONSPEC=
  89 dnl See if we should use setjmp/longjmp exceptions
  90 AC_ARG_ENABLE(sjlj-exceptions,
  91 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  92   if test "$enable_sjlj_exceptions" = yes; then
  93      # This can be set in configure.host.
  94      libgcj_sjlj=yes
  95   fi)
  96
  97 if test "$libgcj_sjlj" = yes; then
  98    EXCEPTIONSPEC="-fsjlj-exceptions"
  99    AC_DEFINE(SJLJ_EXCEPTIONS)
 100 fi
 101
 102 FORCELIBGCCSPEC=
 103 dnl Work around libgcc design flaw.
 104 if test "$ac_cv_prog_gnu_ld" = yes; then
 105    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 106 fi
 107
 108 AC_MSG_CHECKING([for data_start])
 109 LIBDATASTARTSPEC=
 110 NEEDS_DATA_START=
 111 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 112   [AC_MSG_RESULT(found it)],
 113   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 114    NEEDS_DATA_START=yes
 115    AC_MSG_RESULT(missing)])
 116 AC_SUBST(LIBDATASTARTSPEC)
 117
 118 dnl See if the user wants to disable java.net.  This is the mildly
 119 dnl ugly way that we admit that target-side configuration sucks.
 120 AC_ARG_ENABLE(java-net,
 121 [  --disable-java-net      disable java.net])
 122
 123 dnl Whether java.net is built by default can depend on the target.
 124 if test -n "$enable_java_net"; then
 125    enable_java_net=${enable_java_net_default-yes}
 126 fi
 127 if test "$enable_java_net" = no; then
 128    AC_DEFINE(DISABLE_JAVA_NET)
 129 fi
 130
 131 dnl See if the user wants to disable JVMPI support.
 132 AC_ARG_ENABLE(jvmpi,
 133 [  --disable-jvmpi         disable JVMPI support])
 134
 135 if test "$enable_jvmpi" != no; then
 136     AC_DEFINE(ENABLE_JVMPI)
 137 fi
 138
 139 dnl If the target is an eCos system, use the appropriate eCos
 140 dnl I/O routines.
 141 dnl FIXME: this should not be a local option but a global target
 142 dnl system; at present there is no eCos target.
 143 TARGET_ECOS="no"
 144 AC_ARG_WITH(ecos,
 145 [  --with-ecos             enable runtime eCos target support],
 146 TARGET_ECOS="$with_ecos"
 147 )
 148
 149 case "$TARGET_ECOS" in
 150    no)
 151       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 152       PROCESS=${PROCESS-Posix}
 153       ;;
 154    *)
 155       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 156       PROCESS=Ecos
 157       AC_DEFINE(ECOS)
 158       ;;
 159 esac
 160
 161 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 162 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 163 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 164 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 165
 166
 167 dnl These may not be defined in a non-ANS conformant embedded system.
 168 dnl FIXME: Should these case a runtime exception in that case?
 169 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 170 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 171
 172 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 173 dnl to create the link will fail.
 174 test -d java || mkdir java
 175 test -d java/io || mkdir java/io
 176 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 177
 178 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 179 test -d java/lang || mkdir java/lang
 180 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 181 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 182
 183 SYSTEMSPEC=
 184 AC_SUBST(SYSTEMSPEC)
 185
 186 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 187 AC_SUBST(LIBGCJTESTSPEC)
 188
 189 AC_ARG_WITH(system-zlib,
 190 [  --with-system-zlib      use installed libz])
 191 ZLIBSPEC=
 192 AC_SUBST(ZLIBSPEC)
 193 ZLIBTESTSPEC=
 194 AC_SUBST(ZLIBTESTSPEC)
 195
 196 dnl FIXME: this should be _libs on some hosts.
 197 libsubdir=.libs
 198
 199 dnl Allow the GC to be disabled.  Can be useful when debugging.
 200 AC_MSG_CHECKING([for garbage collector to use])
 201 AC_ARG_ENABLE(java-gc,
 202 changequote(<<,>>)dnl
 203 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 204 changequote([,])
 205   GC=$enableval,
 206   GC=boehm)
 207 GCLIBS=
 208 GCINCS=
 209 GCDEPS=
 210 GCOBJS=
 211 GCSPEC=
 212 JC1GCSPEC=
 213 GCTESTSPEC=
 214 case "$GC" in
 215  boehm)
 216     AC_MSG_RESULT(boehm)
 217     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 218     # We include the path to the boehm-gc build directory.
 219     # See Makefile.am to understand why.
 220     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 221     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 222     GCSPEC='-lgcjgc'
 223     JC1GCSPEC='-fuse-boehm-gc'
 224     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 225     dnl We also want to pick up some cpp flags required when including
 226     dnl boehm-config.h.  Yuck.
 227     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 228     GCOBJS=boehm.lo
 229     GCHDR=boehm-gc.h
 230     dnl The POSIX thread support needs to know this.
 231     AC_DEFINE(HAVE_BOEHM_GC)
 232     ;;
 233  no)
 234     AC_MSG_RESULT(none)
 235     GCOBJS=nogc.lo
 236     GCHDR=no-gc.h
 237     ;;
 238  *)
 239     AC_MSG_ERROR(unrecognized collector \"$GC\")
 240     ;;
 241 esac
 242 AC_SUBST(GCLIBS)
 243 AC_SUBST(GCINCS)
 244 AC_SUBST(GCDEPS)
 245 AC_SUBST(GCOBJS)
 246 AC_SUBST(GCSPEC)
 247 AC_SUBST(JC1GCSPEC)
 248 AC_SUBST(GCTESTSPEC)
 249 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 250
 251
 252 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 253 dnl In particular both packages must make the same decision about which
 254 dnl thread package to use.
 255 AC_MSG_CHECKING([for threads package to use])
 256 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 257   THREADS=$enableval,
 258   dnl FIXME: figure out native threads to use here.
 259   THREADS=no)
 260
 261 if test "$THREADS" = yes; then
 262    case "$host" in
 263     *-*-vxworks*)
 264        THREADS=vxworks
 265        ;;
 266     *-*-linux*)
 267        # FIXME: this isn't correct in all cases.
 268        THREADS=posix
 269        ;;
 270     *-*-win*)
 271        THREADS=win32
 272        ;;
 273     *-*-irix*)
 274        # FIXME: for now, choose POSIX, because we implement that.
 275        # Later, choose irix threads.
 276        THREADS=posix
 277        ;;
 278     *-*-solaris*)
 279        # FIXME: for now, choose POSIX, because we implement that.
 280        # Later, choose solaris threads.
 281        THREADS=posix
 282        ;;
 283     *)
 284        # For now.
 285        THREADS=none
 286        ;;
 287    esac
 288 fi
 289
 290 case "$THREADS" in
 291  no | none | single)
 292     THREADS=none
 293     ;;
 294  posix | pthreads)
 295     THREADS=posix
 296     case "$host" in
 297      *-*-linux*)
 298         AC_DEFINE(LINUX_THREADS)
 299         ;;
 300     esac
 301     ;;
 302  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 303     AC_MSG_ERROR(thread package $THREADS not yet supported)
 304     ;;
 305  *)
 306     AC_MSG_ERROR($THREADS is an unknown thread package)
 307     ;;
 308 esac
 309 AC_MSG_RESULT($THREADS)
 310
 311 THREADLIBS=
 312 THREADINCS=
 313 THREADDEPS=
 314 THREADOBJS=
 315 THREADH=
 316 THREADSPEC=
 317 case "$THREADS" in
 318  posix)
 319     THREADLIBS=-lpthread
 320     THREADSPEC=-lpthread
 321     THREADOBJS=posix-threads.lo
 322     THREADH=posix-threads.h
 323     # MIT pthreads doesn't seem to have the mutexattr functions.
 324     # But for now we don't check for it.  We just assume you aren't
 325     # using MIT pthreads.
 326     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 327
 328     # If we're using the Boehm GC, then we happen to know that it
 329     # defines _REENTRANT, so we don't bother.  Eww.
 330     if test "$GC" != boehm; then
 331        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 332     fi
 333     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 334     ;;
 335
 336  none)
 337     THREADOBJS=no-threads.lo
 338     THREADH=no-threads.h
 339     ;;
 340 esac
 341 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 342 AC_SUBST(THREADLIBS)
 343 AC_SUBST(THREADINCS)
 344 AC_SUBST(THREADDEPS)
 345 AC_SUBST(THREADOBJS)
 346 AC_SUBST(THREADSPEC)
 347
 348 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 349
 350 CANADIAN=no
 351 NULL_TARGET=no
 352 NATIVE=yes
 353
 354 # Find eh-common.h and support headers.  If we're in the tree with
 355 # gcc, then look there.  Otherwise look in compat-include.  If all else
 356 # fails, just hope the user has set things up somehow.
 357 if test -r $srcdir/../gcc/eh-common.h; then
 358    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 359 else
 360    if test -d $srcdir/../compat-include; then
 361       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 362    else
 363       EH_COMMON_INCLUDE=
 364    fi
 365 fi
 366
 367 if test -n "${with_cross_host}"; then
 368    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 369    # may not work correctly, because the compiler may not be able to
 370    # link executables.
 371
 372    # We assume newlib.  This lets us hard-code the functions we know
 373    # we'll have.
 374    AC_DEFINE(HAVE_MEMMOVE)
 375    AC_DEFINE(HAVE_MEMCPY)
 376    AC_DEFINE(HAVE_STRERROR)
 377    AC_DEFINE(HAVE_GMTIME_R)
 378    AC_DEFINE(HAVE_LOCALTIME_R)
 379    dnl This is only for POSIX threads.
 380    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 381    dnl We also assume we are using gcc, which provides alloca.
 382    AC_DEFINE(HAVE_ALLOCA)
 383
 384    dnl Assume we do not have getuid and friends.
 385    AC_DEFINE(NO_GETUID)
 386
 387    ZLIBSPEC=-lzgcj
 388    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 389
 390    # If Canadian cross, then don't pick up tools from the build
 391    # directory.
 392    if test "$build" != "$with_cross_host"; then
 393       CANADIAN=yes
 394       EH_COMMON_INCLUDE=
 395       GCJ="${target_alias}-gcj"
 396    else
 397       GCJ=
 398    fi
 399    NATIVE=no
 400 else
 401    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 402    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 403    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 404    AC_CHECK_FUNCS(iconv nl_langinfo)
 405    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 406    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 407    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 408    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 409    AC_CHECK_LIB(dl, dladdr, [
 410      AC_DEFINE(HAVE_DLADDR)])
 411    AC_CHECK_FILES(/proc/self/exe, [
 412      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 413
 414    AC_CHECK_FUNCS(gethostbyname_r, [
 415      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 416      # There are two different kinds of gethostbyname_r.
 417      # We look for the one that returns `int'.
 418      # Hopefully this check is robust enough.
 419      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 420        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 421
 422      case " $GCINCS " in
 423      *" -D_REENTRANT "*) ;;
 424      *)
 425         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 426         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 427         [libjava_cv_gethostbyname_r_needs_reentrant],
 428         [ AC_LANG_SAVE
 429           AC_LANG_CPLUSPLUS
 430           AC_TRY_COMPILE([#include <netdb.h>],
 431             [gethostbyname_r("", 0, 0);],
 432             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 433                 CPPFLAGS_SAVE="$CPPFLAGS"
 434                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 435                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 436                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 437                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 438                 CPPFLAGS="$CPPFLAGS_SAVE"
 439           ])
 440           AC_LANG_RESTORE
 441         ])
 442         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 443           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 444         fi
 445      ;;
 446      esac
 447
 448      AC_CACHE_CHECK([for struct hostent_data],
 449         [libjava_cv_struct_hostent_data], [dnl
 450         AC_TRY_COMPILE([
 451 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 452 # define _REENTRANT 1
 453 #endif
 454 #include <netdb.h>], [struct hostent_data data;],
 455           [libjava_cv_struct_hostent_data=yes],
 456           [libjava_cv_struct_hostent_data=no])])
 457      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 458        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 459          [Define if struct hostent_data is defined in netdb.h])
 460      fi
 461    ])
 462
 463    AC_CHECK_FUNCS(gethostbyaddr_r, [
 464      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 465      # There are two different kinds of gethostbyaddr_r.
 466      # We look for the one that returns `int'.
 467      # Hopefully this check is robust enough.
 468      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 469        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 470
 471    AC_CHECK_FUNCS(gethostname, [
 472      AC_DEFINE(HAVE_GETHOSTNAME)
 473      AC_EGREP_HEADER(gethostname, unistd.h, [
 474        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 475
 476    # Look for these functions in the thread library, but only bother
 477    # if using POSIX threads.
 478    if test "$THREADS" = posix; then
 479       save_LIBS="$LIBS"
 480       LIBS="$LIBS $THREADLIBS"
 481       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 482       # E.g., Solaris.
 483       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 484
 485       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 486       # Solaris 7 the name librt is preferred.
 487       AC_CHECK_FUNCS(sched_yield, , [
 488         AC_CHECK_LIB(rt, sched_yield, [
 489           AC_DEFINE(HAVE_SCHED_YIELD)
 490           THREADLIBS="$THREADLIBS -lrt"
 491           THREADSPEC="$THREADSPEC -lrt"], [
 492           AC_CHECK_LIB(posix4, sched_yield, [
 493             AC_DEFINE(HAVE_SCHED_YIELD)
 494             THREADLIBS="$THREADLIBS -lposix4"
 495             THREADSPEC="$THREADSPEC -lposix4"])])])
 496       LIBS="$save_LIBS"
 497
 498       # We can save a little space at runtime if the mutex has m_count
 499       # or __m_count.  This is a nice hack for Linux.
 500       AC_TRY_COMPILE([#include <pthread.h>], [
 501           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 502         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 503         AC_TRY_COMPILE([#include <pthread.h>], [
 504             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 505           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 506    fi
 507
 508    # We require a way to get the time.
 509    time_found=no
 510    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 511    if test "$time_found" = no; then
 512       AC_MSG_ERROR([no function found to get the time])
 513    fi
 514
 515    AC_CHECK_FUNCS(memmove)
 516
 517    # We require memcpy.
 518    memcpy_found=no
 519    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 520    if test "$memcpy_found" = no; then
 521       AC_MSG_ERROR([memcpy is required])
 522    fi
 523
 524    # Some library-finding code we stole from Tcl.
 525    #--------------------------------------------------------------------
 526    #    Check for the existence of the -lsocket and -lnsl libraries.
 527    #    The order here is important, so that they end up in the right
 528    #    order in the command line generated by make.  Here are some
 529    #    special considerations:
 530    #    1. Use "connect" and "accept" to check for -lsocket, and
 531    #       "gethostbyname" to check for -lnsl.
 532    #    2. Use each function name only once:  can't redo a check because
 533    #       autoconf caches the results of the last check and won't redo it.
 534    #    3. Use -lnsl and -lsocket only if they supply procedures that
 535    #       aren't already present in the normal libraries.  This is because
 536    #       IRIX 5.2 has libraries, but they aren't needed and they're
 537    #       bogus:  they goof up name resolution if used.
 538    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 539    #       To get around this problem, check for both libraries together
 540    #       if -lsocket doesn't work by itself.
 541    #--------------------------------------------------------------------
 542
 543    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 544     [gcj_cv_lib_sockets=
 545      gcj_checkBoth=0
 546      unset ac_cv_func_connect
 547      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 548      if test "$gcj_checkSocket" = 1; then
 549          unset ac_cv_func_connect
 550          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 551                       gcj_checkBoth=1)
 552      fi
 553      if test "$gcj_checkBoth" = 1; then
 554          gcj_oldLibs=$LIBS
 555          LIBS="$LIBS -lsocket -lnsl"
 556          unset ac_cv_func_accept
 557          AC_CHECK_FUNC(accept,
 558                        [gcj_checkNsl=0
 559                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 560          unset ac_cv_func_accept
 561          LIBS=$gcj_oldLibs
 562      fi
 563      unset ac_cv_func_gethostbyname
 564      gcj_oldLibs=$LIBS
 565      LIBS="$LIBS $gcj_cv_lib_sockets"
 566      AC_CHECK_FUNC(gethostbyname, ,
 567                    [AC_CHECK_LIB(nsl, main,
 568                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 569      unset ac_cv_func_gethostbyname
 570      LIBS=$gcj_oldLIBS
 571    ])
 572    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 573
 574    if test "$with_system_zlib" = yes; then
 575       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 576    else
 577       ZLIBSPEC=-lzgcj
 578       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 579    fi
 580
 581    # On Solaris, and maybe other architectures, the Boehm collector
 582    # requires -ldl.
 583    if test "$GC" = boehm; then
 584       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 585    fi
 586
 587    if test -z "${with_multisubdir}"; then
 588       builddotdot=.
 589    else
 590 changequote(<<,>>)
 591       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 592 changequote([,])
 593    fi
 594    if test -x "${builddotdot}/../../gcc/gcj"; then
 595       dir="`cd ${builddotdot}/../../gcc && pwd`"
 596       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 597    else
 598       CANADIAN=yes
 599       NULL_TARGET=yes
 600       GCJ="gcj -B`pwd`/"
 601    fi
 602 fi
 603
 604 # Create it, so that compile/link tests don't fail
 605 test -f libgcj.spec || touch libgcj.spec
 606
 607 LT_AC_PROG_GCJ
 608
 609 dnl FIXME: cross compilation
 610 AC_CHECK_SIZEOF(void *)
 611
 612 ZLIBS=
 613 ZDEPS=
 614 ZINCS=
 615 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 616    # We include the path to the zlib build directory.
 617    # See Makefile.am to understand why.
 618    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 619    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 620    ZINCS='-I$(top_srcdir)/../zlib'
 621 else
 622    ZLIBS="$ZLIBSPEC"
 623 fi
 624 AC_SUBST(ZLIBS)
 625 AC_SUBST(ZDEPS)
 626 AC_SUBST(ZINCS)
 627 AC_SUBST(DIVIDESPEC)
 628 AC_SUBST(EXCEPTIONSPEC)
 629 AC_SUBST(FORCELIBGCCSPEC)
 630
 631 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 632 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 633 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 634 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 635 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 636 AC_SUBST(EH_COMMON_INCLUDE)
 637
 638 # Determine gcj version number.
 639 changequote(<<,>>)
 640 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 641 changequote([,])
 642 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 643
 644 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 645 # we want to continue to support that version.
 646 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 647 cat > conftest.java << 'END'
 648 public class conftest { }
 649 END
 650 use_fuse=yes
 651 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 652    conftest.java > /dev/null 2>&1 \
 653    || use_fuse=no
 654 rm -f conftest.java
 655 if test "$use_fuse" = no; then
 656    DIVIDESPEC=
 657 fi
 658 AC_MSG_RESULT($use_fuse)
 659
 660 AC_SUBST(AM_RUNTESTFLAGS)
 661
 662 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 663 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 664 save_CFLAGS="$CFLAGS"
 665 CFLAGS="-x c++ -O2 -ffloat-store"
 666 AC_TRY_COMPILE([#include <math.h>], ,
 667   [AC_MSG_RESULT(no)],
 668   [AC_DEFINE(__NO_MATH_INLINES)
 669    AC_MSG_RESULT(yes)])
 670 CFLAGS="$save_CFLAGS"
 671
 672 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 673 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 674 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 675 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h)
 676 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 677 dnl for now.  If you change this, you also must update natFile.cc.
 678 AC_CHECK_HEADERS(dirent.h)
 679
 680 AC_CHECK_TYPE([ssize_t], [int])
 681
 682 AC_MSG_CHECKING([for in_addr_t])
 683 AC_TRY_COMPILE([#include <sys/types.h>
 684 #if STDC_HEADERS
 685 #include <stdlib.h>
 686 #include <stddef.h>
 687 #endif
 688 #if HAVE_NETINET_IN_H
 689 #include <netinet/in.h>
 690 #endif], [in_addr_t foo;],
 691   [AC_DEFINE([HAVE_IN_ADDR_T])
 692    AC_MSG_RESULT(yes)],
 693   [AC_MSG_RESULT(no)])
 694
 695 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 696 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 697   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 698    AC_MSG_RESULT(yes)],
 699   [AC_MSG_RESULT(no)])
 700
 701 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 702 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 703   [AC_DEFINE(HAVE_INET6)
 704    AC_MSG_RESULT(yes)],
 705   [AC_MSG_RESULT(no)])
 706
 707 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 708 AC_TRY_COMPILE([#include <sys/types.h>
 709 #include <sys/socket.h>], [socklen_t x = 5;],
 710   [AC_DEFINE(HAVE_SOCKLEN_T)
 711    AC_MSG_RESULT(yes)],
 712   [AC_MSG_RESULT(no)])
 713
 714 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 715 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 716   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 717    AC_MSG_RESULT(yes)],
 718   [AC_MSG_RESULT(no)
 719    AC_MSG_CHECKING([for global timezone variable])
 720    dnl FIXME: we don't want a link check here because that won't work
 721    dnl when cross-compiling.  So instead we make an assumption that
 722    dnl the header file will mention timezone if it exists.
 723    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 724      [AC_DEFINE(HAVE_TIMEZONE)
 725       AC_MSG_RESULT(yes)],
 726      [AC_MSG_RESULT(no)])])
 727
 728 AC_FUNC_ALLOCA
 729
 730 AC_CHECK_PROGS(PERL, perl, false)
 731
 732 SYSDEP_SOURCES=
 733
 734 case "${host}" in
 735  i?86-*-linux*)
 736     SIGNAL_HANDLER=include/i386-signal.h
 737     ;;
 738  sparc-sun-solaris*)
 739     SIGNAL_HANDLER=include/sparc-signal.h
 740     ;;
 741  ia64-*)
 742     SYSDEP_SOURCES=sysdep/ia64.c
 743     test -d sysdep || mkdir sysdep
 744     ;;
 745  *)
 746     SIGNAL_HANDLER=include/default-signal.h
 747     ;;
 748 esac
 749
 750 # If we're using sjlj exceptions, forget what we just learned.
 751 if test "$libgcj_sjlj" = yes; then
 752    SIGNAL_HANDLER=include/default-signal.h
 753 fi
 754
 755 AC_SUBST(SYSDEP_SOURCES)
 756
 757 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 758
 759 if test "${multilib}" = "yes"; then
 760   multilib_arg="--enable-multilib"
 761 else
 762   multilib_arg=
 763 fi
 764
 765 AC_PATH_XTRA
 766
 767 AM_CONDITIONAL(NO_X, test "$no_x" = yes)
 768
 769 here=`pwd`
 770 AC_SUBST(here)
 771
 772
 773 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gcj/Makefile include/Makefile testsuite/Makefile,
 774 [if test -n "$CONFIG_FILES"; then
 775   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 776 fi
 777
 778 # Make subdirectories and `.d' files.  Look in both srcdir and
 779 # builddir for the .java files.
 780 h=`pwd`
 781 : > deps.mk
 782 ( (cd $srcdir && find . -name '*.java' -print) ;
 783   find . -name '*.java' -print) | \
 784    fgrep -v testsuite | \
 785    sed -e 's/\.java/.d/' | \
 786    while read f; do
 787       echo "include $f" >> deps.mk
 788       test -f $f || {
 789 changequote(<<,>>)
 790          d=`echo $f | sed -e 's,/[^/]*$,,'`
 791 changequote([,])
 792          $srcdir/../mkinstalldirs $d
 793          : > $f
 794       }
 795    done
 796 ],
 797 srcdir=${srcdir}
 798 host=${host}
 799 target=${target}
 800 with_multisubdir=${with_multisubdir}
 801 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 802 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 803 libgcj_basedir=${libgcj_basedir}
 804 CC="${CC}"
 805 CXX="${CXX}"
 806 )