libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 AC_ARG_ENABLE(plugin,
  88   AS_HELP_STRING([--enable-plugin],
  89                  [build gcjwebplugin web browser plugin]),
  90     [case "$enableval" in
  91       yes) plugin_enabled=yes ;;
  92       no)  plugin_enabled=no ;;
  93       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  94      esac],
  95     [plugin_enabled=no]
  96 )
  97
  98 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  99 GCC_NO_EXECUTABLES
 100
 101 # (1) We use an abnormal CXX (without library references), so we
 102 # must cache it under a different name.
 103 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 104 # the non-multilib-adjusted value will be used in multilibs.
 105 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 106 # (4) As another side effect, automake doesn't automatically include them
 107 # in Makefile.in.
 108 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 109 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 110 # used in later tests.  This may not be necessary in libjava; I don't know.
 111 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 112 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 113 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 114 save_CXXFLAGS="$CXXFLAGS"
 115 CXXFLAGS="$CXXFLAGS -fno-builtin"
 116 AC_PROG_CC
 117 AC_PROG_CXX
 118 CXXFLAGS="$save_CXXFLAGS"
 119 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 120 AC_SUBST(CFLAGS)
 121 AC_SUBST(CXXFLAGS)
 122 AC_SUBST(LDFLAGS)
 123
 124 AM_INIT_AUTOMAKE([1.9.0])
 125
 126 AC_CHECK_TOOL(AS, as)
 127 AC_CHECK_TOOL(LD, ld)
 128 AC_CHECK_TOOL(AR, ar)
 129 AC_CHECK_TOOL(RANLIB, ranlib, :)
 130 AC_PROG_AWK
 131 AC_CHECK_PROGS([JAR], [jar fastjar], no)
 132 AC_PATH_PROG([ZIP], [zip], no)
 133 AC_PATH_PROG([UNZIP], [unzip], unzip)
 134 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 135 if test "$ZIP" = no; then
 136   if test "$JAR" = no; then
 137     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 138   fi
 139 else
 140   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 141   JAR=`pwd`/scripts/jar
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 AM_MAINTAINER_MODE
 147
 148 AC_EXEEXT
 149
 150 # configure.host sets the following important variables
 151 #       libgcj_cflags    - host specific C compiler flags
 152 #       libgcj_cxxflags  - host specific C++ compiler flags
 153 #       libgcj_javaflags - host specific Java compiler flags
 154
 155 libgcj_cflags=
 156 libgcj_cxxflags=
 157 libgcj_javaflags=
 158
 159 . ${srcdir}/configure.host
 160
 161 LIBGCJ_CFLAGS="${libgcj_cflags}"
 162 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 163 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 164 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 165 AC_SUBST(LIBGCJ_CFLAGS)
 166 AC_SUBST(LIBGCJ_CXXFLAGS)
 167 AC_SUBST(LIBGCJ_JAVAFLAGS)
 168 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 169
 170 # Only use libltdl for non-newlib builds.
 171 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 172    AC_LTDL_SHLIBPATH
 173 fi
 174
 175 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 176
 177 # See if the user has requested runtime debugging.
 178 LIBGCJDEBUG="disable"
 179 AC_SUBST(LIBGCJDEBUG)
 180 AC_ARG_ENABLE(libgcj-debug,
 181   AS_HELP_STRING([--enable-libgcj-debug],
 182                  [enable runtime debugging code]),
 183   [if test "$enable_libgcj_debug" = yes; then
 184     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 185     LIBGCJDEBUG="enable"
 186   fi])
 187
 188 # Determine which AWT peer libraries to build
 189 AC_ARG_ENABLE(java-awt,
 190   AS_HELP_STRING([--enable-java-awt],
 191                  [list of AWT peer implementations to be built]))
 192
 193 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 194 use_xlib_awt=""
 195 use_gtk_awt=""
 196 use_qt_awt=""
 197 # The default toolkit to use is the first one specified.
 198 TOOLKIT=
 199 AC_SUBST(TOOLKIT)
 200
 201 for peer in $peerlibs ; do
 202   case $peer in
 203     xlib)
 204       if test "$no_x" = yes; then
 205         echo "*** xlib peers requested but no X library available" 1>&2
 206         exit 1
 207       else
 208         use_xlib_awt="yes"
 209         if test -z "$TOOLKIT"; then
 210            TOOLKIT=gnu.awt.xlib.XToolkit
 211         fi
 212       fi
 213       ;;
 214     gtk)
 215       if test "$no_x" = yes; then
 216          echo "*** gtk peers requested but no X library available" 1>&2
 217          exit 1
 218       else
 219          use_gtk_awt=yes
 220          if test -z "$TOOLKIT"; then
 221             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 222          fi
 223       fi
 224       ;;
 225     qt)
 226       if test "$no_x" = yes; then
 227          # Perhaps we should admit the possibility of embedded Qt.
 228          echo "*** Qt peers requested but no X library available" 1>&2
 229          exit 1
 230       else
 231          use_qt_awt=yes
 232          if test -z "$TOOLKIT"; then
 233             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 234          fi
 235       fi
 236       ;;
 237     no)
 238       use_xlib_awt=
 239       use_gtk_awt=
 240       use_qt_awt=
 241       break
 242       ;;
 243     *)
 244       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 245       exit 1
 246   esac
 247 done
 248
 249 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 250
 251 # Create standard.omit based on decisions we just made.
 252 cp $srcdir/standard.omit.in standard.omit
 253 if test "$use_xlib_awt" != yes; then
 254    echo gnu/awt/xlib >> standard.omit
 255    echo gnu/gcj/xlib >> standard.omit
 256 fi
 257
 258 if test -z "${with_multisubdir}"; then
 259    builddotdot=.
 260 else
 261    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 262 fi
 263
 264 NATIVE=yes
 265
 266 # Which gcj do we use?
 267 which_gcj=default
 268 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 269 if test -n "${with_cross_host}"; then
 270   # We are being configured with a cross compiler. We can't
 271   # use ac_exeext, because that is for the target platform.
 272   NATIVE=no
 273   cross_host_exeext=
 274   case "${with_cross_host}" in
 275      *mingw* | *cygwin*)
 276          cross_host_exeext=.exe
 277      ;;
 278   esac
 279   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 280      if test x"$build_noncanonical" = x"$with_cross_host"; then
 281         # Ordinary cross (host!=target and host=build)
 282         which_gcj=built
 283      else
 284         # Canadian cross (host!=target and host!=build)
 285         which_gcj=cross
 286      fi
 287   else
 288      which_gcj=cross
 289   fi
 290 else
 291   # We are being configured with a native or crossed-native compiler
 292   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 293      if test x"$build" = x"$host"; then
 294         # True native build (host=target and host=build)
 295         which_gcj=built
 296      else
 297         # Crossed-native build (host=target and host!=build)
 298         which_gcj=cross
 299      fi
 300   else
 301      which_gcj=path
 302   fi
 303 fi
 304 case "${which_gcj}" in
 305    built)
 306       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 307       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 308    ;;
 309    cross)
 310       if test "x${with_newlib}" = "xyes"; then
 311          # FIXME (comment): Why is this needed?
 312          GCC_UNWIND_INCLUDE=
 313          GCJ="${target_noncanonical}-gcj"
 314       else
 315          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 316       fi
 317       GCJH='$(target_noncanonical)-gcjh'
 318    ;;
 319    path)
 320       GCJ="gcj -B`${PWDCMD-pwd}`/"
 321       GCJH=gcjh
 322    ;;
 323 esac
 324
 325 AC_SUBST(GCJH)
 326
 327 # Create it, so that compile/link tests don't fail
 328 test -f libgcj.spec || touch libgcj.spec
 329
 330
 331
 332 # Set up to configure Classpath.
 333 # FIXME: no supported way to pass args in autoconf.
 334 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 335 ac_configure_args="$ac_configure_args --enable-tool-wrappers"
 336 ac_configure_args="$ac_configure_args --disable-load-library"
 337 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 338 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 339 dir1=`cd $srcdir && pwd`
 340 dir2=`pwd`
 341 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 342 ac_configure_args="$ac_configure_args --disable-core-jni"
 343 dnl FIXME?
 344 ac_configure_args="$ac_configure_args --disable-examples"
 345 ac_configure_args="$ac_configure_args --with-glibj=build"
 346 if test "$plugin_enabled" != yes; then
 347   ac_configure_args="$ac_configure_args --disable-plugin"
 348 fi
 349 if test "$use_gtk_awt" != yes; then
 350   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 351 fi
 352 if test "$use_qt_awt" != yes; then
 353   ac_configure_args="$ac_configure_args --disable-qt-peer"
 354 else
 355   # We need this as qt is disabled by default in classpath.
 356   ac_configure_args="$ac_configure_args --enable-qt-peer"
 357 fi
 358 dnl --with-gcj=$GCJ
 359 dnl --with-javah=$GCJH
 360 dnl gjdoc?
 361 dnl gtk-cairo -- just export here...
 362 dnl --enable-regen-headers?
 363
 364 # Only use libltdl for non-newlib builds.
 365 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 366    AC_LIBLTDL_CONVENIENCE
 367    AC_LIBTOOL_DLOPEN
 368    DIRLTDL=libltdl
 369    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 370    # Sigh.  Libtool's macro doesn't do the right thing.
 371    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 372    # FIXME: this is a hack.
 373    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 374    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 375 fi
 376 AC_SUBST(INCLTDL)
 377 AC_SUBST(LIBLTDL)
 378 AC_SUBST(DIRLTDL)
 379 AC_PROG_LIBTOOL
 380 AM_PROG_GCJ
 381 AM_PROG_CC_C_O
 382
 383 AC_CONFIG_SUBDIRS(classpath libltdl)
 384
 385 # The -no-testsuite modules omit the test subdir.
 386 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 387
 388 # Should the runtime set system properties by examining the
 389 # environment variable GCJ_PROPERTIES?
 390 AC_ARG_ENABLE(getenv-properties,
 391   AS_HELP_STRING([--disable-getenv-properties],
 392                  [don't set system properties from GCJ_PROPERTIES]))
 393
 394 # Whether GCJ_PROPERTIES is used depends on the target.
 395 if test -z "$enable_getenv_properties"; then
 396    enable_getenv_properties=${enable_getenv_properties_default-yes}
 397 fi
 398 if test "$enable_getenv_properties" = no; then
 399    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 400      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 401 fi
 402
 403 # Whether we should use arguments to main()
 404 if test -z "$enable_main_args"; then
 405    enable_main_args=${enable_main_args_default-yes}
 406 fi
 407 if test "$enable_main_args" = no; then
 408    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 409 fi
 410
 411
 412 # Should we use hashtable-based synchronization?
 413 # Currently works only for Linux X86/ia64
 414 # Typically faster and more space-efficient
 415 AC_ARG_ENABLE(hash-synchronization,
 416   AS_HELP_STRING([--enable-hash-synchronization],
 417                  [use global hash table for monitor locks]))
 418
 419 if test -z "$enable_hash_synchronization"; then
 420    enable_hash_synchronization=$enable_hash_synchronization_default
 421 fi
 422
 423 AC_ARG_WITH(java-home,
 424   AS_HELP_STRING([--with-java-home=DIRECTORY],
 425                  [value of java.home system property]),
 426                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 427 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 428 AC_SUBST(JAVA_HOME)
 429
 430 # What is the native OS API for MinGW?
 431 AC_ARG_WITH(win32-nlsapi,
 432   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 433                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 434 [case "${withval}" in
 435   ansi) with_win32_nlsapi=ansi ;;
 436   unicows) with_win32_nlsapi=unicows ;;
 437   unicode) with_win32_nlsapi=unicode ;;
 438   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 439 esac],[with_win32_nlsapi=ansi])
 440
 441 case "${with_win32_nlsapi}" in
 442   unicows | unicode)
 443     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 444       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 445     ;;
 446 esac
 447
 448 # configure.host sets slow_pthread_self if the synchronization code should
 449 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 450 if test "${slow_pthread_self}" = "yes"; then
 451   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 452     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 453 fi
 454
 455 # Check for gc debugging.  This option is handled both here and in the GC.
 456 AC_ARG_ENABLE(gc-debug,
 457    AS_HELP_STRING([--enable-gc-debug],
 458                   [include full support for pointer backtracing etc.]),
 459 [ if test "$enable_gc_debug" = "yes"; then
 460     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 461               [Define if we want to use debug calls into the garbage collector.])
 462   fi])
 463
 464 # See if the user has the interpreter included.
 465 AC_ARG_ENABLE(interpreter,
 466   AS_HELP_STRING([--enable-interpreter],
 467                  [enable interpreter]),
 468   [if test "$enable_interpreter" = yes; then
 469     # This can also be set in configure.host.
 470     libgcj_interpreter=yes
 471   elif test "$enable_interpreter" = no; then
 472     libgcj_interpreter=no
 473   fi])
 474
 475 if test "$libgcj_interpreter" = yes; then
 476    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 477 fi
 478 INTERPRETER="$libgcj_interpreter"
 479 AC_SUBST(INTERPRETER)
 480
 481 AC_MSG_CHECKING([for exception model to use])
 482 AC_LANG_PUSH(C++)
 483 AC_ARG_ENABLE(sjlj-exceptions,
 484   AS_HELP_STRING([--enable-sjlj-exceptions],
 485                  [force use of builtin_setjmp for exceptions]),
 486 [:],
 487 [dnl Botheration.  Now we've got to detect the exception model.
 488 dnl Link tests against libgcc.a are problematic since -- at least
 489 dnl as of this writing -- we've not been given proper -L bits for
 490 dnl single-tree newlib and libgloss.
 491 dnl
 492 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 493 dnl conftest files before we got a change to grep them first.
 494 cat > conftest.$ac_ext << EOF
 495 [#]line __oline__ "configure"
 496 struct S { ~S(); };
 497 void bar();
 498 void foo()
 499 {
 500   S s;
 501   bar();
 502 }
 503 EOF
 504 old_CXXFLAGS="$CXXFLAGS"
 505 CXXFLAGS=-S
 506 if AC_TRY_EVAL(ac_compile); then
 507   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 508     enable_sjlj_exceptions=yes
 509   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 510     enable_sjlj_exceptions=no
 511   fi
 512 fi
 513 CXXFLAGS="$old_CXXFLAGS"
 514 rm -f conftest*])
 515 if test x$enable_sjlj_exceptions = xyes; then
 516   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 517         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 518   ac_exception_model_name=sjlj
 519 elif test x$enable_sjlj_exceptions = xno; then
 520   ac_exception_model_name="call frame"
 521 else
 522   AC_MSG_ERROR([unable to detect exception model])
 523 fi
 524 AC_LANG_POP(C++)
 525 AC_MSG_RESULT($ac_exception_model_name)
 526
 527 # If we are non using SJLJ exceptions, and this host does not have support
 528 # for unwinding from a signal handler, enable checked dereferences and divides.
 529 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 530   CHECKREFSPEC=-fcheck-references
 531   DIVIDESPEC=-fuse-divide-subroutine
 532   EXCEPTIONSPEC=
 533 fi
 534
 535 # See if the user wants to disable java.net.  This is the mildly
 536 # ugly way that we admit that target-side configuration sucks.
 537 AC_ARG_ENABLE(java-net,
 538   AS_HELP_STRING([--disable-java-net],
 539                  [disable java.net]))
 540
 541 # Whether java.net is built by default can depend on the target.
 542 if test -z "$enable_java_net"; then
 543    enable_java_net=${enable_java_net_default-yes}
 544 fi
 545 if test "$enable_java_net" = no; then
 546    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 547 fi
 548
 549 # See if the user wants to configure without libffi.  Some
 550 # architectures don't support it, and default values are set in
 551 # configure.host.
 552 AC_ARG_WITH(libffi,
 553   AS_HELP_STRING([--without-libffi],
 554                  [don't use libffi]),
 555   [:],
 556   [with_libffi=${with_libffi_default-yes}])
 557
 558 LIBFFI=
 559 LIBFFIINCS=
 560 if test "$with_libffi" != no; then
 561    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 562    LIBFFI=../libffi/libffi_convenience.la
 563    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 564 fi
 565 AC_SUBST(LIBFFI)
 566 AC_SUBST(LIBFFIINCS)
 567
 568 # See if the user wants to disable JVMPI support.
 569 AC_ARG_ENABLE(jvmpi,
 570   AS_HELP_STRING([--disable-jvmpi],
 571                  [disable JVMPI support]))
 572
 573 if test "$enable_jvmpi" != no; then
 574     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 575 fi
 576
 577 # If the target is an eCos system, use the appropriate eCos
 578 # I/O routines.
 579 # FIXME: this should not be a local option but a global target
 580 # system; at present there is no eCos target.
 581 TARGET_ECOS=${PROCESS-"no"}
 582 AC_ARG_WITH(ecos,
 583 [  --with-ecos             enable runtime eCos target support],
 584 TARGET_ECOS="$with_ecos"
 585 )
 586
 587 PLATFORM_INNER_NAT_HDRS=
 588 case "$TARGET_ECOS" in
 589    no) case "$host" in
 590       *mingw*)
 591             PLATFORM=Win32
 592             PLATFORMNET=Win32
 593             PLATFORMH=win32.h
 594         CHECK_FOR_BROKEN_MINGW_LD
 595       ;;
 596       *)
 597             PLATFORM=Posix
 598             PLATFORMNET=Posix
 599             PLATFORMH=posix.h
 600             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 601       ;;
 602       esac
 603       ;;
 604    *)
 605       PLATFORM=Ecos
 606       PLATFORMNET=NoNet
 607       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 608       PLATFORMH=posix.h
 609       ;;
 610 esac
 611 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 612 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 613
 614 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 615                                       [Define if you have int32_t and uint32_t.]))
 616 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 617                                         [Define if you have int32_t and uint32_t.]))
 618 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 619                                           [Define if you have u_int32_t]))
 620 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 621                                            [Define if you have u_int32_t]))
 622
 623 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 624 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 625
 626 case "$host" in
 627   *-darwin*) DARWIN_CRT=true ;;
 628   *) DARWIN_CRT=false ;;
 629 esac
 630 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 631
 632 # These may not be defined in a non-ANS conformant embedded system.
 633 # FIXME: Should these case a runtime exception in that case?
 634 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 635                                   [Define is you have 'mktime' in <time.h>]))
 636 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 637                                   [Define is you have 'localtime' in <time.h>]))
 638
 639 # Create the subdirectory for natFile.cc, or the attempt
 640 # to create the link will fail.
 641 test -d java || mkdir java
 642 test -d java/io || mkdir java/io
 643 test -d gnu || mkdir gnu
 644 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 645
 646 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 647 test -d java/lang || mkdir java/lang
 648 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 649 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 650
 651 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 652 test -d java/net || mkdir java/net
 653 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 654 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 655
 656 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 657 test -d gnu/java || mkdir gnu/java
 658 test -d gnu/java/net || mkdir gnu/java/net
 659 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 660 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 661
 662 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 663 test -d gnu/java/nio || mkdir gnu/java/nio
 664 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 665 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 666 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 667 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 668
 669 case "${host}" in
 670     *mingw*)
 671       SYSTEMSPEC="-lgdi32 -lws2_32"
 672       if test "${with_win32_nlsapi}" = "unicows"; then
 673         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 674       fi
 675     ;;
 676     *)
 677       SYSTEMSPEC=
 678     ;;
 679 esac
 680 AC_SUBST(SYSTEMSPEC)
 681
 682 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 683 AC_SUBST(LIBGCJTESTSPEC)
 684
 685 AC_ARG_WITH(system-zlib,
 686   AS_HELP_STRING([--with-system-zlib],
 687                  [use installed libz]))
 688 ZLIBSPEC=
 689 AC_SUBST(ZLIBSPEC)
 690 ZLIBTESTSPEC=
 691 AC_SUBST(ZLIBTESTSPEC)
 692
 693 AC_PATH_XTRA
 694
 695 # FIXME: this should be _libs on some hosts.
 696 libsubdir=.libs
 697
 698 # extra LD Flags which are required for targets
 699 case "${host}" in
 700 *-*-darwin[[0-7]].*)
 701     # For now we have to disable it on darwin[8-9] because it slows down
 702     # the linking phase. A possible bug in ld?
 703     # on Darwin -single_module speeds up loading of the dynamic libraries.
 704     extra_ldflags_libjava=-Wl,-single_module
 705     ;;
 706 esac
 707 AC_SUBST(extra_ldflags_libjava)
 708
 709 # Allow the GC to be disabled.  Can be useful when debugging.
 710 AC_MSG_CHECKING([for garbage collector to use])
 711 AC_ARG_ENABLE(java-gc,
 712   AS_HELP_STRING([--enable-java-gc=TYPE],
 713                  [choose garbage collector (default is boehm)]),
 714   [GC=$enableval],
 715   [GC=boehm])
 716 GCLIBS=
 717 GCINCS=
 718 GCDEPS=
 719 GCSPEC=
 720 JC1GCSPEC=
 721 GCTESTSPEC=
 722 case "$GC" in
 723  boehm)
 724     AC_MSG_RESULT(boehm)
 725     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 726     JC1GCSPEC='-fuse-boehm-gc'
 727     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 728     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 729     GCOBJS=boehm.lo
 730     GCHDR=boehm-gc.h
 731     # The POSIX thread support needs to know this.
 732     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 733     ;;
 734  no)
 735     AC_MSG_RESULT(none)
 736     GCHDR=no-gc.h
 737     ;;
 738  *)
 739     AC_MSG_ERROR([unrecognized collector "$GC"])
 740     ;;
 741 esac
 742 AC_SUBST(GCLIBS)
 743 AC_SUBST(GCINCS)
 744 AC_SUBST(GCDEPS)
 745 AC_SUBST(GCSPEC)
 746 AC_SUBST(JC1GCSPEC)
 747 AC_SUBST(GCTESTSPEC)
 748 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 749 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 750 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 751
 752
 753 AC_MSG_CHECKING([for thread model used by GCC])
 754 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 755 AC_MSG_RESULT([$THREADS])
 756
 757 case "$THREADS" in
 758  no | none | single)
 759     THREADS=none
 760     ;;
 761  posix | posix95 | pthreads)
 762     THREADS=posix
 763     case "$host" in
 764      *-*-linux*)
 765         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 766         ;;
 767     esac
 768     ;;
 769  win32)
 770     ;;
 771  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 772     AC_MSG_ERROR(thread package $THREADS not yet supported)
 773     ;;
 774  *)
 775     AC_MSG_ERROR($THREADS is an unknown thread package)
 776     ;;
 777 esac
 778
 779 THREADCXXFLAGS=
 780 THREADLDFLAGS=
 781 THREADLIBS=
 782 THREADINCS=
 783 THREADDEPS=
 784 THREADH=
 785 THREADSPEC=
 786 case "$THREADS" in
 787  posix)
 788     case "$host" in
 789      *-*-cygwin*)
 790         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 791         ;;
 792      *-*-freebsd[[1234]]*)
 793         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 794         # merely adds pthread_* functions) but it does have a -pthread switch
 795         # which is required at link-time to select -lc_r *instead* of -lc.
 796         THREADLDFLAGS=-pthread
 797         # Don't set THREADSPEC here as might be expected since -pthread is
 798         # not processed when found within a spec file, it must come from
 799         # the command line.  For now, the user must provide the -pthread
 800         # switch to link code compiled with gcj.  In future, consider adding
 801         # support for weak references to pthread_* functions ala gthr.h API.
 802         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 803         ;;
 804      *-*-freebsd*)
 805         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 806         # systems which support threads and -lpthread.
 807         THREADLDFLAGS=-pthread
 808         THREADSPEC=-lpthread
 809         ;;
 810      alpha*-dec-osf* | hppa*-hp-hpux*)
 811         THREADCXXFLAGS=-pthread
 812         # boehm-gc needs some functions from librt, so link that too.
 813         THREADLIBS='-lpthread -lrt'
 814         THREADSPEC='-lpthread -lrt'
 815         ;;
 816      *)
 817         THREADLIBS=-lpthread
 818         THREADSPEC=-lpthread
 819         ;;
 820     esac
 821     THREADH=posix-threads.h
 822     # MIT pthreads doesn't seem to have the mutexattr functions.
 823     # But for now we don't check for it.  We just assume you aren't
 824     # using MIT pthreads.
 825     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 826
 827     # If we're using the Boehm GC, then we happen to know that it
 828     # defines _REENTRANT, so we don't bother.  Eww.
 829     if test "$GC" != boehm; then
 830        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 831     fi
 832     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 833     ;;
 834
 835  win32)
 836     THREADH=win32-threads.h
 837     ;;
 838
 839  none)
 840     THREADH=no-threads.h
 841     ;;
 842 esac
 843 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 844 AC_SUBST(THREADLIBS)
 845 AC_SUBST(THREADINCS)
 846 AC_SUBST(THREADDEPS)
 847 AC_SUBST(THREADSPEC)
 848 AC_SUBST(THREADLDFLAGS)
 849 AC_SUBST(THREADCXXFLAGS)
 850 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 851 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 852 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 853
 854 if test -d sysdep; then true; else mkdir sysdep; fi
 855 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 856 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 857 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 858
 859 HASH_SYNC_SPEC=
 860 # Hash synchronization is only useful with posix threads right now.
 861 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 862    HASH_SYNC_SPEC=-fhash-synchronization
 863    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 864 fi
 865 AC_SUBST(HASH_SYNC_SPEC)
 866
 867 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 868
 869 # We're in the tree with gcc, and need to include some of its headers.
 870 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 871
 872 if test "x${with_newlib}" = "xyes"; then
 873    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 874    # may not work correctly, because the compiler may not be able to
 875    # link executables.
 876
 877    # We assume newlib.  This lets us hard-code the functions we know
 878    # we'll have.
 879    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 880    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 881    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 882    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 883    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 884    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 885    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 886    # This is only for POSIX threads.
 887    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 888    # We also assume we are using gcc, which provides alloca.
 889    AC_DEFINE(HAVE_ALLOCA)
 890
 891    # Assume we do not have getuid and friends.
 892    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 893    PLATFORMNET=NoNet
 894 else
 895    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 896                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 897                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
 898                    nl_langinfo setlocale \
 899                    inet_pton uname inet_ntoa \
 900                    fork execvp pipe sigaction ftruncate mmap])
 901    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 902    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 903    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 904    AC_CHECK_LIB(dl, dladdr, [
 905        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 906        AC_CHECK_LIB(dld, dladdr, [
 907        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 908
 909    if test x"$build" = x"$host"; then
 910      AC_CHECK_FILES(/proc/self/exe, [
 911        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 912    else
 913      case $host in
 914      *-linux*)
 915        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 916        ;;
 917      esac
 918    fi
 919
 920    AM_ICONV
 921    AM_LC_MESSAGES
 922    AC_STRUCT_TIMEZONE
 923
 924    AC_CHECK_FUNCS(gethostbyname_r, [
 925      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 926        [Define if you have the 'gethostbyname_r' function.])
 927      # There are two different kinds of gethostbyname_r.
 928      # We look for the one that returns `int'.
 929      # Hopefully this check is robust enough.
 930      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 931        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 932
 933      case " $GCINCS " in
 934      *" -D_REENTRANT "*) ;;
 935      *)
 936         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 937         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 938         [libjava_cv_gethostbyname_r_needs_reentrant],
 939         [ AC_LANG_PUSH(C++)
 940           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 941             [[gethostbyname_r("", 0, 0);]])],
 942             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 943                 CPPFLAGS_SAVE="$CPPFLAGS"
 944                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 945                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 946                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 947                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 948                 CPPFLAGS="$CPPFLAGS_SAVE"
 949           ])
 950           AC_LANG_POP(C++)
 951         ])
 952         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 953           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 954         fi
 955      ;;
 956      esac
 957
 958      AC_CACHE_CHECK([for struct hostent_data],
 959         [libjava_cv_struct_hostent_data], [dnl
 960         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 961 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 962 # define _REENTRANT 1
 963 #endif
 964 #include <netdb.h>]], [[struct hostent_data data;]])],
 965           [libjava_cv_struct_hostent_data=yes],
 966           [libjava_cv_struct_hostent_data=no])])
 967      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 968        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 969          [Define if struct hostent_data is defined in netdb.h])
 970      fi
 971    ])
 972
 973    # FIXME: libjava source code expects to find a prototype for
 974    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 975    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 976    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 977    # linkage check is enough, yet C++ code requires proper prototypes.)
 978    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 979    AC_CHECK_FUNCS(gethostbyaddr_r, [
 980      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 981        [Define if you have the 'gethostbyaddr_r' function.])
 982      # There are two different kinds of gethostbyaddr_r.
 983      # We look for the one that returns `int'.
 984      # Hopefully this check is robust enough.
 985      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 986        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 987          [Define if gethostbyaddr_r returns 'int'.])])])])
 988
 989    AC_CHECK_FUNCS(gethostname, [
 990      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 991        [Define if you have the 'gethostname' function.])
 992      AC_EGREP_HEADER(gethostname, unistd.h, [
 993        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 994          [Define if gethostname is declared in <unistd.h>.])])])
 995
 996    AC_CHECK_FUNCS(usleep, [
 997      AC_EGREP_HEADER(usleep, unistd.h, [
 998        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 999           [Define if usleep is declared in <unistd.h>.])])])
