libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
  12 AC_ARG_WITH(cross-host,
  13 [  --with-cross-host=HOST           Configuring with a cross compiler])
  14
  15 LIBGCJ_CONFIGURE(.)
  16
  17 AM_CONFIG_HEADER(include/config.h)
  18
  19 AM_PROG_LIBTOOL
  20
  21 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  22    COMPPATH=.
  23 else
  24    COMPPATH=..
  25 fi
  26 AC_SUBST(COMPPATH)
  27
  28 dnl The -no-testsuite modules omit the test subdir.
  29 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  30
  31 dnl See whether the user prefers size or speed for Character.
  32 dnl The default is size.
  33 AC_ARG_ENABLE(fast-character,
  34 [  --enable-fast-character          Prefer speed over size for Character],
  35 # Nothing
  36 , AC_DEFINE(COMPACT_CHARACTER))
  37
  38 dnl See if the user has requested runtime debugging.
  39 AC_ARG_ENABLE(libgcj-debug,
  40 [  --enable-libgcj-debug           Enable runtime debugging code],
  41   if test "$enable_libgcj_debug" = yes; then
  42      AC_DEFINE(DEBUG)
  43   fi)
  44
  45 dnl If the target is an eCos system, use the appropriate eCos
  46 dnl I/O routines.
  47 dnl FIXME: this should not be a local option but a global target
  48 dnl system; at present there is no eCos target.
  49 TARGET_ECOS="no"
  50 AC_ARG_WITH(ecos,
  51 [  --with-ecos      Enable runtime eCos target support.],
  52 TARGET_ECOS="$with_ecos"
  53 )
  54
  55 case "$TARGET_ECOS" in
  56    no)
  57       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
  58       ;;
  59    *)
  60       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
  61       AC_DEFINE(ECOS)
  62       ;;
  63 esac
  64
  65 AC_EGREP_HEADER(__uint32_t, sys/types.h, AC_DEFINE(HAVE_INT32_DEFINED))
  66 AC_EGREP_HEADER(__uint32_t, sys/config.h, AC_DEFINE(HAVE_INT32_DEFINED))
  67
  68 dnl These may not be defined in a non-ANS conformant embedded system.
  69 dnl FIXME: Should these case a runtime exception in that case?
  70 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
  71 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
  72
  73 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
  74 dnl to create the link will fail.
  75 test -d java || mkdir java
  76 test -d java/io || mkdir java/io
  77 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
  78
  79 dnl Allow the GC to be disabled.  Can be useful when debugging.
  80 AC_MSG_CHECKING([for garbage collector to use])
  81 AC_ARG_ENABLE(java-gc,
  82 changequote(<<,>>)dnl
  83 <<  --enable-java-gc=TYPE    choose garbage collector [boehm]>>,
  84 changequote([,])
  85   GC=$enableval,
  86   GC=boehm)
  87 GCLIBS=
  88 GCINCS=
  89 GCDEPS=
  90 GCOBJS=
  91 case "$GC" in
  92  boehm)
  93     AC_MSG_RESULT(boehm)
  94     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
  95     GCLIBS="$GCDEPS"
  96     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
  97     dnl We also want to pick up some cpp flags required when including
  98     dnl boehm-config.h.  Yuck.
  99     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 100     GCOBJS=boehm.lo
 101     GCHDR=boehm-gc.h
 102     dnl The POSIX thread support needs to know this.
 103     AC_DEFINE(HAVE_BOEHM_GC)
 104     ;;
 105  no)
 106     AC_MSG_RESULT(none)
 107     GCOBJS=nogc.lo
 108     GCHDR=no-gc.h
 109     ;;
 110  *)
 111     AC_MSG_ERROR(unrecognized collector \"$GC\")
 112     ;;
 113 esac
 114 AC_SUBST(GCLIBS)
 115 AC_SUBST(GCINCS)
 116 AC_SUBST(GCDEPS)
 117 AC_SUBST(GCOBJS)
 118 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 119
 120
 121 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 122 dnl In particular both packages must make the same decision about which
 123 dnl thread package to use.
 124 AC_MSG_CHECKING([for threads package to use])
 125 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE    choose threading package],
 126   THREADS=$enableval,
 127   dnl FIXME: figure out native threads to use here.
 128   THREADS=no)
 129
 130 if test "$THREADS" = yes; then
 131    case "$host" in
 132     *-*-vxworks*)
 133        THREADS=vxworks
 134        ;;
 135     *-*-linux*)
 136        # FIXME: this isn't correct in all cases.
 137        THREADS=posix
 138        ;;
 139     *-*-win*)
 140        THREADS=win32
 141        ;;
 142     *-*-irix*)
 143        THREADS=irix
 144        ;;
 145     *-*-solaris*)
 146        # FIXME: for now, choose POSIX, because we implement that.
 147        # Later, choose solaris threads.
 148        THREADS=posix
 149        ;;
 150     *)
 151        # For now.
 152        THREADS=none
 153        ;;
 154    esac
 155 fi
 156
 157 case "$THREADS" in
 158  no | none | single)
 159     THREADS=none
 160     ;;
 161  posix | pthreads)
 162     THREADS=posix
 163     case "$host" in
 164      *-*-linux*)
 165         AC_DEFINE(LINUX_THREADS)
 166         ;;
 167     esac
 168     ;;
 169  qt)
 170     ;;
 171  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 172     AC_MSG_ERROR(thread package $THREADS not yet supported)
 173     ;;
 174  *)
 175     AC_MSG_ERROR($THREADS is an unknown thread package)
 176     ;;
 177 esac
 178 AC_MSG_RESULT($THREADS)
 179
 180 THREADLIBS=
 181 THREADINCS=
 182 THREADDEPS=
 183 THREADOBJS=
 184 THREADH=
 185 case "$THREADS" in
 186  posix)
 187     THREADLIBS=-lpthread
 188     THREADOBJS=posix-threads.lo
 189     THREADH=posix-threads.h
 190     # MIT pthreads doesn't seem to have the mutexattr functions.
 191     # But for now we don't check for it.  We just assume you aren't
 192     # using MIT pthreads.
 193     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 194     ;;
 195
 196  qt)
 197     THREADDEPS='$(top_builddir)/../qthreads/libgcjcoop.la'
 198     THREADLIBS="$THREADDEPS"
 199     THREADOBJS=quick-threads.lo
 200     THREADINCS='-I$(top_srcdir)/../qthreads'
 201     THREADH=quick-threads.h
 202     ;;
 203
 204  none)
 205     THREADOBJS=no-threads.lo
 206     THREADH=no-threads.h
 207     ;;
 208 esac
 209 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 210 AC_SUBST(THREADLIBS)
 211 AC_SUBST(THREADINCS)
 212 AC_SUBST(THREADDEPS)
 213 AC_SUBST(THREADOBJS)
 214
 215 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 216
 217 CANADIAN=no
 218 NULL_TARGET=no
 219
 220 # Find eh-common.h and support headers.  If we're in the tree with
 221 # gcc, then look there.  Otherwise look in compat-include.  If all else
 222 # fails, just hope the user has set things up somehow.
 223 if test -r $srcdir/../gcc/eh-common.h; then
 224    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 225 else
 226    if test -d $srcdir/../compat-include; then
 227       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 228    else
 229       EH_COMMON_INCLUDE=
 230    fi
 231 fi
 232
 233 if test -n "${with_cross_host}"; then
 234    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 235    # may not work correctly, because the compiler may not be able to
 236    # link executables.
 237
 238    # We assume newlib.  This lets us hard-code the functions we know
 239    # we'll have.
 240    AC_DEFINE(HAVE_MEMMOVE)
 241    AC_DEFINE(HAVE_MEMCPY)
 242    AC_DEFINE(HAVE_STRERROR)
 243    AC_DEFINE(HAVE_CTIME_R)
 244    AC_DEFINE(HAVE_GMTIME_R)
 245    AC_DEFINE(HAVE_LOCALTIME_R)
 246    dnl This is only for POSIX threads.
 247    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 248    dnl We also assume we are using gcc, which provides alloca.
 249    AC_DEFINE(HAVE_ALLOCA)
 250
 251    # If Canadian cross, then don't pick up tools from the build
 252    # directory.
 253    if test "$build" != "$with_cross_host"; then
 254       CANADIAN=yes
 255       EH_COMMON_INCLUDE=
 256    fi
 257 else
 258    # Some POSIX thread systems don't have pthread_mutexattr_settype.
 259    # E.g., Solaris.
 260    AC_CHECK_FUNCS(strerror ioctl select open fsync sleep)
 261    AC_CHECK_FUNCS(ctime_r ctime, break)
 262    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r)
 263    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 264    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 265    AC_CHECK_FUNCS(inet_pton uname)
 266
 267    AC_CHECK_FUNCS(gethostbyname_r, [
 268      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 269      # There are two different kinds of gethostbyname_r.
 270      # We look for the one that returns `int'.
 271      # Hopefully this check is robust enough.
 272      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 273        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])])
 274
 275    AC_CHECK_FUNCS(gethostbyaddr_r, [
 276      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 277      # There are two different kinds of gethostbyaddr_r.
 278      # We look for the one that returns `int'.
 279      # Hopefully this check is robust enough.
 280      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 281        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 282
 283    AC_CHECK_FUNCS(gethostname, [
 284      AC_DEFINE(HAVE_GETHOSTNAME)
 285      AC_EGREP_HEADER(gethostname, unistd.h, [
 286        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 287
 288    # Look for these functions in the thread library.
 289    save_LIBS="$LIBS"
 290    LIBS="$LIBS $THREADLIBS"
 291    AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np sched_yield)
 292    LIBS="$save_LIBS"
 293
 294    # We require a way to get the time.
 295    time_found=no
 296    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 297    if test "$time_found" = no; then
 298       AC_MSG_ERROR([no function found to get the time])
 299    fi
 300
 301    # We require memmove.
 302    memmove_found=no
 303    AC_CHECK_FUNCS(memmove, memmove_found=yes)
 304    if test "$memmove_found" = no; then
 305       AC_MSG_ERROR([memmove is required])
 306    fi
 307
 308    # We require memcpy.
 309    memcpy_found=no
 310    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 311    if test "$memcpy_found" = no; then
 312       AC_MSG_ERROR([memcpy is required])
 313    fi
 314
 315    test -d "$libgcj_basedir/../gcc/java" || {
 316       CANADIAN=yes
 317       NULL_TARGET=yes
 318    }
 319 fi
 320
 321 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 322 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 323 AM_CONDITIONAL(NATIVE, test "$CANADIAN" = no || test "$NULL_TARGET" = yes)
 324
 325 AC_SUBST(EH_COMMON_INCLUDE)
 326
 327 AC_SUBST(AM_RUNTESTFLAGS)
 328
 329 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 330 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 331 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 332 AC_CHECK_HEADERS(unistd.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h)
 333 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 334 dnl for now.  If you change this, you also must update natFile.cc.
 335 AC_CHECK_HEADERS(dirent.h)
 336
 337 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 338 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 339   [AC_DEFINE(HAVE_INET6)
 340    AC_MSG_RESULT(yes)],
 341   [AC_MSG_RESULT(no)])
 342
 343 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 344 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 345   [AC_DEFINE(HAVE_SOCKLEN_T)
 346    AC_MSG_RESULT(yes)],
 347   [AC_MSG_RESULT(no)])
 348
 349 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 350 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 351   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 352    AC_MSG_RESULT(yes)],
 353   [AC_MSG_RESULT(no)
 354    AC_MSG_CHECKING([for global timezone variable])
 355    dnl FIXME: we don't want a link check here because that won't work
 356    dnl when cross-compiling.  So instead we make an assumption that
 357    dnl the header file will mention timezone if it exists.
 358    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 359      [AC_DEFINE(HAVE_TIMEZONE)
 360       AC_MSG_RESULT(yes)],
 361      [AC_MSG_RESULT(no)])])
 362
 363 AC_FUNC_ALLOCA
 364
 365 AC_CHECK_PROGS(PERL, perl, false)
 366
 367 case "${host}" in
 368   i?86-*-linux*)
 369     SIGNAL_HANDLER=include/i386-signal.h
 370         ;;
 371   sparc-sun-solaris*)
 372     SIGNAL_HANDLER=include/sparc-signal.h
 373         ;;
 374   *)
 375     SIGNAL_HANDLER=include/default-signal.h
 376         ;;
 377 esac
 378
 379 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 380
 381 if test "${multilib}" = "yes"; then
 382   multilib_arg="--enable-multilib"
 383 else
 384   multilib_arg=
 385 fi
 386
 387 here=`pwd`
 388 AC_SUBST(here)
 389
 390 AC_OUTPUT(Makefile testsuite/Makefile,
 391 [if test -n "$CONFIG_FILES"; then
 392   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 393 fi],
 394 srcdir=${srcdir}
 395 host=${host}
 396 target=${target}
 397 with_multisubdir=${with_multisubdir}
 398 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 399 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 400 libgcj_basedir=${libgcj_basedir}
 401 CC="${CC}"
 402 CXX="${CXX}"
 403 )