libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 AC_ARG_ENABLE(plugin,
  88   AS_HELP_STRING([--enable-plugin],
  89                  [build gcjwebplugin web browser plugin]),
  90     [case "$enableval" in
  91       yes) plugin_enabled=yes ;;
  92       no)  plugin_enabled=no ;;
  93       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  94      esac],
  95     [plugin_enabled=no]
  96 )
  97
  98 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  99 GCC_NO_EXECUTABLES
 100
 101 # (1) We use an abnormal CXX (without library references), so we
 102 # must cache it under a different name.
 103 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 104 # the non-multilib-adjusted value will be used in multilibs.
 105 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 106 # (4) As another side effect, automake doesn't automatically include them
 107 # in Makefile.in.
 108 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 109 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 110 # used in later tests.  This may not be necessary in libjava; I don't know.
 111 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 112 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 113 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 114 save_CXXFLAGS="$CXXFLAGS"
 115 CXXFLAGS="$CXXFLAGS -fno-builtin"
 116 AC_PROG_CC
 117 AC_PROG_CXX
 118 CXXFLAGS="$save_CXXFLAGS"
 119 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 120 AC_SUBST(CFLAGS)
 121 AC_SUBST(CXXFLAGS)
 122 AC_SUBST(LDFLAGS)
 123
 124 AM_INIT_AUTOMAKE([1.9.0])
 125
 126 AC_CHECK_TOOL(AS, as)
 127 AC_CHECK_TOOL(LD, ld)
 128 AC_CHECK_TOOL(AR, ar)
 129 AC_CHECK_TOOL(RANLIB, ranlib, :)
 130 AC_PROG_AWK
 131 AC_CHECK_PROGS([JAR], [jar fastjar], no)
 132 AC_PATH_PROG([ZIP], [zip], no)
 133 AC_PATH_PROG([UNZIP], [unzip], unzip)
 134 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 135 if test "$ZIP" = no; then
 136   if test "$JAR" = no; then
 137     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 138   fi
 139 else
 140   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 141   JAR=`pwd`/scripts/jar
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 AM_MAINTAINER_MODE
 147
 148 AC_EXEEXT
 149
 150 # configure.host sets the following important variables
 151 #       libgcj_cflags    - host specific C compiler flags
 152 #       libgcj_cxxflags  - host specific C++ compiler flags
 153 #       libgcj_javaflags - host specific Java compiler flags
 154
 155 libgcj_cflags=
 156 libgcj_cxxflags=
 157 libgcj_javaflags=
 158
 159 . ${srcdir}/configure.host
 160
 161 LIBGCJ_CFLAGS="${libgcj_cflags}"
 162 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 163 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 164 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 165 AC_SUBST(LIBGCJ_CFLAGS)
 166 AC_SUBST(LIBGCJ_CXXFLAGS)
 167 AC_SUBST(LIBGCJ_JAVAFLAGS)
 168 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 169
 170 # Only use libltdl for non-newlib builds.
 171 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 172    AC_LTDL_SHLIBPATH
 173 fi
 174
 175 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 176
 177 # See if the user has requested runtime debugging.
 178 LIBGCJDEBUG="disable"
 179 AC_SUBST(LIBGCJDEBUG)
 180 AC_ARG_ENABLE(libgcj-debug,
 181   AS_HELP_STRING([--enable-libgcj-debug],
 182                  [enable runtime debugging code]),
 183   [if test "$enable_libgcj_debug" = yes; then
 184     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 185     LIBGCJDEBUG="enable"
 186   fi])
 187
 188 # Determine which AWT peer libraries to build
 189 AC_ARG_ENABLE(java-awt,
 190   AS_HELP_STRING([--enable-java-awt],
 191                  [list of AWT peer implementations to be built]))
 192
 193 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 194 use_xlib_awt=""
 195 use_gtk_awt=""
 196 use_qt_awt=""
 197 # The default toolkit to use is the first one specified.
 198 TOOLKIT=
 199 AC_SUBST(TOOLKIT)
 200
 201 for peer in $peerlibs ; do
 202   case $peer in
 203     xlib)
 204       if test "$no_x" = yes; then
 205         echo "*** xlib peers requested but no X library available" 1>&2
 206         exit 1
 207       else
 208         use_xlib_awt="yes"
 209         if test -z "$TOOLKIT"; then
 210            TOOLKIT=gnu.awt.xlib.XToolkit
 211         fi
 212       fi
 213       ;;
 214     gtk)
 215       if test "$no_x" = yes; then
 216          echo "*** gtk peers requested but no X library available" 1>&2
 217          exit 1
 218       else
 219          use_gtk_awt=yes
 220          if test -z "$TOOLKIT"; then
 221             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 222          fi
 223       fi
 224       ;;
 225     qt)
 226       if test "$no_x" = yes; then
 227          # Perhaps we should admit the possibility of embedded Qt.
 228          echo "*** Qt peers requested but no X library available" 1>&2
 229          exit 1
 230       else
 231          use_qt_awt=yes
 232          if test -z "$TOOLKIT"; then
 233             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 234          fi
 235       fi
 236       ;;
 237     no)
 238       use_xlib_awt=
 239       use_gtk_awt=
 240       use_qt_awt=
 241       break
 242       ;;
 243     *)
 244       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 245       exit 1
 246   esac
 247 done
 248
 249 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 250
 251 # Create standard.omit based on decisions we just made.
 252 cp $srcdir/standard.omit.in standard.omit
 253 if test "$use_xlib_awt" != yes; then
 254    echo gnu/awt/xlib >> standard.omit
 255    echo gnu/gcj/xlib >> standard.omit
 256 fi
 257
 258 if test -z "${with_multisubdir}"; then
 259    builddotdot=.
 260 else
 261    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 262 fi
 263
 264 NATIVE=yes
 265
 266 # Which gcj do we use?
 267 which_gcj=default
 268 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 269 if test -n "${with_cross_host}"; then
 270   # We are being configured with a cross compiler. We can't
 271   # use ac_exeext, because that is for the target platform.
 272   NATIVE=no
 273   cross_host_exeext=
 274   case "${with_cross_host}" in
 275      *mingw* | *cygwin*)
 276          cross_host_exeext=.exe
 277      ;;
 278   esac
 279   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 280      if test x"$build_noncanonical" = x"$with_cross_host"; then
 281         # Ordinary cross (host!=target and host=build)
 282         which_gcj=built
 283      else
 284         # Canadian cross (host!=target and host!=build)
 285         which_gcj=cross
 286      fi
 287   else
 288      which_gcj=cross
 289   fi
 290 else
 291   # We are being configured with a native or crossed-native compiler
 292   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 293      if test x"$build" = x"$host"; then
 294         # True native build (host=target and host=build)
 295         which_gcj=built
 296      else
 297         # Crossed-native build (host=target and host!=build)
 298         which_gcj=cross
 299      fi
 300   else
 301      which_gcj=path
 302   fi
 303 fi
 304 case "${which_gcj}" in
 305    built)
 306       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 307       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 308    ;;
 309    cross)
 310       if test "x${with_newlib}" = "xyes"; then
 311          # FIXME (comment): Why is this needed?
 312          GCC_UNWIND_INCLUDE=
 313          GCJ="${target_noncanonical}-gcj"
 314       else
 315          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 316       fi
 317       GCJH='$(target_noncanonical)-gcjh'
 318    ;;
 319    path)
 320       GCJ="gcj -B`${PWDCMD-pwd}`/"
 321       GCJH=gcjh
 322    ;;
 323 esac
 324
 325 AC_SUBST(GCJH)
 326
 327 # Create it, so that compile/link tests don't fail
 328 test -f libgcj.spec || touch libgcj.spec
 329
 330
 331
 332 # Set up to configure Classpath.
 333 # FIXME: no supported way to pass args in autoconf.
 334 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 335 ac_configure_args="$ac_configure_args --enable-tool-wrappers"
 336 ac_configure_args="$ac_configure_args --disable-load-library"
 337 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 338 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 339 dir1=`cd $srcdir && pwd`
 340 dir2=`pwd`
 341 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 342 ac_configure_args="$ac_configure_args --disable-core-jni"
 343 dnl FIXME?
 344 ac_configure_args="$ac_configure_args --disable-examples"
 345 ac_configure_args="$ac_configure_args --with-glibj=build"
 346 if test "$plugin_enabled" != yes; then
 347   ac_configure_args="$ac_configure_args --disable-plugin"
 348 fi
 349 if test "$use_gtk_awt" != yes; then
 350   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 351 fi
 352 if test "$use_qt_awt" != yes; then
 353   ac_configure_args="$ac_configure_args --disable-qt-peer"
 354 else
 355   # We need this as qt is disabled by default in classpath.
 356   ac_configure_args="$ac_configure_args --enable-qt-peer"
 357 fi
 358 dnl --with-gcj=$GCJ
 359 dnl --with-javah=$GCJH
 360 dnl gjdoc?
 361 dnl gtk-cairo -- just export here...
 362 dnl --enable-regen-headers?
 363
 364 # Only use libltdl for non-newlib builds.
 365 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 366    AC_LIBLTDL_CONVENIENCE
 367    AC_LIBTOOL_DLOPEN
 368    DIRLTDL=libltdl
 369    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 370    # Sigh.  Libtool's macro doesn't do the right thing.
 371    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 372    # FIXME: this is a hack.
 373    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 374    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 375 fi
 376 AC_SUBST(INCLTDL)
 377 AC_SUBST(LIBLTDL)
 378 AC_SUBST(DIRLTDL)
 379 AC_PROG_LIBTOOL
 380 AM_PROG_GCJ
 381 AM_PROG_CC_C_O
 382
 383 AC_CONFIG_SUBDIRS(classpath libltdl)
 384
 385 # The -no-testsuite modules omit the test subdir.
 386 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 387
 388 # Should the runtime set system properties by examining the
 389 # environment variable GCJ_PROPERTIES?
 390 AC_ARG_ENABLE(getenv-properties,
 391   AS_HELP_STRING([--disable-getenv-properties],
 392                  [don't set system properties from GCJ_PROPERTIES]))
 393
 394 # Whether GCJ_PROPERTIES is used depends on the target.
 395 if test -z "$enable_getenv_properties"; then
 396    enable_getenv_properties=${enable_getenv_properties_default-yes}
 397 fi
 398 if test "$enable_getenv_properties" = no; then
 399    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 400      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 401 fi
 402
 403 # Whether we should use arguments to main()
 404 if test -z "$enable_main_args"; then
 405    enable_main_args=${enable_main_args_default-yes}
 406 fi
 407 if test "$enable_main_args" = no; then
 408    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 409 fi
 410
 411
 412 # Should we use hashtable-based synchronization?
 413 # Currently works only for Linux X86/ia64
 414 # Typically faster and more space-efficient
 415 AC_ARG_ENABLE(hash-synchronization,
 416   AS_HELP_STRING([--enable-hash-synchronization],
 417                  [use global hash table for monitor locks]))
 418
 419 if test -z "$enable_hash_synchronization"; then
 420    enable_hash_synchronization=$enable_hash_synchronization_default
 421 fi
 422
 423 AC_ARG_WITH(java-home,
 424   AS_HELP_STRING([--with-java-home=DIRECTORY],
 425                  [value of java.home system property]),
 426                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 427 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 428 AC_SUBST(JAVA_HOME)
 429
 430 # What is the native OS API for MinGW?
 431 AC_ARG_WITH(win32-nlsapi,
 432   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 433                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 434 [case "${withval}" in
 435   ansi) with_win32_nlsapi=ansi ;;
 436   unicows) with_win32_nlsapi=unicows ;;
 437   unicode) with_win32_nlsapi=unicode ;;
 438   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 439 esac],[with_win32_nlsapi=ansi])
 440
 441 case "${with_win32_nlsapi}" in
 442   unicows | unicode)
 443     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 444       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 445     ;;
 446 esac
 447
 448 # configure.host sets slow_pthread_self if the synchronization code should
 449 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 450 if test "${slow_pthread_self}" = "yes"; then
 451   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 452     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 453 fi
 454
 455 # Check for gc debugging.  This option is handled both here and in the GC.
 456 AC_ARG_ENABLE(gc-debug,
 457    AS_HELP_STRING([--enable-gc-debug],
 458                   [include full support for pointer backtracing etc.]),
 459 [ if test "$enable_gc_debug" = "yes"; then
 460     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 461               [Define if we want to use debug calls into the garbage collector.])
 462   fi])
 463
 464 # See if the user has the interpreter included.
 465 AC_ARG_ENABLE(interpreter,
 466   AS_HELP_STRING([--enable-interpreter],
 467                  [enable interpreter]),
 468   [if test "$enable_interpreter" = yes; then
 469     # This can also be set in configure.host.
 470     libgcj_interpreter=yes
 471   elif test "$enable_interpreter" = no; then
 472     libgcj_interpreter=no
 473   fi])
 474
 475 if test "$libgcj_interpreter" = yes; then
 476    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 477 fi
 478 INTERPRETER="$libgcj_interpreter"
 479 AC_SUBST(INTERPRETER)
 480
 481 AC_MSG_CHECKING([for exception model to use])
 482 AC_LANG_PUSH(C++)
 483 AC_ARG_ENABLE(sjlj-exceptions,
 484   AS_HELP_STRING([--enable-sjlj-exceptions],
 485                  [force use of builtin_setjmp for exceptions]),
 486 [:],
 487 [dnl Botheration.  Now we've got to detect the exception model.
 488 dnl Link tests against libgcc.a are problematic since -- at least
 489 dnl as of this writing -- we've not been given proper -L bits for
 490 dnl single-tree newlib and libgloss.
 491 dnl
 492 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 493 dnl conftest files before we got a change to grep them first.
 494 cat > conftest.$ac_ext << EOF
 495 [#]line __oline__ "configure"
 496 struct S { ~S(); };
 497 void bar();
 498 void foo()
 499 {
 500   S s;
 501   bar();
 502 }
 503 EOF
 504 old_CXXFLAGS="$CXXFLAGS"
 505 CXXFLAGS=-S
 506 if AC_TRY_EVAL(ac_compile); then
 507   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 508     enable_sjlj_exceptions=yes
 509   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 510     enable_sjlj_exceptions=no
 511   fi
 512 fi
 513 CXXFLAGS="$old_CXXFLAGS"
 514 rm -f conftest*])
 515 if test x$enable_sjlj_exceptions = xyes; then
 516   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 517         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 518   ac_exception_model_name=sjlj
 519 elif test x$enable_sjlj_exceptions = xno; then
 520   ac_exception_model_name="call frame"
 521 else
 522   AC_MSG_ERROR([unable to detect exception model])
 523 fi
 524 AC_LANG_POP(C++)
 525 AC_MSG_RESULT($ac_exception_model_name)
 526
 527 # If we are non using SJLJ exceptions, and this host does not have support
 528 # for unwinding from a signal handler, enable checked dereferences and divides.
 529 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 530   CHECKREFSPEC=-fcheck-references
 531   DIVIDESPEC=-fuse-divide-subroutine
 532   EXCEPTIONSPEC=
 533 fi
 534
 535 # See if the user wants to disable java.net.  This is the mildly
 536 # ugly way that we admit that target-side configuration sucks.
 537 AC_ARG_ENABLE(java-net,
 538   AS_HELP_STRING([--disable-java-net],
 539                  [disable java.net]))
 540
 541 # Whether java.net is built by default can depend on the target.
 542 if test -z "$enable_java_net"; then
 543    enable_java_net=${enable_java_net_default-yes}
 544 fi
 545 if test "$enable_java_net" = no; then
 546    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 547 fi
 548
 549 # See if the user wants to configure without libffi.  Some
 550 # architectures don't support it, and default values are set in
 551 # configure.host.
 552 AC_ARG_WITH(libffi,
 553   AS_HELP_STRING([--without-libffi],
 554                  [don't use libffi]),
 555   [:],
 556   [with_libffi=${with_libffi_default-yes}])
 557
 558 LIBFFI=
 559 LIBFFIINCS=
 560 if test "$with_libffi" != no; then
 561    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 562    LIBFFI=../libffi/libffi_convenience.la
 563    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 564 fi
 565 AC_SUBST(LIBFFI)
 566 AC_SUBST(LIBFFIINCS)
 567
 568 # See if the user wants to disable JVMPI support.
 569 AC_ARG_ENABLE(jvmpi,
 570   AS_HELP_STRING([--disable-jvmpi],
 571                  [disable JVMPI support]))
 572
 573 if test "$enable_jvmpi" != no; then
 574     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 575 fi
 576
 577 # If the target is an eCos system, use the appropriate eCos
 578 # I/O routines.
 579 # FIXME: this should not be a local option but a global target
 580 # system; at present there is no eCos target.
 581 TARGET_ECOS=${PROCESS-"no"}
 582 AC_ARG_WITH(ecos,
 583 [  --with-ecos             enable runtime eCos target support],
 584 TARGET_ECOS="$with_ecos"
 585 )
 586
 587 PLATFORM_INNER_NAT_HDRS=
 588 case "$TARGET_ECOS" in
 589    no) case "$host" in
 590       *mingw*)
 591             PLATFORM=Win32
 592             PLATFORMNET=Win32
 593             PLATFORMH=win32.h
 594         CHECK_FOR_BROKEN_MINGW_LD
 595       ;;
 596       *)
 597             PLATFORM=Posix
 598             PLATFORMNET=Posix
 599             PLATFORMH=posix.h
 600             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 601       ;;
 602       esac
 603       ;;
 604    *)
 605       PLATFORM=Ecos
 606       PLATFORMNET=NoNet
 607       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 608       PLATFORMH=posix.h
 609       ;;
 610 esac
 611 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 612 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 613
 614 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 615                                       [Define if you have int32_t and uint32_t.]))
 616 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 617                                         [Define if you have int32_t and uint32_t.]))
 618 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 619                                           [Define if you have u_int32_t]))
 620 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 621                                            [Define if you have u_int32_t]))
 622
 623 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 624 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 625
 626 case "$host" in
 627   *-darwin*) DARWIN_CRT=true ;;
 628   *) DARWIN_CRT=false ;;
 629 esac
 630 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 631
 632 # These may not be defined in a non-ANS conformant embedded system.
 633 # FIXME: Should these case a runtime exception in that case?
 634 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 635                                   [Define is you have 'mktime' in <time.h>]))
 636 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 637                                   [Define is you have 'localtime' in <time.h>]))
 638
 639 # Create the subdirectory for natFile.cc, or the attempt
 640 # to create the link will fail.
 641 test -d java || mkdir java
 642 test -d java/io || mkdir java/io
 643 test -d gnu || mkdir gnu
 644 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 645
 646 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 647 test -d java/lang || mkdir java/lang
 648 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 649 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 650
 651 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 652 test -d java/net || mkdir java/net
 653 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 654 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 655
 656 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 657 test -d gnu/java || mkdir gnu/java
 658 test -d gnu/java/net || mkdir gnu/java/net
 659 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 660 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 661
 662 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 663 test -d gnu/java/nio || mkdir gnu/java/nio
 664 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 665 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 666 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 667 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 668
 669 case "${host}" in
 670     *mingw*)
 671       SYSTEMSPEC="-lgdi32 -lws2_32"
 672       if test "${with_win32_nlsapi}" = "unicows"; then
 673         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 674       fi
 675     ;;
 676     *)
 677       SYSTEMSPEC=
 678     ;;
 679 esac
 680 AC_SUBST(SYSTEMSPEC)
 681
 682 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 683 AC_SUBST(LIBGCJTESTSPEC)
 684
 685 AC_ARG_WITH(system-zlib,
 686   AS_HELP_STRING([--with-system-zlib],
 687                  [use installed libz]))
 688 ZLIBSPEC=
 689 AC_SUBST(ZLIBSPEC)
 690 ZLIBTESTSPEC=
 691 AC_SUBST(ZLIBTESTSPEC)
 692
 693 AC_PATH_XTRA
 694
 695 # FIXME: this should be _libs on some hosts.
 696 libsubdir=.libs
 697
 698 # extra LD Flags which are required for targets
 699 case "${host}" in
 700 *-*-darwin[[0-7]].*)
 701     # For now we have to disable it on darwin[8-9] because it slows down
 702     # the linking phase. A possible bug in ld?
 703     # on Darwin -single_module speeds up loading of the dynamic libraries.
 704     extra_ldflags_libjava=-Wl,-single_module
 705     ;;
 706 esac
 707 AC_SUBST(extra_ldflags_libjava)
 708
 709 # Allow the GC to be disabled.  Can be useful when debugging.
 710 AC_MSG_CHECKING([for garbage collector to use])
 711 AC_ARG_ENABLE(java-gc,
 712   AS_HELP_STRING([--enable-java-gc=TYPE],
 713                  [choose garbage collector (default is boehm)]),
 714   [GC=$enableval],
 715   [GC=boehm])
 716 GCLIBS=
 717 GCINCS=
 718 GCDEPS=
 719 GCSPEC=
 720 JC1GCSPEC=
 721 GCTESTSPEC=
 722 case "$GC" in
 723  boehm)
 724     AC_MSG_RESULT(boehm)
 725     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 726     JC1GCSPEC='-fuse-boehm-gc'
 727     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 728     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 729     GCOBJS=boehm.lo
 730     GCHDR=boehm-gc.h
 731     # The POSIX thread support needs to know this.
 732     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 733     ;;
 734  no)
 735     AC_MSG_RESULT(none)
 736     GCHDR=no-gc.h
 737     ;;
 738  *)
 739     AC_MSG_ERROR([unrecognized collector "$GC"])
 740     ;;
 741 esac
 742 AC_SUBST(GCLIBS)
 743 AC_SUBST(GCINCS)
 744 AC_SUBST(GCDEPS)
 745 AC_SUBST(GCSPEC)
 746 AC_SUBST(JC1GCSPEC)
 747 AC_SUBST(GCTESTSPEC)
 748 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 749 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 750 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 751
 752
 753 AC_MSG_CHECKING([for thread model used by GCC])
 754 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 755 AC_MSG_RESULT([$THREADS])
 756
 757 case "$THREADS" in
 758  no | none | single)
 759     THREADS=none
 760     ;;
 761  posix | posix95 | pthreads)
 762     THREADS=posix
 763     case "$host" in
 764      *-*-linux*)
 765         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 766         ;;
 767     esac
 768     ;;
 769  win32)
 770     ;;
 771  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 772     AC_MSG_ERROR(thread package $THREADS not yet supported)
 773     ;;
 774  *)
 775     AC_MSG_ERROR($THREADS is an unknown thread package)
 776     ;;
 777 esac
 778
 779 THREADCXXFLAGS=
 780 THREADLDFLAGS=
 781 THREADLIBS=
 782 THREADINCS=
 783 THREADDEPS=
 784 THREADH=
 785 THREADSPEC=
 786 THREADSTARTFILESPEC=
 787 case "$THREADS" in
 788  posix)
 789     case "$host" in
 790      *-*-cygwin*)
 791         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 792         ;;
 793      *-*-freebsd[[1234]]*)
 794         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 795         # merely adds pthread_* functions) but it does have a -pthread switch
 796         # which is required at link-time to select -lc_r *instead* of -lc.
 797         THREADLDFLAGS=-pthread
 798         # Don't set THREADSPEC here as might be expected since -pthread is
 799         # not processed when found within a spec file, it must come from
 800         # the command line.  For now, the user must provide the -pthread
 801         # switch to link code compiled with gcj.  In future, consider adding
 802         # support for weak references to pthread_* functions ala gthr.h API.
 803         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 804         ;;
 805      *-*-freebsd*)
 806         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 807         # systems which support threads and -lpthread.
 808         THREADLDFLAGS=-pthread
 809         THREADSPEC=-lpthread
 810         ;;
 811      alpha*-dec-osf* | hppa*-hp-hpux*)
 812         THREADCXXFLAGS=-pthread
 813         # boehm-gc needs some functions from librt, so link that too.
 814         THREADLIBS='-lpthread -lrt'
 815         THREADSPEC='-lpthread -lrt'
 816         ;;
 817      *)
 818         THREADLIBS=-lpthread
 819         THREADSPEC=-lpthread
 820         ;;
 821     esac
 822     THREADH=posix-threads.h
 823     # MIT pthreads doesn't seem to have the mutexattr functions.
 824     # But for now we don't check for it.  We just assume you aren't
 825     # using MIT pthreads.
 826     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 827
 828     # If we're using the Boehm GC, then we happen to know that it
 829     # defines _REENTRANT, so we don't bother.  Eww.
 830     if test "$GC" != boehm; then
 831        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 832     fi
 833     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 834     ;;
 835
 836  win32)
 837     THREADH=win32-threads.h
 838     THREADCXXFLAGS=-mthreads
 839     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 840     # But we do not want the executables created to be dependent on
 841     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 842     # exception handling contexts.  The following kludge achieves this effect
 843     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 844     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 845     # A workaround is to explicitly use -mthreads while linking Java programs.
 846     # See PR libgcj/28263.
 847     #
 848     # FIXME: In Java we are able to detect thread death at the end of
 849     # Thread.run() so we should be able to clean up the exception handling
 850     # contexts ourselves.
 851     THREADSTARTFILESPEC='crtmt%O%s'
 852     ;;
 853
 854  none)
 855     THREADH=no-threads.h
 856     ;;
 857 esac
 858 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 859 AC_SUBST(THREADLIBS)
 860 AC_SUBST(THREADINCS)
 861 AC_SUBST(THREADDEPS)
 862 AC_SUBST(THREADSPEC)
 863 AC_SUBST(THREADSTARTFILESPEC)
 864 AC_SUBST(THREADLDFLAGS)
 865 AC_SUBST(THREADCXXFLAGS)
 866 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 867 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 868 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 869
 870 if test -d sysdep; then true; else mkdir sysdep; fi
 871 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 872 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 873 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 874
 875 HASH_SYNC_SPEC=
 876 # Hash synchronization is only useful with posix threads right now.
 877 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 878    HASH_SYNC_SPEC=-fhash-synchronization
 879    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 880 fi
 881 AC_SUBST(HASH_SYNC_SPEC)
 882
 883 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 884
 885 # We're in the tree with gcc, and need to include some of its headers.
 886 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 887
 888 if test "x${with_newlib}" = "xyes"; then
 889    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 890    # may not work correctly, because the compiler may not be able to
 891    # link executables.
 892
 893    # We assume newlib.  This lets us hard-code the functions we know
 894    # we'll have.
 895    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 896    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 897    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 898    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 899    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 900    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 901    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 902    # This is only for POSIX threads.
 903    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 904    # We also assume we are using gcc, which provides alloca.
 905    AC_DEFINE(HAVE_ALLOCA)
 906
 907    # Assume we do not have getuid and friends.
 908    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 909    PLATFORMNET=NoNet
 910 else
 911    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 912                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 913                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
 914                    nl_langinfo setlocale \
 915                    inet_pton uname inet_ntoa \
 916                    fork execvp pipe sigaction ftruncate mmap \
 917                    getifaddrs])
 918    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 919    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 920    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 921    AC_CHECK_LIB(dl, dladdr, [
 922        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 923        AC_CHECK_LIB(dld, dladdr, [
 924        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 925
 926    if test x"$build" = x"$host"; then
 927      AC_CHECK_FILES(/proc/self/exe, [
 928        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 929    else
 930      case $host in
 931      *-linux*)
 932        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 933        ;;
 934      esac
 935    fi
 936
 937    AM_ICONV
 938    AM_LC_MESSAGES
 939    AC_STRUCT_TIMEZONE
 940
 941    AC_CHECK_FUNCS(gethostbyname_r, [
 942      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 943        [Define if you have the 'gethostbyname_r' function.])
 944      # There are two different kinds of gethostbyname_r.
 945      # We look for the one that returns `int'.
 946      # Hopefully this check is robust enough.
 947      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 948        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 949
 950      case " $GCINCS " in
 951      *" -D_REENTRANT "*) ;;
 952      *)
 953         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 954         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 955         [libjava_cv_gethostbyname_r_needs_reentrant],
 956         [ AC_LANG_PUSH(C++)
 957           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 958             [[gethostbyname_r("", 0, 0);]])],
 959             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 960                 CPPFLAGS_SAVE="$CPPFLAGS"
 961                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 962                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 963                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 964                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 965                 CPPFLAGS="$CPPFLAGS_SAVE"
 966           ])
 967           AC_LANG_POP(C++)
 968         ])
 969         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 970           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 971         fi
 972      ;;
 973      esac
 974
 975      AC_CACHE_CHECK([for struct hostent_data],
 976         [libjava_cv_struct_hostent_data], [dnl
 977         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 978 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 979 # define _REENTRANT 1
 980 #endif
 981 #include <netdb.h>]], [[struct hostent_data data;]])],
 982           [libjava_cv_struct_hostent_data=yes],
 983           [libjava_cv_struct_hostent_data=no])])
 984      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 985        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 986          [Define if struct hostent_data is defined in netdb.h])
 987      fi
 988    ])
 989
 990    # FIXME: libjava source code expects to find a prototype for
 991    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 992    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 993    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 994    # linkage check is enough, yet C++ code requires proper prototypes.)
 995    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 996    AC_CHECK_FUNCS(gethostbyaddr_r, [
 997      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 998        [Define if you have the 'gethostbyaddr_r' function.])
 999      # There are two different kinds of gethostbyaddr_r.
1000      # We look for the one that returns `int'.
1001      # Hopefully this check is robust enough.
1002      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1003        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1004          [Define if gethostbyaddr_r returns 'int'.])])])])
1005
1006    AC_CHECK_FUNCS(gethostname, [
1007      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1008        [Define if you have the 'gethostname' function.])
1009      AC_EGREP_HEADER(gethostname, unistd.h, [
1010        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1011          [Define if gethostname is declared in <unistd.h>.])])])
1012
1013    AC_CHECK_FUNCS(usleep, [
1014      AC_EGREP_HEADER(usleep, unistd.h, [
1015        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1016           [Define if usleep is declared in <unistd.h>.])])])
1017
1018    # Look for these functions in the thread library, but only bother
1019    # if using POSIX threads.
1020    if test "$THREADS" = posix; then
1021       save_LIBS="$LIBS"
1022       LIBS="$LIBS $THREADLIBS"
1023       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1024       # E.g., Solaris.
1025       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1026
1027       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1028       # Solaris 7 the name librt is preferred.
1029       AC_CHECK_FUNCS(sched_yield, , [
1030         AC_CHECK_LIB(rt, sched_yield, [
1031           AC_DEFINE(HAVE_SCHED_YIELD)
1032           THREADLIBS="$THREADLIBS -lrt"
1033           THREADSPEC="$THREADSPEC -lrt"], [
1034           AC_CHECK_LIB(posix4, sched_yield, [
1035             AC_DEFINE(HAVE_SCHED_YIELD)
1036             THREADLIBS="$THREADLIBS -lposix4"
1037             THREADSPEC="$THREADSPEC -lposix4"])])])
1038
1039       AC_CHECK_LIB(rt, clock_gettime, [
1040          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1041          case "$THREADSPEC" in
1042            *-lrt*) ;;
1043            *)
1044              THREADSPEC="$THREADSPEC -lrt"
1045              THREADLIBS="$THREADLIBS -lrt"
1046              ;;
1047          esac])
1048
1049       LIBS="$save_LIBS"
1050
1051       # We can save a little space at runtime if the mutex has m_count
1052       # or __m_count.  This is a nice hack for Linux.
1053       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1054           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1055         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1056              [Define if pthread_mutex_t has m_count member.]), [
1057         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1058             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1059           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1060             [Define if pthread_mutex_t has __m_count member.]))])
1061    fi
1062
1063    # We require a way to get the time.
1064    time_found=no
1065    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1066    if test "$time_found" = no; then
1067       AC_MSG_ERROR([no function found to get the time])
1068    fi
1069
1070    AC_CHECK_FUNCS(memmove)
1071
1072    # We require memcpy.
1073    memcpy_found=no
1074    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1075    if test "$memcpy_found" = no; then
1076       AC_MSG_ERROR([memcpy is required])
1077    fi
1078    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1079    AC_CHECK_LIB(dl, dlopen, [
1080        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1081        AC_CHECK_LIB(dld, dlopen, [
1082        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1083
1084    # Some library-finding code we stole from Tcl.
1085    #--------------------------------------------------------------------
1086    #    Check for the existence of the -lsocket and -lnsl libraries.
1087    #    The order here is important, so that they end up in the right
1088    #    order in the command line generated by make.  Here are some
1089    #    special considerations:
1090    #    1. Use "connect" and "accept" to check for -lsocket, and
1091    #       "gethostbyname" to check for -lnsl.
1092    #    2. Use each function name only once:  can't redo a check because
1093    #       autoconf caches the results of the last check and won't redo it.
1094    #    3. Use -lnsl and -lsocket only if they supply procedures that
1095    #       aren't already present in the normal libraries.  This is because
1096    #       IRIX 5.2 has libraries, but they aren't needed and they're
1097    #       bogus:  they goof up name resolution if used.
1098    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1099    #       To get around this problem, check for both libraries together
1100    #       if -lsocket doesn't work by itself.
1101    #--------------------------------------------------------------------
1102
1103    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1104     [gcj_cv_lib_sockets=
1105      gcj_checkBoth=0
1106      unset ac_cv_func_connect
1107      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1108      if test "$gcj_checkSocket" = 1; then
1109          unset ac_cv_func_connect
1110          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1111                       gcj_checkBoth=1)
1112      fi
1113      if test "$gcj_checkBoth" = 1; then
1114          gcj_oldLibs=$LIBS
1115          LIBS="$LIBS -lsocket -lnsl"
1116          unset ac_cv_func_accept
1117          AC_CHECK_FUNC(accept,
1118                        [gcj_checkNsl=0
1119                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1120          unset ac_cv_func_accept
1121          LIBS=$gcj_oldLibs
1122      fi
1123      unset ac_cv_func_gethostbyname
1124      gcj_oldLibs=$LIBS
1125      LIBS="$LIBS $gcj_cv_lib_sockets"
1126      AC_CHECK_FUNC(gethostbyname, ,
1127                    [AC_CHECK_LIB(nsl, main,
1128                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1129      unset ac_cv_func_gethostbyname
1130      LIBS=$gcj_oldLIBS
1131    ])
1132    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1133
1134    if test "$with_system_zlib" = yes; then
1135       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1136    fi
1137
1138    # Test for Gtk stuff, if asked for.
1139    if test "$use_gtk_awt" = yes; then
1140       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1141       AC_SUBST(GTK_CFLAGS)
1142       AC_SUBST(GTK_LIBS)
1143
1144       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1145       AC_SUBST(GLIB_CFLAGS)
1146       AC_SUBST(GLIB_LIBS)
1147
1148       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1149       AC_SUBST(LIBART_CFLAGS)
1150       AC_SUBST(LIBART_LIBS)
1151
1152       # We require the XTest Extension to support java.awt.Robot.
1153       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1154                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1155                    [${X_LIBS}])
1156    fi
1157
1158    # On Solaris, and maybe other architectures, the Boehm collector
1159    # requires -ldl.
1160    if test "$GC" = boehm; then
1161       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1162    fi
1163 fi
1164
1165 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1166 case $build in
1167     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1168     *)         CLASSPATH_SEPARATOR=':' ;;
1169 esac
1170 AC_SUBST(CLASSPATH_SEPARATOR)
1171
1172 # We must search the source tree for java.lang, since we still don't
1173 # have libgcj.jar nor java/lang/*.class
1174 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1175 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1176
1177 # Since some classes depend on this one, we need its source available
1178 # before we can do any GCJ compilation test :-(
1179 if test ! -f gnu/classpath/Configuration.java; then
1180   test -d gnu || mkdir gnu
1181   test -d gnu/classpath || mkdir gnu/classpath
1182   # Note that it is not crucial that all the values here be correct.
1183   sed -e "s,@prefix@,$prefix," \
1184       -e "s,@VERSION@,$VERSION," \
1185       -e "s,@LIBDEBUG@,false," \
1186       -e "s,@INIT_LOAD_LIBRARY@,false," \
1187       -e "s,@@,$LIBGCJDEBUG," \
1188       -e "s,@default_toolkit@,$TOOLKIT," \
1189       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1190       -e "s,@GTK_CAIRO_ENABLED@,false," \
1191         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1192         > gnu/classpath/Configuration.java
1193   # We do not want to redirect the output of the grep below to /dev/null,
1194   # but we add /dev/null to the input list so that grep will print the
1195   # filename of Configuration.java in case it finds any matches.
1196   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1197     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1198   fi
1199 fi
1200
1201 LT_AC_PROG_GCJ
1202
1203 # Now remove it.
1204 rm -f gnu/classpath/Configuration.java
1205
1206 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1207
1208 AC_CHECK_SIZEOF(void *)
1209
1210 AC_C_BIGENDIAN
1211
1212 ZLIBS=
1213 SYS_ZLIBS=
1214 ZINCS=
1215
1216 if test -z "$ZLIBSPEC"; then
1217    # Use zlib from the GCC tree.
1218    ZINCS='-I$(top_srcdir)/../zlib'
1219    ZLIBS=../zlib/libzgcj_convenience.la
1220 else
1221    # System's zlib.
1222    SYS_ZLIBS="$ZLIBSPEC"
1223 fi
1224 AC_SUBST(ZLIBS)
1225 AC_SUBST(SYS_ZLIBS)
1226 AC_SUBST(ZINCS)
1227 AC_SUBST(DIVIDESPEC)
1228 AC_SUBST(CHECKREFSPEC)
1229 AC_SUBST(EXCEPTIONSPEC)
1230 AC_SUBST(BACKTRACESPEC)
1231 AC_SUBST(IEEESPEC)
1232
1233 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1234 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1235 AC_SUBST(GCC_UNWIND_INCLUDE)
1236
1237 # Process the option "--enable-version-specific-runtime-libs"
1238 # Calculate toolexeclibdir
1239 case ${version_specific_libs} in
1240   yes)
1241     # Need the gcc compiler version to know where to install libraries
1242     # and header files if --enable-version-specific-runtime-libs option
1243     # is selected.
1244     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1245     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1246     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1247     toolexeclibdir=$toolexecmainlibdir
1248     ;;
1249   no)
1250     if test -n "$with_cross_host" &&
1251        test x"$with_cross_host" != x"no"; then
1252       # Install a library built with a cross compiler in tooldir, not libdir.
1253       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1254       toolexecmainlibdir='$(toolexecdir)/lib'
1255     else
1256       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1257       toolexecmainlibdir='$(libdir)'
1258     fi
1259     multi_os_directory=`$CC -print-multi-os-directory`
1260     case $multi_os_directory in
1261       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1262       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1263     esac
1264     ;;
1265 esac
1266 AC_SUBST(toolexecdir)
1267 AC_SUBST(toolexecmainlibdir)
1268 AC_SUBST(toolexeclibdir)
1269
1270 # Determine where the standard .db file and GNU Classpath JNI
1271 # libraries are found.
1272 multi_os_directory=`$CC -print-multi-os-directory`
1273 case $multi_os_directory in
1274   .)
1275    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1276    ac_configure_args="$ac_configure_args --with-native-libdir=\$\(libdir\)/gcj-`cat $srcdir/../gcc/BASE-VER`"
1277    ;;
1278   *)
1279    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1280    ac_configure_args="$ac_configure_args --with-native-libdir=\$\(libdir\)/$multi_os_directory/gcj-`cat $srcdir/../gcc/BASE-VER`"
1281    ;;
1282 esac
1283 AC_SUBST(dbexecdir)
1284
1285 # Determine gcj version number.
1286 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1287 GCJVERSION=$gcjversion
1288 AC_SUBST(GCJVERSION)
1289 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1290
1291 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1292 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1293
1294 TL_AC_GXX_INCLUDE_DIR
1295
1296 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1297 # On that system, sys/ioctl.h will not include sys/filio.h unless
1298 # BSD_COMP is defined; just including sys/filio.h is simpler.
1299 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1300 # for now.  If you change this, you also must update natFile.cc.
1301 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1302                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1303                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1304                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1305                   dirent.h sys/rw_lock.h ifaddrs.h])
1306 AC_CHECK_HEADERS(inttypes.h, [
1307     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1308     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1309 ])
1310 AC_HEADER_SYS_WAIT
1311
1312 AC_CHECK_TYPE([ssize_t], [int])
1313
1314 AC_MSG_CHECKING([for in_addr_t])
1315 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1316 #if STDC_HEADERS
1317 #include <stdlib.h>
1318 #include <stddef.h>
1319 #endif
1320 #if HAVE_NETINET_IN_H
1321 #include <netinet/in.h>
1322 #endif]], [[in_addr_t foo;]])],
1323   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1324      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1325    AC_MSG_RESULT(yes)],
1326   [AC_MSG_RESULT(no)])
1327
1328 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1329 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1330   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1331      [Define if struct ip_mreq is defined in netinet/in.h.])
1332    AC_MSG_RESULT(yes)],
1333   [AC_MSG_RESULT(no)])
1334
1335 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1336 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1337   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1338      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1339    AC_MSG_RESULT(yes)],
1340   [AC_MSG_RESULT(no)])
1341
1342 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1343 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1344   [AC_DEFINE(HAVE_INET6, 1,
1345      [Define if inet6 structures are defined in netinet/in.h.])
1346    AC_MSG_RESULT(yes)],
1347   [AC_MSG_RESULT(no)])
1348
1349 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1350 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1351 #include <sys/types.h>
1352 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1353   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1354    AC_MSG_RESULT(yes)],
1355   [AC_MSG_RESULT(no)])
1356
1357 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1358 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1359   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1360    AC_MSG_RESULT(yes)],
1361   [AC_MSG_RESULT(no)
1362    AC_MSG_CHECKING([for global timezone variable])
1363    dnl FIXME: we don't want a link check here because that won't work
1364    dnl when cross-compiling.  So instead we make an assumption that
1365    dnl the header file will mention timezone if it exists.
1366    dnl Don't find the win32 function timezone
1367    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1368      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1369       AC_MSG_RESULT(yes)],
1370      [AC_MSG_RESULT(no)
1371        AC_MSG_CHECKING([for global _timezone variable])
1372        dnl FIXME: As above, don't want link check
1373        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1374          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1375             [Define if your platform has the global _timezone variable.])
1376           AC_MSG_RESULT(yes)],
1377           [AC_MSG_RESULT(no)])])])
1378
1379 AC_FUNC_ALLOCA
1380
1381 AC_CHECK_PROGS(PERL, perl, false)
1382
1383 SYSDEP_SOURCES=
1384 SIGNAL_HANDLER_AUX=
1385
1386 case "${host}" in
1387  i?86-*-linux*)
1388     SIGNAL_HANDLER=include/i386-signal.h
1389     ;;
1390  sparc*-sun-solaris*)
1391     SIGNAL_HANDLER=include/sparc-signal.h
1392     ;;
1393 # ia64-*)
1394 #    SYSDEP_SOURCES=sysdep/ia64.c
1395 #    test -d sysdep || mkdir sysdep
1396 #    ;;
1397  hppa*-*-linux*)
1398     SIGNAL_HANDLER=include/pa-signal.h
1399     ;;
1400  hppa*-hp-hpux*)
1401     SIGNAL_HANDLER=include/hppa-signal.h
1402     ;;
1403  ia64-*-linux*)
1404     SIGNAL_HANDLER=include/dwarf2-signal.h
1405     ;;
1406  powerpc*-*-linux*)
1407     SIGNAL_HANDLER=include/powerpc-signal.h
1408     ;;
1409  alpha*-*-linux*)
1410     SIGNAL_HANDLER=include/dwarf2-signal.h
1411     ;;
1412  s390*-*-linux*)
1413     SIGNAL_HANDLER=include/s390-signal.h
1414     ;;
1415  x86_64*-*-linux*)
1416     SIGNAL_HANDLER=include/x86_64-signal.h
1417     SIGNAL_HANDLER_AUX=include/i386-signal.h
1418     ;;
1419  sparc*-*-linux*)
1420     SIGNAL_HANDLER=include/dwarf2-signal.h
1421     ;;
1422  sh*-*-linux*)
1423     SIGNAL_HANDLER=include/sh-signal.h
1424     ;;
1425  *mingw*)
1426     SIGNAL_HANDLER=include/win32-signal.h
1427     ;;
1428  mips*-*-linux*)
1429     SIGNAL_HANDLER=include/mips-signal.h
1430     ;;
1431  *-*-darwin*)
1432     SIGNAL_HANDLER=include/darwin-signal.h
1433     ;;
1434  *)
1435     SIGNAL_HANDLER=include/default-signal.h
1436     ;;
1437 esac
1438
1439 # If we're using sjlj exceptions, forget what we just learned.
1440 if test "$enable_sjlj_exceptions" = yes; then
1441    SIGNAL_HANDLER=include/default-signal.h
1442    SIGNAL_HANDLER_AUX=
1443 fi
1444
1445 AC_SUBST(SYSDEP_SOURCES)
1446
1447 if test -z "$SIGNAL_HANDLER_AUX"; then
1448   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1449 fi
1450
1451 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1452                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1453
1454 if test "${multilib}" = "yes"; then
1455   multilib_arg="--enable-multilib"
1456 else
1457   multilib_arg=
1458 fi
1459
1460 # See if we support thread-local storage.
1461 GCC_CHECK_TLS
1462
1463 # Check if linker supports static linking on a per library basis
1464 LD_START_STATIC_SPEC=
1465 LD_FINISH_STATIC_SPEC=
1466 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1467   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1468     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1469     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1470   fi
1471 fi
1472 AC_SUBST(LD_START_STATIC_SPEC)
1473 AC_SUBST(LD_FINISH_STATIC_SPEC)
1474
1475 here=`${PWDCMD-pwd}`
1476 AC_SUBST(here)
1477
1478 # We get this from the environment.
1479 AC_SUBST(GCJFLAGS)
1480
1481 AC_CONFIG_FILES([
1482 Makefile
1483 libgcj.pc
1484 libgcj.spec
1485 libgcj-test.spec
1486 gcj/Makefile
1487 include/Makefile
1488 testsuite/Makefile
1489 ])
1490
1491 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1492
1493 AC_CONFIG_COMMANDS([default],
1494 [# Only add multilib support code if we just rebuilt top-level Makefile.
1495 case " $CONFIG_FILES " in
1496  *" Makefile "*)
1497    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1498    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1499    ;;
1500 esac
1501 for ac_multi_file in $CONFIG_FILES; do
1502   case $ac_multi_file in
1503   */Makefile)
1504     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1505   esac
1506 done
1507 ],
1508 srcdir=${srcdir}
1509 host=${host}
1510 target=${target}
1511 with_multisubdir=${with_multisubdir}
1512 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1513 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1514 libgcj_basedir=${libgcj_basedir}
1515 CC="${CC}"
1516 CXX="${CXX}"
1517 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1518 )
1519
1520 AC_OUTPUT