libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209
 210 libgcj_cflags=
 211 libgcj_cxxflags=
 212 libgcj_javaflags=
 213
 214 . ${srcdir}/configure.host
 215
 216 ACX_PROG_LD_GNU_SYMBOLIC
 217 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 218 if test -z "$libgcj_ld_symbolic"; then
 219   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 220 fi
 221
 222 LIBGCJ_CFLAGS="${libgcj_cflags}"
 223 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 224 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 225 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 226 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 227 AC_SUBST(LIBGCJ_CFLAGS)
 228 AC_SUBST(LIBGCJ_CXXFLAGS)
 229 AC_SUBST(LIBGCJ_JAVAFLAGS)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 231 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 232
 233 # Only use libltdl for non-newlib builds.
 234 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 235    AC_LTDL_SHLIBPATH
 236 fi
 237
 238 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 239
 240 # See if the user has requested runtime debugging.
 241 LIBGCJDEBUG="disable"
 242 AC_SUBST(LIBGCJDEBUG)
 243 AC_ARG_ENABLE(libgcj-debug,
 244   AS_HELP_STRING([--enable-libgcj-debug],
 245                  [enable runtime debugging code]),
 246   [if test "$enable_libgcj_debug" = yes; then
 247     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 248     LIBGCJDEBUG="enable"
 249   fi])
 250
 251 AC_ARG_WITH([escher],
 252          AS_HELP_STRING([--with-escher=ABS.PATH],
 253                         [specify path to escher dir or JAR for X peers]))
 254 case "$with_escher" in
 255 "")
 256         use_escher=false
 257         ;;
 258 "no")
 259         use_escher=false
 260         ;;
 261 "yes")
 262         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 263         ;;
 264 *)
 265         use_escher=true
 266         ;;
 267 esac
 268
 269 # Determine which AWT peer libraries to build
 270 AC_ARG_ENABLE(java-awt,
 271   AS_HELP_STRING([--enable-java-awt],
 272                  [list of AWT peer implementations to be built]))
 273
 274 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 275 use_xlib_awt=""
 276 use_gtk_awt=""
 277 use_qt_awt=""
 278 use_x_awt=""
 279 # The default toolkit to use is the first one specified.
 280 TOOLKIT=
 281 AC_SUBST(TOOLKIT)
 282
 283 for peer in $peerlibs ; do
 284   case $peer in
 285     xlib)
 286       if test "$no_x" = yes; then
 287         echo "*** xlib peers requested but no X library available" 1>&2
 288         exit 1
 289       else
 290         use_xlib_awt="yes"
 291         if test -z "$TOOLKIT"; then
 292            TOOLKIT=gnu.awt.xlib.XToolkit
 293         fi
 294       fi
 295       ;;
 296     gtk)
 297       if test "$no_x" = yes; then
 298          echo "*** gtk peers requested but no X library available" 1>&2
 299          exit 1
 300       else
 301          use_gtk_awt=yes
 302          if test -z "$TOOLKIT"; then
 303             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 304          fi
 305       fi
 306       ;;
 307     qt)
 308       if test "$no_x" = yes; then
 309          # Perhaps we should admit the possibility of embedded Qt.
 310          echo "*** Qt peers requested but no X library available" 1>&2
 311          exit 1
 312       else
 313          use_qt_awt=yes
 314          if test -z "$TOOLKIT"; then
 315             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 316          fi
 317       fi
 318       ;;
 319     x)
 320       use_x_awt=yes
 321       if test -z "$TOOLKIT"; then
 322          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 323       fi
 324       ;;
 325     no)
 326       use_xlib_awt=
 327       use_gtk_awt=
 328       use_qt_awt=
 329       use_x_awt=
 330       break
 331       ;;
 332     *)
 333       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 334       exit 1
 335   esac
 336 done
 337
 338 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 339 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 340
 341 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 342
 343 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 344
 345 # Create standard.omit based on decisions we just made.
 346 cp $srcdir/standard.omit.in standard.omit
 347 if test "$use_xlib_awt" != yes; then
 348    echo gnu/awt/xlib >> standard.omit
 349    echo gnu/gcj/xlib >> standard.omit
 350 fi
 351 if test "$use_x_awt" != yes; then
 352    echo gnu/java/awt/peer/x >> standard.omit
 353 fi
 354
 355 # Tools that need to be compiled against classpath's tools classes
 356 : > vm-tools-packages
 357 for package in gnu/gcj/tools/gc_analyze ; do
 358     echo $package >> standard.omit
 359     echo $package >> vm-tools-packages
 360 done
 361
 362 if test -z "${with_multisubdir}"; then
 363    builddotdot=.
 364 else
 365    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 366 fi
 367
 368 NATIVE=yes
 369
 370 # Which gcj and host gcj (for ecjx) do we use?
 371 which_gcj=default
 372 host_exeext=${ac_exeext}
 373 GCJ_FOR_ECJX=
 374 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 375 if test -n "${with_cross_host}"; then
 376   # We are being configured with a cross compiler. We can't
 377   # use ac_exeext, because that is for the target platform.
 378   NATIVE=no
 379   cross_host_exeext=
 380   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 381   case "${with_cross_host}" in
 382      *mingw* | *cygwin*)
 383          cross_host_exeext=.exe
 384      ;;
 385   esac
 386   host_exeext=${cross_host_exeext}
 387   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 388      if test x"$build_noncanonical" = x"$with_cross_host"; then
 389         # Ordinary cross (host!=target and host=build)
 390         which_gcj=built
 391      else
 392         # Canadian cross (host!=target and host!=build)
 393         which_gcj=cross
 394      fi
 395   else
 396      which_gcj=cross
 397   fi
 398 else
 399   # We are being configured with a native or crossed-native compiler
 400   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 401      if test x"$build" = x"$host"; then
 402         # True native build (host=target and host=build)
 403         which_gcj=built
 404      else
 405         # Crossed-native build (host=target and host!=build)
 406         which_gcj=cross
 407      fi
 408   else
 409      which_gcj=path
 410   fi
 411 fi
 412 case "${which_gcj}" in
 413    built)
 414       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 415       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 416    ;;
 417    cross)
 418       if test "x${with_newlib}" = "xyes"; then
 419          # FIXME (comment): Why is this needed?
 420          GCC_UNWIND_INCLUDE=
 421          GCJ="${target_noncanonical}-gcj"
 422       else
 423          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 424       fi
 425       GCJH='$(target_noncanonical)-gcjh'
 426    ;;
 427    path)
 428       GCJ="gcj -B`${PWDCMD-pwd}`/"
 429       GCJH=gcjh
 430    ;;
 431 esac
 432 JAVAC="$GCJ -C"
 433 export JAVAC
 434
 435 AC_SUBST(GCJ_FOR_ECJX)
 436 AC_SUBST(GCJH)
 437 AC_SUBST(host_exeext)
 438
 439 # Create it, so that compile/link tests don't fail
 440 test -f libgcj.spec || touch libgcj.spec
 441
 442
 443
 444 # Set up to configure Classpath.
 445 # FIXME: no supported way to pass args in autoconf.
 446 # Disable tool wrappers to avoid ltdl.h configure check.
 447 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 448 ac_configure_args="$ac_configure_args --disable-load-library"
 449 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 450 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 451 dir1=`cd $srcdir && pwd`
 452 dir2=`pwd`
 453 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 454 ac_configure_args="$ac_configure_args --disable-core-jni"
 455 dnl FIXME?
 456 ac_configure_args="$ac_configure_args --disable-examples"
 457 ac_configure_args="$ac_configure_args --with-glibj=build"
 458 if test "$plugin_enabled" != yes; then
 459   ac_configure_args="$ac_configure_args --disable-plugin"
 460 fi
 461 if test "$gconf_enabled" != yes; then
 462   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 463   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 464 fi
 465 if test "$use_gtk_awt" != yes; then
 466   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 467 fi
 468 if test "$use_qt_awt" != yes; then
 469   ac_configure_args="$ac_configure_args --disable-qt-peer"
 470 else
 471   # We need this as qt is disabled by default in classpath.
 472   ac_configure_args="$ac_configure_args --enable-qt-peer"
 473 fi
 474 if test "$use_x_awt" != yes; then
 475   ac_configure_args="$ac_configure_args --without-escher"
 476 else
 477   # We need this as escher is disabled by default in classpath.
 478   if test "$use_escher" != true; then
 479     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 480   else
 481     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 482   fi
 483 fi
 484 if test "x$BUILD_GJDOC" = xno; then
 485   ac_configure_args="$ac_configure_args --disable-gjdoc"
 486 fi
 487 # -Werror causes unavoidable problems in code using alsa.
 488 ac_configure_args="$ac_configure_args --disable-regen-headers"
 489 ac_configure_args="$ac_configure_args --disable-Werror"
 490 dnl --with-gcj=$GCJ
 491 dnl --with-javah=$GCJH
 492 dnl gtk-cairo -- just export here...
 493 dnl --enable-regen-headers?
 494
 495 # Only use libltdl for non-newlib builds.
 496 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 497    AC_LIBLTDL_CONVENIENCE
 498    AC_LIBTOOL_DLOPEN
 499    DIRLTDL=libltdl
 500    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 501    # Sigh.  Libtool's macro doesn't do the right thing.
 502    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 503    # FIXME: this is a hack.
 504    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 505    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 506 fi
 507 AC_SUBST(INCLTDL)
 508 AC_SUBST(LIBLTDL)
 509 AC_SUBST(DIRLTDL)
 510 AC_PROG_LIBTOOL
 511 AM_PROG_GCJ
 512 AM_PROG_CC_C_O
 513
 514 AC_CONFIG_SUBDIRS(classpath libltdl)
 515
 516 # The -no-testsuite modules omit the test subdir.
 517 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 518
 519 # Should the runtime set system properties by examining the
 520 # environment variable GCJ_PROPERTIES?
 521 AC_ARG_ENABLE(getenv-properties,
 522   AS_HELP_STRING([--disable-getenv-properties],
 523                  [don't set system properties from GCJ_PROPERTIES]))
 524
 525 # Whether GCJ_PROPERTIES is used depends on the target.
 526 if test -z "$enable_getenv_properties"; then
 527    enable_getenv_properties=${enable_getenv_properties_default-yes}
 528 fi
 529 if test "$enable_getenv_properties" = no; then
 530    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 531      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 532 fi
 533
 534 # Whether we should use arguments to main()
 535 if test -z "$enable_main_args"; then
 536    enable_main_args=${enable_main_args_default-yes}
 537 fi
 538 if test "$enable_main_args" = no; then
 539    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 540 fi
 541
 542
 543 # Should we use hashtable-based synchronization?
 544 # Currently works only for Linux X86/ia64
 545 # Typically faster and more space-efficient
 546 AC_ARG_ENABLE(hash-synchronization,
 547   AS_HELP_STRING([--enable-hash-synchronization],
 548                  [use global hash table for monitor locks]))
 549
 550 if test -z "$enable_hash_synchronization"; then
 551    enable_hash_synchronization=$enable_hash_synchronization_default
 552 fi
 553
 554
 555 install_ecj_jar=no
 556 ECJ_BUILD_JAR=
 557 ECJ_JAR=
 558 AC_ARG_WITH(ecj-jar,
 559         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 560         [ECJ_JAR=$withval],
 561         [if test -f $multi_basedir/ecj.jar; then
 562            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 563            ECJ_JAR='$(jardir)/ecj.jar'
 564            install_ecj_jar=yes
 565          fi])
 566 AC_SUBST(ECJ_BUILD_JAR)
 567 AC_SUBST(ECJ_JAR)
 568 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 569 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 570
 571 AC_ARG_WITH(java-home,
 572   AS_HELP_STRING([--with-java-home=DIRECTORY],
 573                  [value of java.home system property]),
 574                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 575 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 576 AC_SUBST(JAVA_HOME)
 577
 578 suppress_libgcj_bc=no
 579 AC_ARG_ENABLE(libgcj-bc,
 580   AS_HELP_STRING([--enable-libgcj-bc],
 581                  [enable(default) or disable BC ABI for portions of libgcj]),
 582   [if test "$enable_libgcj_bc" = "no"; then
 583      suppress_libgcj_bc=yes
 584    fi])
 585 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 586
 587 build_libgcj_reduced_reflection=no
 588 AC_ARG_ENABLE(reduced-reflection,
 589   AS_HELP_STRING([--enable-reduced-reflection],
 590                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 591   [if test "$enable_reduced_reflection" = "yes"; then
 592      build_libgcj_reduced_reflection=yes
 593    fi])
 594 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 595
 596 # What is the native OS API for MinGW?
 597 AC_ARG_WITH(win32-nlsapi,
 598   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 599                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 600 [case "${withval}" in
 601   ansi) with_win32_nlsapi=ansi ;;
 602   unicows) with_win32_nlsapi=unicows ;;
 603   unicode) with_win32_nlsapi=unicode ;;
 604   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 605 esac],[with_win32_nlsapi=ansi])
 606
 607 case "${with_win32_nlsapi}" in
 608   unicows | unicode)
 609     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 610       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 611     ;;
 612 esac
 613
 614 # configure.host sets slow_pthread_self if the synchronization code should
 615 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 616 if test "${slow_pthread_self}" = "yes"; then
 617   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 618     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 619 fi
 620
 621 # Check for gc debugging.  This option is handled both here and in the GC.
 622 AC_ARG_ENABLE(gc-debug,
 623    AS_HELP_STRING([--enable-gc-debug],
 624                   [include full support for pointer backtracing etc.]),
 625 [ if test "$enable_gc_debug" = "yes"; then
 626     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 627               [Define if we want to use debug calls into the garbage collector.])
 628   fi])
 629
 630 # See if the user has the interpreter included.
 631 AC_ARG_ENABLE(interpreter,
 632   AS_HELP_STRING([--enable-interpreter],
 633                  [enable interpreter]),
 634   [if test "$enable_interpreter" = yes; then
 635     # This can also be set in configure.host.
 636     libgcj_interpreter=yes
 637   elif test "$enable_interpreter" = no; then
 638     libgcj_interpreter=no
 639   fi])
 640
 641 if test "$libgcj_interpreter" = yes; then
 642    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 643 fi
 644 INTERPRETER="$libgcj_interpreter"
 645 AC_SUBST(INTERPRETER)
 646 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 647
 648 AC_MSG_CHECKING([for exception model to use])
 649 AC_LANG_PUSH(C++)
 650 AC_ARG_ENABLE(sjlj-exceptions,
 651   AS_HELP_STRING([--enable-sjlj-exceptions],
 652                  [force use of builtin_setjmp for exceptions]),
 653 [:],
 654 [dnl Botheration.  Now we've got to detect the exception model.
 655 dnl Link tests against libgcc.a are problematic since -- at least
 656 dnl as of this writing -- we've not been given proper -L bits for
 657 dnl single-tree newlib and libgloss.
 658 dnl
 659 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 660 dnl conftest files before we got a change to grep them first.
 661 cat > conftest.$ac_ext << EOF
 662 [#]line __oline__ "configure"
 663 struct S { ~S(); };
 664 void bar();
 665 void foo()
 666 {
 667   S s;
 668   bar();
 669 }
 670 EOF
 671 old_CXXFLAGS="$CXXFLAGS"
 672 CXXFLAGS=-S
 673 if AC_TRY_EVAL(ac_compile); then
 674   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 675     enable_sjlj_exceptions=yes
 676   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 677     enable_sjlj_exceptions=no
 678   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 679     # ARM EH ABI.
 680     enable_sjlj_exceptions=no
 681   fi
 682 fi
 683 CXXFLAGS="$old_CXXFLAGS"
 684 rm -f conftest*])
 685 if test x$enable_sjlj_exceptions = xyes; then
 686   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 687         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 688   ac_exception_model_name=sjlj
 689 elif test x$enable_sjlj_exceptions = xno; then
 690   ac_exception_model_name="call frame"
 691 else
 692   AC_MSG_ERROR([unable to detect exception model])
 693 fi
 694 AC_LANG_POP(C++)
 695 AC_MSG_RESULT($ac_exception_model_name)
 696
 697 # If we are non using SJLJ exceptions, and this host does not have support
 698 # for unwinding from a signal handler, enable checked dereferences and divides.
 699 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 700   CHECKREFSPEC=-fcheck-references
 701   DIVIDESPEC=-fuse-divide-subroutine
 702   EXCEPTIONSPEC=
 703 fi
 704
 705 # See if the user wants to disable java.net.  This is the mildly
 706 # ugly way that we admit that target-side configuration sucks.
 707 AC_ARG_ENABLE(java-net,
 708   AS_HELP_STRING([--disable-java-net],
 709                  [disable java.net]))
 710
 711 # Whether java.net is built by default can depend on the target.
 712 if test -z "$enable_java_net"; then
 713    enable_java_net=${enable_java_net_default-yes}
 714 fi
 715 if test "$enable_java_net" = no; then
 716    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 717 fi
 718
 719 # See if the user wants to configure without libffi.  Some
 720 # architectures don't support it, and default values are set in
 721 # configure.host.
 722 AC_ARG_WITH(libffi,
 723   AS_HELP_STRING([--without-libffi],
 724                  [don't use libffi]),
 725   [:],
 726   [with_libffi=${with_libffi_default-yes}])
 727
 728 LIBFFI=
 729 LIBFFIINCS=
 730 if test "$with_libffi" != no; then
 731    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 732    LIBFFI=../libffi/libffi_convenience.la
 733    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 734 fi
 735 AC_SUBST(LIBFFI)
 736 AC_SUBST(LIBFFIINCS)
 737
 738 # See if the user wants to disable JVMPI support.
 739 AC_ARG_ENABLE(jvmpi,
 740   AS_HELP_STRING([--disable-jvmpi],
 741                  [disable JVMPI support]))
 742
 743 if test "$enable_jvmpi" != no; then
 744     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 745 fi
 746
 747 # If the target is an eCos system, use the appropriate eCos
 748 # I/O routines.
 749 # FIXME: this should not be a local option but a global target
 750 # system; at present there is no eCos target.
 751 TARGET_ECOS=${PROCESS-"no"}
 752 AC_ARG_WITH(ecos,
 753 [  --with-ecos             enable runtime eCos target support],
 754 TARGET_ECOS="$with_ecos"
 755 )
 756
 757 case "$TARGET_ECOS" in
 758    no) case "$host" in
 759       *mingw*)
 760             PLATFORM=Win32
 761             PLATFORMNET=Win32
 762             PLATFORMH=win32.h
 763         CHECK_FOR_BROKEN_MINGW_LD
 764       ;;
 765       *)
 766             PLATFORM=Posix
 767             PLATFORMNET=Posix
 768             PLATFORMH=posix.h
 769       ;;
 770       esac
 771       ;;
 772    *)
 773       PLATFORM=Ecos
 774       PLATFORMNET=NoNet
 775       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 776       PLATFORMH=posix.h
 777       ;;
 778 esac
 779 AC_SUBST(PLATFORM)
 780 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 781
 782 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 783                                       [Define if you have int32_t and uint32_t.]))
 784 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 785                                         [Define if you have int32_t and uint32_t.]))
 786 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 787                                           [Define if you have u_int32_t]))
 788 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 789                                            [Define if you have u_int32_t]))
 790
 791 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 792 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 793
 794 case "$host" in
 795   *-darwin*) DARWIN_CRT=true ;;
 796   *) DARWIN_CRT=false ;;
 797 esac
 798 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 799
 800 # This may not be defined in a non-ANS conformant embedded system.
 801 # FIXME: Should these case a runtime exception in that case?
 802 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 803                                   [Define is you have 'localtime' in <time.h>]))
 804
 805 # Create the subdirectory for natFile.cc, or the attempt
 806 # to create the link will fail.
 807 test -d java || mkdir java
 808 test -d java/io || mkdir java/io
 809 test -d gnu || mkdir gnu
 810 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 811
 812 # Likewise for natConcreteProcess.cc.
 813 test -d java/lang || mkdir java/lang
 814 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 815
 816 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 817 test -d java/net || mkdir java/net
 818 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 819 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 820
 821 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 822 test -d gnu/java || mkdir gnu/java
 823 test -d gnu/java/net || mkdir gnu/java/net
 824 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 825 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 826
 827 # Likewise for natVMPipe.cc and natVMSelector.cc.
 828 test -d gnu/java/nio || mkdir gnu/java/nio
 829 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 830 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 831
 832 # Likewise for natFileChannelImpl.cc
 833 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 834 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 835
 836 case "${host}" in
 837     *mingw*)
 838       SYSTEMSPEC="-lgdi32 -lws2_32"
 839       if test "${with_win32_nlsapi}" = "unicows"; then
 840         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 841       fi
 842     ;;
 843     *)
 844       SYSTEMSPEC=
 845     ;;
 846 esac
 847 AC_SUBST(SYSTEMSPEC)
 848
 849 AC_ARG_WITH(system-zlib,
 850   AS_HELP_STRING([--with-system-zlib],
 851                  [use installed libz]))
 852 ZLIBSPEC=
 853 AC_SUBST(ZLIBSPEC)
 854 ZLIBTESTSPEC=
 855 AC_SUBST(ZLIBTESTSPEC)
 856
 857 AC_PATH_XTRA
 858
 859 # FIXME: this should be _libs on some hosts.
 860 libsubdir=.libs
 861
 862 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 863
 864 LIBSTDCXXSPEC=
 865 # extra LD Flags which are required for targets
 866 case "${host}" in
 867 *-*-darwin[[0-7]].*)
 868     # For now we have to disable it on darwin[8-9] because it slows down
 869     # the linking phase. A possible bug in ld?
 870     # on Darwin -single_module speeds up loading of the dynamic libraries.
 871     extra_ldflags_libjava=-Wl,-single_module
 872     ;;
 873 *-*-darwin[[912]]*)
 874     extra_gij_ldflags=-Wl,-allow_stack_execute
 875     ;;
 876 arm*linux*eabi)
 877     # Some of the ARM unwinder code is actually in libstdc++.  We
 878     # could in principle replicate it in libgcj, but it's better to
 879     # have a dependency on libstdc++.
 880     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 881     LIBSTDCXXSPEC=-lstdc++
 882     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 883     ;;
 884 esac
 885 AC_SUBST(extra_ldflags_libjava)
 886 AC_SUBST(extra_gij_ldflags)
 887 AC_SUBST(extra_ldflags)
 888 AC_SUBST(LIBSTDCXXSPEC)
 889
 890 AC_SUBST(LIBGCJTESTSPEC)
 891
 892 # Allow the GC to be disabled.  Can be useful when debugging.
 893 AC_MSG_CHECKING([for garbage collector to use])
 894 AC_ARG_ENABLE(java-gc,
 895   AS_HELP_STRING([--enable-java-gc=TYPE],
 896                  [choose garbage collector (default is boehm)]),
 897   [GC=$enableval],
 898   [GC=boehm])
 899 GCLIBS=
 900 GCINCS=
 901 GCDEPS=
 902 GCSPEC=
 903 JC1GCSPEC=
 904 GCTESTSPEC=
 905 case "$GC" in
 906  boehm)
 907     AC_MSG_RESULT(boehm)
 908     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 909     JC1GCSPEC='-fuse-boehm-gc'
 910     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 911     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 912     GCOBJS=boehm.lo
 913     GCHDR=boehm-gc.h
 914     # The POSIX thread support needs to know this.
 915     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 916     ;;
 917  no)
 918     AC_MSG_RESULT(none)
 919     GCHDR=no-gc.h
 920     ;;
 921  *)
 922     AC_MSG_ERROR([unrecognized collector "$GC"])
 923     ;;
 924 esac
 925 AC_SUBST(GCLIBS)
 926 AC_SUBST(GCINCS)
 927 AC_SUBST(GCDEPS)
 928 AC_SUBST(GCSPEC)
 929 AC_SUBST(JC1GCSPEC)
 930 AC_SUBST(GCTESTSPEC)
 931 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 932 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 933 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 934
 935
 936 AC_MSG_CHECKING([for thread model used by GCC])
 937 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 938 AC_MSG_RESULT([$THREADS])
 939
 940 case "$THREADS" in
 941  no | none | single)
 942     THREADS=none
 943     ;;
 944  aix | posix | posix95 | pthreads)
 945     THREADS=posix
 946     case "$host" in
 947      *-*-linux*)
 948         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 949         ;;
 950     esac
 951     ;;
 952  win32)
 953     ;;
 954  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 955     AC_MSG_ERROR(thread package $THREADS not yet supported)
 956     ;;
 957  *)
 958     AC_MSG_ERROR($THREADS is an unknown thread package)
 959     ;;
 960 esac
 961
 962 THREADCXXFLAGS=
 963 THREADLDFLAGS=
 964 THREADLIBS=
 965 THREADINCS=
 966 THREADDEPS=
 967 THREADH=
 968 THREADSPEC=
 969 THREADSTARTFILESPEC=
 970 case "$THREADS" in
 971  posix)
 972     case "$host" in
 973      *-*-cygwin*)
 974         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 975         ;;
 976      *-*-freebsd[[1234]]*)
 977         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 978         # merely adds pthread_* functions) but it does have a -pthread switch
 979         # which is required at link-time to select -lc_r *instead* of -lc.
 980         THREADLDFLAGS=-pthread
 981         # Don't set THREADSPEC here as might be expected since -pthread is
 982         # not processed when found within a spec file, it must come from
 983         # the command line.  For now, the user must provide the -pthread
 984         # switch to link code compiled with gcj.  In future, consider adding
 985         # support for weak references to pthread_* functions ala gthr.h API.
 986         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 987         ;;
 988      *-*-freebsd*)
 989         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 990         # systems which support threads and -lpthread.
 991         THREADLDFLAGS=-pthread
 992         THREADSPEC=-lpthread
 993         ;;
 994      alpha*-dec-osf* | hppa*-hp-hpux*)
 995         THREADCXXFLAGS=-pthread
 996         # boehm-gc needs some functions from librt, so link that too.
 997         THREADLIBS='-lpthread -lrt'
 998         THREADSPEC='-lpthread -lrt'
 999         ;;
