libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 # We use these options to decide which functions to include.
   9 AC_ARG_WITH(target-subdir,
  10   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  11                  [configure in a subdirectory]))
  12
  13 # We may get other options which we don't document:
  14 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  15
  16 # When building with srcdir == objdir, links to the source files will
  17 # be created in directories within the target_subdir.  We have to
  18 # adjust toplevel_srcdir accordingly, so that configure finds
  19 # install-sh and other auxiliary files that live in the top-level
  20 # source directory.
  21 if test "${srcdir}" = "."; then
  22   if test -z "${with_target_subdir}"; then
  23     toprel=".."
  24   else
  25     if test "${with_target_subdir}" != "."; then
  26       toprel="${with_multisrctop}../.."
  27     else
  28       toprel="${with_multisrctop}.."
  29     fi
  30   fi
  31 else
  32   toprel=".."
  33 fi
  34
  35 libgcj_basedir=$srcdir/$toprel/./libjava
  36 AC_SUBST(libgcj_basedir)
  37
  38 AC_CANONICAL_SYSTEM
  39 _GCC_TOPLEV_NONCANONICAL_BUILD
  40 _GCC_TOPLEV_NONCANONICAL_TARGET
  41
  42 AC_SUBST(target_noncanonical)
  43
  44 # This works around the fact that libtool configuration may change LD
  45 # for this particular configuration, but some shells, instead of
  46 # keeping the changes in LD private, export them just because LD is
  47 # exported.
  48 ORIGINAL_LD_FOR_MULTILIBS=$LD
  49
  50 AC_PROG_LN_S
  51
  52 # This works around an automake problem.
  53 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  54 AC_SUBST(mkinstalldirs)
  55
  56 AC_ARG_WITH(cross-host,
  57   AS_HELP_STRING([--with-cross-host=HOST],
  58                  [configure with a cross compiler from HOST]))
  59
  60 AC_ARG_WITH(newlib,
  61   AS_HELP_STRING([--with-newlib],
  62                  [configure with newlib]))
  63
  64 AC_ARG_ENABLE(version-specific-runtime-libs,
  65   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  67     [case "$enableval" in
  68       yes) version_specific_libs=yes ;;
  69       no)  version_specific_libs=no ;;
  70       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71      esac],
  72     [version_specific_libs=no]
  73 )
  74
  75 # Default to --enable-multilib
  76 AC_ARG_ENABLE(multilib,
  77   AS_HELP_STRING([--enable-multilib],
  78                  [build many library versions (default)]),
  79 [case "${enableval}" in
  80   yes) multilib=yes ;;
  81   no)  multilib=no ;;
  82   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  83  esac], [multilib=yes])dnl
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
  99 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 100 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 101 save_CXXFLAGS="$CXXFLAGS"
 102 CXXFLAGS="$CXXFLAGS -fno-builtin"
 103 AC_PROG_CC
 104 AC_PROG_CXX
 105 CXXFLAGS="$save_CXXFLAGS"
 106 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107 AC_SUBST(CFLAGS)
 108 AC_SUBST(CXXFLAGS)
 109 AC_SUBST(LDFLAGS)
 110
 111 AM_INIT_AUTOMAKE([1.9.0])
 112
 113 AC_CHECK_TOOL(AS, as)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 AC_PROG_INSTALL
 118
 119 AM_MAINTAINER_MODE
 120
 121 AC_EXEEXT
 122
 123 # configure.host sets the following important variables
 124 #       libgcj_cflags    - host specific C compiler flags
 125 #       libgcj_cxxflags  - host specific C++ compiler flags
 126 #       libgcj_javaflags - host specific Java compiler flags
 127
 128 libgcj_cflags=
 129 libgcj_cxxflags=
 130 libgcj_javaflags=
 131
 132 . ${srcdir}/configure.host
 133
 134 LIBGCJ_CFLAGS="${libgcj_cflags}"
 135 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 136 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 137 AC_SUBST(LIBGCJ_CFLAGS)
 138 AC_SUBST(LIBGCJ_CXXFLAGS)
 139 AC_SUBST(LIBGCJ_JAVAFLAGS)
 140
 141 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 142
 143 # Only use libltdl for non-newlib builds.
 144 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 145    AC_LIBLTDL_CONVENIENCE
 146    AC_LIBTOOL_DLOPEN
 147    DIRLTDL=libltdl
 148    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 149    # Sigh.  Libtool's macro doesn't do the right thing.
 150    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 151    # FIXME: this is a hack.
 152    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 153    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 154 fi
 155 AC_SUBST(INCLTDL)
 156 AC_SUBST(LIBLTDL)
 157 AC_SUBST(DIRLTDL)
 158 AC_PROG_LIBTOOL
 159 AM_PROG_GCJ
 160 AM_PROG_CC_C_O
 161 AC_CONFIG_SUBDIRS(libltdl)
 162
 163 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
 164    COMPPATH=.
 165 else
 166    COMPPATH=..
 167 fi
 168 AC_SUBST(COMPPATH)
 169
 170 # The -no-testsuite modules omit the test subdir.
 171 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 172
 173 # Should the runtime set system properties by examining the
 174 # environment variable GCJ_PROPERTIES?
 175 AC_ARG_ENABLE(getenv-properties,
 176   AS_HELP_STRING([--disable-getenv-properties],
 177                  [don't set system properties from GCJ_PROPERTIES]))
 178
 179 # Whether GCJ_PROPERTIES is used depends on the target.
 180 if test -z "$enable_getenv_properties"; then
 181    enable_getenv_properties=${enable_getenv_properties_default-yes}
 182 fi
 183 if test "$enable_getenv_properties" = no; then
 184    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 185      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 186 fi
 187
 188 # Whether we should use arguments to main()
 189 if test -z "$enable_main_args"; then
 190    enable_main_args=${enable_main_args_default-yes}
 191 fi
 192 if test "$enable_main_args" = no; then
 193    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 194 fi
 195
 196
 197 # Should we use hashtable-based synchronization?
 198 # Currently works only for Linux X86/ia64
 199 # Typically faster and more space-efficient
 200 AC_ARG_ENABLE(hash-synchronization,
 201   AS_HELP_STRING([--enable-hash-synchronization],
 202                  [use global hash table for monitor locks]))
 203
 204 if test -z "$enable_hash_synchronization"; then
 205    enable_hash_synchronization=$enable_hash_synchronization_default
 206 fi
 207
 208 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 209 AC_ARG_ENABLE(libgcj-multifile,
 210   AS_HELP_STRING([--enable-libgcj-multifile]
 211                  [allow compilation of several files at once]),
 212 [case "${enableval}" in
 213   yes) enable_libgcj_multifile=yes ;;
 214   no)  enable_libgcj_multifile=no ;;
 215   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 216 esac],[enable_libgcj_multifile=no])
 217 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 218
 219 # What is the native OS API for MinGW?
 220 AC_ARG_WITH(win32-nlsapi,
 221   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 222                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 223 [case "${withval}" in
 224   ansi) with_win32_nlsapi=ansi ;;
 225   unicows) with_win32_nlsapi=unicows ;;
 226   unicode) with_win32_nlsapi=unicode ;;
 227   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 228 esac],[with_win32_nlsapi=ansi])
 229
 230 case "${with_win32_nlsapi}" in
 231   unicows | unicode)
 232     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 233       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 234     ;;
 235 esac
 236
 237 # configure.host sets slow_pthread_self if the synchronization code should
 238 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 239 if test "${slow_pthread_self}" = "yes"; then
 240   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 241     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 242 fi
 243
 244
 245 # See if the user has requested runtime debugging.
 246 LIBGCJDEBUG="false"
 247 AC_SUBST(LIBGCJDEBUG)
 248 AC_ARG_ENABLE(libgcj-debug,
 249   AS_HELP_STRING([--enable-libgcj-debug],
 250                  [enable runtime debugging code]),
 251   [if test "$enable_libgcj_debug" = yes; then
 252     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 253     LIBGCJDEBUG="true"
 254   fi])
 255
 256 # Check for gc debugging.  This option is handled both here and in the GC.
 257 AC_ARG_ENABLE(gc-debug,
 258    AS_HELP_STRING([--enable-gc-debug],
 259                   [include full support for pointer backtracing etc.]),
 260 [ if test "$enable_gc_debug" = "yes"; then
 261     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 262               [Define if we want to use debug calls into the garbage collector.])
 263   fi])
 264
 265 # See if the user has the interpreter included.
 266 AC_ARG_ENABLE(interpreter,
 267   AS_HELP_STRING([--enable-interpreter],
 268                  [enable interpreter]),
 269   [if test "$enable_interpreter" = yes; then
 270     # This can also be set in configure.host.
 271     libgcj_interpreter=yes
 272   elif test "$enable_interpreter" = no; then
 273     libgcj_interpreter=no
 274   fi])
 275
 276 if test "$libgcj_interpreter" = yes; then
 277    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 278 fi
 279 INTERPRETER="$libgcj_interpreter"
 280 AC_SUBST(INTERPRETER)
 281
 282 AC_MSG_CHECKING([for exception model to use])
 283 AC_LANG_PUSH(C++)
 284 AC_ARG_ENABLE(sjlj-exceptions,
 285   AS_HELP_STRING([--enable-sjlj-exceptions],
 286                  [force use of builtin_setjmp for exceptions]),
 287 [:],
 288 [dnl Botheration.  Now we've got to detect the exception model.
 289 dnl Link tests against libgcc.a are problematic since -- at least
 290 dnl as of this writing -- we've not been given proper -L bits for
 291 dnl single-tree newlib and libgloss.
 292 dnl
 293 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 294 dnl conftest files before we got a change to grep them first.
 295 cat > conftest.$ac_ext << EOF
 296 [#]line __oline__ "configure"
 297 struct S { ~S(); };
 298 void bar();
 299 void foo()
 300 {
 301   S s;
 302   bar();
 303 }
 304 EOF
 305 old_CXXFLAGS="$CXXFLAGS"
 306 CXXFLAGS=-S
 307 if AC_TRY_EVAL(ac_compile); then
 308   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 309     enable_sjlj_exceptions=yes
 310   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 311     enable_sjlj_exceptions=no
 312   fi
 313 fi
 314 CXXFLAGS="$old_CXXFLAGS"
 315 rm -f conftest*])
 316 if test x$enable_sjlj_exceptions = xyes; then
 317   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 318         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 319   ac_exception_model_name=sjlj
 320 elif test x$enable_sjlj_exceptions = xno; then
 321   ac_exception_model_name="call frame"
 322 else
 323   AC_MSG_ERROR([unable to detect exception model])
 324 fi
 325 AC_LANG_POP(C++)
 326 AC_MSG_RESULT($ac_exception_model_name)
 327
 328 # If we are non using SJLJ exceptions, and this host does not have support
 329 # for unwinding from a signal handler, enable checked dereferences and divides.
 330 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 331   CHECKREFSPEC=-fcheck-references
 332   DIVIDESPEC=-fuse-divide-subroutine
 333   EXCEPTIONSPEC=
 334 fi
 335
 336 # See if the user wants to disable java.net.  This is the mildly
 337 # ugly way that we admit that target-side configuration sucks.
 338 AC_ARG_ENABLE(java-net,
 339   AS_HELP_STRING([--disable-java-net],
 340                  [disable java.net]))
 341
 342 # Whether java.net is built by default can depend on the target.
 343 if test -z "$enable_java_net"; then
 344    enable_java_net=${enable_java_net_default-yes}
 345 fi
 346 if test "$enable_java_net" = no; then
 347    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 348 fi
 349
 350 # See if the user wants to configure without libffi.  Some
 351 # architectures don't support it, and default values are set in
 352 # configure.host.
 353 AC_ARG_WITH(libffi,
 354   AS_HELP_STRING([--without-libffi],
 355                  [don't use libffi]),
 356   [:],
 357   [with_libffi=${with_libffi_default-yes}])
 358
 359 LIBFFI=
 360 LIBFFIINCS=
 361 if test "$with_libffi" != no; then
 362    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 363    LIBFFI=../libffi/libffi_convenience.la
 364    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 365 fi
 366 AC_SUBST(LIBFFI)
 367 AC_SUBST(LIBFFIINCS)
 368
 369 # See if the user wants to disable JVMPI support.
 370 AC_ARG_ENABLE(jvmpi,
 371   AS_HELP_STRING([--disable-jvmpi],
 372                  [disable JVMPI support]))
 373
 374 if test "$enable_jvmpi" != no; then
 375     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 376 fi
 377
 378 # If the target is an eCos system, use the appropriate eCos
 379 # I/O routines.
 380 # FIXME: this should not be a local option but a global target
 381 # system; at present there is no eCos target.
 382 TARGET_ECOS=${PROCESS-"no"}
 383 AC_ARG_WITH(ecos,
 384 [  --with-ecos             enable runtime eCos target support],
 385 TARGET_ECOS="$with_ecos"
 386 )
 387
 388 supply_backtrace=no
 389
 390 PLATFORM_INNER_NAT_HDRS=
 391 case "$TARGET_ECOS" in
 392    no) case "$host" in
 393       *mingw*)
 394             PLATFORM=Win32
 395             PLATFORMNET=Win32
 396             PLATFORMH=win32.h
 397         CHECK_FOR_BROKEN_MINGW_LD
 398       ;;
 399       *)
 400             PLATFORM=Posix
 401             PLATFORMNET=Posix
 402             PLATFORMH=posix.h
 403             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 404       ;;
 405       esac
 406       ;;
 407    *)
 408       PLATFORM=Ecos
 409       PLATFORMNET=NoNet
 410       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 411       PLATFORMH=posix.h
 412       ;;
 413 esac
 414 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 415 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 416
 417 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 418                                       [Define if you have int32_t and uint32_t.]))
 419 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 420                                         [Define if you have int32_t and uint32_t.]))
 421 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 422                                           [Define if you have u_int32_t]))
 423 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 424                                            [Define if you have u_int32_t]))
 425
 426 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 427 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 428 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 429
 430 # These may not be defined in a non-ANS conformant embedded system.
 431 # FIXME: Should these case a runtime exception in that case?
 432 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 433                                   [Define is you have 'mktime' in <time.h>]))
 434 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 435                                   [Define is you have 'localtime' in <time.h>]))
 436
 437 # Create the subdirectory for natFile.cc, or the attempt
 438 # to create the link will fail.
 439 test -d java || mkdir java
 440 test -d java/io || mkdir java/io
 441 test -d gnu || mkdir gnu
 442 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 443
 444 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 445 test -d java/lang || mkdir java/lang
 446 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 447 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 448
 449 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 450 test -d java/net || mkdir java/net
 451 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 452 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 453
 454 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 455 test -d gnu/java || mkdir gnu/java
 456 test -d gnu/java/net || mkdir gnu/java/net
 457 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 458 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 459
 460 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 461 test -d gnu/java/nio || mkdir gnu/java/nio
 462 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 463 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 464 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 465 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 466
 467 case "${host}" in
 468     *mingw*)
 469       SYSTEMSPEC="-lgdi32 -lws2_32"
 470       if test "${with_win32_nlsapi}" = "unicows"; then
 471         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 472       fi
 473     ;;
 474     *)
 475       SYSTEMSPEC=
 476     ;;
 477 esac
 478 AC_SUBST(SYSTEMSPEC)
 479
 480 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 481 AC_SUBST(LIBGCJTESTSPEC)
 482
 483 AC_ARG_WITH(system-zlib,
 484   AS_HELP_STRING([--with-system-zlib],
 485                  [use installed libz]))
 486 ZLIBSPEC=
 487 AC_SUBST(ZLIBSPEC)
 488 ZLIBTESTSPEC=
 489 AC_SUBST(ZLIBTESTSPEC)
 490
 491 AC_PATH_XTRA
 492
 493 # Determine which AWT peer libraries to build
 494 AC_ARG_ENABLE(java-awt,
 495   AS_HELP_STRING([--enable-java-awt],
 496                  [list of AWT peer implementations to be built]))
 497
 498 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 499 use_xlib_awt=""
 500 use_gtk_awt=""
 501 # The default toolkit to use is the first one specified.
 502 TOOLKIT=
 503 AC_SUBST(TOOLKIT)
 504
 505 for peer in $peerlibs ; do
 506   case $peer in
 507     xlib)
 508       if test "$no_x" = yes; then
 509         echo "*** xlib peers requested but no X library available" 1>&2
 510         exit 1
 511       else
 512         use_xlib_awt="yes"
 513         if test -z "$TOOLKIT"; then
 514            TOOLKIT=gnu.awt.xlib.XToolkit
 515         fi
 516       fi
 517       ;;
 518     gtk)
 519       if test "$no_x" = yes; then
 520          echo "*** xlib peers requested but no X library available" 1>&2
 521          exit 1
 522       else
 523          use_gtk_awt=yes
 524          if test -z "$TOOLKIT"; then
 525             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 526          fi
 527          test -d jniinclude || mkdir jniinclude
 528       fi
 529       ;;
 530     no)
 531       use_xlib_awt=
 532       use_gtk_awt=
 533       break
 534       ;;
 535     *)
 536       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 537       exit 1
 538   esac
 539 done
 540
 541 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 542 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 543
 544 # determine whether to enable the cairo GTK Graphics2D backend
 545 AC_ARG_ENABLE(gtk-cairo,
 546   AS_HELP_STRING([--enable-gtk-cairo],
 547                  [build the cairo Graphics2D implementation on GTK]))
 548 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 549 if test "x${enable_gtk_cairo}" = xyes
 550 then
 551         PKG_CHECK_MODULES(CAIRO, cairo)
 552         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 553 fi
 554 AC_SUBST(CAIRO_LIBS)
 555 AC_SUBST(CAIRO_CFLAGS)
 556 AC_SUBST(PANGOFT2_LIBS)
 557 AC_SUBST(PANGOFT2_CFLAGS)
 558
 559 # FIXME: this should be _libs on some hosts.
 560 libsubdir=.libs
 561
 562 # Allow the GC to be disabled.  Can be useful when debugging.
 563 AC_MSG_CHECKING([for garbage collector to use])
 564 AC_ARG_ENABLE(java-gc,
 565   AS_HELP_STRING([--enable-java-gc=TYPE],
 566                  [choose garbage collector (default is boehm)]),
 567   [GC=$enableval],
 568   [GC=boehm])
 569 GCLIBS=
 570 GCINCS=
 571 GCDEPS=
 572 GCSPEC=
 573 JC1GCSPEC=
 574 GCTESTSPEC=
 575 case "$GC" in
 576  boehm)
 577     AC_MSG_RESULT(boehm)
 578     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 579     JC1GCSPEC='-fuse-boehm-gc'
 580     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 581     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 582     GCOBJS=boehm.lo
 583     GCHDR=boehm-gc.h
 584     # The POSIX thread support needs to know this.
 585     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 586     ;;
 587  no)
 588     AC_MSG_RESULT(none)
 589     GCHDR=no-gc.h
 590     ;;
 591  *)
 592     AC_MSG_ERROR([unrecognized collector "$GC"])
 593     ;;
 594 esac
 595 AC_SUBST(GCLIBS)
 596 AC_SUBST(GCINCS)
 597 AC_SUBST(GCDEPS)
 598 AC_SUBST(GCSPEC)
 599 AC_SUBST(JC1GCSPEC)
 600 AC_SUBST(GCTESTSPEC)
 601 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 602 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 603 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 604
 605
 606 AC_MSG_CHECKING([for thread model used by GCC])
 607 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 608 AC_MSG_RESULT([$THREADS])
 609
 610 case "$THREADS" in
 611  no | none | single)
 612     THREADS=none
 613     ;;
 614  posix | pthreads)
 615     THREADS=posix
 616     case "$host" in
 617      *-*-linux*)
 618         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 619         ;;
 620     esac
 621     ;;
 622  win32)
 623     ;;
 624  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 625     AC_MSG_ERROR(thread package $THREADS not yet supported)
 626     ;;
 627  *)
 628     AC_MSG_ERROR($THREADS is an unknown thread package)
 629     ;;
 630 esac
 631
 632 THREADCXXFLAGS=
 633 THREADLDFLAGS=
 634 THREADLIBS=
 635 THREADINCS=
 636 THREADDEPS=
 637 THREADH=
 638 THREADSPEC=
 639 case "$THREADS" in
 640  posix)
 641     case "$host" in
 642      *-*-cygwin*)
 643         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 644         ;;
 645      *-*-freebsd[[1234]]*)
 646         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 647         # merely adds pthread_* functions) but it does have a -pthread switch
 648         # which is required at link-time to select -lc_r *instead* of -lc.
 649         THREADLDFLAGS=-pthread
 650         # Don't set THREADSPEC here as might be expected since -pthread is
 651         # not processed when found within a spec file, it must come from
 652         # the command line.  For now, the user must provide the -pthread
 653         # switch to link code compiled with gcj.  In future, consider adding
 654         # support for weak references to pthread_* functions ala gthr.h API.
 655         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 656         ;;
 657      *-*-freebsd*)
 658         # FreeBSD 5 implements a model much closer to other modern UNIX
 659         # which support threads.  However, it still does not support
 660         # -lpthread.
 661         THREADLDFLAGS=-pthread
 662         THREADSPEC=-lc_r
 663         ;;
 664      alpha*-dec-osf*)
 665         THREADCXXFLAGS=-pthread
 666         # boehm-gc needs some functions from librt, so link that too.
 667         THREADLIBS='-lpthread -lrt'
 668         THREADSPEC='-lpthread -lrt'
 669         ;;
 670      *)
 671         THREADLIBS=-lpthread
 672         THREADSPEC=-lpthread
 673         ;;
 674     esac
 675     THREADH=posix-threads.h
 676     # MIT pthreads doesn't seem to have the mutexattr functions.
 677     # But for now we don't check for it.  We just assume you aren't
 678     # using MIT pthreads.
 679     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 680
 681     # If we're using the Boehm GC, then we happen to know that it
 682     # defines _REENTRANT, so we don't bother.  Eww.
 683     if test "$GC" != boehm; then
 684        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 685     fi
 686     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 687     ;;
 688
 689  win32)
 690     THREADH=win32-threads.h
 691     ;;
 692
 693  none)
 694     THREADH=no-threads.h
 695     ;;
 696 esac
 697 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 698 AC_SUBST(THREADLIBS)
 699 AC_SUBST(THREADINCS)
 700 AC_SUBST(THREADDEPS)
 701 AC_SUBST(THREADSPEC)
 702 AC_SUBST(THREADLDFLAGS)
 703 AC_SUBST(THREADCXXFLAGS)
 704 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 705 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 706 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 707
 708 if test -d sysdep; then true; else mkdir sysdep; fi
 709 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 710
 711 HASH_SYNC_SPEC=
 712 # Hash synchronization is only useful with posix threads right now.
 713 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 714    HASH_SYNC_SPEC=-fhash-synchronization
 715    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 716 fi
 717 AC_SUBST(HASH_SYNC_SPEC)
 718
 719
 720 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 721
 722 # We're in the tree with gcc, and need to include some of its headers.
 723 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 724
 725 # Figure out where generated headers like libgcj-config.h get installed.
 726 gcc_version_trigger=${libgcj_basedir}/../gcc/version.c
 727 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^\"]]*\)\".*/\1/'`
 728 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([[^ ]]*\) .*/\1/'`
 729 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 730 AC_SUBST(tool_include_dir)
 731 AC_SUBST(gcc_version)
 732
 733 if test "x${with_newlib}" = "xyes"; then
 734    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 735    # may not work correctly, because the compiler may not be able to
 736    # link executables.
 737
 738    # We assume newlib.  This lets us hard-code the functions we know
 739    # we'll have.
 740    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 741    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 742    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 743    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 744    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 745    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 746    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 747    # This is only for POSIX threads.
 748    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 749    # We also assume we are using gcc, which provides alloca.
 750    AC_DEFINE(HAVE_ALLOCA)
 751
 752    # Assume we do not have getuid and friends.
 753    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 754    PLATFORMNET=NoNet
 755 else
 756    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 757    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 758    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 759    AC_CHECK_FUNCS(nl_langinfo setlocale)
 760    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 761    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 762    AC_CHECK_FUNCS(fork execvp pipe sigaction ftruncate)
 763    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 764    AC_CHECK_FUNC(backtrace, [
 765      case "$host" in
 766        ia64-*-linux*)
 767          # Has broken backtrace()
 768          ;;
 769        mips*-*-linux*)
 770          # Has broken backtrace(), but we supply our own.
 771          if test -d sysdep; then true; else mkdir -p sysdep; fi
 772          supply_backtrace=yes
 773          AC_DEFINE(HAVE_BACKTRACE, 1,
 774            [Define if your platform has a working backtrace() function.])
 775          ;;
 776        *)
 777          AC_DEFINE(HAVE_BACKTRACE, 1,
 778            [Define if your platform has a working backtrace() function.])
 779          ;;
 780      esac
 781    ], [
 782      case "$host" in
 783        *mingw*)
 784          # Has backtrace() defined in libgcj itself
 785          AC_DEFINE(HAVE_BACKTRACE, 1,
 786            [Define if your platform has a working backtrace() function.])
 787          ;;
 788      esac
 789    ])
 790
 791    AC_CHECK_LIB(dl, dladdr, [
 792      if test "x${disable_dladdr}" = "xyes"; then
 793        #Broken dladdr().
 794        true
 795      else
 796        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 797      fi
 798    ])
 799    if test x"$build" = x"$host"; then
 800      AC_CHECK_FILES(/proc/self/exe, [
 801        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 802    else
 803      case $host in
 804      *-linux*)
 805        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 806        ;;
 807      esac
 808    fi
 809
 810    AM_ICONV
 811    AM_LC_MESSAGES
 812    AC_STRUCT_TIMEZONE
 813
 814    AC_CHECK_FUNCS(gethostbyname_r, [
 815      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 816        [Define if you have the 'gethostbyname_r' function.])
 817      # There are two different kinds of gethostbyname_r.
 818      # We look for the one that returns `int'.
 819      # Hopefully this check is robust enough.
 820      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 821        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 822
 823      case " $GCINCS " in
 824      *" -D_REENTRANT "*) ;;
 825      *)
 826         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 827         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 828         [libjava_cv_gethostbyname_r_needs_reentrant],
 829         [ AC_LANG_PUSH(C++)
 830           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 831             [[gethostbyname_r("", 0, 0);]])],
 832             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 833                 CPPFLAGS_SAVE="$CPPFLAGS"
 834                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 835                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 836                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 837                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 838                 CPPFLAGS="$CPPFLAGS_SAVE"
 839           ])
 840           AC_LANG_POP(C++)
 841         ])
 842         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 843           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 844         fi
 845      ;;
 846      esac
 847
 848      AC_CACHE_CHECK([for struct hostent_data],
 849         [libjava_cv_struct_hostent_data], [dnl
 850         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 851 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 852 # define _REENTRANT 1
 853 #endif
 854 #include <netdb.h>]], [[struct hostent_data data;]])],
 855           [libjava_cv_struct_hostent_data=yes],
 856           [libjava_cv_struct_hostent_data=no])])
 857      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 858        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 859          [Define if struct hostent_data is defined in netdb.h])
 860      fi
 861    ])
 862
 863    # FIXME: libjava source code expects to find a prototype for
 864    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 865    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 866    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 867    # linkage check is enough, yet C++ code requires proper prototypes.)
 868    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 869    AC_CHECK_FUNCS(gethostbyaddr_r, [
 870      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 871        [Define if you have the 'gethostbyaddr_r' function.])
 872      # There are two different kinds of gethostbyaddr_r.
 873      # We look for the one that returns `int'.
 874      # Hopefully this check is robust enough.
 875      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 876        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 877          [Define if gethostbyaddr_r returns 'int'.])])])])
 878
 879    AC_CHECK_FUNCS(gethostname, [
 880      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 881        [Define if you have the 'gethostname' function.])
 882      AC_EGREP_HEADER(gethostname, unistd.h, [
 883        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 884          [Define if gethostname is declared in <unistd.h>.])])])
 885
 886    AC_CHECK_FUNCS(usleep, [
 887      AC_EGREP_HEADER(usleep, unistd.h, [
 888        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 889           [Define if usleep is declared in <unistd.h>.])])])
 890
 891    # Look for these functions in the thread library, but only bother
 892    # if using POSIX threads.
 893    if test "$THREADS" = posix; then
 894       save_LIBS="$LIBS"
 895       LIBS="$LIBS $THREADLIBS"
 896       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 897       # E.g., Solaris.
 898       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 899
 900       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 901       # Solaris 7 the name librt is preferred.
 902       AC_CHECK_FUNCS(sched_yield, , [
 903         AC_CHECK_LIB(rt, sched_yield, [
 904           AC_DEFINE(HAVE_SCHED_YIELD)
 905           THREADLIBS="$THREADLIBS -lrt"
 906           THREADSPEC="$THREADSPEC -lrt"], [
 907           AC_CHECK_LIB(posix4, sched_yield, [
 908             AC_DEFINE(HAVE_SCHED_YIELD)
 909             THREADLIBS="$THREADLIBS -lposix4"
 910             THREADSPEC="$THREADSPEC -lposix4"])])])
 911       LIBS="$save_LIBS"
 912
 913       # We can save a little space at runtime if the mutex has m_count
 914       # or __m_count.  This is a nice hack for Linux.
 915       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 916           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 917         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 918              [Define if pthread_mutex_t has m_count member.]), [
 919         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 920             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 921           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 922             [Define if pthread_mutex_t has __m_count member.]))])
 923    fi
 924
 925    # We require a way to get the time.
 926    time_found=no
 927    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 928    if test "$time_found" = no; then
 929       AC_MSG_ERROR([no function found to get the time])
 930    fi
 931
 932    AC_CHECK_FUNCS(memmove)
 933
 934    # We require memcpy.
 935    memcpy_found=no
 936    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 937    if test "$memcpy_found" = no; then
 938       AC_MSG_ERROR([memcpy is required])
 939    fi
 940
 941    AC_CHECK_LIB(dl, dlopen, [
 942        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 943
 944    # Some library-finding code we stole from Tcl.
 945    #--------------------------------------------------------------------
 946    #    Check for the existence of the -lsocket and -lnsl libraries.
 947    #    The order here is important, so that they end up in the right
 948    #    order in the command line generated by make.  Here are some
 949    #    special considerations:
 950    #    1. Use "connect" and "accept" to check for -lsocket, and
 951    #       "gethostbyname" to check for -lnsl.
 952    #    2. Use each function name only once:  can't redo a check because
 953    #       autoconf caches the results of the last check and won't redo it.
 954    #    3. Use -lnsl and -lsocket only if they supply procedures that
 955    #       aren't already present in the normal libraries.  This is because
 956    #       IRIX 5.2 has libraries, but they aren't needed and they're
 957    #       bogus:  they goof up name resolution if used.
 958    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 959    #       To get around this problem, check for both libraries together
 960    #       if -lsocket doesn't work by itself.
 961    #--------------------------------------------------------------------
 962
 963    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 964     [gcj_cv_lib_sockets=
 965      gcj_checkBoth=0
 966      unset ac_cv_func_connect
 967      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 968      if test "$gcj_checkSocket" = 1; then
 969          unset ac_cv_func_connect
 970          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 971                       gcj_checkBoth=1)
 972      fi
 973      if test "$gcj_checkBoth" = 1; then
 974          gcj_oldLibs=$LIBS
 975          LIBS="$LIBS -lsocket -lnsl"
 976          unset ac_cv_func_accept
 977          AC_CHECK_FUNC(accept,
 978                        [gcj_checkNsl=0
 979                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 980          unset ac_cv_func_accept
 981          LIBS=$gcj_oldLibs
 982      fi
 983      unset ac_cv_func_gethostbyname
 984      gcj_oldLibs=$LIBS
 985      LIBS="$LIBS $gcj_cv_lib_sockets"
 986      AC_CHECK_FUNC(gethostbyname, ,
 987                    [AC_CHECK_LIB(nsl, main,
 988                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 989      unset ac_cv_func_gethostbyname
 990      LIBS=$gcj_oldLIBS
 991    ])
 992    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 993
 994    if test "$with_system_zlib" = yes; then
 995       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 996    fi
 997
 998    # Test for Gtk stuff, if asked for.
 999    if test "$use_gtk_awt" = yes; then
1000       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1001       AC_SUBST(GTK_CFLAGS)
1002       AC_SUBST(GTK_LIBS)
1003
1004       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1005       AC_SUBST(GLIB_CFLAGS)
1006       AC_SUBST(GLIB_LIBS)
1007
1008       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1009       AC_SUBST(LIBART_CFLAGS)
1010       AC_SUBST(LIBART_LIBS)
1011    fi
1012
1013    # On Solaris, and maybe other architectures, the Boehm collector
1014    # requires -ldl.
1015    if test "$GC" = boehm; then
1016       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1017    fi
1018 fi
1019 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1020
1021 if test -z "${with_multisubdir}"; then
1022    builddotdot=.
1023 else
1024    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1025 fi
1026
1027 NATIVE=yes
1028
1029 # Which gcj do we use?
1030 which_gcj=default
1031 built_gcc_dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
1032 if test -n "${with_cross_host}"; then
1033   # We are being configured with a cross compiler. We can't
1034   # use ac_exeext, because that is for the target platform.
1035   NATIVE=no
1036   cross_host_exeext=
1037   case "${with_cross_host}" in
1038      *mingw* | *cygwin*)
1039          cross_host_exeext=.exe
1040      ;;
1041   esac
1042   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1043      if test x"$build_noncanonical" = x"$with_cross_host"; then
1044         # Ordinary cross (host!=target and host=build)
1045         which_gcj=built
1046      else
1047         # Canadian cross (host!=target and host!=build)
1048         which_gcj=cross
1049      fi
1050   else
1051      which_gcj=cross
1052   fi
1053 else
1054   # We are being configured with a native or crossed-native compiler
1055   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1056      if test x"$build" = x"$host"; then
1057         # True native build (host=target and host=build)
1058         which_gcj=built
1059      else
1060         # Crossed-native build (host=target and host!=build)
1061         which_gcj=cross
1062      fi
1063   else
1064      which_gcj=path
1065   fi
1066 fi
1067 case "${which_gcj}" in
1068    built)
1069       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1070       GCJH='$(MULTIBUILDTOP)../$(COMPPATH)/gcc/gcjh'
1071       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1072    ;;
1073    cross)
1074       if test "x${with_newlib}" = "xyes"; then
1075          # FIXME (comment): Why is this needed?
1076          GCC_UNWIND_INCLUDE=
1077          GCJ="${target_noncanonical}-gcj"
1078       else
1079          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1080       fi
1081       ZIP=jar
1082       GCJH='$(target_noncanonical)-gcjh'
1083    ;;
1084    path)
1085       GCJ="gcj -B`${PWDCMD-pwd}`/"
1086       ## In this case, gcj is found outside the build tree.  However, zip is
1087       ## found in the build tree.
1088       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1089       GCJH=gcjh
1090    ;;
1091 esac
1092
1093 AC_SUBST(GCJH)
1094 AC_SUBST(ZIP)
1095
1096 # Create it, so that compile/link tests don't fail
1097 test -f libgcj.spec || touch libgcj.spec
1098
1099 # We must search the source tree for java.lang, since we still don't
1100 # have libgcj.jar nor java/lang/*.class
1101 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1102 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1103
1104 # Since some classes depend on this one, we need its source available
1105 # before we can do any GCJ compilation test :-(
1106 if test ! -f gnu/classpath/Configuration.java; then
1107   test -d gnu || mkdir gnu
1108   test -d gnu/classpath || mkdir gnu/classpath
1109   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1110       -e 's,@TOOLKIT@,$TOOLKIT,' \
1111         < $srcdir/gnu/classpath/Configuration.java.in \
1112         > gnu/classpath/Configuration.java
1113   # We do not want to redirect the output of the grep below to /dev/null,
1114   # but we add /dev/null to the input list so that grep will print the
1115   # filename of Configuration.java in case it finds any matches.
1116   if grep @ gnu/classpath/Configuration.java /dev/null; then
1117     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1118   fi
1119 fi
1120
1121 LT_AC_PROG_GCJ
1122
1123 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1124
1125 AC_COMPILE_CHECK_SIZEOF(void *)
1126
1127 AC_C_BIGENDIAN_CROSS
1128
1129 ZLIBS=
1130 SYS_ZLIBS=
1131 ZINCS=
1132
1133 if test -z "$ZLIBSPEC"; then
1134    # Use zlib from the GCC tree.
1135    ZINCS='-I$(top_srcdir)/../zlib'
1136    ZLIBS=../zlib/libzgcj_convenience.la
1137 else
1138    # System's zlib.
1139    SYS_ZLIBS="$ZLIBSPEC"
1140 fi
1141 AC_SUBST(ZLIBS)
1142 AC_SUBST(SYS_ZLIBS)
1143 AC_SUBST(ZINCS)
1144 AC_SUBST(DIVIDESPEC)
1145 AC_SUBST(CHECKREFSPEC)
1146 AC_SUBST(EXCEPTIONSPEC)
1147 AC_SUBST(IEEESPEC)
1148
1149 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1150 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1151 AC_SUBST(GCC_UNWIND_INCLUDE)
1152
1153 # Process the option "--enable-version-specific-runtime-libs"
1154 # Calculate toolexeclibdir
1155 case ${version_specific_libs} in
1156   yes)
1157     # Need the gcc compiler version to know where to install libraries
1158     # and header files if --enable-version-specific-runtime-libs option
1159     # is selected.
1160     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1161     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1162     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1163     toolexeclibdir=$toolexecmainlibdir
1164     ;;
1165   no)
1166     if test -n "$with_cross_host" &&
1167        test x"$with_cross_host" != x"no"; then
1168       # Install a library built with a cross compiler in tooldir, not libdir.
1169       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1170       toolexecmainlibdir='$(toolexecdir)/lib'
1171     else
1172       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1173       toolexecmainlibdir='$(libdir)'
1174     fi
1175     multi_os_directory=`$CC -print-multi-os-directory`
1176     case $multi_os_directory in
1177       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1178       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1179     esac
1180     ;;
1181 esac
1182 AC_SUBST(toolexecdir)
1183 AC_SUBST(toolexecmainlibdir)
1184 AC_SUBST(toolexeclibdir)
1185
1186 # Determine gcj version number.
1187 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1188 GCJVERSION=$gcjversion
1189 AC_SUBST(GCJVERSION)
1190 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1191
1192 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1193 # On that system, sys/ioctl.h will not include sys/filio.h unless
1194 # BSD_COMP is defined; just including sys/filio.h is simpler.
1195 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
1196 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1197 # for now.  If you change this, you also must update natFile.cc.
1198 AC_CHECK_HEADERS(dirent.h)
1199 AC_CHECK_HEADERS(inttypes.h, [
1200     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1201     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1202 ])
1203 AC_HEADER_SYS_WAIT
1204
1205 AC_CHECK_TYPE([ssize_t], [int])
1206
1207 AC_MSG_CHECKING([for in_addr_t])
1208 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1209 #if STDC_HEADERS
1210 #include <stdlib.h>
1211 #include <stddef.h>
1212 #endif
1213 #if HAVE_NETINET_IN_H
1214 #include <netinet/in.h>
1215 #endif]], [[in_addr_t foo;]])],
1216   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1217      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1218    AC_MSG_RESULT(yes)],
1219   [AC_MSG_RESULT(no)])
1220
1221 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1222 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1223   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1224      [Define if struct ip_mreq is defined in netinet/in.h.])
1225    AC_MSG_RESULT(yes)],
1226   [AC_MSG_RESULT(no)])
1227
1228 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1229 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1230   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1231      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1232    AC_MSG_RESULT(yes)],
1233   [AC_MSG_RESULT(no)])
1234
1235 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1236 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1237   [AC_DEFINE(HAVE_INET6, 1,
1238      [Define if inet6 structures are defined in netinet/in.h.])
1239    AC_MSG_RESULT(yes)],
1240   [AC_MSG_RESULT(no)])
1241
1242 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1243 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1244 #include <sys/types.h>
1245 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1246   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1247    AC_MSG_RESULT(yes)],
1248   [AC_MSG_RESULT(no)])
1249
1250 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1252   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1253    AC_MSG_RESULT(yes)],
1254   [AC_MSG_RESULT(no)
1255    AC_MSG_CHECKING([for global timezone variable])
1256    dnl FIXME: we don't want a link check here because that won't work
1257    dnl when cross-compiling.  So instead we make an assumption that
1258    dnl the header file will mention timezone if it exists.
1259    dnl Don't find the win32 function timezone
1260    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1261      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1262       AC_MSG_RESULT(yes)],
1263      [AC_MSG_RESULT(no)
1264        AC_MSG_CHECKING([for global _timezone variable])
1265        dnl FIXME: As above, don't want link check
1266        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1267          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1268             [Define if your platform has the global _timezone variable.])
1269           AC_MSG_RESULT(yes)],
1270           [AC_MSG_RESULT(no)])])])
1271
1272 AC_FUNC_ALLOCA
1273 AC_FUNC_MMAP
1274
1275 AC_CHECK_PROGS(PERL, perl, false)
1276
1277 SYSDEP_SOURCES=
1278 SIGNAL_HANDLER_AUX=
1279
1280 case "${host}" in
1281  i?86-*-linux*)
1282     SIGNAL_HANDLER=include/i386-signal.h
1283     ;;
1284  sparc*-sun-solaris*)
1285     SIGNAL_HANDLER=include/sparc-signal.h
1286     ;;
1287 # ia64-*)
1288 #    SYSDEP_SOURCES=sysdep/ia64.c
1289 #    test -d sysdep || mkdir sysdep
1290 #    ;;
1291  hppa*-*-linux*)
1292     SIGNAL_HANDLER=include/pa-signal.h
1293     ;;
1294  ia64-*-linux*)
1295     SIGNAL_HANDLER=include/dwarf2-signal.h
1296     ;;
1297  powerpc*-*-linux*)
1298     SIGNAL_HANDLER=include/powerpc-signal.h
1299     ;;
1300  alpha*-*-linux*)
1301     SIGNAL_HANDLER=include/dwarf2-signal.h
1302     ;;
1303  s390*-*-linux*)
1304     SIGNAL_HANDLER=include/s390-signal.h
1305     ;;
1306  x86_64*-*-linux*)
1307     SIGNAL_HANDLER=include/x86_64-signal.h
1308     SIGNAL_HANDLER_AUX=include/i386-signal.h
1309     ;;
1310  sparc*-*-linux*)
1311     SIGNAL_HANDLER=include/dwarf2-signal.h
1312     ;;
1313  sh*-*-linux*)
1314     SIGNAL_HANDLER=include/sh-signal.h
1315     ;;
1316  *mingw*)
1317     SIGNAL_HANDLER=include/win32-signal.h
1318     ;;
1319  mips*-*-linux*)
1320     SIGNAL_HANDLER=include/mips-signal.h
1321     ;;
1322  *-*-darwin*)
1323     SIGNAL_HANDLER=include/darwin-signal.h
1324     ;;
1325  *)
1326     SIGNAL_HANDLER=include/default-signal.h
1327     ;;
1328 esac
1329
1330 # If we're using sjlj exceptions, forget what we just learned.
1331 if test "$enable_sjlj_exceptions" = yes; then
1332    SIGNAL_HANDLER=include/default-signal.h
1333    SIGNAL_HANDLER_AUX=
1334 fi
1335
1336 # Define here any compiler flags that you need in order to make backtrace() work.
1337 BACKTRACESPEC=
1338 case "${host}" in
1339  x86_64*-*-linux*|i?86-*)
1340     BACKTRACESPEC=-fno-omit-frame-pointer
1341     ;;
1342 esac
1343 AC_SUBST(BACKTRACESPEC)
1344
1345 AC_SUBST(SYSDEP_SOURCES)
1346
1347 if test -z "$SIGNAL_HANDLER_AUX"; then
1348   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1349 fi
1350
1351 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1352                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1353
1354 if test "${multilib}" = "yes"; then
1355   multilib_arg="--enable-multilib"
1356 else
1357   multilib_arg=
1358 fi
1359
1360
1361
1362 here=`${PWDCMD-pwd}`
1363 AC_SUBST(here)
1364
1365 # We get this from the environment.
1366 AC_SUBST(GCJFLAGS)
1367
1368 AC_CONFIG_FILES([
1369 Makefile
1370 libgcj.pc
1371 libgcj.spec
1372 libgcj-test.spec
1373 gnu/classpath/Configuration.java
1374 gcj/Makefile
1375 include/Makefile
1376 testsuite/Makefile
1377 ])
1378
1379 AC_CONFIG_COMMANDS([default],
1380 [# Only add multilib support code if we just rebuilt top-level Makefile.
1381 case " $CONFIG_FILES " in
1382  *" Makefile "*)
1383    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1384    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1385    ;;
1386 esac
1387 ],
1388 srcdir=${srcdir}
1389 host=${host}
1390 target=${target}
1391 with_multisubdir=${with_multisubdir}
1392 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1393 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1394 libgcj_basedir=${libgcj_basedir}
1395 CC="${CC}"
1396 CXX="${CXX}"
1397 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1398 )
1399
1400 AC_OUTPUT