libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 AC_ARG_ENABLE(plugin,
  88   AS_HELP_STRING([--enable-plugin],
  89                  [build gcjwebplugin web browser plugin]),
  90     [case "$enableval" in
  91       yes) plugin_enabled=yes ;;
  92       no)  plugin_enabled=no ;;
  93       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  94      esac],
  95     [plugin_enabled=no]
  96 )
  97
  98 AC_ARG_ENABLE(gconf-peer,
  99   AS_HELP_STRING([--enable-gconf-peer],
 100                  [compile GConf native peers for util.preferences]),
 101     [case "$enableval" in
 102       yes) gconf_enabled=yes ;;
 103       no)  gconf_enabled=no ;;
 104       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
 105      esac],
 106     [gconf_enabled=no]
 107 )
 108
 109 AC_ARG_ENABLE(java-maintainer-mode,
 110         AS_HELP_STRING([--enable-java-maintainer-mode],
 111         [allow rebuilding of .class and .h files]))
 112 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 113
 114 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 115 GCC_NO_EXECUTABLES
 116
 117 # (1) We use an abnormal CXX (without library references), so we
 118 # must cache it under a different name.
 119 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 120 # the non-multilib-adjusted value will be used in multilibs.
 121 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 122 # (4) As another side effect, automake doesn't automatically include them
 123 # in Makefile.in.
 124 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 125 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 126 # used in later tests.  This may not be necessary in libjava; I don't know.
 127 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 128 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 129 save_CXXFLAGS="$CXXFLAGS"
 130 CXXFLAGS="$CXXFLAGS -fno-builtin"
 131 AC_PROG_CC
 132 AC_PROG_CXX
 133 CXXFLAGS="$save_CXXFLAGS"
 134 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 135 AC_SUBST(CFLAGS)
 136 AC_SUBST(CXXFLAGS)
 137 AC_SUBST(LDFLAGS)
 138
 139 AM_INIT_AUTOMAKE([1.9.0])
 140
 141 AC_CHECK_TOOL(AS, as)
 142 AC_CHECK_TOOL(LD, ld)
 143 AC_CHECK_TOOL(AR, ar)
 144 AC_CHECK_TOOL(RANLIB, ranlib, :)
 145 AC_PROG_AWK
 146 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 147 AC_PATH_PROG([ZIP], [zip], no)
 148 AC_PATH_PROG([UNZIP], [unzip], unzip)
 149 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 150 if test "$ZIP" = no; then
 151   if test "$JAR" = no; then
 152     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 153   fi
 154 else
 155   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 156   JAR=`pwd`/scripts/jar
 157 fi
 158
 159 AC_PROG_INSTALL
 160
 161 AM_MAINTAINER_MODE
 162
 163 AC_EXEEXT
 164
 165 # configure.host sets the following important variables
 166 #       libgcj_cflags    - host specific C compiler flags
 167 #       libgcj_cxxflags  - host specific C++ compiler flags
 168 #       libgcj_javaflags - host specific Java compiler flags
 169
 170 libgcj_cflags=
 171 libgcj_cxxflags=
 172 libgcj_javaflags=
 173
 174 . ${srcdir}/configure.host
 175
 176 ACX_PROG_LD_GNU_SYMBOLIC
 177 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 178 if test -z "$libgcj_ld_symbolic"; then
 179   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 180 fi
 181
 182 LIBGCJ_CFLAGS="${libgcj_cflags}"
 183 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 184 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 185 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 186 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 187 AC_SUBST(LIBGCJ_CFLAGS)
 188 AC_SUBST(LIBGCJ_CXXFLAGS)
 189 AC_SUBST(LIBGCJ_JAVAFLAGS)
 190 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 191 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 192
 193 # Only use libltdl for non-newlib builds.
 194 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 195    AC_LTDL_SHLIBPATH
 196 fi
 197
 198 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 199
 200 # See if the user has requested runtime debugging.
 201 LIBGCJDEBUG="disable"
 202 AC_SUBST(LIBGCJDEBUG)
 203 AC_ARG_ENABLE(libgcj-debug,
 204   AS_HELP_STRING([--enable-libgcj-debug],
 205                  [enable runtime debugging code]),
 206   [if test "$enable_libgcj_debug" = yes; then
 207     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 208     LIBGCJDEBUG="enable"
 209   fi])
 210
 211 AC_ARG_WITH([escher],
 212          AS_HELP_STRING([--with-escher=ABS.PATH],
 213                         [specify path to escher dir or JAR for X peers]))
 214 case "$with_escher" in
 215 "")
 216         use_escher=false
 217         ;;
 218 "no")
 219         use_escher=false
 220         ;;
 221 "yes")
 222         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 223         ;;
 224 *)
 225         use_escher=true
 226         ;;
 227 esac
 228
 229 # Determine which AWT peer libraries to build
 230 AC_ARG_ENABLE(java-awt,
 231   AS_HELP_STRING([--enable-java-awt],
 232                  [list of AWT peer implementations to be built]))
 233
 234 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 235 use_xlib_awt=""
 236 use_gtk_awt=""
 237 use_qt_awt=""
 238 use_x_awt=""
 239 # The default toolkit to use is the first one specified.
 240 TOOLKIT=
 241 AC_SUBST(TOOLKIT)
 242
 243 for peer in $peerlibs ; do
 244   case $peer in
 245     xlib)
 246       if test "$no_x" = yes; then
 247         echo "*** xlib peers requested but no X library available" 1>&2
 248         exit 1
 249       else
 250         use_xlib_awt="yes"
 251         if test -z "$TOOLKIT"; then
 252            TOOLKIT=gnu.awt.xlib.XToolkit
 253         fi
 254       fi
 255       ;;
 256     gtk)
 257       if test "$no_x" = yes; then
 258          echo "*** gtk peers requested but no X library available" 1>&2
 259          exit 1
 260       else
 261          use_gtk_awt=yes
 262          if test -z "$TOOLKIT"; then
 263             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 264          fi
 265       fi
 266       ;;
 267     qt)
 268       if test "$no_x" = yes; then
 269          # Perhaps we should admit the possibility of embedded Qt.
 270          echo "*** Qt peers requested but no X library available" 1>&2
 271          exit 1
 272       else
 273          use_qt_awt=yes
 274          if test -z "$TOOLKIT"; then
 275             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 276          fi
 277       fi
 278       ;;
 279     x)
 280       use_x_awt=yes
 281       if test -z "$TOOLKIT"; then
 282          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 283       fi
 284       ;;
 285     no)
 286       use_xlib_awt=
 287       use_gtk_awt=
 288       use_qt_awt=
 289       use_x_awt=
 290       break
 291       ;;
 292     *)
 293       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 294       exit 1
 295   esac
 296 done
 297
 298 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 299 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 300
 301 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 302
 303 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 304
 305 # Create standard.omit based on decisions we just made.
 306 cp $srcdir/standard.omit.in standard.omit
 307 if test "$use_xlib_awt" != yes; then
 308    echo gnu/awt/xlib >> standard.omit
 309    echo gnu/gcj/xlib >> standard.omit
 310 fi
 311 if test "$use_x_awt" != yes; then
 312    echo gnu/java/awt/peer/x >> standard.omit
 313 fi
 314
 315 if test -z "${with_multisubdir}"; then
 316    builddotdot=.
 317 else
 318    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 319 fi
 320
 321 NATIVE=yes
 322
 323 # Which gcj and host gcj (for ecjx) do we use?
 324 which_gcj=default
 325 host_exeext=${ac_exeext}
 326 GCJ_FOR_ECJX=
 327 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 328 if test -n "${with_cross_host}"; then
 329   # We are being configured with a cross compiler. We can't
 330   # use ac_exeext, because that is for the target platform.
 331   NATIVE=no
 332   cross_host_exeext=
 333   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 334   case "${with_cross_host}" in
 335      *mingw* | *cygwin*)
 336          cross_host_exeext=.exe
 337      ;;
 338   esac
 339   host_exeext=${cross_host_exeext}
 340   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 341      if test x"$build_noncanonical" = x"$with_cross_host"; then
 342         # Ordinary cross (host!=target and host=build)
 343         which_gcj=built
 344      else
 345         # Canadian cross (host!=target and host!=build)
 346         which_gcj=cross
 347      fi
 348   else
 349      which_gcj=cross
 350   fi
 351 else
 352   # We are being configured with a native or crossed-native compiler
 353   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 354      if test x"$build" = x"$host"; then
 355         # True native build (host=target and host=build)
 356         which_gcj=built
 357      else
 358         # Crossed-native build (host=target and host!=build)
 359         which_gcj=cross
 360      fi
 361   else
 362      which_gcj=path
 363   fi
 364 fi
 365 case "${which_gcj}" in
 366    built)
 367       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 368       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 369    ;;
 370    cross)
 371       if test "x${with_newlib}" = "xyes"; then
 372          # FIXME (comment): Why is this needed?
 373          GCC_UNWIND_INCLUDE=
 374          GCJ="${target_noncanonical}-gcj"
 375       else
 376          GCJ="$built_gcc_dir/gcj -B$built_gcc_dir/"
 377       fi
 378       GCJH="$built_gcc_dir/gcjh"
 379    ;;
 380    path)
 381       GCJ="gcj -B`${PWDCMD-pwd}`/"
 382       GCJH=gcjh
 383    ;;
 384 esac
 385
 386 AC_SUBST(GCJ_FOR_ECJX)
 387 AC_SUBST(GCJH)
 388 AC_SUBST(host_exeext)
 389
 390 # Create it, so that compile/link tests don't fail
 391 test -f libgcj.spec || touch libgcj.spec
 392
 393
 394
 395 # Set up to configure Classpath.
 396 # FIXME: no supported way to pass args in autoconf.
 397 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 398 # Disable tool wrappers to avoid ltdl.h configure check.
 399 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 400 ac_configure_args="$ac_configure_args --disable-load-library"
 401 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 402 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 403 dir1=`cd $srcdir && pwd`
 404 dir2=`pwd`
 405 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 406 ac_configure_args="$ac_configure_args --disable-core-jni"
 407 dnl FIXME?
 408 ac_configure_args="$ac_configure_args --disable-examples"
 409 ac_configure_args="$ac_configure_args --with-glibj=build"
 410 if test "$plugin_enabled" != yes; then
 411   ac_configure_args="$ac_configure_args --disable-plugin"
 412 fi
 413 if test "$gconf_enabled" != yes; then
 414   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 415   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 416 fi
 417 if test "$use_gtk_awt" != yes; then
 418   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 419 fi
 420 if test "$use_qt_awt" != yes; then
 421   ac_configure_args="$ac_configure_args --disable-qt-peer"
 422 else
 423   # We need this as qt is disabled by default in classpath.
 424   ac_configure_args="$ac_configure_args --enable-qt-peer"
 425 fi
 426 if test "$use_x_awt" != yes; then
 427   ac_configure_args="$ac_configure_args --without-escher"
 428 else
 429   # We need this as escher is disabled by default in classpath.
 430   if test "$use_escher" != true; then
 431     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 432   else
 433     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 434   fi
 435 fi
 436 # -Werror causes unavoidable problems in code using alsa.
 437 ac_configure_args="$ac_configure_args --disable-Werror"
 438 dnl --with-gcj=$GCJ
 439 dnl --with-javah=$GCJH
 440 dnl gjdoc?
 441 dnl gtk-cairo -- just export here...
 442 dnl --enable-regen-headers?
 443
 444 # Only use libltdl for non-newlib builds.
 445 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 446    AC_LIBLTDL_CONVENIENCE
 447    AC_LIBTOOL_DLOPEN
 448    DIRLTDL=libltdl
 449    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 450    # Sigh.  Libtool's macro doesn't do the right thing.
 451    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 452    # FIXME: this is a hack.
 453    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 454    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 455 fi
 456 AC_SUBST(INCLTDL)
 457 AC_SUBST(LIBLTDL)
 458 AC_SUBST(DIRLTDL)
 459 AC_PROG_LIBTOOL
 460 AM_PROG_GCJ
 461 AM_PROG_CC_C_O
 462
 463 AC_CONFIG_SUBDIRS(classpath libltdl)
 464
 465 # The -no-testsuite modules omit the test subdir.
 466 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 467
 468 # Should the runtime set system properties by examining the
 469 # environment variable GCJ_PROPERTIES?
 470 AC_ARG_ENABLE(getenv-properties,
 471   AS_HELP_STRING([--disable-getenv-properties],
 472                  [don't set system properties from GCJ_PROPERTIES]))
 473
 474 # Whether GCJ_PROPERTIES is used depends on the target.
 475 if test -z "$enable_getenv_properties"; then
 476    enable_getenv_properties=${enable_getenv_properties_default-yes}
 477 fi
 478 if test "$enable_getenv_properties" = no; then
 479    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 480      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 481 fi
 482
 483 # Whether we should use arguments to main()
 484 if test -z "$enable_main_args"; then
 485    enable_main_args=${enable_main_args_default-yes}
 486 fi
 487 if test "$enable_main_args" = no; then
 488    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 489 fi
 490
 491
 492 # Should we use hashtable-based synchronization?
 493 # Currently works only for Linux X86/ia64
 494 # Typically faster and more space-efficient
 495 AC_ARG_ENABLE(hash-synchronization,
 496   AS_HELP_STRING([--enable-hash-synchronization],
 497                  [use global hash table for monitor locks]))
 498
 499 if test -z "$enable_hash_synchronization"; then
 500    enable_hash_synchronization=$enable_hash_synchronization_default
 501 fi
 502
 503
 504 install_ecj_jar=no
 505 ECJ_BUILD_JAR=
 506 ECJ_JAR=
 507 AC_ARG_WITH(ecj-jar,
 508         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 509         [ECJ_JAR=$withval],
 510         [if test -f $libgcj_basedir/../ecj.jar; then
 511            ECJ_BUILD_JAR=$libgcj_basedir/../ecj.jar
 512            ECJ_JAR='$(jardir)/ecj.jar'
 513            install_ecj_jar=yes
 514          fi])
 515 AC_SUBST(ECJ_BUILD_JAR)
 516 AC_SUBST(ECJ_JAR)
 517 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 518 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 519
 520 AC_ARG_WITH(java-home,
 521   AS_HELP_STRING([--with-java-home=DIRECTORY],
 522                  [value of java.home system property]),
 523                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 524 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 525 AC_SUBST(JAVA_HOME)
 526
 527 # What is the native OS API for MinGW?
 528 AC_ARG_WITH(win32-nlsapi,
 529   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 530                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 531 [case "${withval}" in
 532   ansi) with_win32_nlsapi=ansi ;;
 533   unicows) with_win32_nlsapi=unicows ;;
 534   unicode) with_win32_nlsapi=unicode ;;
 535   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 536 esac],[with_win32_nlsapi=ansi])
 537
 538 case "${with_win32_nlsapi}" in
 539   unicows | unicode)
 540     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 541       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 542     ;;
 543 esac
 544
 545 # configure.host sets slow_pthread_self if the synchronization code should
 546 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 547 if test "${slow_pthread_self}" = "yes"; then
 548   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 549     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 550 fi
 551
 552 # Check for gc debugging.  This option is handled both here and in the GC.
 553 AC_ARG_ENABLE(gc-debug,
 554    AS_HELP_STRING([--enable-gc-debug],
 555                   [include full support for pointer backtracing etc.]),
 556 [ if test "$enable_gc_debug" = "yes"; then
 557     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 558               [Define if we want to use debug calls into the garbage collector.])
 559   fi])
 560
 561 # See if the user has the interpreter included.
 562 AC_ARG_ENABLE(interpreter,
 563   AS_HELP_STRING([--enable-interpreter],
 564                  [enable interpreter]),
 565   [if test "$enable_interpreter" = yes; then
 566     # This can also be set in configure.host.
 567     libgcj_interpreter=yes
 568   elif test "$enable_interpreter" = no; then
 569     libgcj_interpreter=no
 570   fi])
 571
 572 if test "$libgcj_interpreter" = yes; then
 573    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 574 fi
 575 INTERPRETER="$libgcj_interpreter"
 576 AC_SUBST(INTERPRETER)
 577
 578 AC_MSG_CHECKING([for exception model to use])
 579 AC_LANG_PUSH(C++)
 580 AC_ARG_ENABLE(sjlj-exceptions,
 581   AS_HELP_STRING([--enable-sjlj-exceptions],
 582                  [force use of builtin_setjmp for exceptions]),
 583 [:],
 584 [dnl Botheration.  Now we've got to detect the exception model.
 585 dnl Link tests against libgcc.a are problematic since -- at least
 586 dnl as of this writing -- we've not been given proper -L bits for
 587 dnl single-tree newlib and libgloss.
 588 dnl
 589 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 590 dnl conftest files before we got a change to grep them first.
 591 cat > conftest.$ac_ext << EOF
 592 [#]line __oline__ "configure"
 593 struct S { ~S(); };
 594 void bar();
 595 void foo()
 596 {
 597   S s;
 598   bar();
 599 }
 600 EOF
 601 old_CXXFLAGS="$CXXFLAGS"
 602 CXXFLAGS=-S
 603 if AC_TRY_EVAL(ac_compile); then
 604   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 605     enable_sjlj_exceptions=yes
 606   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 607     enable_sjlj_exceptions=no
 608   fi
 609 fi
 610 CXXFLAGS="$old_CXXFLAGS"
 611 rm -f conftest*])
 612 if test x$enable_sjlj_exceptions = xyes; then
 613   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 614         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 615   ac_exception_model_name=sjlj
 616 elif test x$enable_sjlj_exceptions = xno; then
 617   ac_exception_model_name="call frame"
 618 else
 619   AC_MSG_ERROR([unable to detect exception model])
 620 fi
 621 AC_LANG_POP(C++)
 622 AC_MSG_RESULT($ac_exception_model_name)
 623
 624 # If we are non using SJLJ exceptions, and this host does not have support
 625 # for unwinding from a signal handler, enable checked dereferences and divides.
 626 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 627   CHECKREFSPEC=-fcheck-references
 628   DIVIDESPEC=-fuse-divide-subroutine
 629   EXCEPTIONSPEC=
 630 fi
 631
 632 # See if the user wants to disable java.net.  This is the mildly
 633 # ugly way that we admit that target-side configuration sucks.
 634 AC_ARG_ENABLE(java-net,
 635   AS_HELP_STRING([--disable-java-net],
 636                  [disable java.net]))
 637
 638 # Whether java.net is built by default can depend on the target.
 639 if test -z "$enable_java_net"; then
 640    enable_java_net=${enable_java_net_default-yes}
 641 fi
 642 if test "$enable_java_net" = no; then
 643    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 644 fi
 645
 646 # See if the user wants to configure without libffi.  Some
 647 # architectures don't support it, and default values are set in
 648 # configure.host.
 649 AC_ARG_WITH(libffi,
 650   AS_HELP_STRING([--without-libffi],
 651                  [don't use libffi]),
 652   [:],
 653   [with_libffi=${with_libffi_default-yes}])
 654
 655 LIBFFI=
 656 LIBFFIINCS=
 657 if test "$with_libffi" != no; then
 658    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 659    LIBFFI=../libffi/libffi_convenience.la
 660    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 661 fi
 662 AC_SUBST(LIBFFI)
 663 AC_SUBST(LIBFFIINCS)
 664
 665 # See if the user wants to disable JVMPI support.
 666 AC_ARG_ENABLE(jvmpi,
 667   AS_HELP_STRING([--disable-jvmpi],
 668                  [disable JVMPI support]))
 669
 670 if test "$enable_jvmpi" != no; then
 671     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 672 fi
 673
 674 # If the target is an eCos system, use the appropriate eCos
 675 # I/O routines.
 676 # FIXME: this should not be a local option but a global target
 677 # system; at present there is no eCos target.
 678 TARGET_ECOS=${PROCESS-"no"}
 679 AC_ARG_WITH(ecos,
 680 [  --with-ecos             enable runtime eCos target support],
 681 TARGET_ECOS="$with_ecos"
 682 )
 683
 684 case "$TARGET_ECOS" in
 685    no) case "$host" in
 686       *mingw*)
 687             PLATFORM=Win32
 688             PLATFORMNET=Win32
 689             PLATFORMH=win32.h
 690         CHECK_FOR_BROKEN_MINGW_LD
 691       ;;
 692       *)
 693             PLATFORM=Posix
 694             PLATFORMNET=Posix
 695             PLATFORMH=posix.h
 696       ;;
 697       esac
 698       ;;
 699    *)
 700       PLATFORM=Ecos
 701       PLATFORMNET=NoNet
 702       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 703       PLATFORMH=posix.h
 704       ;;
 705 esac
 706 AC_SUBST(PLATFORM)
 707 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 708
 709 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 710                                       [Define if you have int32_t and uint32_t.]))
 711 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 712                                         [Define if you have int32_t and uint32_t.]))
 713 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 714                                           [Define if you have u_int32_t]))
 715 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 716                                            [Define if you have u_int32_t]))
 717
 718 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 719 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 720
 721 case "$host" in
 722   *-darwin*) DARWIN_CRT=true ;;
 723   *) DARWIN_CRT=false ;;
 724 esac
 725 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 726
 727 # These may not be defined in a non-ANS conformant embedded system.
 728 # FIXME: Should these case a runtime exception in that case?
 729 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 730                                   [Define is you have 'mktime' in <time.h>]))
 731 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 732                                   [Define is you have 'localtime' in <time.h>]))
 733
 734 # Create the subdirectory for natFile.cc, or the attempt
 735 # to create the link will fail.
 736 test -d java || mkdir java
 737 test -d java/io || mkdir java/io
 738 test -d gnu || mkdir gnu
 739 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 740
 741 # Likewise for natConcreteProcess.cc.
 742 test -d java/lang || mkdir java/lang
 743 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 744
 745 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 746 test -d java/net || mkdir java/net
 747 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 748 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 749
 750 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 751 test -d gnu/java || mkdir gnu/java
 752 test -d gnu/java/net || mkdir gnu/java/net
 753 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 754 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 755
 756 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 757 test -d gnu/java/nio || mkdir gnu/java/nio
 758 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 759 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 760 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 761 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 762
 763 case "${host}" in
 764     *mingw*)
 765       SYSTEMSPEC="-lgdi32 -lws2_32"
 766       if test "${with_win32_nlsapi}" = "unicows"; then
 767         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 768       fi
 769     ;;
 770     *)
 771       SYSTEMSPEC=
 772     ;;
 773 esac
 774 AC_SUBST(SYSTEMSPEC)
 775
 776 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 777 AC_SUBST(LIBGCJTESTSPEC)
 778
 779 AC_ARG_WITH(system-zlib,
 780   AS_HELP_STRING([--with-system-zlib],
 781                  [use installed libz]))
 782 ZLIBSPEC=
 783 AC_SUBST(ZLIBSPEC)
 784 ZLIBTESTSPEC=
 785 AC_SUBST(ZLIBTESTSPEC)
 786
 787 AC_PATH_XTRA
 788
 789 # FIXME: this should be _libs on some hosts.
 790 libsubdir=.libs
 791
 792 # extra LD Flags which are required for targets
 793 case "${host}" in
 794 *-*-darwin[[0-7]].*)
 795     # For now we have to disable it on darwin[8-9] because it slows down
 796     # the linking phase. A possible bug in ld?
 797     # on Darwin -single_module speeds up loading of the dynamic libraries.
 798     extra_ldflags_libjava=-Wl,-single_module
 799     ;;
 800 esac
 801 AC_SUBST(extra_ldflags_libjava)
 802
 803 # Allow the GC to be disabled.  Can be useful when debugging.
 804 AC_MSG_CHECKING([for garbage collector to use])
 805 AC_ARG_ENABLE(java-gc,
 806   AS_HELP_STRING([--enable-java-gc=TYPE],
 807                  [choose garbage collector (default is boehm)]),
 808   [GC=$enableval],
 809   [GC=boehm])
 810 GCLIBS=
 811 GCINCS=
 812 GCDEPS=
 813 GCSPEC=
 814 JC1GCSPEC=
 815 GCTESTSPEC=
 816 case "$GC" in
 817  boehm)
 818     AC_MSG_RESULT(boehm)
 819     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 820     JC1GCSPEC='-fuse-boehm-gc'
 821     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 822     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 823     GCOBJS=boehm.lo
 824     GCHDR=boehm-gc.h
 825     # The POSIX thread support needs to know this.
 826     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 827     ;;
 828  no)
 829     AC_MSG_RESULT(none)
 830     GCHDR=no-gc.h
 831     ;;
 832  *)
 833     AC_MSG_ERROR([unrecognized collector "$GC"])
 834     ;;
 835 esac
 836 AC_SUBST(GCLIBS)
 837 AC_SUBST(GCINCS)
 838 AC_SUBST(GCDEPS)
 839 AC_SUBST(GCSPEC)
 840 AC_SUBST(JC1GCSPEC)
 841 AC_SUBST(GCTESTSPEC)
 842 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 843 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 844 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 845
 846
 847 AC_MSG_CHECKING([for thread model used by GCC])
 848 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 849 AC_MSG_RESULT([$THREADS])
 850
 851 case "$THREADS" in
 852  no | none | single)
 853     THREADS=none
 854     ;;
 855  posix | posix95 | pthreads)
 856     THREADS=posix
 857     case "$host" in
 858      *-*-linux*)
 859         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 860         ;;
 861     esac
 862     ;;
 863  win32)
 864     ;;
 865  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 866     AC_MSG_ERROR(thread package $THREADS not yet supported)
 867     ;;
 868  *)
 869     AC_MSG_ERROR($THREADS is an unknown thread package)
 870     ;;
 871 esac
 872
 873 THREADCXXFLAGS=
 874 THREADLDFLAGS=
 875 THREADLIBS=
 876 THREADINCS=
 877 THREADDEPS=
 878 THREADH=
 879 THREADSPEC=
 880 THREADSTARTFILESPEC=
 881 case "$THREADS" in
 882  posix)
 883     case "$host" in
 884      *-*-cygwin*)
 885         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 886         ;;
 887      *-*-freebsd[[1234]]*)
 888         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 889         # merely adds pthread_* functions) but it does have a -pthread switch
 890         # which is required at link-time to select -lc_r *instead* of -lc.
 891         THREADLDFLAGS=-pthread
 892         # Don't set THREADSPEC here as might be expected since -pthread is
 893         # not processed when found within a spec file, it must come from
 894         # the command line.  For now, the user must provide the -pthread
 895         # switch to link code compiled with gcj.  In future, consider adding
 896         # support for weak references to pthread_* functions ala gthr.h API.
 897         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 898         ;;
 899      *-*-freebsd*)
 900         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 901         # systems which support threads and -lpthread.
 902         THREADLDFLAGS=-pthread
 903         THREADSPEC=-lpthread
 904         ;;
 905      alpha*-dec-osf* | hppa*-hp-hpux*)
 906         THREADCXXFLAGS=-pthread
 907         # boehm-gc needs some functions from librt, so link that too.
 908         THREADLIBS='-lpthread -lrt'
 909         THREADSPEC='-lpthread -lrt'
 910         ;;
 911      *)
 912         THREADLIBS=-lpthread
 913         THREADSPEC=-lpthread
 914         ;;
 915     esac
 916     THREADH=posix-threads.h
 917     # MIT pthreads doesn't seem to have the mutexattr functions.
 918     # But for now we don't check for it.  We just assume you aren't
 919     # using MIT pthreads.
 920     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 921
 922     # If we're using the Boehm GC, then we happen to know that it
 923     # defines _REENTRANT, so we don't bother.  Eww.
 924     if test "$GC" != boehm; then
 925        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 926     fi
 927     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 928     ;;
 929
 930  win32)
 931     THREADH=win32-threads.h
 932     THREADCXXFLAGS=-mthreads
 933     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 934     # But we do not want the executables created to be dependent on
 935     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 936     # exception handling contexts.  The following kludge achieves this effect
 937     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 938     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 939     # A workaround is to explicitly use -mthreads while linking Java programs.
 940     # See PR libgcj/28263.
 941     #
 942     # FIXME: In Java we are able to detect thread death at the end of
 943     # Thread.run() so we should be able to clean up the exception handling
 944     # contexts ourselves.
 945     THREADSTARTFILESPEC='crtmt%O%s'
 946     ;;
 947
 948  none)
 949     THREADH=no-threads.h
 950     ;;
 951 esac
 952 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 953 AC_SUBST(THREADLIBS)
 954 AC_SUBST(THREADINCS)
 955 AC_SUBST(THREADDEPS)
 956 AC_SUBST(THREADSPEC)
 957 AC_SUBST(THREADSTARTFILESPEC)
 958 AC_SUBST(THREADLDFLAGS)
 959 AC_SUBST(THREADCXXFLAGS)
 960 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 961 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 962 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 963 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 964
 965 if test -d sysdep; then true; else mkdir sysdep; fi
 966 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 967 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 968 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 969
 970 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 971 if test "$use_libgcj_bc" = yes; then
 972   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 973 fi
 974 AC_SUBST(LIBGCJ_SPEC)
 975
 976 HASH_SYNC_SPEC=
 977 # Hash synchronization is only useful with posix threads right now.
 978 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 979    HASH_SYNC_SPEC=-fhash-synchronization
 980    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 981 fi
 982 AC_SUBST(HASH_SYNC_SPEC)
 983
 984 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 985
 986 # We're in the tree with gcc, and need to include some of its headers.
 987 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 988
 989 if test "x${with_newlib}" = "xyes"; then
 990    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 991    # may not work correctly, because the compiler may not be able to
 992    # link executables.
 993
 994    # We assume newlib.  This lets us hard-code the functions we know
 995    # we'll have.
 996    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 997    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 998    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 999    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1000    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1001    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1002    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1003    # This is only for POSIX threads.
