libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 # Only use libltdl for non-newlib builds.
 146 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 147    AC_LTDL_SHLIBPATH
 148 fi
 149
 150 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 151
 152 # See if the user has requested runtime debugging.
 153 LIBGCJDEBUG="disable"
 154 AC_SUBST(LIBGCJDEBUG)
 155 AC_ARG_ENABLE(libgcj-debug,
 156   AS_HELP_STRING([--enable-libgcj-debug],
 157                  [enable runtime debugging code]),
 158   [if test "$enable_libgcj_debug" = yes; then
 159     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 160     LIBGCJDEBUG="enable"
 161   fi])
 162
 163 # Determine which AWT peer libraries to build
 164 AC_ARG_ENABLE(java-awt,
 165   AS_HELP_STRING([--enable-java-awt],
 166                  [list of AWT peer implementations to be built]))
 167
 168 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 169 use_xlib_awt=""
 170 use_gtk_awt=""
 171 use_qt_awt=""
 172 # The default toolkit to use is the first one specified.
 173 TOOLKIT=
 174 AC_SUBST(TOOLKIT)
 175
 176 for peer in $peerlibs ; do
 177   case $peer in
 178     xlib)
 179       if test "$no_x" = yes; then
 180         echo "*** xlib peers requested but no X library available" 1>&2
 181         exit 1
 182       else
 183         use_xlib_awt="yes"
 184         if test -z "$TOOLKIT"; then
 185            TOOLKIT=gnu.awt.xlib.XToolkit
 186         fi
 187       fi
 188       ;;
 189     gtk)
 190       if test "$no_x" = yes; then
 191          echo "*** gtk peers requested but no X library available" 1>&2
 192          exit 1
 193       else
 194          use_gtk_awt=yes
 195          if test -z "$TOOLKIT"; then
 196             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 197          fi
 198       fi
 199       ;;
 200     qt)
 201       if test "$no_x" = yes; then
 202          # Perhaps we should admit the possibility of embedded Qt.
 203          echo "*** Qt peers requested but no X library available" 1>&2
 204          exit 1
 205       else
 206          use_qt_awt=yes
 207          if test -z "$TOOLKIT"; then
 208             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 209          fi
 210       fi
 211       ;;
 212     no)
 213       use_xlib_awt=
 214       use_gtk_awt=
 215       use_qt_awt=
 216       break
 217       ;;
 218     *)
 219       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 220       exit 1
 221   esac
 222 done
 223
 224 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 225 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 226 AM_CONDITIONAL(QT_AWT, test "$use_gtk_awt" = yes)
 227
 228 # Create standard.omit based on decisions we just made.
 229 cp $srcdir/standard.omit.in standard.omit
 230 if test "$use_xlib_awt" != yes; then
 231    echo gnu/awt/xlib >> standard.omit
 232    echo gnu/gcj/xlib >> standard.omit
 233 fi
 234 if test "$use_gtk_awt" != yes; then
 235    echo gnu/java/awt/peer/gtk >> standard.omit
 236 fi
 237 if test "$use_qt_awt" != yes; then
 238    echo gnu/java/awt/peer/qt >> standard.omit
 239 fi
 240
 241 if test -z "${with_multisubdir}"; then
 242    builddotdot=.
 243 else
 244    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 245 fi
 246
 247 NATIVE=yes
 248
 249 # Which gcj do we use?
 250 which_gcj=default
 251 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 252 if test -n "${with_cross_host}"; then
 253   # We are being configured with a cross compiler. We can't
 254   # use ac_exeext, because that is for the target platform.
 255   NATIVE=no
 256   cross_host_exeext=
 257   case "${with_cross_host}" in
 258      *mingw* | *cygwin*)
 259          cross_host_exeext=.exe
 260      ;;
 261   esac
 262   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 263      if test x"$build_noncanonical" = x"$with_cross_host"; then
 264         # Ordinary cross (host!=target and host=build)
 265         which_gcj=built
 266      else
 267         # Canadian cross (host!=target and host!=build)
 268         which_gcj=cross
 269      fi
 270   else
 271      which_gcj=cross
 272   fi
 273 else
 274   # We are being configured with a native or crossed-native compiler
 275   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 276      if test x"$build" = x"$host"; then
 277         # True native build (host=target and host=build)
 278         which_gcj=built
 279      else
 280         # Crossed-native build (host=target and host!=build)
 281         which_gcj=cross
 282      fi
 283   else
 284      which_gcj=path
 285   fi
 286 fi
 287 case "${which_gcj}" in
 288    built)
 289       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 290       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 291       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 292    ;;
 293    cross)
 294       if test "x${with_newlib}" = "xyes"; then
 295          # FIXME (comment): Why is this needed?
 296          GCC_UNWIND_INCLUDE=
 297          GCJ="${target_noncanonical}-gcj"
 298       else
 299          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 300       fi
 301       ZIP='$(target_noncanonical)-fastjar'
 302       GCJH='$(target_noncanonical)-gcjh'
 303    ;;
 304    path)
 305       GCJ="gcj -B`${PWDCMD-pwd}`/"
 306       ## In this case, gcj is found outside the build tree.  However, zip is
 307       ## found in the build tree.
 308       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 309       GCJH=gcjh
 310    ;;
 311 esac
 312
 313 AC_SUBST(GCJH)
 314 AC_SUBST(ZIP)
 315
 316 # Create it, so that compile/link tests don't fail
 317 test -f libgcj.spec || touch libgcj.spec
 318
 319
 320
 321 # Set up to configure Classpath.
 322 # FIXME: no supported way to pass args in autoconf.
 323 ac_configure_args="$ac_configure_args --disable-load-library"
 324 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 325 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 326 dir1=`cd $srcdir && pwd`
 327 dir2=`pwd`
 328 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 329 ac_configure_args="$ac_configure_args --disable-core-jni"
 330 dnl FIXME?
 331 ac_configure_args="$ac_configure_args --disable-examples"
 332 ac_configure_args="$ac_configure_args --with-glibj=build"
 333 if test "$use_gtk_awt" != yes; then
 334   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 335 fi
 336 if test "$use_qt_awt" != yes; then
 337   ac_configure_args="$ac_configure_args --disable-qt-peer"
 338 fi
 339 dnl --with-gcj=$GCJ
 340 dnl --with-javah=$GCJH
 341 dnl gjdoc?
 342 dnl gtk-cairo -- just export here...
 343 dnl --enable-regen-headers?
 344
 345 # Only use libltdl for non-newlib builds.
 346 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 347    AC_LIBLTDL_CONVENIENCE
 348    AC_LIBTOOL_DLOPEN
 349    DIRLTDL=libltdl
 350    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 351    # Sigh.  Libtool's macro doesn't do the right thing.
 352    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 353    # FIXME: this is a hack.
 354    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 355    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 356 fi
 357 AC_SUBST(INCLTDL)
 358 AC_SUBST(LIBLTDL)
 359 AC_SUBST(DIRLTDL)
 360 AC_PROG_LIBTOOL
 361 AM_PROG_GCJ
 362 AM_PROG_CC_C_O
 363
 364 AC_CONFIG_SUBDIRS(classpath libltdl)
 365
 366 # The -no-testsuite modules omit the test subdir.
 367 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 368
 369 # Should the runtime set system properties by examining the
 370 # environment variable GCJ_PROPERTIES?
 371 AC_ARG_ENABLE(getenv-properties,
 372   AS_HELP_STRING([--disable-getenv-properties],
 373                  [don't set system properties from GCJ_PROPERTIES]))
 374
 375 # Whether GCJ_PROPERTIES is used depends on the target.
 376 if test -z "$enable_getenv_properties"; then
 377    enable_getenv_properties=${enable_getenv_properties_default-yes}
 378 fi
 379 if test "$enable_getenv_properties" = no; then
 380    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 381      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 382 fi
 383
 384 # Whether we should use arguments to main()
 385 if test -z "$enable_main_args"; then
 386    enable_main_args=${enable_main_args_default-yes}
 387 fi
 388 if test "$enable_main_args" = no; then
 389    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 390 fi
 391
 392
 393 # Should we use hashtable-based synchronization?
 394 # Currently works only for Linux X86/ia64
 395 # Typically faster and more space-efficient
 396 AC_ARG_ENABLE(hash-synchronization,
 397   AS_HELP_STRING([--enable-hash-synchronization],
 398                  [use global hash table for monitor locks]))
 399
 400 if test -z "$enable_hash_synchronization"; then
 401    enable_hash_synchronization=$enable_hash_synchronization_default
 402 fi
 403
 404 AC_ARG_WITH(java-home,
 405   AS_HELP_STRING([--with-java-home=DIRECTORY],
 406                  [value of java.home system property]),
 407                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 408 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 409 AC_SUBST(JAVA_HOME)
 410
 411 # What is the native OS API for MinGW?
 412 AC_ARG_WITH(win32-nlsapi,
 413   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 414                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 415 [case "${withval}" in
 416   ansi) with_win32_nlsapi=ansi ;;
 417   unicows) with_win32_nlsapi=unicows ;;
 418   unicode) with_win32_nlsapi=unicode ;;
 419   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 420 esac],[with_win32_nlsapi=ansi])
 421
 422 case "${with_win32_nlsapi}" in
 423   unicows | unicode)
 424     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 425       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 426     ;;
 427 esac
 428
 429 # configure.host sets slow_pthread_self if the synchronization code should
 430 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 431 if test "${slow_pthread_self}" = "yes"; then
 432   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 433     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 434 fi
 435
 436 # Check for gc debugging.  This option is handled both here and in the GC.
 437 AC_ARG_ENABLE(gc-debug,
 438    AS_HELP_STRING([--enable-gc-debug],
 439                   [include full support for pointer backtracing etc.]),
 440 [ if test "$enable_gc_debug" = "yes"; then
 441     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 442               [Define if we want to use debug calls into the garbage collector.])
 443   fi])
 444
 445 # See if the user has the interpreter included.
 446 AC_ARG_ENABLE(interpreter,
 447   AS_HELP_STRING([--enable-interpreter],
 448                  [enable interpreter]),
 449   [if test "$enable_interpreter" = yes; then
 450     # This can also be set in configure.host.
 451     libgcj_interpreter=yes
 452   elif test "$enable_interpreter" = no; then
 453     libgcj_interpreter=no
 454   fi])
 455
 456 if test "$libgcj_interpreter" = yes; then
 457    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 458 fi
 459 INTERPRETER="$libgcj_interpreter"
 460 AC_SUBST(INTERPRETER)
 461
 462 AC_MSG_CHECKING([for exception model to use])
 463 AC_LANG_PUSH(C++)
 464 AC_ARG_ENABLE(sjlj-exceptions,
 465   AS_HELP_STRING([--enable-sjlj-exceptions],
 466                  [force use of builtin_setjmp for exceptions]),
 467 [:],
 468 [dnl Botheration.  Now we've got to detect the exception model.
 469 dnl Link tests against libgcc.a are problematic since -- at least
 470 dnl as of this writing -- we've not been given proper -L bits for
 471 dnl single-tree newlib and libgloss.
 472 dnl
 473 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 474 dnl conftest files before we got a change to grep them first.
 475 cat > conftest.$ac_ext << EOF
 476 [#]line __oline__ "configure"
 477 struct S { ~S(); };
 478 void bar();
 479 void foo()
 480 {
 481   S s;
 482   bar();
 483 }
 484 EOF
 485 old_CXXFLAGS="$CXXFLAGS"
 486 CXXFLAGS=-S
 487 if AC_TRY_EVAL(ac_compile); then
 488   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 489     enable_sjlj_exceptions=yes
 490   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 491     enable_sjlj_exceptions=no
 492   fi
 493 fi
 494 CXXFLAGS="$old_CXXFLAGS"
 495 rm -f conftest*])
 496 if test x$enable_sjlj_exceptions = xyes; then
 497   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 498         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 499   ac_exception_model_name=sjlj
 500 elif test x$enable_sjlj_exceptions = xno; then
 501   ac_exception_model_name="call frame"
 502 else
 503   AC_MSG_ERROR([unable to detect exception model])
 504 fi
 505 AC_LANG_POP(C++)
 506 AC_MSG_RESULT($ac_exception_model_name)
 507
 508 # If we are non using SJLJ exceptions, and this host does not have support
 509 # for unwinding from a signal handler, enable checked dereferences and divides.
 510 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 511   CHECKREFSPEC=-fcheck-references
 512   DIVIDESPEC=-fuse-divide-subroutine
 513   EXCEPTIONSPEC=
 514 fi
 515
 516 # See if the user wants to disable java.net.  This is the mildly
 517 # ugly way that we admit that target-side configuration sucks.
 518 AC_ARG_ENABLE(java-net,
 519   AS_HELP_STRING([--disable-java-net],
 520                  [disable java.net]))
 521
 522 # Whether java.net is built by default can depend on the target.
 523 if test -z "$enable_java_net"; then
 524    enable_java_net=${enable_java_net_default-yes}
 525 fi
 526 if test "$enable_java_net" = no; then
 527    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 528 fi
 529
 530 # See if the user wants to configure without libffi.  Some
 531 # architectures don't support it, and default values are set in
 532 # configure.host.
 533 AC_ARG_WITH(libffi,
 534   AS_HELP_STRING([--without-libffi],
 535                  [don't use libffi]),
 536   [:],
 537   [with_libffi=${with_libffi_default-yes}])
 538
 539 LIBFFI=
 540 LIBFFIINCS=
 541 if test "$with_libffi" != no; then
 542    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 543    LIBFFI=../libffi/libffi_convenience.la
 544    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 545 fi
 546 AC_SUBST(LIBFFI)
 547 AC_SUBST(LIBFFIINCS)
 548
 549 # See if the user wants to disable JVMPI support.
 550 AC_ARG_ENABLE(jvmpi,
 551   AS_HELP_STRING([--disable-jvmpi],
 552                  [disable JVMPI support]))
 553
 554 if test "$enable_jvmpi" != no; then
 555     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 556 fi
 557
 558 # If the target is an eCos system, use the appropriate eCos
 559 # I/O routines.
 560 # FIXME: this should not be a local option but a global target
 561 # system; at present there is no eCos target.
 562 TARGET_ECOS=${PROCESS-"no"}
 563 AC_ARG_WITH(ecos,
 564 [  --with-ecos             enable runtime eCos target support],
 565 TARGET_ECOS="$with_ecos"
 566 )
 567
 568 supply_backtrace=no
 569
 570 PLATFORM_INNER_NAT_HDRS=
 571 case "$TARGET_ECOS" in
 572    no) case "$host" in
 573       *mingw*)
 574             PLATFORM=Win32
 575             PLATFORMNET=Win32
 576             PLATFORMH=win32.h
 577         CHECK_FOR_BROKEN_MINGW_LD
 578       ;;
 579       *)
 580             PLATFORM=Posix
 581             PLATFORMNET=Posix
 582             PLATFORMH=posix.h
 583             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 584       ;;
 585       esac
 586       ;;
 587    *)
 588       PLATFORM=Ecos
 589       PLATFORMNET=NoNet
 590       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 591       PLATFORMH=posix.h
 592       ;;
 593 esac
 594 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 595 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 596
 597 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 598                                       [Define if you have int32_t and uint32_t.]))
 599 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 600                                         [Define if you have int32_t and uint32_t.]))
 601 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 602                                           [Define if you have u_int32_t]))
 603 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 604                                            [Define if you have u_int32_t]))
 605
 606 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 607 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 608
 609 case "$host" in
 610   *-darwin*) DARWIN_CRT=true ;;
 611   *) DARWIN_CRT=false ;;
 612 esac
 613 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 614
 615 # These may not be defined in a non-ANS conformant embedded system.
 616 # FIXME: Should these case a runtime exception in that case?
 617 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 618                                   [Define is you have 'mktime' in <time.h>]))
 619 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 620                                   [Define is you have 'localtime' in <time.h>]))
 621
 622 # Create the subdirectory for natFile.cc, or the attempt
 623 # to create the link will fail.
 624 test -d java || mkdir java
 625 test -d java/io || mkdir java/io
 626 test -d gnu || mkdir gnu
 627 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 628
 629 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 630 test -d java/lang || mkdir java/lang
 631 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 632 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 633
 634 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 635 test -d java/net || mkdir java/net
 636 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 637 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 638
 639 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 640 test -d gnu/java || mkdir gnu/java
 641 test -d gnu/java/net || mkdir gnu/java/net
 642 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 643 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 644
 645 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 646 test -d gnu/java/nio || mkdir gnu/java/nio
 647 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 648 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 649 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 650 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 651
 652 case "${host}" in
 653     *mingw*)
 654       SYSTEMSPEC="-lgdi32 -lws2_32"
 655       if test "${with_win32_nlsapi}" = "unicows"; then
 656         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 657       fi
 658     ;;
 659     *)
 660       SYSTEMSPEC=
 661     ;;
 662 esac
 663 AC_SUBST(SYSTEMSPEC)
 664
 665 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 666 AC_SUBST(LIBGCJTESTSPEC)
 667
 668 AC_ARG_WITH(system-zlib,
 669   AS_HELP_STRING([--with-system-zlib],
 670                  [use installed libz]))
 671 ZLIBSPEC=
 672 AC_SUBST(ZLIBSPEC)
 673 ZLIBTESTSPEC=
 674 AC_SUBST(ZLIBTESTSPEC)
 675
 676 AC_PATH_XTRA
 677
 678 # determine whether to enable the cairo GTK Graphics2D backend
 679 AC_ARG_ENABLE(gtk-cairo,
 680   AS_HELP_STRING([--enable-gtk-cairo],
 681                  [build the cairo Graphics2D implementation on GTK]))
 682 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 683 if test "x${enable_gtk_cairo}" = xyes
 684 then
 685         PKG_CHECK_MODULES(CAIRO, cairo)
 686         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 687 fi
 688 AC_SUBST(CAIRO_LIBS)
 689 AC_SUBST(CAIRO_CFLAGS)
 690 AC_SUBST(PANGOFT2_LIBS)
 691 AC_SUBST(PANGOFT2_CFLAGS)
 692
 693 # FIXME: this should be _libs on some hosts.
 694 libsubdir=.libs
 695
 696 # extra LD Flags which are required for targets
 697 case "${host}" in
 698 *-*-darwin[[0-7]].*)
 699     # For now we have to disable it on darwin[8-9] because it slows down
 700     # the linking phase. A possible bug in ld?
 701     # on Darwin -single_module speeds up loading of the dynamic libraries.
 702     extra_ldflags_libjava=-Wl,-single_module
 703     ;;
 704 esac
 705 AC_SUBST(extra_ldflags_libjava)
 706
 707 # Allow the GC to be disabled.  Can be useful when debugging.
 708 AC_MSG_CHECKING([for garbage collector to use])
 709 AC_ARG_ENABLE(java-gc,
 710   AS_HELP_STRING([--enable-java-gc=TYPE],
 711                  [choose garbage collector (default is boehm)]),
 712   [GC=$enableval],
 713   [GC=boehm])
 714 GCLIBS=
 715 GCINCS=
 716 GCDEPS=
 717 GCSPEC=
 718 JC1GCSPEC=
 719 GCTESTSPEC=
 720 case "$GC" in
 721  boehm)
 722     AC_MSG_RESULT(boehm)
 723     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 724     JC1GCSPEC='-fuse-boehm-gc'
 725     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 726     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 727     GCOBJS=boehm.lo
 728     GCHDR=boehm-gc.h
 729     # The POSIX thread support needs to know this.
 730     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 731     ;;
 732  no)
 733     AC_MSG_RESULT(none)
 734     GCHDR=no-gc.h
 735     ;;
 736  *)
 737     AC_MSG_ERROR([unrecognized collector "$GC"])
 738     ;;
 739 esac
 740 AC_SUBST(GCLIBS)
 741 AC_SUBST(GCINCS)
 742 AC_SUBST(GCDEPS)
 743 AC_SUBST(GCSPEC)
 744 AC_SUBST(JC1GCSPEC)
 745 AC_SUBST(GCTESTSPEC)
 746 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 747 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 748 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 749
 750
 751 AC_MSG_CHECKING([for thread model used by GCC])
 752 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 753 AC_MSG_RESULT([$THREADS])
 754
 755 case "$THREADS" in
 756  no | none | single)
 757     THREADS=none
 758     ;;
 759  posix | posix95 | pthreads)
 760     THREADS=posix
 761     case "$host" in
 762      *-*-linux*)
 763         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 764         ;;
 765     esac
 766     ;;
 767  win32)
 768     ;;
 769  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 770     AC_MSG_ERROR(thread package $THREADS not yet supported)
 771     ;;
 772  *)
 773     AC_MSG_ERROR($THREADS is an unknown thread package)
 774     ;;
 775 esac
 776
 777 THREADCXXFLAGS=
 778 THREADLDFLAGS=
 779 THREADLIBS=
 780 THREADINCS=
 781 THREADDEPS=
 782 THREADH=
 783 THREADSPEC=
 784 case "$THREADS" in
 785  posix)
 786     case "$host" in
 787      *-*-cygwin*)
 788         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 789         ;;
 790      *-*-freebsd[[1234]]*)
 791         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 792         # merely adds pthread_* functions) but it does have a -pthread switch
 793         # which is required at link-time to select -lc_r *instead* of -lc.
 794         THREADLDFLAGS=-pthread
 795         # Don't set THREADSPEC here as might be expected since -pthread is
 796         # not processed when found within a spec file, it must come from
 797         # the command line.  For now, the user must provide the -pthread
 798         # switch to link code compiled with gcj.  In future, consider adding
 799         # support for weak references to pthread_* functions ala gthr.h API.
 800         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 801         ;;
 802      *-*-freebsd*)
 803         # FreeBSD 5 implements a model much closer to other modern UNIX
 804         # which support threads.  However, it still does not support
 805         # -lpthread.
 806         THREADLDFLAGS=-pthread
 807         THREADSPEC=-lc_r
 808         ;;
 809      alpha*-dec-osf*)
 810         THREADCXXFLAGS=-pthread
 811         # boehm-gc needs some functions from librt, so link that too.
 812         THREADLIBS='-lpthread -lrt'
 813         THREADSPEC='-lpthread -lrt'
 814         ;;
 815      *)
 816         THREADLIBS=-lpthread
 817         THREADSPEC=-lpthread
 818         ;;
 819     esac
 820     THREADH=posix-threads.h
 821     # MIT pthreads doesn't seem to have the mutexattr functions.
 822     # But for now we don't check for it.  We just assume you aren't
 823     # using MIT pthreads.
 824     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 825
 826     # If we're using the Boehm GC, then we happen to know that it
 827     # defines _REENTRANT, so we don't bother.  Eww.
 828     if test "$GC" != boehm; then
 829        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 830     fi
 831     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 832     ;;
 833
 834  win32)
 835     THREADH=win32-threads.h
 836     ;;
 837
 838  none)
 839     THREADH=no-threads.h
 840     ;;
 841 esac
 842 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 843 AC_SUBST(THREADLIBS)
 844 AC_SUBST(THREADINCS)
 845 AC_SUBST(THREADDEPS)
 846 AC_SUBST(THREADSPEC)
 847 AC_SUBST(THREADLDFLAGS)
 848 AC_SUBST(THREADCXXFLAGS)
 849 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 850 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 851 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 852
 853 if test -d sysdep; then true; else mkdir sysdep; fi
 854 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 855 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 856 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 857
 858 HASH_SYNC_SPEC=
 859 # Hash synchronization is only useful with posix threads right now.
 860 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 861    HASH_SYNC_SPEC=-fhash-synchronization
 862    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 863 fi
 864 AC_SUBST(HASH_SYNC_SPEC)
 865
 866 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 867
 868 # We're in the tree with gcc, and need to include some of its headers.
 869 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 870
 871 if test "x${with_newlib}" = "xyes"; then
 872    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 873    # may not work correctly, because the compiler may not be able to
 874    # link executables.
 875
 876    # We assume newlib.  This lets us hard-code the functions we know
 877    # we'll have.
 878    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 879    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 880    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 881    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 882    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 883    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 884    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 885    # This is only for POSIX threads.
 886    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 887    # We also assume we are using gcc, which provides alloca.
 888    AC_DEFINE(HAVE_ALLOCA)
 889
 890    # Assume we do not have getuid and friends.
 891    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 892    PLATFORMNET=NoNet
 893 else
 894    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 895                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 896                    access stat mkdir rename rmdir unlink realpath utime chmod \
 897                    nl_langinfo setlocale \
 898                    inet_pton uname inet_ntoa \
 899                    fork execvp pipe sigaction ftruncate])
 900    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 901    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 902    AC_CHECK_FUNC(backtrace, [
 903      case "$host" in
 904        ia64-*-linux*)
 905          # Has broken backtrace()
 906          ;;
 907        mips*-*-linux*)
 908          # Has broken backtrace(), but we supply our own.
 909          if test -d sysdep; then true; else mkdir -p sysdep; fi
 910          supply_backtrace=yes
 911          AC_DEFINE(HAVE_BACKTRACE, 1,
 912            [Define if your platform has a working backtrace() function.])
 913          ;;
 914        *)
 915          AC_DEFINE(HAVE_BACKTRACE, 1,
 916            [Define if your platform has a working backtrace() function.])
 917          ;;
 918      esac
 919    ], [
 920      case "$host" in
 921        *mingw*)
 922          # Has backtrace() defined in libgcj itself
 923          AC_DEFINE(HAVE_BACKTRACE, 1,
 924            [Define if your platform has a working backtrace() function.])
 925          ;;
 926      esac
 927    ])
 928
 929    AC_CHECK_LIB(dl, dladdr, [
 930      if test "x${disable_dladdr}" = "xyes"; then
 931        #Broken dladdr().
 932        true
 933      else
 934        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 935      fi
 936    ])
 937    if test x"$build" = x"$host"; then
 938      AC_CHECK_FILES(/proc/self/exe, [
 939        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 940    else
 941      case $host in
 942      *-linux*)
 943        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 944        ;;
 945      esac
 946    fi
 947
 948    AM_ICONV
 949    AM_LC_MESSAGES
 950    AC_STRUCT_TIMEZONE
 951
 952    AC_CHECK_FUNCS(gethostbyname_r, [
 953      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 954        [Define if you have the 'gethostbyname_r' function.])
 955      # There are two different kinds of gethostbyname_r.
 956      # We look for the one that returns `int'.
 957      # Hopefully this check is robust enough.
 958      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 959        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 960
 961      case " $GCINCS " in
 962      *" -D_REENTRANT "*) ;;
 963      *)
 964         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 965         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 966         [libjava_cv_gethostbyname_r_needs_reentrant],
 967         [ AC_LANG_PUSH(C++)
 968           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 969             [[gethostbyname_r("", 0, 0);]])],
 970             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 971                 CPPFLAGS_SAVE="$CPPFLAGS"
 972                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 973                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 974                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 975                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 976                 CPPFLAGS="$CPPFLAGS_SAVE"
 977           ])
 978           AC_LANG_POP(C++)
 979         ])
 980         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 981           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 982         fi
 983      ;;
 984      esac
 985
 986      AC_CACHE_CHECK([for struct hostent_data],
 987         [libjava_cv_struct_hostent_data], [dnl
 988         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 989 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 990 # define _REENTRANT 1
 991 #endif
 992 #include <netdb.h>]], [[struct hostent_data data;]])],
 993           [libjava_cv_struct_hostent_data=yes],
 994           [libjava_cv_struct_hostent_data=no])])
 995      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 996        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 997          [Define if struct hostent_data is defined in netdb.h])
 998      fi
 999    ])