1000
1001    # Look for these functions in the thread library, but only bother
1002    # if using POSIX threads.
1003    if test "$THREADS" = posix; then
1004       save_LIBS="$LIBS"
1005       LIBS="$LIBS $THREADLIBS"
1006       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1007       # E.g., Solaris.
1008       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1009
1010       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1011       # Solaris 7 the name librt is preferred.
1012       AC_CHECK_FUNCS(sched_yield, , [
1013         AC_CHECK_LIB(rt, sched_yield, [
1014           AC_DEFINE(HAVE_SCHED_YIELD)
1015           THREADLIBS="$THREADLIBS -lrt"
1016           THREADSPEC="$THREADSPEC -lrt"], [
1017           AC_CHECK_LIB(posix4, sched_yield, [
1018             AC_DEFINE(HAVE_SCHED_YIELD)
1019             THREADLIBS="$THREADLIBS -lposix4"
1020             THREADSPEC="$THREADSPEC -lposix4"])])])
1021
1022       AC_CHECK_LIB(rt, clock_gettime, [
1023          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1024          case "$THREADSPEC" in
1025            *-lrt*) ;;
1026            *)
1027              THREADSPEC="$THREADSPEC -lrt"
1028              THREADLIBS="$THREADLIBS -lrt"
1029              ;;
1030          esac])
1031
1032       LIBS="$save_LIBS"
1033
1034       # We can save a little space at runtime if the mutex has m_count
1035       # or __m_count.  This is a nice hack for Linux.
1036       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1037           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1038         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1039              [Define if pthread_mutex_t has m_count member.]), [
1040         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1041             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1042           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1043             [Define if pthread_mutex_t has __m_count member.]))])
1044    fi
1045
1046    # We require a way to get the time.
1047    time_found=no
1048    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1049    if test "$time_found" = no; then
1050       AC_MSG_ERROR([no function found to get the time])
1051    fi
1052
1053    AC_CHECK_FUNCS(memmove)
1054
1055    # We require memcpy.
1056    memcpy_found=no
1057    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1058    if test "$memcpy_found" = no; then
1059       AC_MSG_ERROR([memcpy is required])
1060    fi
1061    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1062    AC_CHECK_LIB(dl, dlopen, [
1063        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1064        AC_CHECK_LIB(dld, dlopen, [
1065        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1066
1067    # Some library-finding code we stole from Tcl.
1068    #--------------------------------------------------------------------
1069    #    Check for the existence of the -lsocket and -lnsl libraries.
1070    #    The order here is important, so that they end up in the right
1071    #    order in the command line generated by make.  Here are some
1072    #    special considerations:
1073    #    1. Use "connect" and "accept" to check for -lsocket, and
1074    #       "gethostbyname" to check for -lnsl.
1075    #    2. Use each function name only once:  can't redo a check because
1076    #       autoconf caches the results of the last check and won't redo it.
1077    #    3. Use -lnsl and -lsocket only if they supply procedures that
1078    #       aren't already present in the normal libraries.  This is because
1079    #       IRIX 5.2 has libraries, but they aren't needed and they're
1080    #       bogus:  they goof up name resolution if used.
1081    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1082    #       To get around this problem, check for both libraries together
1083    #       if -lsocket doesn't work by itself.
1084    #--------------------------------------------------------------------
1085
1086    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1087     [gcj_cv_lib_sockets=
1088      gcj_checkBoth=0
1089      unset ac_cv_func_connect
1090      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1091      if test "$gcj_checkSocket" = 1; then
1092          unset ac_cv_func_connect
1093          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1094                       gcj_checkBoth=1)
1095      fi
1096      if test "$gcj_checkBoth" = 1; then
1097          gcj_oldLibs=$LIBS
1098          LIBS="$LIBS -lsocket -lnsl"
1099          unset ac_cv_func_accept
1100          AC_CHECK_FUNC(accept,
1101                        [gcj_checkNsl=0
1102                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1103          unset ac_cv_func_accept
1104          LIBS=$gcj_oldLibs
1105      fi
1106      unset ac_cv_func_gethostbyname
1107      gcj_oldLibs=$LIBS
1108      LIBS="$LIBS $gcj_cv_lib_sockets"
1109      AC_CHECK_FUNC(gethostbyname, ,
1110                    [AC_CHECK_LIB(nsl, main,
1111                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1112      unset ac_cv_func_gethostbyname
1113      LIBS=$gcj_oldLIBS
1114    ])
1115    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1116
1117    if test "$with_system_zlib" = yes; then
1118       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1119    fi
1120
1121    # Test for Gtk stuff, if asked for.
1122    if test "$use_gtk_awt" = yes; then
1123       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1124       AC_SUBST(GTK_CFLAGS)
1125       AC_SUBST(GTK_LIBS)
1126
1127       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1128       AC_SUBST(GLIB_CFLAGS)
1129       AC_SUBST(GLIB_LIBS)
1130
1131       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1132       AC_SUBST(LIBART_CFLAGS)
1133       AC_SUBST(LIBART_LIBS)
1134
1135       # We require the XTest Extension to support java.awt.Robot.
1136       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1137                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1138                    [${X_LIBS}])
1139    fi
1140
1141    # On Solaris, and maybe other architectures, the Boehm collector
1142    # requires -ldl.
1143    if test "$GC" = boehm; then
1144       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1145    fi
1146 fi
1147
1148 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1149 case $build in
1150     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1151     *)         CLASSPATH_SEPARATOR=':' ;;
1152 esac
1153 AC_SUBST(CLASSPATH_SEPARATOR)
1154
1155 # We must search the source tree for java.lang, since we still don't
1156 # have libgcj.jar nor java/lang/*.class
1157 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1158 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1159
1160 # Since some classes depend on this one, we need its source available
1161 # before we can do any GCJ compilation test :-(
1162 if test ! -f gnu/classpath/Configuration.java; then
1163   test -d gnu || mkdir gnu
1164   test -d gnu/classpath || mkdir gnu/classpath
1165   # Note that it is not crucial that all the values here be correct.
1166   sed -e "s,@prefix@,$prefix," \
1167       -e "s,@VERSION@,$VERSION," \
1168       -e "s,@LIBDEBUG@,false," \
1169       -e "s,@INIT_LOAD_LIBRARY@,false," \
1170       -e "s,@@,$LIBGCJDEBUG," \
1171       -e "s,@default_toolkit@,$TOOLKIT," \
1172       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1173       -e "s,@GTK_CAIRO_ENABLED@,false," \
1174         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1175         > gnu/classpath/Configuration.java
1176   # We do not want to redirect the output of the grep below to /dev/null,
1177   # but we add /dev/null to the input list so that grep will print the
1178   # filename of Configuration.java in case it finds any matches.
1179   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1180     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1181   fi
1182 fi
1183
1184 LT_AC_PROG_GCJ
1185
1186 # Now remove it.
1187 rm -f gnu/classpath/Configuration.java
1188
1189 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1190
1191 AC_CHECK_SIZEOF(void *)
1192
1193 AC_C_BIGENDIAN
1194
1195 ZLIBS=
1196 SYS_ZLIBS=
1197 ZINCS=
1198
1199 if test -z "$ZLIBSPEC"; then
1200    # Use zlib from the GCC tree.
1201    ZINCS='-I$(top_srcdir)/../zlib'
1202    ZLIBS=../zlib/libzgcj_convenience.la
1203 else
1204    # System's zlib.
1205    SYS_ZLIBS="$ZLIBSPEC"
1206 fi
1207 AC_SUBST(ZLIBS)
1208 AC_SUBST(SYS_ZLIBS)
1209 AC_SUBST(ZINCS)
1210 AC_SUBST(DIVIDESPEC)
1211 AC_SUBST(CHECKREFSPEC)
1212 AC_SUBST(EXCEPTIONSPEC)
1213 AC_SUBST(BACKTRACESPEC)
1214 AC_SUBST(IEEESPEC)
1215
1216 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1217 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1218 AC_SUBST(GCC_UNWIND_INCLUDE)
1219
1220 # Process the option "--enable-version-specific-runtime-libs"
1221 # Calculate toolexeclibdir
1222 case ${version_specific_libs} in
1223   yes)
1224     # Need the gcc compiler version to know where to install libraries
1225     # and header files if --enable-version-specific-runtime-libs option
1226     # is selected.
1227     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1228     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1229     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1230     toolexeclibdir=$toolexecmainlibdir
1231     ;;
1232   no)
1233     if test -n "$with_cross_host" &&
1234        test x"$with_cross_host" != x"no"; then
1235       # Install a library built with a cross compiler in tooldir, not libdir.
1236       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1237       toolexecmainlibdir='$(toolexecdir)/lib'
1238     else
1239       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1240       toolexecmainlibdir='$(libdir)'
1241     fi
1242     multi_os_directory=`$CC -print-multi-os-directory`
1243     case $multi_os_directory in
1244       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1245       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1246     esac
1247     ;;
1248 esac
1249 AC_SUBST(toolexecdir)
1250 AC_SUBST(toolexecmainlibdir)
1251 AC_SUBST(toolexeclibdir)
1252
1253 # Determine where the standard .db file is found.
1254 multi_os_directory=`$CC -print-multi-os-directory`
1255 case $multi_os_directory in
1256   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1257   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1258 esac
1259 AC_SUBST(dbexecdir)
1260
1261 # Determine gcj version number.
1262 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1263 GCJVERSION=$gcjversion
1264 AC_SUBST(GCJVERSION)
1265 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1266
1267 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1268 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1269
1270 TL_AC_GXX_INCLUDE_DIR
1271
1272 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1273 # On that system, sys/ioctl.h will not include sys/filio.h unless
1274 # BSD_COMP is defined; just including sys/filio.h is simpler.
1275 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1276 # for now.  If you change this, you also must update natFile.cc.
1277 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1278                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1279                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1280                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1281                   dirent.h sys/rw_lock.h])
1282 AC_CHECK_HEADERS(inttypes.h, [
1283     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1284     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1285 ])
1286 AC_HEADER_SYS_WAIT
1287
1288 AC_CHECK_TYPE([ssize_t], [int])
1289
1290 AC_MSG_CHECKING([for in_addr_t])
1291 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1292 #if STDC_HEADERS
1293 #include <stdlib.h>
1294 #include <stddef.h>
1295 #endif
1296 #if HAVE_NETINET_IN_H
1297 #include <netinet/in.h>
1298 #endif]], [[in_addr_t foo;]])],
1299   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1300      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1301    AC_MSG_RESULT(yes)],
1302   [AC_MSG_RESULT(no)])
1303
1304 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1305 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1306   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1307      [Define if struct ip_mreq is defined in netinet/in.h.])
1308    AC_MSG_RESULT(yes)],
1309   [AC_MSG_RESULT(no)])
1310
1311 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1312 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1313   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1314      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1315    AC_MSG_RESULT(yes)],
1316   [AC_MSG_RESULT(no)])
1317
1318 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1319 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1320   [AC_DEFINE(HAVE_INET6, 1,
1321      [Define if inet6 structures are defined in netinet/in.h.])
1322    AC_MSG_RESULT(yes)],
1323   [AC_MSG_RESULT(no)])
1324
1325 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1326 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1327 #include <sys/types.h>
1328 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1329   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1330    AC_MSG_RESULT(yes)],
1331   [AC_MSG_RESULT(no)])
1332
1333 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1334 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1335   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1336    AC_MSG_RESULT(yes)],
1337   [AC_MSG_RESULT(no)
1338    AC_MSG_CHECKING([for global timezone variable])
1339    dnl FIXME: we don't want a link check here because that won't work
1340    dnl when cross-compiling.  So instead we make an assumption that
1341    dnl the header file will mention timezone if it exists.
1342    dnl Don't find the win32 function timezone
1343    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1344      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1345       AC_MSG_RESULT(yes)],
1346      [AC_MSG_RESULT(no)
1347        AC_MSG_CHECKING([for global _timezone variable])
1348        dnl FIXME: As above, don't want link check
1349        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1350          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1351             [Define if your platform has the global _timezone variable.])
1352           AC_MSG_RESULT(yes)],
1353           [AC_MSG_RESULT(no)])])])
1354
1355 AC_FUNC_ALLOCA
1356
1357 AC_CHECK_PROGS(PERL, perl, false)
1358
1359 SYSDEP_SOURCES=
1360 SIGNAL_HANDLER_AUX=
1361
1362 case "${host}" in
1363  i?86-*-linux*)
1364     SIGNAL_HANDLER=include/i386-signal.h
1365     ;;
1366  sparc*-sun-solaris*)
1367     SIGNAL_HANDLER=include/sparc-signal.h
1368     ;;
1369 # ia64-*)
1370 #    SYSDEP_SOURCES=sysdep/ia64.c
1371 #    test -d sysdep || mkdir sysdep
1372 #    ;;
1373  hppa*-*-linux*)
1374     SIGNAL_HANDLER=include/pa-signal.h
1375     ;;
1376  hppa*-hp-hpux*)
1377     SIGNAL_HANDLER=include/hppa-signal.h
1378     ;;
1379  ia64-*-linux*)
1380     SIGNAL_HANDLER=include/dwarf2-signal.h
1381     ;;
1382  powerpc*-*-linux*)
1383     SIGNAL_HANDLER=include/powerpc-signal.h
1384     ;;
1385  alpha*-*-linux*)
1386     SIGNAL_HANDLER=include/dwarf2-signal.h
1387     ;;
1388  s390*-*-linux*)
1389     SIGNAL_HANDLER=include/s390-signal.h
1390     ;;
1391  x86_64*-*-linux*)
1392     SIGNAL_HANDLER=include/x86_64-signal.h
1393     SIGNAL_HANDLER_AUX=include/i386-signal.h
1394     ;;
1395  sparc*-*-linux*)
1396     SIGNAL_HANDLER=include/dwarf2-signal.h
1397     ;;
1398  sh*-*-linux*)
1399     SIGNAL_HANDLER=include/sh-signal.h
1400     ;;
1401  *mingw*)
1402     SIGNAL_HANDLER=include/win32-signal.h
1403     ;;
1404  mips*-*-linux*)
1405     SIGNAL_HANDLER=include/mips-signal.h
1406     ;;
1407  *-*-darwin*)
1408     SIGNAL_HANDLER=include/darwin-signal.h
1409     ;;
1410  *)
1411     SIGNAL_HANDLER=include/default-signal.h
1412     ;;
1413 esac
1414
1415 # If we're using sjlj exceptions, forget what we just learned.
1416 if test "$enable_sjlj_exceptions" = yes; then
1417    SIGNAL_HANDLER=include/default-signal.h
1418    SIGNAL_HANDLER_AUX=
1419 fi
1420
1421 AC_SUBST(SYSDEP_SOURCES)
1422
1423 if test -z "$SIGNAL_HANDLER_AUX"; then
1424   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1425 fi
1426
1427 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1428                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1429
1430 if test "${multilib}" = "yes"; then
1431   multilib_arg="--enable-multilib"
1432 else
1433   multilib_arg=
1434 fi
1435
1436 # See if we support thread-local storage.
1437 GCC_CHECK_TLS
1438
1439 # Check if linker supports static linking on a per library basis
1440 LD_START_STATIC_SPEC=
1441 LD_FINISH_STATIC_SPEC=
1442 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1443   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1444     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1445     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1446   fi
1447 fi
1448 AC_SUBST(LD_START_STATIC_SPEC)
1449 AC_SUBST(LD_FINISH_STATIC_SPEC)
1450
1451 here=`${PWDCMD-pwd}`
1452 AC_SUBST(here)
1453
1454 # We get this from the environment.
1455 AC_SUBST(GCJFLAGS)
1456
1457 AC_CONFIG_FILES([
1458 Makefile
1459 libgcj.pc
1460 libgcj.spec
1461 libgcj-test.spec
1462 gcj/Makefile
1463 include/Makefile
1464 testsuite/Makefile
1465 ])
1466
1467 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1468
1469 AC_CONFIG_COMMANDS([default],
1470 [# Only add multilib support code if we just rebuilt top-level Makefile.
1471 case " $CONFIG_FILES " in
1472  *" Makefile "*)
1473    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1474    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1475    ;;
1476 esac
1477 for ac_multi_file in $CONFIG_FILES; do
1478   case $ac_multi_file in
1479   */Makefile)
1480     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1481   esac
1482 done
1483 ],
1484 srcdir=${srcdir}
1485 host=${host}
1486 target=${target}
1487 with_multisubdir=${with_multisubdir}
1488 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1489 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1490 libgcj_basedir=${libgcj_basedir}
1491 CC="${CC}"
1492 CXX="${CXX}"
1493 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1494 )
1495
1496 AC_OUTPUT