libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 # We use these options to decide which functions to include.
   9 AC_ARG_WITH(target-subdir,
  10   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  11                  [configure in a subdirectory]))
  12
  13 # We may get other options which we don't document:
  14 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  15
  16 # When building with srcdir == objdir, links to the source files will
  17 # be created in directories within the target_subdir.  We have to
  18 # adjust toplevel_srcdir accordingly, so that configure finds
  19 # install-sh and other auxiliary files that live in the top-level
  20 # source directory.
  21 if test "${srcdir}" = "."; then
  22   if test -z "${with_target_subdir}"; then
  23     toprel=".."
  24   else
  25     if test "${with_target_subdir}" != "."; then
  26       toprel="${with_multisrctop}../.."
  27     else
  28       toprel="${with_multisrctop}.."
  29     fi
  30   fi
  31 else
  32   toprel=".."
  33 fi
  34
  35 libgcj_basedir=$srcdir/$toprel/./libjava
  36 AC_SUBST(libgcj_basedir)
  37
  38 AC_CANONICAL_SYSTEM
  39 _GCC_TOPLEV_NONCANONICAL_BUILD
  40 _GCC_TOPLEV_NONCANONICAL_TARGET
  41
  42 AC_SUBST(target_noncanonical)
  43
  44 # This works around the fact that libtool configuration may change LD
  45 # for this particular configuration, but some shells, instead of
  46 # keeping the changes in LD private, export them just because LD is
  47 # exported.
  48 ORIGINAL_LD_FOR_MULTILIBS=$LD
  49
  50 AC_PROG_LN_S
  51
  52 # This works around an automake problem.
  53 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  54 AC_SUBST(mkinstalldirs)
  55
  56 AC_ARG_WITH(cross-host,
  57   AS_HELP_STRING([--with-cross-host=HOST],
  58                  [configure with a cross compiler from HOST]))
  59
  60 AC_ARG_WITH(newlib,
  61   AS_HELP_STRING([--with-newlib],
  62                  [configure with newlib]))
  63
  64 AC_ARG_ENABLE(version-specific-runtime-libs,
  65   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  67     [case "$enableval" in
  68       yes) version_specific_libs=yes ;;
  69       no)  version_specific_libs=no ;;
  70       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71      esac],
  72     [version_specific_libs=no]
  73 )
  74
  75 # Default to --enable-multilib
  76 AC_ARG_ENABLE(multilib,
  77   AS_HELP_STRING([--enable-multilib],
  78                  [build many library versions (default)]),
  79 [case "${enableval}" in
  80   yes) multilib=yes ;;
  81   no)  multilib=no ;;
  82   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  83  esac], [multilib=yes])dnl
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
  99 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 100 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 101 save_CXXFLAGS="$CXXFLAGS"
 102 CXXFLAGS="$CXXFLAGS -fno-builtin"
 103 AC_PROG_CC
 104 AC_PROG_CXX
 105 CXXFLAGS="$save_CXXFLAGS"
 106 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107 AC_SUBST(CFLAGS)
 108 AC_SUBST(CXXFLAGS)
 109 AC_SUBST(LDFLAGS)
 110
 111 AM_INIT_AUTOMAKE([1.9.0])
 112
 113 AC_CHECK_TOOL(AS, as)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 AC_PROG_INSTALL
 118
 119 AM_MAINTAINER_MODE
 120
 121 AC_EXEEXT
 122
 123 # configure.host sets the following important variables
 124 #       libgcj_cflags    - host specific C compiler flags
 125 #       libgcj_cxxflags  - host specific C++ compiler flags
 126 #       libgcj_javaflags - host specific Java compiler flags
 127
 128 libgcj_cflags=
 129 libgcj_cxxflags=
 130 libgcj_javaflags=
 131
 132 . ${srcdir}/configure.host
 133
 134 LIBGCJ_CFLAGS="${libgcj_cflags}"
 135 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 136 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 137 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 138 AC_SUBST(LIBGCJ_CFLAGS)
 139 AC_SUBST(LIBGCJ_CXXFLAGS)
 140 AC_SUBST(LIBGCJ_JAVAFLAGS)
 141 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 142
 143 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 144
 145 # Only use libltdl for non-newlib builds.
 146 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 147    AC_LIBLTDL_CONVENIENCE
 148    AC_LIBTOOL_DLOPEN
 149    DIRLTDL=libltdl
 150    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 151    # Sigh.  Libtool's macro doesn't do the right thing.
 152    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 153    # FIXME: this is a hack.
 154    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 155    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 156 fi
 157 AC_SUBST(INCLTDL)
 158 AC_SUBST(LIBLTDL)
 159 AC_SUBST(DIRLTDL)
 160 AC_PROG_LIBTOOL
 161 AM_PROG_GCJ
 162 AM_PROG_CC_C_O
 163 AC_CONFIG_SUBDIRS(libltdl)
 164
 165 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
 166    COMPPATH=.
 167 else
 168    COMPPATH=..
 169 fi
 170 AC_SUBST(COMPPATH)
 171
 172 # The -no-testsuite modules omit the test subdir.
 173 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 174
 175 # Should the runtime set system properties by examining the
 176 # environment variable GCJ_PROPERTIES?
 177 AC_ARG_ENABLE(getenv-properties,
 178   AS_HELP_STRING([--disable-getenv-properties],
 179                  [don't set system properties from GCJ_PROPERTIES]))
 180
 181 # Whether GCJ_PROPERTIES is used depends on the target.
 182 if test -z "$enable_getenv_properties"; then
 183    enable_getenv_properties=${enable_getenv_properties_default-yes}
 184 fi
 185 if test "$enable_getenv_properties" = no; then
 186    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 187      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 188 fi
 189
 190 # Whether we should use arguments to main()
 191 if test -z "$enable_main_args"; then
 192    enable_main_args=${enable_main_args_default-yes}
 193 fi
 194 if test "$enable_main_args" = no; then
 195    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 196 fi
 197
 198
 199 # Should we use hashtable-based synchronization?
 200 # Currently works only for Linux X86/ia64
 201 # Typically faster and more space-efficient
 202 AC_ARG_ENABLE(hash-synchronization,
 203   AS_HELP_STRING([--enable-hash-synchronization],
 204                  [use global hash table for monitor locks]))
 205
 206 if test -z "$enable_hash_synchronization"; then
 207    enable_hash_synchronization=$enable_hash_synchronization_default
 208 fi
 209
 210 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 211 AC_ARG_ENABLE(libgcj-multifile,
 212   AS_HELP_STRING([--enable-libgcj-multifile]
 213                  [allow compilation of several files at once]),
 214 [case "${enableval}" in
 215   yes) enable_libgcj_multifile=yes ;;
 216   no)  enable_libgcj_multifile=no ;;
 217   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 218 esac],[enable_libgcj_multifile=no])
 219 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 220
 221 # What is the native OS API for MinGW?
 222 AC_ARG_WITH(win32-nlsapi,
 223   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 224                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 225 [case "${withval}" in
 226   ansi) with_win32_nlsapi=ansi ;;
 227   unicows) with_win32_nlsapi=unicows ;;
 228   unicode) with_win32_nlsapi=unicode ;;
 229   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 230 esac],[with_win32_nlsapi=ansi])
 231
 232 case "${with_win32_nlsapi}" in
 233   unicows | unicode)
 234     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 235       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 236     ;;
 237 esac
 238
 239 # configure.host sets slow_pthread_self if the synchronization code should
 240 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 241 if test "${slow_pthread_self}" = "yes"; then
 242   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 243     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 244 fi
 245
 246
 247 # See if the user has requested runtime debugging.
 248 LIBGCJDEBUG="false"
 249 AC_SUBST(LIBGCJDEBUG)
 250 AC_ARG_ENABLE(libgcj-debug,
 251   AS_HELP_STRING([--enable-libgcj-debug],
 252                  [enable runtime debugging code]),
 253   [if test "$enable_libgcj_debug" = yes; then
 254     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 255     LIBGCJDEBUG="true"
 256   fi])
 257
 258 # Check for gc debugging.  This option is handled both here and in the GC.
 259 AC_ARG_ENABLE(gc-debug,
 260    AS_HELP_STRING([--enable-gc-debug],
 261                   [include full support for pointer backtracing etc.]),
 262 [ if test "$enable_gc_debug" = "yes"; then
 263     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 264               [Define if we want to use debug calls into the garbage collector.])
 265   fi])
 266
 267 # See if the user has the interpreter included.
 268 AC_ARG_ENABLE(interpreter,
 269   AS_HELP_STRING([--enable-interpreter],
 270                  [enable interpreter]),
 271   [if test "$enable_interpreter" = yes; then
 272     # This can also be set in configure.host.
 273     libgcj_interpreter=yes
 274   elif test "$enable_interpreter" = no; then
 275     libgcj_interpreter=no
 276   fi])
 277
 278 if test "$libgcj_interpreter" = yes; then
 279    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 280 fi
 281 INTERPRETER="$libgcj_interpreter"
 282 AC_SUBST(INTERPRETER)
 283
 284 AC_MSG_CHECKING([for exception model to use])
 285 AC_LANG_PUSH(C++)
 286 AC_ARG_ENABLE(sjlj-exceptions,
 287   AS_HELP_STRING([--enable-sjlj-exceptions],
 288                  [force use of builtin_setjmp for exceptions]),
 289 [:],
 290 [dnl Botheration.  Now we've got to detect the exception model.
 291 dnl Link tests against libgcc.a are problematic since -- at least
 292 dnl as of this writing -- we've not been given proper -L bits for
 293 dnl single-tree newlib and libgloss.
 294 dnl
 295 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 296 dnl conftest files before we got a change to grep them first.
 297 cat > conftest.$ac_ext << EOF
 298 [#]line __oline__ "configure"
 299 struct S { ~S(); };
 300 void bar();
 301 void foo()
 302 {
 303   S s;
 304   bar();
 305 }
 306 EOF
 307 old_CXXFLAGS="$CXXFLAGS"
 308 CXXFLAGS=-S
 309 if AC_TRY_EVAL(ac_compile); then
 310   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 311     enable_sjlj_exceptions=yes
 312   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 313     enable_sjlj_exceptions=no
 314   fi
 315 fi
 316 CXXFLAGS="$old_CXXFLAGS"
 317 rm -f conftest*])
 318 if test x$enable_sjlj_exceptions = xyes; then
 319   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 320         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 321   ac_exception_model_name=sjlj
 322 elif test x$enable_sjlj_exceptions = xno; then
 323   ac_exception_model_name="call frame"
 324 else
 325   AC_MSG_ERROR([unable to detect exception model])
 326 fi
 327 AC_LANG_POP(C++)
 328 AC_MSG_RESULT($ac_exception_model_name)
 329
 330 # If we are non using SJLJ exceptions, and this host does not have support
 331 # for unwinding from a signal handler, enable checked dereferences and divides.
 332 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 333   CHECKREFSPEC=-fcheck-references
 334   DIVIDESPEC=-fuse-divide-subroutine
 335   EXCEPTIONSPEC=
 336 fi
 337
 338 # See if the user wants to disable java.net.  This is the mildly
 339 # ugly way that we admit that target-side configuration sucks.
 340 AC_ARG_ENABLE(java-net,
 341   AS_HELP_STRING([--disable-java-net],
 342                  [disable java.net]))
 343
 344 # Whether java.net is built by default can depend on the target.
 345 if test -z "$enable_java_net"; then
 346    enable_java_net=${enable_java_net_default-yes}
 347 fi
 348 if test "$enable_java_net" = no; then
 349    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 350 fi
 351
 352 # See if the user wants to configure without libffi.  Some
 353 # architectures don't support it, and default values are set in
 354 # configure.host.
 355 AC_ARG_WITH(libffi,
 356   AS_HELP_STRING([--without-libffi],
 357                  [don't use libffi]),
 358   [:],
 359   [with_libffi=${with_libffi_default-yes}])
 360
 361 LIBFFI=
 362 LIBFFIINCS=
 363 if test "$with_libffi" != no; then
 364    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 365    LIBFFI=../libffi/libffi_convenience.la
 366    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 367 fi
 368 AC_SUBST(LIBFFI)
 369 AC_SUBST(LIBFFIINCS)
 370
 371 # See if the user wants to disable JVMPI support.
 372 AC_ARG_ENABLE(jvmpi,
 373   AS_HELP_STRING([--disable-jvmpi],
 374                  [disable JVMPI support]))
 375
 376 if test "$enable_jvmpi" != no; then
 377     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 378 fi
 379
 380 # If the target is an eCos system, use the appropriate eCos
 381 # I/O routines.
 382 # FIXME: this should not be a local option but a global target
 383 # system; at present there is no eCos target.
 384 TARGET_ECOS=${PROCESS-"no"}
 385 AC_ARG_WITH(ecos,
 386 [  --with-ecos             enable runtime eCos target support],
 387 TARGET_ECOS="$with_ecos"
 388 )
 389
 390 supply_backtrace=no
 391
 392 PLATFORM_INNER_NAT_HDRS=
 393 case "$TARGET_ECOS" in
 394    no) case "$host" in
 395       *mingw*)
 396             PLATFORM=Win32
 397             PLATFORMNET=Win32
 398             PLATFORMH=win32.h
 399         CHECK_FOR_BROKEN_MINGW_LD
 400       ;;
 401       *)
 402             PLATFORM=Posix
 403             PLATFORMNET=Posix
 404             PLATFORMH=posix.h
 405             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 406       ;;
 407       esac
 408       ;;
 409    *)
 410       PLATFORM=Ecos
 411       PLATFORMNET=NoNet
 412       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 413       PLATFORMH=posix.h
 414       ;;
 415 esac
 416 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 417 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 418
 419 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 420                                       [Define if you have int32_t and uint32_t.]))
 421 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 422                                         [Define if you have int32_t and uint32_t.]))
 423 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 424                                           [Define if you have u_int32_t]))
 425 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 426                                            [Define if you have u_int32_t]))
 427
 428 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 429 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 430 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 431
 432 case "$host" in
 433   *-darwin*) DARWIN_CRT=true ;;
 434   *) DARWIN_CRT=false ;;
 435 esac
 436 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 437
 438 # These may not be defined in a non-ANS conformant embedded system.
 439 # FIXME: Should these case a runtime exception in that case?
 440 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 441                                   [Define is you have 'mktime' in <time.h>]))
 442 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 443                                   [Define is you have 'localtime' in <time.h>]))
 444
 445 # Create the subdirectory for natFile.cc, or the attempt
 446 # to create the link will fail.
 447 test -d java || mkdir java
 448 test -d java/io || mkdir java/io
 449 test -d gnu || mkdir gnu
 450 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 451
 452 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 453 test -d java/lang || mkdir java/lang
 454 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 455 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 456
 457 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 458 test -d java/net || mkdir java/net
 459 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 460 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 461
 462 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 463 test -d gnu/java || mkdir gnu/java
 464 test -d gnu/java/net || mkdir gnu/java/net
 465 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 466 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 467
 468 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 469 test -d gnu/java/nio || mkdir gnu/java/nio
 470 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 471 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 472 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 473 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 474
 475 case "${host}" in
 476     *mingw*)
 477       SYSTEMSPEC="-lgdi32 -lws2_32"
 478       if test "${with_win32_nlsapi}" = "unicows"; then
 479         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 480       fi
 481     ;;
 482     *)
 483       SYSTEMSPEC=
 484     ;;
 485 esac
 486 AC_SUBST(SYSTEMSPEC)
 487
 488 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 489 AC_SUBST(LIBGCJTESTSPEC)
 490
 491 AC_ARG_WITH(system-zlib,
 492   AS_HELP_STRING([--with-system-zlib],
 493                  [use installed libz]))
 494 ZLIBSPEC=
 495 AC_SUBST(ZLIBSPEC)
 496 ZLIBTESTSPEC=
 497 AC_SUBST(ZLIBTESTSPEC)
 498
 499 AC_PATH_XTRA
 500
 501 # Determine which AWT peer libraries to build
 502 AC_ARG_ENABLE(java-awt,
 503   AS_HELP_STRING([--enable-java-awt],
 504                  [list of AWT peer implementations to be built]))
 505
 506 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 507 use_xlib_awt=""
 508 use_gtk_awt=""
 509 # The default toolkit to use is the first one specified.
 510 TOOLKIT=
 511 AC_SUBST(TOOLKIT)
 512
 513 for peer in $peerlibs ; do
 514   case $peer in
 515     xlib)
 516       if test "$no_x" = yes; then
 517         echo "*** xlib peers requested but no X library available" 1>&2
 518         exit 1
 519       else
 520         use_xlib_awt="yes"
 521         if test -z "$TOOLKIT"; then
 522            TOOLKIT=gnu.awt.xlib.XToolkit
 523         fi
 524       fi
 525       ;;
 526     gtk)
 527       if test "$no_x" = yes; then
 528          echo "*** xlib peers requested but no X library available" 1>&2
 529          exit 1
 530       else
 531          use_gtk_awt=yes
 532          if test -z "$TOOLKIT"; then
 533             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 534          fi
 535          test -d jniinclude || mkdir jniinclude
 536       fi
 537       ;;
 538     no)
 539       use_xlib_awt=
 540       use_gtk_awt=
 541       break
 542       ;;
 543     *)
 544       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 545       exit 1
 546   esac
 547 done
 548
 549 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 550 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 551
 552 # determine whether to enable the cairo GTK Graphics2D backend
 553 AC_ARG_ENABLE(gtk-cairo,
 554   AS_HELP_STRING([--enable-gtk-cairo],
 555                  [build the cairo Graphics2D implementation on GTK]))
 556 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 557 if test "x${enable_gtk_cairo}" = xyes
 558 then
 559         PKG_CHECK_MODULES(CAIRO, cairo)
 560         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 561 fi
 562 AC_SUBST(CAIRO_LIBS)
 563 AC_SUBST(CAIRO_CFLAGS)
 564 AC_SUBST(PANGOFT2_LIBS)
 565 AC_SUBST(PANGOFT2_CFLAGS)
 566
 567 # FIXME: this should be _libs on some hosts.
 568 libsubdir=.libs
 569
 570 # Allow the GC to be disabled.  Can be useful when debugging.
 571 AC_MSG_CHECKING([for garbage collector to use])
 572 AC_ARG_ENABLE(java-gc,
 573   AS_HELP_STRING([--enable-java-gc=TYPE],
 574                  [choose garbage collector (default is boehm)]),
 575   [GC=$enableval],
 576   [GC=boehm])
 577 GCLIBS=
 578 GCINCS=
 579 GCDEPS=
 580 GCSPEC=
 581 JC1GCSPEC=
 582 GCTESTSPEC=
 583 case "$GC" in
 584  boehm)
 585     AC_MSG_RESULT(boehm)
 586     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 587     JC1GCSPEC='-fuse-boehm-gc'
 588     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 589     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 590     GCOBJS=boehm.lo
 591     GCHDR=boehm-gc.h
 592     # The POSIX thread support needs to know this.
 593     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 594     ;;
 595  no)
 596     AC_MSG_RESULT(none)
 597     GCHDR=no-gc.h
 598     ;;
 599  *)
 600     AC_MSG_ERROR([unrecognized collector "$GC"])
 601     ;;
 602 esac
 603 AC_SUBST(GCLIBS)
 604 AC_SUBST(GCINCS)
 605 AC_SUBST(GCDEPS)
 606 AC_SUBST(GCSPEC)
 607 AC_SUBST(JC1GCSPEC)
 608 AC_SUBST(GCTESTSPEC)
 609 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 610 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 611 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 612
 613
 614 AC_MSG_CHECKING([for thread model used by GCC])
 615 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 616 AC_MSG_RESULT([$THREADS])
 617
 618 case "$THREADS" in
 619  no | none | single)
 620     THREADS=none
 621     ;;
 622  posix | posix95 | pthreads)
 623     THREADS=posix
 624     case "$host" in
 625      *-*-linux*)
 626         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 627         ;;
 628     esac
 629     ;;
 630  win32)
 631     ;;
 632  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 633     AC_MSG_ERROR(thread package $THREADS not yet supported)
 634     ;;
 635  *)
 636     AC_MSG_ERROR($THREADS is an unknown thread package)
 637     ;;
 638 esac
 639
 640 THREADCXXFLAGS=
 641 THREADLDFLAGS=
 642 THREADLIBS=
 643 THREADINCS=
 644 THREADDEPS=
 645 THREADH=
 646 THREADSPEC=
 647 case "$THREADS" in
 648  posix)
 649     case "$host" in
 650      *-*-cygwin*)
 651         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 652         ;;
 653      *-*-freebsd[[1234]]*)
 654         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 655         # merely adds pthread_* functions) but it does have a -pthread switch
 656         # which is required at link-time to select -lc_r *instead* of -lc.
 657         THREADLDFLAGS=-pthread
 658         # Don't set THREADSPEC here as might be expected since -pthread is
 659         # not processed when found within a spec file, it must come from
 660         # the command line.  For now, the user must provide the -pthread
 661         # switch to link code compiled with gcj.  In future, consider adding
 662         # support for weak references to pthread_* functions ala gthr.h API.
 663         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 664         ;;
 665      *-*-freebsd*)
 666         # FreeBSD 5 implements a model much closer to other modern UNIX
 667         # which support threads.  However, it still does not support
 668         # -lpthread.
 669         THREADLDFLAGS=-pthread
 670         THREADSPEC=-lc_r
 671         ;;
 672      alpha*-dec-osf*)
 673         THREADCXXFLAGS=-pthread
 674         # boehm-gc needs some functions from librt, so link that too.
 675         THREADLIBS='-lpthread -lrt'
 676         THREADSPEC='-lpthread -lrt'
 677         ;;
 678      *)
 679         THREADLIBS=-lpthread
 680         THREADSPEC=-lpthread
 681         ;;
 682     esac
 683     THREADH=posix-threads.h
 684     # MIT pthreads doesn't seem to have the mutexattr functions.
 685     # But for now we don't check for it.  We just assume you aren't
 686     # using MIT pthreads.
 687     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 688
 689     # If we're using the Boehm GC, then we happen to know that it
 690     # defines _REENTRANT, so we don't bother.  Eww.
 691     if test "$GC" != boehm; then
 692        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 693     fi
 694     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 695     ;;
 696
 697  win32)
 698     THREADH=win32-threads.h
 699     ;;
 700
 701  none)
 702     THREADH=no-threads.h
 703     ;;
 704 esac
 705 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 706 AC_SUBST(THREADLIBS)
 707 AC_SUBST(THREADINCS)
 708 AC_SUBST(THREADDEPS)
 709 AC_SUBST(THREADSPEC)
 710 AC_SUBST(THREADLDFLAGS)
 711 AC_SUBST(THREADCXXFLAGS)
 712 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 713 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 714 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 715
 716 if test -d sysdep; then true; else mkdir sysdep; fi
 717 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 718
 719 HASH_SYNC_SPEC=
 720 # Hash synchronization is only useful with posix threads right now.
 721 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 722    HASH_SYNC_SPEC=-fhash-synchronization
 723    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 724 fi
 725 AC_SUBST(HASH_SYNC_SPEC)
 726
 727
 728 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 729
 730 # We're in the tree with gcc, and need to include some of its headers.
 731 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 732
 733 TL_AC_GCC_VERSION([$srcdir/..])
 734
 735 # Figure out where generated headers like libgcj-config.h get installed.
 736 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 737 AC_SUBST(tool_include_dir)
 738
 739 if test "x${with_newlib}" = "xyes"; then
 740    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 741    # may not work correctly, because the compiler may not be able to
 742    # link executables.
 743
 744    # We assume newlib.  This lets us hard-code the functions we know
 745    # we'll have.
 746    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 747    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 748    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 749    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 750    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 751    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 752    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 753    # This is only for POSIX threads.
 754    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 755    # We also assume we are using gcc, which provides alloca.
 756    AC_DEFINE(HAVE_ALLOCA)
 757
 758    # Assume we do not have getuid and friends.
 759    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 760    PLATFORMNET=NoNet
 761 else
 762    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 763    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 764    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 765    AC_CHECK_FUNCS(nl_langinfo setlocale)
 766    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 767    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 768    AC_CHECK_FUNCS(fork execvp pipe sigaction ftruncate)
 769    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 770    AC_CHECK_FUNC(backtrace, [
 771      case "$host" in
 772        ia64-*-linux*)
 773          # Has broken backtrace()
 774          ;;
 775        mips*-*-linux*)
 776          # Has broken backtrace(), but we supply our own.
 777          if test -d sysdep; then true; else mkdir -p sysdep; fi
 778          supply_backtrace=yes
 779          AC_DEFINE(HAVE_BACKTRACE, 1,
 780            [Define if your platform has a working backtrace() function.])
 781          ;;
 782        *)
 783          AC_DEFINE(HAVE_BACKTRACE, 1,
 784            [Define if your platform has a working backtrace() function.])
 785          ;;
 786      esac
 787    ], [
 788      case "$host" in
 789        *mingw*)
 790          # Has backtrace() defined in libgcj itself
 791          AC_DEFINE(HAVE_BACKTRACE, 1,
 792            [Define if your platform has a working backtrace() function.])
 793          ;;
 794      esac
 795    ])
 796
 797    AC_CHECK_LIB(dl, dladdr, [
 798      if test "x${disable_dladdr}" = "xyes"; then
 799        #Broken dladdr().
 800        true
 801      else
 802        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 803      fi
 804    ])
 805    if test x"$build" = x"$host"; then
 806      AC_CHECK_FILES(/proc/self/exe, [
 807        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 808    else
 809      case $host in
 810      *-linux*)
 811        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 812        ;;
 813      esac
 814    fi
 815
 816    AM_ICONV
 817    AM_LC_MESSAGES
 818    AC_STRUCT_TIMEZONE
 819
 820    AC_CHECK_FUNCS(gethostbyname_r, [
 821      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 822        [Define if you have the 'gethostbyname_r' function.])
 823      # There are two different kinds of gethostbyname_r.
 824      # We look for the one that returns `int'.
 825      # Hopefully this check is robust enough.
 826      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 827        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 828
 829      case " $GCINCS " in
 830      *" -D_REENTRANT "*) ;;
 831      *)
 832         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 833         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 834         [libjava_cv_gethostbyname_r_needs_reentrant],
 835         [ AC_LANG_PUSH(C++)
 836           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 837             [[gethostbyname_r("", 0, 0);]])],
 838             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 839                 CPPFLAGS_SAVE="$CPPFLAGS"
 840                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 841                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 842                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 843                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 844                 CPPFLAGS="$CPPFLAGS_SAVE"
 845           ])
 846           AC_LANG_POP(C++)
 847         ])
 848         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 849           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 850         fi
 851      ;;
 852      esac
 853
 854      AC_CACHE_CHECK([for struct hostent_data],
 855         [libjava_cv_struct_hostent_data], [dnl
 856         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 857 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 858 # define _REENTRANT 1
 859 #endif
 860 #include <netdb.h>]], [[struct hostent_data data;]])],
 861           [libjava_cv_struct_hostent_data=yes],
 862           [libjava_cv_struct_hostent_data=no])])
 863      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 864        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 865          [Define if struct hostent_data is defined in netdb.h])
 866      fi
 867    ])
 868
 869    # FIXME: libjava source code expects to find a prototype for
 870    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 871    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 872    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 873    # linkage check is enough, yet C++ code requires proper prototypes.)
 874    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 875    AC_CHECK_FUNCS(gethostbyaddr_r, [
 876      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 877        [Define if you have the 'gethostbyaddr_r' function.])
 878      # There are two different kinds of gethostbyaddr_r.
 879      # We look for the one that returns `int'.
 880      # Hopefully this check is robust enough.
 881      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 882        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 883          [Define if gethostbyaddr_r returns 'int'.])])])])
 884
 885    AC_CHECK_FUNCS(gethostname, [
 886      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 887        [Define if you have the 'gethostname' function.])
 888      AC_EGREP_HEADER(gethostname, unistd.h, [
 889        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 890          [Define if gethostname is declared in <unistd.h>.])])])
 891
 892    AC_CHECK_FUNCS(usleep, [
 893      AC_EGREP_HEADER(usleep, unistd.h, [
 894        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 895           [Define if usleep is declared in <unistd.h>.])])])
 896
 897    # Look for these functions in the thread library, but only bother
 898    # if using POSIX threads.
 899    if test "$THREADS" = posix; then
 900       save_LIBS="$LIBS"
 901       LIBS="$LIBS $THREADLIBS"
 902       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 903       # E.g., Solaris.
 904       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 905
 906       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 907       # Solaris 7 the name librt is preferred.
 908       AC_CHECK_FUNCS(sched_yield, , [
 909         AC_CHECK_LIB(rt, sched_yield, [
 910           AC_DEFINE(HAVE_SCHED_YIELD)
 911           THREADLIBS="$THREADLIBS -lrt"
 912           THREADSPEC="$THREADSPEC -lrt"], [
 913           AC_CHECK_LIB(posix4, sched_yield, [
 914             AC_DEFINE(HAVE_SCHED_YIELD)
 915             THREADLIBS="$THREADLIBS -lposix4"
 916             THREADSPEC="$THREADSPEC -lposix4"])])])
 917       LIBS="$save_LIBS"
 918
 919       # We can save a little space at runtime if the mutex has m_count
 920       # or __m_count.  This is a nice hack for Linux.
 921       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 922           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 923         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 924              [Define if pthread_mutex_t has m_count member.]), [
 925         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 926             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 927           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 928             [Define if pthread_mutex_t has __m_count member.]))])
 929    fi
 930
 931    # We require a way to get the time.
 932    time_found=no
 933    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 934    if test "$time_found" = no; then
 935       AC_MSG_ERROR([no function found to get the time])
 936    fi
 937
 938    AC_CHECK_FUNCS(memmove)
 939
 940    # We require memcpy.
 941    memcpy_found=no
 942    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 943    if test "$memcpy_found" = no; then
 944       AC_MSG_ERROR([memcpy is required])
 945    fi
 946
 947    AC_CHECK_LIB(dl, dlopen, [
 948        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 949
 950    # Some library-finding code we stole from Tcl.
 951    #--------------------------------------------------------------------
 952    #    Check for the existence of the -lsocket and -lnsl libraries.
 953    #    The order here is important, so that they end up in the right
 954    #    order in the command line generated by make.  Here are some
 955    #    special considerations:
 956    #    1. Use "connect" and "accept" to check for -lsocket, and
 957    #       "gethostbyname" to check for -lnsl.
 958    #    2. Use each function name only once:  can't redo a check because
 959    #       autoconf caches the results of the last check and won't redo it.
 960    #    3. Use -lnsl and -lsocket only if they supply procedures that
 961    #       aren't already present in the normal libraries.  This is because
 962    #       IRIX 5.2 has libraries, but they aren't needed and they're
 963    #       bogus:  they goof up name resolution if used.
 964    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 965    #       To get around this problem, check for both libraries together
 966    #       if -lsocket doesn't work by itself.
 967    #--------------------------------------------------------------------
 968
 969    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 970     [gcj_cv_lib_sockets=
 971      gcj_checkBoth=0
 972      unset ac_cv_func_connect
 973      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 974      if test "$gcj_checkSocket" = 1; then
 975          unset ac_cv_func_connect
 976          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 977                       gcj_checkBoth=1)
 978      fi
 979      if test "$gcj_checkBoth" = 1; then
 980          gcj_oldLibs=$LIBS
 981          LIBS="$LIBS -lsocket -lnsl"
 982          unset ac_cv_func_accept
 983          AC_CHECK_FUNC(accept,
 984                        [gcj_checkNsl=0
 985                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 986          unset ac_cv_func_accept
 987          LIBS=$gcj_oldLibs
 988      fi
 989      unset ac_cv_func_gethostbyname
 990      gcj_oldLibs=$LIBS
 991      LIBS="$LIBS $gcj_cv_lib_sockets"
 992      AC_CHECK_FUNC(gethostbyname, ,
 993                    [AC_CHECK_LIB(nsl, main,
 994                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 995      unset ac_cv_func_gethostbyname
 996      LIBS=$gcj_oldLIBS
 997    ])
 998    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 999
1000    if test "$with_system_zlib" = yes; then
1001       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1002    fi
1003
1004    # Test for Gtk stuff, if asked for.
1005    if test "$use_gtk_awt" = yes; then
1006       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1007       AC_SUBST(GTK_CFLAGS)
1008       AC_SUBST(GTK_LIBS)
1009
1010       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1011       AC_SUBST(GLIB_CFLAGS)
1012       AC_SUBST(GLIB_LIBS)
1013
1014       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1015       AC_SUBST(LIBART_CFLAGS)
1016       AC_SUBST(LIBART_LIBS)
1017    fi
1018
1019    # On Solaris, and maybe other architectures, the Boehm collector
1020    # requires -ldl.
1021    if test "$GC" = boehm; then
1022       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1023    fi
1024 fi
1025 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1026
1027 if test -z "${with_multisubdir}"; then
1028    builddotdot=.
1029 else
1030    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1031 fi
1032
1033 NATIVE=yes
1034
1035 # Which gcj do we use?
1036 which_gcj=default
1037 built_gcc_dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
1038 if test -n "${with_cross_host}"; then
1039   # We are being configured with a cross compiler. We can't
1040   # use ac_exeext, because that is for the target platform.
1041   NATIVE=no
1042   cross_host_exeext=
1043   case "${with_cross_host}" in
1044      *mingw* | *cygwin*)
1045          cross_host_exeext=.exe
1046      ;;
1047   esac
1048   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1049      if test x"$build_noncanonical" = x"$with_cross_host"; then
1050         # Ordinary cross (host!=target and host=build)
1051         which_gcj=built
1052      else
1053         # Canadian cross (host!=target and host!=build)
1054         which_gcj=cross
1055      fi
1056   else
1057      which_gcj=cross
1058   fi
1059 else
1060   # We are being configured with a native or crossed-native compiler
1061   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1062      if test x"$build" = x"$host"; then
1063         # True native build (host=target and host=build)
1064         which_gcj=built
1065      else
1066         # Crossed-native build (host=target and host!=build)
1067         which_gcj=cross
1068      fi
1069   else
1070      which_gcj=path
1071   fi
1072 fi
1073 case "${which_gcj}" in
1074    built)
1075       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1076       GCJH='$(MULTIBUILDTOP)../$(COMPPATH)/gcc/gcjh'
1077       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1078    ;;
1079    cross)
1080       if test "x${with_newlib}" = "xyes"; then
1081          # FIXME (comment): Why is this needed?
1082          GCC_UNWIND_INCLUDE=
1083          GCJ="${target_noncanonical}-gcj"
1084       else
1085          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1086       fi
1087       ZIP=jar
1088       GCJH='$(target_noncanonical)-gcjh'
1089    ;;
1090    path)
1091       GCJ="gcj -B`${PWDCMD-pwd}`/"
1092       ## In this case, gcj is found outside the build tree.  However, zip is
1093       ## found in the build tree.
1094       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1095       GCJH=gcjh
1096    ;;
1097 esac
1098
1099 AC_SUBST(GCJH)
1100 AC_SUBST(ZIP)
1101
1102 # Create it, so that compile/link tests don't fail
1103 test -f libgcj.spec || touch libgcj.spec
1104
1105 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1106 case $build in
1107     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1108     *)         CLASSPATH_SEPARATOR=':' ;;
1109 esac
1110 AC_SUBST(CLASSPATH_SEPARATOR)
1111
1112 # We must search the source tree for java.lang, since we still don't
1113 # have libgcj.jar nor java/lang/*.class
1114 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1115 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1116
1117 # Since some classes depend on this one, we need its source available
1118 # before we can do any GCJ compilation test :-(
1119 if test ! -f gnu/classpath/Configuration.java; then
1120   test -d gnu || mkdir gnu
1121   test -d gnu/classpath || mkdir gnu/classpath
1122   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1123       -e 's,@TOOLKIT@,$TOOLKIT,' \
1124         < $srcdir/gnu/classpath/Configuration.java.in \
1125         > gnu/classpath/Configuration.java
1126   # We do not want to redirect the output of the grep below to /dev/null,
1127   # but we add /dev/null to the input list so that grep will print the
1128   # filename of Configuration.java in case it finds any matches.
1129   if grep @ gnu/classpath/Configuration.java /dev/null; then
1130     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1131   fi
1132 fi
1133
1134 LT_AC_PROG_GCJ
1135
1136 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1137
1138 AC_COMPILE_CHECK_SIZEOF(void *)
1139
1140 AC_C_BIGENDIAN_CROSS
1141
1142 ZLIBS=
1143 SYS_ZLIBS=
1144 ZINCS=
1145
1146 if test -z "$ZLIBSPEC"; then
1147    # Use zlib from the GCC tree.
1148    ZINCS='-I$(top_srcdir)/../zlib'
1149    ZLIBS=../zlib/libzgcj_convenience.la
1150 else
1151    # System's zlib.
1152    SYS_ZLIBS="$ZLIBSPEC"
1153 fi
1154 AC_SUBST(ZLIBS)
1155 AC_SUBST(SYS_ZLIBS)
1156 AC_SUBST(ZINCS)
1157 AC_SUBST(DIVIDESPEC)
1158 AC_SUBST(CHECKREFSPEC)
1159 AC_SUBST(EXCEPTIONSPEC)
1160 AC_SUBST(IEEESPEC)
1161
1162 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1163 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1164 AC_SUBST(GCC_UNWIND_INCLUDE)
1165
1166 # Process the option "--enable-version-specific-runtime-libs"
1167 # Calculate toolexeclibdir
1168 case ${version_specific_libs} in
1169   yes)
1170     # Need the gcc compiler version to know where to install libraries
1171     # and header files if --enable-version-specific-runtime-libs option
1172     # is selected.
1173     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1174     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1175     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1176     toolexeclibdir=$toolexecmainlibdir
1177     ;;
1178   no)
1179     if test -n "$with_cross_host" &&
1180        test x"$with_cross_host" != x"no"; then
1181       # Install a library built with a cross compiler in tooldir, not libdir.
1182       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1183       toolexecmainlibdir='$(toolexecdir)/lib'
1184     else
1185       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1186       toolexecmainlibdir='$(libdir)'
1187     fi
1188     multi_os_directory=`$CC -print-multi-os-directory`
1189     case $multi_os_directory in
1190       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1191       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1192     esac
1193     ;;
1194 esac
1195 AC_SUBST(toolexecdir)
1196 AC_SUBST(toolexecmainlibdir)
1197 AC_SUBST(toolexeclibdir)
1198
1199 # Determine gcj version number.
1200 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1201 GCJVERSION=$gcjversion
1202 AC_SUBST(GCJVERSION)
1203 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1204
1205 TL_AC_GXX_INCLUDE_DIR
1206
1207 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1208 # On that system, sys/ioctl.h will not include sys/filio.h unless
1209 # BSD_COMP is defined; just including sys/filio.h is simpler.
1210 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
1211 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1212 # for now.  If you change this, you also must update natFile.cc.
1213 AC_CHECK_HEADERS(dirent.h)
1214 AC_CHECK_HEADERS(inttypes.h, [
1215     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1216     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1217 ])
1218 AC_HEADER_SYS_WAIT
1219
1220 AC_CHECK_TYPE([ssize_t], [int])
1221
1222 AC_MSG_CHECKING([for in_addr_t])
1223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1224 #if STDC_HEADERS
1225 #include <stdlib.h>
1226 #include <stddef.h>
1227 #endif
1228 #if HAVE_NETINET_IN_H
1229 #include <netinet/in.h>
1230 #endif]], [[in_addr_t foo;]])],
1231   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1232      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1233    AC_MSG_RESULT(yes)],
1234   [AC_MSG_RESULT(no)])
1235
1236 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1237 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1238   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1239      [Define if struct ip_mreq is defined in netinet/in.h.])
1240    AC_MSG_RESULT(yes)],
1241   [AC_MSG_RESULT(no)])
1242
1243 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1244 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1245   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1246      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1247    AC_MSG_RESULT(yes)],
1248   [AC_MSG_RESULT(no)])
1249
1250 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1252   [AC_DEFINE(HAVE_INET6, 1,
1253      [Define if inet6 structures are defined in netinet/in.h.])
1254    AC_MSG_RESULT(yes)],
1255   [AC_MSG_RESULT(no)])
1256
1257 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1258 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1259 #include <sys/types.h>
1260 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1261   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1262    AC_MSG_RESULT(yes)],
1263   [AC_MSG_RESULT(no)])
1264
1265 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1266 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1267   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1268    AC_MSG_RESULT(yes)],
1269   [AC_MSG_RESULT(no)
1270    AC_MSG_CHECKING([for global timezone variable])
1271    dnl FIXME: we don't want a link check here because that won't work
1272    dnl when cross-compiling.  So instead we make an assumption that
1273    dnl the header file will mention timezone if it exists.
1274    dnl Don't find the win32 function timezone
1275    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1276      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1277       AC_MSG_RESULT(yes)],
1278      [AC_MSG_RESULT(no)
1279        AC_MSG_CHECKING([for global _timezone variable])
1280        dnl FIXME: As above, don't want link check
1281        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1282          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1283             [Define if your platform has the global _timezone variable.])
1284           AC_MSG_RESULT(yes)],
1285           [AC_MSG_RESULT(no)])])])
1286
1287 AC_FUNC_ALLOCA
1288 AC_FUNC_MMAP
1289
1290 AC_CHECK_PROGS(PERL, perl, false)
1291
1292 SYSDEP_SOURCES=
1293 SIGNAL_HANDLER_AUX=
1294
1295 case "${host}" in
1296  i?86-*-linux*)
1297     SIGNAL_HANDLER=include/i386-signal.h
1298     ;;
1299  sparc*-sun-solaris*)
1300     SIGNAL_HANDLER=include/sparc-signal.h
1301     ;;
1302 # ia64-*)
1303 #    SYSDEP_SOURCES=sysdep/ia64.c
1304 #    test -d sysdep || mkdir sysdep
1305 #    ;;
1306  hppa*-*-linux*)
1307     SIGNAL_HANDLER=include/pa-signal.h
1308     ;;
1309  ia64-*-linux*)
1310     SIGNAL_HANDLER=include/dwarf2-signal.h
1311     ;;
1312  powerpc*-*-linux*)
1313     SIGNAL_HANDLER=include/powerpc-signal.h
1314     ;;
1315  alpha*-*-linux*)
1316     SIGNAL_HANDLER=include/dwarf2-signal.h
1317     ;;
1318  s390*-*-linux*)
1319     SIGNAL_HANDLER=include/s390-signal.h
1320     ;;
1321  x86_64*-*-linux*)
1322     SIGNAL_HANDLER=include/x86_64-signal.h
1323     SIGNAL_HANDLER_AUX=include/i386-signal.h
1324     ;;
1325  sparc*-*-linux*)
1326     SIGNAL_HANDLER=include/dwarf2-signal.h
1327     ;;
1328  sh*-*-linux*)
1329     SIGNAL_HANDLER=include/sh-signal.h
1330     ;;
1331  *mingw*)
1332     SIGNAL_HANDLER=include/win32-signal.h
1333     ;;
1334  mips*-*-linux*)
1335     SIGNAL_HANDLER=include/mips-signal.h
1336     ;;
1337  *-*-darwin*)
1338     SIGNAL_HANDLER=include/darwin-signal.h
1339     ;;
1340  *)
1341     SIGNAL_HANDLER=include/default-signal.h
1342     ;;
1343 esac
1344
1345 # If we're using sjlj exceptions, forget what we just learned.
1346 if test "$enable_sjlj_exceptions" = yes; then
1347    SIGNAL_HANDLER=include/default-signal.h
1348    SIGNAL_HANDLER_AUX=
1349 fi
1350
1351 # Define here any compiler flags that you need in order to make backtrace() work.
1352 BACKTRACESPEC=
1353 case "${host}" in
1354  x86_64*-*-linux*|i?86-*)
1355     BACKTRACESPEC=-fno-omit-frame-pointer
1356     ;;
1357 esac
1358 AC_SUBST(BACKTRACESPEC)
1359
1360 AC_SUBST(SYSDEP_SOURCES)
1361
1362 if test -z "$SIGNAL_HANDLER_AUX"; then
1363   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1364 fi
1365
1366 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1367                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1368
1369 if test "${multilib}" = "yes"; then
1370   multilib_arg="--enable-multilib"
1371 else
1372   multilib_arg=
1373 fi
1374
1375
1376
1377 here=`${PWDCMD-pwd}`
1378 AC_SUBST(here)
1379
1380 # We get this from the environment.
1381 AC_SUBST(GCJFLAGS)
1382
1383 AC_CONFIG_FILES([
1384 Makefile
1385 libgcj.pc
1386 libgcj.spec
1387 libgcj-test.spec
1388 gnu/classpath/Configuration.java
1389 gcj/Makefile
1390 include/Makefile
1391 testsuite/Makefile
1392 ])
1393
1394 AC_CONFIG_COMMANDS([default],
1395 [# Only add multilib support code if we just rebuilt top-level Makefile.
1396 case " $CONFIG_FILES " in
1397  *" Makefile "*)
1398    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1399    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1400    ;;
1401 esac
1402 ],
1403 srcdir=${srcdir}
1404 host=${host}
1405 target=${target}
1406 with_multisubdir=${with_multisubdir}
1407 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1408 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1409 libgcj_basedir=${libgcj_basedir}
1410 CC="${CC}"
1411 CXX="${CXX}"
1412 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1413 )
1414
1415 AC_OUTPUT