libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename_force([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209 #       libgcj_sublib_ltflags - host specific Libtool flags
 210 #                          (only used when building sublibs)
 211 # and a number of others; see the list at the start of the file.
 212
 213 libgcj_cflags=
 214 libgcj_cxxflags=
 215 libgcj_javaflags=
 216 libgcj_sublib_ltflags=
 217
 218 . ${srcdir}/configure.host
 219
 220 ACX_PROG_LD_GNU_SYMBOLIC
 221 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 222 if test -z "$libgcj_ld_symbolic"; then
 223   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 224 fi
 225
 226 LIBGCJ_CFLAGS="${libgcj_cflags}"
 227 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 228 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 229 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 230 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 231 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 232 AC_SUBST(LIBGCJ_CFLAGS)
 233 AC_SUBST(LIBGCJ_CXXFLAGS)
 234 AC_SUBST(LIBGCJ_JAVAFLAGS)
 235 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 236 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 237 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 238
 239 # Only use libltdl for non-newlib builds.
 240 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 241    AC_LTDL_SHLIBPATH
 242 fi
 243
 244 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 245
 246 # Possibly build libgcj as many sub-libraries.
 247 AC_ARG_ENABLE(libgcj-sublibs,
 248   AS_HELP_STRING([--enable-libgcj-sublibs],
 249                  [build libgcj as many sub-libraries]))
 250
 251 if test -z "$enable_libgcj_sublibs"; then
 252    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 253 fi
 254 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 255 if test "$enable_libgcj_sublibs" = yes ; then
 256   # In theory we could make do with only one override and simply
 257   # tag "_bc" onto the end of it when we use it to generate the
 258   # spec, but that's an ugly thing to do when there are multiple
 259   # words in the string and you're relying on the ordering to
 260   # append the correct one.
 261   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 262   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 263 fi
 264
 265
 266 # See if the user has requested runtime debugging.
 267 LIBGCJDEBUG="disable"
 268 AC_SUBST(LIBGCJDEBUG)
 269 AC_ARG_ENABLE(libgcj-debug,
 270   AS_HELP_STRING([--enable-libgcj-debug],
 271                  [enable runtime debugging code]),
 272   [if test "$enable_libgcj_debug" = yes; then
 273     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 274     LIBGCJDEBUG="enable"
 275   fi])
 276
 277 AC_ARG_WITH([escher],
 278          AS_HELP_STRING([--with-escher=ABS.PATH],
 279                         [specify path to escher dir or JAR for X peers]))
 280 case "$with_escher" in
 281 "")
 282         use_escher=false
 283         ;;
 284 "no")
 285         use_escher=false
 286         ;;
 287 "yes")
 288         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 289         ;;
 290 *)
 291         use_escher=true
 292         ;;
 293 esac
 294
 295 # Determine which AWT peer libraries to build
 296 AC_ARG_ENABLE(java-awt,
 297   AS_HELP_STRING([--enable-java-awt],
 298                  [list of AWT peer implementations to be built]))
 299
 300 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 301 use_xlib_awt=""
 302 use_gtk_awt=""
 303 use_qt_awt=""
 304 use_x_awt=""
 305 # The default toolkit to use is the first one specified.
 306 TOOLKIT=
 307 AC_SUBST(TOOLKIT)
 308
 309 for peer in $peerlibs ; do
 310   case $peer in
 311     xlib)
 312       if test "$no_x" = yes; then
 313         echo "*** xlib peers requested but no X library available" 1>&2
 314         exit 1
 315       else
 316         use_xlib_awt="yes"
 317         if test -z "$TOOLKIT"; then
 318            TOOLKIT=gnu.awt.xlib.XToolkit
 319         fi
 320       fi
 321       ;;
 322     gtk)
 323       if test "$no_x" = yes; then
 324          echo "*** gtk peers requested but no X library available" 1>&2
 325          exit 1
 326       else
 327          use_gtk_awt=yes
 328          if test -z "$TOOLKIT"; then
 329             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 330          fi
 331       fi
 332       ;;
 333     qt)
 334       if test "$no_x" = yes; then
 335          # Perhaps we should admit the possibility of embedded Qt.
 336          echo "*** Qt peers requested but no X library available" 1>&2
 337          exit 1
 338       else
 339          use_qt_awt=yes
 340          if test -z "$TOOLKIT"; then
 341             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 342          fi
 343       fi
 344       ;;
 345     x)
 346       use_x_awt=yes
 347       if test -z "$TOOLKIT"; then
 348          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 349       fi
 350       ;;
 351     no)
 352       use_xlib_awt=
 353       use_gtk_awt=
 354       use_qt_awt=
 355       use_x_awt=
 356       break
 357       ;;
 358     *)
 359       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 360       exit 1
 361   esac
 362 done
 363
 364 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 365 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 366
 367 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 368
 369 expanded_prefix=$prefix
 370 if test "X$prefix" = XNONE; then
 371   expanded_prefix=${ac_default_prefix}
 372 fi
 373
 374 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 375
 376 # Create standard.omit based on decisions we just made.
 377 cp $srcdir/standard.omit.in standard.omit
 378 if test "$use_xlib_awt" != yes; then
 379    echo gnu/awt/xlib >> standard.omit
 380    echo gnu/gcj/xlib >> standard.omit
 381 fi
 382 if test "$use_x_awt" != yes; then
 383    echo gnu/java/awt/peer/x >> standard.omit
 384 fi
 385
 386 # Tools that need to be compiled against classpath's tools classes
 387 : > vm-tools-packages
 388 for package in gnu/gcj/tools/gc_analyze ; do
 389     echo $package >> standard.omit
 390     echo $package >> vm-tools-packages
 391 done
 392
 393 if test -z "${with_multisubdir}"; then
 394    builddotdot=.
 395 else
 396    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 397 fi
 398
 399 NATIVE=yes
 400
 401 # Which gcj and host gcj (for ecjx) do we use?
 402 which_gcj=default
 403 host_exeext=${ac_exeext}
 404 GCJ_FOR_ECJX=
 405 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 406 if test -n "${with_cross_host}"; then
 407   # We are being configured with a cross compiler. We can't
 408   # use ac_exeext, because that is for the target platform.
 409   NATIVE=no
 410   cross_host_exeext=
 411   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 412   case "${with_cross_host}" in
 413      *mingw* | *cygwin*)
 414          cross_host_exeext=.exe
 415      ;;
 416   esac
 417   host_exeext=${cross_host_exeext}
 418   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 419      if test x"$build_noncanonical" = x"$with_cross_host"; then
 420         # Ordinary cross (host!=target and host=build)
 421         which_gcj=built
 422      else
 423         # Canadian cross (host!=target and host!=build)
 424         which_gcj=cross
 425      fi
 426   else
 427      which_gcj=cross
 428   fi
 429 else
 430   # We are being configured with a native or crossed-native compiler
 431   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 432      if test x"$build" = x"$host"; then
 433         # True native build (host=target and host=build)
 434         which_gcj=built
 435      else
 436         # Crossed-native build (host=target and host!=build)
 437         which_gcj=cross
 438      fi
 439   else
 440      which_gcj=path
 441   fi
 442 fi
 443 libgcjdir=`${PWDCMD-pwd}`
 444 case $GCJ in
 445 *" -B"*)
 446   # Just in case there is a comma in the build dir, quote it for the
 447   # sed command below.
 448   case $libgcjdir in
 449   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 450   *) qlibgcjdir=$libgcjdir;;
 451   esac
 452   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 453   ;;
 454 *)
 455   GCJ=$GCJ" -B$libgcjdir/"
 456   ;;
 457 esac
 458 case "${which_gcj}" in
 459    built)
 460       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 461    ;;
 462    cross)
 463       if test "x${with_newlib}" = "xyes"; then
 464          # FIXME (comment): Why is this needed?
 465          GCC_UNWIND_INCLUDE=
 466       fi
 467       GCJH='$(target_noncanonical)-gcjh'
 468    ;;
 469    path)
 470       GCJH=gcjh
 471    ;;
 472 esac
 473 JAVAC="$GCJ -C"
 474 export JAVAC
 475
 476 AC_SUBST(GCJ_FOR_ECJX)
 477 AC_SUBST(GCJH)
 478 AC_SUBST(host_exeext)
 479
 480 # Create it, so that compile/link tests don't fail
 481 test -f libgcj.spec || touch libgcj.spec
 482
 483
 484
 485 # Set up to configure Classpath.
 486 # FIXME: no supported way to pass args in autoconf.
 487 # Disable tool wrappers to avoid ltdl.h configure check.
 488 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 489 ac_configure_args="$ac_configure_args --disable-load-library"
 490 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 491 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 492 dir1=`cd $srcdir && pwd`
 493 dir2=`pwd`
 494 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 495 ac_configure_args="$ac_configure_args --disable-core-jni"
 496 dnl FIXME?
 497 ac_configure_args="$ac_configure_args --disable-examples"
 498 ac_configure_args="$ac_configure_args --with-glibj=build"
 499 if test "$browser_plugin_enabled" != yes; then
 500   ac_configure_args="$ac_configure_args --disable-plugin"
 501 else
 502   ac_configure_args="$ac_configure_args --enable-plugin"
 503 fi
 504 if test "$gconf_enabled" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 506   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 507 fi
 508 if test "$use_gtk_awt" != yes; then
 509   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 510 fi
 511 if test "$use_qt_awt" != yes; then
 512   ac_configure_args="$ac_configure_args --disable-qt-peer"
 513 else
 514   # We need this as qt is disabled by default in classpath.
 515   ac_configure_args="$ac_configure_args --enable-qt-peer"
 516 fi
 517 if test "$use_x_awt" != yes; then
 518   ac_configure_args="$ac_configure_args --without-escher"
 519 else
 520   # We need this as escher is disabled by default in classpath.
 521   if test "$use_escher" != true; then
 522     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 523   else
 524     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 525   fi
 526 fi
 527 if test "x$BUILD_GJDOC" = xno; then
 528   ac_configure_args="$ac_configure_args --disable-gjdoc"
 529 fi
 530 # -Werror causes unavoidable problems in code using alsa.
 531 ac_configure_args="$ac_configure_args --disable-regen-headers"
 532 ac_configure_args="$ac_configure_args --disable-Werror"
 533 dnl --with-gcj=$GCJ
 534 dnl --with-javah=$GCJH
 535 dnl gtk-cairo -- just export here...
 536 dnl --enable-regen-headers?
 537
 538 # Only use libltdl for non-newlib builds.
 539 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 540    AC_LIBLTDL_CONVENIENCE
 541    AC_LIBTOOL_DLOPEN
 542    DIRLTDL=libltdl
 543    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 544    # Sigh.  Libtool's macro doesn't do the right thing.
 545    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 546    # FIXME: this is a hack.
 547    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 548    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 549 fi
 550 AC_SUBST(INCLTDL)
 551 AC_SUBST(LIBLTDL)
 552 AC_SUBST(DIRLTDL)
 553 AC_PROG_LIBTOOL
 554 AM_PROG_GCJ
 555 AM_PROG_CC_C_O
 556
 557 AC_CONFIG_SUBDIRS(classpath libltdl)
 558
 559 # The -no-testsuite modules omit the test subdir.
 560 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 561
 562 # Should the runtime set system properties by examining the
 563 # environment variable GCJ_PROPERTIES?
 564 AC_ARG_ENABLE(getenv-properties,
 565   AS_HELP_STRING([--disable-getenv-properties],
 566                  [don't set system properties from GCJ_PROPERTIES]))
 567
 568 # Whether GCJ_PROPERTIES is used depends on the target.
 569 if test -z "$enable_getenv_properties"; then
 570    enable_getenv_properties=${enable_getenv_properties_default-yes}
 571 fi
 572 if test "$enable_getenv_properties" = no; then
 573    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 574      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 575 fi
 576
 577 # Whether we should use arguments to main()
 578 if test -z "$enable_main_args"; then
 579    enable_main_args=${enable_main_args_default-yes}
 580 fi
 581 if test "$enable_main_args" = no; then
 582    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 583 fi
 584
 585
 586 # Should we use hashtable-based synchronization?
 587 # Currently works only for Linux X86/ia64
 588 # Typically faster and more space-efficient
 589 AC_ARG_ENABLE(hash-synchronization,
 590   AS_HELP_STRING([--enable-hash-synchronization],
 591                  [use global hash table for monitor locks]))
 592
 593 if test -z "$enable_hash_synchronization"; then
 594    enable_hash_synchronization=$enable_hash_synchronization_default
 595 fi
 596
 597
 598 install_ecj_jar=no
 599 ECJ_BUILD_JAR=
 600 ECJ_JAR=
 601 AC_ARG_WITH(ecj-jar,
 602         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 603         [ECJ_JAR=$withval],
 604         [if test -f $multi_basedir/ecj.jar; then
 605            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 606            ECJ_JAR='$(jardir)/ecj.jar'
 607            install_ecj_jar=yes
 608          fi])
 609 AC_SUBST(ECJ_BUILD_JAR)
 610 AC_SUBST(ECJ_JAR)
 611 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 612 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 613
 614 AC_ARG_WITH(java-home,
 615   AS_HELP_STRING([--with-java-home=DIRECTORY],
 616                  [value of java.home system property]),
 617                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 618 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 619 AC_SUBST(JAVA_HOME)
 620
 621 suppress_libgcj_bc=no
 622 AC_ARG_ENABLE(libgcj-bc,
 623   AS_HELP_STRING([--enable-libgcj-bc],
 624                  [enable(default) or disable BC ABI for portions of libgcj]),
 625   [if test "$enable_libgcj_bc" = "no"; then
 626      suppress_libgcj_bc=yes
 627    fi])
 628 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 629
 630 build_libgcj_reduced_reflection=no
 631 AC_ARG_ENABLE(reduced-reflection,
 632   AS_HELP_STRING([--enable-reduced-reflection],
 633                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 634   [if test "$enable_reduced_reflection" = "yes"; then
 635      build_libgcj_reduced_reflection=yes
 636    fi])
 637 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 638
 639 # What is the native OS API for MinGW?
 640 AC_ARG_WITH(win32-nlsapi,
 641   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 642                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 643 [case "${withval}" in
 644   ansi) with_win32_nlsapi=ansi ;;
 645   unicows) with_win32_nlsapi=unicows ;;
 646   unicode) with_win32_nlsapi=unicode ;;
 647   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 648 esac],[with_win32_nlsapi=ansi])
 649
 650 case "${with_win32_nlsapi}" in
 651   unicows | unicode)
 652     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 653       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 654     ;;
 655 esac
 656
 657 # configure.host sets slow_pthread_self if the synchronization code should
 658 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 659 if test "${slow_pthread_self}" = "yes"; then
 660   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 661     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 662 fi
 663
 664 # Check for gc debugging.  This option is handled both here and in the GC.
 665 AC_ARG_ENABLE(gc-debug,
 666    AS_HELP_STRING([--enable-gc-debug],
 667                   [include full support for pointer backtracing etc.]),
 668 [ if test "$enable_gc_debug" = "yes"; then
 669     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 670               [Define if we want to use debug calls into the garbage collector.])
 671   fi])
 672
 673 # See if the user has the interpreter included.
 674 AC_ARG_ENABLE(interpreter,
 675   AS_HELP_STRING([--enable-interpreter],
 676                  [enable interpreter]),
 677   [if test "$enable_interpreter" = yes; then
 678     # This can also be set in configure.host.
 679     libgcj_interpreter=yes
 680   elif test "$enable_interpreter" = no; then
 681     libgcj_interpreter=no
 682   fi])
 683
 684 if test "$libgcj_interpreter" = yes; then
 685    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 686 fi
 687 INTERPRETER="$libgcj_interpreter"
 688 AC_SUBST(INTERPRETER)
 689 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 690
 691 AC_MSG_CHECKING([for exception model to use])
 692 AC_LANG_PUSH(C++)
 693 AC_ARG_ENABLE(sjlj-exceptions,
 694   AS_HELP_STRING([--enable-sjlj-exceptions],
 695                  [force use of builtin_setjmp for exceptions]),
 696 [:],
 697 [dnl Botheration.  Now we've got to detect the exception model.
 698 dnl Link tests against libgcc.a are problematic since -- at least
 699 dnl as of this writing -- we've not been given proper -L bits for
 700 dnl single-tree newlib and libgloss.
 701 dnl
 702 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 703 dnl conftest files before we got a change to grep them first.
 704 cat > conftest.$ac_ext << EOF
 705 [#]line __oline__ "configure"
 706 struct S { ~S(); };
 707 void bar();
 708 void foo()
 709 {
 710   S s;
 711   bar();
 712 }
 713 EOF
 714 old_CXXFLAGS="$CXXFLAGS"
 715 CXXFLAGS=-S
 716 if AC_TRY_EVAL(ac_compile); then
 717   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 718     enable_sjlj_exceptions=yes
 719   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 720     enable_sjlj_exceptions=no
 721   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 722     # ARM EH ABI.
 723     enable_sjlj_exceptions=no
 724   fi
 725 fi
 726 CXXFLAGS="$old_CXXFLAGS"
 727 rm -f conftest*])
 728 if test x$enable_sjlj_exceptions = xyes; then
 729   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 730         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 731   ac_exception_model_name=sjlj
 732 elif test x$enable_sjlj_exceptions = xno; then
 733   ac_exception_model_name="call frame"
 734 else
 735   AC_MSG_ERROR([unable to detect exception model])
 736 fi
 737 AC_LANG_POP(C++)
 738 AC_MSG_RESULT($ac_exception_model_name)
 739
 740 # If we are non using SJLJ exceptions, and this host does not have support
 741 # for unwinding from a signal handler, enable checked dereferences and divides.
 742 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 743   CHECKREFSPEC=-fcheck-references
 744   DIVIDESPEC=-fuse-divide-subroutine
 745   EXCEPTIONSPEC=
 746 fi
 747
 748 # See if the user wants to disable java.net.  This is the mildly
 749 # ugly way that we admit that target-side configuration sucks.
 750 AC_ARG_ENABLE(java-net,
 751   AS_HELP_STRING([--disable-java-net],
 752                  [disable java.net]))
 753
 754 # Whether java.net is built by default can depend on the target.
 755 if test -z "$enable_java_net"; then
 756    enable_java_net=${enable_java_net_default-yes}
 757 fi
 758 if test "$enable_java_net" = no; then
 759    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 760 fi
 761
 762 # See if the user wants to configure without libffi.  Some
 763 # architectures don't support it, and default values are set in
 764 # configure.host.
 765 AC_ARG_WITH(libffi,
 766   AS_HELP_STRING([--without-libffi],
 767                  [don't use libffi]),
 768   [:],
 769   [with_libffi=${with_libffi_default-yes}])
 770
 771 LIBFFI=
 772 LIBFFIINCS=
 773 if test "$with_libffi" != no; then
 774    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 775    LIBFFI=../libffi/libffi_convenience.la
 776    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 777 fi
 778 AC_SUBST(LIBFFI)
 779 AC_SUBST(LIBFFIINCS)
 780
 781 # See if the user wants to disable JVMPI support.
 782 AC_ARG_ENABLE(jvmpi,
 783   AS_HELP_STRING([--disable-jvmpi],
 784                  [disable JVMPI support]))
 785
 786 if test "$enable_jvmpi" != no; then
 787     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 788 fi
 789
 790 # If the target is an eCos system, use the appropriate eCos
 791 # I/O routines.
 792 # FIXME: this should not be a local option but a global target
 793 # system; at present there is no eCos target.
 794 TARGET_ECOS=${PROCESS-"no"}
 795 AC_ARG_WITH(ecos,
 796 [  --with-ecos             enable runtime eCos target support],
 797 TARGET_ECOS="$with_ecos"
 798 )
 799
 800 case "$TARGET_ECOS" in
 801    no) case "$host" in
 802       *mingw*)
 803             PLATFORM=Win32
 804             PLATFORMNET=Win32
 805             PLATFORMH=win32.h
 806         CHECK_FOR_BROKEN_MINGW_LD
 807       ;;
 808       *)
 809             PLATFORM=Posix
 810             PLATFORMNET=Posix
 811             PLATFORMH=posix.h
 812       ;;
 813       esac
 814       ;;
 815    *)
 816       PLATFORM=Ecos
 817       PLATFORMNET=NoNet
 818       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 819       PLATFORMH=posix.h
 820       ;;
 821 esac
 822 AC_SUBST(PLATFORM)
 823 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 824
 825 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 826                                       [Define if you have int32_t and uint32_t.]))
 827 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 828                                         [Define if you have int32_t and uint32_t.]))
 829 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 830                                           [Define if you have u_int32_t]))
 831 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 832                                            [Define if you have u_int32_t]))
 833
 834 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 835 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 836
 837 case "$host" in
 838   *-darwin*) DARWIN_CRT=true ;;
 839   *) DARWIN_CRT=false ;;
 840 esac
 841 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 842
 843 # This may not be defined in a non-ANS conformant embedded system.
 844 # FIXME: Should these case a runtime exception in that case?
 845 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 846                                   [Define is you have 'localtime' in <time.h>]))
 847
 848 # Create the subdirectory for natFile.cc, or the attempt
 849 # to create the link will fail.
 850 test -d java || mkdir java
 851 test -d java/io || mkdir java/io
 852 test -d gnu || mkdir gnu
 853 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 854
 855 # Likewise for natConcreteProcess.cc.
 856 test -d java/lang || mkdir java/lang
 857 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 858
 859 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 860 test -d java/net || mkdir java/net
 861 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 862 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 863
 864 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 865 test -d gnu/java || mkdir gnu/java
 866 test -d gnu/java/net || mkdir gnu/java/net
 867 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 868 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 869
 870 # Likewise for natVMPipe.cc and natVMSelector.cc.
 871 test -d gnu/java/nio || mkdir gnu/java/nio
 872 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 873 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 874
 875 # Likewise for natFileChannelImpl.cc
 876 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 877 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 878
 879 # Likewise for natVMSecureRandom.cc
 880 test -d gnu/java/security || mkdir gnu/java/security
 881 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 882 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 883 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 884
 885 case "${host}" in
 886     *mingw*)
 887       SYSTEMSPEC="-lgdi32 -lws2_32"
 888       if test "${with_win32_nlsapi}" = "unicows"; then
 889         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 890       fi
 891     ;;
 892     *)
 893       SYSTEMSPEC=
 894     ;;
 895 esac
 896 AC_SUBST(SYSTEMSPEC)
 897
 898 AC_ARG_WITH(system-zlib,
 899   AS_HELP_STRING([--with-system-zlib],
 900                  [use installed libz]))
 901 ZLIBSPEC=
 902 AC_SUBST(ZLIBSPEC)
 903 ZLIBTESTSPEC=
 904 AC_SUBST(ZLIBTESTSPEC)
 905
 906 AC_PATH_XTRA
 907
 908 # FIXME: this should be _libs on some hosts.
 909 libsubdir=.libs
 910
 911 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 912
 913 LIBSTDCXXSPEC=
 914 # extra LD Flags which are required for targets
 915 case "${host}" in
 916 *-*-darwin[[0-7]].*)
 917     # For now we have to disable it on darwin[8-9] because it slows down
 918     # the linking phase. A possible bug in ld?
 919     # on Darwin -single_module speeds up loading of the dynamic libraries.
 920     extra_ldflags_libjava=-Wl,-single_module
 921     ;;
 922 *-*-darwin[[912]]*)
 923     extra_gij_ldflags=-Wl,-allow_stack_execute
 924     ;;
 925 arm*linux*eabi)
 926     # Some of the ARM unwinder code is actually in libstdc++.  We
 927     # could in principle replicate it in libgcj, but it's better to
 928     # have a dependency on libstdc++.
 929     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 930     LIBSTDCXXSPEC=-lstdc++
 931     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 932     ;;
 933 *-*-cygwin)
 934     extra_ldflags_libjava=-liconv
 935     ;;
 936 esac
 937 AC_SUBST(extra_ldflags_libjava)
 938 AC_SUBST(extra_gij_ldflags)
 939 AC_SUBST(extra_ldflags)
 940 AC_SUBST(LIBSTDCXXSPEC)
 941
 942 AC_SUBST(LIBGCJTESTSPEC)
 943
 944 # Allow the GC to be disabled.  Can be useful when debugging.
 945 AC_MSG_CHECKING([for garbage collector to use])
 946 AC_ARG_ENABLE(java-gc,
 947   AS_HELP_STRING([--enable-java-gc=TYPE],
 948                  [choose garbage collector (default is boehm)]),
 949   [GC=$enableval],
 950   [GC=boehm])
 951 GCLIBS=
 952 GCINCS=
 953 GCDEPS=
 954 GCSPEC=
 955 JC1GCSPEC=
 956 GCTESTSPEC=
 957 case "$GC" in
 958  boehm)
 959     AC_MSG_RESULT(boehm)
 960     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 961     JC1GCSPEC='-fuse-boehm-gc'
 962     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 963     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 964     GCOBJS=boehm.lo
 965     GCHDR=boehm-gc.h
 966     # The POSIX thread support needs to know this.
 967     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 968     ;;
 969  no)
 970     AC_MSG_RESULT(none)
 971     GCHDR=no-gc.h
 972     ;;
 973  *)
 974     AC_MSG_ERROR([unrecognized collector "$GC"])
 975     ;;
 976 esac
 977 AC_SUBST(GCLIBS)
 978 AC_SUBST(GCINCS)
 979 AC_SUBST(GCDEPS)
 980 AC_SUBST(GCSPEC)
 981 AC_SUBST(JC1GCSPEC)
 982 AC_SUBST(GCTESTSPEC)
 983 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 984 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 985 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 986
 987
 988 AC_MSG_CHECKING([for thread model used by GCC])
 989 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 990 AC_MSG_RESULT([$THREADS])
 991
 992 case "$THREADS" in
 993  no | none | single)
 994     THREADS=none
 995     ;;
 996  aix | posix | posix95 | pthreads)
 997     THREADS=posix
 998     case "$host" in
 999      *-*-linux*)
