libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 146
 147
 148 # See if the user has requested runtime debugging.
 149 LIBGCJDEBUG="disable"
 150 AC_SUBST(LIBGCJDEBUG)
 151 AC_ARG_ENABLE(libgcj-debug,
 152   AS_HELP_STRING([--enable-libgcj-debug],
 153                  [enable runtime debugging code]),
 154   [if test "$enable_libgcj_debug" = yes; then
 155     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 156     LIBGCJDEBUG="enable"
 157   fi])
 158
 159 # Determine which AWT peer libraries to build
 160 AC_ARG_ENABLE(java-awt,
 161   AS_HELP_STRING([--enable-java-awt],
 162                  [list of AWT peer implementations to be built]))
 163
 164 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 165 use_xlib_awt=""
 166 use_gtk_awt=""
 167 # The default toolkit to use is the first one specified.
 168 TOOLKIT=
 169 AC_SUBST(TOOLKIT)
 170
 171 for peer in $peerlibs ; do
 172   case $peer in
 173     xlib)
 174       if test "$no_x" = yes; then
 175         echo "*** xlib peers requested but no X library available" 1>&2
 176         exit 1
 177       else
 178         # This code has bit-rotted a bit.
 179         echo "*** xlib peers can't currently be compiled -- disabling" 1>&2
 180 #        use_xlib_awt="yes"
 181 #       if test -z "$TOOLKIT"; then
 182 #          TOOLKIT=gnu.awt.xlib.XToolkit
 183 #       fi
 184       fi
 185       ;;
 186     gtk)
 187       if test "$no_x" = yes; then
 188          echo "*** xlib peers requested but no X library available" 1>&2
 189          exit 1
 190       else
 191          use_gtk_awt=yes
 192          if test -z "$TOOLKIT"; then
 193             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 194          fi
 195       fi
 196       ;;
 197     no)
 198       use_xlib_awt=
 199       use_gtk_awt=
 200       break
 201       ;;
 202     *)
 203       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 204       exit 1
 205   esac
 206 done
 207
 208 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 209 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 210
 211
 212 if test -z "${with_multisubdir}"; then
 213    builddotdot=.
 214 else
 215    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 216 fi
 217
 218 NATIVE=yes
 219
 220 # Which gcj do we use?
 221 which_gcj=default
 222 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 223 if test -n "${with_cross_host}"; then
 224   # We are being configured with a cross compiler. We can't
 225   # use ac_exeext, because that is for the target platform.
 226   NATIVE=no
 227   cross_host_exeext=
 228   case "${with_cross_host}" in
 229      *mingw* | *cygwin*)
 230          cross_host_exeext=.exe
 231      ;;
 232   esac
 233   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 234      if test x"$build_noncanonical" = x"$with_cross_host"; then
 235         # Ordinary cross (host!=target and host=build)
 236         which_gcj=built
 237      else
 238         # Canadian cross (host!=target and host!=build)
 239         which_gcj=cross
 240      fi
 241   else
 242      which_gcj=cross
 243   fi
 244 else
 245   # We are being configured with a native or crossed-native compiler
 246   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 247      if test x"$build" = x"$host"; then
 248         # True native build (host=target and host=build)
 249         which_gcj=built
 250      else
 251         # Crossed-native build (host=target and host!=build)
 252         which_gcj=cross
 253      fi
 254   else
 255      which_gcj=path
 256   fi
 257 fi
 258 case "${which_gcj}" in
 259    built)
 260       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 261       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 262       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 263    ;;
 264    cross)
 265       if test "x${with_newlib}" = "xyes"; then
 266          # FIXME (comment): Why is this needed?
 267          GCC_UNWIND_INCLUDE=
 268          GCJ="${target_noncanonical}-gcj"
 269       else
 270          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 271       fi
 272       ZIP='$(target_noncanonical)-fastjar'
 273       GCJH='$(target_noncanonical)-gcjh'
 274    ;;
 275    path)
 276       GCJ="gcj -B`${PWDCMD-pwd}`/"
 277       ## In this case, gcj is found outside the build tree.  However, zip is
 278       ## found in the build tree.
 279       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 280       GCJH=gcjh
 281    ;;
 282 esac
 283
 284 AC_SUBST(GCJH)
 285 AC_SUBST(ZIP)
 286
 287 # Create it, so that compile/link tests don't fail
 288 test -f libgcj.spec || touch libgcj.spec
 289
 290
 291
 292 # Set up to configure Classpath.
 293 # FIXME: no supported way to pass args in autoconf.
 294 ac_configure_args="$ac_configure_args --disable-load-library"
 295 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 296 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 297 dir1=`cd $srcdir && pwd`
 298 dir2=`pwd`
 299 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 300 ac_configure_args="$ac_configure_args --disable-core-jni"
 301 dnl FIXME?
 302 ac_configure_args="$ac_configure_args --disable-examples"
 303 ac_configure_args="$ac_configure_args --with-glibj=build"
 304 if test "$use_gtk_awt" != yes; then
 305   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 306 fi
 307 dnl --with-gcj=$GCJ
 308 dnl --with-javah=$GCJH
 309 dnl gjdoc?
 310 dnl gtk-cairo -- just export here...
 311 dnl --enable-regen-headers?
 312
 313 # Only use libltdl for non-newlib builds.
 314 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 315    AC_LIBLTDL_CONVENIENCE
 316    AC_LIBTOOL_DLOPEN
 317    DIRLTDL=libltdl
 318    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 319    # Sigh.  Libtool's macro doesn't do the right thing.
 320    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 321    # FIXME: this is a hack.
 322    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 323    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 324 fi
 325 AC_SUBST(INCLTDL)
 326 AC_SUBST(LIBLTDL)
 327 AC_SUBST(DIRLTDL)
 328 AC_PROG_LIBTOOL
 329 AM_PROG_GCJ
 330 AM_PROG_CC_C_O
 331
 332 AC_CONFIG_SUBDIRS(classpath libltdl)
 333
 334 # The -no-testsuite modules omit the test subdir.
 335 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 336
 337 # Should the runtime set system properties by examining the
 338 # environment variable GCJ_PROPERTIES?
 339 AC_ARG_ENABLE(getenv-properties,
 340   AS_HELP_STRING([--disable-getenv-properties],
 341                  [don't set system properties from GCJ_PROPERTIES]))
 342
 343 # Whether GCJ_PROPERTIES is used depends on the target.
 344 if test -z "$enable_getenv_properties"; then
 345    enable_getenv_properties=${enable_getenv_properties_default-yes}
 346 fi
 347 if test "$enable_getenv_properties" = no; then
 348    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 349      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 350 fi
 351
 352 # Whether we should use arguments to main()
 353 if test -z "$enable_main_args"; then
 354    enable_main_args=${enable_main_args_default-yes}
 355 fi
 356 if test "$enable_main_args" = no; then
 357    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 358 fi
 359
 360
 361 # Should we use hashtable-based synchronization?
 362 # Currently works only for Linux X86/ia64
 363 # Typically faster and more space-efficient
 364 AC_ARG_ENABLE(hash-synchronization,
 365   AS_HELP_STRING([--enable-hash-synchronization],
 366                  [use global hash table for monitor locks]))
 367
 368 if test -z "$enable_hash_synchronization"; then
 369    enable_hash_synchronization=$enable_hash_synchronization_default
 370 fi
 371
 372 AC_ARG_WITH(java-home,
 373   AS_HELP_STRING([--with-java-home=DIRECTORY],
 374                  [value of java.home system property]),
 375                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 376 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 377 AC_SUBST(JAVA_HOME)
 378
 379 # What is the native OS API for MinGW?
 380 AC_ARG_WITH(win32-nlsapi,
 381   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 382                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 383 [case "${withval}" in
 384   ansi) with_win32_nlsapi=ansi ;;
 385   unicows) with_win32_nlsapi=unicows ;;
 386   unicode) with_win32_nlsapi=unicode ;;
 387   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 388 esac],[with_win32_nlsapi=ansi])
 389
 390 case "${with_win32_nlsapi}" in
 391   unicows | unicode)
 392     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 393       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 394     ;;
 395 esac
 396
 397 # configure.host sets slow_pthread_self if the synchronization code should
 398 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 399 if test "${slow_pthread_self}" = "yes"; then
 400   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 401     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 402 fi
 403
 404 # Check for gc debugging.  This option is handled both here and in the GC.
 405 AC_ARG_ENABLE(gc-debug,
 406    AS_HELP_STRING([--enable-gc-debug],
 407                   [include full support for pointer backtracing etc.]),
 408 [ if test "$enable_gc_debug" = "yes"; then
 409     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 410               [Define if we want to use debug calls into the garbage collector.])
 411   fi])
 412
 413 # See if the user has the interpreter included.
 414 AC_ARG_ENABLE(interpreter,
 415   AS_HELP_STRING([--enable-interpreter],
 416                  [enable interpreter]),
 417   [if test "$enable_interpreter" = yes; then
 418     # This can also be set in configure.host.
 419     libgcj_interpreter=yes
 420   elif test "$enable_interpreter" = no; then
 421     libgcj_interpreter=no
 422   fi])
 423
 424 if test "$libgcj_interpreter" = yes; then
 425    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 426 fi
 427 INTERPRETER="$libgcj_interpreter"
 428 AC_SUBST(INTERPRETER)
 429
 430 AC_MSG_CHECKING([for exception model to use])
 431 AC_LANG_PUSH(C++)
 432 AC_ARG_ENABLE(sjlj-exceptions,
 433   AS_HELP_STRING([--enable-sjlj-exceptions],
 434                  [force use of builtin_setjmp for exceptions]),
 435 [:],
 436 [dnl Botheration.  Now we've got to detect the exception model.
 437 dnl Link tests against libgcc.a are problematic since -- at least
 438 dnl as of this writing -- we've not been given proper -L bits for
 439 dnl single-tree newlib and libgloss.
 440 dnl
 441 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 442 dnl conftest files before we got a change to grep them first.
 443 cat > conftest.$ac_ext << EOF
 444 [#]line __oline__ "configure"
 445 struct S { ~S(); };
 446 void bar();
 447 void foo()
 448 {
 449   S s;
 450   bar();
 451 }
 452 EOF
 453 old_CXXFLAGS="$CXXFLAGS"
 454 CXXFLAGS=-S
 455 if AC_TRY_EVAL(ac_compile); then
 456   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 457     enable_sjlj_exceptions=yes
 458   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 459     enable_sjlj_exceptions=no
 460   fi
 461 fi
 462 CXXFLAGS="$old_CXXFLAGS"
 463 rm -f conftest*])
 464 if test x$enable_sjlj_exceptions = xyes; then
 465   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 466         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 467   ac_exception_model_name=sjlj
 468 elif test x$enable_sjlj_exceptions = xno; then
 469   ac_exception_model_name="call frame"
 470 else
 471   AC_MSG_ERROR([unable to detect exception model])
 472 fi
 473 AC_LANG_POP(C++)
 474 AC_MSG_RESULT($ac_exception_model_name)
 475
 476 # If we are non using SJLJ exceptions, and this host does not have support
 477 # for unwinding from a signal handler, enable checked dereferences and divides.
 478 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 479   CHECKREFSPEC=-fcheck-references
 480   DIVIDESPEC=-fuse-divide-subroutine
 481   EXCEPTIONSPEC=
 482 fi
 483
 484 # See if the user wants to disable java.net.  This is the mildly
 485 # ugly way that we admit that target-side configuration sucks.
 486 AC_ARG_ENABLE(java-net,
 487   AS_HELP_STRING([--disable-java-net],
 488                  [disable java.net]))
 489
 490 # Whether java.net is built by default can depend on the target.
 491 if test -z "$enable_java_net"; then
 492    enable_java_net=${enable_java_net_default-yes}
 493 fi
 494 if test "$enable_java_net" = no; then
 495    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 496 fi
 497
 498 # See if the user wants to configure without libffi.  Some
 499 # architectures don't support it, and default values are set in
 500 # configure.host.
 501 AC_ARG_WITH(libffi,
 502   AS_HELP_STRING([--without-libffi],
 503                  [don't use libffi]),
 504   [:],
 505   [with_libffi=${with_libffi_default-yes}])
 506
 507 LIBFFI=
 508 LIBFFIINCS=
 509 if test "$with_libffi" != no; then
 510    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 511    LIBFFI=../libffi/libffi_convenience.la
 512    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 513 fi
 514 AC_SUBST(LIBFFI)
 515 AC_SUBST(LIBFFIINCS)
 516
 517 # See if the user wants to disable JVMPI support.
 518 AC_ARG_ENABLE(jvmpi,
 519   AS_HELP_STRING([--disable-jvmpi],
 520                  [disable JVMPI support]))
 521
 522 if test "$enable_jvmpi" != no; then
 523     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 524 fi
 525
 526 # If the target is an eCos system, use the appropriate eCos
 527 # I/O routines.
 528 # FIXME: this should not be a local option but a global target
 529 # system; at present there is no eCos target.
 530 TARGET_ECOS=${PROCESS-"no"}
 531 AC_ARG_WITH(ecos,
 532 [  --with-ecos             enable runtime eCos target support],
 533 TARGET_ECOS="$with_ecos"
 534 )
 535
 536 supply_backtrace=no
 537
 538 PLATFORM_INNER_NAT_HDRS=
 539 case "$TARGET_ECOS" in
 540    no) case "$host" in
 541       *mingw*)
 542             PLATFORM=Win32
 543             PLATFORMNET=Win32
 544             PLATFORMH=win32.h
 545         CHECK_FOR_BROKEN_MINGW_LD
 546       ;;
 547       *)
 548             PLATFORM=Posix
 549             PLATFORMNET=Posix
 550             PLATFORMH=posix.h
 551             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 552       ;;
 553       esac
 554       ;;
 555    *)
 556       PLATFORM=Ecos
 557       PLATFORMNET=NoNet
 558       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 559       PLATFORMH=posix.h
 560       ;;
 561 esac
 562 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 563 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 564
 565 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 566                                       [Define if you have int32_t and uint32_t.]))
 567 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 568                                         [Define if you have int32_t and uint32_t.]))
 569 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 570                                           [Define if you have u_int32_t]))
 571 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 572                                            [Define if you have u_int32_t]))
 573
 574 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 575 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 576
 577 case "$host" in
 578   *-darwin*) DARWIN_CRT=true ;;
 579   *) DARWIN_CRT=false ;;
 580 esac
 581 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 582
 583 # These may not be defined in a non-ANS conformant embedded system.
 584 # FIXME: Should these case a runtime exception in that case?
 585 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 586                                   [Define is you have 'mktime' in <time.h>]))
 587 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 588                                   [Define is you have 'localtime' in <time.h>]))
 589
 590 # Create the subdirectory for natFile.cc, or the attempt
 591 # to create the link will fail.
 592 test -d java || mkdir java
 593 test -d java/io || mkdir java/io
 594 test -d gnu || mkdir gnu
 595 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 596
 597 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 598 test -d java/lang || mkdir java/lang
 599 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 600 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 601
 602 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 603 test -d java/net || mkdir java/net
 604 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 605 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 606
 607 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 608 test -d gnu/java || mkdir gnu/java
 609 test -d gnu/java/net || mkdir gnu/java/net
 610 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 611 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 612
 613 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 614 test -d gnu/java/nio || mkdir gnu/java/nio
 615 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 616 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 617 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 618 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 619
 620 case "${host}" in
 621     *mingw*)
 622       SYSTEMSPEC="-lgdi32 -lws2_32"
 623       if test "${with_win32_nlsapi}" = "unicows"; then
 624         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 625       fi
 626     ;;
 627     *)
 628       SYSTEMSPEC=
 629     ;;
 630 esac
 631 AC_SUBST(SYSTEMSPEC)
 632
 633 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 634 AC_SUBST(LIBGCJTESTSPEC)
 635
 636 AC_ARG_WITH(system-zlib,
 637   AS_HELP_STRING([--with-system-zlib],
 638                  [use installed libz]))
 639 ZLIBSPEC=
 640 AC_SUBST(ZLIBSPEC)
 641 ZLIBTESTSPEC=
 642 AC_SUBST(ZLIBTESTSPEC)
 643
 644 AC_PATH_XTRA
 645
 646 # determine whether to enable the cairo GTK Graphics2D backend
 647 AC_ARG_ENABLE(gtk-cairo,
 648   AS_HELP_STRING([--enable-gtk-cairo],
 649                  [build the cairo Graphics2D implementation on GTK]))
 650 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 651 if test "x${enable_gtk_cairo}" = xyes
 652 then
 653         PKG_CHECK_MODULES(CAIRO, cairo)
 654         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 655 fi
 656 AC_SUBST(CAIRO_LIBS)
 657 AC_SUBST(CAIRO_CFLAGS)
 658 AC_SUBST(PANGOFT2_LIBS)
 659 AC_SUBST(PANGOFT2_CFLAGS)
 660
 661 # FIXME: this should be _libs on some hosts.
 662 libsubdir=.libs
 663
 664 # Allow the GC to be disabled.  Can be useful when debugging.
 665 AC_MSG_CHECKING([for garbage collector to use])
 666 AC_ARG_ENABLE(java-gc,
 667   AS_HELP_STRING([--enable-java-gc=TYPE],
 668                  [choose garbage collector (default is boehm)]),
 669   [GC=$enableval],
 670   [GC=boehm])
 671 GCLIBS=
 672 GCINCS=
 673 GCDEPS=
 674 GCSPEC=
 675 JC1GCSPEC=
 676 GCTESTSPEC=
 677 case "$GC" in
 678  boehm)
 679     AC_MSG_RESULT(boehm)
 680     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 681     JC1GCSPEC='-fuse-boehm-gc'
 682     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 683     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 684     GCOBJS=boehm.lo
 685     GCHDR=boehm-gc.h
 686     # The POSIX thread support needs to know this.
 687     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 688     ;;
 689  no)
 690     AC_MSG_RESULT(none)
 691     GCHDR=no-gc.h
 692     ;;
 693  *)
 694     AC_MSG_ERROR([unrecognized collector "$GC"])
 695     ;;
 696 esac
 697 AC_SUBST(GCLIBS)
 698 AC_SUBST(GCINCS)
 699 AC_SUBST(GCDEPS)
 700 AC_SUBST(GCSPEC)
 701 AC_SUBST(JC1GCSPEC)
 702 AC_SUBST(GCTESTSPEC)
 703 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 704 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 705 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 706
 707
 708 AC_MSG_CHECKING([for thread model used by GCC])
 709 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 710 AC_MSG_RESULT([$THREADS])
 711
 712 case "$THREADS" in
 713  no | none | single)
 714     THREADS=none
 715     ;;
 716  posix | posix95 | pthreads)
 717     THREADS=posix
 718     case "$host" in
 719      *-*-linux*)
 720         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 721         ;;
 722     esac
 723     ;;
 724  win32)
 725     ;;
 726  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 727     AC_MSG_ERROR(thread package $THREADS not yet supported)
 728     ;;
 729  *)
 730     AC_MSG_ERROR($THREADS is an unknown thread package)
 731     ;;
 732 esac
 733
 734 THREADCXXFLAGS=
 735 THREADLDFLAGS=
 736 THREADLIBS=
 737 THREADINCS=
 738 THREADDEPS=
 739 THREADH=
 740 THREADSPEC=
 741 case "$THREADS" in
 742  posix)
 743     case "$host" in
 744      *-*-cygwin*)
 745         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 746         ;;
 747      *-*-freebsd[[1234]]*)
 748         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 749         # merely adds pthread_* functions) but it does have a -pthread switch
 750         # which is required at link-time to select -lc_r *instead* of -lc.
 751         THREADLDFLAGS=-pthread
 752         # Don't set THREADSPEC here as might be expected since -pthread is
 753         # not processed when found within a spec file, it must come from
 754         # the command line.  For now, the user must provide the -pthread
 755         # switch to link code compiled with gcj.  In future, consider adding
 756         # support for weak references to pthread_* functions ala gthr.h API.
 757         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 758         ;;
 759      *-*-freebsd*)
 760         # FreeBSD 5 implements a model much closer to other modern UNIX
 761         # which support threads.  However, it still does not support
 762         # -lpthread.
 763         THREADLDFLAGS=-pthread
 764         THREADSPEC=-lc_r
 765         ;;
 766      alpha*-dec-osf*)
 767         THREADCXXFLAGS=-pthread
 768         # boehm-gc needs some functions from librt, so link that too.
 769         THREADLIBS='-lpthread -lrt'
 770         THREADSPEC='-lpthread -lrt'
 771         ;;
 772      *)
 773         THREADLIBS=-lpthread
 774         THREADSPEC=-lpthread
 775         ;;
 776     esac
 777     THREADH=posix-threads.h
 778     # MIT pthreads doesn't seem to have the mutexattr functions.
 779     # But for now we don't check for it.  We just assume you aren't
 780     # using MIT pthreads.
 781     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 782
 783     # If we're using the Boehm GC, then we happen to know that it
 784     # defines _REENTRANT, so we don't bother.  Eww.
 785     if test "$GC" != boehm; then
 786        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 787     fi
 788     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 789     ;;
 790
 791  win32)
 792     THREADH=win32-threads.h
 793     ;;
 794
 795  none)
 796     THREADH=no-threads.h
 797     ;;
 798 esac
 799 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 800 AC_SUBST(THREADLIBS)
 801 AC_SUBST(THREADINCS)
 802 AC_SUBST(THREADDEPS)
 803 AC_SUBST(THREADSPEC)
 804 AC_SUBST(THREADLDFLAGS)
 805 AC_SUBST(THREADCXXFLAGS)
 806 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 807 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 808 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 809
 810 if test -d sysdep; then true; else mkdir sysdep; fi
 811 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 812 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 813 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 814
 815 HASH_SYNC_SPEC=
 816 # Hash synchronization is only useful with posix threads right now.
 817 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 818    HASH_SYNC_SPEC=-fhash-synchronization
 819    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 820 fi
 821 AC_SUBST(HASH_SYNC_SPEC)
 822
 823 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 824
 825 # We're in the tree with gcc, and need to include some of its headers.
 826 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 827
 828 if test "x${with_newlib}" = "xyes"; then
 829    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 830    # may not work correctly, because the compiler may not be able to
 831    # link executables.
 832
 833    # We assume newlib.  This lets us hard-code the functions we know
 834    # we'll have.
 835    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 836    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 837    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 838    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 839    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 840    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 841    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 842    # This is only for POSIX threads.
 843    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 844    # We also assume we are using gcc, which provides alloca.
 845    AC_DEFINE(HAVE_ALLOCA)
 846
 847    # Assume we do not have getuid and friends.
 848    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 849    PLATFORMNET=NoNet
 850 else
 851    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 852                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 853                    access stat mkdir rename rmdir unlink realpath utime chmod \
 854                    nl_langinfo setlocale \
 855                    inet_pton uname inet_ntoa \
 856                    fork execvp pipe sigaction ftruncate])
 857    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 858    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 859    AC_CHECK_FUNC(backtrace, [
 860      case "$host" in
 861        ia64-*-linux*)
 862          # Has broken backtrace()
 863          ;;
 864        mips*-*-linux*)
 865          # Has broken backtrace(), but we supply our own.
 866          if test -d sysdep; then true; else mkdir -p sysdep; fi
 867          supply_backtrace=yes
 868          AC_DEFINE(HAVE_BACKTRACE, 1,
 869            [Define if your platform has a working backtrace() function.])
 870          ;;
 871        *)
 872          AC_DEFINE(HAVE_BACKTRACE, 1,
 873            [Define if your platform has a working backtrace() function.])
 874          ;;
 875      esac
 876    ], [
 877      case "$host" in
 878        *mingw*)
 879          # Has backtrace() defined in libgcj itself
 880          AC_DEFINE(HAVE_BACKTRACE, 1,
 881            [Define if your platform has a working backtrace() function.])
 882          ;;
 883      esac
 884    ])
 885
 886    AC_CHECK_LIB(dl, dladdr, [
 887      if test "x${disable_dladdr}" = "xyes"; then
 888        #Broken dladdr().
 889        true
 890      else
 891        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 892      fi
 893    ])
 894    if test x"$build" = x"$host"; then
 895      AC_CHECK_FILES(/proc/self/exe, [
 896        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 897    else
 898      case $host in
 899      *-linux*)
 900        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 901        ;;
 902      esac
 903    fi
 904
 905    AM_ICONV
 906    AM_LC_MESSAGES
 907    AC_STRUCT_TIMEZONE
 908
 909    AC_CHECK_FUNCS(gethostbyname_r, [
 910      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 911        [Define if you have the 'gethostbyname_r' function.])
 912      # There are two different kinds of gethostbyname_r.
 913      # We look for the one that returns `int'.
 914      # Hopefully this check is robust enough.
 915      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 916        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 917
 918      case " $GCINCS " in
 919      *" -D_REENTRANT "*) ;;
 920      *)
 921         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 922         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 923         [libjava_cv_gethostbyname_r_needs_reentrant],
 924         [ AC_LANG_PUSH(C++)
 925           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 926             [[gethostbyname_r("", 0, 0);]])],
 927             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 928                 CPPFLAGS_SAVE="$CPPFLAGS"
 929                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 930                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 931                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 932                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 933                 CPPFLAGS="$CPPFLAGS_SAVE"
 934           ])
 935           AC_LANG_POP(C++)
 936         ])
 937         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 938           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 939         fi
 940      ;;
 941      esac
 942
 943      AC_CACHE_CHECK([for struct hostent_data],
 944         [libjava_cv_struct_hostent_data], [dnl
 945         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 946 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 947 # define _REENTRANT 1
 948 #endif
 949 #include <netdb.h>]], [[struct hostent_data data;]])],
 950           [libjava_cv_struct_hostent_data=yes],
 951           [libjava_cv_struct_hostent_data=no])])
 952      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 953        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 954          [Define if struct hostent_data is defined in netdb.h])
 955      fi
 956    ])
 957
 958    # FIXME: libjava source code expects to find a prototype for
 959    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 960    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 961    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 962    # linkage check is enough, yet C++ code requires proper prototypes.)
 963    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 964    AC_CHECK_FUNCS(gethostbyaddr_r, [
 965      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 966        [Define if you have the 'gethostbyaddr_r' function.])
 967      # There are two different kinds of gethostbyaddr_r.
 968      # We look for the one that returns `int'.
 969      # Hopefully this check is robust enough.
 970      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 971        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 972          [Define if gethostbyaddr_r returns 'int'.])])])])
 973
 974    AC_CHECK_FUNCS(gethostname, [
 975      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 976        [Define if you have the 'gethostname' function.])
 977      AC_EGREP_HEADER(gethostname, unistd.h, [
 978        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 979          [Define if gethostname is declared in <unistd.h>.])])])
 980
 981    AC_CHECK_FUNCS(usleep, [
 982      AC_EGREP_HEADER(usleep, unistd.h, [
 983        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 984           [Define if usleep is declared in <unistd.h>.])])])
 985
 986    # Look for these functions in the thread library, but only bother
 987    # if using POSIX threads.
 988    if test "$THREADS" = posix; then
 989       save_LIBS="$LIBS"
 990       LIBS="$LIBS $THREADLIBS"
 991       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 992       # E.g., Solaris.
 993       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 994
 995       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 996       # Solaris 7 the name librt is preferred.
 997       AC_CHECK_FUNCS(sched_yield, , [
 998         AC_CHECK_LIB(rt, sched_yield, [
 999           AC_DEFINE(HAVE_SCHED_YIELD)
1000           THREADLIBS="$THREADLIBS -lrt"
1001           THREADSPEC="$THREADSPEC -lrt"], [
1002           AC_CHECK_LIB(posix4, sched_yield, [
1003             AC_DEFINE(HAVE_SCHED_YIELD)
1004             THREADLIBS="$THREADLIBS -lposix4"
1005             THREADSPEC="$THREADSPEC -lposix4"])])])
1006       LIBS="$save_LIBS"
1007
1008       # We can save a little space at runtime if the mutex has m_count
1009       # or __m_count.  This is a nice hack for Linux.
1010       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1011           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1012         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1013              [Define if pthread_mutex_t has m_count member.]), [
1014         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1015             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1016           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1017             [Define if pthread_mutex_t has __m_count member.]))])
1018    fi
1019
1020    # We require a way to get the time.
1021    time_found=no
1022    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1023    if test "$time_found" = no; then
1024       AC_MSG_ERROR([no function found to get the time])
1025    fi
1026
1027    AC_CHECK_FUNCS(memmove)
1028
1029    # We require memcpy.
1030    memcpy_found=no
1031    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1032    if test "$memcpy_found" = no; then
1033       AC_MSG_ERROR([memcpy is required])
1034    fi
1035
1036    AC_CHECK_LIB(dl, dlopen, [
1037        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1038
1039    # Some library-finding code we stole from Tcl.
1040    #--------------------------------------------------------------------
1041    #    Check for the existence of the -lsocket and -lnsl libraries.
1042    #    The order here is important, so that they end up in the right
1043    #    order in the command line generated by make.  Here are some
1044    #    special considerations:
1045    #    1. Use "connect" and "accept" to check for -lsocket, and
1046    #       "gethostbyname" to check for -lnsl.
1047    #    2. Use each function name only once:  can't redo a check because
1048    #       autoconf caches the results of the last check and won't redo it.
1049    #    3. Use -lnsl and -lsocket only if they supply procedures that
1050    #       aren't already present in the normal libraries.  This is because
1051    #       IRIX 5.2 has libraries, but they aren't needed and they're
1052    #       bogus:  they goof up name resolution if used.
1053    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1054    #       To get around this problem, check for both libraries together
1055    #       if -lsocket doesn't work by itself.
1056    #--------------------------------------------------------------------
1057
1058    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1059     [gcj_cv_lib_sockets=
1060      gcj_checkBoth=0
1061      unset ac_cv_func_connect
1062      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1063      if test "$gcj_checkSocket" = 1; then
1064          unset ac_cv_func_connect
1065          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1066                       gcj_checkBoth=1)
1067      fi
1068      if test "$gcj_checkBoth" = 1; then
1069          gcj_oldLibs=$LIBS
1070          LIBS="$LIBS -lsocket -lnsl"
1071          unset ac_cv_func_accept
1072          AC_CHECK_FUNC(accept,
1073                        [gcj_checkNsl=0
1074                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1075          unset ac_cv_func_accept
1076          LIBS=$gcj_oldLibs
1077      fi
1078      unset ac_cv_func_gethostbyname
1079      gcj_oldLibs=$LIBS
1080      LIBS="$LIBS $gcj_cv_lib_sockets"
1081      AC_CHECK_FUNC(gethostbyname, ,
1082                    [AC_CHECK_LIB(nsl, main,
1083                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1084      unset ac_cv_func_gethostbyname
1085      LIBS=$gcj_oldLIBS
1086    ])
1087    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1088
1089    if test "$with_system_zlib" = yes; then
1090       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1091    fi
1092
1093    # Test for Gtk stuff, if asked for.
1094    if test "$use_gtk_awt" = yes; then
1095       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1096       AC_SUBST(GTK_CFLAGS)
1097       AC_SUBST(GTK_LIBS)
1098
1099       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1100       AC_SUBST(GLIB_CFLAGS)
1101       AC_SUBST(GLIB_LIBS)
1102
1103       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1104       AC_SUBST(LIBART_CFLAGS)
1105       AC_SUBST(LIBART_LIBS)
1106
1107       # We require the XTest Extension to support java.awt.Robot.
1108       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1109                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1110                    [${X_LIBS}])
1111    fi
1112
1113    # On Solaris, and maybe other architectures, the Boehm collector
1114    # requires -ldl.
1115    if test "$GC" = boehm; then
1116       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1117    fi
1118 fi
1119 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1120
1121 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1122 case $build in
1123     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1124     *)         CLASSPATH_SEPARATOR=':' ;;
1125 esac
1126 AC_SUBST(CLASSPATH_SEPARATOR)
1127
1128 # We must search the source tree for java.lang, since we still don't
1129 # have libgcj.jar nor java/lang/*.class
1130 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1131 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1132
1133 # Since some classes depend on this one, we need its source available
1134 # before we can do any GCJ compilation test :-(
1135 if test ! -f gnu/classpath/Configuration.java; then
1136   test -d gnu || mkdir gnu
1137   test -d gnu/classpath || mkdir gnu/classpath
1138   sed -e "s,@LIBGCJDEBUG@,$LIBGCJDEBUG," \
1139       -e "s,@TOOLKIT@,$TOOLKIT," \
1140         < $srcdir/gnu/classpath/Configuration.java.in \
1141         > gnu/classpath/Configuration.java
1142   # We do not want to redirect the output of the grep below to /dev/null,
1143   # but we add /dev/null to the input list so that grep will print the
1144   # filename of Configuration.java in case it finds any matches.
1145   if grep @ gnu/classpath/Configuration.java /dev/null; then
1146     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1147   fi
1148 fi
1149
1150 LT_AC_PROG_GCJ
1151
1152 # Now remove it.
1153 rm -f gnu/classpath/Configuration.java
1154
1155 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1156
1157 AC_CHECK_SIZEOF(void *)
1158
1159 AC_C_BIGENDIAN
1160
1161 ZLIBS=
1162 SYS_ZLIBS=
1163 ZINCS=
1164
1165 if test -z "$ZLIBSPEC"; then
1166    # Use zlib from the GCC tree.
1167    ZINCS='-I$(top_srcdir)/../zlib'
1168    ZLIBS=../zlib/libzgcj_convenience.la
1169 else
1170    # System's zlib.
1171    SYS_ZLIBS="$ZLIBSPEC"
1172 fi
1173 AC_SUBST(ZLIBS)
1174 AC_SUBST(SYS_ZLIBS)
1175 AC_SUBST(ZINCS)
1176 AC_SUBST(DIVIDESPEC)
1177 AC_SUBST(CHECKREFSPEC)
1178 AC_SUBST(EXCEPTIONSPEC)
1179 AC_SUBST(BACKTRACESPEC)
1180 AC_SUBST(IEEESPEC)
1181
1182 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1183 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1184 AC_SUBST(GCC_UNWIND_INCLUDE)
1185
1186 # Process the option "--enable-version-specific-runtime-libs"
1187 # Calculate toolexeclibdir
1188 case ${version_specific_libs} in
1189   yes)
1190     # Need the gcc compiler version to know where to install libraries
1191     # and header files if --enable-version-specific-runtime-libs option
1192     # is selected.
1193     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1194     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1195     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1196     toolexeclibdir=$toolexecmainlibdir
1197     ;;
1198   no)
1199     if test -n "$with_cross_host" &&
1200        test x"$with_cross_host" != x"no"; then
1201       # Install a library built with a cross compiler in tooldir, not libdir.
1202       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1203       toolexecmainlibdir='$(toolexecdir)/lib'
1204     else
1205       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1206       toolexecmainlibdir='$(libdir)'
1207     fi
1208     multi_os_directory=`$CC -print-multi-os-directory`
1209     case $multi_os_directory in
1210       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1211       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1212     esac
1213     ;;
1214 esac
1215 AC_SUBST(toolexecdir)
1216 AC_SUBST(toolexecmainlibdir)
1217 AC_SUBST(toolexeclibdir)
1218
1219 # Determine gcj version number.
1220 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1221 GCJVERSION=$gcjversion
1222 AC_SUBST(GCJVERSION)
1223 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1224
1225 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1226 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1227
1228 TL_AC_GXX_INCLUDE_DIR
1229
1230 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1231 # On that system, sys/ioctl.h will not include sys/filio.h unless
1232 # BSD_COMP is defined; just including sys/filio.h is simpler.
1233 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1234 # for now.  If you change this, you also must update natFile.cc.
1235 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1236                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1237                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1238                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1239                   dirent.h])
1240 AC_CHECK_HEADERS(inttypes.h, [
1241     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1242     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1243 ])
1244 AC_HEADER_SYS_WAIT
1245
1246 AC_CHECK_TYPE([ssize_t], [int])
1247
1248 AC_MSG_CHECKING([for in_addr_t])
1249 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1250 #if STDC_HEADERS
1251 #include <stdlib.h>
1252 #include <stddef.h>
1253 #endif
1254 #if HAVE_NETINET_IN_H
1255 #include <netinet/in.h>
1256 #endif]], [[in_addr_t foo;]])],
1257   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1258      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1259    AC_MSG_RESULT(yes)],
1260   [AC_MSG_RESULT(no)])
1261
1262 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1263 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1264   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1265      [Define if struct ip_mreq is defined in netinet/in.h.])
1266    AC_MSG_RESULT(yes)],
1267   [AC_MSG_RESULT(no)])
1268
1269 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1270 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1271   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1272      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1273    AC_MSG_RESULT(yes)],
1274   [AC_MSG_RESULT(no)])
1275
1276 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1277 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1278   [AC_DEFINE(HAVE_INET6, 1,
1279      [Define if inet6 structures are defined in netinet/in.h.])
1280    AC_MSG_RESULT(yes)],
1281   [AC_MSG_RESULT(no)])
1282
1283 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1284 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1285 #include <sys/types.h>
1286 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1287   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1288    AC_MSG_RESULT(yes)],
1289   [AC_MSG_RESULT(no)])
1290
1291 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1292 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1293   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1294    AC_MSG_RESULT(yes)],
1295   [AC_MSG_RESULT(no)
1296    AC_MSG_CHECKING([for global timezone variable])
1297    dnl FIXME: we don't want a link check here because that won't work
1298    dnl when cross-compiling.  So instead we make an assumption that
1299    dnl the header file will mention timezone if it exists.
1300    dnl Don't find the win32 function timezone
1301    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1302      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1303       AC_MSG_RESULT(yes)],
1304      [AC_MSG_RESULT(no)
1305        AC_MSG_CHECKING([for global _timezone variable])
1306        dnl FIXME: As above, don't want link check
1307        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1308          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1309             [Define if your platform has the global _timezone variable.])
1310           AC_MSG_RESULT(yes)],
1311           [AC_MSG_RESULT(no)])])])
1312
1313 AC_FUNC_ALLOCA
1314 AC_FUNC_MMAP
1315
1316 AC_CHECK_PROGS(PERL, perl, false)
1317
1318 SYSDEP_SOURCES=
1319 SIGNAL_HANDLER_AUX=
1320
1321 case "${host}" in
1322  i?86-*-linux*)
1323     SIGNAL_HANDLER=include/i386-signal.h
1324     ;;
1325  sparc*-sun-solaris*)
1326     SIGNAL_HANDLER=include/sparc-signal.h
1327     ;;
1328 # ia64-*)
1329 #    SYSDEP_SOURCES=sysdep/ia64.c
1330 #    test -d sysdep || mkdir sysdep
1331 #    ;;
1332  hppa*-*-linux*)
1333     SIGNAL_HANDLER=include/pa-signal.h
1334     ;;
1335  ia64-*-linux*)
1336     SIGNAL_HANDLER=include/dwarf2-signal.h
1337     ;;
1338  powerpc*-*-linux*)
1339     SIGNAL_HANDLER=include/powerpc-signal.h
1340     ;;
1341  alpha*-*-linux*)
1342     SIGNAL_HANDLER=include/dwarf2-signal.h
1343     ;;
1344  s390*-*-linux*)
1345     SIGNAL_HANDLER=include/s390-signal.h
1346     ;;
1347  x86_64*-*-linux*)
1348     SIGNAL_HANDLER=include/x86_64-signal.h
1349     SIGNAL_HANDLER_AUX=include/i386-signal.h
1350     ;;
1351  sparc*-*-linux*)
1352     SIGNAL_HANDLER=include/dwarf2-signal.h
1353     ;;
1354  sh*-*-linux*)
1355     SIGNAL_HANDLER=include/sh-signal.h
1356     ;;
1357  *mingw*)
1358     SIGNAL_HANDLER=include/win32-signal.h
1359     ;;
1360  mips*-*-linux*)
1361     SIGNAL_HANDLER=include/mips-signal.h
1362     ;;
1363  *-*-darwin*)
1364     SIGNAL_HANDLER=include/darwin-signal.h
1365     ;;
1366  *)
1367     SIGNAL_HANDLER=include/default-signal.h
1368     ;;
1369 esac
1370
1371 # If we're using sjlj exceptions, forget what we just learned.
1372 if test "$enable_sjlj_exceptions" = yes; then
1373    SIGNAL_HANDLER=include/default-signal.h
1374    SIGNAL_HANDLER_AUX=
1375 fi
1376
1377 AC_SUBST(SYSDEP_SOURCES)
1378
1379 if test -z "$SIGNAL_HANDLER_AUX"; then
1380   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1381 fi
1382
1383 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1384                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1385
1386 if test "${multilib}" = "yes"; then
1387   multilib_arg="--enable-multilib"
1388 else
1389   multilib_arg=
1390 fi
1391
1392
1393
1394 here=`${PWDCMD-pwd}`
1395 AC_SUBST(here)
1396
1397 # We get this from the environment.
1398 AC_SUBST(GCJFLAGS)
1399
1400 AC_CONFIG_FILES([
1401 Makefile
1402 libgcj.pc
1403 libgcj.spec
1404 libgcj-test.spec
1405 gcj/Makefile
1406 include/Makefile
1407 testsuite/Makefile
1408 ])
1409
1410 AC_CONFIG_COMMANDS([default],
1411 [# Only add multilib support code if we just rebuilt top-level Makefile.
1412 case " $CONFIG_FILES " in
1413  *" Makefile "*)
1414    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1415    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1416    ;;
1417 esac
1418 for ac_multi_file in $CONFIG_FILES; do
1419   case $ac_multi_file in
1420   */Makefile)
1421     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1422   esac
1423 done
1424 ],
1425 srcdir=${srcdir}
1426 host=${host}
1427 target=${target}
1428 with_multisubdir=${with_multisubdir}
1429 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1430 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1431 libgcj_basedir=${libgcj_basedir}
1432 CC="${CC}"
1433 CXX="${CXX}"
1434 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1435 )
1436
1437 AC_OUTPUT