1000      *)
1001         THREADLIBS=-lpthread
1002         THREADSPEC=-lpthread
1003         ;;
1004     esac
1005     THREADH=posix-threads.h
1006     # MIT pthreads doesn't seem to have the mutexattr functions.
1007     # But for now we don't check for it.  We just assume you aren't
1008     # using MIT pthreads.
1009     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1010
1011     # If we're using the Boehm GC, then we happen to know that it
1012     # defines _REENTRANT, so we don't bother.  Eww.
1013     if test "$GC" != boehm; then
1014        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1015     fi
1016     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1017     ;;
1018
1019  win32)
1020     THREADH=win32-threads.h
1021     THREADCXXFLAGS=-mthreads
1022     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1023     # But we do not want the executables created to be dependent on
1024     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1025     # exception handling contexts.  The following kludge achieves this effect
1026     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1027     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1028     # A workaround is to explicitly use -mthreads while linking Java programs.
1029     # See PR libgcj/28263.
1030     #
1031     # FIXME: In Java we are able to detect thread death at the end of
1032     # Thread.run() so we should be able to clean up the exception handling
1033     # contexts ourselves.
1034     THREADSTARTFILESPEC='crtmt%O%s'
1035     ;;
1036
1037  none)
1038     THREADH=no-threads.h
1039     ;;
1040 esac
1041 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1042 AC_SUBST(THREADLIBS)
1043 AC_SUBST(THREADINCS)
1044 AC_SUBST(THREADDEPS)
1045 AC_SUBST(THREADSPEC)
1046 AC_SUBST(THREADSTARTFILESPEC)
1047 AC_SUBST(THREADLDFLAGS)
1048 AC_SUBST(THREADCXXFLAGS)
1049 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1050 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1051 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1052 if test "$enable_shared" != yes; then
1053   use_libgcj_bc=no
1054 fi
1055 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1056
1057 if test -d sysdep; then true; else mkdir sysdep; fi
1058 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1059 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1060 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1061
1062 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
1063 if test "$use_libgcj_bc" = yes; then
1064   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:-lgcj;:-lgcj_bc}"
1065 fi
1066 AC_SUBST(LIBGCJ_SPEC)
1067
1068 HASH_SYNC_SPEC=
1069 # Hash synchronization is only useful with posix threads right now.
1070 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1071    HASH_SYNC_SPEC=-fhash-synchronization
1072    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1073 fi
1074 AC_SUBST(HASH_SYNC_SPEC)
1075
1076 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1077
1078 # We're in the tree with gcc, and need to include some of its headers.
1079 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1080
1081 if test "x${with_newlib}" = "xyes"; then
1082    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1083    # may not work correctly, because the compiler may not be able to
1084    # link executables.
1085
1086    # We assume newlib.  This lets us hard-code the functions we know
1087    # we'll have.
1088    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1089    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1090    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1091    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1092    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1093    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1094    # This is only for POSIX threads.
1095    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1096
1097    # Assume we do not have getuid and friends.
1098    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1099    PLATFORMNET=NoNet
1100 else
1101    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1102                    localtime_r getpwuid_r getcwd \
1103                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1104                    nl_langinfo setlocale \
1105                    inet_pton uname inet_ntoa \
1106                    getrlimit sigaction ftruncate mmap \
1107                    getifaddrs])
1108    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1109    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1110    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1111    AC_CHECK_LIB(dl, dladdr, [
1112        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1113        AC_CHECK_LIB(dld, dladdr, [
1114        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1115
1116    if test x"$cross_compiling" = x"no"; then
1117      AC_CHECK_FILES(/proc/self/exe, [
1118        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1119      AC_CHECK_FILES(/proc/self/maps, [
1120        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1121          [Define if you have /proc/self/maps])])
1122    else
1123      case $host in
1124      *-linux*)
1125        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1126        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1127        ;;
1128      esac
1129    fi
1130
1131    AM_ICONV
1132    AM_LC_MESSAGES
1133    AC_STRUCT_TIMEZONE
1134
1135    AC_CHECK_FUNCS(gethostbyname_r, [
1136      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1137        [Define if you have the 'gethostbyname_r' function.])
1138      # There are two different kinds of gethostbyname_r.
1139      # We look for the one that returns `int'.
1140      # Hopefully this check is robust enough.
1141      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1142        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1143
1144      case " $GCINCS " in
1145      *" -D_REENTRANT "*) ;;
1146      *)
1147         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1148         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1149         [libjava_cv_gethostbyname_r_needs_reentrant],
1150         [ AC_LANG_PUSH(C++)
1151           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1152             [[gethostbyname_r("", 0, 0);]])],
1153             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1154                 CPPFLAGS_SAVE="$CPPFLAGS"
1155                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1156                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1157                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1158                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1159                 CPPFLAGS="$CPPFLAGS_SAVE"
1160           ])
1161           AC_LANG_POP(C++)
1162         ])
1163         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1164           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1165         fi
1166      ;;
1167      esac
1168
1169      AC_CACHE_CHECK([for struct hostent_data],
1170         [libjava_cv_struct_hostent_data], [dnl
1171         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1172 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1173 # define _REENTRANT 1
1174 #endif
1175 #include <netdb.h>]], [[struct hostent_data data;]])],
1176           [libjava_cv_struct_hostent_data=yes],
1177           [libjava_cv_struct_hostent_data=no])])
1178      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1179        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1180          [Define if struct hostent_data is defined in netdb.h])
1181      fi
1182    ])
1183
1184    # FIXME: libjava source code expects to find a prototype for
1185    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1186    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1187    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1188    # linkage check is enough, yet C++ code requires proper prototypes.)
1189    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1190    AC_CHECK_FUNCS(gethostbyaddr_r, [
1191      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1192        [Define if you have the 'gethostbyaddr_r' function.])
1193      # There are two different kinds of gethostbyaddr_r.
1194      # We look for the one that returns `int'.
1195      # Hopefully this check is robust enough.
1196      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1197        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1198          [Define if gethostbyaddr_r returns 'int'.])])])])
1199
1200    AC_CHECK_FUNCS(gethostname, [
1201      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1202        [Define if you have the 'gethostname' function.])
1203      AC_EGREP_HEADER(gethostname, unistd.h, [
1204        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1205          [Define if gethostname is declared in <unistd.h>.])])])
1206
1207    AC_CHECK_FUNCS(usleep, [
1208      AC_EGREP_HEADER(usleep, unistd.h, [
1209        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1210           [Define if usleep is declared in <unistd.h>.])])])
1211
1212    # Look for these functions in the thread library, but only bother
1213    # if using POSIX threads.
1214    if test "$THREADS" = posix; then
1215       save_LIBS="$LIBS"
1216       LIBS="$LIBS $THREADLIBS"
1217
1218       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1219       # Solaris 7 the name librt is preferred.
1220       AC_CHECK_FUNCS(sched_yield, , [
1221         AC_CHECK_LIB(rt, sched_yield, [
1222           AC_DEFINE(HAVE_SCHED_YIELD)
1223           THREADLIBS="$THREADLIBS -lrt"
1224           THREADSPEC="$THREADSPEC -lrt"], [
1225           AC_CHECK_LIB(posix4, sched_yield, [
1226             AC_DEFINE(HAVE_SCHED_YIELD)
1227             THREADLIBS="$THREADLIBS -lposix4"
1228             THREADSPEC="$THREADSPEC -lposix4"])])])
1229
1230       AC_CHECK_LIB(rt, clock_gettime, [
1231          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1232          case "$THREADSPEC" in
1233            *-lrt*) ;;
1234            *)
1235              THREADSPEC="$THREADSPEC -lrt"
1236              THREADLIBS="$THREADLIBS -lrt"
1237              ;;
1238          esac])
1239
1240       LIBS="$save_LIBS"
1241
1242       # We can save a little space at runtime if the mutex has m_count
1243       # or __m_count.  This is a nice hack for Linux.
1244       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1245           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1246         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1247              [Define if pthread_mutex_t has m_count member.]), [
1248         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1249             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1250           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1251             [Define if pthread_mutex_t has __m_count member.]))])
1252    fi
1253
1254    # We require a way to get the time.
1255    time_found=no
1256    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1257    if test "$time_found" = no; then
1258       AC_MSG_ERROR([no function found to get the time])
1259    fi
1260
1261    AC_CHECK_FUNCS(memmove)
1262
1263    # We require memcpy.
1264    memcpy_found=no
1265    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1266    if test "$memcpy_found" = no; then
1267       AC_MSG_ERROR([memcpy is required])
1268    fi
1269    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1270    AC_CHECK_LIB(dl, dlopen, [
1271        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1272        AC_CHECK_LIB(dld, dlopen, [
1273        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1274
1275    # Some library-finding code we stole from Tcl.
1276    #--------------------------------------------------------------------
1277    #    Check for the existence of the -lsocket and -lnsl libraries.
1278    #    The order here is important, so that they end up in the right
1279    #    order in the command line generated by make.  Here are some
1280    #    special considerations:
1281    #    1. Use "connect" and "accept" to check for -lsocket, and
1282    #       "gethostbyname" to check for -lnsl.
1283    #    2. Use each function name only once:  can't redo a check because
1284    #       autoconf caches the results of the last check and won't redo it.
1285    #    3. Use -lnsl and -lsocket only if they supply procedures that
1286    #       aren't already present in the normal libraries.  This is because
1287    #       IRIX 5.2 has libraries, but they aren't needed and they're
1288    #       bogus:  they goof up name resolution if used.
1289    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1290    #       To get around this problem, check for both libraries together
1291    #       if -lsocket doesn't work by itself.
1292    #--------------------------------------------------------------------
1293
1294    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1295     [gcj_cv_lib_sockets=
1296      gcj_checkBoth=0
1297      unset ac_cv_func_connect
1298      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1299      if test "$gcj_checkSocket" = 1; then
1300          unset ac_cv_func_connect
1301          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1302                       gcj_checkBoth=1)
1303      fi
1304      if test "$gcj_checkBoth" = 1; then
1305          gcj_oldLibs=$LIBS
1306          LIBS="$LIBS -lsocket -lnsl"
1307          unset ac_cv_func_accept
1308          AC_CHECK_FUNC(accept,
1309                        [gcj_checkNsl=0
1310                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1311          unset ac_cv_func_accept
1312          LIBS=$gcj_oldLibs
1313      fi
1314      unset ac_cv_func_gethostbyname
1315      gcj_oldLibs=$LIBS
1316      LIBS="$LIBS $gcj_cv_lib_sockets"
1317      AC_CHECK_FUNC(gethostbyname, ,
1318                    [AC_CHECK_LIB(nsl, main,
1319                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1320      unset ac_cv_func_gethostbyname
1321      LIBS=$gcj_oldLIBS
1322    ])
1323    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1324
1325    if test "$with_system_zlib" = yes; then
1326       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1327    fi
1328
1329    # Test for Gtk stuff, if asked for.
1330    if test "$use_gtk_awt" = yes; then
1331       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1332       AC_SUBST(GTK_CFLAGS)
1333       AC_SUBST(GTK_LIBS)
1334
1335       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1336       AC_SUBST(GLIB_CFLAGS)
1337       AC_SUBST(GLIB_LIBS)
1338
1339       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1340       AC_SUBST(LIBART_CFLAGS)
1341       AC_SUBST(LIBART_LIBS)
1342
1343       # We require the XTest Extension to support java.awt.Robot.
1344       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1345                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1346                    [${X_LIBS}])
1347    fi
1348
1349    # On Solaris, and maybe other architectures, the Boehm collector
1350    # requires -ldl.
1351    if test "$GC" = boehm; then
1352       case "${host}" in
1353           mips-sgi-irix6*)
1354             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1355             # libgcj.spec is used, so override here
1356             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1357           ;;
1358           *)
1359             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1360           ;;
1361       esac
1362    fi
1363 fi
1364
1365 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1366 case $build in
1367     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1368     *)         CLASSPATH_SEPARATOR=':' ;;
1369 esac
1370 AC_SUBST(CLASSPATH_SEPARATOR)
1371
1372 # We must search the source tree for java.lang, since we still don't
1373 # have libgcj.jar nor java/lang/*.class
1374 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1375 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1376
1377 # Since some classes depend on this one, we need its source available
1378 # before we can do any GCJ compilation test :-(
1379 if test ! -f gnu/classpath/Configuration.java; then
1380   test -d gnu || mkdir gnu
1381   test -d gnu/classpath || mkdir gnu/classpath
1382   # Note that it is not crucial that all the values here be correct.
1383   sed -e "s,@prefix@,$prefix," \
1384       -e "s,@VERSION@,$VERSION," \
1385       -e "s,@LIBDEBUG@,false," \
1386       -e "s,@INIT_LOAD_LIBRARY@,false," \
1387       -e "s,@@,$LIBGCJDEBUG," \
1388       -e "s,@default_toolkit@,$TOOLKIT," \
1389       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1390       -e "s,@GTK_CAIRO_ENABLED@,false," \
1391       -e "s,@ECJ_JAR@,," \
1392       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1393         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1394         > gnu/classpath/Configuration.java
1395   # We do not want to redirect the output of the grep below to /dev/null,
1396   # but we add /dev/null to the input list so that grep will print the
1397   # filename of Configuration.java in case it finds any matches.
1398   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1399     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1400   fi
1401 fi
1402
1403 LT_AC_PROG_GCJ
1404
1405 # Now remove it.
1406 rm -f gnu/classpath/Configuration.java
1407
1408 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1409
1410 AC_CHECK_SIZEOF(void *)
1411
1412 AC_C_BIGENDIAN
1413
1414 ZLIBS=
1415 SYS_ZLIBS=
1416 ZINCS=
1417
1418 if test -z "$ZLIBSPEC"; then
1419    # Use zlib from the GCC tree.
1420    ZINCS='-I$(top_srcdir)/../zlib'
1421    ZLIBS=../zlib/libzgcj_convenience.la
1422 else
1423    # System's zlib.
1424    SYS_ZLIBS="$ZLIBSPEC"
1425 fi
1426 AC_SUBST(ZLIBS)
1427 AC_SUBST(SYS_ZLIBS)
1428 AC_SUBST(ZINCS)
1429 AC_SUBST(DIVIDESPEC)
1430 AC_SUBST(CHECKREFSPEC)
1431 AC_SUBST(EXCEPTIONSPEC)
1432 AC_SUBST(BACKTRACESPEC)
1433 AC_SUBST(IEEESPEC)
1434
1435 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1436 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1437 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1438 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1439 AC_SUBST(GCC_UNWIND_INCLUDE)
1440
1441 # Process the option "--enable-version-specific-runtime-libs"
1442 # Calculate toolexeclibdir
1443 case ${version_specific_libs} in
1444   yes)
1445     # Need the gcc compiler version to know where to install libraries
1446     # and header files if --enable-version-specific-runtime-libs option
1447     # is selected.
1448     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1449     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1450     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1451     toolexeclibdir=$toolexecmainlibdir
1452     ;;
1453   no)
1454     if test -n "$with_cross_host" &&
1455        test x"$with_cross_host" != x"no"; then
1456       # Install a library built with a cross compiler in tooldir, not libdir.
1457       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1458       toolexecmainlibdir='$(toolexecdir)/lib'
1459     else
1460       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1461       toolexecmainlibdir='$(libdir)'
1462     fi
1463     multi_os_directory=`$CC -print-multi-os-directory`
1464     case $multi_os_directory in
1465       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1466       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1467     esac
1468     ;;
1469 esac
1470 AC_SUBST(toolexecdir)
1471 AC_SUBST(toolexecmainlibdir)
1472 AC_SUBST(toolexeclibdir)
1473
1474 # Determine gcj and libgcj version number.
1475 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1476 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1477 GCJVERSION=$gcjversion
1478 AC_SUBST(GCJVERSION)
1479 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1480
1481 # Determine where the standard .db file and GNU Classpath JNI
1482 # libraries are found.
1483 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1484 multi_os_directory=`$CC -print-multi-os-directory`
1485 case $multi_os_directory in
1486   .)
1487    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1488    ;;
1489   *)
1490    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1491    ;;
1492 esac
1493 AC_SUBST(dbexecdir)
1494 AC_SUBST(gcjsubdir)
1495
1496 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1497 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1498
1499 TL_AC_GXX_INCLUDE_DIR
1500
1501 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1502 # On that system, sys/ioctl.h will not include sys/filio.h unless
1503 # BSD_COMP is defined; just including sys/filio.h is simpler.
1504 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1505 # for now.  If you change this, you also must update natFile.cc.
1506 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1507                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1508                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1509                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1510                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1511 AC_CHECK_HEADERS(inttypes.h, [
1512     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1513     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1514 ])
1515
1516 AC_CHECK_TYPE([ssize_t], [int])
1517 AC_CHECK_TYPE([magic_t], [
1518     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1519 #ifdef HAVE_MAGIC_H
1520 #include <magic.h>
1521 #endif])
1522
1523 AC_MSG_CHECKING([for in_addr_t])
1524 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1525 #if STDC_HEADERS
1526 #include <stdlib.h>
1527 #include <stddef.h>
1528 #endif
1529 #if HAVE_NETINET_IN_H
1530 #include <netinet/in.h>
1531 #endif]], [[in_addr_t foo;]])],
1532   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1533      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1534    AC_MSG_RESULT(yes)],
1535   [AC_MSG_RESULT(no)])
1536
1537 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1538 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1539   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1540      [Define if struct ip_mreq is defined in netinet/in.h.])
1541    AC_MSG_RESULT(yes)],
1542   [AC_MSG_RESULT(no)])
1543
1544 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1545 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1546   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1547      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1548    AC_MSG_RESULT(yes)],
1549   [AC_MSG_RESULT(no)])
1550
1551 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1552 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1553   [AC_DEFINE(HAVE_INET6, 1,
1554      [Define if inet6 structures are defined in netinet/in.h.])
1555    AC_MSG_RESULT(yes)],
1556   [AC_MSG_RESULT(no)])
1557
1558 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1559 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1560 #include <sys/types.h>
1561 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1562   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1563    AC_MSG_RESULT(yes)],
1564   [AC_MSG_RESULT(no)])
1565
1566 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1567 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1568   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1569    AC_MSG_RESULT(yes)],
1570   [AC_MSG_RESULT(no)
1571    AC_MSG_CHECKING([for global timezone variable])
1572    dnl FIXME: we don't want a link check here because that won't work
1573    dnl when cross-compiling.  So instead we make an assumption that
1574    dnl the header file will mention timezone if it exists.
1575    dnl Don't find the win32 function timezone
1576    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1577      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1578       AC_MSG_RESULT(yes)],
1579      [AC_MSG_RESULT(no)
1580        AC_MSG_CHECKING([for global _timezone variable])
1581        dnl FIXME: As above, don't want link check
1582        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1583          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1584             [Define if your platform has the global _timezone variable.])
1585           AC_MSG_RESULT(yes)],
1586           [AC_MSG_RESULT(no)])])])
1587
1588 AC_CHECK_PROGS(PERL, perl, false)
1589
1590 SYSDEP_SOURCES=
1591 SIGNAL_HANDLER_AUX=
1592
1593 case "${host}" in
1594  i?86-*-linux*)
1595     SIGNAL_HANDLER=include/i386-signal.h
1596     ;;
1597  sparc*-sun-solaris*)
1598     SIGNAL_HANDLER=include/sparc-signal.h
1599     ;;
1600 # ia64-*)
1601 #    SYSDEP_SOURCES=sysdep/ia64.c
1602 #    test -d sysdep || mkdir sysdep
1603 #    ;;
1604  hppa*-*-linux*)
1605     SIGNAL_HANDLER=include/pa-signal.h
1606     ;;
1607  hppa*-hp-hpux*)
1608     SIGNAL_HANDLER=include/hppa-signal.h
1609     ;;
1610  ia64-*-linux*)
1611     SIGNAL_HANDLER=include/dwarf2-signal.h
1612     ;;
1613  powerpc*-*-linux*)
1614     SIGNAL_HANDLER=include/powerpc-signal.h
1615     ;;
1616  alpha*-*-linux*)
1617     SIGNAL_HANDLER=include/dwarf2-signal.h
1618     ;;
1619  s390*-*-linux*)
1620     SIGNAL_HANDLER=include/s390-signal.h
1621     ;;
1622  x86_64*-*-linux*)
1623     SIGNAL_HANDLER=include/x86_64-signal.h
1624     SIGNAL_HANDLER_AUX=include/i386-signal.h
1625     ;;
1626  sparc*-*-linux*)
1627     SIGNAL_HANDLER=include/dwarf2-signal.h
1628     ;;
1629  sh*-*-linux*)
1630     SIGNAL_HANDLER=include/sh-signal.h
1631     ;;
1632  *mingw*)
1633     SIGNAL_HANDLER=include/win32-signal.h
1634     ;;
1635  mips*-*-linux*)
1636     SIGNAL_HANDLER=include/mips-signal.h
1637     ;;
1638  m68*-*-linux*)
1639     SIGNAL_HANDLER=include/dwarf2-signal.h
1640     ;;
1641  powerpc*-*-darwin* | i?86-*-darwin9* | x86_64-*-darwin9*)
1642     SIGNAL_HANDLER=include/darwin-signal.h
1643     ;;
1644  powerpc*-*-aix*)
1645     SIGNAL_HANDLER=include/aix-signal.h
1646     ;;
1647  *)
1648     SIGNAL_HANDLER=include/default-signal.h
1649     ;;
1650 esac
1651
1652 # If we're using sjlj exceptions, forget what we just learned.
1653 if test "$enable_sjlj_exceptions" = yes; then
1654    SIGNAL_HANDLER=include/default-signal.h
1655    SIGNAL_HANDLER_AUX=
1656 fi
1657
1658 AC_SUBST(SYSDEP_SOURCES)
1659
1660 if test -z "$SIGNAL_HANDLER_AUX"; then
1661   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1662 fi
1663
1664 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1665                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1666
1667 if test "${multilib}" = "yes"; then
1668   multilib_arg="--enable-multilib"
1669 else
1670   multilib_arg=
1671 fi
1672
1673 # See if we support thread-local storage.
1674 GCC_CHECK_TLS
1675
1676 # For _Unwind_GetIPInfo.
1677 GCC_CHECK_UNWIND_GETIPINFO
1678
1679 # See if linker supports anonymous version scripts.
1680 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1681   [libjava_cv_anon_version_script],
1682   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1683    libjava_cv_anon_version_script=no
1684    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1685    echo '{ global: globalsymb*; local: *; };' > conftest.map
1686    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1687                [libjava_cv_anon_version_script=yes], [])
1688    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1689   ])
1690 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1691
1692 # Check if linker supports static linking on a per library basis
1693 LD_START_STATIC_SPEC=
1694 LD_FINISH_STATIC_SPEC=
1695 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1696   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1697     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1698     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1699   fi
1700 fi
1701 AC_SUBST(LD_START_STATIC_SPEC)
1702 AC_SUBST(LD_FINISH_STATIC_SPEC)
1703
1704 here=`${PWDCMD-pwd}`
1705 AC_SUBST(here)
1706
1707 # We get this from the environment.
1708 AC_SUBST(GCJFLAGS)
1709
1710 AC_ARG_WITH([python-dir],
1711             AS_HELP_STRING([--with-python-dir],
1712                            [the location to install Python modules. This path should NOT include the prefix.]),
1713             [with_python_dir=$withval], [with_python_dir=""])
1714
1715 if test "x${with_python_dir}" = "x"
1716 then
1717   # Needed for installing Python modules during make install.
1718   python_mod_dir="\${prefix}/share/python"
1719   # Needed for substituting into aot-compile*
1720   python_mod_dir_expanded="${prefix}/share/python"
1721 else
1722   python_mod_dir="\${prefix}${with_python_dir}"
1723   python_mod_dir_expanded="${prefix}${with_python_dir}"
1724 fi
1725 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1726 AC_SUBST(python_mod_dir)
1727 AC_SUBST(python_mod_dir_expanded)
1728
1729 # needed for aot-compile-rpm
1730 MAKE=`which make`
1731 AC_SUBST(MAKE)
1732
1733 AC_ARG_ENABLE([aot-compile-rpm],
1734   [AS_HELP_STRING([--enable-aot-compile-rpm],
1735                  [enable installation of aot-compile-rpm [default=no]])],
1736   [case "${enableval}" in
1737     yes) AOT_RPM_ENABLED=yes ;;
1738     no)  AOT_RPM_ENABLED=no ;;
1739     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1740   esac],
1741   [AOT_RPM_ENABLED=no]
1742 )
1743 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1744
1745 AC_ARG_ENABLE([java-home],
1746   [AS_HELP_STRING([--enable-java-home],
1747                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1748   [case "${enableval}" in
1749     yes) JAVA_HOME_ENABLED=yes ;;
1750     no)  JAVA_HOME_ENABLED=no ;;
1751     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1752   esac],
1753   [JAVA_HOME_ENABLED=no]
1754 )
1755 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1756
1757 # Only do these checks if java-home above is enabled.
1758 if test "x${JAVA_HOME_ENABLED}" = xyes
1759 then
1760
1761   AC_ARG_WITH([gcc-suffix],
1762               AS_HELP_STRING([--with-gcc-suffix],
1763                              [the GCC tool suffix (defaults to empty string)]),
1764               [gcc_suffix=$withval], [gcc_suffix=""])
1765   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1766   AC_SUBST(gcc_suffix)
1767
1768   AC_ARG_WITH([arch-directory],
1769               AS_HELP_STRING([--with-arch-directory],
1770                              [the arch directory under jre/lib (defaults to auto-detect)]),
1771               [host_cpu=$withval], [host_cpu=""])
1772
1773   AC_ARG_WITH([os-directory],
1774               AS_HELP_STRING([--with-os-directory],
1775                              [the os directory under include (defaults to auto-detect)]),
1776               [host_os=$withval], [host_os=""])
1777
1778   AC_ARG_WITH([origin-name],
1779               AS_HELP_STRING([--with-origin-name],
1780                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1781               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1782   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1783
1784   AC_ARG_WITH([arch-suffix],
1785               AS_HELP_STRING([--with-arch-suffix],
1786                              [the arch directory suffix (default is the empty string]),
1787               [arch_suffix=$withval], [arch_suffix=""])
1788   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1789
1790   AC_ARG_WITH([jvm-root-dir],
1791               AS_HELP_STRING([--with-jvm-root-dir],
1792                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1793               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1794   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1795
1796   AC_ARG_WITH([jvm-jar-dir],
1797               AS_HELP_STRING([--with-jvm-jar-dir],
1798                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1799               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1800   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1801
1802   JAVA_VERSION=1.5.0
1803   BUILD_VERSION=0
1804   AC_SUBST(JAVA_VERSION)
1805   AC_SUBST(BUILD_VERSION)
1806   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1807
1808   jre_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}/jre
1809   sdk_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}
1810   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1811   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1812
1813   JVM_ROOT_DIR=${jvm_root_dir}
1814   AC_SUBST(JVM_ROOT_DIR)
1815   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1816
1817   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1818   AC_SUBST(JVM_JAR_ROOT_DIR)
1819   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1820
1821   JVM_JAR_DIR=${jvm_jar_dir}/${sdk_dir}
1822   AC_SUBST(JVM_JAR_DIR)
1823   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1824
1825   JRE_DIR=${jre_dir}
1826   AC_SUBST(JRE_DIR)
1827
1828   SDK_DIR=${sdk_dir}
1829   AC_SUBST(SDK_DIR)
1830
1831   JRE_LNK=${jre_lnk}
1832   AC_SUBST(JRE_LNK)
1833
1834   SDK_LNK=${sdk_lnk}
1835   AC_SUBST(SDK_LNK)
1836
1837   SDK_BIN_DIR=${jvm_root_dir}/${sdk_dir}/bin
1838   AC_SUBST(SDK_BIN_DIR)
1839   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1840
1841   SDK_LIB_DIR=${jvm_root_dir}/${sdk_dir}/lib
1842   AC_SUBST(SDK_LIB_DIR)
1843   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1844
1845   SDK_INCLUDE_DIR=${jvm_root_dir}/${sdk_dir}/include
1846   AC_SUBST(SDK_INCLUDE_DIR)
1847   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1848
1849   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1850   AC_SUBST(JRE_BIN_DIR)
1851   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1852
1853   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1854   AC_SUBST(JRE_LIB_DIR)
1855   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1856
1857   # Find gcj prefix using gcj found in PATH.
1858   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1859
1860   # Where do the gcj binaries live?
1861   # For jhbuild based builds, they all live in a sibling of bin called
1862   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1863   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1864   AC_SUBST(GCJ_BIN_DIR)
1865   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1866
1867   echo host is ${host}
1868   if test "x${host_cpu}" = "x"
1869   then
1870     case ${host} in
1871       *-mingw* | *-cygwin*)
1872         host_cpu=x86;;
1873       i486-* | i586-* | i686-*)
1874         host_cpu=i386;;
1875       *)
1876         host_cpu=${host_cpu};;
1877     esac
1878   fi
1879   AC_MSG_RESULT(arch directory: ${host_cpu})
1880   CPU=${host_cpu}
1881   AC_SUBST(CPU)
1882
1883   if test "x${host_os}" = "x"
1884   then
1885     case ${host} in
1886       *-mingw* | *-cygwin*)
1887         host_os=win32;;
1888       *-linux*)
1889         host_os=linux;;
1890       *)
1891         host_os=${host_os};;
1892     esac
1893   fi
1894   echo os directory: ${host_os}
1895   OS=${host_os}
1896   AC_SUBST(OS)
1897
1898   # make an expanded $libdir, for substituting into
1899   # scripts (and other non-Makefile things).
1900   LIBDIR=$libdir
1901   if test "x${exec_prefix}" = "xNONE"
1902   then
1903       lib_exec_prefix=$prefix
1904   else
1905       lib_exec_prefix=$exec_prefix
1906   fi
1907   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1908   AC_SUBST(LIBDIR)
1909 fi
1910
1911 AC_CONFIG_FILES([
1912 Makefile
1913 libgcj.pc
1914 libgcj.spec
1915 libgcj-test.spec
1916 gcj/Makefile
1917 include/Makefile
1918 testsuite/Makefile
1919 contrib/aotcompile.py
1920 contrib/aot-compile
1921 contrib/aot-compile-rpm
1922 contrib/rebuild-gcj-db
1923 ])
1924
1925 if test ${multilib} = yes; then
1926   multilib_arg="--enable-multilib"
1927 else
1928   multilib_arg=
1929 fi
1930
1931 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1932 AC_OUTPUT