1000         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1001         ;;
1002     esac
1003     ;;
1004  win32)
1005     ;;
1006  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1007     AC_MSG_ERROR(thread package $THREADS not yet supported)
1008     ;;
1009  *)
1010     AC_MSG_ERROR($THREADS is an unknown thread package)
1011     ;;
1012 esac
1013
1014 THREADCXXFLAGS=
1015 THREADLDFLAGS=
1016 THREADLIBS=
1017 THREADINCS=
1018 THREADDEPS=
1019 THREADH=
1020 THREADSPEC=
1021 THREADSTARTFILESPEC=
1022 case "$THREADS" in
1023  posix)
1024     case "$host" in
1025      *-*-cygwin*)
1026         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1027         ;;
1028      *-*-freebsd[[1234]]*)
1029         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1030         # merely adds pthread_* functions) but it does have a -pthread switch
1031         # which is required at link-time to select -lc_r *instead* of -lc.
1032         THREADLDFLAGS=-pthread
1033         # Don't set THREADSPEC here as might be expected since -pthread is
1034         # not processed when found within a spec file, it must come from
1035         # the command line.  For now, the user must provide the -pthread
1036         # switch to link code compiled with gcj.  In future, consider adding
1037         # support for weak references to pthread_* functions ala gthr.h API.
1038         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1039         ;;
1040      *-*-freebsd*)
1041         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1042         # systems which support threads and -lpthread.
1043         THREADLDFLAGS=-pthread
1044         THREADSPEC=-lpthread
1045         ;;
1046      alpha*-dec-osf* | hppa*-hp-hpux*)
1047         THREADCXXFLAGS=-pthread
1048         # boehm-gc needs some functions from librt, so link that too.
1049         THREADLIBS='-lpthread -lrt'
1050         THREADSPEC='-lpthread -lrt'
1051         ;;
1052      *)
1053         THREADLIBS=-lpthread
1054         THREADSPEC=-lpthread
1055         ;;
1056     esac
1057     THREADH=posix-threads.h
1058     # MIT pthreads doesn't seem to have the mutexattr functions.
1059     # But for now we don't check for it.  We just assume you aren't
1060     # using MIT pthreads.
1061     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1062
1063     # If we're using the Boehm GC, then we happen to know that it
1064     # defines _REENTRANT, so we don't bother.  Eww.
1065     if test "$GC" != boehm; then
1066        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1067     fi
1068     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1069     ;;
1070
1071  win32)
1072     THREADH=win32-threads.h
1073     THREADCXXFLAGS=-mthreads
1074     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1075     # But we do not want the executables created to be dependent on
1076     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1077     # exception handling contexts.  The following kludge achieves this effect
1078     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1079     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1080     # A workaround is to explicitly use -mthreads while linking Java programs.
1081     # See PR libgcj/28263.
1082     #
1083     # FIXME: In Java we are able to detect thread death at the end of
1084     # Thread.run() so we should be able to clean up the exception handling
1085     # contexts ourselves.
1086     THREADSTARTFILESPEC='crtmt%O%s'
1087     ;;
1088
1089  none)
1090     THREADH=no-threads.h
1091     ;;
1092 esac
1093 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1094 AC_SUBST(THREADLIBS)
1095 AC_SUBST(THREADINCS)
1096 AC_SUBST(THREADDEPS)
1097 AC_SUBST(THREADSPEC)
1098 AC_SUBST(THREADSTARTFILESPEC)
1099 AC_SUBST(THREADLDFLAGS)
1100 AC_SUBST(THREADCXXFLAGS)
1101 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1102 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1103 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1104 if test "$enable_shared" != yes; then
1105   use_libgcj_bc=no
1106 fi
1107 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1108
1109 if test -d sysdep; then true; else mkdir sysdep; fi
1110 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1111 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1112 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1113
1114 LIBGCJ_SPEC_LGCJ=-lgcj
1115 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1116 if test x"$libgcj_spec_lgcj_override" != x ; then
1117   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1118 fi
1119 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1120   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1121 fi
1122 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1123 if test "$use_libgcj_bc" = yes; then
1124   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1125   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1126 fi
1127 AC_SUBST(LIBGCJ_SPEC)
1128 AC_SUBST(LIBGCJ_BC_SPEC)
1129
1130 HASH_SYNC_SPEC=
1131 # Hash synchronization is only useful with posix threads right now.
1132 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1133    HASH_SYNC_SPEC=-fhash-synchronization
1134    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1135 fi
1136 AC_SUBST(HASH_SYNC_SPEC)
1137
1138 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1139
1140 # We're in the tree with gcc, and need to include some of its headers.
1141 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1142
1143 if test "x${with_newlib}" = "xyes"; then
1144    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1145    # may not work correctly, because the compiler may not be able to
1146    # link executables.
1147
1148    # We assume newlib.  This lets us hard-code the functions we know
1149    # we'll have.
1150    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1151    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1152    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1153    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1154    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1155    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1156    # This is only for POSIX threads.
1157    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1158
1159    # Assume we do not have getuid and friends.
1160    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1161    PLATFORMNET=NoNet
1162 else
1163    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1164                    localtime_r getpwuid_r getcwd \
1165                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1166                    nl_langinfo setlocale \
1167                    inet_pton uname inet_ntoa \
1168                    getrlimit sigaction ftruncate mmap \
1169                    getifaddrs])
1170    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1171    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1172    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1173    AC_CHECK_LIB(dl, dladdr, [
1174        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1175        AC_CHECK_LIB(dld, dladdr, [
1176        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1177
1178    if test x"$cross_compiling" = x"no"; then
1179      AC_CHECK_FILES(/proc/self/exe, [
1180        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1181      AC_CHECK_FILES(/proc/self/maps, [
1182        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1183          [Define if you have /proc/self/maps])])
1184    else
1185      case $host in
1186      *-linux*)
1187        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1188        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1189        ;;
1190      esac
1191    fi
1192
1193    AM_ICONV
1194    AM_LC_MESSAGES
1195    AC_STRUCT_TIMEZONE
1196
1197    AC_CHECK_FUNCS(gethostbyname_r, [
1198      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1199        [Define if you have the 'gethostbyname_r' function.])
1200      # There are two different kinds of gethostbyname_r.
1201      # We look for the one that returns `int'.
1202      # Hopefully this check is robust enough.
1203      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1204        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1205
1206      case " $GCINCS " in
1207      *" -D_REENTRANT "*) ;;
1208      *)
1209         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1210         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1211         [libjava_cv_gethostbyname_r_needs_reentrant],
1212         [ AC_LANG_PUSH(C++)
1213           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1214             [[gethostbyname_r("", 0, 0);]])],
1215             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1216                 CPPFLAGS_SAVE="$CPPFLAGS"
1217                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1218                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1219                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1220                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1221                 CPPFLAGS="$CPPFLAGS_SAVE"
1222           ])
1223           AC_LANG_POP(C++)
1224         ])
1225         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1226           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1227         fi
1228      ;;
1229      esac
1230
1231      AC_CACHE_CHECK([for struct hostent_data],
1232         [libjava_cv_struct_hostent_data], [dnl
1233         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1234 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1235 # define _REENTRANT 1
1236 #endif
1237 #include <netdb.h>]], [[struct hostent_data data;]])],
1238           [libjava_cv_struct_hostent_data=yes],
1239           [libjava_cv_struct_hostent_data=no])])
1240      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1241        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1242          [Define if struct hostent_data is defined in netdb.h])
1243      fi
1244    ])
1245
1246    # FIXME: libjava source code expects to find a prototype for
1247    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1248    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1249    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1250    # linkage check is enough, yet C++ code requires proper prototypes.)
1251    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1252    AC_CHECK_FUNCS(gethostbyaddr_r, [
1253      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1254        [Define if you have the 'gethostbyaddr_r' function.])
1255      # There are two different kinds of gethostbyaddr_r.
1256      # We look for the one that returns `int'.
1257      # Hopefully this check is robust enough.
1258      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1259        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1260          [Define if gethostbyaddr_r returns 'int'.])])])])
1261
1262    AC_CHECK_FUNCS(gethostname, [
1263      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1264        [Define if you have the 'gethostname' function.])
1265      AC_EGREP_HEADER(gethostname, unistd.h, [
1266        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1267          [Define if gethostname is declared in <unistd.h>.])])])
1268
1269    AC_CHECK_FUNCS(usleep, [
1270      AC_EGREP_HEADER(usleep, unistd.h, [
1271        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1272           [Define if usleep is declared in <unistd.h>.])])])
1273
1274    # Look for these functions in the thread library, but only bother
1275    # if using POSIX threads.
1276    if test "$THREADS" = posix; then
1277       save_LIBS="$LIBS"
1278       LIBS="$LIBS $THREADLIBS"
1279
1280       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1281       # Solaris 7 the name librt is preferred.
1282       AC_CHECK_FUNCS(sched_yield, , [
1283         AC_CHECK_LIB(rt, sched_yield, [
1284           AC_DEFINE(HAVE_SCHED_YIELD)
1285           THREADLIBS="$THREADLIBS -lrt"
1286           THREADSPEC="$THREADSPEC -lrt"], [
1287           AC_CHECK_LIB(posix4, sched_yield, [
1288             AC_DEFINE(HAVE_SCHED_YIELD)
1289             THREADLIBS="$THREADLIBS -lposix4"
1290             THREADSPEC="$THREADSPEC -lposix4"])])])
1291
1292       AC_CHECK_LIB(rt, clock_gettime, [
1293          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1294          case "$THREADSPEC" in
1295            *-lrt*) ;;
1296            *)
1297              THREADSPEC="$THREADSPEC -lrt"
1298              THREADLIBS="$THREADLIBS -lrt"
1299              ;;
1300          esac])
1301
1302       LIBS="$save_LIBS"
1303
1304       # We can save a little space at runtime if the mutex has m_count
1305       # or __m_count.  This is a nice hack for Linux.
1306       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1307           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1308         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1309              [Define if pthread_mutex_t has m_count member.]), [
1310         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1311             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1312           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1313             [Define if pthread_mutex_t has __m_count member.]))])
1314    fi
1315
1316    # We require a way to get the time.
1317    time_found=no
1318    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1319    if test "$time_found" = no; then
1320       AC_MSG_ERROR([no function found to get the time])
1321    fi
1322
1323    AC_CHECK_FUNCS(memmove)
1324
1325    # We require memcpy.
1326    memcpy_found=no
1327    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1328    if test "$memcpy_found" = no; then
1329       AC_MSG_ERROR([memcpy is required])
1330    fi
1331    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1332    AC_CHECK_LIB(dl, dlopen, [
1333        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1334        AC_CHECK_LIB(dld, dlopen, [
1335        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1336
1337    # Some library-finding code we stole from Tcl.
1338    #--------------------------------------------------------------------
1339    #    Check for the existence of the -lsocket and -lnsl libraries.
1340    #    The order here is important, so that they end up in the right
1341    #    order in the command line generated by make.  Here are some
1342    #    special considerations:
1343    #    1. Use "connect" and "accept" to check for -lsocket, and
1344    #       "gethostbyname" to check for -lnsl.
1345    #    2. Use each function name only once:  can't redo a check because
1346    #       autoconf caches the results of the last check and won't redo it.
1347    #    3. Use -lnsl and -lsocket only if they supply procedures that
1348    #       aren't already present in the normal libraries.  This is because
1349    #       IRIX 5.2 has libraries, but they aren't needed and they're
1350    #       bogus:  they goof up name resolution if used.
1351    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1352    #       To get around this problem, check for both libraries together
1353    #       if -lsocket doesn't work by itself.
1354    #--------------------------------------------------------------------
1355
1356    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1357     [gcj_cv_lib_sockets=
1358      gcj_checkBoth=0
1359      unset ac_cv_func_connect
1360      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1361      if test "$gcj_checkSocket" = 1; then
1362          unset ac_cv_func_connect
1363          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1364                       gcj_checkBoth=1)
1365      fi
1366      if test "$gcj_checkBoth" = 1; then
1367          gcj_oldLibs=$LIBS
1368          LIBS="$LIBS -lsocket -lnsl"
1369          unset ac_cv_func_accept
1370          AC_CHECK_FUNC(accept,
1371                        [gcj_checkNsl=0
1372                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1373          unset ac_cv_func_accept
1374          LIBS=$gcj_oldLibs
1375      fi
1376      unset ac_cv_func_gethostbyname
1377      gcj_oldLibs=$LIBS
1378      LIBS="$LIBS $gcj_cv_lib_sockets"
1379      AC_CHECK_FUNC(gethostbyname, ,
1380                    [AC_CHECK_LIB(nsl, main,
1381                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1382      unset ac_cv_func_gethostbyname
1383      LIBS=$gcj_oldLIBS
1384    ])
1385    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1386
1387    if test "$with_system_zlib" = yes; then
1388       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1389    fi
1390
1391    # Test for Gtk stuff, if asked for.
1392    if test "$use_gtk_awt" = yes; then
1393       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1394       AC_SUBST(GTK_CFLAGS)
1395       AC_SUBST(GTK_LIBS)
1396
1397       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1398       AC_SUBST(GLIB_CFLAGS)
1399       AC_SUBST(GLIB_LIBS)
1400
1401       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1402       AC_SUBST(LIBART_CFLAGS)
1403       AC_SUBST(LIBART_LIBS)
1404
1405       # We require the XTest Extension to support java.awt.Robot.
1406       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1407                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1408                    [${X_LIBS}])
1409    fi
1410
1411    # On Solaris, and maybe other architectures, the Boehm collector
1412    # requires -ldl.
1413    if test "$GC" = boehm; then
1414       case "${host}" in
1415           mips-sgi-irix6*)
1416             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1417             # libgcj.spec is used, so override here
1418             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1419           ;;
1420           *)
1421             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1422           ;;
1423       esac
1424    fi
1425 fi
1426
1427 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1428 case $build in
1429     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1430     *)         CLASSPATH_SEPARATOR=':' ;;
1431 esac
1432 AC_SUBST(CLASSPATH_SEPARATOR)
1433
1434 # We must search the source tree for java.lang, since we still don't
1435 # have libgcj.jar nor java/lang/*.class
1436 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1437 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1438
1439 # Since some classes depend on this one, we need its source available
1440 # before we can do any GCJ compilation test :-(
1441 if test ! -f gnu/classpath/Configuration.java; then
1442   test -d gnu || mkdir gnu
1443   test -d gnu/classpath || mkdir gnu/classpath
1444   # Note that it is not crucial that all the values here be correct.
1445   sed -e "s,@prefix@,$expanded_prefix," \
1446       -e "s,@VERSION@,$VERSION," \
1447       -e "s,@LIBDEBUG@,false," \
1448       -e "s,@INIT_LOAD_LIBRARY@,false," \
1449       -e "s,@@,$LIBGCJDEBUG," \
1450       -e "s,@default_toolkit@,$TOOLKIT," \
1451       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1452       -e "s,@GTK_CAIRO_ENABLED@,false," \
1453       -e "s,@ECJ_JAR@,," \
1454       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1455         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1456         > gnu/classpath/Configuration.java
1457   # We do not want to redirect the output of the grep below to /dev/null,
1458   # but we add /dev/null to the input list so that grep will print the
1459   # filename of Configuration.java in case it finds any matches.
1460   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1461     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1462   fi
1463 fi
1464
1465 LT_AC_PROG_GCJ
1466
1467 # Now remove it.
1468 rm -f gnu/classpath/Configuration.java
1469
1470 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1471
1472 AC_CHECK_SIZEOF(void *)
1473
1474 AC_C_BIGENDIAN
1475
1476 ZLIBS=
1477 SYS_ZLIBS=
1478 ZINCS=
1479
1480 if test -z "$ZLIBSPEC"; then
1481    # Use zlib from the GCC tree.
1482    ZINCS='-I$(top_srcdir)/../zlib'
1483    ZLIBS=../zlib/libzgcj_convenience.la
1484 else
1485    # System's zlib.
1486    SYS_ZLIBS="$ZLIBSPEC"
1487 fi
1488 AC_SUBST(ZLIBS)
1489 AC_SUBST(SYS_ZLIBS)
1490 AC_SUBST(ZINCS)
1491 AC_SUBST(DIVIDESPEC)
1492 AC_SUBST(CHECKREFSPEC)
1493 AC_SUBST(EXCEPTIONSPEC)
1494 AC_SUBST(BACKTRACESPEC)
1495 AC_SUBST(IEEESPEC)
1496 AC_SUBST(ATOMICSPEC)
1497
1498 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1499 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1500 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1501 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1502 AC_SUBST(GCC_UNWIND_INCLUDE)
1503
1504 # Process the option "--enable-version-specific-runtime-libs"
1505 # Calculate toolexeclibdir
1506 case ${version_specific_libs} in
1507   yes)
1508     # Need the gcc compiler version to know where to install libraries
1509     # and header files if --enable-version-specific-runtime-libs option
1510     # is selected.
1511     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1512     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1513     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1514     toolexeclibdir=$toolexecmainlibdir
1515     ;;
1516   no)
1517     if test -n "$with_cross_host" &&
1518        test x"$with_cross_host" != x"no"; then
1519       # Install a library built with a cross compiler in tooldir, not libdir.
1520       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1521       toolexecmainlibdir='$(toolexecdir)/lib'
1522     else
1523       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1524       toolexecmainlibdir='$(libdir)'
1525     fi
1526     multi_os_directory=`$CC -print-multi-os-directory`
1527     case $multi_os_directory in
1528       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1529       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1530     esac
1531     ;;
1532 esac
1533 AC_SUBST(toolexecdir)
1534 AC_SUBST(toolexecmainlibdir)
1535 AC_SUBST(toolexeclibdir)
1536
1537 # Determine gcj and libgcj version number.
1538 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1539 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1540 GCJVERSION=$gcjversion
1541 AC_SUBST(GCJVERSION)
1542 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1543
1544 # Determine where the standard .db file and GNU Classpath JNI
1545 # libraries are found.
1546 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1547 multi_os_directory=`$CC -print-multi-os-directory`
1548 case $multi_os_directory in
1549   .)
1550    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1551    ;;
1552   *)
1553    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1554    ;;
1555 esac
1556 AC_SUBST(dbexecdir)
1557 AC_SUBST(gcjsubdir)
1558
1559 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1560 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1561
1562 TL_AC_GXX_INCLUDE_DIR
1563
1564 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1565 # On that system, sys/ioctl.h will not include sys/filio.h unless
1566 # BSD_COMP is defined; just including sys/filio.h is simpler.
1567 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1568 # for now.  If you change this, you also must update natFile.cc.
1569 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1570                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1571                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1572                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1573                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1574 AC_CHECK_HEADERS(inttypes.h, [
1575     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1576     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1577 ])
1578
1579 AC_CHECK_TYPE([ssize_t], [int])
1580 AC_CHECK_TYPE([magic_t], [
1581     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1582 #ifdef HAVE_MAGIC_H
1583 #include <magic.h>
1584 #endif])
1585
1586 AC_MSG_CHECKING([for in_addr_t])
1587 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1588 #if STDC_HEADERS
1589 #include <stdlib.h>
1590 #include <stddef.h>
1591 #endif
1592 #if HAVE_NETINET_IN_H
1593 #include <netinet/in.h>
1594 #endif]], [[in_addr_t foo;]])],
1595   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1596      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1597    AC_MSG_RESULT(yes)],
1598   [AC_MSG_RESULT(no)])
1599
1600 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1601 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1602   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1603      [Define if struct ip_mreq is defined in netinet/in.h.])
1604    AC_MSG_RESULT(yes)],
1605   [AC_MSG_RESULT(no)])
1606
1607 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1608 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1609   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1610      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1611    AC_MSG_RESULT(yes)],
1612   [AC_MSG_RESULT(no)])
1613
1614 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1615 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1616   [AC_DEFINE(HAVE_INET6, 1,
1617      [Define if inet6 structures are defined in netinet/in.h.])
1618    AC_MSG_RESULT(yes)],
1619   [AC_MSG_RESULT(no)])
1620
1621 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1622 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1623 #include <sys/types.h>
1624 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1625   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1626    AC_MSG_RESULT(yes)],
1627   [AC_MSG_RESULT(no)])
1628
1629 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1630 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1631   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1632    AC_MSG_RESULT(yes)],
1633   [AC_MSG_RESULT(no)
1634    AC_MSG_CHECKING([for global timezone variable])
1635    dnl FIXME: we don't want a link check here because that won't work
1636    dnl when cross-compiling.  So instead we make an assumption that
1637    dnl the header file will mention timezone if it exists.
1638    dnl Don't find the win32 function timezone
1639    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1640      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1641       AC_MSG_RESULT(yes)],
1642      [AC_MSG_RESULT(no)
1643        AC_MSG_CHECKING([for global _timezone variable])
1644        dnl FIXME: As above, don't want link check
1645        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1646          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1647             [Define if your platform has the global _timezone variable.])
1648           AC_MSG_RESULT(yes)],
1649           [AC_MSG_RESULT(no)])])])
1650
1651 AC_CHECK_PROGS(PERL, perl, false)
1652
1653 SYSDEP_SOURCES=
1654 SIGNAL_HANDLER_AUX=
1655
1656 case "${host}" in
1657  i?86-*-linux*)
1658     SIGNAL_HANDLER=include/i386-signal.h
1659     ;;
1660  sparc*-sun-solaris*)
1661     SIGNAL_HANDLER=include/sparc-signal.h
1662     ;;
1663 # ia64-*)
1664 #    SYSDEP_SOURCES=sysdep/ia64.c
1665 #    test -d sysdep || mkdir sysdep
1666 #    ;;
1667  hppa*-*-linux*)
1668     SIGNAL_HANDLER=include/pa-signal.h
1669     ;;
1670  hppa*-hp-hpux*)
1671     SIGNAL_HANDLER=include/hppa-signal.h
1672     ;;
1673  ia64-*-linux*)
1674     SIGNAL_HANDLER=include/dwarf2-signal.h
1675     ;;
1676  powerpc*-*-linux*)
1677     SIGNAL_HANDLER=include/powerpc-signal.h
1678     ;;
1679  alpha*-*-linux*)
1680     SIGNAL_HANDLER=include/dwarf2-signal.h
1681     ;;
1682  s390*-*-linux*)
1683     SIGNAL_HANDLER=include/s390-signal.h
1684     ;;
1685  x86_64*-*-linux*)
1686     SIGNAL_HANDLER=include/x86_64-signal.h
1687     SIGNAL_HANDLER_AUX=include/i386-signal.h
1688     ;;
1689  sparc*-*-linux*)
1690     SIGNAL_HANDLER=include/dwarf2-signal.h
1691     ;;
1692  sh*-*-linux*)
1693     SIGNAL_HANDLER=include/sh-signal.h
1694     ;;
1695  *mingw*)
1696     SIGNAL_HANDLER=include/win32-signal.h
1697     ;;
1698  mips*-*-linux*)
1699     SIGNAL_HANDLER=include/mips-signal.h
1700     ;;
1701  m68*-*-linux*)
1702     SIGNAL_HANDLER=include/dwarf2-signal.h
1703     ;;
1704  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1705     SIGNAL_HANDLER=include/darwin-signal.h
1706     ;;
1707  powerpc*-*-aix*)
1708     SIGNAL_HANDLER=include/aix-signal.h
1709     ;;
1710  *)
1711     SIGNAL_HANDLER=include/default-signal.h
1712     ;;
1713 esac
1714
1715 # If we're using sjlj exceptions, forget what we just learned.
1716 if test "$enable_sjlj_exceptions" = yes; then
1717    SIGNAL_HANDLER=include/default-signal.h
1718    SIGNAL_HANDLER_AUX=
1719 fi
1720
1721 AC_SUBST(SYSDEP_SOURCES)
1722
1723 if test -z "$SIGNAL_HANDLER_AUX"; then
1724   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1725 fi
1726
1727 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1728                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1729
1730 if test "${multilib}" = "yes"; then
1731   multilib_arg="--enable-multilib"
1732 else
1733   multilib_arg=
1734 fi
1735
1736 # See if we support thread-local storage.
1737 GCC_CHECK_TLS
1738
1739 # For _Unwind_GetIPInfo.
1740 GCC_CHECK_UNWIND_GETIPINFO
1741
1742 # See if linker supports anonymous version scripts.
1743 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1744   [libjava_cv_anon_version_script],
1745   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1746    libjava_cv_anon_version_script=no
1747    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1748    echo '{ global: globalsymb*; local: *; };' > conftest.map
1749    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1750                [libjava_cv_anon_version_script=yes], [])
1751    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1752   ])
1753 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1754
1755 # Check if linker supports static linking on a per library basis
1756 LD_START_STATIC_SPEC=
1757 LD_FINISH_STATIC_SPEC=
1758 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1759   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1760     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1761     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1762   fi
1763 fi
1764 AC_SUBST(LD_START_STATIC_SPEC)
1765 AC_SUBST(LD_FINISH_STATIC_SPEC)
1766
1767 here=`${PWDCMD-pwd}`
1768 AC_SUBST(here)
1769
1770 # We get this from the environment.
1771 AC_SUBST(GCJFLAGS)
1772
1773 AC_ARG_WITH([python-dir],
1774             AS_HELP_STRING([--with-python-dir],
1775                            [the location to install Python modules. This path should NOT include the prefix.]),
1776             [with_python_dir=$withval], [with_python_dir=""])
1777
1778 if test "x${with_python_dir}" = "x"
1779 then
1780   # Needed for installing Python modules during make install.
1781   python_mod_dir="\${prefix}/share/python"
1782   # Needed for substituting into aot-compile*
1783   python_mod_dir_expanded="${expanded_prefix}/share/python"
1784 else
1785   python_mod_dir="\${prefix}${with_python_dir}"
1786   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1787 fi
1788 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1789 AC_SUBST(python_mod_dir)
1790 AC_SUBST(python_mod_dir_expanded)
1791
1792 # needed for aot-compile-rpm
1793 MAKE=`which make`
1794 AC_SUBST(MAKE)
1795
1796 AC_ARG_ENABLE([aot-compile-rpm],
1797   [AS_HELP_STRING([--enable-aot-compile-rpm],
1798                  [enable installation of aot-compile-rpm [default=no]])],
1799   [case "${enableval}" in
1800     yes) AOT_RPM_ENABLED=yes ;;
1801     no)  AOT_RPM_ENABLED=no ;;
1802     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1803   esac],
1804   [AOT_RPM_ENABLED=no]
1805 )
1806 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1807
1808 AC_ARG_ENABLE([java-home],
1809   [AS_HELP_STRING([--enable-java-home],
1810                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1811   [case "${enableval}" in
1812     yes) JAVA_HOME_ENABLED=yes ;;
1813     no)  JAVA_HOME_ENABLED=no ;;
1814     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1815   esac],
1816   [JAVA_HOME_ENABLED=no]
1817 )
1818 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1819
1820 # Only do these checks if java-home above is enabled.
1821 if test "x${JAVA_HOME_ENABLED}" = xyes
1822 then
1823
1824   AC_ARG_WITH([gcc-suffix],
1825               AS_HELP_STRING([--with-gcc-suffix],
1826                              [the GCC tool suffix (defaults to empty string)]),
1827               [gcc_suffix=$withval], [gcc_suffix=""])
1828   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1829   AC_SUBST(gcc_suffix)
1830
1831   AC_ARG_WITH([arch-directory],
1832               AS_HELP_STRING([--with-arch-directory],
1833                              [the arch directory under jre/lib (defaults to auto-detect)]),
1834               [host_cpu=$withval], [host_cpu=""])
1835
1836   AC_ARG_WITH([os-directory],
1837               AS_HELP_STRING([--with-os-directory],
1838                              [the os directory under include (defaults to auto-detect)]),
1839               [host_os=$withval], [host_os=""])
1840
1841   AC_ARG_WITH([origin-name],
1842               AS_HELP_STRING([--with-origin-name],
1843                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1844               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1845   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1846
1847   AC_ARG_WITH([arch-suffix],
1848               AS_HELP_STRING([--with-arch-suffix],
1849                              [the arch directory suffix (default is the empty string]),
1850               [arch_suffix=$withval], [arch_suffix=""])
1851   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1852
1853   AC_ARG_WITH([jvm-root-dir],
1854               AS_HELP_STRING([--with-jvm-root-dir],
1855                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1856               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1857   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1858
1859   AC_ARG_WITH([jvm-jar-dir],
1860               AS_HELP_STRING([--with-jvm-jar-dir],
1861                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1862               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1863   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1864
1865   JAVA_VERSION=1.5.0
1866   BUILD_VERSION=0
1867   AC_SUBST(JAVA_VERSION)
1868   AC_SUBST(BUILD_VERSION)
1869   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1870
1871   jre_dir=jre
1872   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1873   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1874
1875   JVM_ROOT_DIR=${jvm_root_dir}
1876   AC_SUBST(JVM_ROOT_DIR)
1877   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1878
1879   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1880   AC_SUBST(JVM_JAR_ROOT_DIR)
1881   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1882
1883   JVM_JAR_DIR=${jvm_jar_dir}
1884   AC_SUBST(JVM_JAR_DIR)
1885   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1886
1887   JRE_DIR=${jre_dir}
1888   AC_SUBST(JRE_DIR)
1889
1890   JRE_LNK=${jre_lnk}
1891   AC_SUBST(JRE_LNK)
1892
1893   SDK_LNK=${sdk_lnk}
1894   AC_SUBST(SDK_LNK)
1895
1896   SDK_BIN_DIR=${jvm_root_dir}/bin
1897   AC_SUBST(SDK_BIN_DIR)
1898   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1899
1900   SDK_LIB_DIR=${jvm_root_dir}/lib
1901   AC_SUBST(SDK_LIB_DIR)
1902   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1903
1904   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1905   AC_SUBST(SDK_INCLUDE_DIR)
1906   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1907
1908   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1909   AC_SUBST(JRE_BIN_DIR)
1910   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1911
1912   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1913   AC_SUBST(JRE_LIB_DIR)
1914   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1915
1916   # Find gcj prefix using gcj found in PATH.
1917   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1918
1919   # Where do the gcj binaries live?
1920   # For jhbuild based builds, they all live in a sibling of bin called
1921   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1922   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1923   AC_SUBST(GCJ_BIN_DIR)
1924   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1925
1926   AC_MSG_RESULT(host is ${host})
1927   if test "x${host_cpu}" = "x"
1928   then
1929     case ${host} in
1930       *-mingw* | *-cygwin*)
1931         host_cpu=x86;;
1932       i486-* | i586-* | i686-*)
1933         host_cpu=i386;;
1934       x86_64-*)
1935         host_cpu=amd64;;
1936       *)
1937         host_cpu=${host_cpu};;
1938     esac
1939   fi
1940   AC_MSG_RESULT(arch directory: ${host_cpu})
1941   CPU=${host_cpu}
1942   AC_SUBST(CPU)
1943
1944   if test "x${host_os}" = "x"
1945   then
1946     case ${host} in
1947       *-mingw* | *-cygwin*)
1948         host_os=win32;;
1949       *-linux*)
1950         host_os=linux;;
1951       *)
1952         host_os=${host_os};;
1953     esac
1954   fi
1955   echo os directory: ${host_os}
1956   OS=${host_os}
1957   AC_SUBST(OS)
1958
1959   # make an expanded $libdir, for substituting into
1960   # scripts (and other non-Makefile things).
1961   LIBDIR=$libdir
1962   if test "x${exec_prefix}" = "xNONE"
1963   then
1964       lib_exec_prefix=$expanded_prefix
1965   else
1966       lib_exec_prefix=$exec_prefix
1967   fi
1968   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1969   AC_SUBST(LIBDIR)
1970 fi
1971
1972 AC_CONFIG_FILES([
1973 Makefile
1974 libgcj.pc
1975 libgcj.spec
1976 libgcj-test.spec
1977 gcj/Makefile
1978 include/Makefile
1979 testsuite/Makefile
1980 contrib/aotcompile.py
1981 contrib/aot-compile
1982 contrib/aot-compile-rpm
1983 contrib/generate-cacerts.pl
1984 contrib/rebuild-gcj-db
1985 ])
1986
1987 if test ${multilib} = yes; then
1988   multilib_arg="--enable-multilib"
1989 else
1990   multilib_arg=
1991 fi
1992
1993 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1994 AC_OUTPUT