1000
1001    # FIXME: libjava source code expects to find a prototype for
1002    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1003    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1004    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1005    # linkage check is enough, yet C++ code requires proper prototypes.)
1006    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1007    AC_CHECK_FUNCS(gethostbyaddr_r, [
1008      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1009        [Define if you have the 'gethostbyaddr_r' function.])
1010      # There are two different kinds of gethostbyaddr_r.
1011      # We look for the one that returns `int'.
1012      # Hopefully this check is robust enough.
1013      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1014        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1015          [Define if gethostbyaddr_r returns 'int'.])])])])
1016
1017    AC_CHECK_FUNCS(gethostname, [
1018      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1019        [Define if you have the 'gethostname' function.])
1020      AC_EGREP_HEADER(gethostname, unistd.h, [
1021        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1022          [Define if gethostname is declared in <unistd.h>.])])])
1023
1024    AC_CHECK_FUNCS(usleep, [
1025      AC_EGREP_HEADER(usleep, unistd.h, [
1026        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1027           [Define if usleep is declared in <unistd.h>.])])])
1028
1029    # Look for these functions in the thread library, but only bother
1030    # if using POSIX threads.
1031    if test "$THREADS" = posix; then
1032       save_LIBS="$LIBS"
1033       LIBS="$LIBS $THREADLIBS"
1034       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1035       # E.g., Solaris.
1036       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1037
1038       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1039       # Solaris 7 the name librt is preferred.
1040       AC_CHECK_FUNCS(sched_yield, , [
1041         AC_CHECK_LIB(rt, sched_yield, [
1042           AC_DEFINE(HAVE_SCHED_YIELD)
1043           THREADLIBS="$THREADLIBS -lrt"
1044           THREADSPEC="$THREADSPEC -lrt"], [
1045           AC_CHECK_LIB(posix4, sched_yield, [
1046             AC_DEFINE(HAVE_SCHED_YIELD)
1047             THREADLIBS="$THREADLIBS -lposix4"
1048             THREADSPEC="$THREADSPEC -lposix4"])])])
1049       LIBS="$save_LIBS"
1050
1051       # We can save a little space at runtime if the mutex has m_count
1052       # or __m_count.  This is a nice hack for Linux.
1053       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1054           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1055         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1056              [Define if pthread_mutex_t has m_count member.]), [
1057         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1058             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1059           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1060             [Define if pthread_mutex_t has __m_count member.]))])
1061    fi
1062
1063    # We require a way to get the time.
1064    time_found=no
1065    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1066    if test "$time_found" = no; then
1067       AC_MSG_ERROR([no function found to get the time])
1068    fi
1069
1070    AC_CHECK_FUNCS(memmove)
1071
1072    # We require memcpy.
1073    memcpy_found=no
1074    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1075    if test "$memcpy_found" = no; then
1076       AC_MSG_ERROR([memcpy is required])
1077    fi
1078
1079    AC_CHECK_LIB(dl, dlopen, [
1080        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1081
1082    # Some library-finding code we stole from Tcl.
1083    #--------------------------------------------------------------------
1084    #    Check for the existence of the -lsocket and -lnsl libraries.
1085    #    The order here is important, so that they end up in the right
1086    #    order in the command line generated by make.  Here are some
1087    #    special considerations:
1088    #    1. Use "connect" and "accept" to check for -lsocket, and
1089    #       "gethostbyname" to check for -lnsl.
1090    #    2. Use each function name only once:  can't redo a check because
1091    #       autoconf caches the results of the last check and won't redo it.
1092    #    3. Use -lnsl and -lsocket only if they supply procedures that
1093    #       aren't already present in the normal libraries.  This is because
1094    #       IRIX 5.2 has libraries, but they aren't needed and they're
1095    #       bogus:  they goof up name resolution if used.
1096    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1097    #       To get around this problem, check for both libraries together
1098    #       if -lsocket doesn't work by itself.
1099    #--------------------------------------------------------------------
1100
1101    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1102     [gcj_cv_lib_sockets=
1103      gcj_checkBoth=0
1104      unset ac_cv_func_connect
1105      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1106      if test "$gcj_checkSocket" = 1; then
1107          unset ac_cv_func_connect
1108          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1109                       gcj_checkBoth=1)
1110      fi
1111      if test "$gcj_checkBoth" = 1; then
1112          gcj_oldLibs=$LIBS
1113          LIBS="$LIBS -lsocket -lnsl"
1114          unset ac_cv_func_accept
1115          AC_CHECK_FUNC(accept,
1116                        [gcj_checkNsl=0
1117                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1118          unset ac_cv_func_accept
1119          LIBS=$gcj_oldLibs
1120      fi
1121      unset ac_cv_func_gethostbyname
1122      gcj_oldLibs=$LIBS
1123      LIBS="$LIBS $gcj_cv_lib_sockets"
1124      AC_CHECK_FUNC(gethostbyname, ,
1125                    [AC_CHECK_LIB(nsl, main,
1126                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1127      unset ac_cv_func_gethostbyname
1128      LIBS=$gcj_oldLIBS
1129    ])
1130    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1131
1132    if test "$with_system_zlib" = yes; then
1133       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1134    fi
1135
1136    # Test for Gtk stuff, if asked for.
1137    if test "$use_gtk_awt" = yes; then
1138       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1139       AC_SUBST(GTK_CFLAGS)
1140       AC_SUBST(GTK_LIBS)
1141
1142       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1143       AC_SUBST(GLIB_CFLAGS)
1144       AC_SUBST(GLIB_LIBS)
1145
1146       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1147       AC_SUBST(LIBART_CFLAGS)
1148       AC_SUBST(LIBART_LIBS)
1149
1150       # We require the XTest Extension to support java.awt.Robot.
1151       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1152                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1153                    [${X_LIBS}])
1154    fi
1155
1156    # On Solaris, and maybe other architectures, the Boehm collector
1157    # requires -ldl.
1158    if test "$GC" = boehm; then
1159       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1160    fi
1161 fi
1162 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1163
1164 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1165 case $build in
1166     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1167     *)         CLASSPATH_SEPARATOR=':' ;;
1168 esac
1169 AC_SUBST(CLASSPATH_SEPARATOR)
1170
1171 # We must search the source tree for java.lang, since we still don't
1172 # have libgcj.jar nor java/lang/*.class
1173 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1174 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1175
1176 # Since some classes depend on this one, we need its source available
1177 # before we can do any GCJ compilation test :-(
1178 if test ! -f gnu/classpath/Configuration.java; then
1179   test -d gnu || mkdir gnu
1180   test -d gnu/classpath || mkdir gnu/classpath
1181   # Note that it is not crucial that all the values here be correct.
1182   sed -e "s,@prefix@,$prefix," \
1183       -e "s,@VERSION@,$VERSION," \
1184       -e "s,@LIBDEBUG@,false," \
1185       -e "s,@INIT_LOAD_LIBRARY@,false," \
1186       -e "s,@@,$LIBGCJDEBUG," \
1187       -e "s,@default_toolkit@,$TOOLKIT," \
1188       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1189       -e "s,@GTK_CAIRO_ENABLED@,false," \
1190         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1191         > gnu/classpath/Configuration.java
1192   # We do not want to redirect the output of the grep below to /dev/null,
1193   # but we add /dev/null to the input list so that grep will print the
1194   # filename of Configuration.java in case it finds any matches.
1195   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1196     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1197   fi
1198 fi
1199
1200 LT_AC_PROG_GCJ
1201
1202 # Now remove it.
1203 rm -f gnu/classpath/Configuration.java
1204
1205 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1206
1207 AC_CHECK_SIZEOF(void *)
1208
1209 AC_C_BIGENDIAN
1210
1211 ZLIBS=
1212 SYS_ZLIBS=
1213 ZINCS=
1214
1215 if test -z "$ZLIBSPEC"; then
1216    # Use zlib from the GCC tree.
1217    ZINCS='-I$(top_srcdir)/../zlib'
1218    ZLIBS=../zlib/libzgcj_convenience.la
1219 else
1220    # System's zlib.
1221    SYS_ZLIBS="$ZLIBSPEC"
1222 fi
1223 AC_SUBST(ZLIBS)
1224 AC_SUBST(SYS_ZLIBS)
1225 AC_SUBST(ZINCS)
1226 AC_SUBST(DIVIDESPEC)
1227 AC_SUBST(CHECKREFSPEC)
1228 AC_SUBST(EXCEPTIONSPEC)
1229 AC_SUBST(BACKTRACESPEC)
1230 AC_SUBST(IEEESPEC)
1231
1232 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1233 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1234 AC_SUBST(GCC_UNWIND_INCLUDE)
1235
1236 # Process the option "--enable-version-specific-runtime-libs"
1237 # Calculate toolexeclibdir
1238 case ${version_specific_libs} in
1239   yes)
1240     # Need the gcc compiler version to know where to install libraries
1241     # and header files if --enable-version-specific-runtime-libs option
1242     # is selected.
1243     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1244     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1245     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1246     toolexeclibdir=$toolexecmainlibdir
1247     ;;
1248   no)
1249     if test -n "$with_cross_host" &&
1250        test x"$with_cross_host" != x"no"; then
1251       # Install a library built with a cross compiler in tooldir, not libdir.
1252       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1253       toolexecmainlibdir='$(toolexecdir)/lib'
1254     else
1255       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1256       toolexecmainlibdir='$(libdir)'
1257     fi
1258     multi_os_directory=`$CC -print-multi-os-directory`
1259     case $multi_os_directory in
1260       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1261       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1262     esac
1263     ;;
1264 esac
1265 AC_SUBST(toolexecdir)
1266 AC_SUBST(toolexecmainlibdir)
1267 AC_SUBST(toolexeclibdir)
1268
1269 # Determine gcj version number.
1270 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1271 GCJVERSION=$gcjversion
1272 AC_SUBST(GCJVERSION)
1273 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1274
1275 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1276 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1277
1278 TL_AC_GXX_INCLUDE_DIR
1279
1280 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1281 # On that system, sys/ioctl.h will not include sys/filio.h unless
1282 # BSD_COMP is defined; just including sys/filio.h is simpler.
1283 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1284 # for now.  If you change this, you also must update natFile.cc.
1285 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1286                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1287                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1288                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1289                   dirent.h])
1290 AC_CHECK_HEADERS(inttypes.h, [
1291     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1292     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1293 ])
1294 AC_HEADER_SYS_WAIT
1295
1296 AC_CHECK_TYPE([ssize_t], [int])
1297
1298 AC_MSG_CHECKING([for in_addr_t])
1299 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1300 #if STDC_HEADERS
1301 #include <stdlib.h>
1302 #include <stddef.h>
1303 #endif
1304 #if HAVE_NETINET_IN_H
1305 #include <netinet/in.h>
1306 #endif]], [[in_addr_t foo;]])],
1307   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1308      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1309    AC_MSG_RESULT(yes)],
1310   [AC_MSG_RESULT(no)])
1311
1312 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1313 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1314   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1315      [Define if struct ip_mreq is defined in netinet/in.h.])
1316    AC_MSG_RESULT(yes)],
1317   [AC_MSG_RESULT(no)])
1318
1319 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1321   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1322      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1323    AC_MSG_RESULT(yes)],
1324   [AC_MSG_RESULT(no)])
1325
1326 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1327 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1328   [AC_DEFINE(HAVE_INET6, 1,
1329      [Define if inet6 structures are defined in netinet/in.h.])
1330    AC_MSG_RESULT(yes)],
1331   [AC_MSG_RESULT(no)])
1332
1333 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1334 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1335 #include <sys/types.h>
1336 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1337   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1338    AC_MSG_RESULT(yes)],
1339   [AC_MSG_RESULT(no)])
1340
1341 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1342 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1343   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1344    AC_MSG_RESULT(yes)],
1345   [AC_MSG_RESULT(no)
1346    AC_MSG_CHECKING([for global timezone variable])
1347    dnl FIXME: we don't want a link check here because that won't work
1348    dnl when cross-compiling.  So instead we make an assumption that
1349    dnl the header file will mention timezone if it exists.
1350    dnl Don't find the win32 function timezone
1351    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1352      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1353       AC_MSG_RESULT(yes)],
1354      [AC_MSG_RESULT(no)
1355        AC_MSG_CHECKING([for global _timezone variable])
1356        dnl FIXME: As above, don't want link check
1357        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1358          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1359             [Define if your platform has the global _timezone variable.])
1360           AC_MSG_RESULT(yes)],
1361           [AC_MSG_RESULT(no)])])])
1362
1363 AC_FUNC_ALLOCA
1364 AC_FUNC_MMAP
1365
1366 AC_CHECK_PROGS(PERL, perl, false)
1367
1368 SYSDEP_SOURCES=
1369 SIGNAL_HANDLER_AUX=
1370
1371 case "${host}" in
1372  i?86-*-linux*)
1373     SIGNAL_HANDLER=include/i386-signal.h
1374     ;;
1375  sparc*-sun-solaris*)
1376     SIGNAL_HANDLER=include/sparc-signal.h
1377     ;;
1378 # ia64-*)
1379 #    SYSDEP_SOURCES=sysdep/ia64.c
1380 #    test -d sysdep || mkdir sysdep
1381 #    ;;
1382  hppa*-*-linux*)
1383     SIGNAL_HANDLER=include/pa-signal.h
1384     ;;
1385  ia64-*-linux*)
1386     SIGNAL_HANDLER=include/dwarf2-signal.h
1387     ;;
1388  powerpc*-*-linux*)
1389     SIGNAL_HANDLER=include/powerpc-signal.h
1390     ;;
1391  alpha*-*-linux*)
1392     SIGNAL_HANDLER=include/dwarf2-signal.h
1393     ;;
1394  s390*-*-linux*)
1395     SIGNAL_HANDLER=include/s390-signal.h
1396     ;;
1397  x86_64*-*-linux*)
1398     SIGNAL_HANDLER=include/x86_64-signal.h
1399     SIGNAL_HANDLER_AUX=include/i386-signal.h
1400     ;;
1401  sparc*-*-linux*)
1402     SIGNAL_HANDLER=include/dwarf2-signal.h
1403     ;;
1404  sh*-*-linux*)
1405     SIGNAL_HANDLER=include/sh-signal.h
1406     ;;
1407  *mingw*)
1408     SIGNAL_HANDLER=include/win32-signal.h
1409     ;;
1410  mips*-*-linux*)
1411     SIGNAL_HANDLER=include/mips-signal.h
1412     ;;
1413  *-*-darwin*)
1414     SIGNAL_HANDLER=include/darwin-signal.h
1415     ;;
1416  *)
1417     SIGNAL_HANDLER=include/default-signal.h
1418     ;;
1419 esac
1420
1421 # If we're using sjlj exceptions, forget what we just learned.
1422 if test "$enable_sjlj_exceptions" = yes; then
1423    SIGNAL_HANDLER=include/default-signal.h
1424    SIGNAL_HANDLER_AUX=
1425 fi
1426
1427 AC_SUBST(SYSDEP_SOURCES)
1428
1429 if test -z "$SIGNAL_HANDLER_AUX"; then
1430   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1431 fi
1432
1433 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1434                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1435
1436 if test "${multilib}" = "yes"; then
1437   multilib_arg="--enable-multilib"
1438 else
1439   multilib_arg=
1440 fi
1441
1442 # See if we support thread-local storage.
1443 GCC_CHECK_TLS
1444
1445
1446 here=`${PWDCMD-pwd}`
1447 AC_SUBST(here)
1448
1449 # We get this from the environment.
1450 AC_SUBST(GCJFLAGS)
1451
1452 AC_CONFIG_FILES([
1453 Makefile
1454 libgcj.pc
1455 libgcj.spec
1456 libgcj-test.spec
1457 gcj/Makefile
1458 include/Makefile
1459 testsuite/Makefile
1460 ])
1461
1462 AC_CONFIG_COMMANDS([default],
1463 [# Only add multilib support code if we just rebuilt top-level Makefile.
1464 case " $CONFIG_FILES " in
1465  *" Makefile "*)
1466    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1467    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1468    ;;
1469 esac
1470 for ac_multi_file in $CONFIG_FILES; do
1471   case $ac_multi_file in
1472   */Makefile)
1473     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1474   esac
1475 done
1476 ],
1477 srcdir=${srcdir}
1478 host=${host}
1479 target=${target}
1480 with_multisubdir=${with_multisubdir}
1481 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1482 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1483 libgcj_basedir=${libgcj_basedir}
1484 CC="${CC}"
1485 CXX="${CXX}"
1486 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1487 )
1488
1489 AC_OUTPUT