libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 # We use these options to decide which functions to include.
   9 AC_ARG_WITH(target-subdir,
  10   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  11                  [configure in a subdirectory]))
  12
  13 # We may get other options which we don't document:
  14 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  15
  16 # When building with srcdir == objdir, links to the source files will
  17 # be created in directories within the target_subdir.  We have to
  18 # adjust toplevel_srcdir accordingly, so that configure finds
  19 # install-sh and other auxiliary files that live in the top-level
  20 # source directory.
  21 if test "${srcdir}" = "."; then
  22   if test -z "${with_target_subdir}"; then
  23     toprel=".."
  24   else
  25     if test "${with_target_subdir}" != "."; then
  26       toprel="${with_multisrctop}../.."
  27     else
  28       toprel="${with_multisrctop}.."
  29     fi
  30   fi
  31 else
  32   toprel=".."
  33 fi
  34
  35 libgcj_basedir=$srcdir/$toprel/./libjava
  36 AC_SUBST(libgcj_basedir)
  37
  38 AC_CANONICAL_SYSTEM
  39 _GCC_TOPLEV_NONCANONICAL_BUILD
  40 _GCC_TOPLEV_NONCANONICAL_TARGET
  41
  42 AC_SUBST(target_noncanonical)
  43
  44 # This works around the fact that libtool configuration may change LD
  45 # for this particular configuration, but some shells, instead of
  46 # keeping the changes in LD private, export them just because LD is
  47 # exported.
  48 ORIGINAL_LD_FOR_MULTILIBS=$LD
  49
  50 AC_PROG_LN_S
  51
  52 # This works around an automake problem.
  53 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  54 AC_SUBST(mkinstalldirs)
  55
  56 AC_ARG_WITH(cross-host,
  57   AS_HELP_STRING([--with-cross-host=HOST],
  58                  [configure with a cross compiler from HOST]))
  59
  60 AC_ARG_WITH(newlib,
  61   AS_HELP_STRING([--with-newlib],
  62                  [configure with newlib]))
  63
  64 AC_ARG_ENABLE(version-specific-runtime-libs,
  65   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  67     [case "$enableval" in
  68       yes) version_specific_libs=yes ;;
  69       no)  version_specific_libs=no ;;
  70       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71      esac],
  72     [version_specific_libs=no]
  73 )
  74
  75 # Default to --enable-multilib
  76 AC_ARG_ENABLE(multilib,
  77   AS_HELP_STRING([--enable-multilib],
  78                  [build many library versions (default)]),
  79 [case "${enableval}" in
  80   yes) multilib=yes ;;
  81   no)  multilib=no ;;
  82   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  83  esac], [multilib=yes])dnl
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
  99 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 100 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 101 save_CXXFLAGS="$CXXFLAGS"
 102 CXXFLAGS="$CXXFLAGS -fno-builtin"
 103 AC_PROG_CC
 104 AC_PROG_CXX
 105 CXXFLAGS="$save_CXXFLAGS"
 106 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107 AC_SUBST(CFLAGS)
 108 AC_SUBST(CXXFLAGS)
 109 AC_SUBST(LDFLAGS)
 110
 111 AM_INIT_AUTOMAKE([1.9.0])
 112
 113 AC_CHECK_TOOL(AS, as)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 AC_PROG_INSTALL
 118
 119 AM_MAINTAINER_MODE
 120
 121 AC_EXEEXT
 122
 123 # configure.host sets the following important variables
 124 #       libgcj_cflags    - host specific C compiler flags
 125 #       libgcj_cxxflags  - host specific C++ compiler flags
 126 #       libgcj_javaflags - host specific Java compiler flags
 127
 128 libgcj_cflags=
 129 libgcj_cxxflags=
 130 libgcj_javaflags=
 131
 132 . ${srcdir}/configure.host
 133
 134 LIBGCJ_CFLAGS="${libgcj_cflags}"
 135 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 136 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 137 AC_SUBST(LIBGCJ_CFLAGS)
 138 AC_SUBST(LIBGCJ_CXXFLAGS)
 139 AC_SUBST(LIBGCJ_JAVAFLAGS)
 140
 141 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 142
 143 # Only use libltdl for non-newlib builds.
 144 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 145    AC_LIBLTDL_CONVENIENCE
 146    AC_LIBTOOL_DLOPEN
 147    DIRLTDL=libltdl
 148    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 149    # Sigh.  Libtool's macro doesn't do the right thing.
 150    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 151    # FIXME: this is a hack.
 152    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 153    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 154 fi
 155 AC_SUBST(INCLTDL)
 156 AC_SUBST(LIBLTDL)
 157 AC_SUBST(DIRLTDL)
 158 AC_PROG_LIBTOOL
 159 AM_PROG_GCJ
 160 AM_PROG_CC_C_O
 161 AC_CONFIG_SUBDIRS(libltdl)
 162
 163 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
 164    COMPPATH=.
 165 else
 166    COMPPATH=..
 167 fi
 168 AC_SUBST(COMPPATH)
 169
 170 # The -no-testsuite modules omit the test subdir.
 171 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 172
 173 # Should the runtime set system properties by examining the
 174 # environment variable GCJ_PROPERTIES?
 175 AC_ARG_ENABLE(getenv-properties,
 176   AS_HELP_STRING([--disable-getenv-properties],
 177                  [don't set system properties from GCJ_PROPERTIES]))
 178
 179 # Whether GCJ_PROPERTIES is used depends on the target.
 180 if test -z "$enable_getenv_properties"; then
 181    enable_getenv_properties=${enable_getenv_properties_default-yes}
 182 fi
 183 if test "$enable_getenv_properties" = no; then
 184    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 185      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 186 fi
 187
 188 # Whether we should use arguments to main()
 189 if test -z "$enable_main_args"; then
 190    enable_main_args=${enable_main_args_default-yes}
 191 fi
 192 if test "$enable_main_args" = no; then
 193    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 194 fi
 195
 196
 197 # Should we use hashtable-based synchronization?
 198 # Currently works only for Linux X86/ia64
 199 # Typically faster and more space-efficient
 200 AC_ARG_ENABLE(hash-synchronization,
 201   AS_HELP_STRING([--enable-hash-synchronization],
 202                  [use global hash table for monitor locks]))
 203
 204 if test -z "$enable_hash_synchronization"; then
 205    enable_hash_synchronization=$enable_hash_synchronization_default
 206 fi
 207
 208 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 209 AC_ARG_ENABLE(libgcj-multifile,
 210   AS_HELP_STRING([--enable-libgcj-multifile]
 211                  [allow compilation of several files at once]),
 212 [case "${enableval}" in
 213   yes) enable_libgcj_multifile=yes ;;
 214   no)  enable_libgcj_multifile=no ;;
 215   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 216 esac],[enable_libgcj_multifile=no])
 217 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 218
 219 # What is the native OS API for MinGW?
 220 AC_ARG_WITH(win32-nlsapi,
 221   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 222                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 223 [case "${withval}" in
 224   ansi) with_win32_nlsapi=ansi ;;
 225   unicows) with_win32_nlsapi=unicows ;;
 226   unicode) with_win32_nlsapi=unicode ;;
 227   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 228 esac],[with_win32_nlsapi=ansi])
 229
 230 case "${with_win32_nlsapi}" in
 231   unicows | unicode)
 232     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 233       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 234     ;;
 235 esac
 236
 237 # configure.host sets slow_pthread_self if the synchronization code should
 238 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 239 if test "${slow_pthread_self}" = "yes"; then
 240   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 241     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 242 fi
 243
 244
 245 # See if the user has requested runtime debugging.
 246 LIBGCJDEBUG="false"
 247 AC_SUBST(LIBGCJDEBUG)
 248 AC_ARG_ENABLE(libgcj-debug,
 249   AS_HELP_STRING([--enable-libgcj-debug],
 250                  [enable runtime debugging code]),
 251   [if test "$enable_libgcj_debug" = yes; then
 252     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 253     LIBGCJDEBUG="true"
 254   fi])
 255
 256 # Check for gc debugging.  This option is handled both here and in the GC.
 257 AC_ARG_ENABLE(gc-debug,
 258    AS_HELP_STRING([--enable-gc-debug],
 259                   [include full support for pointer backtracing etc.]),
 260 [ if test "$enable_gc_debug" = "yes"; then
 261     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 262               [Define if we want to use debug calls into the garbage collector.])
 263   fi])
 264
 265 # See if the user has the interpreter included.
 266 AC_ARG_ENABLE(interpreter,
 267   AS_HELP_STRING([--enable-interpreter],
 268                  [enable interpreter]),
 269   [if test "$enable_interpreter" = yes; then
 270     # This can also be set in configure.host.
 271     libgcj_interpreter=yes
 272   elif test "$enable_interpreter" = no; then
 273     libgcj_interpreter=no
 274   fi])
 275
 276 if test "$libgcj_interpreter" = yes; then
 277    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 278 fi
 279 INTERPRETER="$libgcj_interpreter"
 280 AC_SUBST(INTERPRETER)
 281
 282 AC_MSG_CHECKING([for exception model to use])
 283 AC_LANG_PUSH(C++)
 284 AC_ARG_ENABLE(sjlj-exceptions,
 285   AS_HELP_STRING([--enable-sjlj-exceptions],
 286                  [force use of builtin_setjmp for exceptions]),
 287 [:],
 288 [dnl Botheration.  Now we've got to detect the exception model.
 289 dnl Link tests against libgcc.a are problematic since -- at least
 290 dnl as of this writing -- we've not been given proper -L bits for
 291 dnl single-tree newlib and libgloss.
 292 dnl
 293 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 294 dnl conftest files before we got a change to grep them first.
 295 cat > conftest.$ac_ext << EOF
 296 [#]line __oline__ "configure"
 297 struct S { ~S(); };
 298 void bar();
 299 void foo()
 300 {
 301   S s;
 302   bar();
 303 }
 304 EOF
 305 old_CXXFLAGS="$CXXFLAGS"
 306 CXXFLAGS=-S
 307 if AC_TRY_EVAL(ac_compile); then
 308   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 309     enable_sjlj_exceptions=yes
 310   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 311     enable_sjlj_exceptions=no
 312   fi
 313 fi
 314 CXXFLAGS="$old_CXXFLAGS"
 315 rm -f conftest*])
 316 if test x$enable_sjlj_exceptions = xyes; then
 317   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 318         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 319   ac_exception_model_name=sjlj
 320 elif test x$enable_sjlj_exceptions = xno; then
 321   ac_exception_model_name="call frame"
 322 else
 323   AC_MSG_ERROR([unable to detect exception model])
 324 fi
 325 AC_LANG_POP(C++)
 326 AC_MSG_RESULT($ac_exception_model_name)
 327
 328 # If we are non using SJLJ exceptions, and this host does not have support
 329 # for unwinding from a signal handler, enable checked dereferences and divides.
 330 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 331   CHECKREFSPEC=-fcheck-references
 332   DIVIDESPEC=-fuse-divide-subroutine
 333   EXCEPTIONSPEC=
 334 fi
 335
 336 # See if the user wants to disable java.net.  This is the mildly
 337 # ugly way that we admit that target-side configuration sucks.
 338 AC_ARG_ENABLE(java-net,
 339   AS_HELP_STRING([--disable-java-net],
 340                  [disable java.net]))
 341
 342 # Whether java.net is built by default can depend on the target.
 343 if test -z "$enable_java_net"; then
 344    enable_java_net=${enable_java_net_default-yes}
 345 fi
 346 if test "$enable_java_net" = no; then
 347    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 348 fi
 349
 350 # See if the user wants to configure without libffi.  Some
 351 # architectures don't support it, and default values are set in
 352 # configure.host.
 353 AC_ARG_WITH(libffi,
 354   AS_HELP_STRING([--without-libffi],
 355                  [don't use libffi]),
 356   [:],
 357   [with_libffi=${with_libffi_default-yes}])
 358
 359 LIBFFI=
 360 LIBFFIINCS=
 361 if test "$with_libffi" != no; then
 362    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 363    LIBFFI=../libffi/libffi_convenience.la
 364    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 365 fi
 366 AC_SUBST(LIBFFI)
 367 AC_SUBST(LIBFFIINCS)
 368
 369 # See if the user wants to disable JVMPI support.
 370 AC_ARG_ENABLE(jvmpi,
 371   AS_HELP_STRING([--disable-jvmpi],
 372                  [disable JVMPI support]))
 373
 374 if test "$enable_jvmpi" != no; then
 375     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 376 fi
 377
 378 # If the target is an eCos system, use the appropriate eCos
 379 # I/O routines.
 380 # FIXME: this should not be a local option but a global target
 381 # system; at present there is no eCos target.
 382 TARGET_ECOS=${PROCESS-"no"}
 383 AC_ARG_WITH(ecos,
 384 [  --with-ecos             enable runtime eCos target support],
 385 TARGET_ECOS="$with_ecos"
 386 )
 387
 388 supply_backtrace=no
 389
 390 PLATFORM_INNER_NAT_HDRS=
 391 case "$TARGET_ECOS" in
 392    no) case "$host" in
 393       *mingw*)
 394             PLATFORM=Win32
 395             PLATFORMNET=Win32
 396             PLATFORMH=win32.h
 397         CHECK_FOR_BROKEN_MINGW_LD
 398       ;;
 399       *)
 400             PLATFORM=Posix
 401             PLATFORMNET=Posix
 402             PLATFORMH=posix.h
 403             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 404       ;;
 405       esac
 406       ;;
 407    *)
 408       PLATFORM=Ecos
 409       PLATFORMNET=NoNet
 410       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 411       PLATFORMH=posix.h
 412       ;;
 413 esac
 414 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 415 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 416
 417 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 418                                       [Define if you have int32_t and uint32_t.]))
 419 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 420                                         [Define if you have int32_t and uint32_t.]))
 421 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 422                                           [Define if you have u_int32_t]))
 423 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 424                                            [Define if you have u_int32_t]))
 425
 426 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 427 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 428 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 429
 430 case "$host" in
 431   *-darwin*) DARWIN_CRT=true ;;
 432   *) DARWIN_CRT=false ;;
 433 esac
 434 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 435
 436 # These may not be defined in a non-ANS conformant embedded system.
 437 # FIXME: Should these case a runtime exception in that case?
 438 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 439                                   [Define is you have 'mktime' in <time.h>]))
 440 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 441                                   [Define is you have 'localtime' in <time.h>]))
 442
 443 # Create the subdirectory for natFile.cc, or the attempt
 444 # to create the link will fail.
 445 test -d java || mkdir java
 446 test -d java/io || mkdir java/io
 447 test -d gnu || mkdir gnu
 448 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 449
 450 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 451 test -d java/lang || mkdir java/lang
 452 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 453 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 454
 455 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 456 test -d java/net || mkdir java/net
 457 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 458 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 459
 460 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 461 test -d gnu/java || mkdir gnu/java
 462 test -d gnu/java/net || mkdir gnu/java/net
 463 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 464 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 465
 466 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 467 test -d gnu/java/nio || mkdir gnu/java/nio
 468 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 469 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 470 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 471 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 472
 473 case "${host}" in
 474     *mingw*)
 475       SYSTEMSPEC="-lgdi32 -lws2_32"
 476       if test "${with_win32_nlsapi}" = "unicows"; then
 477         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 478       fi
 479     ;;
 480     *)
 481       SYSTEMSPEC=
 482     ;;
 483 esac
 484 AC_SUBST(SYSTEMSPEC)
 485
 486 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 487 AC_SUBST(LIBGCJTESTSPEC)
 488
 489 AC_ARG_WITH(system-zlib,
 490   AS_HELP_STRING([--with-system-zlib],
 491                  [use installed libz]))
 492 ZLIBSPEC=
 493 AC_SUBST(ZLIBSPEC)
 494 ZLIBTESTSPEC=
 495 AC_SUBST(ZLIBTESTSPEC)
 496
 497 AC_PATH_XTRA
 498
 499 # Determine which AWT peer libraries to build
 500 AC_ARG_ENABLE(java-awt,
 501   AS_HELP_STRING([--enable-java-awt],
 502                  [list of AWT peer implementations to be built]))
 503
 504 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 505 use_xlib_awt=""
 506 use_gtk_awt=""
 507 # The default toolkit to use is the first one specified.
 508 TOOLKIT=
 509 AC_SUBST(TOOLKIT)
 510
 511 for peer in $peerlibs ; do
 512   case $peer in
 513     xlib)
 514       if test "$no_x" = yes; then
 515         echo "*** xlib peers requested but no X library available" 1>&2
 516         exit 1
 517       else
 518         use_xlib_awt="yes"
 519         if test -z "$TOOLKIT"; then
 520            TOOLKIT=gnu.awt.xlib.XToolkit
 521         fi
 522       fi
 523       ;;
 524     gtk)
 525       if test "$no_x" = yes; then
 526          echo "*** xlib peers requested but no X library available" 1>&2
 527          exit 1
 528       else
 529          use_gtk_awt=yes
 530          if test -z "$TOOLKIT"; then
 531             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 532          fi
 533          test -d jniinclude || mkdir jniinclude
 534       fi
 535       ;;
 536     no)
 537       use_xlib_awt=
 538       use_gtk_awt=
 539       break
 540       ;;
 541     *)
 542       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 543       exit 1
 544   esac
 545 done
 546
 547 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 548 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 549
 550 # determine whether to enable the cairo GTK Graphics2D backend
 551 AC_ARG_ENABLE(gtk-cairo,
 552   AS_HELP_STRING([--enable-gtk-cairo],
 553                  [build the cairo Graphics2D implementation on GTK]))
 554 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 555 if test "x${enable_gtk_cairo}" = xyes
 556 then
 557         PKG_CHECK_MODULES(CAIRO, cairo)
 558         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 559 fi
 560 AC_SUBST(CAIRO_LIBS)
 561 AC_SUBST(CAIRO_CFLAGS)
 562 AC_SUBST(PANGOFT2_LIBS)
 563 AC_SUBST(PANGOFT2_CFLAGS)
 564
 565 # FIXME: this should be _libs on some hosts.
 566 libsubdir=.libs
 567
 568 # Allow the GC to be disabled.  Can be useful when debugging.
 569 AC_MSG_CHECKING([for garbage collector to use])
 570 AC_ARG_ENABLE(java-gc,
 571   AS_HELP_STRING([--enable-java-gc=TYPE],
 572                  [choose garbage collector (default is boehm)]),
 573   [GC=$enableval],
 574   [GC=boehm])
 575 GCLIBS=
 576 GCINCS=
 577 GCDEPS=
 578 GCSPEC=
 579 JC1GCSPEC=
 580 GCTESTSPEC=
 581 case "$GC" in
 582  boehm)
 583     AC_MSG_RESULT(boehm)
 584     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 585     JC1GCSPEC='-fuse-boehm-gc'
 586     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 587     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 588     GCOBJS=boehm.lo
 589     GCHDR=boehm-gc.h
 590     # The POSIX thread support needs to know this.
 591     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 592     ;;
 593  no)
 594     AC_MSG_RESULT(none)
 595     GCHDR=no-gc.h
 596     ;;
 597  *)
 598     AC_MSG_ERROR([unrecognized collector "$GC"])
 599     ;;
 600 esac
 601 AC_SUBST(GCLIBS)
 602 AC_SUBST(GCINCS)
 603 AC_SUBST(GCDEPS)
 604 AC_SUBST(GCSPEC)
 605 AC_SUBST(JC1GCSPEC)
 606 AC_SUBST(GCTESTSPEC)
 607 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 608 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 609 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 610
 611
 612 AC_MSG_CHECKING([for thread model used by GCC])
 613 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 614 AC_MSG_RESULT([$THREADS])
 615
 616 case "$THREADS" in
 617  no | none | single)
 618     THREADS=none
 619     ;;
 620  posix | pthreads)
 621     THREADS=posix
 622     case "$host" in
 623      *-*-linux*)
 624         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 625         ;;
 626     esac
 627     ;;
 628  win32)
 629     ;;
 630  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 631     AC_MSG_ERROR(thread package $THREADS not yet supported)
 632     ;;
 633  *)
 634     AC_MSG_ERROR($THREADS is an unknown thread package)
 635     ;;
 636 esac
 637
 638 THREADCXXFLAGS=
 639 THREADLDFLAGS=
 640 THREADLIBS=
 641 THREADINCS=
 642 THREADDEPS=
 643 THREADH=
 644 THREADSPEC=
 645 case "$THREADS" in
 646  posix)
 647     case "$host" in
 648      *-*-cygwin*)
 649         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 650         ;;
 651      *-*-freebsd[[1234]]*)
 652         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 653         # merely adds pthread_* functions) but it does have a -pthread switch
 654         # which is required at link-time to select -lc_r *instead* of -lc.
 655         THREADLDFLAGS=-pthread
 656         # Don't set THREADSPEC here as might be expected since -pthread is
 657         # not processed when found within a spec file, it must come from
 658         # the command line.  For now, the user must provide the -pthread
 659         # switch to link code compiled with gcj.  In future, consider adding
 660         # support for weak references to pthread_* functions ala gthr.h API.
 661         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 662         ;;
 663      *-*-freebsd*)
 664         # FreeBSD 5 implements a model much closer to other modern UNIX
 665         # which support threads.  However, it still does not support
 666         # -lpthread.
 667         THREADLDFLAGS=-pthread
 668         THREADSPEC=-lc_r
 669         ;;
 670      alpha*-dec-osf*)
 671         THREADCXXFLAGS=-pthread
 672         # boehm-gc needs some functions from librt, so link that too.
 673         THREADLIBS='-lpthread -lrt'
 674         THREADSPEC='-lpthread -lrt'
 675         ;;
 676      *)
 677         THREADLIBS=-lpthread
 678         THREADSPEC=-lpthread
 679         ;;
 680     esac
 681     THREADH=posix-threads.h
 682     # MIT pthreads doesn't seem to have the mutexattr functions.
 683     # But for now we don't check for it.  We just assume you aren't
 684     # using MIT pthreads.
 685     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 686
 687     # If we're using the Boehm GC, then we happen to know that it
 688     # defines _REENTRANT, so we don't bother.  Eww.
 689     if test "$GC" != boehm; then
 690        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 691     fi
 692     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 693     ;;
 694
 695  win32)
 696     THREADH=win32-threads.h
 697     ;;
 698
 699  none)
 700     THREADH=no-threads.h
 701     ;;
 702 esac
 703 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 704 AC_SUBST(THREADLIBS)
 705 AC_SUBST(THREADINCS)
 706 AC_SUBST(THREADDEPS)
 707 AC_SUBST(THREADSPEC)
 708 AC_SUBST(THREADLDFLAGS)
 709 AC_SUBST(THREADCXXFLAGS)
 710 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 711 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 712 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 713
 714 if test -d sysdep; then true; else mkdir sysdep; fi
 715 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 716
 717 HASH_SYNC_SPEC=
 718 # Hash synchronization is only useful with posix threads right now.
 719 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 720    HASH_SYNC_SPEC=-fhash-synchronization
 721    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 722 fi
 723 AC_SUBST(HASH_SYNC_SPEC)
 724
 725
 726 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 727
 728 # We're in the tree with gcc, and need to include some of its headers.
 729 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 730
 731 # Figure out where generated headers like libgcj-config.h get installed.
 732 gcc_version_trigger=${libgcj_basedir}/../gcc/version.c
 733 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^\"]]*\)\".*/\1/'`
 734 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([[^ ]]*\) .*/\1/'`
 735 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 736 AC_SUBST(tool_include_dir)
 737 AC_SUBST(gcc_version)
 738
 739 if test "x${with_newlib}" = "xyes"; then
 740    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 741    # may not work correctly, because the compiler may not be able to
 742    # link executables.
 743
 744    # We assume newlib.  This lets us hard-code the functions we know
 745    # we'll have.
 746    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 747    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 748    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 749    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 750    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 751    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 752    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 753    # This is only for POSIX threads.
 754    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 755    # We also assume we are using gcc, which provides alloca.
 756    AC_DEFINE(HAVE_ALLOCA)
 757
 758    # Assume we do not have getuid and friends.
 759    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 760    PLATFORMNET=NoNet
 761 else
 762    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 763    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 764    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 765    AC_CHECK_FUNCS(nl_langinfo setlocale)
 766    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 767    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 768    AC_CHECK_FUNCS(fork execvp pipe sigaction ftruncate)
 769    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 770    AC_CHECK_FUNC(backtrace, [
 771      case "$host" in
 772        ia64-*-linux*)
 773          # Has broken backtrace()
 774          ;;
 775        mips*-*-linux*)
 776          # Has broken backtrace(), but we supply our own.
 777          if test -d sysdep; then true; else mkdir -p sysdep; fi
 778          supply_backtrace=yes
 779          AC_DEFINE(HAVE_BACKTRACE, 1,
 780            [Define if your platform has a working backtrace() function.])
 781          ;;
 782        *)
 783          AC_DEFINE(HAVE_BACKTRACE, 1,
 784            [Define if your platform has a working backtrace() function.])
 785          ;;
 786      esac
 787    ], [
 788      case "$host" in
 789        *mingw*)
 790          # Has backtrace() defined in libgcj itself
 791          AC_DEFINE(HAVE_BACKTRACE, 1,
 792            [Define if your platform has a working backtrace() function.])
 793          ;;
 794      esac
 795    ])
 796
 797    AC_CHECK_LIB(dl, dladdr, [
 798      if test "x${disable_dladdr}" = "xyes"; then
 799        #Broken dladdr().
 800        true
 801      else
 802        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 803      fi
 804    ])
 805    if test x"$build" = x"$host"; then
 806      AC_CHECK_FILES(/proc/self/exe, [
 807        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 808    else
 809      case $host in
 810      *-linux*)
 811        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 812        ;;
 813      esac
 814    fi
 815
 816    AM_ICONV
 817    AM_LC_MESSAGES
 818    AC_STRUCT_TIMEZONE
 819
 820    AC_CHECK_FUNCS(gethostbyname_r, [
 821      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 822        [Define if you have the 'gethostbyname_r' function.])
 823      # There are two different kinds of gethostbyname_r.
 824      # We look for the one that returns `int'.
 825      # Hopefully this check is robust enough.
 826      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 827        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 828
 829      case " $GCINCS " in
 830      *" -D_REENTRANT "*) ;;
 831      *)
 832         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 833         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 834         [libjava_cv_gethostbyname_r_needs_reentrant],
 835         [ AC_LANG_PUSH(C++)
 836           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 837             [[gethostbyname_r("", 0, 0);]])],
 838             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 839                 CPPFLAGS_SAVE="$CPPFLAGS"
 840                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 841                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 842                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 843                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 844                 CPPFLAGS="$CPPFLAGS_SAVE"
 845           ])
 846           AC_LANG_POP(C++)
 847         ])
 848         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 849           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 850         fi
 851      ;;
 852      esac
 853
 854      AC_CACHE_CHECK([for struct hostent_data],
 855         [libjava_cv_struct_hostent_data], [dnl
 856         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 857 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 858 # define _REENTRANT 1
 859 #endif
 860 #include <netdb.h>]], [[struct hostent_data data;]])],
 861           [libjava_cv_struct_hostent_data=yes],
 862           [libjava_cv_struct_hostent_data=no])])
 863      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 864        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 865          [Define if struct hostent_data is defined in netdb.h])
 866      fi
 867    ])
 868
 869    # FIXME: libjava source code expects to find a prototype for
 870    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 871    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 872    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 873    # linkage check is enough, yet C++ code requires proper prototypes.)
 874    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 875    AC_CHECK_FUNCS(gethostbyaddr_r, [
 876      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 877        [Define if you have the 'gethostbyaddr_r' function.])
 878      # There are two different kinds of gethostbyaddr_r.
 879      # We look for the one that returns `int'.
 880      # Hopefully this check is robust enough.
 881      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 882        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 883          [Define if gethostbyaddr_r returns 'int'.])])])])
 884
 885    AC_CHECK_FUNCS(gethostname, [
 886      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 887        [Define if you have the 'gethostname' function.])
 888      AC_EGREP_HEADER(gethostname, unistd.h, [
 889        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 890          [Define if gethostname is declared in <unistd.h>.])])])
 891
 892    AC_CHECK_FUNCS(usleep, [
 893      AC_EGREP_HEADER(usleep, unistd.h, [
 894        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 895           [Define if usleep is declared in <unistd.h>.])])])
 896
 897    # Look for these functions in the thread library, but only bother
 898    # if using POSIX threads.
 899    if test "$THREADS" = posix; then
 900       save_LIBS="$LIBS"
 901       LIBS="$LIBS $THREADLIBS"
 902       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 903       # E.g., Solaris.
 904       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 905
 906       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 907       # Solaris 7 the name librt is preferred.
 908       AC_CHECK_FUNCS(sched_yield, , [
 909         AC_CHECK_LIB(rt, sched_yield, [
 910           AC_DEFINE(HAVE_SCHED_YIELD)
 911           THREADLIBS="$THREADLIBS -lrt"
 912           THREADSPEC="$THREADSPEC -lrt"], [
 913           AC_CHECK_LIB(posix4, sched_yield, [
 914             AC_DEFINE(HAVE_SCHED_YIELD)
 915             THREADLIBS="$THREADLIBS -lposix4"
 916             THREADSPEC="$THREADSPEC -lposix4"])])])
 917       LIBS="$save_LIBS"
 918
 919       # We can save a little space at runtime if the mutex has m_count
 920       # or __m_count.  This is a nice hack for Linux.
 921       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 922           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 923         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 924              [Define if pthread_mutex_t has m_count member.]), [
 925         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 926             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 927           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 928             [Define if pthread_mutex_t has __m_count member.]))])
 929    fi
 930
 931    # We require a way to get the time.
 932    time_found=no
 933    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 934    if test "$time_found" = no; then
 935       AC_MSG_ERROR([no function found to get the time])
 936    fi
 937
 938    AC_CHECK_FUNCS(memmove)
 939
 940    # We require memcpy.
 941    memcpy_found=no
 942    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 943    if test "$memcpy_found" = no; then
 944       AC_MSG_ERROR([memcpy is required])
 945    fi
 946
 947    AC_CHECK_LIB(dl, dlopen, [
 948        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 949
 950    # Some library-finding code we stole from Tcl.
 951    #--------------------------------------------------------------------
 952    #    Check for the existence of the -lsocket and -lnsl libraries.
 953    #    The order here is important, so that they end up in the right
 954    #    order in the command line generated by make.  Here are some
 955    #    special considerations:
 956    #    1. Use "connect" and "accept" to check for -lsocket, and
 957    #       "gethostbyname" to check for -lnsl.
 958    #    2. Use each function name only once:  can't redo a check because
 959    #       autoconf caches the results of the last check and won't redo it.
 960    #    3. Use -lnsl and -lsocket only if they supply procedures that
 961    #       aren't already present in the normal libraries.  This is because
 962    #       IRIX 5.2 has libraries, but they aren't needed and they're
 963    #       bogus:  they goof up name resolution if used.
 964    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 965    #       To get around this problem, check for both libraries together
 966    #       if -lsocket doesn't work by itself.
 967    #--------------------------------------------------------------------
 968
 969    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 970     [gcj_cv_lib_sockets=
 971      gcj_checkBoth=0
 972      unset ac_cv_func_connect
 973      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 974      if test "$gcj_checkSocket" = 1; then
 975          unset ac_cv_func_connect
 976          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 977                       gcj_checkBoth=1)
 978      fi
 979      if test "$gcj_checkBoth" = 1; then
 980          gcj_oldLibs=$LIBS
 981          LIBS="$LIBS -lsocket -lnsl"
 982          unset ac_cv_func_accept
 983          AC_CHECK_FUNC(accept,
 984                        [gcj_checkNsl=0
 985                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 986          unset ac_cv_func_accept
 987          LIBS=$gcj_oldLibs
 988      fi
 989      unset ac_cv_func_gethostbyname
 990      gcj_oldLibs=$LIBS
 991      LIBS="$LIBS $gcj_cv_lib_sockets"
 992      AC_CHECK_FUNC(gethostbyname, ,
 993                    [AC_CHECK_LIB(nsl, main,
 994                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 995      unset ac_cv_func_gethostbyname
 996      LIBS=$gcj_oldLIBS
 997    ])
 998    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 999
1000    if test "$with_system_zlib" = yes; then
1001       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1002    fi
1003
1004    # Test for Gtk stuff, if asked for.
1005    if test "$use_gtk_awt" = yes; then
1006       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1007       AC_SUBST(GTK_CFLAGS)
1008       AC_SUBST(GTK_LIBS)
1009
1010       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1011       AC_SUBST(GLIB_CFLAGS)
1012       AC_SUBST(GLIB_LIBS)
1013
1014       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1015       AC_SUBST(LIBART_CFLAGS)
1016       AC_SUBST(LIBART_LIBS)
1017    fi
1018
1019    # On Solaris, and maybe other architectures, the Boehm collector
1020    # requires -ldl.
1021    if test "$GC" = boehm; then
1022       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1023    fi
1024 fi
1025 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1026
1027 if test -z "${with_multisubdir}"; then
1028    builddotdot=.
1029 else
1030    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1031 fi
1032
1033 NATIVE=yes
1034
1035 # Which gcj do we use?
1036 which_gcj=default
1037 built_gcc_dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
1038 if test -n "${with_cross_host}"; then
1039   # We are being configured with a cross compiler. We can't
1040   # use ac_exeext, because that is for the target platform.
1041   NATIVE=no
1042   cross_host_exeext=
1043   case "${with_cross_host}" in
1044      *mingw* | *cygwin*)
1045          cross_host_exeext=.exe
1046      ;;
1047   esac
1048   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1049      if test x"$build_noncanonical" = x"$with_cross_host"; then
1050         # Ordinary cross (host!=target and host=build)
1051         which_gcj=built
1052      else
1053         # Canadian cross (host!=target and host!=build)
1054         which_gcj=cross
1055      fi
1056   else
1057      which_gcj=cross
1058   fi
1059 else
1060   # We are being configured with a native or crossed-native compiler
1061   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1062      if test x"$build" = x"$host"; then
1063         # True native build (host=target and host=build)
1064         which_gcj=built
1065      else
1066         # Crossed-native build (host=target and host!=build)
1067         which_gcj=cross
1068      fi
1069   else
1070      which_gcj=path
1071   fi
1072 fi
1073 case "${which_gcj}" in
1074    built)
1075       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1076       GCJH='$(MULTIBUILDTOP)../$(COMPPATH)/gcc/gcjh'
1077       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1078    ;;
1079    cross)
1080       if test "x${with_newlib}" = "xyes"; then
1081          # FIXME (comment): Why is this needed?
1082          GCC_UNWIND_INCLUDE=
1083          GCJ="${target_noncanonical}-gcj"
1084       else
1085          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1086       fi
1087       ZIP=jar
1088       GCJH='$(target_noncanonical)-gcjh'
1089    ;;
1090    path)
1091       GCJ="gcj -B`${PWDCMD-pwd}`/"
1092       ## In this case, gcj is found outside the build tree.  However, zip is
1093       ## found in the build tree.
1094       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1095       GCJH=gcjh
1096    ;;
1097 esac
1098
1099 AC_SUBST(GCJH)
1100 AC_SUBST(ZIP)
1101
1102 # Create it, so that compile/link tests don't fail
1103 test -f libgcj.spec || touch libgcj.spec
1104
1105 # We must search the source tree for java.lang, since we still don't
1106 # have libgcj.jar nor java/lang/*.class
1107 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1108 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1109
1110 # Since some classes depend on this one, we need its source available
1111 # before we can do any GCJ compilation test :-(
1112 if test ! -f gnu/classpath/Configuration.java; then
1113   test -d gnu || mkdir gnu
1114   test -d gnu/classpath || mkdir gnu/classpath
1115   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1116       -e 's,@TOOLKIT@,$TOOLKIT,' \
1117         < $srcdir/gnu/classpath/Configuration.java.in \
1118         > gnu/classpath/Configuration.java
1119   # We do not want to redirect the output of the grep below to /dev/null,
1120   # but we add /dev/null to the input list so that grep will print the
1121   # filename of Configuration.java in case it finds any matches.
1122   if grep @ gnu/classpath/Configuration.java /dev/null; then
1123     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1124   fi
1125 fi
1126
1127 LT_AC_PROG_GCJ
1128
1129 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1130
1131 AC_COMPILE_CHECK_SIZEOF(void *)
1132
1133 AC_C_BIGENDIAN_CROSS
1134
1135 ZLIBS=
1136 SYS_ZLIBS=
1137 ZINCS=
1138
1139 if test -z "$ZLIBSPEC"; then
1140    # Use zlib from the GCC tree.
1141    ZINCS='-I$(top_srcdir)/../zlib'
1142    ZLIBS=../zlib/libzgcj_convenience.la
1143 else
1144    # System's zlib.
1145    SYS_ZLIBS="$ZLIBSPEC"
1146 fi
1147 AC_SUBST(ZLIBS)
1148 AC_SUBST(SYS_ZLIBS)
1149 AC_SUBST(ZINCS)
1150 AC_SUBST(DIVIDESPEC)
1151 AC_SUBST(CHECKREFSPEC)
1152 AC_SUBST(EXCEPTIONSPEC)
1153 AC_SUBST(IEEESPEC)
1154
1155 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1156 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1157 AC_SUBST(GCC_UNWIND_INCLUDE)
1158
1159 # Process the option "--enable-version-specific-runtime-libs"
1160 # Calculate toolexeclibdir
1161 case ${version_specific_libs} in
1162   yes)
1163     # Need the gcc compiler version to know where to install libraries
1164     # and header files if --enable-version-specific-runtime-libs option
1165     # is selected.
1166     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1167     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1168     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1169     toolexeclibdir=$toolexecmainlibdir
1170     ;;
1171   no)
1172     if test -n "$with_cross_host" &&
1173        test x"$with_cross_host" != x"no"; then
1174       # Install a library built with a cross compiler in tooldir, not libdir.
1175       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1176       toolexecmainlibdir='$(toolexecdir)/lib'
1177     else
1178       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1179       toolexecmainlibdir='$(libdir)'
1180     fi
1181     multi_os_directory=`$CC -print-multi-os-directory`
1182     case $multi_os_directory in
1183       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1184       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1185     esac
1186     ;;
1187 esac
1188 AC_SUBST(toolexecdir)
1189 AC_SUBST(toolexecmainlibdir)
1190 AC_SUBST(toolexeclibdir)
1191
1192 # Determine gcj version number.
1193 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1194 GCJVERSION=$gcjversion
1195 AC_SUBST(GCJVERSION)
1196 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1197
1198 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1199 # On that system, sys/ioctl.h will not include sys/filio.h unless
1200 # BSD_COMP is defined; just including sys/filio.h is simpler.
1201 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
1202 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1203 # for now.  If you change this, you also must update natFile.cc.
1204 AC_CHECK_HEADERS(dirent.h)
1205 AC_CHECK_HEADERS(inttypes.h, [
1206     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1207     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1208 ])
1209 AC_HEADER_SYS_WAIT
1210
1211 AC_CHECK_TYPE([ssize_t], [int])
1212
1213 AC_MSG_CHECKING([for in_addr_t])
1214 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1215 #if STDC_HEADERS
1216 #include <stdlib.h>
1217 #include <stddef.h>
1218 #endif
1219 #if HAVE_NETINET_IN_H
1220 #include <netinet/in.h>
1221 #endif]], [[in_addr_t foo;]])],
1222   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1223      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1224    AC_MSG_RESULT(yes)],
1225   [AC_MSG_RESULT(no)])
1226
1227 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1228 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1229   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1230      [Define if struct ip_mreq is defined in netinet/in.h.])
1231    AC_MSG_RESULT(yes)],
1232   [AC_MSG_RESULT(no)])
1233
1234 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1236   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1237      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1238    AC_MSG_RESULT(yes)],
1239   [AC_MSG_RESULT(no)])
1240
1241 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1242 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1243   [AC_DEFINE(HAVE_INET6, 1,
1244      [Define if inet6 structures are defined in netinet/in.h.])
1245    AC_MSG_RESULT(yes)],
1246   [AC_MSG_RESULT(no)])
1247
1248 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1249 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1250 #include <sys/types.h>
1251 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1252   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1253    AC_MSG_RESULT(yes)],
1254   [AC_MSG_RESULT(no)])
1255
1256 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1257 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1258   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1259    AC_MSG_RESULT(yes)],
1260   [AC_MSG_RESULT(no)
1261    AC_MSG_CHECKING([for global timezone variable])
1262    dnl FIXME: we don't want a link check here because that won't work
1263    dnl when cross-compiling.  So instead we make an assumption that
1264    dnl the header file will mention timezone if it exists.
1265    dnl Don't find the win32 function timezone
1266    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1267      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1268       AC_MSG_RESULT(yes)],
1269      [AC_MSG_RESULT(no)
1270        AC_MSG_CHECKING([for global _timezone variable])
1271        dnl FIXME: As above, don't want link check
1272        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1273          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1274             [Define if your platform has the global _timezone variable.])
1275           AC_MSG_RESULT(yes)],
1276           [AC_MSG_RESULT(no)])])])
1277
1278 AC_FUNC_ALLOCA
1279 AC_FUNC_MMAP
1280
1281 AC_CHECK_PROGS(PERL, perl, false)
1282
1283 SYSDEP_SOURCES=
1284 SIGNAL_HANDLER_AUX=
1285
1286 case "${host}" in
1287  i?86-*-linux*)
1288     SIGNAL_HANDLER=include/i386-signal.h
1289     ;;
1290  sparc*-sun-solaris*)
1291     SIGNAL_HANDLER=include/sparc-signal.h
1292     ;;
1293 # ia64-*)
1294 #    SYSDEP_SOURCES=sysdep/ia64.c
1295 #    test -d sysdep || mkdir sysdep
1296 #    ;;
1297  hppa*-*-linux*)
1298     SIGNAL_HANDLER=include/pa-signal.h
1299     ;;
1300  ia64-*-linux*)
1301     SIGNAL_HANDLER=include/dwarf2-signal.h
1302     ;;
1303  powerpc*-*-linux*)
1304     SIGNAL_HANDLER=include/powerpc-signal.h
1305     ;;
1306  alpha*-*-linux*)
1307     SIGNAL_HANDLER=include/dwarf2-signal.h
1308     ;;
1309  s390*-*-linux*)
1310     SIGNAL_HANDLER=include/s390-signal.h
1311     ;;
1312  x86_64*-*-linux*)
1313     SIGNAL_HANDLER=include/x86_64-signal.h
1314     SIGNAL_HANDLER_AUX=include/i386-signal.h
1315     ;;
1316  sparc*-*-linux*)
1317     SIGNAL_HANDLER=include/dwarf2-signal.h
1318     ;;
1319  sh*-*-linux*)
1320     SIGNAL_HANDLER=include/sh-signal.h
1321     ;;
1322  *mingw*)
1323     SIGNAL_HANDLER=include/win32-signal.h
1324     ;;
1325  mips*-*-linux*)
1326     SIGNAL_HANDLER=include/mips-signal.h
1327     ;;
1328  *-*-darwin*)
1329     SIGNAL_HANDLER=include/darwin-signal.h
1330     ;;
1331  *)
1332     SIGNAL_HANDLER=include/default-signal.h
1333     ;;
1334 esac
1335
1336 # If we're using sjlj exceptions, forget what we just learned.
1337 if test "$enable_sjlj_exceptions" = yes; then
1338    SIGNAL_HANDLER=include/default-signal.h
1339    SIGNAL_HANDLER_AUX=
1340 fi
1341
1342 # Define here any compiler flags that you need in order to make backtrace() work.
1343 BACKTRACESPEC=
1344 case "${host}" in
1345  x86_64*-*-linux*|i?86-*)
1346     BACKTRACESPEC=-fno-omit-frame-pointer
1347     ;;
1348 esac
1349 AC_SUBST(BACKTRACESPEC)
1350
1351 AC_SUBST(SYSDEP_SOURCES)
1352
1353 if test -z "$SIGNAL_HANDLER_AUX"; then
1354   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1355 fi
1356
1357 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1358                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1359
1360 if test "${multilib}" = "yes"; then
1361   multilib_arg="--enable-multilib"
1362 else
1363   multilib_arg=
1364 fi
1365
1366
1367
1368 here=`${PWDCMD-pwd}`
1369 AC_SUBST(here)
1370
1371 # We get this from the environment.
1372 AC_SUBST(GCJFLAGS)
1373
1374 AC_CONFIG_FILES([
1375 Makefile
1376 libgcj.pc
1377 libgcj.spec
1378 libgcj-test.spec
1379 gnu/classpath/Configuration.java
1380 gcj/Makefile
1381 include/Makefile
1382 testsuite/Makefile
1383 ])
1384
1385 AC_CONFIG_COMMANDS([default],
1386 [# Only add multilib support code if we just rebuilt top-level Makefile.
1387 case " $CONFIG_FILES " in
1388  *" Makefile "*)
1389    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1390    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1391    ;;
1392 esac
1393 ],
1394 srcdir=${srcdir}
1395 host=${host}
1396 target=${target}
1397 with_multisubdir=${with_multisubdir}
1398 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1399 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1400 libgcj_basedir=${libgcj_basedir}
1401 CC="${CC}"
1402 CXX="${CXX}"
1403 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1404 )
1405
1406 AC_OUTPUT