1004    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1005    # We also assume we are using gcc, which provides alloca.
1006    AC_DEFINE(HAVE_ALLOCA)
1007
1008    # Assume we do not have getuid and friends.
1009    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1010    PLATFORMNET=NoNet
1011 else
1012    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
1013                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
1014                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1015                    nl_langinfo setlocale \
1016                    inet_pton uname inet_ntoa \
1017                    fork execvp pipe sigaction ftruncate mmap \
1018                    getifaddrs])
1019    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1020    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
1021    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1022    AC_CHECK_LIB(dl, dladdr, [
1023        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1024        AC_CHECK_LIB(dld, dladdr, [
1025        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1026
1027    if test x"$build" = x"$host"; then
1028      AC_CHECK_FILES(/proc/self/exe, [
1029        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1030    else
1031      case $host in
1032      *-linux*)
1033        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1034        ;;
1035      esac
1036    fi
1037
1038    AM_ICONV
1039    AM_LC_MESSAGES
1040    AC_STRUCT_TIMEZONE
1041
1042    AC_CHECK_FUNCS(gethostbyname_r, [
1043      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1044        [Define if you have the 'gethostbyname_r' function.])
1045      # There are two different kinds of gethostbyname_r.
1046      # We look for the one that returns `int'.
1047      # Hopefully this check is robust enough.
1048      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1049        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1050
1051      case " $GCINCS " in
1052      *" -D_REENTRANT "*) ;;
1053      *)
1054         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1055         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1056         [libjava_cv_gethostbyname_r_needs_reentrant],
1057         [ AC_LANG_PUSH(C++)
1058           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1059             [[gethostbyname_r("", 0, 0);]])],
1060             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1061                 CPPFLAGS_SAVE="$CPPFLAGS"
1062                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1063                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1064                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1065                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1066                 CPPFLAGS="$CPPFLAGS_SAVE"
1067           ])
1068           AC_LANG_POP(C++)
1069         ])
1070         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1071           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1072         fi
1073      ;;
1074      esac
1075
1076      AC_CACHE_CHECK([for struct hostent_data],
1077         [libjava_cv_struct_hostent_data], [dnl
1078         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1079 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1080 # define _REENTRANT 1
1081 #endif
1082 #include <netdb.h>]], [[struct hostent_data data;]])],
1083           [libjava_cv_struct_hostent_data=yes],
1084           [libjava_cv_struct_hostent_data=no])])
1085      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1086        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1087          [Define if struct hostent_data is defined in netdb.h])
1088      fi
1089    ])
1090
1091    # FIXME: libjava source code expects to find a prototype for
1092    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1093    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1094    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1095    # linkage check is enough, yet C++ code requires proper prototypes.)
1096    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1097    AC_CHECK_FUNCS(gethostbyaddr_r, [
1098      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1099        [Define if you have the 'gethostbyaddr_r' function.])
1100      # There are two different kinds of gethostbyaddr_r.
1101      # We look for the one that returns `int'.
1102      # Hopefully this check is robust enough.
1103      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1104        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1105          [Define if gethostbyaddr_r returns 'int'.])])])])
1106
1107    AC_CHECK_FUNCS(gethostname, [
1108      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1109        [Define if you have the 'gethostname' function.])
1110      AC_EGREP_HEADER(gethostname, unistd.h, [
1111        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1112          [Define if gethostname is declared in <unistd.h>.])])])
1113
1114    AC_CHECK_FUNCS(usleep, [
1115      AC_EGREP_HEADER(usleep, unistd.h, [
1116        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1117           [Define if usleep is declared in <unistd.h>.])])])
1118
1119    # Look for these functions in the thread library, but only bother
1120    # if using POSIX threads.
1121    if test "$THREADS" = posix; then
1122       save_LIBS="$LIBS"
1123       LIBS="$LIBS $THREADLIBS"
1124       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1125       # E.g., Solaris.
1126       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1127
1128       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1129       # Solaris 7 the name librt is preferred.
1130       AC_CHECK_FUNCS(sched_yield, , [
1131         AC_CHECK_LIB(rt, sched_yield, [
1132           AC_DEFINE(HAVE_SCHED_YIELD)
1133           THREADLIBS="$THREADLIBS -lrt"
1134           THREADSPEC="$THREADSPEC -lrt"], [
1135           AC_CHECK_LIB(posix4, sched_yield, [
1136             AC_DEFINE(HAVE_SCHED_YIELD)
1137             THREADLIBS="$THREADLIBS -lposix4"
1138             THREADSPEC="$THREADSPEC -lposix4"])])])
1139
1140       AC_CHECK_LIB(rt, clock_gettime, [
1141          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1142          case "$THREADSPEC" in
1143            *-lrt*) ;;
1144            *)
1145              THREADSPEC="$THREADSPEC -lrt"
1146              THREADLIBS="$THREADLIBS -lrt"
1147              ;;
1148          esac])
1149
1150       LIBS="$save_LIBS"
1151
1152       # We can save a little space at runtime if the mutex has m_count
1153       # or __m_count.  This is a nice hack for Linux.
1154       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1155           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1156         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1157              [Define if pthread_mutex_t has m_count member.]), [
1158         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1159             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1160           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1161             [Define if pthread_mutex_t has __m_count member.]))])
1162    fi
1163
1164    # We require a way to get the time.
1165    time_found=no
1166    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1167    if test "$time_found" = no; then
1168       AC_MSG_ERROR([no function found to get the time])
1169    fi
1170
1171    AC_CHECK_FUNCS(memmove)
1172
1173    # We require memcpy.
1174    memcpy_found=no
1175    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1176    if test "$memcpy_found" = no; then
1177       AC_MSG_ERROR([memcpy is required])
1178    fi
1179    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1180    AC_CHECK_LIB(dl, dlopen, [
1181        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1182        AC_CHECK_LIB(dld, dlopen, [
1183        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1184
1185    # Some library-finding code we stole from Tcl.
1186    #--------------------------------------------------------------------
1187    #    Check for the existence of the -lsocket and -lnsl libraries.
1188    #    The order here is important, so that they end up in the right
1189    #    order in the command line generated by make.  Here are some
1190    #    special considerations:
1191    #    1. Use "connect" and "accept" to check for -lsocket, and
1192    #       "gethostbyname" to check for -lnsl.
1193    #    2. Use each function name only once:  can't redo a check because
1194    #       autoconf caches the results of the last check and won't redo it.
1195    #    3. Use -lnsl and -lsocket only if they supply procedures that
1196    #       aren't already present in the normal libraries.  This is because
1197    #       IRIX 5.2 has libraries, but they aren't needed and they're
1198    #       bogus:  they goof up name resolution if used.
1199    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1200    #       To get around this problem, check for both libraries together
1201    #       if -lsocket doesn't work by itself.
1202    #--------------------------------------------------------------------
1203
1204    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1205     [gcj_cv_lib_sockets=
1206      gcj_checkBoth=0
1207      unset ac_cv_func_connect
1208      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1209      if test "$gcj_checkSocket" = 1; then
1210          unset ac_cv_func_connect
1211          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1212                       gcj_checkBoth=1)
1213      fi
1214      if test "$gcj_checkBoth" = 1; then
1215          gcj_oldLibs=$LIBS
1216          LIBS="$LIBS -lsocket -lnsl"
1217          unset ac_cv_func_accept
1218          AC_CHECK_FUNC(accept,
1219                        [gcj_checkNsl=0
1220                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1221          unset ac_cv_func_accept
1222          LIBS=$gcj_oldLibs
1223      fi
1224      unset ac_cv_func_gethostbyname
1225      gcj_oldLibs=$LIBS
1226      LIBS="$LIBS $gcj_cv_lib_sockets"
1227      AC_CHECK_FUNC(gethostbyname, ,
1228                    [AC_CHECK_LIB(nsl, main,
1229                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1230      unset ac_cv_func_gethostbyname
1231      LIBS=$gcj_oldLIBS
1232    ])
1233    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1234
1235    if test "$with_system_zlib" = yes; then
1236       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1237    fi
1238
1239    LIBMAGIC=
1240    AC_CHECK_LIB(magic, magic_open, [
1241       AC_DEFINE([HAVE_MAGIC_OPEN], 1, [Define if you have magic_open().])
1242       LIBMAGIC="-lmagic"])
1243    AC_SUBST(LIBMAGIC)
1244
1245    # Test for Gtk stuff, if asked for.
1246    if test "$use_gtk_awt" = yes; then
1247       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1248       AC_SUBST(GTK_CFLAGS)
1249       AC_SUBST(GTK_LIBS)
1250
1251       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1252       AC_SUBST(GLIB_CFLAGS)
1253       AC_SUBST(GLIB_LIBS)
1254
1255       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1256       AC_SUBST(LIBART_CFLAGS)
1257       AC_SUBST(LIBART_LIBS)
1258
1259       # We require the XTest Extension to support java.awt.Robot.
1260       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1261                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1262                    [${X_LIBS}])
1263    fi
1264
1265    # On Solaris, and maybe other architectures, the Boehm collector
1266    # requires -ldl.
1267    if test "$GC" = boehm; then
1268       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1269    fi
1270 fi
1271
1272 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1273 case $build in
1274     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1275     *)         CLASSPATH_SEPARATOR=':' ;;
1276 esac
1277 AC_SUBST(CLASSPATH_SEPARATOR)
1278
1279 # We must search the source tree for java.lang, since we still don't
1280 # have libgcj.jar nor java/lang/*.class
1281 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1282 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1283
1284 # Since some classes depend on this one, we need its source available
1285 # before we can do any GCJ compilation test :-(
1286 if test ! -f gnu/classpath/Configuration.java; then
1287   test -d gnu || mkdir gnu
1288   test -d gnu/classpath || mkdir gnu/classpath
1289   # Note that it is not crucial that all the values here be correct.
1290   sed -e "s,@prefix@,$prefix," \
1291       -e "s,@VERSION@,$VERSION," \
1292       -e "s,@LIBDEBUG@,false," \
1293       -e "s,@INIT_LOAD_LIBRARY@,false," \
1294       -e "s,@@,$LIBGCJDEBUG," \
1295       -e "s,@default_toolkit@,$TOOLKIT," \
1296       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1297       -e "s,@GTK_CAIRO_ENABLED@,false," \
1298         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1299         > gnu/classpath/Configuration.java
1300   # We do not want to redirect the output of the grep below to /dev/null,
1301   # but we add /dev/null to the input list so that grep will print the
1302   # filename of Configuration.java in case it finds any matches.
1303   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1304     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1305   fi
1306 fi
1307
1308 LT_AC_PROG_GCJ
1309
1310 # Now remove it.
1311 rm -f gnu/classpath/Configuration.java
1312
1313 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1314
1315 AC_CHECK_SIZEOF(void *)
1316
1317 AC_C_BIGENDIAN
1318
1319 ZLIBS=
1320 SYS_ZLIBS=
1321 ZINCS=
1322
1323 if test -z "$ZLIBSPEC"; then
1324    # Use zlib from the GCC tree.
1325    ZINCS='-I$(top_srcdir)/../zlib'
1326    ZLIBS=../zlib/libzgcj_convenience.la
1327 else
1328    # System's zlib.
1329    SYS_ZLIBS="$ZLIBSPEC"
1330 fi
1331 AC_SUBST(ZLIBS)
1332 AC_SUBST(SYS_ZLIBS)
1333 AC_SUBST(ZINCS)
1334 AC_SUBST(DIVIDESPEC)
1335 AC_SUBST(CHECKREFSPEC)
1336 AC_SUBST(EXCEPTIONSPEC)
1337 AC_SUBST(BACKTRACESPEC)
1338 AC_SUBST(IEEESPEC)
1339
1340 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1341 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1342 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1343 AC_SUBST(GCC_UNWIND_INCLUDE)
1344
1345 # Process the option "--enable-version-specific-runtime-libs"
1346 # Calculate toolexeclibdir
1347 case ${version_specific_libs} in
1348   yes)
1349     # Need the gcc compiler version to know where to install libraries
1350     # and header files if --enable-version-specific-runtime-libs option
1351     # is selected.
1352     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1353     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1354     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1355     toolexeclibdir=$toolexecmainlibdir
1356     ;;
1357   no)
1358     if test -n "$with_cross_host" &&
1359        test x"$with_cross_host" != x"no"; then
1360       # Install a library built with a cross compiler in tooldir, not libdir.
1361       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1362       toolexecmainlibdir='$(toolexecdir)/lib'
1363     else
1364       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1365       toolexecmainlibdir='$(libdir)'
1366     fi
1367     multi_os_directory=`$CC -print-multi-os-directory`
1368     case $multi_os_directory in
1369       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1370       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1371     esac
1372     ;;
1373 esac
1374 AC_SUBST(toolexecdir)
1375 AC_SUBST(toolexecmainlibdir)
1376 AC_SUBST(toolexeclibdir)
1377
1378 # Determine where the standard .db file and GNU Classpath JNI
1379 # libraries are found.
1380 multi_os_directory=`$CC -print-multi-os-directory`
1381 case $multi_os_directory in
1382   .)
1383    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1384    ;;
1385   *)
1386    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1387    ;;
1388 esac
1389 AC_SUBST(dbexecdir)
1390
1391 # Determine gcj version number.
1392 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1393 GCJVERSION=$gcjversion
1394 AC_SUBST(GCJVERSION)
1395 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1396
1397 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1398 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1399
1400 TL_AC_GXX_INCLUDE_DIR
1401
1402 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1403 # On that system, sys/ioctl.h will not include sys/filio.h unless
1404 # BSD_COMP is defined; just including sys/filio.h is simpler.
1405 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1406 # for now.  If you change this, you also must update natFile.cc.
1407 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1408                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1409                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1410                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1411                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1412 AC_CHECK_HEADERS(inttypes.h, [
1413     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1414     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1415 ])
1416 AC_HEADER_SYS_WAIT
1417
1418 AC_CHECK_TYPE([ssize_t], [int])
1419
1420 AC_MSG_CHECKING([for in_addr_t])
1421 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1422 #if STDC_HEADERS
1423 #include <stdlib.h>
1424 #include <stddef.h>
1425 #endif
1426 #if HAVE_NETINET_IN_H
1427 #include <netinet/in.h>
1428 #endif]], [[in_addr_t foo;]])],
1429   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1430      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1431    AC_MSG_RESULT(yes)],
1432   [AC_MSG_RESULT(no)])
1433
1434 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1435 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1436   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1437      [Define if struct ip_mreq is defined in netinet/in.h.])
1438    AC_MSG_RESULT(yes)],
1439   [AC_MSG_RESULT(no)])
1440
1441 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1442 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1443   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1444      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1445    AC_MSG_RESULT(yes)],
1446   [AC_MSG_RESULT(no)])
1447
1448 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1449 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1450   [AC_DEFINE(HAVE_INET6, 1,
1451      [Define if inet6 structures are defined in netinet/in.h.])
1452    AC_MSG_RESULT(yes)],
1453   [AC_MSG_RESULT(no)])
1454
1455 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1456 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1457 #include <sys/types.h>
1458 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1459   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1460    AC_MSG_RESULT(yes)],
1461   [AC_MSG_RESULT(no)])
1462
1463 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1464 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1465   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1466    AC_MSG_RESULT(yes)],
1467   [AC_MSG_RESULT(no)
1468    AC_MSG_CHECKING([for global timezone variable])
1469    dnl FIXME: we don't want a link check here because that won't work
1470    dnl when cross-compiling.  So instead we make an assumption that
1471    dnl the header file will mention timezone if it exists.
1472    dnl Don't find the win32 function timezone
1473    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1474      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1475       AC_MSG_RESULT(yes)],
1476      [AC_MSG_RESULT(no)
1477        AC_MSG_CHECKING([for global _timezone variable])
1478        dnl FIXME: As above, don't want link check
1479        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1480          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1481             [Define if your platform has the global _timezone variable.])
1482           AC_MSG_RESULT(yes)],
1483           [AC_MSG_RESULT(no)])])])
1484
1485 AC_FUNC_ALLOCA
1486
1487 AC_CHECK_PROGS(PERL, perl, false)
1488
1489 SYSDEP_SOURCES=
1490 SIGNAL_HANDLER_AUX=
1491
1492 case "${host}" in
1493  i?86-*-linux*)
1494     SIGNAL_HANDLER=include/i386-signal.h
1495     ;;
1496  sparc*-sun-solaris*)
1497     SIGNAL_HANDLER=include/sparc-signal.h
1498     ;;
1499 # ia64-*)
1500 #    SYSDEP_SOURCES=sysdep/ia64.c
1501 #    test -d sysdep || mkdir sysdep
1502 #    ;;
1503  hppa*-*-linux*)
1504     SIGNAL_HANDLER=include/pa-signal.h
1505     ;;
1506  hppa*-hp-hpux*)
1507     SIGNAL_HANDLER=include/hppa-signal.h
1508     ;;
1509  ia64-*-linux*)
1510     SIGNAL_HANDLER=include/dwarf2-signal.h
1511     ;;
1512  powerpc*-*-linux*)
1513     SIGNAL_HANDLER=include/powerpc-signal.h
1514     ;;
1515  alpha*-*-linux*)
1516     SIGNAL_HANDLER=include/dwarf2-signal.h
1517     ;;
1518  s390*-*-linux*)
1519     SIGNAL_HANDLER=include/s390-signal.h
1520     ;;
1521  x86_64*-*-linux*)
1522     SIGNAL_HANDLER=include/x86_64-signal.h
1523     SIGNAL_HANDLER_AUX=include/i386-signal.h
1524     ;;
1525  sparc*-*-linux*)
1526     SIGNAL_HANDLER=include/dwarf2-signal.h
1527     ;;
1528  sh*-*-linux*)
1529     SIGNAL_HANDLER=include/sh-signal.h
1530     ;;
1531  *mingw*)
1532     SIGNAL_HANDLER=include/win32-signal.h
1533     ;;
1534  mips*-*-linux*)
1535     SIGNAL_HANDLER=include/mips-signal.h
1536     ;;
1537  powerpc*-*-darwin*)
1538     SIGNAL_HANDLER=include/darwin-signal.h
1539     ;;
1540  *)
1541     SIGNAL_HANDLER=include/default-signal.h
1542     ;;
1543 esac
1544
1545 # If we're using sjlj exceptions, forget what we just learned.
1546 if test "$enable_sjlj_exceptions" = yes; then
1547    SIGNAL_HANDLER=include/default-signal.h
1548    SIGNAL_HANDLER_AUX=
1549 fi
1550
1551 AC_SUBST(SYSDEP_SOURCES)
1552
1553 if test -z "$SIGNAL_HANDLER_AUX"; then
1554   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1555 fi
1556
1557 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1558                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1559
1560 if test "${multilib}" = "yes"; then
1561   multilib_arg="--enable-multilib"
1562 else
1563   multilib_arg=
1564 fi
1565
1566 # See if we support thread-local storage.
1567 GCC_CHECK_TLS
1568
1569 # For _Unwind_GetIPInfo.
1570 GCC_CHECK_UNWIND_GETIPINFO
1571
1572 # Check if linker supports static linking on a per library basis
1573 LD_START_STATIC_SPEC=
1574 LD_FINISH_STATIC_SPEC=
1575 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1576   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1577     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1578     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1579   fi
1580 fi
1581 AC_SUBST(LD_START_STATIC_SPEC)
1582 AC_SUBST(LD_FINISH_STATIC_SPEC)
1583
1584 here=`${PWDCMD-pwd}`
1585 AC_SUBST(here)
1586
1587 # We get this from the environment.
1588 AC_SUBST(GCJFLAGS)
1589
1590 AC_CONFIG_FILES([
1591 Makefile
1592 libgcj.pc
1593 libgcj.spec
1594 libgcj-test.spec
1595 gcj/Makefile
1596 include/Makefile
1597 testsuite/Makefile
1598 ])
1599
1600 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1601
1602 AC_CONFIG_COMMANDS([default],
1603 [# Only add multilib support code if we just rebuilt top-level Makefile.
1604 case " $CONFIG_FILES " in
1605  *" Makefile "*)
1606    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1607    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1608    ;;
1609 esac
1610 for ac_multi_file in $CONFIG_FILES; do
1611   case $ac_multi_file in
1612   */Makefile)
1613     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1614   esac
1615 done
1616 ],
1617 srcdir=${srcdir}
1618 host=${host}
1619 target=${target}
1620 with_multisubdir=${with_multisubdir}
1621 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1622 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1623 libgcj_basedir=${libgcj_basedir}
1624 CC="${CC}"
1625 CXX="${CXX}"
1626 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1627 )
1628
1629 AC_OUTPUT