libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -n "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67 dnl See if the user has requested runtime debugging.
  68 LIBGCJDEBUG="false"
  69 AC_SUBST(LIBGCJDEBUG)
  70 AC_ARG_ENABLE(libgcj-debug,
  71 [  --enable-libgcj-debug   enable runtime debugging code],
  72   if test "$enable_libgcj_debug" = yes; then
  73     AC_DEFINE(DEBUG)
  74     LIBGCJDEBUG="true"
  75   fi)
  76
  77 dnl See if the user has the interpreter included.
  78 AC_ARG_ENABLE(interpreter,
  79 [  --enable-interpreter    enable interpreter],
  80   if test "$enable_interpreter" = yes; then
  81     # This can also be set in configure.host.
  82     libgcj_interpreter=yes
  83   elif test "$enable_interpreter" = no; then
  84     libgcj_interpreter=no
  85   fi)
  86
  87 if test "$libgcj_interpreter" = yes; then
  88    AC_DEFINE(INTERPRETER)
  89 fi
  90
  91 AC_MSG_CHECKING([for exception model to use])
  92 AC_LANG_SAVE
  93 AC_LANG_CPLUSPLUS
  94 AC_ARG_ENABLE(sjlj-exceptions,
  95 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
  96 [:],
  97 [dnl Botheration.  Now we've got to detect the exception model.
  98 dnl Link tests against libgcc.a are problematic since -- at least
  99 dnl as of this writing -- we've not been given proper -L bits for
 100 dnl single-tree newlib and libgloss.
 101 dnl
 102 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 103 dnl conftest files before we got a change to grep them first.
 104 cat > conftest.$ac_ext << EOF
 105 [#]line __oline__ "configure"
 106 struct S { ~S(); };
 107 void bar();
 108 void foo()
 109 {
 110   S s;
 111   bar();
 112 }
 113 EOF
 114 old_CXXFLAGS="$CXXFLAGS"
 115 CXXFLAGS=-S
 116 if AC_TRY_EVAL(ac_compile); then
 117   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 118     enable_sjlj_exceptions=yes
 119   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 120     enable_sjlj_exceptions=no
 121   fi
 122 fi
 123 CXXFLAGS="$old_CXXFLAGS"
 124 rm -f conftest*])
 125 if test x$enable_sjlj_exceptions = xyes; then
 126   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 127         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 128   ac_exception_model_name=sjlj
 129 elif test x$enable_sjlj_exceptions = xno; then
 130   ac_exception_model_name="call frame"
 131 else
 132   AC_MSG_ERROR([unable to detect exception model])
 133 fi
 134 AC_LANG_RESTORE
 135 AC_MSG_RESULT($ac_exception_model_name)
 136
 137 AC_MSG_CHECKING([for data_start])
 138 LIBDATASTARTSPEC=
 139 NEEDS_DATA_START=
 140 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 141   [AC_MSG_RESULT(found it)],
 142   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 143    NEEDS_DATA_START=yes
 144    AC_MSG_RESULT(missing)])
 145 AC_SUBST(LIBDATASTARTSPEC)
 146
 147 dnl See if the user wants to disable java.net.  This is the mildly
 148 dnl ugly way that we admit that target-side configuration sucks.
 149 AC_ARG_ENABLE(java-net,
 150 [  --disable-java-net      disable java.net])
 151
 152 dnl Whether java.net is built by default can depend on the target.
 153 if test -n "$enable_java_net"; then
 154    enable_java_net=${enable_java_net_default-yes}
 155 fi
 156 if test "$enable_java_net" = no; then
 157    AC_DEFINE(DISABLE_JAVA_NET)
 158 fi
 159
 160 dnl See if the user wants to disable JVMPI support.
 161 AC_ARG_ENABLE(jvmpi,
 162 [  --disable-jvmpi         disable JVMPI support])
 163
 164 if test "$enable_jvmpi" != no; then
 165     AC_DEFINE(ENABLE_JVMPI)
 166 fi
 167
 168 dnl If the target is an eCos system, use the appropriate eCos
 169 dnl I/O routines.
 170 dnl FIXME: this should not be a local option but a global target
 171 dnl system; at present there is no eCos target.
 172 TARGET_ECOS="no"
 173 AC_ARG_WITH(ecos,
 174 [  --with-ecos             enable runtime eCos target support],
 175 TARGET_ECOS="$with_ecos"
 176 )
 177
 178 case "$TARGET_ECOS" in
 179    no)
 180       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 181       PROCESS=${PROCESS-Posix}
 182       ;;
 183    *)
 184       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 185       PROCESS=Ecos
 186       AC_DEFINE(ECOS)
 187       ;;
 188 esac
 189
 190 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 191 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 192 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 193 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 194
 195
 196 dnl These may not be defined in a non-ANS conformant embedded system.
 197 dnl FIXME: Should these case a runtime exception in that case?
 198 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 199 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 200
 201 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 202 dnl to create the link will fail.
 203 test -d java || mkdir java
 204 test -d java/io || mkdir java/io
 205 test -d gnu || mkdir gnu
 206 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 207
 208 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 209 test -d java/lang || mkdir java/lang
 210 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 211 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 212
 213 SYSTEMSPEC=
 214 AC_SUBST(SYSTEMSPEC)
 215
 216 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 217 AC_SUBST(LIBGCJTESTSPEC)
 218
 219 AC_ARG_WITH(system-zlib,
 220 [  --with-system-zlib      use installed libz])
 221 ZLIBSPEC=
 222 AC_SUBST(ZLIBSPEC)
 223 ZLIBTESTSPEC=
 224 AC_SUBST(ZLIBTESTSPEC)
 225
 226 dnl FIXME: this should be _libs on some hosts.
 227 libsubdir=.libs
 228
 229 dnl Allow the GC to be disabled.  Can be useful when debugging.
 230 AC_MSG_CHECKING([for garbage collector to use])
 231 AC_ARG_ENABLE(java-gc,
 232 changequote(<<,>>)dnl
 233 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 234 changequote([,])
 235   GC=$enableval,
 236   GC=boehm)
 237 GCLIBS=
 238 GCINCS=
 239 GCDEPS=
 240 GCOBJS=
 241 GCSPEC=
 242 JC1GCSPEC=
 243 GCTESTSPEC=
 244 case "$GC" in
 245  boehm)
 246     AC_MSG_RESULT(boehm)
 247     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 248     # We include the path to the boehm-gc build directory.
 249     # See Makefile.am to understand why.
 250     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 251     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 252     GCSPEC='-lgcjgc'
 253     JC1GCSPEC='-fuse-boehm-gc'
 254     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 255     dnl We also want to pick up some cpp flags required when including
 256     dnl boehm-config.h.  Yuck.
 257     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 258     GCOBJS=boehm.lo
 259     GCHDR=boehm-gc.h
 260     dnl The POSIX thread support needs to know this.
 261     AC_DEFINE(HAVE_BOEHM_GC)
 262     ;;
 263  no)
 264     AC_MSG_RESULT(none)
 265     GCOBJS=nogc.lo
 266     GCHDR=no-gc.h
 267     ;;
 268  *)
 269     AC_MSG_ERROR(unrecognized collector \"$GC\")
 270     ;;
 271 esac
 272 AC_SUBST(GCLIBS)
 273 AC_SUBST(GCINCS)
 274 AC_SUBST(GCDEPS)
 275 AC_SUBST(GCOBJS)
 276 AC_SUBST(GCSPEC)
 277 AC_SUBST(JC1GCSPEC)
 278 AC_SUBST(GCTESTSPEC)
 279 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 280
 281
 282 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 283 dnl In particular both packages must make the same decision about which
 284 dnl thread package to use.
 285 AC_MSG_CHECKING([for threads package to use])
 286 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 287   THREADS=$enableval,
 288   dnl FIXME: figure out native threads to use here.
 289   THREADS=no)
 290
 291 if test "$THREADS" = yes; then
 292    case "$host" in
 293     *-*-vxworks*)
 294        THREADS=vxworks
 295        ;;
 296     *-*-linux*)
 297        # FIXME: this isn't correct in all cases.
 298        THREADS=posix
 299        ;;
 300     *-*-win*)
 301        THREADS=win32
 302        ;;
 303     *-*-irix*)
 304        # FIXME: for now, choose POSIX, because we implement that.
 305        # Later, choose irix threads.
 306        THREADS=posix
 307        ;;
 308     *-*-solaris*)
 309        # FIXME: for now, choose POSIX, because we implement that.
 310        # Later, choose solaris threads.
 311        THREADS=posix
 312        ;;
 313     *)
 314        # For now.
 315        THREADS=none
 316        ;;
 317    esac
 318 fi
 319
 320 case "$THREADS" in
 321  no | none | single)
 322     THREADS=none
 323     ;;
 324  posix | pthreads)
 325     THREADS=posix
 326     case "$host" in
 327      *-*-linux*)
 328         AC_DEFINE(LINUX_THREADS)
 329         ;;
 330     esac
 331     ;;
 332  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 333     AC_MSG_ERROR(thread package $THREADS not yet supported)
 334     ;;
 335  *)
 336     AC_MSG_ERROR($THREADS is an unknown thread package)
 337     ;;
 338 esac
 339 AC_MSG_RESULT($THREADS)
 340
 341 THREADLIBS=
 342 THREADINCS=
 343 THREADDEPS=
 344 THREADOBJS=
 345 THREADH=
 346 THREADSPEC=
 347 case "$THREADS" in
 348  posix)
 349     THREADLIBS=-lpthread
 350     THREADSPEC=-lpthread
 351     THREADOBJS=posix-threads.lo
 352     THREADH=posix-threads.h
 353     # MIT pthreads doesn't seem to have the mutexattr functions.
 354     # But for now we don't check for it.  We just assume you aren't
 355     # using MIT pthreads.
 356     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 357
 358     # If we're using the Boehm GC, then we happen to know that it
 359     # defines _REENTRANT, so we don't bother.  Eww.
 360     if test "$GC" != boehm; then
 361        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 362     fi
 363     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 364     ;;
 365
 366  none)
 367     THREADOBJS=no-threads.lo
 368     THREADH=no-threads.h
 369     ;;
 370 esac
 371 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 372 AC_SUBST(THREADLIBS)
 373 AC_SUBST(THREADINCS)
 374 AC_SUBST(THREADDEPS)
 375 AC_SUBST(THREADOBJS)
 376 AC_SUBST(THREADSPEC)
 377
 378 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 379
 380 CANADIAN=no
 381 NULL_TARGET=no
 382 NATIVE=yes
 383
 384 # Find unwind.h and support headers.  If we're in the tree with
 385 # gcc, then look there.  Otherwise look in compat-include.  If all else
 386 # fails, just hope the user has set things up somehow.
 387 echo "probing $srcdir/../gcc/unwind.h"
 388 if test -r $srcdir/../gcc/unwind.h; then
 389    GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../gcc'
 390 else
 391    if test -d $srcdir/../compat-include; then
 392       GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../compat-include'
 393    else
 394       GCC_UNWIND_INCLUDE=
 395    fi
 396 fi
 397
 398 if test -n "${with_cross_host}"; then
 399    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 400    # may not work correctly, because the compiler may not be able to
 401    # link executables.
 402
 403    # We assume newlib.  This lets us hard-code the functions we know
 404    # we'll have.
 405    AC_DEFINE(HAVE_MEMMOVE)
 406    AC_DEFINE(HAVE_MEMCPY)
 407    AC_DEFINE(HAVE_STRERROR)
 408    AC_DEFINE(HAVE_GMTIME_R)
 409    AC_DEFINE(HAVE_LOCALTIME_R)
 410    dnl This is only for POSIX threads.
 411    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 412    dnl We also assume we are using gcc, which provides alloca.
 413    AC_DEFINE(HAVE_ALLOCA)
 414
 415    dnl Assume we do not have getuid and friends.
 416    AC_DEFINE(NO_GETUID)
 417
 418    ZLIBSPEC=-lzgcj
 419    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 420
 421    # If Canadian cross, then don't pick up tools from the build
 422    # directory.
 423    if test "$build" != "$with_cross_host"; then
 424       CANADIAN=yes
 425       GCC_UNWIND_INCLUDE=
 426       GCJ="${target_alias}-gcj"
 427    else
 428       GCJ=
 429    fi
 430    NATIVE=no
 431 else
 432    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 433    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 434    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 435    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 436    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 437    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 438    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 439    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 440    AC_CHECK_LIB(dl, dladdr, [
 441      AC_DEFINE(HAVE_DLADDR)])
 442    AC_CHECK_FILES(/proc/self/exe, [
 443      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 444
 445    AC_CHECK_FUNCS(gethostbyname_r, [
 446      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 447      # There are two different kinds of gethostbyname_r.
 448      # We look for the one that returns `int'.
 449      # Hopefully this check is robust enough.
 450      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 451        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 452
 453      case " $GCINCS " in
 454      *" -D_REENTRANT "*) ;;
 455      *)
 456         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 457         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 458         [libjava_cv_gethostbyname_r_needs_reentrant],
 459         [ AC_LANG_SAVE
 460           AC_LANG_CPLUSPLUS
 461           AC_TRY_COMPILE([#include <netdb.h>],
 462             [gethostbyname_r("", 0, 0);],
 463             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 464                 CPPFLAGS_SAVE="$CPPFLAGS"
 465                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 466                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 467                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 468                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 469                 CPPFLAGS="$CPPFLAGS_SAVE"
 470           ])
 471           AC_LANG_RESTORE
 472         ])
 473         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 474           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 475         fi
 476      ;;
 477      esac
 478
 479      AC_CACHE_CHECK([for struct hostent_data],
 480         [libjava_cv_struct_hostent_data], [dnl
 481         AC_TRY_COMPILE([
 482 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 483 # define _REENTRANT 1
 484 #endif
 485 #include <netdb.h>], [struct hostent_data data;],
 486           [libjava_cv_struct_hostent_data=yes],
 487           [libjava_cv_struct_hostent_data=no])])
 488      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 489        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 490          [Define if struct hostent_data is defined in netdb.h])
 491      fi
 492    ])
 493
 494    AC_CHECK_FUNCS(gethostbyaddr_r, [
 495      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 496      # There are two different kinds of gethostbyaddr_r.
 497      # We look for the one that returns `int'.
 498      # Hopefully this check is robust enough.
 499      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 500        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 501
 502    AC_CHECK_FUNCS(gethostname, [
 503      AC_DEFINE(HAVE_GETHOSTNAME)
 504      AC_EGREP_HEADER(gethostname, unistd.h, [
 505        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 506
 507    # Look for these functions in the thread library, but only bother
 508    # if using POSIX threads.
 509    if test "$THREADS" = posix; then
 510       save_LIBS="$LIBS"
 511       LIBS="$LIBS $THREADLIBS"
 512       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 513       # E.g., Solaris.
 514       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 515
 516       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 517       # Solaris 7 the name librt is preferred.
 518       AC_CHECK_FUNCS(sched_yield, , [
 519         AC_CHECK_LIB(rt, sched_yield, [
 520           AC_DEFINE(HAVE_SCHED_YIELD)
 521           THREADLIBS="$THREADLIBS -lrt"
 522           THREADSPEC="$THREADSPEC -lrt"], [
 523           AC_CHECK_LIB(posix4, sched_yield, [
 524             AC_DEFINE(HAVE_SCHED_YIELD)
 525             THREADLIBS="$THREADLIBS -lposix4"
 526             THREADSPEC="$THREADSPEC -lposix4"])])])
 527       LIBS="$save_LIBS"
 528
 529       # We can save a little space at runtime if the mutex has m_count
 530       # or __m_count.  This is a nice hack for Linux.
 531       AC_TRY_COMPILE([#include <pthread.h>], [
 532           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 533         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 534         AC_TRY_COMPILE([#include <pthread.h>], [
 535             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 536           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 537    fi
 538
 539    # We require a way to get the time.
 540    time_found=no
 541    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 542    if test "$time_found" = no; then
 543       AC_MSG_ERROR([no function found to get the time])
 544    fi
 545
 546    AC_CHECK_FUNCS(memmove)
 547
 548    # We require memcpy.
 549    memcpy_found=no
 550    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 551    if test "$memcpy_found" = no; then
 552       AC_MSG_ERROR([memcpy is required])
 553    fi
 554
 555    # Some library-finding code we stole from Tcl.
 556    #--------------------------------------------------------------------
 557    #    Check for the existence of the -lsocket and -lnsl libraries.
 558    #    The order here is important, so that they end up in the right
 559    #    order in the command line generated by make.  Here are some
 560    #    special considerations:
 561    #    1. Use "connect" and "accept" to check for -lsocket, and
 562    #       "gethostbyname" to check for -lnsl.
 563    #    2. Use each function name only once:  can't redo a check because
 564    #       autoconf caches the results of the last check and won't redo it.
 565    #    3. Use -lnsl and -lsocket only if they supply procedures that
 566    #       aren't already present in the normal libraries.  This is because
 567    #       IRIX 5.2 has libraries, but they aren't needed and they're
 568    #       bogus:  they goof up name resolution if used.
 569    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 570    #       To get around this problem, check for both libraries together
 571    #       if -lsocket doesn't work by itself.
 572    #--------------------------------------------------------------------
 573
 574    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 575     [gcj_cv_lib_sockets=
 576      gcj_checkBoth=0
 577      unset ac_cv_func_connect
 578      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 579      if test "$gcj_checkSocket" = 1; then
 580          unset ac_cv_func_connect
 581          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 582                       gcj_checkBoth=1)
 583      fi
 584      if test "$gcj_checkBoth" = 1; then
 585          gcj_oldLibs=$LIBS
 586          LIBS="$LIBS -lsocket -lnsl"
 587          unset ac_cv_func_accept
 588          AC_CHECK_FUNC(accept,
 589                        [gcj_checkNsl=0
 590                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 591          unset ac_cv_func_accept
 592          LIBS=$gcj_oldLibs
 593      fi
 594      unset ac_cv_func_gethostbyname
 595      gcj_oldLibs=$LIBS
 596      LIBS="$LIBS $gcj_cv_lib_sockets"
 597      AC_CHECK_FUNC(gethostbyname, ,
 598                    [AC_CHECK_LIB(nsl, main,
 599                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 600      unset ac_cv_func_gethostbyname
 601      LIBS=$gcj_oldLIBS
 602    ])
 603    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 604
 605    if test "$with_system_zlib" = yes; then
 606       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 607    else
 608       ZLIBSPEC=-lzgcj
 609       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 610    fi
 611
 612    # On Solaris, and maybe other architectures, the Boehm collector
 613    # requires -ldl.
 614    if test "$GC" = boehm; then
 615       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 616    fi
 617
 618    if test -z "${with_multisubdir}"; then
 619       builddotdot=.
 620    else
 621 changequote(<<,>>)
 622       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 623 changequote([,])
 624    fi
 625    if test -x "${builddotdot}/../../gcc/gcj"; then
 626       dir="`cd ${builddotdot}/../../gcc && pwd`"
 627       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 628    else
 629       CANADIAN=yes
 630       NULL_TARGET=yes
 631       GCJ="gcj -B`pwd`/"
 632    fi
 633 fi
 634
 635 # Create it, so that compile/link tests don't fail
 636 test -f libgcj.spec || touch libgcj.spec
 637
 638 LT_AC_PROG_GCJ
 639
 640 dnl FIXME: cross compilation
 641 AC_CHECK_SIZEOF(void *)
 642
 643 ZLIBS=
 644 ZDEPS=
 645 ZINCS=
 646 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 647    # We include the path to the zlib build directory.
 648    # See Makefile.am to understand why.
 649    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 650    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 651    ZINCS='-I$(top_srcdir)/../zlib'
 652 else
 653    ZLIBS="$ZLIBSPEC"
 654 fi
 655 AC_SUBST(ZLIBS)
 656 AC_SUBST(ZDEPS)
 657 AC_SUBST(ZINCS)
 658 AC_SUBST(DIVIDESPEC)
 659
 660 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 661 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 662 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 663 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 664 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 665 AC_SUBST(GCC_UNWIND_INCLUDE)
 666
 667 # Determine gcj version number.
 668 changequote(<<,>>)
 669 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 670 changequote([,])
 671 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 672 AC_SUBST(GCJVERSION)
 673
 674 AC_SUBST(AM_RUNTESTFLAGS)
 675
 676 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 677 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 678 save_CFLAGS="$CFLAGS"
 679 CFLAGS="-x c++ -O2 -ffloat-store"
 680 AC_TRY_COMPILE([#include <math.h>], ,
 681   [AC_MSG_RESULT(no)],
 682   [AC_DEFINE(__NO_MATH_INLINES)
 683    AC_MSG_RESULT(yes)])
 684 CFLAGS="$save_CFLAGS"
 685
 686 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 687 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 688 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 689 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 690 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 691 dnl for now.  If you change this, you also must update natFile.cc.
 692 AC_CHECK_HEADERS(dirent.h)
 693
 694 AC_CHECK_TYPE([ssize_t], [int])
 695
 696 AC_MSG_CHECKING([for in_addr_t])
 697 AC_TRY_COMPILE([#include <sys/types.h>
 698 #if STDC_HEADERS
 699 #include <stdlib.h>
 700 #include <stddef.h>
 701 #endif
 702 #if HAVE_NETINET_IN_H
 703 #include <netinet/in.h>
 704 #endif], [in_addr_t foo;],
 705   [AC_DEFINE([HAVE_IN_ADDR_T])
 706    AC_MSG_RESULT(yes)],
 707   [AC_MSG_RESULT(no)])
 708
 709 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 710 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 711   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 712    AC_MSG_RESULT(yes)],
 713   [AC_MSG_RESULT(no)])
 714
 715 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 716 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 717   [AC_DEFINE(HAVE_INET6)
 718    AC_MSG_RESULT(yes)],
 719   [AC_MSG_RESULT(no)])
 720
 721 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 722 AC_TRY_COMPILE([#include <sys/types.h>
 723 #include <sys/socket.h>], [socklen_t x = 5;],
 724   [AC_DEFINE(HAVE_SOCKLEN_T)
 725    AC_MSG_RESULT(yes)],
 726   [AC_MSG_RESULT(no)])
 727
 728 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 729 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 730   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 731    AC_MSG_RESULT(yes)],
 732   [AC_MSG_RESULT(no)
 733    AC_MSG_CHECKING([for global timezone variable])
 734    dnl FIXME: we don't want a link check here because that won't work
 735    dnl when cross-compiling.  So instead we make an assumption that
 736    dnl the header file will mention timezone if it exists.
 737    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 738      [AC_DEFINE(HAVE_TIMEZONE)
 739       AC_MSG_RESULT(yes)],
 740      [AC_MSG_RESULT(no)])])
 741
 742 AC_FUNC_ALLOCA
 743
 744 AC_CHECK_PROGS(PERL, perl, false)
 745
 746 SYSDEP_SOURCES=
 747
 748 case "${host}" in
 749  i?86-*-linux*)
 750     SIGNAL_HANDLER=include/i386-signal.h
 751     ;;
 752  sparc-sun-solaris*)
 753     SIGNAL_HANDLER=include/sparc-signal.h
 754     ;;
 755  ia64-*)
 756     SYSDEP_SOURCES=sysdep/ia64.c
 757     test -d sysdep || mkdir sysdep
 758     ;;
 759  *)
 760     SIGNAL_HANDLER=include/default-signal.h
 761     ;;
 762 esac
 763
 764 # If we're using sjlj exceptions, forget what we just learned.
 765 if test "$libgcj_sjlj" = yes; then
 766    SIGNAL_HANDLER=include/default-signal.h
 767 fi
 768
 769 AC_SUBST(SYSDEP_SOURCES)
 770
 771 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 772
 773 if test "${multilib}" = "yes"; then
 774   multilib_arg="--enable-multilib"
 775 else
 776   multilib_arg=
 777 fi
 778
 779 AC_PATH_XTRA
 780
 781 dnl Determine which AWT peer libraries to build
 782 AC_ARG_ENABLE(java-awt,
 783 [  --enable-java-awt       list of AWT peer implementations to be built])
 784
 785 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 786 use_xlib_awt=""
 787 use_gtk_awt=""
 788
 789 for peer in $peerlibs ; do
 790   case $peer in
 791     xlib)
 792       if [test "$no_x" = yes]; then
 793         echo "*** xlib peers requested but no X library available" 1>&2
 794         exit 1
 795       else
 796         use_xlib_awt="yes"
 797       fi
 798       ;;
 799     gtk)
 800       # Nothing, yet...
 801       ;;
 802     *)
 803       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 804       exit 1
 805   esac
 806 done
 807
 808 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 809 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 810
 811
 812 here=`pwd`
 813 AC_SUBST(here)
 814
 815 # We get this from the environment.
 816 AC_SUBST(GCJFLAGS)
 817
 818 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 819 [if test -n "$CONFIG_FILES"; then
 820   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 821 fi
 822
 823 # Make subdirectories and `.d' files.  Look in both srcdir and
 824 # builddir for the .java files.
 825 h=`pwd`
 826 : > deps.mk
 827 ( (cd $srcdir && find . -name '*.java' -print) ;
 828   find . -name '*.java' -print) | \
 829    fgrep -v testsuite | \
 830    sed -e 's/\.java/.d/' | \
 831    while read f; do
 832       echo "include $f" >> deps.mk
 833       test -f $f || {
 834 changequote(<<,>>)
 835          d=`echo $f | sed -e 's,/[^/]*$,,'`
 836 changequote([,])
 837          $srcdir/../mkinstalldirs $d
 838          echo > $f
 839       }
 840    done
 841 ],
 842 srcdir=${srcdir}
 843 host=${host}
 844 target=${target}
 845 with_multisubdir=${with_multisubdir}
 846 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 847 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 848 libgcj_basedir=${libgcj_basedir}
 849 CC="${CC}"
 850 CXX="${CXX}"
 851 )