libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 121 if test "$ZIP" = no; then
 122   if test "$JAR" = no; then
 123     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 124   fi
 125 else
 126   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 127   JAR=`pwd`/scripts/jar
 128 fi
 129
 130 AC_PROG_INSTALL
 131
 132 AM_MAINTAINER_MODE
 133
 134 AC_EXEEXT
 135
 136 # configure.host sets the following important variables
 137 #       libgcj_cflags    - host specific C compiler flags
 138 #       libgcj_cxxflags  - host specific C++ compiler flags
 139 #       libgcj_javaflags - host specific Java compiler flags
 140
 141 libgcj_cflags=
 142 libgcj_cxxflags=
 143 libgcj_javaflags=
 144
 145 . ${srcdir}/configure.host
 146
 147 ACX_PROG_LD_GNU_SYMBOLIC
 148 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 149 if test -z "$libgcj_ld_symbolic"; then
 150   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 151 fi
 152
 153 LIBGCJ_CFLAGS="${libgcj_cflags}"
 154 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 155 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 156 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 157 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 158 AC_SUBST(LIBGCJ_CFLAGS)
 159 AC_SUBST(LIBGCJ_CXXFLAGS)
 160 AC_SUBST(LIBGCJ_JAVAFLAGS)
 161 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 162 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 163
 164 # Only use libltdl for non-newlib builds.
 165 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 166    AC_LTDL_SHLIBPATH
 167 fi
 168
 169 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 170
 171 # See if the user has requested runtime debugging.
 172 LIBGCJDEBUG="disable"
 173 AC_SUBST(LIBGCJDEBUG)
 174 AC_ARG_ENABLE(libgcj-debug,
 175   AS_HELP_STRING([--enable-libgcj-debug],
 176                  [enable runtime debugging code]),
 177   [if test "$enable_libgcj_debug" = yes; then
 178     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 179     LIBGCJDEBUG="enable"
 180   fi])
 181
 182 AC_ARG_WITH([escher],
 183          AS_HELP_STRING([--with-escher=ABS.PATH],
 184                         [specify path to escher dir or JAR for X peers]))
 185 case "$with_escher" in
 186 "")
 187         use_escher=false
 188         ;;
 189 "no")
 190         use_escher=false
 191         ;;
 192 "yes")
 193         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 194         ;;
 195 *)
 196         use_escher=true
 197         ;;
 198 esac
 199
 200 # Determine which AWT peer libraries to build
 201 AC_ARG_ENABLE(java-awt,
 202   AS_HELP_STRING([--enable-java-awt],
 203                  [list of AWT peer implementations to be built]))
 204
 205 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 206 use_xlib_awt=""
 207 use_gtk_awt=""
 208 use_qt_awt=""
 209 use_x_awt=""
 210 # The default toolkit to use is the first one specified.
 211 TOOLKIT=
 212 AC_SUBST(TOOLKIT)
 213
 214 for peer in $peerlibs ; do
 215   case $peer in
 216     xlib)
 217       if test "$no_x" = yes; then
 218         echo "*** xlib peers requested but no X library available" 1>&2
 219         exit 1
 220       else
 221         use_xlib_awt="yes"
 222         if test -z "$TOOLKIT"; then
 223            TOOLKIT=gnu.awt.xlib.XToolkit
 224         fi
 225       fi
 226       ;;
 227     gtk)
 228       if test "$no_x" = yes; then
 229          echo "*** gtk peers requested but no X library available" 1>&2
 230          exit 1
 231       else
 232          use_gtk_awt=yes
 233          if test -z "$TOOLKIT"; then
 234             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 235          fi
 236       fi
 237       ;;
 238     qt)
 239       if test "$no_x" = yes; then
 240          # Perhaps we should admit the possibility of embedded Qt.
 241          echo "*** Qt peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_qt_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 247          fi
 248       fi
 249       ;;
 250     x)
 251       use_x_awt=yes
 252       if test -z "$TOOLKIT"; then
 253          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 254       fi
 255       ;;
 256     no)
 257       use_xlib_awt=
 258       use_gtk_awt=
 259       use_qt_awt=
 260       use_x_awt=
 261       break
 262       ;;
 263     *)
 264       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 265       exit 1
 266   esac
 267 done
 268
 269 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 270 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 271
 272 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 273
 274 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 275
 276 # Create standard.omit based on decisions we just made.
 277 cp $srcdir/standard.omit.in standard.omit
 278 if test "$use_xlib_awt" != yes; then
 279    echo gnu/awt/xlib >> standard.omit
 280    echo gnu/gcj/xlib >> standard.omit
 281 fi
 282 if test "$use_x_awt" != yes; then
 283    echo gnu/java/awt/peer/x >> standard.omit
 284 fi
 285
 286 if test -z "${with_multisubdir}"; then
 287    builddotdot=.
 288 else
 289    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 290 fi
 291
 292 NATIVE=yes
 293
 294 # Which gcj and host gcj (for ecjx) do we use?
 295 which_gcj=default
 296 host_exeext=${ac_exeext}
 297 GCJ_FOR_ECJX=
 298 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 299 if test -n "${with_cross_host}"; then
 300   # We are being configured with a cross compiler. We can't
 301   # use ac_exeext, because that is for the target platform.
 302   NATIVE=no
 303   cross_host_exeext=
 304   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 305   case "${with_cross_host}" in
 306      *mingw* | *cygwin*)
 307          cross_host_exeext=.exe
 308      ;;
 309   esac
 310   host_exeext=${cross_host_exeext}
 311   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 312      if test x"$build_noncanonical" = x"$with_cross_host"; then
 313         # Ordinary cross (host!=target and host=build)
 314         which_gcj=built
 315      else
 316         # Canadian cross (host!=target and host!=build)
 317         which_gcj=cross
 318      fi
 319   else
 320      which_gcj=cross
 321   fi
 322 else
 323   # We are being configured with a native or crossed-native compiler
 324   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 325      if test x"$build" = x"$host"; then
 326         # True native build (host=target and host=build)
 327         which_gcj=built
 328      else
 329         # Crossed-native build (host=target and host!=build)
 330         which_gcj=cross
 331      fi
 332   else
 333      which_gcj=path
 334   fi
 335 fi
 336 case "${which_gcj}" in
 337    built)
 338       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 339       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 340    ;;
 341    cross)
 342       if test "x${with_newlib}" = "xyes"; then
 343          # FIXME (comment): Why is this needed?
 344          GCC_UNWIND_INCLUDE=
 345          GCJ="${target_noncanonical}-gcj"
 346       else
 347          GCJ="$built_gcc_dir/gcj -B$built_gcc_dir/"
 348       fi
 349       GCJH="$built_gcc_dir/gcjh"
 350    ;;
 351    path)
 352       GCJ="gcj -B`${PWDCMD-pwd}`/"
 353       GCJH=gcjh
 354    ;;
 355 esac
 356
 357 AC_SUBST(GCJ_FOR_ECJX)
 358 AC_SUBST(GCJH)
 359 AC_SUBST(host_exeext)
 360
 361 # Create it, so that compile/link tests don't fail
 362 test -f libgcj.spec || touch libgcj.spec
 363
 364
 365
 366 # Set up to configure Classpath.
 367 # FIXME: no supported way to pass args in autoconf.
 368 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 369 # Disable tool wrappers to avoid ltdl.h configure check.
 370 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 371 ac_configure_args="$ac_configure_args --disable-load-library"
 372 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 373 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 374 dir1=`cd $srcdir && pwd`
 375 dir2=`pwd`
 376 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 377 ac_configure_args="$ac_configure_args --disable-core-jni"
 378 dnl FIXME?
 379 ac_configure_args="$ac_configure_args --disable-examples"
 380 ac_configure_args="$ac_configure_args --with-glibj=build"
 381 if test "$plugin_enabled" != yes; then
 382   ac_configure_args="$ac_configure_args --disable-plugin"
 383 fi
 384 if test "$gconf_enabled" != yes; then
 385   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 386   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 387 fi
 388 if test "$use_gtk_awt" != yes; then
 389   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 390 fi
 391 if test "$use_qt_awt" != yes; then
 392   ac_configure_args="$ac_configure_args --disable-qt-peer"
 393 else
 394   # We need this as qt is disabled by default in classpath.
 395   ac_configure_args="$ac_configure_args --enable-qt-peer"
 396 fi
 397 if test "$use_x_awt" != yes; then
 398   ac_configure_args="$ac_configure_args --without-escher"
 399 else
 400   # We need this as escher is disabled by default in classpath.
 401   if test "$use_escher" != true; then
 402     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 403   else
 404     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 405   fi
 406 fi
 407 # -Werror causes unavoidable problems in code using alsa.
 408 ac_configure_args="$ac_configure_args --disable-Werror"
 409 dnl --with-gcj=$GCJ
 410 dnl --with-javah=$GCJH
 411 dnl gjdoc?
 412 dnl gtk-cairo -- just export here...
 413 dnl --enable-regen-headers?
 414
 415 # Only use libltdl for non-newlib builds.
 416 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 417    AC_LIBLTDL_CONVENIENCE
 418    AC_LIBTOOL_DLOPEN
 419    DIRLTDL=libltdl
 420    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 421    # Sigh.  Libtool's macro doesn't do the right thing.
 422    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 423    # FIXME: this is a hack.
 424    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 425    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 426 fi
 427 AC_SUBST(INCLTDL)
 428 AC_SUBST(LIBLTDL)
 429 AC_SUBST(DIRLTDL)
 430 AC_PROG_LIBTOOL
 431 AM_PROG_GCJ
 432 AM_PROG_CC_C_O
 433
 434 AC_CONFIG_SUBDIRS(classpath libltdl)
 435
 436 # The -no-testsuite modules omit the test subdir.
 437 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 438
 439 # Should the runtime set system properties by examining the
 440 # environment variable GCJ_PROPERTIES?
 441 AC_ARG_ENABLE(getenv-properties,
 442   AS_HELP_STRING([--disable-getenv-properties],
 443                  [don't set system properties from GCJ_PROPERTIES]))
 444
 445 # Whether GCJ_PROPERTIES is used depends on the target.
 446 if test -z "$enable_getenv_properties"; then
 447    enable_getenv_properties=${enable_getenv_properties_default-yes}
 448 fi
 449 if test "$enable_getenv_properties" = no; then
 450    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 451      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 452 fi
 453
 454 # Whether we should use arguments to main()
 455 if test -z "$enable_main_args"; then
 456    enable_main_args=${enable_main_args_default-yes}
 457 fi
 458 if test "$enable_main_args" = no; then
 459    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 460 fi
 461
 462
 463 # Should we use hashtable-based synchronization?
 464 # Currently works only for Linux X86/ia64
 465 # Typically faster and more space-efficient
 466 AC_ARG_ENABLE(hash-synchronization,
 467   AS_HELP_STRING([--enable-hash-synchronization],
 468                  [use global hash table for monitor locks]))
 469
 470 if test -z "$enable_hash_synchronization"; then
 471    enable_hash_synchronization=$enable_hash_synchronization_default
 472 fi
 473
 474
 475 install_ecj_jar=no
 476 ECJ_BUILD_JAR=
 477 ECJ_JAR=
 478 AC_ARG_WITH(ecj-jar,
 479         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 480         [ECJ_JAR=$withval],
 481         [if test -f $libgcj_basedir/../ecj.jar; then
 482            ECJ_BUILD_JAR=$libgcj_basedir/../ecj.jar
 483            ECJ_JAR='$(jardir)/ecj.jar'
 484            install_ecj_jar=yes
 485          fi])
 486 AC_SUBST(ECJ_BUILD_JAR)
 487 AC_SUBST(ECJ_JAR)
 488 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 489 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 490
 491 AC_ARG_WITH(java-home,
 492   AS_HELP_STRING([--with-java-home=DIRECTORY],
 493                  [value of java.home system property]),
 494                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 495 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 496 AC_SUBST(JAVA_HOME)
 497
 498 # What is the native OS API for MinGW?
 499 AC_ARG_WITH(win32-nlsapi,
 500   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 501                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 502 [case "${withval}" in
 503   ansi) with_win32_nlsapi=ansi ;;
 504   unicows) with_win32_nlsapi=unicows ;;
 505   unicode) with_win32_nlsapi=unicode ;;
 506   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 507 esac],[with_win32_nlsapi=ansi])
 508
 509 case "${with_win32_nlsapi}" in
 510   unicows | unicode)
 511     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 512       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 513     ;;
 514 esac
 515
 516 # configure.host sets slow_pthread_self if the synchronization code should
 517 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 518 if test "${slow_pthread_self}" = "yes"; then
 519   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 520     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 521 fi
 522
 523 # Check for gc debugging.  This option is handled both here and in the GC.
 524 AC_ARG_ENABLE(gc-debug,
 525    AS_HELP_STRING([--enable-gc-debug],
 526                   [include full support for pointer backtracing etc.]),
 527 [ if test "$enable_gc_debug" = "yes"; then
 528     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 529               [Define if we want to use debug calls into the garbage collector.])
 530   fi])
 531
 532 # See if the user has the interpreter included.
 533 AC_ARG_ENABLE(interpreter,
 534   AS_HELP_STRING([--enable-interpreter],
 535                  [enable interpreter]),
 536   [if test "$enable_interpreter" = yes; then
 537     # This can also be set in configure.host.
 538     libgcj_interpreter=yes
 539   elif test "$enable_interpreter" = no; then
 540     libgcj_interpreter=no
 541   fi])
 542
 543 if test "$libgcj_interpreter" = yes; then
 544    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 545 fi
 546 INTERPRETER="$libgcj_interpreter"
 547 AC_SUBST(INTERPRETER)
 548
 549 AC_MSG_CHECKING([for exception model to use])
 550 AC_LANG_PUSH(C++)
 551 AC_ARG_ENABLE(sjlj-exceptions,
 552   AS_HELP_STRING([--enable-sjlj-exceptions],
 553                  [force use of builtin_setjmp for exceptions]),
 554 [:],
 555 [dnl Botheration.  Now we've got to detect the exception model.
 556 dnl Link tests against libgcc.a are problematic since -- at least
 557 dnl as of this writing -- we've not been given proper -L bits for
 558 dnl single-tree newlib and libgloss.
 559 dnl
 560 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 561 dnl conftest files before we got a change to grep them first.
 562 cat > conftest.$ac_ext << EOF
 563 [#]line __oline__ "configure"
 564 struct S { ~S(); };
 565 void bar();
 566 void foo()
 567 {
 568   S s;
 569   bar();
 570 }
 571 EOF
 572 old_CXXFLAGS="$CXXFLAGS"
 573 CXXFLAGS=-S
 574 if AC_TRY_EVAL(ac_compile); then
 575   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 576     enable_sjlj_exceptions=yes
 577   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 578     enable_sjlj_exceptions=no
 579   fi
 580 fi
 581 CXXFLAGS="$old_CXXFLAGS"
 582 rm -f conftest*])
 583 if test x$enable_sjlj_exceptions = xyes; then
 584   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 585         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 586   ac_exception_model_name=sjlj
 587 elif test x$enable_sjlj_exceptions = xno; then
 588   ac_exception_model_name="call frame"
 589 else
 590   AC_MSG_ERROR([unable to detect exception model])
 591 fi
 592 AC_LANG_POP(C++)
 593 AC_MSG_RESULT($ac_exception_model_name)
 594
 595 # If we are non using SJLJ exceptions, and this host does not have support
 596 # for unwinding from a signal handler, enable checked dereferences and divides.
 597 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 598   CHECKREFSPEC=-fcheck-references
 599   DIVIDESPEC=-fuse-divide-subroutine
 600   EXCEPTIONSPEC=
 601 fi
 602
 603 # See if the user wants to disable java.net.  This is the mildly
 604 # ugly way that we admit that target-side configuration sucks.
 605 AC_ARG_ENABLE(java-net,
 606   AS_HELP_STRING([--disable-java-net],
 607                  [disable java.net]))
 608
 609 # Whether java.net is built by default can depend on the target.
 610 if test -z "$enable_java_net"; then
 611    enable_java_net=${enable_java_net_default-yes}
 612 fi
 613 if test "$enable_java_net" = no; then
 614    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 615 fi
 616
 617 # See if the user wants to configure without libffi.  Some
 618 # architectures don't support it, and default values are set in
 619 # configure.host.
 620 AC_ARG_WITH(libffi,
 621   AS_HELP_STRING([--without-libffi],
 622                  [don't use libffi]),
 623   [:],
 624   [with_libffi=${with_libffi_default-yes}])
 625
 626 LIBFFI=
 627 LIBFFIINCS=
 628 if test "$with_libffi" != no; then
 629    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 630    LIBFFI=../libffi/libffi_convenience.la
 631    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 632 fi
 633 AC_SUBST(LIBFFI)
 634 AC_SUBST(LIBFFIINCS)
 635
 636 # See if the user wants to disable JVMPI support.
 637 AC_ARG_ENABLE(jvmpi,
 638   AS_HELP_STRING([--disable-jvmpi],
 639                  [disable JVMPI support]))
 640
 641 if test "$enable_jvmpi" != no; then
 642     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 643 fi
 644
 645 # If the target is an eCos system, use the appropriate eCos
 646 # I/O routines.
 647 # FIXME: this should not be a local option but a global target
 648 # system; at present there is no eCos target.
 649 TARGET_ECOS=${PROCESS-"no"}
 650 AC_ARG_WITH(ecos,
 651 [  --with-ecos             enable runtime eCos target support],
 652 TARGET_ECOS="$with_ecos"
 653 )
 654
 655 case "$TARGET_ECOS" in
 656    no) case "$host" in
 657       *mingw*)
 658             PLATFORM=Win32
 659             PLATFORMNET=Win32
 660             PLATFORMH=win32.h
 661         CHECK_FOR_BROKEN_MINGW_LD
 662       ;;
 663       *)
 664             PLATFORM=Posix
 665             PLATFORMNET=Posix
 666             PLATFORMH=posix.h
 667       ;;
 668       esac
 669       ;;
 670    *)
 671       PLATFORM=Ecos
 672       PLATFORMNET=NoNet
 673       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 674       PLATFORMH=posix.h
 675       ;;
 676 esac
 677 AC_SUBST(PLATFORM)
 678 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 679
 680 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 681                                       [Define if you have int32_t and uint32_t.]))
 682 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 683                                         [Define if you have int32_t and uint32_t.]))
 684 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 685                                           [Define if you have u_int32_t]))
 686 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 687                                            [Define if you have u_int32_t]))
 688
 689 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 690 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 691
 692 case "$host" in
 693   *-darwin*) DARWIN_CRT=true ;;
 694   *) DARWIN_CRT=false ;;
 695 esac
 696 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 697
 698 # These may not be defined in a non-ANS conformant embedded system.
 699 # FIXME: Should these case a runtime exception in that case?
 700 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 701                                   [Define is you have 'mktime' in <time.h>]))
 702 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 703                                   [Define is you have 'localtime' in <time.h>]))
 704
 705 # Create the subdirectory for natFile.cc, or the attempt
 706 # to create the link will fail.
 707 test -d java || mkdir java
 708 test -d java/io || mkdir java/io
 709 test -d gnu || mkdir gnu
 710 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 711
 712 # Likewise for natConcreteProcess.cc.
 713 test -d java/lang || mkdir java/lang
 714 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 715
 716 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 717 test -d java/net || mkdir java/net
 718 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 719 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 720
 721 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 722 test -d gnu/java || mkdir gnu/java
 723 test -d gnu/java/net || mkdir gnu/java/net
 724 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 725 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 726
 727 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 728 test -d gnu/java/nio || mkdir gnu/java/nio
 729 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 730 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 731 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 732 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 733
 734 case "${host}" in
 735     *mingw*)
 736       SYSTEMSPEC="-lgdi32 -lws2_32"
 737       if test "${with_win32_nlsapi}" = "unicows"; then
 738         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 739       fi
 740     ;;
 741     *)
 742       SYSTEMSPEC=
 743     ;;
 744 esac
 745 AC_SUBST(SYSTEMSPEC)
 746
 747 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 748 AC_SUBST(LIBGCJTESTSPEC)
 749
 750 AC_ARG_WITH(system-zlib,
 751   AS_HELP_STRING([--with-system-zlib],
 752                  [use installed libz]))
 753 ZLIBSPEC=
 754 AC_SUBST(ZLIBSPEC)
 755 ZLIBTESTSPEC=
 756 AC_SUBST(ZLIBTESTSPEC)
 757
 758 AC_PATH_XTRA
 759
 760 # FIXME: this should be _libs on some hosts.
 761 libsubdir=.libs
 762
 763 # extra LD Flags which are required for targets
 764 case "${host}" in
 765 *-*-darwin[[0-7]].*)
 766     # For now we have to disable it on darwin[8-9] because it slows down
 767     # the linking phase. A possible bug in ld?
 768     # on Darwin -single_module speeds up loading of the dynamic libraries.
 769     extra_ldflags_libjava=-Wl,-single_module
 770     ;;
 771 esac
 772 AC_SUBST(extra_ldflags_libjava)
 773
 774 # Allow the GC to be disabled.  Can be useful when debugging.
 775 AC_MSG_CHECKING([for garbage collector to use])
 776 AC_ARG_ENABLE(java-gc,
 777   AS_HELP_STRING([--enable-java-gc=TYPE],
 778                  [choose garbage collector (default is boehm)]),
 779   [GC=$enableval],
 780   [GC=boehm])
 781 GCLIBS=
 782 GCINCS=
 783 GCDEPS=
 784 GCSPEC=
 785 JC1GCSPEC=
 786 GCTESTSPEC=
 787 case "$GC" in
 788  boehm)
 789     AC_MSG_RESULT(boehm)
 790     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 791     JC1GCSPEC='-fuse-boehm-gc'
 792     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 793     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 794     GCOBJS=boehm.lo
 795     GCHDR=boehm-gc.h
 796     # The POSIX thread support needs to know this.
 797     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 798     ;;
 799  no)
 800     AC_MSG_RESULT(none)
 801     GCHDR=no-gc.h
 802     ;;
 803  *)
 804     AC_MSG_ERROR([unrecognized collector "$GC"])
 805     ;;
 806 esac
 807 AC_SUBST(GCLIBS)
 808 AC_SUBST(GCINCS)
 809 AC_SUBST(GCDEPS)
 810 AC_SUBST(GCSPEC)
 811 AC_SUBST(JC1GCSPEC)
 812 AC_SUBST(GCTESTSPEC)
 813 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 814 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 815 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 816
 817
 818 AC_MSG_CHECKING([for thread model used by GCC])
 819 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 820 AC_MSG_RESULT([$THREADS])
 821
 822 case "$THREADS" in
 823  no | none | single)
 824     THREADS=none
 825     ;;
 826  posix | posix95 | pthreads)
 827     THREADS=posix
 828     case "$host" in
 829      *-*-linux*)
 830         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 831         ;;
 832     esac
 833     ;;
 834  win32)
 835     ;;
 836  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 837     AC_MSG_ERROR(thread package $THREADS not yet supported)
 838     ;;
 839  *)
 840     AC_MSG_ERROR($THREADS is an unknown thread package)
 841     ;;
 842 esac
 843
 844 THREADCXXFLAGS=
 845 THREADLDFLAGS=
 846 THREADLIBS=
 847 THREADINCS=
 848 THREADDEPS=
 849 THREADH=
 850 THREADSPEC=
 851 THREADSTARTFILESPEC=
 852 case "$THREADS" in
 853  posix)
 854     case "$host" in
 855      *-*-cygwin*)
 856         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 857         ;;
 858      *-*-freebsd[[1234]]*)
 859         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 860         # merely adds pthread_* functions) but it does have a -pthread switch
 861         # which is required at link-time to select -lc_r *instead* of -lc.
 862         THREADLDFLAGS=-pthread
 863         # Don't set THREADSPEC here as might be expected since -pthread is
 864         # not processed when found within a spec file, it must come from
 865         # the command line.  For now, the user must provide the -pthread
 866         # switch to link code compiled with gcj.  In future, consider adding
 867         # support for weak references to pthread_* functions ala gthr.h API.
 868         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 869         ;;
 870      *-*-freebsd*)
 871         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 872         # systems which support threads and -lpthread.
 873         THREADLDFLAGS=-pthread
 874         THREADSPEC=-lpthread
 875         ;;
 876      alpha*-dec-osf* | hppa*-hp-hpux*)
 877         THREADCXXFLAGS=-pthread
 878         # boehm-gc needs some functions from librt, so link that too.
 879         THREADLIBS='-lpthread -lrt'
 880         THREADSPEC='-lpthread -lrt'
 881         ;;
 882      *)
 883         THREADLIBS=-lpthread
 884         THREADSPEC=-lpthread
 885         ;;
 886     esac
 887     THREADH=posix-threads.h
 888     # MIT pthreads doesn't seem to have the mutexattr functions.
 889     # But for now we don't check for it.  We just assume you aren't
 890     # using MIT pthreads.
 891     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 892
 893     # If we're using the Boehm GC, then we happen to know that it
 894     # defines _REENTRANT, so we don't bother.  Eww.
 895     if test "$GC" != boehm; then
 896        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 897     fi
 898     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 899     ;;
 900
 901  win32)
 902     THREADH=win32-threads.h
 903     THREADCXXFLAGS=-mthreads
 904     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 905     # But we do not want the executables created to be dependent on
 906     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 907     # exception handling contexts.  The following kludge achieves this effect
 908     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 909     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 910     # A workaround is to explicitly use -mthreads while linking Java programs.
 911     # See PR libgcj/28263.
 912     #
 913     # FIXME: In Java we are able to detect thread death at the end of
 914     # Thread.run() so we should be able to clean up the exception handling
 915     # contexts ourselves.
 916     THREADSTARTFILESPEC='crtmt%O%s'
 917     ;;
 918
 919  none)
 920     THREADH=no-threads.h
 921     ;;
 922 esac
 923 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 924 AC_SUBST(THREADLIBS)
 925 AC_SUBST(THREADINCS)
 926 AC_SUBST(THREADDEPS)
 927 AC_SUBST(THREADSPEC)
 928 AC_SUBST(THREADSTARTFILESPEC)
 929 AC_SUBST(THREADLDFLAGS)
 930 AC_SUBST(THREADCXXFLAGS)
 931 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 932 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 933 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 934 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 935
 936 if test -d sysdep; then true; else mkdir sysdep; fi
 937 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 938 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 939 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 940
 941 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 942 if test "$use_libgcj_bc" = yes; then
 943   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 944 fi
 945 AC_SUBST(LIBGCJ_SPEC)
 946
 947 HASH_SYNC_SPEC=
 948 # Hash synchronization is only useful with posix threads right now.
 949 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 950    HASH_SYNC_SPEC=-fhash-synchronization
 951    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 952 fi
 953 AC_SUBST(HASH_SYNC_SPEC)
 954
 955 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 956
 957 # We're in the tree with gcc, and need to include some of its headers.
 958 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
 959
 960 if test "x${with_newlib}" = "xyes"; then
 961    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 962    # may not work correctly, because the compiler may not be able to
 963    # link executables.
 964
 965    # We assume newlib.  This lets us hard-code the functions we know
 966    # we'll have.
 967    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 968    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 969    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 970    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 971    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 972    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 973    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 974    # This is only for POSIX threads.
 975    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 976    # We also assume we are using gcc, which provides alloca.
 977    AC_DEFINE(HAVE_ALLOCA)
 978
 979    # Assume we do not have getuid and friends.
 980    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 981    PLATFORMNET=NoNet
 982 else
 983    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 984                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 985                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
 986                    nl_langinfo setlocale \
 987                    inet_pton uname inet_ntoa \
 988                    fork execvp pipe sigaction ftruncate mmap \
 989                    getifaddrs])
 990    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 991    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 992    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 993    AC_CHECK_LIB(dl, dladdr, [
 994        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 995        AC_CHECK_LIB(dld, dladdr, [
 996        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 997
 998    if test x"$cross_compiling" = x"no"; then
 999      AC_CHECK_FILES(/proc/self/exe, [
1000        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1001    else
1002      case $host in
1003      *-linux*)
1004        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1005        ;;
1006      esac
1007    fi
1008
1009    AM_ICONV
1010    AM_LC_MESSAGES
1011    AC_STRUCT_TIMEZONE
1012
1013    AC_CHECK_FUNCS(gethostbyname_r, [
1014      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1015        [Define if you have the 'gethostbyname_r' function.])
1016      # There are two different kinds of gethostbyname_r.
1017      # We look for the one that returns `int'.
1018      # Hopefully this check is robust enough.
1019      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1020        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1021
1022      case " $GCINCS " in
1023      *" -D_REENTRANT "*) ;;
1024      *)
1025         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1026         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1027         [libjava_cv_gethostbyname_r_needs_reentrant],
1028         [ AC_LANG_PUSH(C++)
1029           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1030             [[gethostbyname_r("", 0, 0);]])],
1031             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1032                 CPPFLAGS_SAVE="$CPPFLAGS"
1033                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1034                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1035                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1036                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1037                 CPPFLAGS="$CPPFLAGS_SAVE"
1038           ])
1039           AC_LANG_POP(C++)
1040         ])
1041         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1042           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1043         fi
1044      ;;
1045      esac
1046
1047      AC_CACHE_CHECK([for struct hostent_data],
1048         [libjava_cv_struct_hostent_data], [dnl
1049         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1050 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1051 # define _REENTRANT 1
1052 #endif
1053 #include <netdb.h>]], [[struct hostent_data data;]])],
1054           [libjava_cv_struct_hostent_data=yes],
1055           [libjava_cv_struct_hostent_data=no])])
1056      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1057        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1058          [Define if struct hostent_data is defined in netdb.h])
1059      fi
1060    ])
1061
1062    # FIXME: libjava source code expects to find a prototype for
1063    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1064    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1065    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1066    # linkage check is enough, yet C++ code requires proper prototypes.)
1067    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1068    AC_CHECK_FUNCS(gethostbyaddr_r, [
1069      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1070        [Define if you have the 'gethostbyaddr_r' function.])
1071      # There are two different kinds of gethostbyaddr_r.
1072      # We look for the one that returns `int'.
1073      # Hopefully this check is robust enough.
1074      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1075        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1076          [Define if gethostbyaddr_r returns 'int'.])])])])
1077
1078    AC_CHECK_FUNCS(gethostname, [
1079      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1080        [Define if you have the 'gethostname' function.])
1081      AC_EGREP_HEADER(gethostname, unistd.h, [
1082        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1083          [Define if gethostname is declared in <unistd.h>.])])])
1084
1085    AC_CHECK_FUNCS(usleep, [
1086      AC_EGREP_HEADER(usleep, unistd.h, [
1087        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1088           [Define if usleep is declared in <unistd.h>.])])])
1089
1090    # Look for these functions in the thread library, but only bother
1091    # if using POSIX threads.
1092    if test "$THREADS" = posix; then
1093       save_LIBS="$LIBS"
1094       LIBS="$LIBS $THREADLIBS"
1095       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1096       # E.g., Solaris.
1097       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1098
1099       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1100       # Solaris 7 the name librt is preferred.
1101       AC_CHECK_FUNCS(sched_yield, , [
1102         AC_CHECK_LIB(rt, sched_yield, [
1103           AC_DEFINE(HAVE_SCHED_YIELD)
1104           THREADLIBS="$THREADLIBS -lrt"
1105           THREADSPEC="$THREADSPEC -lrt"], [
1106           AC_CHECK_LIB(posix4, sched_yield, [
1107             AC_DEFINE(HAVE_SCHED_YIELD)
1108             THREADLIBS="$THREADLIBS -lposix4"
1109             THREADSPEC="$THREADSPEC -lposix4"])])])
1110
1111       AC_CHECK_LIB(rt, clock_gettime, [
1112          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1113          case "$THREADSPEC" in
1114            *-lrt*) ;;
1115            *)
1116              THREADSPEC="$THREADSPEC -lrt"
1117              THREADLIBS="$THREADLIBS -lrt"
1118              ;;
1119          esac])
1120
1121       LIBS="$save_LIBS"
1122
1123       # We can save a little space at runtime if the mutex has m_count
1124       # or __m_count.  This is a nice hack for Linux.
1125       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1126           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1127         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1128              [Define if pthread_mutex_t has m_count member.]), [
1129         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1130             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1131           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1132             [Define if pthread_mutex_t has __m_count member.]))])
1133    fi
1134
1135    # We require a way to get the time.
1136    time_found=no
1137    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1138    if test "$time_found" = no; then
1139       AC_MSG_ERROR([no function found to get the time])
1140    fi
1141
1142    AC_CHECK_FUNCS(memmove)
1143
1144    # We require memcpy.
1145    memcpy_found=no
1146    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1147    if test "$memcpy_found" = no; then
1148       AC_MSG_ERROR([memcpy is required])
1149    fi
1150    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1151    AC_CHECK_LIB(dl, dlopen, [
1152        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1153        AC_CHECK_LIB(dld, dlopen, [
1154        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1155
1156    # Some library-finding code we stole from Tcl.
1157    #--------------------------------------------------------------------
1158    #    Check for the existence of the -lsocket and -lnsl libraries.
1159    #    The order here is important, so that they end up in the right
1160    #    order in the command line generated by make.  Here are some
1161    #    special considerations:
1162    #    1. Use "connect" and "accept" to check for -lsocket, and
1163    #       "gethostbyname" to check for -lnsl.
1164    #    2. Use each function name only once:  can't redo a check because
1165    #       autoconf caches the results of the last check and won't redo it.
1166    #    3. Use -lnsl and -lsocket only if they supply procedures that
1167    #       aren't already present in the normal libraries.  This is because
1168    #       IRIX 5.2 has libraries, but they aren't needed and they're
1169    #       bogus:  they goof up name resolution if used.
1170    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1171    #       To get around this problem, check for both libraries together
1172    #       if -lsocket doesn't work by itself.
1173    #--------------------------------------------------------------------
1174
1175    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1176     [gcj_cv_lib_sockets=
1177      gcj_checkBoth=0
1178      unset ac_cv_func_connect
1179      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1180      if test "$gcj_checkSocket" = 1; then
1181          unset ac_cv_func_connect
1182          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1183                       gcj_checkBoth=1)
1184      fi
1185      if test "$gcj_checkBoth" = 1; then
1186          gcj_oldLibs=$LIBS
1187          LIBS="$LIBS -lsocket -lnsl"
1188          unset ac_cv_func_accept
1189          AC_CHECK_FUNC(accept,
1190                        [gcj_checkNsl=0
1191                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1192          unset ac_cv_func_accept
1193          LIBS=$gcj_oldLibs
1194      fi
1195      unset ac_cv_func_gethostbyname
1196      gcj_oldLibs=$LIBS
1197      LIBS="$LIBS $gcj_cv_lib_sockets"
1198      AC_CHECK_FUNC(gethostbyname, ,
1199                    [AC_CHECK_LIB(nsl, main,
1200                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1201      unset ac_cv_func_gethostbyname
1202      LIBS=$gcj_oldLIBS
1203    ])
1204    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1205
1206    if test "$with_system_zlib" = yes; then
1207       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1208    fi
1209
1210    LIBMAGIC=
1211    AC_CHECK_LIB(magic, magic_open, [
1212       AC_DEFINE([HAVE_MAGIC_OPEN], 1, [Define if you have magic_open().])
1213       LIBMAGIC="-lmagic"])
1214    AC_SUBST(LIBMAGIC)
1215
1216    # Test for Gtk stuff, if asked for.
1217    if test "$use_gtk_awt" = yes; then
1218       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1219       AC_SUBST(GTK_CFLAGS)
1220       AC_SUBST(GTK_LIBS)
1221
1222       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1223       AC_SUBST(GLIB_CFLAGS)
1224       AC_SUBST(GLIB_LIBS)
1225
1226       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1227       AC_SUBST(LIBART_CFLAGS)
1228       AC_SUBST(LIBART_LIBS)
1229
1230       # We require the XTest Extension to support java.awt.Robot.
1231       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1232                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1233                    [${X_LIBS}])
1234    fi
1235
1236    # On Solaris, and maybe other architectures, the Boehm collector
1237    # requires -ldl.
1238    if test "$GC" = boehm; then
1239       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1240    fi
1241 fi
1242
1243 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1244 case $build in
1245     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1246     *)         CLASSPATH_SEPARATOR=':' ;;
1247 esac
1248 AC_SUBST(CLASSPATH_SEPARATOR)
1249
1250 # We must search the source tree for java.lang, since we still don't
1251 # have libgcj.jar nor java/lang/*.class
1252 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1253 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1254
1255 # Since some classes depend on this one, we need its source available
1256 # before we can do any GCJ compilation test :-(
1257 if test ! -f gnu/classpath/Configuration.java; then
1258   test -d gnu || mkdir gnu
1259   test -d gnu/classpath || mkdir gnu/classpath
1260   # Note that it is not crucial that all the values here be correct.
1261   sed -e "s,@prefix@,$prefix," \
1262       -e "s,@VERSION@,$VERSION," \
1263       -e "s,@LIBDEBUG@,false," \
1264       -e "s,@INIT_LOAD_LIBRARY@,false," \
1265       -e "s,@@,$LIBGCJDEBUG," \
1266       -e "s,@default_toolkit@,$TOOLKIT," \
1267       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1268       -e "s,@GTK_CAIRO_ENABLED@,false," \
1269         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1270         > gnu/classpath/Configuration.java
1271   # We do not want to redirect the output of the grep below to /dev/null,
1272   # but we add /dev/null to the input list so that grep will print the
1273   # filename of Configuration.java in case it finds any matches.
1274   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1275     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1276   fi
1277 fi
1278
1279 LT_AC_PROG_GCJ
1280
1281 # Now remove it.
1282 rm -f gnu/classpath/Configuration.java
1283
1284 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1285
1286 AC_CHECK_SIZEOF(void *)
1287
1288 AC_C_BIGENDIAN
1289
1290 ZLIBS=
1291 SYS_ZLIBS=
1292 ZINCS=
1293
1294 if test -z "$ZLIBSPEC"; then
1295    # Use zlib from the GCC tree.
1296    ZINCS='-I$(top_srcdir)/../zlib'
1297    ZLIBS=../zlib/libzgcj_convenience.la
1298 else
1299    # System's zlib.
1300    SYS_ZLIBS="$ZLIBSPEC"
1301 fi
1302 AC_SUBST(ZLIBS)
1303 AC_SUBST(SYS_ZLIBS)
1304 AC_SUBST(ZINCS)
1305 AC_SUBST(DIVIDESPEC)
1306 AC_SUBST(CHECKREFSPEC)
1307 AC_SUBST(EXCEPTIONSPEC)
1308 AC_SUBST(BACKTRACESPEC)
1309 AC_SUBST(IEEESPEC)
1310
1311 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1312 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1313 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1314 AC_SUBST(GCC_UNWIND_INCLUDE)
1315
1316 # Process the option "--enable-version-specific-runtime-libs"
1317 # Calculate toolexeclibdir
1318 case ${version_specific_libs} in
1319   yes)
1320     # Need the gcc compiler version to know where to install libraries
1321     # and header files if --enable-version-specific-runtime-libs option
1322     # is selected.
1323     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1324     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1325     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1326     toolexeclibdir=$toolexecmainlibdir
1327     ;;
1328   no)
1329     if test -n "$with_cross_host" &&
1330        test x"$with_cross_host" != x"no"; then
1331       # Install a library built with a cross compiler in tooldir, not libdir.
1332       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1333       toolexecmainlibdir='$(toolexecdir)/lib'
1334     else
1335       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1336       toolexecmainlibdir='$(libdir)'
1337     fi
1338     multi_os_directory=`$CC -print-multi-os-directory`
1339     case $multi_os_directory in
1340       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1341       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1342     esac
1343     ;;
1344 esac
1345 AC_SUBST(toolexecdir)
1346 AC_SUBST(toolexecmainlibdir)
1347 AC_SUBST(toolexeclibdir)
1348
1349 # Determine where the standard .db file and GNU Classpath JNI
1350 # libraries are found.
1351 multi_os_directory=`$CC -print-multi-os-directory`
1352 case $multi_os_directory in
1353   .)
1354    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1355    ;;
1356   *)
1357    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1358    ;;
1359 esac
1360 AC_SUBST(dbexecdir)
1361
1362 # Determine gcj version number.
1363 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1364 GCJVERSION=$gcjversion
1365 AC_SUBST(GCJVERSION)
1366 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1367
1368 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1369 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1370
1371 TL_AC_GXX_INCLUDE_DIR
1372
1373 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1374 # On that system, sys/ioctl.h will not include sys/filio.h unless
1375 # BSD_COMP is defined; just including sys/filio.h is simpler.
1376 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1377 # for now.  If you change this, you also must update natFile.cc.
1378 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1379                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1380                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1381                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1382                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1383 AC_CHECK_HEADERS(inttypes.h, [
1384     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1385     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1386 ])
1387 AC_HEADER_SYS_WAIT
1388
1389 AC_CHECK_TYPE([ssize_t], [int])
1390
1391 AC_MSG_CHECKING([for in_addr_t])
1392 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1393 #if STDC_HEADERS
1394 #include <stdlib.h>
1395 #include <stddef.h>
1396 #endif
1397 #if HAVE_NETINET_IN_H
1398 #include <netinet/in.h>
1399 #endif]], [[in_addr_t foo;]])],
1400   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1401      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1402    AC_MSG_RESULT(yes)],
1403   [AC_MSG_RESULT(no)])
1404
1405 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1406 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1407   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1408      [Define if struct ip_mreq is defined in netinet/in.h.])
1409    AC_MSG_RESULT(yes)],
1410   [AC_MSG_RESULT(no)])
1411
1412 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1413 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1414   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1415      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1416    AC_MSG_RESULT(yes)],
1417   [AC_MSG_RESULT(no)])
1418
1419 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1420 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1421   [AC_DEFINE(HAVE_INET6, 1,
1422      [Define if inet6 structures are defined in netinet/in.h.])
1423    AC_MSG_RESULT(yes)],
1424   [AC_MSG_RESULT(no)])
1425
1426 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1427 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1428 #include <sys/types.h>
1429 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1430   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1431    AC_MSG_RESULT(yes)],
1432   [AC_MSG_RESULT(no)])
1433
1434 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1435 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1436   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1437    AC_MSG_RESULT(yes)],
1438   [AC_MSG_RESULT(no)
1439    AC_MSG_CHECKING([for global timezone variable])
1440    dnl FIXME: we don't want a link check here because that won't work
1441    dnl when cross-compiling.  So instead we make an assumption that
1442    dnl the header file will mention timezone if it exists.
1443    dnl Don't find the win32 function timezone
1444    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1445      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1446       AC_MSG_RESULT(yes)],
1447      [AC_MSG_RESULT(no)
1448        AC_MSG_CHECKING([for global _timezone variable])
1449        dnl FIXME: As above, don't want link check
1450        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1451          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1452             [Define if your platform has the global _timezone variable.])
1453           AC_MSG_RESULT(yes)],
1454           [AC_MSG_RESULT(no)])])])
1455
1456 AC_FUNC_ALLOCA
1457
1458 AC_CHECK_PROGS(PERL, perl, false)
1459
1460 SYSDEP_SOURCES=
1461 SIGNAL_HANDLER_AUX=
1462
1463 case "${host}" in
1464  i?86-*-linux*)
1465     SIGNAL_HANDLER=include/i386-signal.h
1466     ;;
1467  sparc*-sun-solaris*)
1468     SIGNAL_HANDLER=include/sparc-signal.h
1469     ;;
1470 # ia64-*)
1471 #    SYSDEP_SOURCES=sysdep/ia64.c
1472 #    test -d sysdep || mkdir sysdep
1473 #    ;;
1474  hppa*-*-linux*)
1475     SIGNAL_HANDLER=include/pa-signal.h
1476     ;;
1477  hppa*-hp-hpux*)
1478     SIGNAL_HANDLER=include/hppa-signal.h
1479     ;;
1480  ia64-*-linux*)
1481     SIGNAL_HANDLER=include/dwarf2-signal.h
1482     ;;
1483  powerpc*-*-linux*)
1484     SIGNAL_HANDLER=include/powerpc-signal.h
1485     ;;
1486  alpha*-*-linux*)
1487     SIGNAL_HANDLER=include/dwarf2-signal.h
1488     ;;
1489  s390*-*-linux*)
1490     SIGNAL_HANDLER=include/s390-signal.h
1491     ;;
1492  x86_64*-*-linux*)
1493     SIGNAL_HANDLER=include/x86_64-signal.h
1494     SIGNAL_HANDLER_AUX=include/i386-signal.h
1495     ;;
1496  sparc*-*-linux*)
1497     SIGNAL_HANDLER=include/dwarf2-signal.h
1498     ;;
1499  sh*-*-linux*)
1500     SIGNAL_HANDLER=include/sh-signal.h
1501     ;;
1502  *mingw*)
1503     SIGNAL_HANDLER=include/win32-signal.h
1504     ;;
1505  mips*-*-linux*)
1506     SIGNAL_HANDLER=include/mips-signal.h
1507     ;;
1508  powerpc*-*-darwin*)
1509     SIGNAL_HANDLER=include/darwin-signal.h
1510     ;;
1511  *)
1512     SIGNAL_HANDLER=include/default-signal.h
1513     ;;
1514 esac
1515
1516 # If we're using sjlj exceptions, forget what we just learned.
1517 if test "$enable_sjlj_exceptions" = yes; then
1518    SIGNAL_HANDLER=include/default-signal.h
1519    SIGNAL_HANDLER_AUX=
1520 fi
1521
1522 AC_SUBST(SYSDEP_SOURCES)
1523
1524 if test -z "$SIGNAL_HANDLER_AUX"; then
1525   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1526 fi
1527
1528 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1529                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1530
1531 if test "${multilib}" = "yes"; then
1532   multilib_arg="--enable-multilib"
1533 else
1534   multilib_arg=
1535 fi
1536
1537 # See if we support thread-local storage.
1538 GCC_CHECK_TLS
1539
1540 # For _Unwind_GetIPInfo.
1541 GCC_CHECK_UNWIND_GETIPINFO
1542
1543 # Check if linker supports static linking on a per library basis
1544 LD_START_STATIC_SPEC=
1545 LD_FINISH_STATIC_SPEC=
1546 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1547   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1548     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1549     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1550   fi
1551 fi
1552 AC_SUBST(LD_START_STATIC_SPEC)
1553 AC_SUBST(LD_FINISH_STATIC_SPEC)
1554
1555 here=`${PWDCMD-pwd}`
1556 AC_SUBST(here)
1557
1558 # We get this from the environment.
1559 AC_SUBST(GCJFLAGS)
1560
1561 AC_CONFIG_FILES([
1562 Makefile
1563 libgcj.pc
1564 libgcj.spec
1565 libgcj-test.spec
1566 gcj/Makefile
1567 include/Makefile
1568 testsuite/Makefile
1569 ])
1570
1571 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1572
1573 AC_CONFIG_COMMANDS([default],
1574 [# Only add multilib support code if we just rebuilt top-level Makefile.
1575 case " $CONFIG_FILES " in
1576  *" Makefile "*)
1577    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1578    ac_file=Makefile . ${multi_basedir}/./libjava/../config-ml.in
1579    ;;
1580 esac
1581 for ac_multi_file in $CONFIG_FILES; do
1582   case $ac_multi_file in
1583   */Makefile)
1584     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1585   esac
1586 done
1587 ],
1588 srcdir=${srcdir}
1589 host=${host}
1590 target=${target}
1591 with_multisubdir=${with_multisubdir}
1592 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1593 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1594 multi_basedir=${multi_basedir}
1595 CC="${CC}"
1596 CXX="${CXX}"
1597 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1598 )
1599
1600 AC_OUTPUT